         TITLE '      IERADX - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
*MODULE NAME *** IERADX ***                                             00600013
         SPACE 2                                                        00900013
*STATUS:CHANGE LEVEL 000                                                01200013
         SPACE 2                                                        01500013
*MODULE FUNCTION/OPERATION: PHASE 3 ASSIGNMENT MODULE - F.L. TAPE SORT  01800013
*   THE FUNCTION OF THIS MODULE IS TO RESERVE AREA IN GENERATED CORE    02100013
*   FOR THE TABLE OF INPUT BUFFER ADDRESSES AND FILL IN EACH ENTRY IN   02400013
*   THE TABLE WITH THE STARTING ADDRESS(LOWER CORE) OF EACH INPUT BFR.  02700013
*   SINCE THE READ ASSIGNMENT MODULE HAS PRIMED THE INPUT BUFFERS AND   03000013
*   PUT THE STARTG ADDRESSES+4(FOR THE NETWORK) IN PPIPDWA TABLE THIS   03300013
*   MODULE MOVES THE ADDRESSES TO THE APPROPRIATE ENTRY IN THE TABLE OF 03600013
*   INPUT BUFFER ADDRESSES (AFTER ADJUSTING THE ADDRESSES TO POINT TO   03900013
*   THE START OF EACH BUFFER). THESE ADDRESSES WILL BE USED BY IERRDX   04200013
*   TO PASS AS A PARAMETER TO THE READ FORWARD MODULE. THE ADDRESSES IN 04500013
*   PPIPDWA WILL NOW HAVE TO BE CHANGED TO POINT TO THE LAST RECORD     04800013
*   (HI CORE) IN EACH BUFFER. THIS IS SO THE MERGE NETWORK WILL BE      05100013
*   ABLE TO COMPARE EACH BUFFER FROM HI TO LOW. IERRDX WILL CONTINUE    05400013
*   DEBLOCKING EACH BUFFER FROM HI TO LOW CORE.                         05700013
         SPACE 2                                                        06000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               06300013
*                                                                       06600013
*     N/A                                                               06900013
*                                                                       07200013
*LIST OF MACROS USED BY THE MODULE:                                     07500013
         SPACE 1                                                        07800013
*   SMPPI                                                               08100013
         SPACE 2                                                        08400013
*ENTRY POINTS:                                                          08700013
         SPACE 1                                                        09000013
*   FROM IERRC9                    ENTRY FROM: IERRC9                   09300013
*                                    CALLING SEQUENCE-                  09600013
*                                      LOAD EP=IERADX,DCB=SORTLIB       09900013
*                                      LR   RP,RA                       10200013
*                                      BALR RO,RP                       10500013
         SPACE 2                                                        10800013
*INPUT: PPI FIELDS REFERENCED                                           11100013
         SPACE 1                                                        11400013
*   PPIDEB     PPIRCDL2                                                 11700013
*   PPISPGN1   PPIPDWA                                                  12000013
*   PPISBLCT                                                            12300013
         SPACE 1                                                        12600013
*   VARIOUS ADDRESSES OF TABLES,AND RECORD LENGTHS FOR CALCULATIONS     12900013
         SPACE 2                                                        13200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED                              13500013
         SPACE 1                                                        13800013
*   PPISPGN1                                                            14100013
*   PPIBDSVA                                                            14400013
         SPACE 1                                                        14700013
*   UPDATE POINTER IN GEN CORE AND INITIALIZE BUFFER ADDR TABLE PTR.    15000013
         SPACE 2                                                        15300013
*EXTERNAL ROUTINES:                                                     15600013
         SPACE 1                                                        15900013
*   NONE                                                                16200013
         SPACE 2                                                        16500013
*EXTERNAL PARAMETERS:                                                   16800013
         SPACE 1                                                        17100013
*   SEE REGISTERS                                                       17400013
         SPACE 2                                                        17700013
*EXITS: NORMAL                                                          18000013
         SPACE 1                                                        18300013
*   TO ASSIGNMENT LOADER           EXIT TO: IERRC9                      18600013
*                                    CALLING SEQUENCE-                  18900013
*                                      BR   RO         RETURN           19200013
         SPACE 2                                                        19500013
*EXITS: ERROR                                                           19800013
         SPACE 1                                                        20100013
*   NONE                                                                20400013
         SPACE 2                                                        20700013
