         TITLE '      IERAGM - OS/360 SORT/MERGE - 360S-SM023 05/26/66' 00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERAGM ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 3 ASSIGNMENT MODULE. READ FWD         00700013
*   THE FUNCTION OF THIS MODULE IS TO CHECK IF USER READ ERROR EXIT E38 00800013
*   SYNAD IS ACTIVATED AND OVERLAYS THE READ FORWARD RUNNING MODULE,    00900013
*   IERRGM. IT ALSO CHECKS WHETHER FIXED OR VARIABLE LENGTH RECORDS AND 01000013
*   OVERLAYS IERRGM.                                                    01100013
         SPACE 1                                                        01200013
*   THIS MODULE ALLOCATES SPACE IN GENERATED CORE AND BUILDS THE READ   01300013
*   FORWARD CCWS AND THE TABLE OF INPUT BLOCK COUNTERS. ENOUGH SPACE IS 01400013
*   RESERVED FOR 2M CCWS EVEN THOUGH THERE MAY NOT BE FULL OVERLAP, AND 01500013
*   N+1(N=TOTAL NUMBER OF WORK UNITS) INPUT BLOCKS(MAXIMUM CASE).       01600013
         SPACE 1                                                        01700013
*   AFTER FINDING ALL THE INPUT UNITS FROM THE TAPE TABLE, M INPUT      01800013
*   BUFFERS ARE PRIMED AND READS ISSUED ON ANY REMAINING BUFFERS.       01900013
         SPACE 1                                                        02000013
*   TWO TABLES ARE CREATED. THE TABLE OF FILE COUNTERS WHICH HAS EACH   02100013
*   INPUT UNIT'S INCREMENT AND THE NUMBER OF BUFFERS ATTACHED TO IT,    02200013
*   AND THE PRIMING TABLE WHICH HAS EACH INPUT UNIT'S INCREMENT WITH    02300013
*   THE STARTING ADDRESS OF ITS PRIMARY BUFFER.                         02400013
         SPACE 1                                                        02500013
*   THIS MODULE ALSO CHECKS FOR READ ERRORS. IF USER EXIT E38 SYNAD IS  02600013
*   NOT ACTIVATED IT WILL ABORT THROUGH SORT SYSTEM CONTROL. IF IT IS   02700013
*   ACTIVE, THE USER MAY TRY TO FIX THE ERROR AFTER IOS HAS TRIED TO    02800013
*   DO SO.                                                              02900013
         SPACE 2                                                        03000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               03100013
         SPACE 1                                                        03200013
*   NONE                                                                03300013
         SPACE 2                                                        03400013
*LIST OF MACROS USED BY MODULE:                                         03500013
         SPACE 1                                                        03600013
*   EXCP                                                                03700013
*   SMPPI                                                               03800013
*   DCBD                                                                03900013
*   WAIT                                                                04000013
         SPACE 2                                                        04100013
*ENTRY POINTS:                                                          04200013
         SPACE 1                                                        04300013
*   FROM LOAD ROUTINE              ENTRY FROM:IERRC9                    04400013
*                                    CALLING SEQUENCE-                  04500013
*                                      LOAD EP=IERAGM,DCB=SORTLIB       04600013
*                                      LR   RP,RA                       04700013
*                                      BALR RO,RP                       04800013
*   FROM E38 SYNAD                 ENTRY FROM:E38 SYNAD                 04900013
*                                    CALLING SEQUENCE-                  05000013
*                                      BR   RO         RETURN           05100013
         SPACE 2                                                        05200013
*INPUT: - PPI FIELDS REFERENCED                                         05300013
         SPACE 1                                                        05400013
*   PPIBDSVA   PPIMRGMX   PPISRTBL   PPIWKARE                           05500013
*   PPILAB03   PPIRCDCT   PPISTDCB                                      05600013
*   PPIMODEX   PPIRCDL2   PPITPTBL                                      05700013
         SPACE 2                                                        05800013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            05900013
         SPACE 1                                                        06000013
*   PPILAB01   PPISBLCT   PPISW1                                        06100013
*   PPILAB02   PPISPGN1                                                 06200013
*   PPILAB03   PPISVARE                                                 06300013
         SPACE 2                                                        06400013
*EXTERNAL ROUTINES:                                                     06500013
         SPACE 1                                                        06600013
*   NONE                                                                06700013
         SPACE 2                                                        06800013
*EXTERNAL PARAMETERS:                                                   06900013
         SPACE 1                                                        07000013
*   SEE REGISTERS                                                       07100013
         SPACE 2                                                        07200013
*EXITS-NORMAL:                                                          07300013
         SPACE 1                                                        07400013
*   TO LOAD ROUTINE                EXIT TO:IERRC9                       07500013
*                                    CALLING SEQUENCE-                  07600013
*                                      BR   RO         RETURN           07700013
*   TO PH3 HOUSEKEEPING            EXIT TO:IERRPG                       07800013
*                                    CALLING SEQUENCE-                  07900013
*                                      L    RL,PPIWRT+4                 08000013
*                                      BCR  8,RL       0 INPUT W/O E35  08100013
*                                      B    4(0,RL)    0 INPUT W/E35    08200013
         SPACE 2                                                        08300013
*EXITS-ERROR:                                                           08400013
         SPACE 1                                                        08500013
*   TO E38 SYNAD(IF ACTIVE)        EXIT TO:E38 SYNAD                    08600013
*                                    CALLING SEQUENCE-                  08700013
*                                      L    RP,ADCONE38                 08800013
*                                      BALR RO,RP      READ ERROR       08900013
*   TO SSC                         EXIT TO:SSC VIA                      09000013
*                                      L    RP,PPIADSSC                 09100013
*                                      B    16(0,RP)   ABORT            09200013
         SPACE 2                                                        09300013
*TABLES/WORK AREAS:                                                     09400013
         SPACE 1                                                        09500013
*   WORK AREAS ARE IN PPI                                               09600013
         SPACE 2                                                        09700013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   09800013
         SPACE 2                                                        09900013
*NOTES: THIS MODULE WILL EXECUTE FOR F.L BALANCED OR OSCILLATING SORT   10000013
*   REQUIRING PH1 TO PH3 SITUATION TO ELIMINATE A COPY PH2 PASS.        10100013
         EJECT                                                          10200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            10300013
         SPACE 1                                                        10400013
