         TITLE '      IERAGL - OS/360 SORT/MERGE - 360S-SM023 05/15/66' 00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERAGL ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 2 ASSIGNMENT MOD. READ FORWARD        00700013
*   THE FUNCTION OF THIS MODULE IS TO CHECK IF USER EXIT E28 IS ACTIVE  00800013
*   AND MODIFY IERRGL IN APPROPRIATE PLACES. IT ALSO CHECKS WHETHER     00900013
*   FIXED OR VARIABLE LENGTH RECORDS AND OVERLAYS IERRGL.               01000013
         SPACE 1                                                        01100013
*   THIS MODULE ALLOCATES SPACE FOR THE READ FORWARD CCWS AND BLOCK     01200013
*   COUNT TABLE IN GENERATED CORE. ENOUGH SPACE IS RESERVED IN GENERA-  01300013
*   TED CORE FOR 2M CCWS EVEN THOUGH THERE MAY NOT BE FULL OVERLAP, AND 01400013
*   N+1(N=TOTAL NUMBER OF WORK UNITS) INPUT BLOCKS(MAXIMUM CASE). THE   01500013
*   BLOCK COUNT, READ FORWARD COMMAND CODE, AND SILI BIT(FOR V.L. RCDS) 01600013
*   IS PUT IN 2M CCWS. M BUFFERS ARE ATTACHED TO M CCWS AND IF THERE    01700013
*   ARE ANY INPUT BUFFERS REMAINING,THEY ARE ATTACHED TO AS MANY CCWS   01800013
*   AS THERE ARE ALTERNATE(REMAINING) BUFFERS                           01900013
         SPACE 1                                                        02000013
*   THIS MODULE THEN RETURNS TO IERRC9.                                 02100013
         SPACE 2                                                        02200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               02300013
         SPACE 1                                                        02400013
*   NONE                                                                02500013
         SPACE 2                                                        02600013
*LIST OF MACROS USED BY MODULE:                                         02700013
         SPACE 1                                                        02800013
*   SMPPI                                                               02900013
         SPACE 2                                                        03000013
*ENTRY POINTS:                                                          03100013
         SPACE 1                                                        03200013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    03300013
*                                    CALLING SEQUENCE-                  03400013
*                                      LOAD EP=IERAGL,DCB=SORTLIB       03500013
*                                      LR   RP,RA                       03600013
*                                      BALR RO,RP                       03700013
         SPACE 2                                                        03800013
*INPUT: - PPI FIELDS REFERENCED                                         03900013
         SPACE 1                                                        04000013
*   PPIMRGMX   PPISPGN1   PPITPTBL                                      04100013
*   PPIBDSVA   PPISW1     PPILAB02                                      04200013
*   PPILAB03   PPISTDCB                                                 04300013
         SPACE 1                                                        04400013
*   INFO NEEDED FOR CALCULATIONS TO BUILD SKELETON CCWS,AND TO ATTACH   04500013
*   BUFFERS TO THE IOBS.                                                04600013
         SPACE 2                                                        04700013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            04800013
         SPACE 1                                                        04900013
*   PPILAB03                                                            05000013
*   PPIPSVA                                                             05100013
*   PPIWKARE                                                            05200013
         SPACE 1                                                        05300013
*   WORK AREAS NEEDED IN THE CALCULATIONS,ALSO IF NEEDED PPILAB03(HI    05400013
*   BYTE)WILL BE CHANGED TO 2M IF NO. OF BFRS EXCEED 2M.                05500013
         SPACE 2                                                        05600013
*EXTERNAL ROUTINES:                                                     05700013
         SPACE 1                                                        05800013
*   NONE                                                                05900013
         SPACE 2                                                        06000013
*EXTERNAL PARAMETERS:                                                   06100013
         SPACE 1                                                        06200013
*   SEE REGISTERS                                                       06300013
         SPACE 2                                                        06400013
*EXITS-NORMAL:                                                          06500013
         SPACE 1                                                        06600013
*   TO IERRC9                      EXIT TO:IERRC9                       06700013
*                                    CALLING SEQUENCE-                  06800013
*                                      BR   RO         RETURN           06900013
         SPACE 2                                                        07000013
*EXITS-ERROR:                                                           07100013
         SPACE 1                                                        07200013
*   NONE                                                                07300013
         SPACE 2                                                        07400013
*TABLES/WORK AREAS:                                                     07500013
         SPACE 1                                                        07600013
*   TABLES AND WORK AREAS ARE IN PPI                                    07700013
         SPACE 2                                                        07800013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   07900013
         SPACE 2                                                        08000013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY BALANCED TAPE SORT INVOLVING   08100013
*   A READ FORWARD EXECUTION TO SAVE A COPY PASS.                       08200013
         EJECT                                                          08300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            08400013
         SPACE 1                                                        08500013
RA       EQU   0                   CONTENTS IN-N/A                      08600013
*                                  USE-CCW CTR                          08700013
*                                     -WORK REGISTER                    08800013
*                                  CONTENTS OUT-N/A                     08900013
RB       EQU   1                   CONTENTS IN-N/A                      09000013
*                                  USE-OPEN LIST BASE REG(DSECT)        09100013
*                                     -WORK REGISTER                    09200013
*                                  CONTENTS OUT-N/A                     09300013
RC       EQU   2                   CONTENTS IN-N/A                      09400013
*                                  USE-MERGE ORDER LOOP CTR             09500013
*                                     -ALT.BFR LOOP CTR                 09600013
*                                  CONTENTS OUT-N/A                     09700013
RD       EQU   3                   CONTENTS IN-N/A                      09800013
*                                  USE-AVAILABLE CCW PTR                09900013
*                                     -WORK REGISTER                    10000013
*                                  CONTENTS OUT-N/A                     10100013
RE       EQU   4                   CONTENTS IN-N/A                      10200013
*                                  USE-PTR TO GEN CORE TO MOVE A CCW    10300013
*                                     -WORK REGISTER                    10400013
*                                  CONTENTS OUT-N/A                     10500013
RF       EQU   5                   CONTENTS IN-N/A                      10600013
*                                  USE-IOB BASE REGISTER(DSECT)         10700013
*                                     -WORK REGISTER                    10800013
*                                  CONTENTS OUT-N/A                     10900013
RG       EQU   6                   CONTENTS IN-N/A                      11000013
*                                  USE-DCB BASE REGISTER(DSECT)         11100013
*                                     -PTR TO INPUT BFR ADDR TABLE      11200013
*                                  CONTENTS OUT-N/A                     11300013
RH       EQU   7                   CONTENTS IN-N/A                      11400013
*                                  USE-PTR TO IOB TABLE(PPIWKARE)       11500013
*                                  CONTENTS OUT-N/A                     11600013
RI       EQU   8                   CONTENTS IN-N/A                      11700013
*                                  USE-PTR TO ALT CCW ADDR IN GEN CORE  11800013
*                                  CONTENTS OUT-N/A                     11900013
RJ       EQU   9                   CONTENTS IN-N/A                      12000013
*                                  USE-NOT USED                         12100013
*                                  CONTENTS OUT-N/A                     12200013
RK       EQU   10                  CONTENTS IN-N/A                      12300013
*                                  USE-BASE REG OF IERRGL DSECT         12400013
*                                  CONTENTS OUT-N/A                     12500013
RL       EQU   11                  CONTENTS IN-N/A                      12600013
*                                  USE-MODULE BASE REGISTER             12700013
*                                  CONTENTS OUT-N/A                     12800013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   12900013
*                                  USE-NOT USED                         13000013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   13100013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              13200013
*                                  USE-PPI REFERENCES,REG SAVE AREA     13300013
*                                  CONTENTS OUT-ADDR OF PPI             13400013
RO       EQU   14                  CONTENTS IN-RETURN ADDR TO IERRC9    13500013
*                                  USE-NOT USED                         13600013
*                                  CONTENTS OUT-RETURN ADDR TO IERRC9   13700013
RP       EQU   15                  CONTENTS IN-THIS MODULE ENTRY PT     13800013
*                                  USE-ESTABLISH THIS MODULE BASE REG   13900013
*                                  CONTENTS OUT-N/A                     14000013
         SPACE 2                                                        14100013