*TABLES/WORK AREAS:                                                     21000013
         SPACE 1                                                        21300013
*   NONE                                                                21600013
         SPACE 2                                                        21900013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  22200013
         SPACE 2                                                        22500013
*NOTES: THIS MODULE IS EXECUTED FOR FIXED LENGTH RECORDS AND TO SAVE A  22800013
*   COPY PASS. IT IS EXECUTED ALONG WITH THE READ FORWARD TAPE MODULE.  23100013
         EJECT                                                          23400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            23700013
         SPACE 1                                                        24000013
RA       EQU   0                   CONTENTS IN- N/A                     24300013
*                                  USE- NOT USED                        24600013
*                                  CONTENTS OUT- N/A                    24900013
RB       EQU   1                   CONTENTS IN- N/A                     25200013
*                                  USE- NOT USED                        25500013
*                                  CONTENTS OUT- N/A                    25800013
RC       EQU   2                   CONTENTS IN- N/A                     26100013
*                                  USE- NOT USED                        26400013
*                                  CONTENTS OUT- N/A                    26700013
RD       EQU   3                   CONTENTS IN- N/A                     27000013
*                                  USE- NOT USED                        27300013
*                                  CONTENTS OUT- N/A                    27600013
RE       EQU   4                   CONTENTS IN- N/A                     27900013
*                                  USE-GENERAL WORK REGISTER            28200013
*                                     -STRTG ADDR(TABLE INPUT BFR ADDR) 28500013
*                                  CONTENTS OUT- N/A                    28800013
RF       EQU   5                   CONTENTS IN- N/A                     29100013
*                                  USE-GENERAL WORK REGISTER            29400013
*                                     -ADDR OF PRIME AREA TABLE         29700013
*                                  CONTENTS OUT- N/A                    30000013
RG       EQU   6                   CONTENTS IN- N/A                     30300013
*                                  USE- ADDR OF TABLE OF INPUT BFR      30600013
*                                    BLOCK CTRS.                        30900013
*                                  CONTENTS OUT- N/A                    31200013
RH       EQU   7                   CONTENTS IN- N/A                     31500013
*                                  USE- GENERAL WORK REGISTER           31800013
*                                  CONTENTS OUT- N/A                    32100013
RI       EQU   8                   CONTENTS IN- N/A                     32400013
*                                  USE- INCR OF AN INPUT FILE           32700013
*                                  CONTENTS OUT- N/A                    33000013
RJ       EQU   9                   CONTENTS IN- N/A                     33300013
*                                  USE- GENERAL WORK REGISTER           33600013
*                                  CONTENTS OUT- N/A                    33900013
RK       EQU   10                  CONTENTS IN- N/A                     34200013
*                                  USE- IERRDX DSECT BASE REGISTER      34500013
*                                  CONTENTS OUT- N/A                    34800013
RL       EQU   11                  CONTENTS IN- N/A                     35100013
*                                  USE- THIS MODULE BASE REGISTER       35400013
*                                  CONTENTS OUT- N/A                    35700013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   36000013
*                                  USE- NOT USED                        36300013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  36600013
RN       EQU   13                  CONTENTS IN- PPI ADDR                36900013
*                                  USE- PPI REFERENCES, REG SAVE AREA   37200013
*                                  CONTENTS OUT- PPI ADDR               37500013
RO       EQU   14                  CONTENTS IN- RETURN ADDR OF IERRC9   37800013
*                                  USE- NOT USED                        38100013
*                                  CONTENTS OUT- RETURN ADDR OF IERRC9  38400013
RP       EQU   15                  CONTENTS IN- THIS MODULE ENTRY PT    38700013
*                                  USE- ESTABLISH THIS MODULE BASE REG  39000013
*                                  CONTENTS OUT- N/A                    39300013
         SPACE 2                                                        39600013
*START OF MODULE CODE PROPER:                                           39900013
         SPACE 2                                                        40200013
IERADX   CSECT                                                          40500013
         USING *,RL                                                     40800013
         USING IERRCA,RN           ADDR OF PPI DSECT                    41100013
         USING IERRDX,RK           ADDR OF IERRDX DSECT                 41400013
         LR    RL,RP               ESTABLISH THIS MODULE BASE REG       41700013
         L     RK,PPIDEB+4         ESTABLISH IERRDX DSECT BASE REG      42000013
         SPACE 1                                                        42300013