RA       EQU   0                   CONTENTS IN-N/A                      10500013
*                                  USE-WORK REGISTER                    10600013
*                                     -READ TO E38 SYNAD(ADDR OF IOB    10700013
*                                    W/INCR TO CCW IN HI ORDER BYTE)    10800013
*                                  CONTENTS OUT-N/A                     10900013
RB       EQU   1                   CONTENTS IN-N/A                      11000013
*                                  USE-WORK REGISTER                    11100013
*                                  CONTENTS OUT-N/A                     11200013
RC       EQU   2                   CONTENTS IN-N/A                      11300013
*                                  USE-WORK REGISTER                    11400013
*                                  CONTENTS OUT-N/A                     11500013
RD       EQU   3                   CONTENTS IN-N/A                      11600013
*                                  USE-WORK REGISTER                    11700013
*                                  CONTENTS OUT-N/A                     11800013
RE       EQU   4                   CONTENTS IN-N/A                      11900013
*                                  USE-WORK REGISTER                    12000013
*                                  CONTENTS OUT-N/A                     12100013
RF       EQU   5                   CONTENTS IN-N/A                      12200013
*                                  USE-IOB DSECT BASE REGISTER          12300013
*                                     -WORK REGISTER                    12400013
*                                  CONTENTS OUT-N/A                     12500013
RG       EQU   6                   CONTENTS IN-N/A                      12600013
*                                  USE-DCB DSECT BASE REGISTER          12700013
*                                     -WORK REGISTER                    12800013
*                                  CONTENTS OUT-N/A                     12900013
RH       EQU   7                   CONTENTS IN-N/A                      13000013
*                                  USE-WORK REGISTER                    13100013
*                                  CONTENTS OUT-N/A                     13200013
RI       EQU   8                   CONTENTS IN-N/A                      13300013
*                                  USE-WORK REGISTER                    13400013
*                                  CONTENTS OUT-N/A                     13500013
RJ       EQU   9                   CONTENTS IN-N/A                      13600013
*                                  USE-WORK REGISTER                    13700013
*                                  CONTENTS OUT-N/A                     13800013
RK       EQU   10                  CONTENTS IN-N/A                      13900013
*                                  USE-IERRGM DSECT BASE REGISTER       14000013
*                                     -WORK REGISTER                    14100013
*                                  CONTENTS OUT-N/A                     14200013
RL       EQU   11                  CONTENTS IN-N/A                      14300013
*                                  USE-MODULE BASE REGISTER,ENTRY PT TO 14400013
*                                    EOJ/OPEN OUTPUT FILE RTN           14500013
*                                  CONTENTS OUT-N/A                     14600013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   14700013
*                                  USE-NOT USED                         14800013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   14900013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              15000013
*                                  USE-PPI REFERENCES,REG SAVE AREA     15100013
*                                  CONTENTS OUT-ADDR OF PPI             15200013
RO       EQU   14                  CONTENTS IN-RETURN ADDR OF IERRC9    15300013
*                                  USE-READ TO E38 SYNAD(THIS MODULE    15400013
*                                    RETURN ADDR)                       15500013
*                                  CONTENTS OUT-RETURN ADDR OF IERRC9   15600013
RP       EQU   15                  CONTENTS IN-THIS MODULE ENTRY PT     15700013
*                                  USE-READ TO E38 SYNAD(ADDR OF E38)   15800013
*                                     -READ TO SSC(ADDR OF SSC)         15900013
*                                     -WORK REGISTER                    16000013
*                                  CONTENTS OUT-N/A                     16100013
         SPACE 2                                                        16200013
*START OF MODULE CODE PROPER:                                           16300013
         SPACE 2                                                        16400013
IERAGM   CSECT                                                          16500013
*                                                                A31855 16550021
         USING IERAP33,RB                                               16600013
         USING *,RL                                                     16700013
         USING IERRCA,RN                                                16800013
         USING IERRGM,RK           DSECT BASE REGISTER                  16900013
         USING IERIOB,RF                                                17000013
         USING IHADCB,RG                                                17100013
IERMGD   LR    RL,RP                                                    17200013
         L     RK,PPIRCDCT         CHECK FOR ZERO                       17300013
         LTR   RK,RK                                                    17400013
         BCR   8,RO                  FILE                               17500013
*                                                                       17600013
         ST    RO,KSAVC9           SAVE RETURN REGISTER                 17700013
         L     RK,PPIRD+4          READ ROUTINE                         17800013
         SR    RD,RD                                                    17900013
         SPACE 1                                                        18000013
* ERROR OPTION OVERLAYS                                                 18100013
         SPACE 1                                                        18200013
         L     RB,PPIOPEN+4        SET UP ERROR OPTION AND              18300013
         CLC   WRDOPT+1(3),KCCW+1       DOES USER WISH ACTIVE E38       18400013
         BE    AGMAUTO                   IF NOT,BYPASS SETTINGS         18500013
         MVC   ADCONE38+1(3),WRDOPT+1    IF SO, SET ADCON FOR R.P.      18600013
         OI    PPISW1+7,X'01'      SET ACCEPT SKIP SWITCH               18700013
         CLI   WRDOPT,X'40'             TEST OPTION BYTE                18800013
         BL    AGMTERMX                  LESS THAN 40 = TERMINATE       18900013
         BE    AGDST001                  EQUAL, NO MORE SKIP SETUP      19000013
         MVC   RGDACCPT(4),RGDACCBR      MODIFY ACCEPT ADDRESSES        19100013
         MVC   AGDACCPT(4),AGDACCBR       IN RP & AP                    19200013
AGMRAN   B     AGDST001                  USED AS CONSTANT 47FO ALSO     19300013
         SPACE 2                                                        19400013
AGMAUTO  MVI   RGMTERM+1,X'F0'          SET TERMINATE IMMEDIATELY R.P.  19500013
         MVI   AGMTERM+1,X'F0'          SET TERMINATE IMMEDIATELY A.P.  19600013
AGMTERMX NI    PPISW1+7,X'FE'      TURN OFF SKIP ACCEPT SWITCH          19700013
         DROP  RB                                                       19800013
*                                                                       19900013
* CALCULATE AND ALLOCATE SPACE FOR CCW'S AND BLOCK COUNT TABLE          20000013
         SPACE 1                                                        20100013
AGDST001 NI    PPISPGN1+3,X'F8'    ALIGN TO NEXT LOWEST DOUBLE WD BNDRY 20200013
         L     RB,PPISPGN1         START OF GEN. CORE                   20300013
         LH    RC,PPIMRGMX         MERGE ORDER                          20400013
         LR    RA,RC                                                    20500013
         SLL   RC,4                SIZE OF CCW'S                        20600013
         SR    RB,RC                                                    20700013
         SPACE 2                                                        20800013
*THIS EOUTINE WRITES DIAGNOSTIC MSG 'I/P CCW ADDR XXXX'                 20900013
         SPACE 1                                                        21000013
         TM    PPISW1+6,X'01'      TEST IF MESSAGE BIT IS ON            21100013
         BC    8,AGMTEST           BR IF NO                             21200013
         STM   RO,RE,AGMSTM        SAVE REGS                            21300013
         LR    RA,RB               ADDR OF 1ST CCW IN GEN CORE          21400013
         SPACE 1                                                        21500013
         USING AGMAMB,RE           BASE REG FOR MESSAGE MODULE          21600013
         SPACE 1                                                        21700013
         L     RE,PPIAMB+4         BASE REG FOR MESSAGE MODULE          21800013
         L     RP,PPICONV+4        ADDR OF CONVERT ROUTINE              21900013
         BAL   RO,4(0,RP)                                               22000013
         MVC   DMSG945A(8),0(RB)   CONVERTED DATA IN RB PTR             22100013
         LM    RA,RB,DMSG945X      ADDR AND LENGTH OF MESSAGE           22200013
         L     RP,PPIADSSC         ADDR OF SSC                          22300013
         BAL   RO,12(0,RP)         BR TO PRINT MESSAGE                  22400013
         LM    RO,RE,AGMSTM        RESTORE REGISTERS                    22500013
         SPACE 1                                                        22600013
*END OF DIAGNOSTIC ROUTINE                                              22700013
         SPACE 1                                                        22800013
AGMTEST  SLL   RA,1                EQUALS 2M                            22900013
         STC   RA,RGDK2M+1                                              23000013
         IC    RD,PPILAB03         IF NO. BUFFERS.G.(2*M), RESET NO.    23100013
         CLR   RD,RA                 OF BUFFERS TO 2*M.                 23200013
         BC    12,AGDST010                                              23300013
         STC   RA,PPILAB03                                              23400013
