         TITLE 'IERADT - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERADT ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION:                                                       01400013
*   OSCL./2314 SORT PH DEBLOCK ASSIGN. FOR V.L. RCDS W/O USER EXITS.    01600013
*   THE FUNCTION OF THIS MODULE IS TO CALCULATE THE NUMBER OF BINS IN   01800013
*   UP TO 5 NON-CONTIGUOUS RECORD STORAGE AREAS AND CHAIN ALL THESE     02000013
*   BINS TOGETHER. IT PUTS THE ADDRESS OF THE FIRST BIN IN THE FIRST    02200013
*   RSA IN AVAIL(PPIBDSVA+4). INPUT BUFFERS ARE SET UP VIA THE BUILD    02400013
*   MACRO. EXTRACT SIZE+4 IS CALCULATED AND STORED IN THE RUNNING       02600013
*   PROGRAM,IERRDG.                                                     02800013
         SPACE 1                                                        03000013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      03200013
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.              03400013
         SPACE 2                                                        03600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               03800013
         SPACE 1                                                        04000013
*   NONE                                                                04200013
         SPACE 2                                                        04400013
*LIST OF MACROS USED BY MODULE:                                         04600013
         SPACE 1                                                        04800013
*   BUILDS                                                              05000013
*   BUILD                                                               05200013
         SPACE 2                                                        05400013
*ENTRY POINTS:                                                          05600013
         SPACE 1                                                        05800013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    06000013
*                                    CALLING SEQUENCE-                  06200013
*                                      LOAD EP=IERADG,DCB=SORTLIB       06400013
*                                      LR   RP,RA                       06600013
*                                      BALR RO,RP                       06800013
         SPACE 2                                                        07000013
*INPUT: - PPI FIELDS REFERENCED                                         07200013
         SPACE 1                                                        07400013
*   PPIBINSZ   PPILAB08                                                 07600013
*   PPILAB03   PPILEXFF                                                 07800013
*   PPILAB02                                                            08000013
         SPACE 1                                                        08200013
*   ADDRESSES FOR BUFFERS AND TABLES,FOR THE RSA CHAINING ROUTINE, AND  08400013
*   FOR THE BUILD MACRO                                                 08600013
         SPACE 2                                                        08800013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            09000013
         SPACE 1                                                        09200013
*   PPIBDSVA                                                            09400013
*   PPISW1                                                              09600013
         SPACE 1                                                        09800013
*   INITIALIZE START OF RSA(AVAIL) AND TOTAL NUMBER OF BINS IN ALL THE  10000013
*   RSA'S                                                               10200013
         SPACE 2                                                        10400013
*EXTERNAL ROUTINES:                                                     10600013
         SPACE 1                                                        10800013
*   NONE                                                                11000013
         SPACE 2                                                        11200013
*EXTERNAL PARAMETERS:                                                   11400013
         SPACE 1                                                        11600013
*   SEE REGISTERS                                                       11800013
         SPACE 2                                                        12000013
*EXITS-NORMAL:                                                          12200013
         SPACE 1                                                        12400013
*   TO IERRC9                      EXIT TO:IERRC9                       12600013
*                                    CALLING SEQUENCE-                  12800013
*                                      BR   RO         RETURN           13000013
         SPACE 2                                                        13200013
*EXITS-ERROR:                                                           13400013
         SPACE 1                                                        13600013
*   NONE                                                                13800013
         SPACE 2                                                        14000013
*TABLES/WORK AREAS:                                                     14200013
         SPACE 1                                                        14400013
*   WCOMBINE-WORK AREA                                                  14600013
         SPACE 2                                                        14800013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   15000013
         SPACE 2                                                        15200013
*NOTES:                                                                 15400013
*   THIS MODULE IS AN ASSIGNMENT ROUTINE FOR THE OSCL OR 2314 SORT PH.  15600013
*   DEBLOCK ROUTINE FOR VARIABLE LENGTH RECORDS WITHOUT USER EXITS.     15800013
         EJECT                                                          16000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            16200013
         SPACE 1                                                        16400013