*START OF MODULE CODE PROPER:                                           14200013
         SPACE 2                                                        14300013
IERAGL   CSECT                                                          14400013
*C488000,D489000                                                 A31855 14410021
*C532000                                                         A31871 14420020
*                                                                A26439 14450019
         USING *,RL                THIS MODULE BASE REGISTER            14500013
         USING IERAP22,RB          OPEN LIST BASE REGISTER(DSECT)       14600013
         USING IERRCA,RN           PPI BASE REG(DSECT)                  14700013
         USING IERRGL,RK           RUNNING PROGRAM BASE REGISTER(DSECT) 14800013
         USING IERIOB,RF           IOB BASE REG(DSECT)                  14900013
         USING IHADCB,RG           DCB BASE REG(DSECT)                  15000013
         SPACE 2                                                        15100013
*START OF ACTUAL CODE                                                   15200013
         SPACE 1                                                        15300013
IERMGB   LR    RL,RP               ESTABLISH THIS MODULE ADDRESSABILITY 15400013
         L     RK,PPIRD+4          ADDR OF IERRDL                       15500013
         SR    RD,RD                                                    15600013
         L     RB,PPIOPEN+4        ADDR OF OPEN LIST                    15700013
         SPACE 2                                                        15710017
         SPACE 2                                                        15800013
*ERROR OPTIONS. CHECK TO SEE IF USER READ ERROR SYNAD EXIT E28 IS       15900013
*   ACTIVATED. IF ACTIVATED, CHECK USER OPTIONS. 20=TERMINATE PROGRAM,  16000013
*   40=SKIP THE PHYSICAL RECORD, 80=ACCEPT THE PHYSICAL RECORD. IF NOT  16100013
*   ACTIVATED 20 IS ASSUMED. THEN MODIFY THE RUNNING PROGRAM,IERRDL, IN 16200013
*   THE APPROPRIATE PLACES.                                             16300013
         SPACE 1                                                        16400013
         LA    RP,RGBERROR+4       MODIFICATION AREA IN IERRGL          16500013
         CLC   WRDOPT+1(3),KCCW+1  IS E28 SYNAD ACTIVE FOR PH.2         16600013
         BE    AGBNOADR            BR IF NOT ACTIVE                     16700013
         OI    PPISW1+7,X'01'      SET ACCEPT SKIP SWITCH               16800013
         CLI   WRDOPT,X'40'             TEST OPTION BYTE                16900013
         BL    AGBTERM                    LESS THAN 40 = TERMINATE      17000013
         BE    AGBSTRT                    EQUAL,BYPASS FURTHER SETTINGS 17100013
         MVC   RGBACCPT(2),AGLRAN         GREATER,SET ACCEPT OPTION     17200013
AGLRAN   B     AGBSTRT                    BRANCH IS ALSO USED AS 47F0   17300013
         SPACE                                                          17400013
AGBNOADR MVI   RGLTERM+1,X'F0'          CONVERT NOP TO AUTOMATIC ABEND  17500013
AGBTERM  NI    PPISW1+7,X'FE'      TURN OFF SKIP ACCEPT SWITCH          17600013
         SPACE 2                                                        17700013
*CALCULATE AND ALLOCATE SPACE FOR CCW'S AND BLOCK COUNT TABLE           17800013
         SPACE 1                                                        17900013
AGBSTRT  MVC   KSAVE(2),PPIMRGMX   M=NO. OF INPUT FILES                 18000013
         NI    PPISPGN1+3,X'F8'    ALIGN TO DOUBLE WORD BOUNDARY BY     18100013
*                                    DECR START OF GEN CORE TO DOUBL WD 18200013
         L     RB,PPISPGN1         START OF GEN CORE ON DOUBLE WD BNDRY 18300013
         LH    RC,KSAVE            MERGE ORDER                          18400013
         LR    RA,RC                                                    18500013
         SLL   RC,4                X16.EACH CCW IS 8 BYTES. THIS CALC   18600013
*                                    EQUALS 2MX8                        18700013
         SR    RB,RC               RESRV 2MX8 BYTES IN GEN CORE FOR NOW 18800013
         SPACE 2                                                        18900013
*THIS EOUTINE WRITES DIAGNOSTIC MSG 'I/P CCW ADDR XXXX'                 19000013
         SPACE 1                                                        19100013
         TM    PPISW1+6,X'01'      TEST IF MESSAGE BIT IS ON            19200013
         BC    8,AGLTEST           BR IF NO                             19300013
         STM   RO,RE,AGLSTM        SAVE REGS                            19400013
         LR    RA,RB               ADDR OF 1ST CCW IN GEN CORE          19500013
         SPACE 1                                                        19600013
         USING AGLAMB,RE           BASE REG FOR MESSAGE MODULE          19700013
         SPACE 1                                                        19800013
         L     RE,PPIAMB+4         BASE REG FOR MESSAGE MODULE          19900013
         L     RP,PPICONV+4        ADDR OF CONVERT ROUTINE              20000013
         BAL   RO,4(0,RP)          CONVERT RTN.                         20100018
         MVC   DMSG927A(8),0(RB)   CONVERTED DATA IN RB PTR             20200013
         LM    RA,RB,DMSG927X      ADDR AND LENGTH OF MESSAGE           20300013
         L     RP,PPIADSSC         ADDR OF SSC                          20400013
         BAL   RO,12(0,RP)         BR TO PRINT MESSAGE                  20500013
         LM    RO,RE,AGLSTM        RESTORE REGISTERS                    20600013
         SPACE 1                                                        20700013
*END OF DIAGNOSTIC ROUTINE                                              20800013
         SPACE 1                                                        20900013
AGLTEST  SLL   RA,1                EQUALS 2M                            21000013
         IC    RD,PPILAB03         NUMBER OF INPUT BUFFERS              21100013
         CLR   RD,RA               COMPARE ACTUAL BUFFERS TO FULL       21200013
*                                    OVERLAP BUFFER CONDITION           21300013
         BC    12,*+8              BR ON LESS THAN OR EQUAL TO 2XM      21400013
         STC   RA,PPILAB03         WE HAVE MORE BUFFERS THAN MAXIMUM    21500013
*                                    NEEDED(THAN FULL OVERLAP) THUS     21600013
*                                    RESET NO. OF BUFFERS TO 2XM        21700013
         SPACE 2                                                        21800013
*CALCULATION FOR RESERVING CORE FOR THE TABLE OF BLOCK COUNTERS. THEN   21900013
*   MODIFY PPISPGN1 TO THE PROPER ADDRESS.                              22000013
         SPACE 1                                                        22100013
         IC    RD,PPIBDSVA         TOTAL NO. OF WORK UNITS              22200013
         LA    RD,1(0,RD)          ADD 1 FOR TABLE ALIGNMENT            22300013
         SLL   RD,2                X4. 4 BYTES FOR EACH ENTRY           22400013
         LR    RE,RB               SAVE STARTG ADDR OF CCW LIST         22500013
         SR    RB,RD               RESERVE SPACE FOR BLOCK CTRS         22600013
         ST    RB,PPISPGN1         SAVE UPDATED ADDRESS FOR NEXT RTN    22700013
*                                    USING GENERATED CORE.              22800013
         ST    RB,PPISBLCT         PLACE BLK CNT POINTER IN PPI         22900013
         SPACE 2                                                        23000013
*CHECK FOR THE PROPER RECORD FORMAT BEFORE BUILDING THE CCWS            23100013
         SPACE 1                                                        23200013
         TM    PPISW1,X'40'        CHECK FOR VAR. RCD FORMAT            23300013
         BO    AGBVR020            BR IF VAR RECORD FORMAT              23400013
         SPACE 2                                                        23500013
