         TITLE '      IERADS - OS/360 SORT/MERGE - 360S-SM023 05/08/66' 00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERADS ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION:                                                       00700013
*   OSCL/2314 SORT PH DEBLOCK ASSIGN. FOR V.L. RCDS W/E15 AND/OR E16    00800013
*   THE FUNCTION OF THIS MODULE IS TO CALCULATE THE NUMBER OF BINS IN   00900013
*   UP TO 5 NON-CONTIGUOUS RECORD STORAGE AREAS AND CHAIN ALL THESE     01000013
*   BINS TOGETHER. IT PUTS THE ADDRESS OF THE FIRST BIN IN THE FIRST    01100013
*   RSA IN AVAIL(PPIBDSVA+4). INPUT BUFFERS ARE SET UP VIA THE BUILD    01200013
*   MACRO. EXTRACT SIZE + 4 IS CALCULATED AND STORED IN THE RUNNING     01300013
*   PROGRAM. EXITS E15 AND E16 ARE TESTED AND A TEST IS MADE TO SEE IF  01400013
*   SORT HAS BEEN ATTACHED. AS A RESULT OF THESE TESTS PROPER OVERLAYS  01500013
*   WILL BE MADE AND NMAX+1 MAY BE STORED IN RUNNING PROGRAM,IERRDE.    01600013
         SPACE 1                                                        01700013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      01800013
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.              01900013
         SPACE 2                                                        02000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               02100013
         SPACE 1                                                        02200013
*   NONE                                                                02300013
         SPACE 2                                                        02400013
*LIST OF MACROS USED BY MODULE:                                         02500013
         SPACE 1                                                        02600013
*   SMPPI                                                               02700013
*   BUILDS                                                              02800013
         SPACE 2                                                        02900013
*ENTRY POINTS:                                                          03000013
         SPACE 1                                                        03100013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    03200013
*                                    CALLING SEQUENCE-                  03300013
*                                      LOAD EP=IERADD,DCB=SORTLIB       03400013
*                                      LR   RP,RA                       03500013
*                                      BALR RO,RP                       03600013
         SPACE 2                                                        03700013
*INPUT: - PPI FIELDS REFERENCED                                         03800013
         SPACE 1                                                        03900013
*   PPINMAX    PPILAB03   PPIMODEX                                      04000013
*   PPIBINSZ   PPILAB02   PPILEXFF                                      04100013
*   PPIATPIE   PPILAB08                                                 04200013
         SPACE 1                                                        04300013
*   ADDRESSES FOR BUFFERS AND TABLES,INFO FOR USER EXITS AND FOR THE    04400013
*   RSA CHAINING ROUTINE AND FOR THE BUILD MACRO                        04500013
         SPACE 2                                                        04600013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            04700013
         SPACE 1                                                        04800013
*   PPIBDSVA                                                            04900013
*   PPISW1                                                              05000013
         SPACE 1                                                        05100013
*   INITIALIZE START OF RSA(AVAIL) AND TOTAL NUMBER OF BINS IN ALL THE  05200013
*   RSA'S.                                                              05300013
         SPACE 2                                                        05400013
*EXTERNAL ROUTINES:                                                     05500013
         SPACE 1                                                        05600013
*   NONE                                                                05700013
         SPACE 2                                                        05800013
*EXTERNAL PARAMETERS:                                                   05900013
         SPACE 1                                                        06000013
*   SEE REGISTERS                                                       06100013
         SPACE 2                                                        06200013
*EXITS-NORMAL:                                                          06300013
         SPACE 1                                                        06400013
*   TO IERRC9                      EXIT TO:IERRC9                       06500013
*                                    CALLING SEQUENCE-                  06600013
*                                      BR   RO         RETURN           06700013
         SPACE 2                                                        06800013
*EXITS-ERROR:                                                           06900013
         SPACE 1                                                        07000013
*   NONE                                                                07100013
         SPACE 2                                                        07200013
*TABLES/WORK AREAS:                                                     07300013
         SPACE 1                                                        07400013
*   WCOMBINE-WORK AREA                                                  07500013
         SPACE 2                                                        07600013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   07700013
         SPACE 2                                                        07800013
*NOTES:                                                                 07900013
*   THIS MODULE IS THE ASSIGNMENT ROUTINE FOR THE OSCILLATING/2314 SORT 08000013
*   PHASE DEBLOCK ROUTINE FOR VARIABLE LENGTH RECORDS WITH USER         08100013
*   MODIFICATION EXITS E15 AND/OR E16.                                  08200013
         EJECT                                                          08300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            08400013
         SPACE 1                                                        08500013