RA       EQU   0                   CONTENTS IN-N/A                      16600013
*                                  USE-NO. OF BUFFERS AND BUFFER SIZE   16800013
*                                    FOR BUILD MACRO                    17000013
*                                  CONTENTS OUT-N/A                     17200013
RB       EQU   1                   CONTENTS IN-N/A                      17400013
*                                  USE-ADDR OF INPUT BUFFER POOL FOR    17600013
*                                    BUILD MACRO.                       17800013
*                                  CONTENTS OUT-N/A                     18000013
RC       EQU   2                   CONTENTS IN-N/A                      18200013
*                                  USE-NOT USED                         18400013
*                                  CONTENTS OUT-N/A                     18600013
RD       EQU   3                   CONTENTS IN-N/A                      18800013
*                                  USE-NO. OF RSA AREAS-RSA TABLE CALC  19000013
*                                  CONTENTS OUT-N/A                     19200013
RE       EQU   4                   CONTENTS IN-N/A                      19400013
*                                  USE-WORK REGISTER                    19600013
*                                  CONTENTS OUT-N/A                     19800013
RF       EQU   5                   CONTENTS IN-N/A                      20000013
*                                  USE-NO. OF BYTES COUNTER IN 1 RSA    20200013
*                                  CONTENTS OUT-N/A                     20400013
RG       EQU   6                   CONTENTS IN-N/A                      20600013
*                                  USE-CURRENT BIN ADDRESS IN A RSA-    20800013
*                                    USED IN RSA TABLE CALC.            21000013
*                                  CONTENTS OUT-N/A                     21200013
RH       EQU   7                   CONTENTS IN- N/A                     21400013
*                                  USE- GENERAL WORK REGISTER           21600013
*                                  CONTENTS OUT-N/A                     21800013
RI       EQU   8                   CONTENTS IN- N/A                     22000013
*                                  USE- NOT USED                        22200013
*                                  CONTENTS OUT- N/A                    22400013
RJ       EQU   9                   CONTENTS IN- N/A                     22600013
*                                  USE- NOT USED                        22800013
*                                  CONTENTS OUT- N/A                    23000013
RK       EQU   10                  CONTENTS IN- N/A                     23200013
*                                  USE-IERRDG BASE REGISTER             23400013
*                                  CONTENTS OUT-N/A                     23600013
RL       EQU   11                  CONTENTS IN-N/A                      23800013
*                                  USE-MODULE BASE REGISTER             24000013
*                                  CONTENTS OUT-N/A                     24200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   24400013
*                                  USE-NOT USED                         24600013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   24800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              25000013
*                                  USE-PPI REFERENCES,REG SAVE AREA     25200013
*                                  CONTENTS OUT-ADDR OF PPI             25400013
RO       EQU   14                  CONTENTS IN-IERRC9 RETURN ADDR       25600013
*                                  USE-NOT USED                         25800013
*                                  CONTENTS OUT-IERRC9 RETURN ADDR      26000013
RP       EQU   15                  CONTENTS IN-IERADG ENTRY PT          26200013
*                                  USE-ESTABLISH THIS MOD BASE REGISTER 26400013
*                                  CONTENTS OUT-N/A                     26600013
         SPACE 2                                                        26800013
*START OF MODULE CODE PROPER:                                           27000013
         SPACE 2                                                        27200013
IERADT   CSECT                                                          27400013
         USING *,RL                THIS MODULE BASE REGISTER            27600013
         USING IERRDT,RK           IERRDT DSECT BASE REGISTER           27800013
         USING IERRCA,RN           PPI ADDR                             28000013
IERMDA   LR    RL,RP               ESTABLISH THIS MODULE BASE REGISTER  28200013
         L     RK,PPIDEB+4         ADDR OF IERRDG CSECT                 28400013
         SPACE 2                                                        28600013
*CHAIN ALL BINS TOGETHER BY PUTTING IN EACH BIN THE ADDR OF THE NEXT    28800013
*   AVAILABLE BIN. SAVE THE ADDRESS OF THE 1ST AVAILABLE BIN IN         29000013
*   PPIBDSVA+4,AND THE TOTAL NO. OF AVAILABLE BINS IN PPIBDSVA+8.       29200013
         SPACE 1                                                        29400013
         SR    RD,RD                                                    29600013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     29800013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              30000013
         L     RG,0(0,RH)          ADDR OF THIS RSA AREA BIN            30200013
         ST    RG,PPIBDSVA+4       SAVE THIS ADDR IN AVAIL(FOR IERRDG)  30400013