AGDST010 IC    RD,PPIBDSVA         TOTAL WORK UNITS                     23500013
         LA    RD,1(0,RD)                                               23600013
         SLL   RD,2                BLOCK COUNTERS AREA IN GENERATED     23700013
         LR    RE,RB                 CORE                               23800013
         SR    RB,RD                                                    23900013
         ST    RB,PPISPGN1         SAVE UPDATED                         24000013
         ST    RB,PPISBLCT           ADDRESS                            24100013
         TM    PPISW1,X'40'                                             24200013
         BC    1,AGDVR020                                               24300013
         SPACE 2                                                        24400013
*BUILD 2M CCWS IN GEN CORE. SET SILI BIT TO 0 FOR F.L. RCDS AND TO A 1  24500013
*   FOR V.L. RCDS.                                                      24600013
         SPACE 1                                                        24700013
         SR    RD,RD                 ALL FLAG BITS OFF FOR FIX. FORMAT  24800013
AGDCCWGN MVC   KCCW+6(2),PPILAB03+2    COUNT                            24900013
         MVC   KBLKCHR+2(2),PPILAB03+2                                  25000013
         STC   RD,KCCW+4               FLAGS                            25100013
         LR    RD,RE                 GENERATE 2*M CCW'S                 25200013
AGDCCWLP MVC   0(8,RE),KCCW                                             25300013
         LA    RE,8(0,RE)            UPDATE GEN. AREA POINTER BY SIZE   25400013
         BCT   RA,AGDCCWLP             OF A CCW.                        25500013
*                                                                       25600013
         LH    RC,PPIMRGMX           MERGE ORDER                        25700013
         L     RB,PPISTDCB                                              25800013
         LA    RE,PPITPTBL         TAPE TABLE POINTER                   25900013
         LA    RJ,PPIWKARE           SORT WORK AREA                     26000013
AGDIN030 TM    0(RE),X'80'           SEARCH TAPE TABLE FOR              26100013
         BC    1,AGDIN040              INPUT FILES                      26200013
         LA    RE,2(0,RE)                                               26300013
         BC    15,AGDIN030                                              26400013
*                                                                       26500013
*                                                                       26600013
* OVERLAYS FOR VARIABLE RECORD FORMAT                                   26700013
         SPACE 1                                                        26800013
AGDVR020 LA    RD,32                 SLI FLAG ON FOR VAR. FORMAT        26900013
         MVI   AGDBRVR+1,X'F0'     VARIABLE LENGTH RCD. OVERLAYS        27000013
         MVI   RGDBRVR+1,X'F0'       IN ASSG. AND RUNNING PGM.          27100013
         MVI   AGDVRDSP+3,X'08'    FOR THE MERGE RCD ADDR.-BYPASS BCC   27200013
         MVI   RGDRTRNV+3,X'08'      AND EOS INDICATOR                  27300013
         MVI   RGDEOSB1+3,X'06'                                         27400013
         BC    15,AGDCCWGN                                              27500013
         SPACE 2                                                        27600013
*BUILD PPIWKARE TABLE. INCR OF INPUT UNIT IN 1ST BYTE, IOB ADDR IN NEXT 27700013
*   3 BYTES. DO THIS FOR M INPUT UNITS. UPDATE EACH INPUT DCB TO 1 BFR. 27800013
         SPACE 1                                                        27900013
AGDIN040 SR    RG,RG                                                    28000013
         IC    RG,1(0,RE)          INCR                                 28100013
         STC   RG,0(0,RJ)          SAVE INCR                            28200013
         L     RG,0(RG,RB)                                              28300013
         MVI   DCBBUFNO,X'01'      BUFNO IN DCB                         28400013
         MVC   1(3,RJ),DCBIOBAD+1  SAVE IOB ADDR. IN SORT WORK AREA     28500013
         LA    RJ,4(0,RJ)            FOR LATER USE- TO ATTACH CCW'S     28600013
*                                    AND TO PRIME THE BUFFERS.          28700013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE POINTER            28800013
         BCT   RC,AGDIN030                                              28900013
*                                                                       29000013
*ATTACH THE CCW'S AND START PRIMING THE BUFFERS                         29100013
         LA    RE,PPIWKARE         SORT WORK AREA                       29200013
         L     RG,PPILAB02         INPUT BUFFER TABLE ADDRESS           29300013
         LH    RH,PPIMRGMX                                              29400013
AGDIN050 L     RF,0(0,RE)          RF=IOB BASE REG. RE=DTR TO PPIWKARE  29500013
*                                    TABLE W/ADDR OF IOB IN IT.         29600013
         ST    RD,START            RD=PTR TO CCWS IN GEN CORE. INSERT   29700013
*                                    ADDR OF A CCW IN IOB               29800013
         L     RB,0(0,RG)          STARTG ADDR OF INPUT BFR FROM INPUT  29900013
*                                    BUFFER ADDR TABLE.                 30000013
         ST    RB,PPISVARE         MOVE TO WORK AREA TO REMOVE 1ST BYTE 30100013
         MVC   1(3,RD),PPISVARE+1  STORE STRTG ADDR OF BFR IN A CCW     30200013
         MVI   4(RD),X'20'         TURN SILI BIT ON IN CASE SHORT BLOCK 30300013
         EXCP  (RF)                READ FORWARD                         30400013
         LA    RD,8(0,RD)                                               30500013
         L     RP,ECBPTR           SAVE ALTERNATE CCW                   30600013
         ST    RD,4(0,RP)            ADDR.                              30700013
         LA    RD,8(0,RD)          UPDATE CCW, BUFFER,                  30800013
         LA    RG,4(0,RG)            AND IOB POINTERS                   30900013
         LA    RE,4(0,RE)                                               31000013
         BCT   RH,AGDIN050                                              31100013
         SPACE 2                                                        31200013
*M INPUT BUFFERS ARE PRIMED. ALTRNATE CCWS HAVE BEEN ASSIGNED THE IOBS  31300013
         SPACE 1                                                        31400013
         LA    RE,PPIWKARE         IOBS IN SORT WORK AREA               31500013
         LA    RI,TFCNT            FILE COUNTERS                        31600013
         IC    RH,PPILAB03         NO.OF INPUT BUFFERS MINUS MERGE      31700013
         STC   RH,KTOTAL                                                31800013
         SH    RH,PPIMRGMX           ORDER = NO. OF ALTERNATE BUFFERS   31900013
         BC    8,AGDNOVLP          NO OVERLAP                           32000013
         STH   RH,PPILAB01+12                                           32100013
*PRIME ALTERNATE BUFFERS                                                32200013
         LR    RD,RH               LOAD NO. OF ALT BFRS CTR             32300013
         LH    RA,PPISRTBL         FILE COUNTER                         32400013
         SLL   RA,1                  ENTRY IS 2*SORTBLKING              32500013
         ST    RA,PPILAB01+4                                            32600013