RA       EQU   0                   CONTENTS IN-N/A                      08600013
*                                  USE-NO. OF BUFFERS AND BUFFER SIZE   08700013
*                                    FOR BUILD MACRO                    08800013
*                                  CONTENTS OUT-N/A                     08900013
RB       EQU   1                   CONTENTS IN-N/A                      09000013
*                                  USE-ADDR OF INPUT BUFFER POOL FOR    09100013
*                                    BUILD MACRO.                       09200013
*                                  CONTENTS OUT-N/A                     09300013
RC       EQU   2                   CONTENTS IN-N/A                      09400013
*                                  USE-NOT USED                         09500013
*                                  CONTENTS OUT-N/A                     09600013
RD       EQU   3                   CONTENTS IN-N/A                      09700013
*                                  USE-NO. OF RSA AREAS -RSA TABLE CALC 09800013
*                                  CONTENTS OUT-N/A                     09900013
RE       EQU   4                   CONTENTS IN-N/A                      10000013
*                                  USE-WORK REGISTER                    10100013
*                                  CONTENTS OUT-N/A                     10200013
RF       EQU   5                   CONTENTS IN-N/A                      10300013
*                                  USE-NO. OF BYTES COUNTER IN 1 RSA    10400013
*                                  CONTENTS OUT-N/A                     10500013
RG       EQU   6                   CONTENTS IN-N/A                      10600013
*                                  USE-CURRENT BIN ADDR IN AN RSA-USED  10700013
*                                    IN RSA TABLE CALC.                 10800013
*                                  CONTENTS OUT- N/A                    10900013
RH       EQU   7                   CONTENTS IN-N/A                      11000013
*                                  USE-PTR TO RSA TABLE IN PPI-UPDATE   11100013
*                                    FOR EACH RSA.                      11200013
*                                  CONTENTS OUT- N/A                    11300013
RI       EQU   8                   CONTENTS IN- N/A                     11400013
*                                  USE- GENERAL WORK REGISTER           11500013
*                                  CONTENTS OUT-N/A                     11600013
RJ       EQU   9                   CONTENTS IN- N/A                     11700013
*                                  USE-NOT USED                         11800013
*                                  CONTENTS OUT-N/A                     11900013
RK       EQU   10                  CONTENTS IN- N/A                     12000013
*                                  USE-IERRDE DSECT BASE REGISTER       12100013
*                                  CONTENTS OUT-N/A                     12200013
RL       EQU   11                  CONTENTS IN-N/A                      12300013
*                                  USE-MODULE BASE REGISTER             12400013
*                                  CONTENTS OUT-N/A                     12500013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   12600013
*                                  USE-NOT USED                         12700013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   12800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              12900013
*                                  USE-PPI REFERENCES,REG SAVE AREA     13000013
*                                  CONTENTS OUT-ADDR OF PPI             13100013
RO       EQU   14                  CONTENTS IN-IERRC9 RETURN ADDR       13200013
*                                  USE-NOT USED                         13300013
*                                  CONTENTS OUT-IERRC9 RETURN ADDR      13400013
RP       EQU   15                  CONTENTS IN-IERADE ENTRY PT          13500013
*                                  USE-ESTABLISH IERADE BASE REG        13600013
*                                  CONTENTS OUT-N/A                     13700013
         SPACE 2                                                        13800013
*START OF MODULE CODE PROPER:                                           13900013
         SPACE 2                                                        14000013
IERADS   CSECT                                                          14100013
*1157414500                                                        1297 14150018
         USING *,RL                THIS MODULE BASE REGISTER            14200013
         USING IERRDS,RK           IERRDS DSECT BASE REGISTER           14300013
         USING IERRCA,RN           PPI ADDR                             14400013
IERMDA   LR    RL,RP               ESTABLISH THIS MODULE BASE REGISTER  14500013
         L     RK,PPIDEB+4         ADDR OF IERRDE CSECT                 14600013
         SPACE 2                                                        14700013
*CHAIN ALL BINS TOGETHER BY PUTTING IN EACH BIN THE ADDR OF THE NEXT    14800013
*   AVAILABLE BIN. SAVE THE ADDRESS OF THE 1ST AVAILABLE BIN IN         14900013
*   PPIBDSVA+4,AND THE TOTAL NO. OF AVAILABLE BINS IN PPIBDSVA+8.       15000013
         SPACE 1                                                        15100013
         SR    RD,RD                                                    15200013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     15300013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              15400013
         L     RG,0(0,RH)          ADDR OF THIS RSA AREA BIN            15500013
         ST    RG,PPIBDSVA+4       SAVE THIS ADDR IN AVAIL(FOR IERRDE)  15600013
ADSLOOPO L     RF,4(0,RH)          NO. OF BYTES IN THIS RSA AREA        15700013
         LA    RI,ADSLOOPI         LOAD RETURN REG FOR THIS LOOP CALC   15800013
         SR    RE,RE                                                    15900013
         D     RE,PPIBINSZ         RE=NO.OF BINS IN THIS RSA AREA       16000013
         L     RE,PPIBDSVA+8       TOTAL NO.OF BINS IN ALL RSA'S SO FAR 16100013
         AR    RE,RF               UPDATE BIN COUNT                     16200013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               16300013