*BUILD THE CCWS IN GEN CORE WITH THE COUNT FIELD,READ FWD COMMAND,FLAG  23600013
*   FIELD(NO SILI BIT FOR F.L.)                                         23700013
         SPACE 1                                                        23800013
AGBGN010 MVC   KCCW+6(2),PPILAB03+2 COUNT FIELD                         23900013
AGBFLAG  MVI   KCCW+4,X'00'        FLAG=00 FOR F.L.,WILL BE 20 FOR V.L. 24000013
*                                    (SILI BIT ON)                      24100013
         SPACE 2                                                        24200013
*GENERATE 2XM CCWS IN GENERATED CORE                                    24300013
         SPACE 1                                                        24400013
         LR    RD,RE               STARTG ADDR OF CCWS IN GEN CORE      24500013
AGBCCWLP MVC   0(8,RE),KCCW        MOVE A CCW INTO GENERATED CORE       24600013
         LA    RE,8(0,RE)          UPDATE GEN CORE PTR TO MOVE NEXT CCW 24700013
         BCT   RA,AGBCCWLP         DECR 2M CCW CTR. LOOP IF MORE CCWS   24800013
         SPACE 2                                                        24900013
*ATTACH THE CCWS AND BUFFERS TO THE INPUT IOBS SPECIFIED BY THE TAPE    25000013
*   TABLE VIA THE INPUT BIT AND INCREMENT.                              25100013
         SPACE 1                                                        25200013
         LR    RA,RD               STARTG ADDR OF THE CCWS IN GEN CORE  25300013
         LH    RC,KSAVE            MERGE ORDER(M)                       25400013
         L     RB,PPISTDCB         PTR TO THE DCB TABLE OF ADDRS        25500013
         LA    RE,PPITPTBL         PTR TO THE TAPE TABLE HAVING THE     25600013
*                                    INPUT BIT AND FILE INCR.           25700013
         LA    RH,PPIWKARE         WORK AREA IN PPI                     25800013
AGBGN030 TM    0(RE),X'80'         SEARCH TAPE TABLE FOR INPUT FILE     25900013
         BO    AGBGN040            BR ON AN INPUT FILE                  26000013
         LA    RE,2(0,RE)          NEXT ENTRY IN THE TAPE TABLE         26100013
         B     AGBGN030            LOOP                                 26200013
         SPACE 2                                                        26300013
*VARIABLE LENGTH OVERLAYS FOR THE RUNNING PROGRAM,IERRGL.               26400013
         SPACE 1                                                        26500013
AGBVR020 MVI   AGBFLAG+1,X'20'     SET THE SILI BIT IN IERAGL INSTR     26600013
         MVI   RGBBRVR+1,X'F0'                                          26700013
         MVI   RGBRTRNV+3,X'08'                                         26800013
         MVI   RGBEOSV+3,X'06'                                          26900013
         MVI   RGBPREOS+3,X'06'                                         27000013
         MVI   RGBEREOS+3,X'06'                                         27100013
         MVI   RGBBRVAR+3,X'08'                                         27200013
         MVI   RGBBCCV+1,X'F0'                                          27300013
         MVI   RGBLSTBK+3,X'06'                                         27400013
         MVI   RGBCKEOS+3,X'06'                                         27500013
         B     AGBGN010            MORE CCWS TO BE GENERATED            27600018
         SPACE 2                                                        27700013
*THE IOBS ARE ALREADY ATTACHED TO THE DCBS. ATTACH A BUFFER NO. OF 1    27800013
*   TO THE DCB. SAVE IOB ADDR TO ATTACH AN ALTERNATE BUFFER,TO GAIN     27900013
*   FULL OVERLAP,IF THERE ARE BUFFERS REMAINING. ATTACH A CCW TO THE    28000013
*   IOB AND ATTACH A BUFFER TO THIS CCW. ATTACH A 2ND CCW IN THE 4      28100013
*   BYTES FOLLOWING THE ECB IN PREPARATION FOR PARTIAL OR FULL OVERLAP. 28200013
         SPACE 1                                                        28300013
AGBGN040 SR    RG,RG                                                    28400013
         IC    RG,1(0,RE)          INCR FROM THE TAPE TABLE             28500013
         STC   RG,0(0,RH)          STORE IN PPIWKARE                    28600013
         L     RG,0(RG,RB)         LOAD A DCB ADDR VIA INCR             28700013
         MVI   DCBBUFNO,X'01'      SET BUFNO IN DCB TO A 1              28800013
         MVC   1(3,RH),DCBIOBAD+1  SAVE IOB ADDR IN PPIWKARE            28900013
         L     RF,DCBIOBAD         ADDR OF THE IOB ATTACHED TO THIS DCB 29000013
         ST    RD,START            ATTACH STRTG ADDR OF A CCW TO IOB    29100013
         L     RG,PPILAB02         ADDR OF BEGINNING OF INPUT BFR ADDR  29200013
*                                    TABLE                              29300013
         L     RI,0(0,RG)          STRTG ADDR OF AN INPUT BUFFER        29400013
         ST    RI,PPIPSVA+4        SAVE IN A WORK AREA                  29500013
         MVC   1(3,RD),PPIPSVA+5   MOVE ONLY THE ADDR OF THE INPUT BFR  29600013
*                                    INTO   CCW ATTACHED TO THE IOB.    29700013
         LA    RG,4(0,RG)          UPDATE INPUT BUFFER ADDR PTR         29800013
         ST    RG,PPILAB02         UPDATE THE PTR IN PPI                29900013
         LA    RD,8(0,RD)          UPDATE CCW PTR TO NEXT AVAILABLE CCW 30000013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE PTR TO NEXT ENTRY  30100013
         LA    RH,4(0,RH)          UPDATE PTR TO NEXT FREE AREA IN      30200013
*                                    PPIWKARE TABLE,TO INSRT NEXT IOB   30300013
         L     RI,ECBPTR           ADDR OF ECB ATTACHED TO IOB          30400013
         ST    RD,4(0,RI)          ATTACH THE ALTERNATE CCW TO THE IOB  30500013
*                                    (DCB GENERATION SETS ASIDE 4 BYTES 30600013
*                                    AFTER THE ECB FOR THIS CCW ADDR)   30700013
         LA    RD,8(0,RD)          UPDATE CCW PTR TO NEXT AVAILABLE CCW 30800013
         BCT   RC,AGBGN030         DECR MERGE ORDER.LOOP UNTIL M=0      30900013
         SPACE 2                                                        31000013
*AT THIS POINT EACH INPUT DCB HAS AN IOB. EACH IOB HAS A CCW WITH 1     31100013
*   INPUT BUFFER ATTACHED TO IT. THE ADDR OF A 2ND CCW IS LOCATED IN    31200013
*   THE 4 BYTES FOLLOWING THE ECB FOR EACH IOB.                         31300013
         SPACE 1                                                        31400013
         IC    RC,PPILAB03         TOTAL NO. OF INPUT BUFFERS           31500013
         SH    RC,KSAVE            MINUS MERGE ORDER=NO. OF ALT. BFRS.  31600013
         BZ    AGBLK070            BR IF ZERO(NO ALT. BFRS FOR OVLAP)   31700013
         SPACE 2                                                        31800013
*PARTIAL OR FULL OVERLAP ROUTINE. ATTACH THE ALTERNATE BUFFERS TO THE   31900013
*   IOBS' ALTERNATE CCWS. RC CONTAINS NO. OF ALTERNATE BUFFERS. ALL THE 32000013
*   IOB ADDRESSES WITH THEIR FILE INCR WERE SAVED IN PPIWKARE TABLE.    32100013
         SPACE 1                                                        32200013
         LA    RH,PPIWKARE         ADDR OF THE IOB TABLE OF ADDRS.      32300013
         L     RE,PPILAB02         ALTERNATE BFR ADDR PTR               32400013
         CH    RC,KSAVE            NO. OF ALT. BFRS TO MERGE ORDER      32500013
         BE    AGBAL060            BR IF HAVE FULL OVERLAP CONDITION    32600013
         MVI   RGBRFBF+1,X'F0'     PARTIAL OVLAP. SET INSTR IN IERRGL   32700013