*INSURE STARTING ADDR OF AVAILABLE CORE ON FULL WORD BOUNDARY           42600013
         SPACE 1                                                        42900013
         NI    PPISPGN1+3,X'FC'    ROUND TO NEXT LOWEST FULL WORD       43200013
         L     RE,PPISPGN1                                              43500013
         SPACE 1                                                        43800013
*CALCULATE SIZE OF INPUT BUFFER ADDR TABLE AND RESERVE AREA IN GEN CORE 44100013
         SPACE 1                                                        44400013
ADHDA020 SR    RF,RF                                                    44700013
         IC    RF,PPIBDSVA         TOTAL NO. OF WORK UNITS              45000013
         SLL   RF,2                *4                                   45300013
         LA    RF,4(0,RF)          ALIGN TABLE FOR PROPER INCR          45600013
         SR    RE,RF               RESERVE THE SPACE IN GEN CORE        45900013
         ST    RE,WDBLSV           SAVE START OF TABLE IN IERRDX        46200013
         ST    RE,PPISPGN1         RESTORE PTR IN PPI                   46500013
         MVC   PPIBDSVA+1(3),PPISPGN1+1 SAVE ADDR IN COMMON SAVE AREA   46800013
*                                         IN PPI(BLOCK/DEBLK SAVE AREA) 47100013
         LH    RJ,PPIMRGMX         INPUT MERGE ORDER                    47400013
         L     RG,PPISBLCT         ADDR OF TABLE OF INPUT BUFFER BLOCK  47700013
*                                    CTRS                               48000013
         LA    RF,PPIPDWA          ADDR OF PRIME AREA TABLE HAVING THE  48300013
*                                    STRTG ADDRS+4 OF   PRIMARY INPUT   48600013
*                                    BUFFERS.                           48900013
         SR    RI,RI                                                    49200013
         SPACE 1                                                        49500013
*INSERT THE STARTING ADDRESSES OF EACH INPUT BUFFER IN THE CORRECT      49800013
*   LOCATION IN THE TABLE OF INPUT BUFFER ADDRESSES.                    50100013
         SPACE 1                                                        50400013
ADHDK030 IC    RI,0(0,RF)          INCR OF THE FILE                     50700013
         L     RH,0(0,RF)          ADDR+4 OF THE INPUT BFR              51000013
         S     RH,KFOUR            -4 FOR EOS BYTES                     51300013
         ST    RH,0(RI,RE)         STARTG ADDR OF BFR TO BUFFER TABLE   51600013
*                                    FOR READ FORWARD                   51900013
         SPACE 1                                                        52200013
*UPDATE THE ADDRESSES IN PPIPDWA TO POINT TO THE 1ST RECORD(HI CORE)    52500013
*   IN EACH BUFFER FOR THE MERGE ROUTINE TO COMPARE.                    52800013
         SPACE 1                                                        53100013
         L     RH,0(RI,RG)         BLOCK COUNT OF THIS FILES BUFFER     53400013
         BCTR  RH,0                -1                                   53700013
         MH    RH,PPIRCDL2         EQUALS CHARACTER COUNT OF THE RCDS   54000013
*                                    IN THE BUFFER MINUS 1 RCD.         54300013
         A     RH,0(0,RF)          ADD STARTING ADDR+4 OF THE BUFFER    54600013
         ST    RH,0(0,RF)          STARTG ADDR OF 1ST RCD TO COMPARE    54900013
*                                    (REBUILDING  PPIPDWA TABLE)        55200013
         LA    RF,4(0,RF)          UPDATE PPIPDWA PTR                   55500013
         BCT   RJ,ADHDK030         DECR MERGE ORDER. BR IF UNEQUAL 0    55800013
         SPACE 1                                                        56100013
*EXIT TO NEXT ROUTINE                                                   56400013
         SPACE 1                                                        56700013
         BR    RO                  RETURN TO IERRC9                     57000013
         SPACE 2                                                        57300013
*LIST OF CONSTANTS USED BY THE MODULE.                                  57600013
         SPACE 1                                                        57900013
KFOUR    DC    A(4)                                                     58200013
         SPACE 2                                                        58500013
*DSECT OF IERRDX NEXT PAGE.                                             58800013
         EJECT                                                          59100013