ADELOOPO L     RF,4(0,RH)          NO. OF BYTES IN THIS RSA AREA        30600013
         LA    RI,ADELOOPI         LOAD RETURN REG FOR THIS LOOP CALC   30800013
         SR    RE,RE                                                    31000013
         D     RE,PPIBINSZ         RF=NO. OF BINS IN THIS RSA AREA      31200013
         L     RE,PPIBDSVA+8       TOTAL NO.OF BINS IN ALL RSA'S SO FAR 31400013
         AR    RE,RF               UPDATE BIN COUNT                     31600013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               31800013
ADELOOPI BCT   RF,ADECHAIN         DECR NO. OF BINS CTR FOR THIS RSA.   32000013
*                                    BR IF MORE BINS IN THIS RSA.       32200013
         BCT   RD,ADNXTRSA         DECR NO. OF RSA'S CTR. BR IF MORE    32400013
*                                   RSA'S. THE LAST BIN IN THE LAST     32600013
*                                   RSA HAS NO CHAIN ADDRESS.           32800013
         MVC   WCOMBINE+1(1),PPILAB03                                   33000013
         MVC   WCOMBINE+2(2),PPILAB03+2                                 33200013
         L     RA,WCOMBINE         POSITION NO. AND SIZE OF BUFFERS     33400013
         L     RB,PPILAB02        SET REG 1 = ADDRESS OF BUFFER LIST    33600013
         BUILDS (1),(0)                                                 33800013
         SPACE 2                                                        34000013
*   SET USER EOF SWITCH IN PPI, SINCE THERE IS NO USER EXIT             34200013
         SPACE 1                                                        34400013
         OI    PPISW1+7,X'80'                                           34600013
         LH    RE,PPILEXFF         GET EXTRACT SIZE                     34800013
         A     RE,KFOUR                                                 35000013
         STH   RE,EXPLFOUR         STORE EXTRACT SIZE + 4               35200013
ADTEXIT  L     RE,PPISTDCB         DCB ADDRESS                   A26453 35220019
         L     RE,0(RE)                                          A26453 35240019
         ST    RE,KAWORK+4         STORE IN R.P.WORK AREA        A26453 35260019
         TM    PPIMODEX+2,X'02'    VRE IN?                       A26453 35280019
         BZ    ADTRETUR            NO...                         A26453 35300019
         L     RE,PPIGETMN         ADDR OF GETMAIN TABLE OF ADDR A26453 35320019
         L     RE,12(RE)           FETCH ADDR OF VRE WORK AREA   A26453 35340019
         ST    RE,KAWORK           STORE IN R.P. WORK AREA       A26453 35370019
         SPACE 1                                                        35400013
*IF 2314, OVERLAY RMAX CHECK IN R.P.  RETURN TO IERRC9.                 35600013
ADTRETUR TM    PPISW1+6,X'02'      CHECK FOR 2314                A26453 35800019
         BCR   8,RO                  NO, RETURN TO IERRC9               36000013
         SPACE 1                                                        36200013
         MVC   RDTRMAX(4),KADTKON  OVERLAY RMAX CHECK                   36400013
         BR    RO                  RETURN TO IERRC9                     36600013
         SPACE 2                                                        36800013
ADNXTRSA LA    RI,ADEREAL          RESET RETURN REG FOR THIS LOOP       37000013
         SPACE 2                                                        37200013
*INSERT CHAIN ADDR IN EACH BIN OF EACH RSA EXCEPT THE LAST BIN OF THE   37400013
*   LAST RSA.                                                           37600013
         SPACE 1                                                        37800013
ADECHAIN A     RG,PPIBINSZ         ADDR OF THIS BIN + BIN SIZE          38000013
         LR    RE,RG               SAVE ADDR OF THE NEXT BIN            38200013
         S     RE,KFOUR            PTS TO AREA IN PREVIOUS BIN TO PUT   38400013
*                                    THE CHAIN ADDR OF NEXT BIN(IN RG)  38600013
         ST    RG,0(0,RE)          PREVIOUS BIN NOW CHAINED TO NEXT BIN 38800013
         BR    RI                  BR TO ADELOOPI ON ALL BINS EXCEPT    39000013
*                                    THE LAST BIN IN EACH RSA OTHERWISE 39200013
*                                    BR TO ADEREAL ON THIS LAST BIN     39400013
         SPACE 2                                                        39600013
*OVERLAY LAST BIN CHAIN ADDR OF THIS RSA WITH PROPER ADDRESS.(1ST BIN   39800013
*   ADDR OF NEXT RSA)                                                   40000013
         SPACE 1                                                        40200013