*                                    TO UNCONDITIONAL BR.               32800013
AGBAL060 L     RF,0(0,RH)          IOB ADDR FROM TABLE                  32900013
         L     RI,ECBPTR           ADDR OF ECB ATTACHED TO THIS IOB     33000013
         L     RG,DCBPTR           ADDR OF DCB ATTACHED TO THIS IOB     33100013
         L     RI,4(0,RI)          IOB'S ALTERNATE CCW ADDR IN GEN CORE 33200013
         L     RF,0(0,RE)          STRTG ADDR OF NEXT AVAILABLE INPUT   33300013
*                                    BUFFER                             33400013
         ST    RF,PPIPSVA+4        SAVE THIS ADDR IN A WORK AREA        33500013
         MVC   1(3,RI),PPIPSVA+5   STORE ALT BFR ADDR IN ACTUAL ALT CCW 33600013
         MVI   DCBBUFNO,X'02'      UPDATE IOB'S DCB TO 2 BUFFERS        33700013
         LA    RH,4(0,RH)          UPDATE IOB ADDR TABLE PTR            33800013
         LA    RE,4(0,RE)          UPDATE ALTERNATE BUFFER ADDR PTR     33900013
         BCT   RC,AGBAL060         DECR ALT. BFR CTR. LOOP IF MORE BFRS 34000013
         SPACE 2                                                        34100013
*INTERFACE TO IERRC9                                                    34200013
         SPACE 1                                                        34300013
AGBLK070 BR    RO                  RETURN                               34400013
         SPACE 2                                                        34500013
*LIST OF CONSTANTS:                                                     34600013
         SPACE 1                                                        34700013
KCCW     DC    X'02000000'         MODEL CCW WORK AREA                  34800013
         DC    X'00000000'         MODEL CCW WORK AREA                  34900018
AGLSTM   DC    7F'0'               SAVE AREA FOR REGS RO-RE             35000013
         EJECT                                                          35100013
IERRGL   DSECT ,                   DUMMY MODULE OF IERRGL               35200013
         USING *,RL                THIS MODULE BASE REGISTER            35300013
         USING IERRCA,RN           PPI BASE REG(DSECT)                  35400013
         USING IERIOB,RF           IOB BASE REG(DSECT)                  35500013
         USING IHADCB,RG           DCB BASE REG(DSECT)                  35600013
         SPACE 2                                                        35700013
*START OF ACTUAL CODE                                                   35800013
         SPACE 1                                                        35900013
IERDGB2D BC    0,IERDGB2D          DUMMY ENTRY                          36000013
         B     RGBPR200            ENTRY FROM ALG-PRIME TIME            36100013
         SPACE 2                                                        36200013
*ENTRY FROM DEBLOCK DURING RUN TIME. RC-ADDR OF EMPTY INPUT BLOCK. RD-  36300013
*   INCREMENT OF THE INPUT UNIT.                                        36400013
         SPACE 1                                                        36500013
         STM   RC,RH,KSAVE         SAVE REGS                            36600013
         ST    RC,IERDGB2D         ALSO SAVE RC SEPARATELY              36700013
RGBCKEOS TM    2(RC),X'07'         IS THIS AN EOS BFR. A.P. WILL OVLAY  36800013
*                                    THE 2 W/6 FOR V.L. BUFFER          36900013
         BZ    RGBST010            BR IF NOT EQUAL TO EOS BFR           37000013
         SPACE 2                                                        37100013
*INTERFACE TO MERGE NETWORK ON END OF SEQUENCE FOR THIS UNIT            37200013
         SPACE 1                                                        37300013
RGBRTEOS L     RL,PPINETM+4                                             37400013
         B     4(0,RL)             BR TO MERGE ON AN INPUT EOS          37500013
         SPACE 2                                                        37600013
*THERE IS NO EOS ON THIS FILE. IF THERE IS NO ALTERNATE BUFFER ISSUE A  37700013
*   READ ON THIS FILE(TO FILL THE EMPTY BFR) AND A WAIT, OTHERWISE      37800013
*   ISSUE A WAIT ON THE ALTERNATE BUFFER.                               37900013
         SPACE 1                                                        38000013
RGBST010 L     RG,PPISTDCB         PTR TO INPUT DCB ADDR TABLE          38100013
         L     RG,0(RD,RG)         THIS FILE'S DCB ADDR                 38200013
         L     RF,DCBIOBAD         THIS DCB'S IOB ADDR                  38300013
         TM    DCBBUFNO,X'02'      TEST IF 2 BUFFERS FOR THIS FILE      38400013
         BO    RGBAL020            BR IF 2,TO WAIT ON THE ACT BFR       38500013
         EXCP  (RF)                READ FWD                             38600013
         BAL   RE,RGBEOSCK         BR TO WAIT & CK IF EOS BFR.          38700013
         SPACE 2                                                        38800013
*AT THIS POINT RB-NO OF RCDS IN THE BFR(F.L) OR RB-BCC MINUS 4 EOS      38900013
*   BYTES(V.L.).IT INCLUDES THE 4 BCC BYTES FOR V.L. WHICH BLOCK WILL   39000013
*   SUBTRACT.                                                           39100013
         SPACE 1                                                        39200013
RGBRTRN  LM    RC,RH,KSAVE         RC NOW CONTAINS STRTG ADDR OF THE    39300013
*                                    FILLED BUFFER.                     39400013
         SPACE 2                                                        39500013
*INTERFACE TO DEBLOCK. THE REGISTERS WILL CONTAIN: RB-BLOCK COUNT,      39600013
*   RC-PTR TO 1ST RCD(LO CORE) IN THE BLOCK, RD-FILE INCR, RE-STRTG     39700013
*   ADDRESS OF THE BLOCK                                                39800013
         SPACE 1                                                        39900013
RGBRTRNV LA    RC,4(0,RC)          RC NOW PTS TO 1ST RCD IN BFR. A.P.   40000013
*                                    WILL OVLAY 4 W/8 TO BYPASS THE 4   40100013
*                                    BYTES FOR THE BCC IN ADDTN TO EOS  40200013
         L     RL,PPIBLK2+4        ADDR OF BLOCK/DEBLOCK                40300013
         B     4(0,RL)             GO TO BLOCK/DEBLOCK RTN.             40400018
         SPACE 2                                                        40500013
*ISSUE A WAIT ON THE BUFFER                                             40600013
         SPACE 1                                                        40700013
RGBEOSCK L     RB,ECBPTR           ADDR OF IOB'S ECB                    40800013
         WAIT  1,ECB=(1)                                                40900013
         BAL   RH,RGBEE100         BR TO EOF/ERROR CHECK RTN            41000013
RGBEOSV  TM    2(RC),X'07'         IS BUFFER EOS.                       41100013
         BCR   12,RE               BR IF NO TO DEBLOCK(NO ALT BFRS) OR  41200013
*                                    TO ALT BFR RTN                     41300013
RGBEOS   MVI   KSAVE+8,C'$'        SET EOS BYTE ON IN HI ORDER BYTE OF  41400013
*                                    BFR ADDR FOR NXT RD ON THIS FILE   41500013
         B     RGBRTRN             RESTORE REGS. THEN GO TO DEBLOCK     41600018
         SPACE 2                                                        41700013
RGBAL020 BAL   RE,RGBEOSCK         WAIT ON FILE-CHECK FOR EOS           41800013
RGBRFBF  BC    0,RGBFL040          A.P. WILL SET THIS NOP TO A BR IF    41900013
*                                    HAVE PARTIAL OVLAP(FLOATING BFRS)  42000013
         SPACE 2                                                        42100013
