         TITLE 'IERADR - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERADR ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION:                                                       00700013
*   OSCL/2314 SORT PH DEBLOCK ASSIGN. FOR F.L. RCDS. W/E15 AND/OR E16   00800013
*   THE FUNCTION OF THIS MODULE IS TO INITIALIZE A RECORD STORAGE AREA  00900013
*   TABLE IN IERRDD. THIS TABLE WOULD CONSIST OF UP TO 5 ENTRIES FOR    01000013
*   5 NON-CONTIGUOUS RSA'S. THIS MODULE BUILDS THE INPUT BUFFER(S)      01100013
*   IT ALSO CHECKS TO SEE WHETHER WE ARE ATTACHED,WHETHER E15 AND E16   01200013
*   ARE ACTIVATED AND OVERLAYS IERRDD IN APPROPRIATE PLACES. IT ALSO    01300013
*   PASSES IERRDD THE STARTING ADDRESS OF THE INPUT DCB.                01400013
         SPACE 2                                                        01500013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               01600013
         SPACE 1                                                        01700013
*   NONE                                                                01800013
         SPACE 2                                                        01900013
*LIST OF MACROS USED BY MODULE:                                         02000013
         SPACE 1                                                        02100013
*   SMPPI                                                               02200013
*   BUILDS                                                              02300013
         SPACE 2                                                        02400013
*ENTRY POINTS:                                                          02500013
         SPACE 1                                                        02600013
*   FROM  IERRC9                   ENTRY FROM:IERRC9                    02700013
*                                    CALLING SEQUENCE-                  02800013
*                                      LOAD EP=IERADD,DCB=SORTLIB       02900013
*                                      LR   RP,RA                       03000013
*                                      BALR RO,RP                       03100013
         SPACE 2                                                        03200013
*INPUT: - PPI FIELDS REFERENCED                                         03300013
         SPACE 1                                                        03400013
*   PPIDEB     PPILAB08   PPINMAX                                       03500013
*   PPILAB03   PPILEXFF   PPIATP1E                                      03600013
*   PPILAB02   PPIMODEX   PPISTDCB                                      03700013
         SPACE 1                                                        03800013
*   INFO IS NEEDED TO BUILD RSA TABLE IN IERRDD,TO BUILD THE INPUT      03900013
*   BUFFER(S),TO SEE WHAT USER EXITS ARE ACTIVATED                      04000013
         SPACE 2                                                        04100013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            04200013
         SPACE 1                                                        04300013
*   PPISW1                                                              04400013
         SPACE 2                                                        04500013
*EXTERNAL ROUTINES:                                                     04600013
         SPACE 1                                                        04700013
*   NONE                                                                04800013
         SPACE 2                                                        04900013
*EXTERNAL PARAMETERS:                                                   05000013
         SPACE 1                                                        05100013
*   SEE REGISTERS                                                       05200013
         SPACE 2                                                        05300013
*EXITS-NORMAL:                                                          05400013
         SPACE 1                                                        05500013
*   TO  IERRC9                     EXIT TO:IERRC9                       05600013
*                                    CALLING SEQUENCE-                  05700013
*                                      BR   RO         RETURN           05800013
         SPACE 2                                                        05900013
*EXITS-ERROR:                                                           06000013
         SPACE 1                                                        06100013
*   NONE                                                                06200013
         SPACE 2                                                        06300013
*TABLES/WORK AREAS:                                                     06400013
         SPACE 1                                                        06500013
*   WAREA-WORK AREA                                                     06600013
         SPACE 2                                                        06700013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   06800013
         SPACE 2                                                        06900013
*NOTES:THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT HAVING        07000013
*   USER EXITS E15 AND/OR E16, OR ATTACHED. IT IS USED IN THE           07100013
*   OSCILLATING OR 2314 SORT.                                           07200013
         EJECT                                                          07300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07400013
         SPACE 1                                                        07500013