ADEREAL  LA    RH,8(0,RH)          UPDATE PPI RSA TABLE PTR TO NEXT     40400013
*                                    RSA ENTRY                          40600013
         L     RG,0(0,RH)          ADDR OF 1ST BIN IN NEXT RSA          40800013
         ST    RG,0(0,RE)          STORE AS CHAIN ADDR IN LAST BIN OF   41000013
*                                    PREVIOUS RSA.                      41200013
         B     ADELOOPO            BR TO CHAIN BINS OF THIS RSA         41400013
         SPACE 2                                                        41600013
*LIST OF WORK AREAS/TABLES:                                             41800013
         SPACE 1                                                        42000013
WCOMBINE DC    F'0'                WORK AREA                            42200013
         SPACE 2                                                        42400013
*LIST OF CONSTANTS:                                                     42600013
         SPACE 1                                                        42800013
         DROP  RL                                                       43000013
         DROP  RK                                                       43200013
         USING IERRDT,RL                                                43400013
KADTKON  B     RDTMOVE             BYPASS RMAX CHECK                    43600013
         EJECT                                                          43800013
IERRDT   DSECT                                                          44000013
         USING *,RL                                                     44200013
         USING IERRCA,RN                                                44400013
IERDD1   B     RDTOLAY             GO TO OVERLAY EXITS                  44600013
         B     RDTEOF              GO TO EOF ROUTINE                    44800013
         B     RDTBEGIN            NORMAL ENTRY TO DEBLOCK ANOTHER RCD  45000013
         SPACE 2                                                        45200013
*        ENTRY TO REINITIALIZE TO BEGIN REFILLING THE TREE              45400013
         SPACE 1                                                        45600013
         LA    RE,4                CHANGE ENTRIES TO NETWORK            45800013
         STC   RE,RDTFIT+3                                              46000013
         LA    RE,24                                                    46200013
         STC   RE,RDTNORM-1                                             46400013
         MVC   RDTBEGIN(8),KREINITI                                     46600013
         SPACE 2                                                        46800013
*        CHAIN BINS TOGETHER BY PUTTING IN EACH BIN THE ADDRESS OF THE  47000013
*        NEXT AVAILABLE BIN. SAVE THE ADDRESS OF THE FIRST AVAILABLE    47200013
*        BIN IN PPIBDSVA+4 AND THE TOTAL NUMBER OF AVAILABLE BINS IN    47400013
*        PPIBDSVA+8.                                                    47600013
         SPACE 1                                                        47800013
         SR    RD,RD                                                    48000013
         ST    RD,PPIBDSVA+8      REINITIALIZE TOTAL OF AVAILABE BINE   48200013
         IC    RD,PPILAB08         NUMBER OF RSA AREAS                  48400013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              48600013
         L     RG,0(RH)            ADDRESS OF THIS RSA AREA BIN         48800013
         ST    RG,PPIBDSVA+4       SAVE ADDRESS OF FIRST RSA BIN        49000013
         SPACE 1                                                        49200013
RDAAAA   L     RF,4(RH)            NO. BYTES IN THIS RSA AREA           49400013
         LA    RI,RDBBBB           LOAD RETURN REG FOR THIS LOOP CALC   49600013
         SR    RE,RE                                                    49800013
         D     RE,PPIBINSZ         RF = NO. BINS IN THIS RSA AREA       50000013
         L     RE,PPIBDSVA+8       TOTAL NO. BINS IN RSA SO FAR         50200013
         AR    RE,RF               UPDATE BIN COUNT                     50400013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               50600013
         SPACE 1                                                        50800013
RDBBBB   BCT   RF,RDDDDD           DECR NO. BINS CTR FOR THIS RSA       51000013
*                                    BR IF MORE BINS IN THIS RSA        51200013
         BCT   RD,RDCCCC           DECR NO. OF RSA'S CTR. BR IF MORE    51400013
*                                    RSA'S. THE LAST BIN IN THE LAST    51600013
*                                    RSA HAS NO CHAIN ADDRESS.          51800013
         B     RDFFFF              BR TO LOAD MOVE PARAMETERS           52000013
         SPACE 1                                                        52200013
RDCCCC   LA    RI,RDEEEE           RESET RETURN REG FOR THIS LOOP       52400013
RDDDDD   A     RG,PPIBINSZ         ADDRESS OF THIS BIN + BIN SIZE       52600013
         LR    RE,RG               SAVE ADDRESS OF NEXT BIN             52800013
         S     RE,KFOUR            PTS TO AREA IN PREVIOS BIN TO PUT    53000013