*ATTACH EMPTY BFR FROM DEBLOCK TO THE FILE VIA THE IOB START PTR AND    42200013
*   DATA ADDR. IN THE CCW                                               42300013
         SPACE 1                                                        42400013
RGBAL030 LA    RC,IERDGB2D         ADDR OF THE BFR                      42500013
         LA    RH,RGBRTRN          RETURN ADDR                          42600013
         B     RGBIOBUP            BR TO ISSUE READ ON BUFFER           42700013
         SPACE 2                                                        42800013
*ERROR CHECKING ROUTINE                                                 42900013
         SPACE 1                                                        43000013
RGBEE100 TM    CSW+4,X'01'         UNIT EXCEPTION IN CSW ON FOR EOF TM  43100013
         BO    RGBEOF              BR IF ON TO EOF ROUTINE              43200013
         TM    CSW+4,X'02'         UNIT CHECK ON IN CSW FOR DEVICE ERR  43300013
         BZ    RGBPRMSK            BR IF NOT ON.CHECK CHANNEL ERROR     43400013
         MVC   WSENSE0,SENSE       SAVE SENSE BYTE.WE HAVE DEVICE ERR   43500013
         B     RGBERROR            ERROR RTN.                           43600018
RGBPRMSK TM    CSW+5,X'08'         CHECK IF CHANNEL ERROR               43700013
         BC    1,RGSTORRF          BR IF ON TO SAVE IOB ADDR BEFORD     43800013
*                                    GOING TO ERROR RTN                 43900013
         SPACE 1                                                        44000013
         L     RC,START            SET RC TO STARTING                   44100013
         L     RC,0(0,RC)            LOCATION IN THE BUFFER             44200013
         TM    CSW+5,X'40'         CHECK IF INCORRECT LENGTH BIT ON     44300013
         BC    8,RGBEE105          NO - BR                              44400013
         SPACE 1                                                        44500013
RGBLSTBK TM    2(RC),X'07'         IS IT LAST BLOCK OF SEQUENCE.        44600013
         BZ    RGSTORRF            NO-BLOCK IS IN ERROR                 44700013
         SPACE 2                                                        44800013
*NO ERRORS ON THIS BUFFER                                               44900013
         SPACE 1                                                        45000013
         NI    DCBIFLGS,X'3F'                                           45100013
RGBEE105 LH    RB,PPILAB03+2       SIZE OF AN INPUT BUFFER              45200013
         SH    RB,CSW+6            SUBTR RESIDUAL COUNT(NO. OF BYTES    45300013
*                                    DIDNT READ IN)                     45400013
         LA    RC,0(0,RC)          CLEAR COMMAND CODE IN RC             45500013
         ST    RC,KSAVE+8          SET RE(IN THE SAVE AREA) FOR DEBLOCK 45600013
         SH    RB,KFOUR            SUBTR EOS BYTES FROM RESIDUAL CNT    45700013
RGBBRVR  BC    0,RGBEE110          A.P. WILL OVLAY TO A BR IF V.L. RCDS 45800013
         SPACE 2                                                        45900013
*COUNT THE NUMBER OF RECORDS IN THE FIXED LENGTH BLOCK                  46000013
         SPACE 1                                                        46100013
         SR    RO,RO               RECORD CTR                           46200013
RGBFIX   SH    RB,PPIRCDL2         SORT RECORD LENGTH                   46300013
         LA    RO,1(0,RO)          ADD 1 TO RECORD CTR                  46400013
         CH    RB,PPIRCDL2         CHECK TO SEE IF MORE RCDS IN BUFFER  46500013
         BC    10,RGBFIX           BR ON RB =OR GTR.THUS MORE RCDS      46600013
*                                    REMAIN IN BUFFER                   46700013
         LR    RB,RO               RB HAS NO OF RCDS IN BUFFER          46800013
RGBEE110 ST    RC,KSAVE            SET RC(IN THE SAVE AREA) FOR DEBLOCK 46900013
         BR    RH                  BR TO RGBEREOS IF E28 ACTIVE & USER  47000013
*                                    WANTS TO SKIP OR RGBBCCV AT        47100013
*                                    PRIME TIME OR RGBEOSV AT RUN TIME  47200013
         SPACE 2                                                        47300013
*END OF FILE ROUTINE. ONLY COME HERE AT PRIME TIME BECAUSE THE RUNNING  47400013
*   PORTION OF RGL ONLY CHECKS FOR EOS. THUS CAN ONLY GET EOF AT PRIME. 47500013
         SPACE 1                                                        47600013
RGBEOF   STM   RD,RJ,KSAVE         SAVE REGISTERS                       47700013
         SR    RA,RA                                                    47800013
         IC    RA,0(0,RD)          OBTAIN FILE INCREMENT                47900013
         LR    RD,RA                                                    48000013
         L     RG,PPISTDCB         DCB ADDR TABLE POINTER               48100013
         L     RG,0(RD,RG)         DCB ADDR                             48200013
         NI    DCBIFLGS,X'3F'      RESET 1ST 2 BITS OF IFLGS FIELD      48300013
         LH    RA,KNNINE           UPDATE FILE CNT TO EOF               48400013
         STC   RD,RGBINST+1        SET I FIELD TO UNIT'S INCR           48500013
         BAL   RH,RGBFLUP          BR TO UPDATE UNIT'S FILE CTR TO EOF  48600013
         SPACE 2                                                        48700013
         OI    DCBOFLGS,X'04'      TURN OFF FLAG BITS IN DCB     A31855 48800021
         CLOSE ((RG))              CLOSE AND REWIND THIS FILE           49000013
         L     RG,PPISTDCB                                              49100013
         AR    RG,RD               ADD INCR TO GET TO THIS INPUT DCB    49200013
*                                    ADDR                               49300013
         MVI   0(RG),X'80'         TURN ON CLOSE BIT IN DCB ADDR TABLE  49400013
         SPACE 2                                                        49500013
*INTERFACE TO ALGORITHM. EOF AT PRIME TIME                              49600013
         SPACE 1                                                        49700013
         L     RL,PPIALG+4                                              49800013
         BAL   RO,12(0,RL)         GO TO ALGORITHM                      49900018
         SPACE 2                                                        50000013
         LM    RD,RJ,KSAVE         RESTORE REGS FOR PRIMING             50100013
         LR    RO,RE               RE HAS M MINUS NO.OF ACTUAL FILLED   50200013
*                                    BFRS                               50300013
         SLL   RO,2                X4                                   50400013
         BCTR  RO,0                -1                                   50500018
         EX    RO,KMOVE            BYPASS FILE ENTRY W/EOF IN PPIA      50600013
         B     RGBPRLP             BR TO DECR RE & WAIT ON REMAING BFRS 50700013
         SPACE 2                                                        50800013
*RD PTS TO THE CORRECT ENTRY IN THE PPIWKARE TABLE                      50900013
         SPACE 1                                                        51000013
KMOVE    MVC   0(1,RD),4(RD)       SHIFT THE REMAINDER OF THE TABLE UP  51100013
*                                    TO OVLAY THIS EOF ENTRY. THERE     51200013
*                                    MUST BE NO HOLES IN THE TABLE      51300013
         SPACE 2                                                        51400013
*A REAL ERROR HAS OCCURED. EITHER UNIT OR CHANNEL DATA CHECK            51500013
         SPACE 1                                                        51600013
RGBERROR OI    PPISW1+5,X'80'      TURN ON READ ERROR BIT               51700013
RGLTERM  NOP   RGPRTABT            SKIP DIRECTLY TO END IF NO E28       51800013
         L     RB,DCBPTR           DCB ADDR. A.P. WILL OVLAY TO BR TO   51900013