RA       EQU   0                   CONTENTS IN- N/A                     07600013
*                                  USE- NO. OF BUFFERS AND BUFFER SIZE  07700013
*                                    FOR BUILD MACRO                    07800013
*                                  CONTENTS OUT- N/A                    07900013
RB       EQU   1                   CONTENTS IN- N/A                     08000013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   08100013
*                                    BUILD MACRO                        08200013
*                                  CONTENTS OUT- N/A                    08300013
RC       EQU   2                   CONTENTS IN- N/A                     08400013
*                                  USE- ADDR OF RSA TABLE IN IERRDC     08500013
*                                  CONTENTS OUT- N/A                    08600013
RD       EQU   3                   CONTENTS IN- N/A                     08700013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    08800013
*                                  CONTENTS OUT- N/A                    08900013
RE       EQU   4                   CONTENTS IN- N/A                     09000013
*                                  USE- WORK REGISTER                   09100013
*                                  CONTENTS OUT- N/A                    09200013
RF       EQU   5                   CONTENTS IN- N/A                     09300013
*                                  USE- ADDR OF RSA TABLE IN PPI        09400013
*                                  CONTENTS OUT- N/A                    09500013
RG       EQU   6                   CONTENTS IN- N/A                     09600013
*                                  USE- INDEX REGISTER                  09700013
*                                  CONTENTS OUT- N/A                    09800013
RH       EQU   7                   CONTENTS IN- N/A                     09900013
*                                  USE- WORK REGISTER                   10000013
*                                  CONTENTS OUT- N/A                    10100013
RI       EQU   8                   CONTENTS IN- N/A                     10200013
*                                  USE- NOT USED                        10300013
*                                  CONTENTS OUT- N/A                    10400013
RJ       EQU   9                   CONTENTS IN- N/A                     10500013
*                                  USE- NOT USED                        10600013
*                                  CONTENTS OUT- N/A                    10700013
RK       EQU   10                  CONTENTS IN-N/A                      10800013
*                                  USE- IERRDD DSECT BASE REGISTER      10900013
*                                  CONTENTS OUT- N/A                    11000013
RL       EQU   11                  CONTENTS IN- N/A                     11100013
*                                  USE-MODULE BASE REGISTER             11200013
*                                  CONTENTS OUT- N/A                    11300013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   11400013
*                                  USE- NOT USED                        11500013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   11600013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              11700013
*                                  USE-PPI REFERENCES,REG SAVE AREA     11800013
*                                  CONTENTS OUT-ADDR OF PPI             11900013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      12000013
*                                  USE- NOT USED                        12100013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     12200013
RP       EQU   15                  CONTENTS IN- IERADD ENTRY PT         12300013
*                                  USE- ESTABLISH IERADD BASE REGISTER  12400013
*                                  CONTENTS OUT- N/A                    12500013
         SPACE 2                                                        12600013
*START OF MODULE CODE PROPER:                                           12700013
         SPACE 2                                                        12800013
IERADR   CSECT                                                          12900013
         USING *,RL                THIS MODULE BASE REGISTER            13000013
         USING IERRDR,RK           BASE REG FOR R.P. DSECT              13100013
         USING IERRCA,RN           PPI BASE REG                         13200013
IERMDA   LR    RL,RP                                                    13300013
         L     RK,PPIDEB+4                                              13400013
         SPACE 2                                                        13500013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  13600013
*   COUNTS AND BUILD RSA TABLE IN IERRDD.                               13700013
         SPACE 1                                                        13800013
         L     RC,PPILAB08        PTR TO TABLE OF RSA ADDRS WITH        13900013
         ST    RC,ADCONPTR          THIER RESPECTIVE BYTE COUNTS        14000013
         SR    RD,RD                                                    14100013
         SR    RG,RG                                                    14200013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     14300013
         LA    RH,4                4 BYTES FOR TREE ADDRESS             14400013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       14500013
*                                    CONTROL FIELDS                     14600013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 14700013
*                                    RESPECTIVE BYTE COUNTS             14800013
ADDRSALP L     RE,0(RG,RF)         STARTING ADDR OF AN RSA AREA         14900013
         AR    RE,RH               EQLS ADDR OF 1ST RCD IN THE RSA AREA 15000013
         ST    RE,0(RG,RC)         STORE IN IERRDD RSA ADDR TABLE       15100013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          15200013
         ST    RE,4(RG,RC)         STORE IN IERRDD RSA ADDR TABLE       15300013
         LA    RG,8(0,RG)          UPDATE INDEX REG                     15400013
         BCT   RD,ADDRSALP         DECR RSA CTR, LOOP IF MORE RSA AREAS 15500013
         MVC   WADDRSA(8),0(RC)   INITIALIZE PARAMETERS IN RUNNING P.   15600013
         SPACE 1                                                        15700013
         CLC   PPIATP1E,KZERO      TEST IF ATTACHED EXIT                15800013
         BC    7,ADBYPSB           YES, BYPASS BUILD MACRO              15900013
         SPACE 1                                                        16000013