ADSLOOPI BCT   RF,ADSCHAIN         DECR NO. OF BINS CTR FOR THIS RSA.   16400013
*                                    BR IF MORE BINS IN THIS RSA.       16500013
         BCT   RD,ADNXTRSA         DECR NO. OF RSA'S CTR. BR IF MORE    16600013
*                                   RSA'S. THE LAST BIN IN THE LAST     16700013
*                                   RSA HAS NO CHAIN ADDRESS.           16800013
         A     RF,PPIATP1E         ARE WE ATTACHED                      16900013
         BC    7,ADSNOBLD          YES-DON'T BUILD BUFFERS              17000013
         MVC   WCOMBINE+1(1),PPILAB03                                   17100013
         MVC   WCOMBINE+2(2),PPILAB03+2                                 17200013
         L     RA,WCOMBINE         POSITION NO. AND SIZE OF BUFFERS     17300013
         L     RB,PPILAB02        SET REG 1 = ADDRESS OF BUFFER LIST    17400013
         BUILDS (1),(0)                                                 17500013
         SPACE 2                                                        17600013
ADSNOBLD LH    RE,PPILEXFF         GET EXTRACT SIZE                     17700013
         A     RE,KFOUR                                                 17800013
         STH   RE,EXPLFOUR         STORE EXTRACT SIZE + 4               17900013
         TM    PPIMODEX,X'20'      TEST IF NMAX EXIT ACTIVATED          18000013
         BC    1,ADSSTNM           GO STORE NMAX IN R.P.-IT'S ACTIVE    18100013
         MVC   RDSMAXCK(4),K2      OVERLAY NMAX TEST IN INSER3 LEG      18200013
         MVC   RDSDONO(4),K3       OVERLAY NMAX TEST IN ALTER LEG       18300013
ADSTATT  CLC   PPIATP1E,KZERO      TEST IF ATTACHED                     18400013
         BC    7,ADSATACH          IT IS ATTACHED                       18500013
         TM    PPIMODEX,X'40'      TEST FOR USER RCD MOD EXIT           18600013
         BC    1,ADSEXIT           BRANCH TO EXIT                       18700013
         MVC   RDSUEXIT(4),K4      OVERLAY USER EXIT 15 WITH A BRANCH   18800013
         MVC   RDSMSG,K7                                                18900013
         OI    PPISW1+7,X'80'      SET USER EXIT E15 EOF SWITCH IN PPI  19000013
         MVI   RDSISWON,X'58'      CHANGE INSTRUCTION TO L RB,ADRHOLD   19100013
ADSEXIT  L     RE,PPISTDCB         DCB ADDRESS                   A26453 19110019
         L     RE,0(RE)                                          A26453 19120019
         ST    RE,KAWORK+4         STORE IN R.P.WORK AREA        A26453 19130019
         TM    PPIMODEX+2,X'02'    VRE IN?                       A26453 19140019
         BZ    ADSRETUR            NO...                         A26453 19150019
         L     RE,PPIGETMN         ADDR OF GETMAIN TABLE OF ADDR A26453 19160019
         L     RE,12(RE)           FETCH ADDR OF VRE WORK AREA   A26453 19170019
         ST    RE,KAWORK           STORE IN R.P. WORK AREA       A26453 19180019
         SPACE 1                                                        19200013
*IF 2314, OVERLAY RMAX CHECK IN R.P.  RETURN TO IERRC9.                 19300013
ADSRETUR TM    PPISW1+6,X'02'      2314 CHECK                    A26453 19400019
         BCR   8,RO                  NO, RETURN TO RC9                  19500013
         SPACE 1                                                        19600013
         MVC   RDSRMAX(4),KADSKON  OVERLAY RMAX CHECK                   19700013
         BR    RO                  RETURN TO RC9                        19800018
         SPACE 2                                                        19900013
ADSSTNM  L     RE,PPINMAX          LOAD NMAX                            20000013
         LA    RE,1(0,RE)          PLUS 1 (FOR USING BCT INSTRUCTION)   20100013
         ST    RE,WNMAX            STORE IN R.P.                        20200013
         B     ADSTATT             GO TEST FOR ATTACHED                 20300013
         SPACE 2                                                        20400013
ADSATACH MVC   PPIX15+4(4),PPIATP1E E15 NOW IS ATTACHED                 20500013
         MVC   RDSNORM(4),K5       OVERLAY INSRT SW TEST-BR ARND GET    20600013
         OI    PPISW1+3,X'01'      SET SYSTEM EOF SWITCH IN PPI         20700013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       20800013
*                                    EOF'S ARE SIMULATED                20900013
         B     ADSEXIT             RETURN TO LOAD MODULE                21000013
         SPACE 2                                                        21100013
ADNXTRSA LA    RI,ADSREAL          RESET RETURN REG FOR THIS LOOP       21200013
         SPACE 2                                                        21300013