AGDOVLP  ST    RG,PPILAB01+8       SAVE BUFFER POINTER. PTS TO NEXT     32700013
*                                    AVAILABLE BFR ADDR IN THE TABLE.   32800013
         BAL   RJ,AGDLK060         WAIT-ADDR.IN SORT WORK AREA-BLCNT    32900013
         L     RC,PPILAB01+8       BUFFER POINTER                       33000013
         ST    RE,PPILAB01+16                                           33100013
         L     RG,DCBPTR           DCB ADDR.                            33200013
         L     RE,START            ATTACH THE ALTERNATE BUFFER TO       33300013
         L     RO,ECBPTR                                                33400013
         MVC   START(4),4(RO)        THE FILE                           33500013
         ST    RE,4(0,RO)                                               33600013
         L     RE,START            STORE BUFFER ADDR. IN                33700013
         L     RO,0(0,RC)            THE CCW (RD.BKWDS)                 33800013
         ST    RO,PPISVARE         STORE STRTG BFR ADDR OF ACT BFR      33900013
         MVC   1(3,RE),PPISVARE+1  STORE JUST THE STRTG ADDR IN THE CCW 34000013
         MVI   DCBBUFNO,X'02'      UPDATE BUFNO IN DCB TO 2 BFRS        34100013
         EXCP  (RF)                READ FORWARD ON ALT. BFR             34200013
         L     RE,PPILAB01+16      PREVIOUS ENTRY ADDR OF PPIWKARE TABL 34300013
         L     RG,PPILAB01+8       ADDR OF BUFFER(JUST USED AS ALT) IN  34400013
*                                    BUFFER ADDR TABLE                  34500013
         LA    RG,4(0,RG)          UP BUFFER PTR TO NEXT FREE BFR ADDR  34600013
AGDOVEND LA    RE,4(0,RE)          UP PPIWKARE PTR TO NEXT(IOB) ENTRY   34700013
         BCT   RD,AGDOVLP          DECR NO OF ALT BFRS CTR. BR IF MORE  34800013
         SPACE 1                                                        34900013
         ST    RG,PPILAB02         SAVE BUFFER POINTER FOR R.P.'S USE   35000013
         CLC   PPILAB01+12(2),PPIMRGMX                                  35100013
         BC    8,AGDRTN            FULL OVERLAP-ALL WAITS ISSUED        35200013
         SPACE 1                                                        35300013
*PARTIAL OVERLAP.AT THIS PT M INPUT BUFFERS HAVE BEEN PRIMED. ALSO,     35400013
*   READS HAVE BEEN ISSUED ON ALL ALTERNATE BUFFERS. WAITS HAVE BEEN    35500013
*   ISSUED ON AS MANY PRIMARY BFRS AS THERE ARE ALTERNATE BFRS SO NOW   35600013
*   WAITS MUST BE ISSUED ON THE REST OF THE PRIMARY BUFFERS(THESE BE-   35700013
*   LONG TO THE SINGLE BUFFERED FILES).                                 35800013
         SPACE 1                                                        35900013
         LH    RD,PPIMRGMX         NEED TO ISSUE WAITS AND PASS ADDRS.  36000013
         SH    RD,PPILAB01+12        IN SORT WORK AREA ON THE FILES     36100013
         BC    15,AGDNOVLP+8         WITH NO ALTERNATE BUFFERS.         36200013
*                                                                       36300013
*                                                                       36400013
AGDNOVLP LH    RD,PPIMRGMX                                              36500013
         ST    RG,PPILAB02         SAVE BUFFER POINTER FOR R.P.'S USE   36600013
         MVC   PPILAB01+6(2),PPISRTBL  FILE COUNTER ENTRY IS SORTBLK.   36700013
         BAL   RJ,AGDLK060         WAIT ON EACH FILE AND PASS INITIAL   36800013
         LA    RE,4(0,RE)          UPDATE IOB POINTER                   36900013
         BCT   RD,AGDLP070           ADDR. OF RCDS. TO MERGE IN         37000013
*                                    SORT WORK AREA. SET UP BLCNT       37100013
AGDRTN   L     RO,KSAVC9           RETURN TO IERRC9                     37200013
         MVC   KMRGMX(2),PPIMRGMX                                       37300013
         MVC   KMRGMX1(2),PPIMRGMX                                      37400013
         BR    RO                                                       37500013
*                                                                       37600013
*                                                                       37700013
* WAIT ON M BUFFERS AND ERROR CHECK                                     37800013
         SPACE 1                                                        37900013
AGDLK060 L     RG,PPISBLCT         TABLE OF BLOCK COUNTERS FOR DEBLOCK  38000013
AGDLP070 L     RF,0(0,RE)          IOB ADDRESS                          38100013
         L     RB,ECBPTR                                                38200013
         WAIT  1,ECB=(1)           WAIT ON FILE                         38300013
         NI    CSW+5,X'BF'         TURN OFF INCORRECT LENGTH BIT IF ON  38400013
*EOF-ERROR CHECK                                                        38500013
*                                                                       38600013
AGDEE100 TM    CSW+4,X'03'         UNIT CHECK/UNIT EXCEPTION BITS -FOR  38700013
         BC    5,AGSTORRF          SAVE IOB ADDR IN CASE NO SYNAD RTN   38800013
*                                    NO NULL FILES OPENED IN IERAGH.    38900013
         TM    CSW+5,X'08'         CHANNEL DATA CHECK -FOR ERROR        39000013
         BC    1,AGSTORRF          SAVE IOB ADDR IN CASE NO SYNAD RTN   39100013
AGDEE110 L     RB,KBLKCHR          COUNT OF A FULL BFR FROM LAB03       39200013
         SH    RB,CSW+6            MINUS NO. OF BYTES NOT READ IN       39300013
*                                    EQUALS NO. OF BYTES READ IN        39400013
         L     RC,START            ADDR OF THIS IOB'S CCW               39500013
         LR    RP,RC               SAVE ADDR                            39600013
         L     RC,0(0,RC)          STARTG ADDR OF THE INPUT BFR         39700013
         SH    RB,KFOUR            ACTUAL NO. OF BYTES JUST FOR         39800013
*                                    THE NO. OF RCDS(4 BYTES=EOS)       39900013
         SPACE 1                                                        40000013
AGDBRVR  BC    0,AGDLP075          A.P. WILL MAKE A BR FOR V.L. RCDS    40100013
         SPACE 2                                                        40200013
*DETERMINE ACTUAL COUNT OF RCDS IN THIS BUFFER AND LOAD RB.             40300013
         SPACE 1                                                        40400013
         MVI   4(RP),X'00'         TURN OFF SILI BIT(DON'T CARE WHETHER 40500013
*                                    SHORT BLOCK AT THIS TIME)          40600013
         SR    RO,RO                                                    40700013
AGDFIX   SH    RB,PPIRCDL2         SUBTR LGTH OF 1 F.L. RCD FROM COUNT  40800013
         LA    RO,1(0,RO)          INCR RCD COUNTER BY ONE              40900013
         CH    RB,PPIRCDL2         COMPARE REMAINING COUNT              41000013
         BC    10,AGDFIX           BR ON EQ OR GTR( MORE RCDS IN BFR)   41100013
         LR    RB,RO               LOAD NO. OF RCDS IN BFR CTR          41200013
         SPACE 1                                                        41300013
*PLACE M STARTING BUFFER ADDRESSES IN PPIWKARE(RE PTR TO PPIWKARE) AND  41400013
*   M BLOCK COUNTS(RG PTR TO BLK CNT TABLE) IN BLK COUNT TABLE AS EACH  41500013
*   BUFFER IS READ IN. INSERT INCR OF UNIT(HI BYTE) AND FILE CTR ENTRY  41600013
*   (2B FOR OVLAP,B FOR NO OVLAP) IN TABLE OF FILE CTRS. RI PTR TO THIS 41700013
*   TABLE.                                                              41800013
         SPACE 1                                                        41900013