* SET UP AND BUILD THE INPUT BUFFER(S)                                  16100013
         SPACE 1                                                        16200013
         L     RB,PPILAB02        SET REG 1 = ADDRESS OF BUFFER LIST    16300013
         MVC   WAREA+2(2),PPILAB03+2  SIZE OF INPUT BFR(S)              16400013
         MVC   WAREA+1(1),PPILAB03   NO. OF INPUT BFR(S)                16500013
         L     0,WAREA             NO. AND SIZE OF BFR(S) IN BYTES      16600013
         SPACE 1                                                        16700013
         BUILDS (1),(0)            BUILD INPUT BUFFER(S)                16800013
         SPACE 1                                                        16900013
* CALCULATE ADDR OF DCB AND STORE IN R.P.                               17000013
         SPACE 1                                                        17100013
ADBYPSB  L     RE,PPISTDCB         POINTER TO LIST OF DCB ADDRESSES     17200013
         MVC   WDCB,0(RE)          STORE DCB ADDR IN R.P.               17300013
         SPACE 1                                                        17400013
         TM    PPIMODEX,X'20'      TEST IF NMAX EXIT ACTIVATED          17500013
         BC    1,ADSTONMX          YES,BR TO STORE NMAX IN R.P.         17600013
         MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN OF R.P. 17700013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ETC R.P.  17800013
ADTSTATT CLC   PPIATP1E,KZERO      TEST IF ATTACHED EXIT                17900013
         BC    7,ADATTEXT          YES, BR TO ATTACH EXIT RTN           18000013
         TM    PPIMODEX,X'40'      TEST IF ANY USER RCD MODIFICATIONS   18100013
         BC    1,ADENDMOD          YES, BR TO LINK TO NEXT RTN          18200013
         MVC   RDUSREXT,RDOVLAY4   OVERLAY USER EXIT E15 WITH A BRANCH  18300013
*                                    TO DO NOTHING RTN IN R.P.          18400013
         OI    PPISW1+7,X'80'      SET USER EXIT E15 EOF SWITCH IN PPI  18500013
         SPACE 1                                                        18600013
*IF 2314, OVERLAY RMAX CHECK IN R.P.  RETURN TO IERRC9.                 18700013
         SPACE 1                                                        18800013
ADENDMOD TM    PPISW1+6,X'02'      2314 SORT                            18900013
         BCR   8,RO                  NO, RETURN TO RC9.                 19000013
         SPACE 1                                                        19100013
         MVC   RDRMXCNT(4),KADRKON OVERLAY RMAX CHECK                   19200013
         BR    RO                  RETURN TO RC9                        19300013
         SPACE 2                                                        19400013
ADATTEXT MVC   PPIX15+4(4),PPIATP1E  R.P. EXIT E15 NOW LINKS TO ATTACH  19500013
*                                    RTN                                19600013
         MVC   RDTSTISW(4),K5      OVLAY INSERT SWITCH TEST IN R.P.     19700013
         OI    PPISW1+3,X'01'      SET SYSTEM EOF SWITCH IN PPI         19800013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       19900013
*                                    EOF'S ARE SIMULATED                20000013
         B     ADENDMOD            RETURN TO LOAD MODULE                20100013
         SPACE 2                                                        20200013
ADSTONMX L     RE,PPINMAX          LOAD NMAX                            20300013
         LA    RE,1(0,RE)          EQUALS NMAX + 1 (TO ALLOW BCT INSTR  20400013
*                                    IN R.P. TO DECR NMAX CTR)          20500013
         ST    RE,WNMAX            STORE IN R.P.                        20600013
         B     ADTSTATT            BR TO TEST IF ATTACHED               20700013
         SPACE 1                                                        20800013
         SPACE 2                                                        20900013
* LIST OF CONSTANTS USED BY THE MODULE                                  21000013
KZERO    DC    F'0'                                                     21100013
         DROP  RL                                                       21200013
         DROP  RK                                                       21300013
         USING IERRDR,RL                                                21400013
KADRKON  B     RDOVLAY5            BYPASS RMAX CHECK                    21500013
         SPACE 1                                                        21600013
         SPACE 2                                                        21700013