*INSERT CHAIN ADDR IN EACH BIN OF EACH RSA EXCEPT THE LAST BIN OF THE   21400013
*   LAST RSA.                                                           21500013
         SPACE 1                                                        21600013
ADSCHAIN A     RG,PPIBINSZ         ADDR OF THIS BIN + BIN SIZE          21700013
         LR    RE,RG               SAVE ADDR OF THE NEXT BIN            21800013
         S     RE,KFOUR            PTS TO AREA IN PREVIOUS BIN TO PUT   21900013
*                                    THE CHAIN ADDR OF NEXT BIN(IN RG)  22000013
         ST    RG,0(0,RE)          PREVIOUS BIN NOW CHAINED TO NEXT BIN 22100013
         BR    RI                  BR TO ADELOOPI ON ALL BINS EXCEPT    22200013
*                                    THE LAST BIN IN EACH RSA OTHERWISE 22300013
*                                    BR TO ADEREAL ON THIS LAST BIN     22400013
         SPACE 2                                                        22500013
*OVERLAY LAST BIN CHAIN ADDR OF THIS RSA WITH PROPER ADDRESS.(1ST BIN   22600013
*   ADDR OF NEXT RSA)                                                   22700013
         SPACE 1                                                        22800013
ADSREAL  LA    RH,8(0,RH)          UPDATE PPI RSA TABLE PTR TO NEXT     22900013
*                                    RSA ENTRY                          23000013
         L     RG,0(0,RH)          ADDR OF 1ST BIN IN NEXT RSA          23100013
         ST    RG,0(0,RE)          STORE AS CHAIN ADDR IN LAST BIN OF   23200013
*                                    PREVIOUS RSA.                      23300013
         B     ADSLOOPO            BR TO CHAIN BINS OF THIS RSA         23400013
         SPACE 2                                                        23500013
*LIST OF CONSTANTS:                                                     23600013
         SPACE 1                                                        23700013
KZERO    DC    F'0'                CONSTANT 0                           23800013
         DROP  RL                                                       23900013
         DROP  RK                                                       24000013
         USING IERRDS,RL                                                24100013
KADSKON  B     RDSPTB              BYPASS RMAX CHECK                    24200013
         SPACE 2                                                        24300013
*LIST OF WORK AREAS/TABLES:                                             24400013
         SPACE 1                                                        24500013
WCOMBINE DC    F'0'                WORK AREA                            24600013
         EJECT                                                          24700013
IERRDS   DSECT                                                          24800013
         USING *,RL                                                     24900013
         USING IERRCA,RN                                                25000013
         USING IERRMA,RO           MESSAGE MODULE ADR                   25100013
IERDD1   B     RDSOLAY             GO TO OVERLAY EXITS                  25200013
         B     RDSEOF              GO TO EOF ROUTINE                    25300013
         B     RDSNTER             NORMAL ENTRY TO DEBLOCK ANOTHER RCD  25400013
         SPACE 2                                                        25500013
*        ENTRY TO REINITIALIZE TO BEGIN REFILLING THE TREE              25600013
         SPACE 1                                                        25700013
         LA    RE,4                CHANGE ENTRIES TO NETWORK            25800013
         STC   RE,RDSFIT+3                                              25900013
         LA    RE,24                                                    26000013
         STC   RE,RDSSPEC-1                                             26100013
         MVC   RDSNTER(4),K6                                            26200013
         SPACE 2                                                        26300013
*        CHAIN BINS TOGETHER BY PUTTING IN EACH BIN THE ADDRESS OF THE  26400013
*        NEXT AVAILABLE BIN. SAVE THE ADDRESS OF THE FIRST AVAILABLE    26500013
*        BIN IN PPIBDSVA+4 AND THE TOTAL NUMBER OF AVAILABLE BINS IN    26600013
*        PPIBDSVA+8.                                                    26700013
         SPACE 1                                                        26800013
         SR    RD,RD                                                    26900013
         ST    RD,PPIBDSVA+8      ZERO OUT AV0TCABLE BINS COUNT         27000013
         IC    RD,PPILAB08         NUMBER OF RSA AREAS                  27100013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              27200013
         L     RG,0(RH)            ADDRESS OF THIS RSA AREA BIN         27300013
         ST    RG,PPIBDSVA+4       SAVE ADDRESS OF FIRST RSA BIN        27400013
         SPACE 1                                                        27500013
RDAAAA   L     RF,4(RH)            NO. BYTES IN THIS RSA AREA           27600013
         LA    RI,RDBBBB           LOAD RETURN REG FOR THIS LOOP CALC   27700013
         SR    RE,RE                                                    27800013
         D     RE,PPIBINSZ         RF = NO. BINS IN THIS RSA AREA       27900013
         L     RE,PPIBDSVA+8       TOTAL NO. BINS IN RSA SO FAR         28000013
         AR    RE,RF               UPDATE BIN COUNT                     28100013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               28200013
         SPACE 1                                                        28300013