AGDLP075 SR    RP,RP                                                    42000013
         IC    RP,0(0,RE)          INCR                                 42100013
         MVC   1(3,RI),PPILAB01+5  READ'S FILE COUNTER ENTRY WITH INCR  42200013
         STC   RP,0(0,RI)            IN HIGH ORDER POSITION.            42300013
         ST    RB,0(RP,RG)         STORE BLOCK COUNTER IN BLCNT TABLE   42400013
         LA    RI,4(0,RI)            VIA INCR FOR DEBLOCK               42500013
AGDVRDSP LA    RC,4(0,RC)          BYPASS EOS ENTRY(THE 4 WILL BE 8 TO  42600013
*                                    BYPASS BCC ALSO FOR V.L. RCDS)     42700013
         ST    RC,0(0,RE)          ADDR OF 1ST RCD IN BFR IN PPIWKARE   42800013
*                                    TABLE FOR MERGE NTWK               42900013
         STC   RP,0(0,RE)          STORE INCR IN HI ORDER BYTE          43000013
         BCR   15,RJ               RETURN TO EITHER OVERLAP OR NO       43100013
*                                    OVERLAP ROUTINE                    43200013
         EJECT                                                          43300013
*READ ERROR HAS OCCURRED                                                43400013
*                                                                       43500013
AGDERROR OI    PPISW1+5,X'80'      TURN ON ERROR BIT IN PPI             43600013
AGMTERM  NOP   AGPRTABT                 TURNED TO B IF IMMEDIATE TERM   43700013
         L     RB,DCBPTR           DCB ADDRESS                          43800013
         ST    RF,KCCW             SET IOB ADDRESS WITH                 43900013
         MVI   KCCW,X'10'            INCREMENT TO CCW ADDRESS IN        44000013
         L     RA,KCCW               THE HIGH ORDER BYTE                44100013
*        CALL  ADCONE38            E38 EXIT                             44200013
         L     RP,ADCONE38  *                                           44300013
         BALR  RO,RP        *                                           44400013
         SPACE 2                                                        44500013
*PRINT IOS READ ERROR MSG BEFORE ABORTING                               44600013
         SPACE 1                                                        44700013
AGPRTABT L     RE,KCCW             ADDR OF IOB WITH ERROR ON IT         44800013
         L     RE,20(0,RE)         ADDR OF IOB'S DCB                    44900013
         L     RE,44(0,RE)         ADDR OF DCB'S DEB                    45000013
         L     RE,32(0,RE)         ADDR OF DEB'S UCB                    45100013
         MVC   PPIRCV(3),13(RE)                                         45200013
         L     RP,PPIADSSC                                              45300013
         BAL   RO,16(0,RP)                                              45400013
*                                                                       45500013
AGDSKIP  OI    FLG1,X'40'          IF ERROR ACCEPTED,RESET ERROR BITS   45600013
         NI    CSW+5,X'F7'           IN THE IOB AND DCB                 45700013
         LR    RP,RG               SAVE REGISTER                        45800013
         L     RG,DCBPTR                                                45900013
         NI    DCBIFLGS,X'3F'                                           46000013
         LR    RG,RP                                                    46100013
         NI    DCBOFLGS,X'44'                                           46200013
AGDACCPT EXCP  (RF)                READ    NEXT BLOCK INTO              46300013
         L     RB,ECBPTR             SAME BUFFER AREA                   46400013
         WAIT  1,ECB=(1)                                                46500013
         B     AGDEE100            BR TO ERROR CHECK THE BUFFER         46600013
AGSTORRF ST    RF,KCCW                                                  46700013
         B     AGDERROR                                                 46800013
AGDACCBR B     AGDEE110                                                 46900013
         SPACE 2                                                        47000013
*LIST OF CONSTANTS USED BY THE MODULE:                                  47100013
         SPACE 1                                                        47200013
KSAVC9   DC    F'0'                                                     47300013
KCCW     DC    X'02000000'                                              47400013
         DC    X'00000000'                                              47500013
AGMSTM   DC    7F'0'               SAVE AREA FOR REGS RO-RE             47600013
         EJECT                                                          47700013
IERRGM   DSECT                                                          47800013
         USING *,RL                                                     47900013
         USING IERRCA,RN                                                48000013
         USING IERIOB,RF                                                48100013
         USING IHADCB,RG                                                48200013
IERDGB   BC    0,IERDGB            DUMMY ENTRY                          48300013
         STM   RC,RH,KSAVE                                              48400013
         ST    RC,IERDGB                                                48500013
         L     RG,PPISTDCB                                              48600013
         L     RG,0(RD,RG)         APPROPRIATE DCB VIA INCR IN RD       48700013
         L     RF,DCBIOBAD         IOB ADDR.                            48800013
         TM    DCBBUFNO,X'02'      BUFNO- CK FOR ALTERNATE BUFFER       48900013
         BC    1,RGDAL020            FOR FILE.                          49000013
         EXCP  (RF)                READ FORWARD                         49100013
         L     RB,ECBPTR                                                49200013
         WAIT  1,ECB=(1)           WAIT ON FILE                         49300013
         SPACE 2                                                        49400013
*RETURN FROM EOF-ERROR CK RTN. RB-ACTUAL COUNT OF RCOS IN THE BUFFER    49500013
*   FOR F.L.,OR ACTUAL NO.OF BYTES IN BUFFER -4(FOR BCC)FOR V.L. RCDS.  49600013
*   RC AND RE CONTAIN STARTING ADDR OF THE BUFFER.                      49700013
         SPACE 1                                                        49800013
RGDLINK  BAL   RH,RGDEE100         EOF-ERROR CK.SUBRTN.                 49900013
         LH    RC,KCOUNT           AVAILABLE BUFFER                     50000013
         BCT   RC,RGDBF010           ON LIST TO ATTACH TO FILE          50100013
RGDRTRN  LM    RC,RH,KSAVE                                              50200013
         L     RL,PPIDEB+4         LINK TO DEBLOCK                      50300013
RGDRTRNV LA    RC,4(0,RC)          FIXED-BYPASS EOS INDICATOR           50400013
*                                  VAR.- BYPASS EOS INDICATOR AND BCC   50500013
         BCR   15,RL                                                    50600013
*                                                                       50700013
*                                                                       50800013
RGDBF010 STH   RC,KCOUNT                                                50900013
         L     RC,PPILAB02                                              51000013
         BAL   RH,RGDIOBUP         UPDATE IOB- ATTACH BUFFER FROM       51100013
         LA    RC,4(0,RC)            AVAILABLE LIST                     51200013
         ST    RC,PPILAB02         UPDATE LIST                          51300013
         STC   RD,RGDINST+1        FILE INCR(FR DEBLOCK)                51400013
         LH    RA,PPISRTBL                                              51500013
         LA    RH,RGDRTRN                                               51600013
RGDFLUP  LA    RC,TFCNT            FIND FILE COUNT IN ORDER             51700013
RGDINST  CLI   0(RC),X'00'                                              51800013
         BC    8,RGDBF015            TO UPDATE COUNT                    51900013
         LA    RC,4(0,RC)                                               52000013
         BC    15,RGDINST                                               52100013