*                                    THE CHAIN AD OF NEXT BIN (IN RG)   53200013
         ST    RG,0(RE)            PREVIOUS BIN NOW CHAINED TO NEXT BIN 53400013
         BR    RI                  BR TO RDBBBB ON ALL BINS EXCEPT THE  53600013
*                                    LAST BIN IN EACH RSA. OTHERWISE    53800013
*                                    BR TO RDEEEE                       54000013
         SPACE 1                                                        54200013
RDEEEE   LA    RH,8(RH)            UPDATE PPI RSA TABLE PTR TO NEXT     54400013
*                                    RSA ENTRY                          54600013
         L     RG,0(RH)            ADDRESS OF FIRST BIN IN NEXT RSA     54800013
         ST    RG,0(RE)            STORE AS CHAIN ADDRESS IN LAST BIN   55000013
*                                    OF PREVIOUS RSA.                   55200013
         B     RDAAAA                                                   55400013
         SPACE 2                                                        55600013
*        LOAD PARAMS TO MOVE SAVED RECORD INTO RSA                      55800013
         SPACE 1                                                        56000013
RDFFFF   L     RE,ADRHOLD          GET ADDRESS OF SAVED RECORD          56200013
         B     RDTRMAX             B TO RESTART RMAX COUNT              56400013
         SPACE 2                                                        56600013
*        NORMAL ENTRY TO DEBLOCK ANOTHER RECORD                         56800013
         SPACE 1                                                        57000013
RDTBEGIN CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  57200013
         BL    RDTNORM             NO FIT SWITCH OFF                    57400013
         BH    RDTSPEC             NO. OF BINS=0 DURING FILL            57600013
         SR    RE,RE                                                    57800013
         A     RE,PPIBDSVA+8                                            58000013
         BZ    RDTNOFIT                                                 58200013
         L     RA,WSAVE                                                 58400013
         L     RE,WSAVE+4                                               58600013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 58800013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                59000013
         ST    RD,0(RC)            INSERT CHAIN ADDRESS                 59200013
         L     RB,KEIGHT           INDICATE DEBLOCK WITH NOFIT PREV     59400013
RDTBINS  L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          59600013
         L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             59800013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               60000013
         SPACE 2                                                        60200013
         B     RDTNOTF             RECORD DIDN'T FIT                    60400013
         SPACE                                                          60600013
*  RECORD FIT ROUTINE                                                   60800013
         SPACE                                                          61000013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  61200013
         BC    7,RDTUSUAL          LAST MOVE WAS NOT A NO FIT           61400013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       61600013
         SR    RC,RC                                                    61800013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     62000013
         B     RDTUSUAL+4          RD ALREADY LOADED                    62200013
RDTUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RECORD JUST MOVED       62400013
         AH    RD,EXPLFOUR         ADD EXT SIZE + 4                     62600013
         L     RC,ADRHOLD          LOAD BUFFER ADDRESS                  62800013
         L     RE,PPIBDSVA+8                                            63000013
         SR    RE,RB                                                    63200013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     63400013
         L     RE,0(RF)                                                 63600013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         63800013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               64000013
         L     RL,PPINET+4                                              64200013
RDTFIT   B     4(RL)               EXIT TO SORT ON RECORD FIT CONDITION 64400013
         SPACE 2                                                        64600013
*  RECORD NOFIT ROUTINE                                                 64800013
         SPACE                                                          65000013
RDTNOTF  ST    RA,WSAVE                                                 65200013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              65400013
         SR    RD,RD                                                    65600013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         65800013
         OI    NOFITSW,X'01'                                            66000013
         A     RD,WSAVAIL                                               66200013
         BC    7,RDTNOFIT         SECOND NOFIT ON SAME RECORD           66400013
         L     RD,PPIBDSVA+4                                            66600013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      66800013
RDTNOFIT L     RL,PPINET+4                                              67000013
         B     24(RL)              EXIT TO SORT ON RECORD NO FIT        67200013
         SPACE 2                                                        67400013
RDTNORM  LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 67600019
         GET   (1),(0)                                           A26453 67900019
         SPACE 2                                                        68200013