* LIST OF WORK AREAS                                                    21800013
WAREA    DC    F'0'                                                     21900013
         EJECT                                                          22000013
IERRDR   DSECT                     DSECT OF IERRDR                      22100013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    22200013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  22300013
         USING IERRMA,RO           MESSAGE MODULE ADDR                  22400013
         SPACE 1                                                        22500013
* ENTER BRANCH TABLE FROM REPLACEMENT SORT,0(RL).FROM READ MOD, 4(RL).  22600013
*   OR FROM REPLACEMENT SORT(INITIALLY TO FILL TREE), ALGORITHM(AT THE  22700013
*   END OF A SEQUENCE), BLOCK MODULE(AFTER FILLING TREE), 8(RL).        22800013
IERDD1   B     RDOVLAYF            FROM REPL SORT,FINISHD FILLING TREE  22900013
         B     RDSETSW             FROM READ MOD(GET,ON EOF)            23000013
         B     RDNORMAL            NORMAL ENTRY FROM REPLACEMENT SORT   23100013
*                                    BLOCK MODULE OR ALGORITHM          23200013
         SPACE 2                                                        23300013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN REFILLING TREE         23400013
         SPACE 1                                                        23500013
         OI    RDOVLAY6+1,X'F0'    REACTIVATE BR INSTR TO FILLING EXIT  23600013
         NI    RDDOVLAY+1,X'00'    NOP BRANCH ON (G+1)TH RECORD         23700013
         MVC   RDNORMAL,K6         REINITIALIZE ENTRY BRANCH INSTR      23800013
         MVC   RDOVLAY5,K7         REOVERLAY BRANCH ON (G+1)TH RECORD   23900013
         L     RK,PPILAB08        LOAD ADDRESS OF RSA PARAM TABLE       24000013
         ST    RK,ADCONPTR         STORE                                24100013
         MVC   WADDRSA(8),0(RK)    MOVE NEW RSA PARAMS INTO WORK AREA   24200013
*                                    FIRST WORD = ADDRESS NEXT RSA BIN  24300013
*                                    SECOND = BIN BYTE COUNT            24400013
         L     RB,WADDRESS         LOAD AD OF LAST RECORD FOR MOVE RTN  24500013
         L     RD,WADDRSA           TO MOVE SAVED RCD INTO RSA          24600013
         B     RDRMXCNT                                                 24700013
         SPACE 2                                                        24800013
* FROM REPLACEMT SORT BLOCK MOD,OR ALGORITHM                            24900013
         SPACE 1                                                        25000013
RDNORMAL ST    RD,WINNER           ADDR OF A FREE AREA IN RSA-LAST WNR  25100013
RDLDCTRS STM   RJ,RK,WRJ           SAVE TRANSPARENT REGS                25200013
         LM    RJ,RK,WNMAX         RESTORE NMAX AND DCB ADDR            25400013
RDTSTISW TM    PPISW1+7,X'20'     TST INSERT SW. WILL BE OVERLAID BY    25500013
*                                    A.P. IF ATTACHED,OR BY R.P. ON     25600013
*                                    SYSTEM EOF,WITH B RDUSREXT         25700013
         BC    1,RDUSREXT          ON, BR TO USER EXIT                  25800013
RDGET    GET   (RK)                UPDATE ADDR IN INPUT AREA(REG RB)    25900013
*                                    REG RK HAS DCB ADDR                26000013
         L     RG,PPICOUNT         RECORD COUNTER                       26050013
         LA    RG,1(0,RG)          INCR RCD CTR BY ONE                  26100013
         ST    RG,PPICOUNT         STORE RECORD COUNT                   26150013
         ST    RB,WADDRESS         SET FOR RE-INIT. ENTRY               26200013
         ST    RB,WINPTRCD         SAVE ADDR OF RCD THATS IN INPUT BLK  26300013
         SPACE 1                                                        26400013
* USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.            26500013
*   PASS ADDR OF PARAMETER LIST(ADDR OF INPUT RCD) IN REGISTER RB       26600013
         SPACE 1                                                        26700013
RDUSREXT LA    RB,WINPTRCD         ADDR OF PARAMETER LIST. IF E15 NOT   26800013
*                                    ACTIVATED, OR IF ACTIVATED AND HIT 26900013
*                                    USER EOF,THIS INSTR WILL BE OVLAYD 27000013
*                                    BY B RDALSHNO                      27100013
         L     RP,PPIX15+4         ADDR OF USER EXIT E15. IF ATTACHED   27200013