*                                                                       52200013
*                                                                       52300013
RGDBF015 L     RE,0(0,RC)          ADD SORT BLOCKING                    52400013
         AR    RE,RA                                                    52500013
         ST    RE,0(0,RC)            TO FILE COUNT                      52600013
         BCR   15,RH                                                    52700013
*                                                                       52800013
*                                                                       52900013
RGDIOBUP L     RE,START            ATTACH NEW(OR ALTERNATE) CCW         53000013
         L     RP,ECBPTR                                                53100013
         MVC   START+1(3),5(RP)      TO FILE TO HANDLE READS ON         53200013
         ST    RE,4(0,RP)            ALTERNATE BUFFER                   53300013
         L     RE,START                                                 53400013
         MVC   1(3,RE),1(RC)       STORE BUFFER ADDR. IN CCW            53500013
         MVI   DCBBUFNO,X'02'      UPDATE BUFNO                         53600013
         LR    RE,RB               SAVE BLOCK COUNT                     53700013
         EXCP  (RF)                READ FWD                             53800013
         LR    RB,RE               RESTORE BLOCK COUNT FOR DEBLOCK      53900013
         BCR   15,RH                                                    54000013
*                                                                       54100013
*                                                                       54200013
RGDAL020 L     RB,ECBPTR                                                54300013
         WAIT  1,ECB=(1)           WAIT ON ALTERNATE                    54400013
         BAL   RH,RGDEE100         EOF-ERROR CK.                        54500013
         SPACE 2                                                        54600013
*RETURN FROM EOF-ERROR CK RTN. RB-ACTUAL COUNT OF RCDS IN THE BUFFER    54700013
*   FOR F.L.,OR ACTUAL NO.OF BYTES IN BUFFER -4(FOR BCC) FOR V.L. RCDS. 54800013
*   RC AND RE CONTAIN STARTING ADDR OF THE BUFFER.                      54900013
         SPACE 1                                                        55000013
RGDK2M   CLI   KTOTAL,X'00'        FULL OVLAP TEST.'I' FIELD SET TO 2M  55100013
*                                    BY A.P. AND RECALC ON EA INPT      55200013
*                                    EOF BY R.P.                        55300013
         BL    RGDFL030            BR ON KTOTAL LESS THAN 2M            55400013
         SPACE 2                                                        55500013
*FULL OVERLAP IN PHASE 3                                                55600013
         SPACE 1                                                        55700013
RGDAL025 LA    RC,IERDGB                                                55800013
         LA    RH,RGDRTRN            TO SAME FILE AGAIN                 55900013
         B     RGDIOBUP            BR TO UPDATE IOB                     56000013
         SPACE 2                                                        56100013
*PARTIAL OVERLAP ROUTINE. ASSIGN AN AVAILABLE BUFFER TO A UNIT HAVING   56200013
*   ONLY 1 BUFFER. SINCE THERE MAY BE MORE THAN 1 UNIT HAVING 1 BUFFER  56300013
*   TAKE THE BUFFER WITH THE LEAST AMOUNT OF RECORDS IN IT.             56400013
         SPACE 1                                                        56500013
RGDFL030 LA    RC,TFCNT            ADDR OF TABLE OF FILE COUNTERS       56600013
         ST    RB,KSAVEB           SAVE BLOCK CNT FOR DEBLOCK           56700013
         L     RB,PPISBLCT                                              56800013
         LH    RH,KMRGMX              -ADDING OF  DEBLOCK               56900013
         LA    RE,PPIPSVA                                               57000013
         SR    RO,RO                    COUNTS TO THE                   57100013
         ST    RO,0(RD,RB)         SET RELEASED FILE'S BLCNT=0          57200013
         SPACE 2                                                        57300013
*THE TABLE OF FILE COUNTERS CONTAIN ENTRIES OF ALL THE INPUT UNITS INTO 57400013
*   PHASE 3. EACH ENTRY IS 4 BYTES. 1ST BYTE IS THE FILE INCR. THE NEXT 57500013
*   3 BYTES IS EITHER 2B OR B DEPENDING WHETHER 2 OR 1 BUFFER IS        57600013
*   ATTACHED TO THE FILE. TAKE THESE ENTRIES AND ADD THE BLOCK COUNT    57700013
*   OF EACH FILE'S BLOCK COUNTERS AND ESTABLISH A PPIPSVA TABLE WHICH   57800013
*   WILL HAVE A 4 BYTE ENTRY FOR EACH FILE. 1ST BYTE IS FILE INCR. NEXT 57900013
*   3 BYTES IS(2B OR B) + REMAINING BLOCK COUNT FROM THE TABLE OF       58000013
*   BLOCK COUNTERS. THE RELEASED FILE'S BLOCK COUNT WAS SET TO 0 SO ITS 58100013
*   ENTRY IN PPIPSVA TABLE CANNOT EXCEED 2B.                            58200013
         SPACE 1                                                        58300013
RGDFL035 IC    RO,0(0,RC)                                               58400013
         L     RP,0(RO,RB)              FILE COUNTS                     58500013
         A     RP,0(0,RC)                                               58600013
         ST    RP,0(0,RE)                                               58700013
         LA    RC,4(0,RC)                                               58800013
         LA    RE,4(0,RE)                                               58900013
         BCT   RH,RGDFL035                                              59000013
*                                                                       59100013
         LA    RC,PPIPSVA          OBTAIN FILE COUNT ADDRS. VIA         59200013
         LH    RB,KMRGMX             FILE TO BE READ                    59300013
         STC   RD,RGDINST1+1                                            59400013
         LR    RE,RC                                                    59500013
         B     RGDINST1            BR TO SCAN PPISVA TABLE              59600013
         SPACE 2                                                        59700013
*FIND THE FILE ENTRY IN PPIPSVA OF THE FILE RELEASING THE BUFFER AND    59800013
*   THE FILE TO WHICH THE BUFFER WILL BE GIVEN. THE DISPLACEMENTS WILL  59900013
*   CORRESPOND TO THE DISPLACEMENTS OF THESE FILES IN THE TABLE OF      60000013
*   FILE CTRS. THE RELEASED FILES BUFFER WILL BE UPDATED TO B AND THE   60100013
*   NEW 2 BUFFER FILE WILL BE UPDATED TO 2B IN THE TABLE OF FILE CTRS.  60200013
         SPACE 1                                                        60300013
RGDLP040 LA    RE,4(0,RE)            SCAN FOR LOWEST FILE COUNT         60400013
         CLC   1(3,RC),1(RE)                                            60500013
         BC    2,RGDEX050              AND FOR THE RELEASED             60600013
RGDINST1 CLI   0(RE),X'00'                                              60700013
         BC    8,RGDRL060            FILE COUNT                         60800013
RGDLPEND BCT   RB,RGDLP040                                              60900013
         LR    RB,RA                                                    61000013
         LA    RA,PPIPSVA            DISPLACEMENTS OF LOWEST AND        61100013
         SR    RC,RA                 RELEASED FROM PPIPSVA              61200013
         SR    RB,RA                                                    61300013
         LA    RA,TFCNT                                                 61400013
         AR    RB,RA                                                    61500013
         AR    RC,RA                                                    61600013
         L     RE,0(0,RC)          UPDATE-                              61700013
         AH    RE,PPISRTBL                                              61800013
         ST    RE,0(0,RC)            NEW FILE COUNT                     61900013
         MVI   DCBBUFNO,X'01'        RELEASED FILE'S BUFNO(IN DCB)      62000013
         L     RE,0(0,RB)                                               62100013
         SH    RE,PPISRTBL                                              62200013
         ST    RE,0(0,RB)            RELEASED FILE COUNT                62300013
         SR    RB,RB                                                    62400013
         IC    RB,0(0,RC)          INCR IN NEW FILE COUNT'S FIRST BYTE  62500013
         L     RG,PPISTDCB                                              62600013
         L     RG,0(RB,RG)         IOB ADDR.                            62700013
         L     RF,DCBIOBAD           OF NEW FILE                        62800013
         L     RB,KSAVEB           RESTORE BLOCK CNT                    62900013
         BC    15,RGDAL025                                              63000013