*                                    SSC IF E28 SYNAD NOT ACTIVATED.    52000013
         ST    RF,PPIWKARE         IOB ADDR                             52100013
         MVI   PPIWKARE,X'10'      INCR TO CCW ADDR                     52200013
         L     RA,PPIWKARE         INCR TO CCW IN THE IOB & IOB ADDR    52300013
         SPACE 2                                                        52400013
*INTERFACE TO E28 SYNAD                                                 52500013
         SPACE 1                                                        52600013
         BALR  RO,RP               USER MOD.                            52700018
         SPACE 2                                                        52800013
         SPACE 2                                                        52900013
*PRINT IOS READ ERROR MSG BEFORE ABORTING                               53000013
         SPACE 1                                                        53100013
RGPRTABT LR    RE,RF               ADDRESS OF CURRENT IOB        A31871 53200020
         L     RE,20(0,RE)         ADDR OF IOB'S DCB                    53300013
         L     RE,44(0,RE)         ADDR OF DCB'S DEB                    53400013
         L     RE,32(0,RE)         ADDR OF DEB'S UCB                    53500013
         MVC   PPILAB02+1(3),13(RE) UNIT NAME (I.E.  182,183)           53600013
         L     RP,PPIADSSC                                              53700013
         BAL   RO,16(0,RP)         SORT SYSTEM CONTROL                  53800018
         SPACE 2                                                        53900013
*RESET ALL ERROR BITS SET BY IOS IN THE DCB & IOB OTHERWISE THE FILE    54000013
*   WILL REMAIN PURGED.                                                 54100013
         SPACE 1                                                        54200013
RGBSKIP  OI    FLG1,X'40'                                               54300013
         NI    CSW+5,X'B7'                                              54400013
         NI    DCBIFLGS,X'3F'                                           54500013
RGBACCPT BAL   RH,RGBEE105         A.P. WILL OVLAY WITH B RGBEE105 ON   54600013
*                                    E28 ACCEPT OPTION=80.              54700013
RGBEREOS TM    2(RC),X'07'         CHECK IF ERROR WAS ON EOS BLOCK.     54800013
         BO    RGBRTEOS            BR IF EOS BFR                        54900013
         EXCP  (RF)                ISSUE NEW READ INTO BUFFER AREA      55000013
         B     RGBEOSCK            GO TO WAIT                           55100018
RGSTORRF ST    RF,PPIWKARE                                              55200013
         B     RGBERROR            ERROR RTN.                           55300018
         SPACE 2                                                        55400013
*ISSUE READ ON THE EMPTY BUFFER                                         55500013
         SPACE 1                                                        55600013
RGBIOBUP L     RE,START            ATTACH THE ALTERNATE CCW TO          55700013
         L     RP,ECBPTR                                                55800013
         MVC   START+1(3),5(RP)    FILE TO HANDLE READS ON              55900013
         ST    RE,4(0,RP)            THE ALTERNATE BUFFER               56000013
         L     RE,START                                                 56100013
         MVC   1(3,RE),1(RC)       STORE BUFFER ADDR. IN CCW            56200013
         MVI   DCBBUFNO,X'02'      UPDATE BUFNO                         56300013
         LR    RE,RB               SAVE BLOCK COUNT                     56400013
         EXCP  (RF)                                                     56500013
         LR    RB,RE               RESTORE BLOCK COUNT FOR DEBLOCK      56600013
         BCR   15,RH               RETURN TO EOF RTN.                   56700018
         SPACE 2                                                        56800013
*SEARCH FILE COUNTER TABLE. SET FILE COUNT ON EOF UNIT TO FFFF. RGBINST 56900013
*  'I' FIELD WILL CONTAIN INCR OF EOF UNIT(SET BY EOF RTN)              57000013
         SPACE 1                                                        57100013
RGBFLUP  LA    RC,TFCNT            ADDR OF TABLE OF FILE COUNTERS       57200013
RGBINST  CLI   0(RC),X'00'         COMPARE FOR EOF UNIT                 57300013
         BE    RGBFL120            BR WHEN FOUND                        57400013
         LA    RC,4(0,RC)          UPDATE POINTER                       57500013
         B     RGBINST             CHECK FOR EOF                        57600018
         SPACE 2                                                        57700013
RGBFL120 L     RE,0(0,RC)          OBTAIN THE COUNT OF THE UNIT(COULD   57800013
*                                    BE B, OR 2B)                       57900013
         AR    RE,RA               ADD FFFF(EOF) TO FILE COUNT          58000013
         ST    RE,0(0,RC)          RESTORE COUNT                        58100013
         BCR   15,RH               RETURN TO EOF ROUTINE                58200013
         SPACE 2                                                        58300013
*PARTIAL OVERLAP,FLOATING BUFFER RTN.EXECUTED DURING RUN TIME. AT THIS  58400013
*   POINT WE HAVE AN EMPTY BFR AND A FULL BUFFER ON THE FILE FOR DEBLK. 58500013
*   FIND A FILE W/1 BFR HAVING THE LEAST AMOUNT OF RCDS IN IT. THIS IS  58600013
*   THE FILE TO ATTACH THE ALTERNATE BUFFER(MOST LIKELY TO EMPTY 1ST)   58700013
         SPACE 1                                                        58800013
RGBFL040 LA    RC,TFCNT            ATTACH FLOATING BUFFER TO NEXT       58900013
         ST    RB,KSAVEB           SAVE BLOCK CNT FOR DEBLOCK           59000013
         L     RB,PPISBLCT           FILE TO BE READ                    59100013
         LH    RH,KMRGMX                                                59200013
         LA    RE,PPIPSVA                                               59300013
         SR    RO,RO                                                    59400013
         ST    RO,0(RD,RB)         SET RELEASED FILE'S BLCNT=0          59500013
RGBFL050 IC    RO,0(0,RC)          OBTAIN DEBLOCK'S BLOCK COUNTERS      59600013
         L     RP,0(RO,RB)                                              59700013
         A     RP,0(0,RC)            AND ADD THEM TO READ'S APPROPRIATE 59800013
         ST    RP,0(0,RE)                                               59900013
         LA    RC,4(0,RC)            FILE COUNTERS.                     60000013
         LA    RE,4(0,RE)                                               60100013
         BCT   RH,RGBFL050         GET NEXT COUNTER                     60200018
*                                                                       60300013
         LA    RC,PPIPSVA                                               60400013
         LH    RB,KMRGMX                                                60500013
         STC   RD,RGBINST1+1                                            60600013
         LR    RE,RC                                                    60700013
         BC    15,RGBINST1         CHECK FILE COUNT                     60800018
*                                                                       60900013
*                                                                       61000013
RGBFL060 LA    RE,4(0,RE)          SCAN FOR LOWEST FILE COUNT           61100013
         CLC   1(3,RC),1(RE)                                            61200013
         BC    2,RGBEX070            AND FOR THE RELEASED               61300013
RGBINST1 CLI   0(RE),X'00'                                              61400013
         BC    8,RGBRL080            FILE COUNT                         61500013
RGBLPEND BCT   RB,RGBFL060         CONTINUE SCAN                        61600018
         LA    RA,PPIPSVA          OBTAIN FILE COUNT ADDRS. VIA         61700013
         SR    RC,RA                 DISPLACEMENTS OF LOWEST AND        61800013
         SR    RP,RA                 RELEASED FROM PPIPSVA              61900013
         LA    RA,TFCNT                                                 62000013
         AR    RP,RA                                                    62100013
         AR    RC,RA                                                    62200013
         MVI   DCBBUFNO,X'01'        RELEASED FILE'S BUFNO(IN DCB)      62300013
         LR    RO,RG                                                    62400013
         LR    RA,RF                                                    62500013
         IC    RB,0(0,RC)          INCR IN NEW FILE COUNT'S FIRST BYTE  62600013
         L     RG,PPISTDCB                                              62700013
         L     RG,0(RB,RG)         DCB  AND IOB ADDRS.                  62800013
         L     RF,DCBIOBAD           OF NEW FILE                        62900013
         L     RE,PPIBDSVA         BUFFER TABLE ADDR.                   63000013
         AR    RE,RB                                                    63100013
         L     RB,KSAVEB           RESTORE BLOCK CNT                    63200013