RDBBBB   BCT   RF,RDDDDD           DECR NO. BINS CTR FOR THIS RSA       28400013
*                                    BR IF MORE BINS IN THIS RSA        28500013
         BCT   RD,RDCCCC           DECR NO. OF RSA'S CTR. BR IF MORE    28600013
*                                    RSA'S. THE LAST BIN IN THE LAST    28700013
*                                    RSA HAS NO CHAIN ADDRESS.          28800013
         B     RDFFFF              BR TO LOAD MOVE PARAMETERS           28900013
         SPACE 1                                                        29000013
RDCCCC   LA    RI,RDSEEE           RESET RETURN REG FOR THIS LOOP       29100013
RDDDDD   A     RG,PPIBINSZ         ADDRESS OF THIS BIN + BIN SIZE       29200013
         LR    RE,RG               SAVE ADDRESS OF NEXT BIN             29300013
         S     RE,KFOUR            PTS TO AREA IN PREVIOS BIN TO PUT    29400013
*                                    THE CHAIN AD OF NEXT BIN (IN RG)   29500013
         ST    RG,0(RE)            PREVIOUS BIN NOW CHAINED TO NEXT BIN 29600013
         BR    RI                  BR TO RDBBBB ON ALL BINS EXCEPT THE  29700013
*                                    LAST BIN IN EACH RSA. OTHERWISE    29800013
*                                    BR TO RDSEEE                       29900013
         SPACE 1                                                        30000013
RDSEEE   LA    RH,8(RH)            UPDATE PPI RSA TABLE PTR TO NEXT     30100013
*                                    RSA ENTRY                          30200013
         L     RG,0(RH)            ADDRESS OF FIRST BIN IN NEXT RSA     30300013
         ST    RG,0(RE)            STORE AS CHAIN ADDRESS IN LAST BIN   30400013
*                                    OF PREVIOUS RSA.                   30500013
         B     RDAAAA              CAL NEW RSA                          30600018
         SPACE 2                                                        30700013
*        LOAD PARAMS TO MOVE SAVED RECORD INTO RSA                      30800013
         SPACE 1                                                        30900013
RDFFFF   L     RE,WADDRESS         GE3 ADDRES2 OF SAVED RECORD          31000013
         B     RDSRMAX             B TO RESTART RMAX COUNT              31100013
         SPACE 2                                                        31200013
*        NORMAL ENTRY TO DEBLOCK ANOTHER RECORD                         31300013
         SPACE 1                                                        31400013
RDSNTER  CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  31500013
         BL    RDSNORM             NO FIT SWITCH OFF                    31600013
         BH    RDSSPEC             NO. OF BINS WAS=0                    31700013
         SR    RE,RE                                                    31800013
         A     RE,PPIBDSVA+8                                            31900013
         BZ    RDSBINZ             BIN COUNT STILL=0                    32000013
         L     RA,WSAVE                                                 32100013
         L     RE,WSAVE+4          RELOAD REGS TO CONTINUE MOVE         32200013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 32300013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                32400013
         ST    RD,0(0,RC)          INSERT CHAIN ADDRESS                 32500013
         LA    RB,8(0)             INDICATE DEBLOCK WITH NOFIT PREVIOUS 32600013
         L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          32700013
RDSMOVE  L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             32800013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               32900013
         SPACE 2                                                        33000013
         B     RDSNOTF             RECORD DIDN'T FIT                    33100013
         SPACE                                                          33200013
*  RECORD FIT ROUTINE                                                   33300013
         SPACE                                                          33400013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  33500013
         BC    7,RDSUSUAL          LAST MOVE WAS NOT A NO FIT           33600013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       33700013
         SR    RC,RC                                                    33800013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     33900013
         B     RDSUSUAL+4          RD ALREADY LOADED                    34000013
RDSUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RCD JUST MOVED          34100013
         AH    RD,EXPLFOUR         ADD EXT SIZE & 4                     34200013
         L     RC,ADRHOLDB         LOAD BUFFER ADDRESS                  34300013
         L     RE,PPIBDSVA+8                                            34400013
         SR    RE,RB                                                    34500013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     34600013
         L     RE,0(0,RF)                                               34700013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         34800013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               34900013
         L     RL,PPINET+4                                              35000013
RDSFIT   B     4(0,RL)             EXIT TO SORT ON RECORD FIT CONDITION 35100013
         SPACE 2                                                        35200013
*  RECORD NO FIT ROUTINE                                                35300013
         SPACE                                                          35400013
RDSNOTF  ST    RA,WSAVE                                                 35500013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              35600013
         SR    RD,RD                                                    35700013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         35800013
         OI    NOFITSW,X'01'       SET NOFITSW=01                       35900013
         A     RD,WSAVAIL                                               36000013
         BC    7,RDSBINZ           MORE THAN ONE NO FIT ON SAME RECORD  36100013
         L     RD,PPIBDSVA+4                                            36200013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      36300013