RDTGOT   ST    RB,ADRHOLD          SAVE ADDRESS OF RECORD               68400013
         L     RE,PPICOUNT                                              68600013
         LA    RE,1(RE)                                                 68800013
         ST    RE,PPICOUNT         ADD ONE TO RECORD COUNT              69000013
         LR    RE,RB               SET UP BUFFER ADDRESS FOR MOVE RTN   69200013
         SR    RD,RD                                                    69400013
         A     RD,PPIBDSVA+8                                            69600013
         BC    7,RDTRMAX           BRANCH UNLESS BIN COUNT EQUALS ZERO  69800013
         OI    NOFITSW,X'03'                                            70000013
         B     RDTNOFIT            SPECIAL NO FIT CONDITION             70200013
         SPACE 2                                                        70400013
*  OVERLAY EXITS TO REPLACEMENT - CHANGE FROM FILLING TO NORMAL         70600013
         SPACE                                                          70800013
RDTOLAY  LA    RE,12(0)                                                 71000013
         STC   RE,RDTFIT+3         OVERLAY EXIT TO SORT-RECORD FIT      71200013
         LA    RE,28(0)                                                 71400013
         STC   RE,RDTNORM-1        OVERLAY EXIT TO SORT-RECORD NO FIT   71600013
         B     RDTBEGIN            BRANCH TO NORMAL ENTRY               71800013
         SPACE 2                                                        72000013
*  EOF - SET UP UNCONDITIONAL RETURN TO REPLACEMENT FOR FUTURE USE      72200013
         SPACE                                                          72400013
RDTEOF   MVC   RDTBEGIN(4),RDTFIT-4                                     72600013
         MVC   RDTBEGIN+4(4),KBRANCH    OVERLAY ENTRY WITH UNCOND EXIT  72800013
         L     RL,PPINET+4                                              73000013
         B     8(RL)               ONE TIME EXIT AT EOF                 73200013
         SPACE 2                                                        73400013
RDTSPEC  SR    RE,RE                                                    73600013
         A     RE,PPIBDSVA+8                                            73800013
         BZ    RDTNOFIT                                                 74000013
         NI    NOFITSW,X'00'       ZERO NOFITSW - SPEC CONDITION        74200013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE             74400013
         L     RE,ADRHOLD          LOAD BUFFER ADR                      74600013
RDTMOVE  L     RF,PPIBDSVA+4                                            74800013
         AH    RF,EXPLFOUR         ADD EXT SIZE + 4 TO AVAIL ADR        75000013
         SR    RB,RB               INICATE DEBLOCK TO MOVE ROUTINE      75200013
         B     RDTBINS+4           CONTINUE PREP FOR MOVE               75400013
         SPACE 2                                                        75600013
*        TEST TO SEE WHETHER TO FLUSH TREE AND MERGE RECORDS ONTO       75800013
*        ONE REEL OF TAPE                                               76000013
         SPACE 1                                                        76200013
RDTRMAX  L     RC,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   76400013
         MVC   WRCDLEN(2),0(RE)    MAX NO OF BYTES ON ONE REEL TAPE     76600013
         AH    RC,WRCDLEN                                               76800013
         ST    RC,WRMAX            SAVE                                 77000013
         C     RC,PPIRMAX          HAVE RMAX BYTES BEEN EXCEEDED?       77200013
         BH    RDTRMXCT            BRANCH ON YES                        77400013
         B     RDTMOVE                                                  77600013
         SPACE 2                                                        77800013
*        ENOUGH BYTES HAVE BEEN READ IN TO FILL ONE REEL OF TAPE        78000013
         SPACE 1                                                        78200013
RDTRMXCT SR    RE,RE                                                    78400013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   78600013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  78800013
         B     RDTEOF              BRANCH TO OVERLAY DEBLOCK            79000013
         SPACE 2                                                        79200013
         SPACE 2                                                        79400013
KBRANCH  B     16(RL)                                                   79600013
KREINITI CLI   NOFITSW,X'01'                                            79800013
         BL    RDTNORM                                                  80000013
NOFITSW  DC    X'00'                                                    80200013
ADRHOLD  DC    F'0'                                                     80400013
KEIGHT   DC    F'8'                                                     80600013
KFOUR    DC    F'4'                                                     80800013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     81000013
WSAVE    DC    3F'0'                                                    81200013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADR         81400013
EXPLFOUR DC    H'0'                EXTRACT SIZE + 4                     81600013
WRCDLEN  DS    H                  HALF-WORD BOUNDARY FOR RECORD LENGTH  81800013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 81900019
         SMPPI                                                          82000013
         END                                                            82200013