RGBFBV   CLI   0(RE),C'$'          CK FOR EOS                           63300013
         BC    7,RGBCONT           YES-BRANCH                           63400018
         LR    RG,RO               REATTACH BUFFER TO PREVIOUS          63500013
         LR    RF,RA                                                    63600013
         BC    15,RGBAL030           (IE RELEASED FILE)                 63700013
         SPACE 2                                                        63800013
*CHECK FOR EOS AT PRIMING ON THE FILE W/LEAST RCDS IN ITS BUFFER        63900013
         SPACE 1                                                        64000013
RGBCONT  CLI   WEOSCNT,X'00'       EOS ON THIS LOWEST FILE              64100013
         BC    7,RGBFBV+8          BR IF YES.FALL THRU IF NO            64200013
         L     RE,0(0,RC)          FILE COUNT FOR LOWEST FILE=B.        64300013
         AH    RE,PPISRTBL         ADD B. NOW=2B                        64400013
         ST    RE,0(0,RC)          STORE AS NEW FILE COUNT              64500013
         L     RE,0(0,RP)          FILE COUNT FOR RELEASED FILE=2B      64600013
         SH    RE,PPISRTBL         SUBTRACT B, NOW=B.                   64700013
         ST    RE,0(0,RP)          STORE AS NEW FILE COUNT              64800013
         B     RGBAL030            BR TO ACTUALLY ATTACH EMPTY BFR      64900013
         SPACE 2                                                        65000013
*FOUND A NEW LOWER FILE COUNT                                           65100013
         SPACE 1                                                        65200013
RGBEX070 LR    RC,RE               ADDR OF LOWEST FILE COUNT            65300013
         B     RGBINST1            CHECK FILE COUNT                     65400018
         SPACE 2                                                        65500013
*ADDR IN PPISVA OF UNIT WITH EMPTY BFR                                  65600013
         SPACE 1                                                        65700013
RGBRL080 LR    RP,RE               ADDR OF RELEASED FILE COUNT          65800013
         B     RGBLPEND            CONTINUE SCAN FOR LOWEST FILE        65900018
         SPACE 2                                                        66000013
*PRIMING SUBROUTINE                                                     66100013
         SPACE 1                                                        66200013
RGBPR200 MVI   WEOSCNT,X'00'       RESET EOS CTR FROM PREVIOUS PRIME    66300013
*                                    PASS                               66400013
         LA    RB,TINCR            ADDR OF TABLE OF INCREMENTS          66500013
         ST    RB,AEOSPR                                                66600013
RGBPR220 LA    RE,PPITPTBL         ADDR OF TAPE TABLE                   66700013
         LH    RH,PPIMRGMX         M                                    66800013
         L     RJ,PPISTDCB         DCB TABLE OF ADDRS PTR               66900013
         LA    RD,PPIWKARE                                              67000013
         SPACE 2                                                        67100013
*SEARCH TAPE TABLE FOR INPUT FILES. AS A UNIT IS FOUND ISSUE A READ ON  67200013
*   IT AND RETURN.                                                      67300013
         SPACE 1                                                        67400013
RGBPR230 TM    0(RE),X'80'         TEST FOR INPUT BIT                   67500013
         BO    RGBPR240            BR ON INPUT UNIT                     67600013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE POINTER            67700013
         B     RGBPR230            CHECK NEXT ENTRY IN TABLE            67800018
         SPACE 2                                                        67900013
*PRIME M BUFFERS                                                        68000013
         SPACE 1                                                        68100013
RGBPR240 SR    RG,RG                                                    68200013
         IC    RG,1(0,RE)          INPUT UNIT INCREMENT FROM TAPE TABLE 68300013
         STC   RG,0(0,RD)          STORE IN PPIWKARE 1ST BYTE           68400013
         L     RG,0(RG,RJ)         INPUT UNIT'S DCB ADDR                68500013
         MVC   1(3,RD),DCBIOBAD+1  STORE IT'S IOB ADDR IN NEXT 3 BYTES  68600013
*                                    IN PPIWKARE TABLE                  68700013
         L     RF,DCBIOBAD         IOB ADDR                             68800013
         EXCP  (RF)                READ FORWARD. PRIME 1 INPUT BLOCK    68900013
         LA    RD,4(0,RD)          UPDATE PPIWKARE PTR                  69000013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE PTR                69100013
         BCT   RH,RGBPR230         DECR MERGE ORDER BY 1. GO BACK TO    69200013
*                                    PRIME ANOTHER INPUT BUFFER         69300013
         SPACE 2                                                        69400013
*AT THIS POINT M INPUT BUFFERS HAVE BEEN PRIMED. ISSUE WAITS ON EACH    69500013
*   BUFFER                                                              69600013
         SPACE 1                                                        69700013
         LH    RE,PPIMRGMX         M                                    69800013
         L     RI,PPISBLCT         TABLE OF BLOCK CTRS PTR              69900013
         LA    RJ,TFCNT            PTR  TO TABLE OF FILE CTRS           70000013
         LA    RD,PPIWKARE         PTR TO PPIWKARE TABLE                70100013
RGBPR245 L     RF,0(0,RD)          ADDR OF IOB WE ARE WORKING WITH      70200013
         L     RG,DCBPTR           LOAD DCB ADDR                 A26439 70250019
         L     RB,ECBPTR           ADDR OF THAT IOB'S ECB               70300013
         WAIT  1,ECB=(1)           ISSUE A WAIT ON THE BUFFER(IN ORDER  70400013
*                                    OF PRIMING)                        70500013
         BAL   RH,RGBEE100         BR TO ERROR CHECK RTN                70600013
RGBBCCV  BC    0,RGBPR280          A.P. WILL CHANGE TO A BR FOR V.L RCD 70700013
         L     RP,START                                                 70800013
         MVI   4(RP),X'00'         TURN OFF SILI BIT FOR F.L. RCDS      70900013
RGBPR280 SR    RO,RO                                                    71000013
         IC    RO,0(RD)            INCR OF UNIT WE ARE WORKG WITH(FROM  71100013
*                                    PPIWKARE TABLE)                    71200013
RGBPREOS TM    2(RC),X'07'         IS IT EOS ON COMPLETED READ          71300013
         BO    RGBPR260            BR ON EOS BUFFER                     71400013
         SPACE 2                                                        71500013
*CHECK UNIT FOR AN ALTERNATE BUFFER                                     71600013
         SPACE 1                                                        71700013
         L     RG,DCBPTR           ADDR OF THE IOB'S DCB                71800013
         CLI   DCBBUFNO,X'02'      CHECK DCB FOR 2 BUFFERS(1 IS AN ALT) 71900013
         BE    RGBPR270            BR IF IT HAS AN ALT BFR              72000013
RGBPR250 MVC   2(2,RJ),PPISRTBL    SET UNIT'S TABLE OF FILE COUNTERS TO 72100013
*                                    SORT BLKG=B                        72200013
RGBBRVAR LA    RC,4(0,RC)          F.L- BYPASS EOS INDICATOR            72300013
*                                    V.L- BYPASS EOS & BCC. A.P. WILL   72400013
*                                    OVLAY THE 4 TO AN 8 DISPLACEMENT.  72500013
         STC   RO,0(0,RJ)          STORE INCR IN HI BYTE OF FILE CTR    72600013
         LA    RJ,4(0,RJ)          UPDATE FILE PTR                      72700013
         ST    RB,0(RO,RI)         STORE BLOCK COUNT IN TABLE OF BLOCK  72800013
*                                    CTR FOR THE DEBLOCK RTN.           72900013
         ST    RC,IERDGB2D         SAVE STRTG ADDR OF INPUT BUFFER JUST 73000013