RDSBINZ  L     RL,PPINET+4                                              36400013
         B     24(0,RL)            EXIT TO SORT ON RECORD NO FIT        36500013
         SPACE 2                                                        36600013
RDSSPEC  SR    RE,RE                                                    36700013
         A     RE,PPIBDSVA+8       CHECK BIN COUNT                      36800013
         BZ    RDSBINZ             BIN COUNT STILL ZERO                 36900013
         NI    NOFITSW,X'00'       ZERO NOFITSW-BIN COUNT NO LONGER 0   37000013
         L     RE,ADRHOLDA         RELOAD BUFFER ADDRESS                37100013
RDSPTB   L     RF,PPIBDSVA+4                                            37200013
         AH    RF,EXPLFOUR         ADD EXT SIZE & 4 TO AVAIL ADR        37300013
         ST    RE,ADRHOLDB         SAVE BUFFER ADDRESS                  37400013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     37500013
         B     RDSMOVE             CONTINUE PREP FOR MOVE               37600013
         SPACE 2                                                        37700013
RDSNORM  TM    PPISW1+7,X'20'                                           37800013
         BO    RDSISWON            GO TO USER MOD                       37900018
RDSGET   LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 38000019
         GET   (1),(0)                                           A26453 38100019
         SPACE 2                                                        38300013
         L     RJ,PPICOUNT                                              38400013
         LA    RJ,1(0,RJ)                                               38500013
         ST    RJ,PPICOUNT         ADD 1 TO RECORD COUNT                38600013
         ST    RB,WADDRESS         SET FOR RE-INIT. ENTRY               38700013
         ST    RB,ADRHOLD                                               38800013
RDSISWON LA    RB,ADRHOLD          SET UP PARAMETER FOR USER MOD        38900013
*                                    WILL BE L RB,ADRHOLD ON USER EOF   39000013
         L     RJ,WNMAX                                                 39100013
         SPACE                                                          39200013
*  USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.           39300013
*    ADDRESS OF INPUT RECORD PASSED IN RB                               39400013
         SPACE                                                          39500013
RDSUEXIT L     RP,PPIX15+4         OVERLAYED IF THIS EXIT NOT ACTIVATED 39600013
*                                  OR IF USER EOF REACHED.              39700013
         BALR  RO,RP               BRANCH TO USER                       39800013
         SPACE 2                                                        39900013
*  USER RETURNS VIA RO WITH PROPER DISPLACEMENT IN RP. HE ALSO PASSES,  40000013
*    IN REG RB, THE ADR OF THE RECORD TO BE INSERTED OR THE ADR OF THE  40100013
*    WORK AREA IF THE USER HAS ALTERED THE RECORD.                      40200013
         SPACE                                                          40300013
         B     *+4(15)             BRANCH TABLE FOR USER ENTRY          40400018
         B     RDSDONO             ALTER OR DO NOTHING                  40500013
         B     RDSLETE             DELETE A RECORD                      40600013
         B     RDSUEOF             USER END OF FILE                     40700013
         SPACE                                                          40800013
*  INSERT A RECORD                                                      40900013
         SPACE                                                          41000013
RDSMAXCK BCT   RJ,RDSINSRT         CHECK FOR NMAX AND DECREMENT         41100013
         B     RDSMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  41200013
         SPACE 2                                                        41300013
RDSINSRT OI    PPISW1+7,X'20'      SET INSERT SWITCH                    41400013
         L     RF,PPIINSCT                                              41500013
         LA    RF,1(0,RF)                                               41600013
         ST    RF,PPIINSCT         ADD 1 TO INSERT COUNT                41700013
RDSTSTBC LR    RE,RB               SET UP BUFF ADR FOR MOVE             41800013
         ST    RJ,WNMAX            SAVE NMAX REG                        41900013
         ST    RB,WADDRESS         SET FOR REINITIALIZATION ENTRY  1297 42000018
         SR    RF,RF                                                    42100013
         A     RF,PPIBDSVA+8       TEST BIN COUNT                       42200013
         BC    7,RDSRMAX           BRANCH UNLESS BIN COUNT EQUALS ZERO  42300013
         ST    RE,ADRHOLDA         SAVE RCD ADR UNTIL BIN IS AVAILABLE  42400013
         OI    NOFITSW,X'03'       SET NO FIT SWITCH = 11               42500013
         B     RDSBINZ             GO TO NO FIT EXIT                    42600013
         SPACE 2                                                        42700013
RDSDONO  BCT   RJ,RDSNOTM          CHECK FOR NMAX AND DECREMENT         42800013
         B     RDSMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  42900013
         SPACE 2                                                        43000013