*                                    A.P. WILL LOAD PPIX15 WITH ADDR IN 27300013
*                                    PPIATP1E                           27400013
         BALR  RO,RP               BR TO USER                           27500013
         SPACE 1                                                        27600013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS. USER   27700013
*   PASSES ADDR OF RECORD TO BE INSERTED OR ADDR OF WORK AREA IF HE     27800013
*   ALTERS,LENGTHENS,OR SHORTENS A RCD IN REG RB.                       27900013
         SPACE 1                                                        28000013
         B     *+4(15)                                                  28100013
RDOVLAY4 B     RDALSHNO            ALTER,LENGTHN,SHORTN,DO NOTHING      28200013
*                                    WILL BE OVERLAYED BY K4 IF,WHEN    28300013
*                                    REACH NMAX IT IS IGNORED, OR BY    28400013
*                                    A.P. WITH K4 IF EXIT NOT ACTIVE    28500013
         B     RDDELETE            DELETE A RCD                         28600013
         B     RDUSREOF            USER END OF FILE                     28700013
         SPACE 1                                                        28800013
* INSERT A RECORD                                                       28900013
         SPACE 1                                                        29000013
RDTSTNMX BCT   RJ,RDISWON          DECR NMAX CTR BY ONE AND TEST TO     29100013
*                                    SEE IF REACHED NMAX                29200013
*                                    WILL BE OVERLAYED BY K3 IF, WHEN   29300013
*                                    REACH NMAX IT IS IGNORED, OR BY    29400013
*                                    A.P. WITH K3 IF EXIT NOT ACTIVE    29500013
         B     RDWSW1ON            YES,BR TO NMAX USER EXIT E16,SW ON   29600013
         SPACE 2                                                        29700013
* SYSTEM END OF FILE ROUTINE                                            29800013
         SPACE 1                                                        29900013
RDSETSW  TM    PPISW1+7,X'80'      TEST IF USER EOF SWITCH ON           30000013
         BO    RDCNTSRT              YES, BRANCH TO FLUSH TREE          30100013
         SPACE 1                                                        30200013
         TM    PPISW1+3,X'01'      TEST IF SIMULATED EOF                30300013
         BNO   RDCNTSRT              YES, BRANCH TO FLUSH TREE          30400013
           SPACE 1                                                      30500013
         CLI   REALEOF,X'01'       IS THIS SIM. EOF AFTER               30600013
         BE    RDCNTSRT              REAL EOF                           30700013
         SPACE 1                                                        30800013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       30900013
*                                    EOF'S ARE SIMULATED                31000013
         SPACE 1                                                        31100013
         SR    RB,RB               CLEAR INPUT RCD PARAM REG            31200013
         MVC   RDTSTISW,K5         TO BYPASS GOING TO GET AFTER SYS EOF 31300013
         B     RDUSREXT-4          NO, BR TO USER                       31400013
         SPACE 2                                                        31500013
* USER END OF FILE ROUTINE                                              31600013
         SPACE 1                                                        31700013
RDUSREOF OI    PPISW1+7,X'80'     SET USER EOF SWITCH                   31800013
         MVC   RDUSREXT,RDOVLAY4   OVLAY USER EXIT-BYPASS EXIT E15      31900013
         TM    PPISW1+3,X'01'     TEST IF SYSTEM EOF SWITCH ON          32000013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              32100013
         L     RB,WINPTRCD         RESTORE ADDR OF RCD IN INPUT BLK     32200013
         B     RDALSHNO            BR TO SORT THIS RCD                  32300013
         SPACE 2                                                        32400013
RDISWON  OI    PPISW1+7,X'20'     TURN INSET SWITCH ON                  32500013
         L     RI,PPIINSCT         INSERT COUNT                         32550013
         LA    RI,1(0,RI)          INCR INSERT CTR BY ONE               32600013
        ST    RI,PPIINSCT         STORE INSERT COUNT                    32700013
RDSTM    ST    RB,WADDRESS         SAVE FOR RE-INIT                     32800013
         ST    RJ,WNMAX            SAVE NMAX CTR                        32900013
RDRMXCNT L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   33000013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   33100013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     33200013
         BH    RDRMAX              BRANCH ON YES                        33300013
         ST    RG,WRMAX            SAVE                                 33400013
         SPACE 1                                                        33500013