*                                    READ IN.                           73100013
         MVC   1(3,RD),IERDGB2D+1  STORE IN PPIWKARE TABLE NEXT TO INCR 73200013
*                                    FOR MERGE NETWORK                  73300013
         LA    RD,4(0,RD)          UPDATE PPIWKARE PTR                  73400013
RGBPRLP  BCT   RE,RGBPR245         DECR MERGE ORDER,LOOP TO PROCESS     73500013
*                                    NEXT UNIT'S PRIMARY BUFFER.        73600013
         SPACE 2                                                        73700013
*AT THIS POINT M INPUT BUFFERS ARE PRIMED. THEY HAVE BEEN CHECKED FOR   73800013
*   ERRORS. READS ON ALL THE ALTERNATE BUFFERS HAVE BEEN STARTED & THE  73900013
*   IOBS HAVE BEEN UPDATED TO POINT TO THE ALT CCW. THE WAITS WILL BE   74000013
*   ISSUED AT RUN TIME.                                                 74100013
         SPACE 1                                                        74200013
         MVC   KMRGMX(2),PPIMRGMX                                       74300013
         SPACE 2                                                        74400013
*INTERFACE WITH BUFFER TABLE ROUTINE TO BUILD TABLE OF INPUT BUFFER     74500013
*   ADDRESSES(1ST RCD ADDR IN EACH BUFFER FOR NETWORK)                  74600013
         SPACE 1                                                        74700013
         L     RL,PPIDEB2+4                                             74800013
         BR    RL                  BUILD INPUT BUFFER ADDR. TABLE       74900018
         SPACE 2                                                        75000013
*END OF SEQUENCE ROUTINE AT PRIMING TIME. MOVE INCR OF EOS UNIT INTO    75100013
*   INCREMENT TABLE AND UPDATE EOS COUNTER.                             75200013
         SPACE 1                                                        75300013
RGBPR260 L     RP,AEOSPR           PTR TO TABLE OF INCREMENTS           75400013
         MVC   0(1,RP),0(RD)       MOVE INCR OF EOS UNIT INTO TABLE     75500013
*                                    THIS TABLE IS FOR RUN TIME TO TELL 75600013
*                                    WHICH UNITS HIT EOS AT PRIME TIME. 75700013
         LA    RP,1(0,RP)          UPDATE TABLE PTR                     75800013
         ST    RP,AEOSPR           STORE UPDATED PTR                    75900013
         SR    RP,RP                                                    76000013
         IC    RP,WEOSCNT                                               76100013
         LA    RP,1(0,RP)          UPDATE COUNT OF NO. OF EOS UNITS     76200013
         STC   RP,WEOSCNT          RESTORE UPDATED COUNTER              76300013
         B     RGBPR250            CHECK SORT BLOCKING                  76400018
         SPACE 2                                                        76500013
*PRIME ALTERNATE BUFFER ROUTINE. SWITCH THE ALTERNATE CCW WITH THE      76600013
*   PRIME CCW AND ISSUE A READ ON THE IOB(ALT CCW ADDR NOW IN IOB)      76700013
         SPACE 1                                                        76800013
RGBPR270 LR    RA,RO               INCR OF UNIT WE ARE WORKING WITH     76900013
         STM   RA,RC,KSAVE                                              77000013
         L     RB,ECBPTR                                                77100013
         L     RP,4(0,RB)          ALT CCW ADDR                         77200013
         MVC   5(3,RB),START+1     MOVE PRIMARY CCW ADDR INTO ALT CCW   77300013
*                                    LOCATION(4 BYTES AFTER ECB)        77400013
         ST    RP,START            STORE ALT CCW ADDR AS NEW PRIMARY    77500013
*                                    CCW ADDR IN THE IOB.               77600013
         EXCP  (RF)                START A READ ON THE ALT. BFR         77700013
         LM    RA,RC,KSAVE         RA=INCR,RB=BLOCK CNT FOR F.L RCDS OR 77800013
*                                    BCC-4 EOS BYTES FOR V.L. RCDS,RC=  77900013
*                                    STRTG ADDR OF PREVIOUS PRMRY BFR.  78000013
         LR    RO,RA               INCR OF THIS INPUT UNIT              78100013
         LH    RP,PPISRTBL         B                                    78200013
         SLL   RP,1                2XB                                  78300013
         STH   RP,2(0,RJ)          STORE IN TABLE OF FILE CTRS FOR      78400013
         B     RGBBRVAR              THIS UNIT                          78500013
         SPACE 2                                                        78600013
*LIST OF ADCONS:                                                        78700013
         SPACE 1                                                        78800013
AEOSPR   DC    A(TINCR)            TABLE OF INCREMENTS PTR              78900013
ADCONE28 DC    F'0'                SYNAD E28 ADDR. LOADED BY A.P.       79000013
         SPACE 2                                                        79100013
*LIST OF WORK AREAS/TABLES:                                             79200013
         SPACE 1                                                        79300013
TINCR    DC    4F'0'               TABLE OF INCREMENTS(EOS UNITS AT     79400013
*                                    PRIME TIME                         79500013
TFCNT    DC    16F'0'              TABLE OF FILE CTRS                   79600013
WSENSE0  DC    X'00'               CONTAINS SENSE BYTE 0 ON UNIT CHECK  79700013
WEOSCNT  DC    X'00'               CTR FOR NO. OF UNITS HITTING EOS     79800013
         SPACE 2                                                        79900013
*LIST OF CONSTANTS:                                                     80000013
         SPACE 1                                                        80100013
KSAVE    DC    7F'0'               WILL HAVE RD-RJ ON EVERY INPUT EOF   80200013
*                                    AND RC-RH DURING RUN TIME          80300013
KSAVEB   DC    1F'0'               BLOCK CNT OF BFR JUST READ IN-FILLED 80400013
*                                    DURING FLOATG BFR RTN              80500013
KNNINE   DC    X'FFFF'             FFFF                                 80600013
KMRGMX   DC    X'0000'             NO. OF INPUT UNITS ENTERING 1ST PASS 80700013
KFOUR    DC    X'0004'             CONSTANT OF FOUR                     80800018
KOUTINCR DC    X'00'               TEMP. STORAGE                        80900018
         EJECT                                                          81000013
         DS    0F                                                       81100013
IERIOB   DSECT ,                   DUMMY IOB- SEE 14.90.1.4             81200013
FLG1     DC    X'00'               IOB EXPANSION                        81300018
FLG2     DC    X'00'               IOB EXPANSION                        81400018
SENSE    DC    AL2(0)              IOB EXPANSION                        81500018
ECBPTR   DC    AL4(0)              IOB EXPANSION                        81600018
CSW      DC    AL4(0)              IOB EXPANSION                        81700018
         DC    AL4(0)              IOB EXPANSION                        81800018
START    DC    AL4(0)              IOB EXPANSION                        81900018
DCBPTR   DC    AL4(0)              IOB EXPANSION                        82000018
RESTART  DC    AL4(0)              IOB EXPANSION                        82100018
INCAMT   DC    AL2(0)              IOB EXPANSION                        82200018
ERRCNTS  DC    AL2(0)              IOB EXPANSION                        82300018
*                                                                       82400018
*                                                                       82500018
IERAP22  DSECT                                                          82600018
         DC    33F'0'              IOB EXPANSION                        82700018
WRDOPT   DC    F'0'                IOB EXPANSION                        82800018
         DC    11F'0'              IOB EXPANSION                        82900018
         EJECT                                                          83000013
AGLAMB   DSECT ,                   PHASE 2 DUMMY MESSAGE MODULE         83100013
       COPY  AMBMAIN                                                    83200013
         EJECT                                                          83300013
         SMPPI                                                          83400013
         EJECT                                                          83500013
         DCBD  DSORG=PS                                                 83600013
         END                                                            83700013