RDSNOTM  NI    PPISW1+7,X'DF'     ZERO OUT INSERT SWITCH                43100013
         B     RDSTSTBC            GO CHECK BIN COUNT                   43200013
         SPACE 2                                                        43300013
RDSLETE  NI    PPISW1+7,X'DF'     ZERO OUT INSERT SWITCH                43400013
         L     RF,PPIDELCT                                              43500013
         LA    RF,1(0,RF)                                               43600013
         ST    RF,PPIDELCT         ADD 1 TO DELETE COUNT                43700013
         B     RDSGET              GO GET ANOTHER RECORD                43800013
         SPACE 2                                                        43900013
RDSMSG   STH   RP,WINSALT          SAVE INSERT-ALTER CONDITION          44000013
         L     RO,PPIRMA+4         MESSAGE MODULE ADR                   44100013
         LR    RE,RB               SAVE BUFF ADR                        44200013
         LM    RA,RB,MSGP1A04                                           44300013
         L     RP,PPIADSSC         LOAD PRINT RTN ADR                   44400013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      44500013
         SPACE 2                                                        44600013
*  USER EXIT E16-SORT CAPACITY, NMAX, HAS BEEN REACHED                  44700013
*    CALL MACRO INSTRUCTION EXPANSION                                   44800013
         SPACE                                                          44900013
         LR    RB,RE               RESTORE BUFF ADR                     45000013
         L     RP,PPIX16+4         NMAX EXIT ADR                        45100013
         BALR  RO,RP               BRANCH TO USER                       45200013
         SPACE 2                                                        45300013
*  USER RETURNS TO MODULE VIA RO WITH PROPER DISPLACEMENT IN RP         45400013
         SPACE                                                          45500013
         B     *+4(15)             BRANCH TABLE FOR USER ENTRY          45600018
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         45700013
         B     RDSIGNOR            IGNORE NMAX-CONTINUE SORT            45800013
         SPACE                                                          45900013
*  ABORT THE JOB                                                        46000013
         SPACE                                                          46100013
         L     RP,PPIADSSC                                              46200013
         BAL   RO,16(0,RP)         EXIT TO SORT SYSTEM CONTROL          46300013
         SPACE 2                                                        46400013
RDSSRTCR MVC   RDSNTER(4),K1       OVERLAY ENTRANCE                     46500013
         L     RL,PPINET+4                                              46600013
         B     8(0,RL)             BRANCH TO SORT TO EMPTY TREE         46700013
         SPACE 2                                                        46800013
RDSMPTYT L     RL,PPINET+4                                              46900013
         B     16(0,RL)            BRANCH TO SORT TO CONT. EMPTY TREE   47000013
         SPACE 2                                                        47100013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              47200013
         SPACE 1                                                        47300013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 47400013
         OI    PPISW1+7,X'80'      SET USER EOF FOR ALG.                47500013
         TM    PPISW1+3,X'01'     WAS SYSTEM INPUT EOF REACHED          47600013
         BO    RDSSRTCR           YES, DO NOT DECR PPICOUNT-FLUCH TREE  47700013
         L     RE,PPICOUNT         RCD IN INPUT BFR WILL NOT BE SORTED  47800013
         BCTR  RE,0                DECR PPICOUNT BY ONE                 47900013
         ST    RE,PPICOUNT         RESTORE PPICOUNT                     48000013
         OI    PPISW1+3,X'01'      SET EOF SW, SO ALG. WON'T RETURN     48100013
         B     RDSSRTCR            BR TO FLUSH TREE                     48200013
         SPACE 1                                                        48300013
*  IGNORE NMAX-OVERLAY NMAX TEST WITH A BRANCH                          48400013
         SPACE                                                          48500013
RDSIGNOR MVC   RDSMAXCK(4),K2      OVERLAY NMAX CK IN INSERT LEG        48600013
         MVC   RDSDONO(4),K3       OVERLAY NMAX CK IN ALTER LEG         48700013
         SR    RF,RF                                                    48800013
         AH    RF,WINSALT                                               48900013
         BZ    RDSNOTM             RESUME WITH INPUT RECORD             49000013
         B     RDSINSRT            RESUME WITH INSERT RECORD            49100013
         SPACE 2                                                        49200013
RDSOLAY  LA    RE,12(0)                                                 49300013
         STC   RE,RDSFIT+3         OVERLAY FILLING-FIT EXIT             49400013
         LA    RE,28(0)                                                 49500013
         STC   RE,RDSSPEC-1        OVERLAY FILLING-NO FIT EXIT          49600013
         B     RDSNTER             BRANCH TO NORMAL ENTRANCE            49700013
         SPACE 2                                                        49800013