* INITALIZE AND BR TO MOVE RTN TO MOVE NEXT INPUT RCD TO RSA            33600013
         SPACE 1                                                        33700013
RDOVLAY5 B     RDDLDRSA            BR TO GET ADDR IN RSA TO MOVE RCD    33800013
*                                    WILL BE OVLAYED BY L RF,WINNER     33900013
*                                    AFTER G+1 RCDS                     34000013
RDDLDRE  LR    RE,RB               ADDR OF RCD IN INPUT BUFFER OR FROM  34100013
*                                    USER'S WORK AREA                   34200013
         L     RP,PPIBDSVA+4       ADDR OF MOVE RTN IN GENERATED CORE   34300013
         BALR  RO,RP               BR TO MOVE RTN.MOVE RCD TO RSA       34400013
RDOVLAY6 B     RDFILLTR            BR TO SORT NETWORK FILLING TREE RTN  34500013
*                                    WILL BE OVLAYED BY NOP AFTER       34600013
*                                    TREE IS INITIALLY FILLED           34700013
         SPACE 2                                                        34800013
* NORMAL EXIT TO SORT NETWORK AFTER PREVIOUS INSTR IS OVERLAYED BY NOP  34900013
         SPACE 1                                                        35000013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          35100013
         L     RD,WINNER                                                35200013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 35300013
         B     12(RL)              BR TO SORT NETWORK NORMAL RTN        35400013
         SPACE 2                                                        35500013
* EXIT TO SORT NETWORK WHILE FILLING TREE                               35600013
         SPACE 1                                                        35700013
RDFILLTR LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          35800013
         A     RD,PPIBINSZ         UPDATE TO NEXT BIN IN THIS RSA       35900013
         ST    RD,WADDRSA          SAVE UPDATED RSA ADDRESS             36000013
         S     RD,PPIBINSZ         RESTORE FOR NETWORK. ADDR OF THIS    36100013
*                                    RCD IN RSA                         36200013
         L     RL,PPINET+4         ADDR OF NETWORK                      36300013
         B     4(RL)               BR TO SORT NETWORK FILL TREE RTN     36400013
         SPACE 2                                                        36500013
         SPACE 2                                                        36600013
* FINISHED FILLING TREE RTN -ONE TIME RTN                               36700013
         SPACE 1                                                        36800013
RDOVLAYF NI    RDOVLAY6+1,X'00'    NOP THE BR INSTR TO THE FILLING EXIT 36900013
         MVI   RDDOVLAY+1,X'F0'    OVLAY INSTR IN RSA TABLE ROUTINE     37000013
         B     RDLDCTRS            BR TO GET G+1 RECORD.                37100013
         SPACE 2                                                        37200013
*RSA TABLE ROUTINE USED DURING FILLING OF TREE. ENTER HERE ONLY THROUGH 37300013
*   G+1 RECORDS.                                                        37400013
         SPACE 1                                                        37500013
RDDLDRSA L     RK,ADCONPTR         RSA TABLE PTR                        37600013
RDDRTRN  LM    RD,RE,WADDRSA       RD=ADDR IN THIS RSA, RE = REMAINING  37700013
*                                    BYTE COUNT OF THIS RSA.            37800013
         S     RE,PPIBINSZ         SUBTR SIZE OF THIS RCD               37900013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS RSA 38000013
RDDOVLAY BC    0,RDDLAST           WILL BE A BR AFTER RSA HAS G RCDS    38100013
         SPACE 2                                                        38200013
         ST    RE,WBYTECNT         SAVE REMAINING BYTE COUNT THIS RSA   38300013
         LR    RF,RD               ADDR IN RSA TO MOVE THE RCD          38400013
         B     RDDLDRE             BR TO MOVE RCD TO RSA                38500013
         SPACE 2                                                        38600013
RDNEWRSA LA    RK,8(0,RK)          UPDATE RSA TABLE PTR TO NEXT RSA     38700013
*                                    ENTRY(NEXT NON-CONTIGUOUS RSA)     38800013
         ST    RK,ADCONPTR         SAVE UPDATED PTR                     38900013
         MVC   WADDRSA(8),0(RK)   MOVE NEW PARAMS INTO WORK AREA        39000013
*                                    FIRST WORD = ADDRESS NEXT RSA BIN  39100013
*                                    SECOND = BIN BYTE COUNT            39200013
         B     RDDRTRN             BR TO USE THIS RSA                   39300013
         SPACE 2                                                        39400013