*                                                                       63100013
*                                                                       63200013
RGDEX050 LR    RC,RE               ADDR. OF LOWEST FILE COUNT           63300013
         BC    15,RGDINST1                                              63400013
*                                                                       63500013
*                                                                       63600013
RGDRL060 LR    RA,RE                                                    63700013
         BC    15,RGDLPEND         ADDR. OF RELEASED FILE COUNT         63800013
         SPACE 2                                                        63900013
*END OF FILE/ERROR CHECK ROUTINE                                        64000013
         SPACE 1                                                        64100013
RGDEE100 TM    CSW+4,X'01'         UNIT EXCEPTION. HIT TAPE MARK        64200013
         BO    RGDEOFR             BR IF YES TO EOF ROUTINE             64300013
         TM    CSW+4,X'02'         UNIT CHECK FOR DEVICE ERROR          64400013
         BC    8,RGDPRMSK          BR IF NOT ON TO CHECK CHANNEL ERROR  64500013
         MVC   WSENSE0,SENSE       SENSE BYTE IN IOB TO SAVE AREA       64600013
RGSTORRF ST    RF,PPIWKARE         SAVE IOB ADDR IN CASE NO SYNAD RTN   64700013
RGDERROR OI    PPISW1+5,X'80'      TURN ON ERROR BIT IN PPI             64800013
RGMTERM  NOP   RGPRTABT                                                 64900013
         L     RB,DCBPTR           DCB ADDR IN IOB FOR E38 SYNAD        65000013
         ST    RF,PPIWKARE         IOB ADDR                             65100013
         MVI   PPIWKARE,X'10'      INCR TO CCW ADDR IN IOB FOR E38      65200013
         L     RA,PPIWKARE                                              65300013
         SPACE 2                                                        65400013
* INTERFACE WITH USER EXIT E38 SYNAD                                    65500013
         SPACE 1                                                        65600013
         L     RP,ADCONE38                                              65700013
         BALR  RO,RP                                                    65800013
         SPACE 2                                                        65900013
*PRINT IOS READ ERROR MSG BEFORE ABORTING                               66000013
         SPACE 1                                                        66100013
RGPRTABT L     RE,PPIWKARE         ADDR OF IOB WITH ERROR ON IT         66200013
         L     RE,20(0,RE)         ADDR OF IOB'S DCB                    66300013
         L     RE,44(0,RE)         ADDR OF DCB'S DEB                    66400013
         L     RE,32(0,RE)         ADDR OF DEB'S UCB                    66500013
         MVC   PPILAB02+1(3),13(RE) UNIT NAME (I.E.  182,183)           66600013
         L     RP,PPIADSSC                                              66700013
         BAL   RO,16(0,RP)                                              66800013
         SPACE 2                                                        66900013
         SPACE 1                                                        67000013
RGDSKIP  OI    FLG1,X'40'          IF ERROR ACCEPTED, RESET ERROR BITS  67100013
         NI    CSW+5,X'B7'           IN THE IOB AND DCB                 67200013
         NI    DCBIFLGS,X'3F'      DCB EXCEPTION BITS FOR PERM. ERROR   67300013
RGDACCPT EXCP  (RF)                READ FORWARD INTO SAME BUFFER        67400013
         L     RB,ECBPTR                                                67500013
         WAIT  1,ECB=(1)                                                67600013
RGDACCBR B     RGDEE110                                                 67700013
         SPACE 2                                                        67800013
*NO UNIT EXCEPTION OR UNIT CHECK BITS ON. CHECK IF OTHER ERRORS.        67900013
         SPACE 1                                                        68000013
RGDPRMSK TM    CSW+5,X'08'         CHECK IF CHANNEL ERROR               68100013
         BO    RGSTORRF            BR IF YES TO SAVE IOB ADDR           68200013
         TM    CSW+5,X'40'         CHECK IF INCORRECT LENGTH BIT ON     68300013
         BO    RGDEOSBF            BR IF YES TO CHECK IF EOS BFR        68400013
RGDEE110 L     RE,START            ADDR OF CCW FROM IOB                 68500013
         L     RE,0(RE)            STARTING BFR ADDR FROM CCW FOR DEBLK 68600013
         SPACE 2                                                        68700013
*TEST IF VARIABLE LENGTH RECORDS.                                       68800013
         SPACE 1                                                        68900013
RGDBRVR  BC    0,RGDVAR            A.P. WILL MAKE A BR IF V.L. RCDS.    69000013
         SPACE 1                                                        69100013
         TM    2(RE),X'07'         IS BUFFER EOS.                       69200013
         BO    RGDFIX              BR IF YES TO COUNT RCDS IN SHORT BLK 69300013
         LH    RB,PPISRTBL         NO,LOAD SORT BLOCKING INTO RB        69400013
RGDEE120 LR    RC,RE                                                    69500013
         ST    RC,KSAVE            STORE IN RC POS'N IN SAVE AREA       69600013
         MVI   KSAVE,X'00'         ZERO OUT CC                          69700013
         ST    RE,KSAVE+8          STORE IN RE POS'N IN SAVE AREA       69800013
         BCR   15,RH               RETURN TO MAIN LINE TO EITHER THE    69900013
*                                    OVERLAP OR NO OVERLAP RTN          70000013
         SPACE 2                                                        70100013
*CHECK IF BUFFER IS AN EOS BUFFER(INCORRECT LENGTH BIT IS ON IN CSW)    70200013
         SPACE 1                                                        70300013
RGDEOSBF L     RE,START                                                 70400013
         L     RE,0(RE)                                                 70500013
RGDEOSB1 TM    2(RE),X'07'         IS IT EOS.                           70600013
         BZ    RGSTORRF            BR IF NO TO PRINT MSG BEFORE ABORTG  70700013
         NI    DCBIFLGS,X'3F'      RESET IFLGS                          70800013
         B     RGDBRVR             BR IF YES TO CHK IF V.L. RCDS        70900013
         SPACE 2                                                        71000013
*DETERMINE ACTUAL NO OF BYTES IN THE V.L. BFR MINUS 4 FOR THE BCC       71100013
         SPACE 1                                                        71200013
RGDVAR   LH    RB,PPILAB03+2       SIZE OF ROUNDED INPUT BUFFER         71300013
         SH    RB,CSW+6            MINUS NO. OF BYTES DIDN'T READ IN    71400013
*                                    FROM COUNT FIELD OF CSW            71500013
         LR    RA,RB                                                    71600013
         SH    RB,KFOUR            MINUS 4 BYTES FOR BCC                71700013
         B     RGDEE120            BR TO LOAD RC & RE W/STRTG BFR ADDR  71800013
         SPACE 2                                                        71900013