IERRDX   DSECT                                                          59400013
         USING *,RL                THIS MODULE BASE REGISTER            59700013
         USING IERRCA,RN           ADDR OF PPI                          60000013
         BC    15,RDHDB020         FROM READ                            60300013
         LR    RG,RD               FROM BLOCK-RD HAS INCR & ADDR OF WNR 60600013
         SRL   RD,24               OBTAIN INCR                          60900013
         SPACE 1                                                        61200013
*LOAD BLOCK COUNT OF WNR'S BUFFER. IF EMPTY BRANCH TO READ RTN          61500013
         SPACE 1                                                        61800013
         L     RE,PPISBLCT         ADDR OF INPUT BFRS BLOCK CNT TABLE   62100013
         L     RF,0(RE,RD)         LOAD WINNER'S REMAINING BLOCK COUNT  62400013
         S     RF,KONE             DECR BY 1                            62700013
         BC    12,RDHDB010         BR TO READ IF BUFFER IS EMPTY        63000013
         ST    RF,0(RE,RD)         SAVE ADJUSTED BLOCK COUNT            63300013
         LR    RD,RG               RESTORE RD                           63600013
         SH    RD,PPIRCDL2         OBTAIN NEW INPUT RECORD ADDR         63900013
         SPACE 1                                                        64200013
*INTERFACE WITH NETWORK. RD HAS INCR AND NEW INPUT RCD ADDR             64500013
         SPACE 1                                                        64800013
         L     RL,PPINET+4         ADDR OF MERGE NETWORK                65100013
         B     8(0,RL)             BR TO NETWORK                        65400013
         SPACE 2                                                        65700013
*INTERFACE WITH READ ROUTINE                                            66000013
         SPACE 1                                                        66300013
RDHDB010 L     RG,WDBLSV           ADDR OF BUFFER ADDR TABLE            66600013
         L     RC,0(RG,RD)         THIS FILE'S EMPTY STRTG BFR ADDR     66900013
         L     RL,PPIRD+4          ADDR OF READ RTN                     67200013
         B     4(0,RL)             BR TO READ RTN                       67500013
         SPACE 2                                                        67800013
*RETURN POINT FROM READ RTN. DISPLACE ADDR IN RC BY BLOCK CNT IN RB-1 * 68100013
*   RCD LENGTH TO FIND 1ST RCD TO DEBLOCK IN THE BFR FOR MERGE.         68400013
         SPACE 1                                                        68700013
RDHDB020 L     RF,PPISBLCT         ADDR OF TABLE OF INPUT BFRS BLK CNT  69000013
         ST    RB,0(RF,RD)         STORE NEW BUFFER'S BLOCK COUNT IN    69300013
*                                    ITS APPROPRIATE PLACE.             69600013
         BCTR  RB,0                BLOCK CNT -1                         69900013
         MH    RB,PPIRCDL2         EQUALS CHAR CNT OF RCDS IN THIS BFR  70200013
*                                    MINUS ONE RCD                      70500013
         AR    RB,RC               ADD STRTG ADDR+4 OF THE BUFFER       70800013
         ST    RE,0(RG,RD)         STORE STRTG ADDR OF BUFFER IN TABLE  71100013
*                                    OF INPUT BUFFER ADDRS.             71400013
         SLL   RD,24               REPOSITION INCR                      71700013
         AR    RD,RB               INSERT STRTG ADDR OF 1ST RCD TO DBLK 72000013
         SPACE 2                                                        72300013
*INTERFACE TO MERGE NETWORK                                             72600013
         SPACE 1                                                        72900013
         L     RL,PPINET+4         ADDR OF MERGE NETWORK                73200013
         B     8(0,RL)             BRANCH TO MERGE NTWK                 73500013
         SPACE 2                                                        73800013
*LIST OF WORK AREAS:                                                    74100013
         SPACE 1                                                        74400013
WDBLSV   DC    F'0'                A.P. WILL LOAD TO ADDR OF TABLE OF   74700013
*                                    INPUT BUFFER ADDRS                 75000013
         SPACE 2                                                        75300013
*LIST OF CONSTANTS:                                                     75600013
         SPACE 1                                                        75900013
KONE     DC    F'1'                CONSTANT OF 1                        76200013
         EJECT                                                          76500013
         SMPPI                                                          76800013
         END                                                            77100013