*WE ARE GOING TO PROCESS THE G+1 RECORD.                                39500013
         SPACE 1                                                        39600013
RDDLAST  ST    RD,WINNER           ADDR IN RSA TO MOVE RCD              39700013
         MVC   RDOVLAY5(4),K1      OVLAY BRANCH INSTR TO RSA TABLE RTN  39800013
         B     RDOVLAY5            BR TO MOVE G+1 RCD TO RSA.           39900013
         SPACE 2                                                        40000013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              40100013
         SPACE 1                                                        40200013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 40300013
         OI    PPISW1+7,X'80'      SET USER EOF FOR ALG.                40400013
         TM    PPISW1+3,X'01'    WAS SYS EOF REACHED                    40500013
         BC    1,RDCNTSRT          YES,BR AROUND NEXT INSTRS-FLUSH TREE 40600013
         L     RG,PPICOUNT         RECORD COUNT                         40650013
         BCTR  RG,0                DECR PPICOUNT BY ONE                 40700013
         ST    RG,PPICOUNT         STORE RECORD COUNT                   40750013
         OI    PPISW1+3,X'01'      SET EOF SW, SO ALG. WON'T RETURN     40800013
         SPACE 1                                                        40900013
* FROM GET ON END OF FILE                                               41000013
RDCNTSRT MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               41100013
         L     RL,PPINET+4         ADDR OF NTWK                         41300013
         B     8(RL)               BR TO NTWK TO EMPTY TREE             41400013
         SPACE 2                                                        41500013
RDEMPTYT L     RL,PPINET+4         ADDR OF NTWK                         41600013
         B     16(RL)              BR TO SORT TO CONTINUE EMPTYING TREE 41700013
         SPACE 2                                                        41800013
* WRITE MESSAGE NMAX EXCEEDED                                           41900013
         SPACE 1                                                        42000013
RDWSW1ON OI    WSW1,X'01'          TURN SWITCH 1 ON                     42100013
RDMSGS   L     RO,PPIRMA+4        ADDRESS OF MESSAGE MODULE             42200013
         LR    RE,RB               SAVE ADDR OF NMAX+1 RCD              42300013
         LM    RA,RB,MSGP1A04      NAME AND LENGTH OF MESSAGE           42400013
         L     RP,PPIADSSC         LOAD PRINT RTN ADDR                  42500013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      42600013
         SPACE 1                                                        42700013
* USER EXIT E16 -SORT CAPACITY, NMAX, HAS BEEN REACHED                  42800013
*   CALL MACRO INSTRUCTION EXPANSION                                    42900013
         SPACE 1                                                        43000013
         LR    RB,RE               RESTORE ADDR OF NMAX+1 RCD           43100013
         L     RP,PPIX16+4         ADDR OF NMAX EXIT                    43200013
         BALR  RO,RP               BR TO USER                           43300013
         SPACE 2                                                        43400013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS.        43500013
         SPACE 1                                                        43600013
         B     *+4(15)                                                  43700013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         43800013
         B     RDIGNORE            IGNORE NMAX AND CONTINUE TO SORT     43900013
         SPACE 1                                                        44000013
* ABORT THE JOB. SET UP ABNORMAL END INDICATION FOR SORT SYSTEM CONTROL 44100013
         SPACE 1                                                        44200013
         L     RP,PPIADSSC                                              44300013
         BAL   RO,16(0,RP)         BR TO SORT SYSTEM CONTROL            44400013
         SPACE 1                                                        44500013
* IGNORE NMAX. OVERLAY NMAX TEST WITH A BYPASS BRANCH INSTR.            44600013
         SPACE 1                                                        44700013
RDIGNORE MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN         44800013
         CLC   RDUSREXT,RDOVLAY4   HAS USER EXIT CODE BEEN OVERLAID?    44900013
         BNE   *+10                IF NOT, BRANCH AROUND NEXT INSTRUC   45000013
         MVC   RDUSREXT,K4         CHANGE OVERLAID INSTRUCTION          45100013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ALTER RTN 45200013
         TM    WSW1,X'01'          TEST SWITCH 1                        45300013
         BC    1,RDISWON           ON,BR TO TURN INSERT SWITCH ON       45400013
         B     RDISWOFF            BR TO TURN INSERT SWITCH OFF         45500013
         SPACE 2                                                        45600013