RDSUEOF  OI    PPISW1+7,X'80'      INDICATE USER EOF                    49900013
         TM    PPISW1+3,X'01'      HAVE WE REACHED INPUT EOF            50000013
         BO    RDSSRTCR            YES - GO EMPTY TREE                  50100013
         MVC   RDSUEXIT(4),K4      OVERLAY AFTER USER EOF               50200013
         MVC   RDSMSG,K7                                                50300013
         L     RB,ADRHOLD          RESTORE ADDR OF RCD IN INPUT BLK     50400013
         MVI   RDSISWON,X'58'      CHANGE LA INSTRUCTION TO L           50500013
         B     RDSNOTM             BRANCH TO MOVE INPUT RECORD          50600013
         SPACE 2                                                        50700013
RDSEOF   TM    PPISW1+7,X'80'     HAS USER REACHED EOF                  50800013
         BO    RDSSRTCR            YES                                  50900018
         SPACE 1                                                        51000013
         TM    PPISW1+3,X'01'      TEST IF SIMULATED EOF                51100013
         BNO   RDSSRTCR              YES, BRANCH TO FLUSH TREE          51200013
           SPACE 1                                                      51300013
         CLI   REALEOF,X'01'       IS THIS SIM. EOF AFTER               51400013
         BE    RDSSRTCR              REAL EOF                           51500013
         SPACE 1                                                        51600013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       51700013
*                                    EOF'S ARE SIMULATED                51800013
         SPACE 1                                                        51900013
         MVC   RDSGET(4),K5        OVERLAY AFTER INPUT EOF              52000013
         SR    RB,RB                                                    52100013
         ST    RB,ADRHOLD          INPUT EOF INDICATION TO USER         52200013
         B     RDSISWON            GO TO SET UP FOR BRANCH TO USER      52300013
         SPACE 2                                                        52400013
*        TEST TO SEE WHETHER TO FLUSH TREE AND MERGE RECORDS ONTO       52500013
*        ONE REEL OF TAPE                                               52600013
         SPACE 1                                                        52700013
RDSRMAX  L     RC,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   52800013
         MVC   WRCDLEN(2),0(RE)    MAX NO OF BYTES ON ONE REEL TAPE     52900013
         AH    RC,WRCDLEN                                               53000013
         ST    RC,WRMAX            SAVE                                 53100013
         C     RC,PPIRMAX          HAVE RMAX BYTES BEEN EXCEEDED?       53200013
         BH    RDSRMXCT            BRANCH ON YES                        53300013
         B     RDSPTB              NO                                   53400018
         SPACE 2                                                        53500013
*        ENOUGH BYTES HAVE BEEN READ IN TO FILL ONE REEL OF TAPE        53600013
         SPACE 1                                                        53700013
RDSRMXCT SR    RE,RE                                                    53800013
         ST    RB,WADDRESS         SAVE ADDRESS OF THIS RECORD          53900013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   54000013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  54100013
         B     RDSSRTCR            BRANCH TO OVERLAY DEBLOCK            54200013
         SPACE 2                                                        54300013
         SPACE 2                                                        54400013
NOFITSW  DC    X'00'               NO FIT SWITCH                        54500018
REALEOF  DC    X'00'               REAL EOF SWITCH                      54600018
EXPLFOUR DC    H'0'                EXTRACT SIZE PLUS FOUR               54700018
WSAVE    DC    3F'0'               FOR MOVE RTN                         54800013
ADRHOLD  DC    F'0'                FOR BUFFER ADR                       54900013
ADRHOLDA DC    F'0'                RECORD ADR WHEN BIN COUNT=0          55000013
ADRHOLDB DC    F'0'                RECORD ADR FOR MOVE RTN AND SORT RTN 55100013
WADDRESS DS    F                   ADDRESS OF NEXT RECORD TO BE MOVED   55200013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     55300013
WNMAX    DC    F'0'                NUMBER OF RCDS TO GO & 1             55400013
WINSALT  DC    H'0'                INSERT-ALTER SWITCH                  55500013
WRCDLEN  DS    H                  HALF-WORD BOUNDARY FOR RECORD LENGTH  55600013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADDRESS     55700013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 55750019
         SPACE 2                                                        55800013
K1       B     RDSMPTYT            OVERLAY TO EMPTY TREE                55900013
K2       B     RDSINSRT            OVERLAY IN INSERT LEG                56000013
K3       B     RDSNOTM             OVERLAY IN ALTER LEG                 56100013
K4       B     RDSDONO             OVERLAY AFTER USER EOF               56200013
K5       B     RDSISWON           OVLY AFTER INPUT E O F                56300013
K6       CLI   NOFITSW,X'01'                                            56400013
K7       NOP   0                                                        56500013
KFOUR    DC    F'4'                CONSTANT FOUR                        56600018
         SMPPI                                                          56700013
* MODULE NAME ***IERRMA***                                              56800013
*                                                                       56900013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        57000013
* PHASE 1 RUNNING PROGRAM.                                              57100013
         SPACE 1                                                        57200013
IERRMA   DSECT                                                          57300013
*                                                                       57400013
       COPY  RMAMAIN                                                    57500013
*                                                                       57600013
         END                                                            57700013