*COUNT THE NUMBER OF RECORDS IN THE FIXED LENGTH EOS BUFFER             72000013
         SPACE 1                                                        72100013
RGDFIX   L     RB,KBLKCHR          COUNT OF A FULL BUFFER FROM PPILAB03 72200013
         SH    RB,CSW+6            MINUS NO. OF BYTES NOT READ IN       72300013
*                                    EQUALS NO. OF BYTES READ IN        72400013
         SH    RB,KFOUR            MINUS 4 FOR EOS BYTES                72500013
         SR    RO,RO                                                    72600013
RGDLOOP  SH    RB,PPIRCDL2         SUBTR LGTH OF 1 F.L. RCD FROM COUNT  72700013
         LA    RO,1(0,RO)          INCR RECORD COUNTER BY 1             72800013
         CH    RB,PPIRCDL2         COMPARE REMAINING COUNT              72900013
         BC    10,RGDLOOP          BR ON EQ OR GTR(MORE RCDS IN BFR)    73000013
         LR    RB,RO               LOAD NO. OF RCDS IN BUFFER IN RB     73100013
         B     RGDEE120            BR TO LOAD RC AND RE FOR DEBLOCK.    73200013
         SPACE 2                                                        73300013
*END OF FILE ROUTINE. PUT THIS FILE'S BUFFER(S) ON THE AVAILABLE BUFFER 73400013
*   LIST.                                                               73500013
         SPACE 1                                                        73600013
RGDEOFR  L     RE,START            ADDR OF PRIMARY CCW FROM THE IOB     73700013
RGDTWO   L     RC,PPILAB02         AVAIL BUFFER TABLE PTR               73800013
         SH    RC,KFOUR            DECR PTR                             73900013
         MVC   1(3,RC),1(RE)       BUFFER ADDR IN CCW TO TABLE          74000013
         ST    RC,PPILAB02         UPDATED BUFFER TABLE PTR             74100013
         LH    RC,KCOUNT                                                74200013
         LA    RC,1(0,RC)          ADD 1 TO AVAILABLE BUFFER CTR        74300013
         STH   RC,KCOUNT           STORE UPDATED CTR                    74400013
         CLI   DCBBUFNO,X'02'      DOES THIS FILE HAVE 2 BUFFERS        74500013
         BNE   RGDONE              BR IF NO                             74600013
         MVI   DCBBUFNO,X'01'      YES,CHANGE THE 2 TO A 1              74700013
         L     RE,ECBPTR           ADDR OF THE ECB                      74800013
         L     RE,4(0,RE)          ADDR OF THE ALTERNATE CCW            74900013
         B     RGDTWO                                                   75000013
         SPACE 2                                                        75100013
RGDONE   LH    RA,KNNINE           EOF INDICATION TO UPDATE TABLE OF    75200013
*                                    FILE COUNTERS.                     75300013
         STC   RD,RGDINST+1        INCR OF EOF FILE                     75400013
         BAL   RH,RGDFLUP          UPDATE TABLE OF FILE CTR ENTRY(EOF)  75500013
         LH    RH,KMRGMX1          ACTUAL INPUT MERGE ORDER UPDATED     75600013
         BCTR  RH,0                DECR BY 1 FOR THE INPUT EOF          75700013
         STH   RH,KMRGMX1          RESTORE NEW MERGE ORDER              75800013
         AR    RH,RH               2M                                   75900013
         STC   RH,RGDK2M+1         SET THE 'I' FIELD OF THE CLI INSTR   76000013
         OI    DCBOFLGS,X'04'      TURN OFF FLAG BITS IN DCB     A31855 76100021
         CLOSE ((RG))              CLOSE THE INPUT FILE                 76200013
         SPACE 2                                                        76300013
*INTERFACE TO MERGE NETWORK TO CUTBACK MERGE ORDER THEN MERGE GOES      76400013
*   TO BLOCK WITH ANOTHER WINNER.                                       76500013
         SPACE 1                                                        76600013
         L     RL,PPINET+4                                              76700013
         B     4(0,RL)                                                  76800013
         SPACE 2                                                        76900013
*LIST OF WORK AREAS/TABLES:                                             77000013
         SPACE 1                                                        77100013
TFCNT    DS    16F                 FILE COUNT TABLE, 4 BYTE ENTRIES     77200013
*                                    1ST BYTE-FILE INCR                 77300013
*                                    NEXT 3 BYTES- 2B=2 BFRS OR B=1 BFR 77400013
*                                      OR FFFF FOR EOF ON THE FILE      77500013
WSENSE0  DC    X'00'               SENSE BYTE SAVED ON UNIT CHECK       77600013
         SPACE 2                                                        77700013
*LIST OF CONSTANTS:                                                     77800013
         SPACE 1                                                        77900013
KTOTAL   DC    X'0000'             NO. OF INPUT BUFFERS PRESENTLY       78000013
*                                    ATTACHED                           78100013
KMRGMX   DC    H'0'                A.P. INSERTS INPUT MERGE ORDER INTO  78200013
*                                    PHASE 3                            78300013
KMRGMX1  DC    H'0'                A.P INSERTS INPUT MERGE ORDER INTO   78400013
*                                    PH 3.  R.P. DECR BY 1 EA INPT EOF  78500013
KCOUNT   DC    AL2(1)              AVAILABLE BUFFER COUNTER             78600013
KNNINE   DC    X'7FFF'             EOF CONSTANT FOR TFCNT ENTRY ON EOF  78700013
KFOUR    DC    AL2(4)              CONSTANT OF 4                        78800013
KBLKCHR  DC    F'0'                SORT BLOCK CHAR CNT(F AND V RCDS)    78900013
KSAVE    DC    6F'0'               REGISTER SAVE AREA                   79000013
KSAVEB   DC    F'0'                                                     79100013
         SPACE 2                                                        79200013
*LIST OF ADCONS:                                                        79300013
         SPACE 1                                                        79400013
ADCONE38 DC    F'0'                ADDR OF USER EXIT E38 SYNAD.LOADED   79500013
*                                    BY A.P.                            79600013
         EJECT                                                          79700013
         DS    0F                                                       79800013
IERIOB   DSECT                     DUMMY IOB-(SEE 14.90.1.4)            79900013
FLG1     DC    X'00'                                                    80000013
FLG2     DC    X'00'                                                    80100013
SENSE    DC    AL2(0)                                                   80200013
ECBPTR   DC    AL4(0)                                                   80300013
CSW      DC    AL4(0)                                                   80400013
         DC    AL4(0)                                                   80500013
START    DC    AL4(0)              HIGH ORDER BYTE IS CC.               80600013
DCBPTR   DC    AL4(0)              HIGH ORDER BYTE IS WGHT.             80700013
RESTART  DC    AL4(0)                                                   80800013
INCAMT   DC    AL2(0)                                                   80900013
ERRCNTS  DC    AL2(0)                                                   81000013
*                                                                       81100013
IERAP33  DSECT                                                          81200013
         DC    23F'0'                                                   81300013
WRDOPT   DC    F'0'                                                     81400013
         DC    8F'0'                                                    81500013
         EJECT                                                          81600013
AGMAMB   DSECT ,                   PHASE 3 DUMMY MESSAGE MODULE         81700013
*                                                                       81800013
       COPY  AMCMAIN                                                    81900013
         EJECT                                                          82000013
         SMPPI                                                          82100013
         DCBD  DSORG=PS                                                 82200013
         END                                                            82300013