* DO NOTHING, ALTER, LENGTHEN, SHORTEN A RCD. ADDR OF INPUT RCD IN RB.  45700013
         SPACE 1                                                        45800013
RDALSHNO BCT   RJ,RDISWOFF         DECR NMAX CTR BY ONE AND TST TO SEE  45900013
*                                    IF REACHED NMAX                    46000013
         B     RDMSGS              YES, BR TO NMAX USER EXIT E16        46100013
         SPACE 2                                                        46200013
RDISWOFF NI    PPISW1+7,X'DF'     TURN OFF INSERT SWITCH                46300013
         B     RDSTM               BR TO LOAD ADDR OF FREE AREA IN RSA  46400013
         SPACE 2                                                        46500013
* DELETE A RECORD                                                       46600013
         SPACE 1                                                        46700013
RDDELETE NI    PPISW1+7,X'DF'     TURN OFF INSERT SWITCH                46800013
         L     RH,PPIDELCT         DELETE COUNT                         46850013
         LA    RH,1(0,RH)          INCR DELETE CTR BY ONE               46900013
         ST    RH,PPIDELCT         STORE DELETE COUNT                   46950013
         B     RDGET               BR TO GET ANOTHER RECORD             47000013
         SPACE 2                                                        47100013
*        ENOUGH RECORDS HAVE BEEN READ IN TO FILL ONE REEL OF TAPE      47200013
         SPACE 1                                                        47300013
RDRMAX   SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         47400013
         ST    RB,WADDRESS         SAVE ADDRESS OF THIS RECORD          47500013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   47600013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  47700013
         MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               47800013
         L     RL,PPINET+4         ADDRESS OF NETWORK                   47900013
         B     8(RL)               BR TO NETWORK TO EMPTY TREE          48000013
         SPACE 1                                                        48100013
* END OF CODING --- ADCONS NEXT PAGE                                    48200013
         EJECT                                                          48300013
* LIST OF CONSTANTS USED BY THE MODULE                                  48400013
         SPACE 1                                                        48500013
K1       L     RF,WINNER           OVERLAY WHEN FINISHED FILLING TREE   48600013
K2       B     RDEMPTYT            OVERLAY TO EMPTYTREE ON GET EOF      48700013
K3       B     RDISWON             BYPASS NMAX TEST IN INSERT RTN       48800013
K4       B     RDISWOFF            BYPASS NMAX TEST IN DO NOTHG,ETC RTN 48900013
K5       B     RDUSREXT            OVERLAY INSERT SW TEST BY A.P. IF    49000013
*                                    ATTACHED                           49100013
K6       ST    RD,WINNER           AD OF FREE AREA IN RSA - LAST WINNER 49200013
K7       B     RDDLDRSA            BR TO GET AD IN RSA TO MOVE RECORD   49300013
         SPACE 2                                                        49400013
* LIST OF WORK AREAS                                                    49500013
         SPACE 1                                                        49600013
WSW1     DC    X'00'               SWITCH 1 IN INSERT RTN               49700013
REALEOF  DC    X'00'                                                    49800013
WINNER   DC    F'0'                SORT WINNER RCD ADDR                 49900013
WNMAX    DC    F'0'                MAX NO OF RCDS TO SORT PLUS ONE(FOR  50000013
*                                    SPEED, CAN NOW USE BCT TO DECR     50100013
*                                    NMAX CTR TO ZERO)                  50200013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR INPUT FILE  50300013
*                                    LOADED BY ASSIGNMENT ROUTINE       50400013
WRJ      DC    2F'0'               SAVE TRANPARENT REGS                 50500013
WINPTRCD DC    F'0'                ADDR OF RCD IN INPUT AREA            50600013
WADDRESS DS    F                   ADDRESS OF NEXT RECORD TO BE MOVED   50700013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     50800013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               50900013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    51000013
ADCONPTR DS    F                  UPDATED ADDRESS OF RSA PARAM TABLE    51100013
         EJECT                                                          51200013
* MODULE NAME ***IERRMA***                                              51300013
*                                                                       51400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        51500013
* PHASE 1 RUNNING PROGRAM.                                              51600013
         SPACE 1                                                        51700013
IERRMA   DSECT                                                          51800013
*                                                                       51900013
       COPY  RMAMAIN                                                    52000013
         EJECT                                                          52100013
         SMPPI                                                          52200013
         END                                                            52300013
