         TITLE 'IERAGN - OS/360 SORT/MERGE - 360S-SM023 - 6/8/66'       00100013
         SPACE 2                                                        00200013
*STATUS: CHANGE LEVEL 000                                               00300013
         SPACE 2                                                        00400013
*MODULE FUNCTION/OPERATION'                                             00500013
*    THE FUNCTION OF THIS MODULE IS TO GENERATE ALL DCB'S, IOB'S,       00600013
*    ECB'S, AND ALTERNATE CCW POINTER SLOTS ASSOCIATED WITH PHASES      00700013
*    ONE AND TWO OF AN OSCILLATING SORT. THEY ARE CREATED IN GENERATED  00800013
*    CORE AS FOLLOWS:                                                   00900013
*        ONE QSAM DCB FOR INPUT                                         01000013
*        M+1 EXCP DCB'S FOR OUTPUT                                      01100013
*        M+1 IOB'S, ECB'S, AND ALTERNATE CCW POINTERS                   01200013
*    THE ADDRESS OF EACH DCB GENERATED IS PLACED IN A DCB ADDRESS       01300013
*    TABLE AND DCB OPEN LIST. IF THE ACTIVE BITS FOR ANY OR ALL OF      01400013
*    USER MODIFICATION EXITS E18, E28, E19, AND E29 ARE FOUND ON, THE   01500013
*    PARAMETERS FROM THE USER'S PROGRAM(2) ARE INCORPORATED INTO THE    01600013
*    DCB'S AND THE OPEN LIST.                                           01700013
         SPACE 2                                                        01800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               01900013
*                                                                       02000013
*     N/A                                                               02100013
*                                                                       02200013
*MACROS USED'                                                           02300013
         SPACE 1                                                        02400013
*   SMPPI                                                               02500013
*   DCB                                                                 02600013
*   DCBD                                                                02700013
         SPACE 2                                                        02800013
*ENTRY POINTS:                                                          02900013
         SPACE 1                                                        03000013
*        ENTRY IERMGN              ENTRY FROM: LOAD MODULE, IERRC9      03100013
*                                    CALLING SEQUENCE-                  03200013
*                                       LOAD EP=IERAGN,DCB=             03300013
*                                       LR RP,RA                        03400013
*                                       BALR RO,RP                      03500013
         SPACE 2                                                        03600013
*INPUT: PPI FIELDS REFERENCED-                                          03700013
         SPACE 1                                                        03800013
*   PPIAMA          PPILAB03       PPIRCV         PPIX18                03900013
*   PPIBDSVA        PPILAB06       PPISPGN1       PPIX19                04000013
*   PPIDDSRT        PPIMODEX       PPISTDCB       PPIX28                04100013
*   PPIDEPHO        PPIMRGMX       PPISW1         PPIX29                04200013
*   PPIEOF          PPIOPEN        PPITPTBL                             04300013
         SPACE 2                                                        04400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             04500013
         SPACE 1                                                        04600013
*   PPIDEPHO                                                            04700013
*   PPISPGN1                                                            04800013
*   PPITPTBL                                                            04900013
*   ONE QSAM DCB FOR INPUT                                              05000013
*   M+1 EXCP DCB'S FOR OUTPUT                                           05100013
*   M+1 IOB'S, ECB'S, AND ALTERNATE CCW POINTERS                        05200013
         SPACE 2                                                        05300013
*EXTERNAL ROUTINES:                                                     05400013
         SPACE 1                                                        05500013
*        NONE                                                           05600013
         SPACE 2                                                        05700013
*EXTERNAL PARAMETERS:                                                   05800013
         SPACE 1                                                        05900013
*        NONE                                                           06000013
         SPACE 1                                                        06100013
*EXITS: NORMAL                                                          06200013
         SPACE 1                                                        06300013
*        BR    RO - RETURN TO LOAD MODULE, IERRC9                       06400013
         SPACE 2                                                        06500013
*EXITS: ERROR                                                           06600013
         SPACE 1                                                        06700013
*        NONE                                                           06800013
         SPACE 2                                                        06900013
*TABLES/WORK AREAS:                                                     07000013
         SPACE 1                                                        07100013
*   WADOPEN - UPDATED ADDRESS OF OPEN LIST                              07200013
*   WDCBADR - UPDATED ADDRESS OF DCB AREA IN CORE                       07300013
*   WDCBTAB - ADDRESS OF DCB ADDRESS TABLE IN GENERATED CORE            07400013
*   WECBADR - ADDRESS OF ECB/IOB ADDRESS IN GENERATED CORE              07500013
*   WFRSTERR - GENERAL SWITCH                                           07600013
*   WINADJ - INPUT DCB ADDRESS ADJUSTMENT FACTOR                        07700013
*   WINSIZE - SIZE OF INPUT QSAM DCB                                    07800013
*   WOUTADJ - OUTPUT DCB ADDRESS ADJUSTMENT FACTOR                      07900013
*   WOUTSIZE -  SIZE OF OUTPUT EXCP DCB                                 08000013
*   WREGS - REGISTER SAVE AREA DURING PRINT ROUTINE                     08100013
*   WSAVAREA - GENERAL REGISTER SAVE AREA                               08200013
*   WIOBMDL - MODEL ECB AND IOB USED BY THE PROGRAM                     08300013
*   WEXCPDCB - MODEL OUTPUT EXCP DCB                                    08400013
*   WQSAMDCB - MODEL INPUT QSAM DCB                                     08500013
         SPACE 2                                                        08600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  08700013
         SPACE 2                                                        08800013
*NOTES:                                                                 08900013
         SPACE 1                                                        09000013
*        SINCE THE OSCILLATING SORT USES ONLY TAPES, THIS MODULE        09100013
*    GENERATES THE NECESSARY PARAMETERS FOR USE WITH TAPE ONLY.         09200013
         SPACE 2                                                        09300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            09400013
         SPACE 1                                                        09500013
RA       EQU   0                   CONTENTS IN- N/A                     09600013
*                                  USE- WORK REGISTER                   09700013
*                                  CONTENTS OUT- N/A                    09800013
RB       EQU   1                   CONTENTS IN- N/A                     09900013
*                                  USE- WORK REGISTER                   10000013
*                                  CONTENTS OUT- N/A                    10100013
RC       EQU   2                   CONTENTS IN- N/A                     10200013
*                                  USE- WORK REGISTER                   10300013
*                                  CONTENTS OUT- N/A                    10400013
RD       EQU   3                   CONTENTS IN- N/A                     10500013
*                                  USE- WORK REGISTER                   10600013
*                                  CONTENTS OUT- N/A                    10700013
RE       EQU   4                   CONTENTS IN- N/A                     10800013
*                                  USE- WORK REGISTER                   10900013
*                                  CONTENTS OUT- N/A                    11000013
RF       EQU   5                   CONTENTS IN- N/A                     11100013
*                                  USE- WORK REGISTER                   11200013
*                                  CONTENTS OUT- N/A                    11300013
RG       EQU   6                   CONTENTS IN- N/A                     11400013
*                                  USE- WORK REGISTER                   11500013
*                                  CONTENTS OUT- N/A                    11600013
RH       EQU   7                   CONTENTS IN- N/A                     11700013
*                                  USE- WORK REGISTER                   11800013
*                                  CONTENTS OUT- N/A                    11900013
RI       EQU   8                   CONTENTS IN- N/A                     12000013
*                                  USE- WORK REGISTER                   12100013
*                                  CONTENTS OUT- N/A                    12200013
RJ       EQU   9                   CONTENTS IN- N/A                     12300013
*                                  USE- WORK REGISTER                   12400013
*                                  CONTENTS OUT- N/A                    12500013
RK       EQU   10                  CONTENTS IN- N/A                     12600013
*                                  USE- WORK REGISTER                   12700013
*                                  CONTENTS OUT- N/A                    12800013
RL       EQU   11                  CONTENTS IN- N/A                     12900013
*                                  USE- PROGRAM BASE REGISTER           13000013
*                                  CONTENTS OUT- N/A                    13100013
RM       EQU   12                  CONTENTS IN- N/A                     13200013
*                                  USE- BASE REGISTER FOR DCB DSECT     13300013
*                                  CONTENTS OUT- N/A                    13400013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          13500013
*                                  USE- PPI REFERENCE,REGISTER SAVE     13600013
*                                    AREA                               13700013
*                                  CONTENTS OUT- ADDRESS OF PPI         13800013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      13900013
*                                                IERRC9                 14000013
*                                 USE- BASE REG FOR PRINT MOC DSECT     14100013
*                                  CONTENTS OUT - RETURN ADDRESS IN     14200013
*                                                 IERRC9                14300013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMGN 14400013
*                                  USE- BASE REG FOR OPEN LIST DSECT    14500013
*                                  CONTENTS OUT- N/A                    14600013
         EJECT                                                          14700013
*START OF MODULE CODE PROPER:                                           14800013
         SPACE 1                                                        14900013
IERAGN   CSECT                                                          15000013
         SPACE 2                                                        15100013
         USING *,RL                 BASE REGISTER FOR THIS MODULE       15200013
         USING IHADCB,RM            BASE REGISTER FOR DCB DSECT         15300013
         USING IERRCA,RN            PPI COMMON MODULE BASE REGISTER     15400013
         USING DIERAMA,RO           BASE REG FOR MESSAGE MODULE DSECT   15500013
         USING OPENLIST,RP          BASE REG FOR OPEN LIST DSECT        15600013
         SPACE 3                                                        15700013
IERMGN   LR    RL,RP                LOAD BASE REGISTER                  15800013
         STM   RA,RP,WSAVAREA       SAVE REGISTERS                      15900013
         L     RO,PPIAMA+4          LOAD BASE REG FOR MESSAGE MOD DSECT 16000013
         MVC   KINPID(4),PPIDDSRT   MOVE DDNAME LETTERS INTO INPUT ID   16100013
         MVC   KOUTID(4),PPIDDSRT   MOVE DDNAME LETTERS INTO OUTPUT ID  16200013
         SPACE 2                                                        16300013
*        COMPUTE SIZE AND ADDRESS ADJUSTMENT FACTOR FOR OUTPUT EXCP DCB 16400013
         SPACE 1                                                        16500013
         LA    RM,WEXCPDCB          EXCP DCB MODEL                      16600013
         LA    RB,KMARK1+1          ADDRESS OF BEGINNING OF DCB         16700013
         LA    RC,KMARK2            ADDRESS OF END OF DCB               16800013
         SR    RC,RB                                                    16900013
         ST    RC,WOUTSIZE          WOUTSIZE EQUALS OUTPUT DCB SIZE     17000013
         SPACE 1                                                        17100013
         LA    RC,DCBDDNAM                                              17200013
         SR    RC,RB                FIND DISPLACEMENT OF DDNAME         17300013
         LA    RB,40                                                    17400013
         SR    RB,RC                                                    17500013
         ST    RB,WOUTADJ           OUTPUT DCB ADJUSTMENT FACTOR        17600013
         SPACE 2                                                        17700013
*        COMPUTE SIZE AND ADDRESS ADJUSTMENT FACTOR FOR INPUT QSAM DCB  17800013
         SPACE 1                                                        17900013
         LA    RM,WQSAMDCB          QSAM DCB MODEL                      18000013
         LA    RB,KMARK3+1          ADDRESS OF BEGINNING OF DCB         18100013
         SR    RC,RC               ZERO REG                      A26453 18200019
         ST    RC,WINSIZE          STORE IN WORK AREA            A26453 18300019
         MVC   WINSIZE+2(2),PPIDCBIN      GET SIZE OF DCB        A26453 18400019
         SPACE 1                                                        18500013
         LA    RC,DCBDDNAM                                              18600013
         SR    RC,RB                FIND DISPLACEMENT OF DDNAME         18700013
         LA    RB,40                                                    18800013
         SR    RB,RC                                                    18900013
         ST    RB,WINADJ            INPUT DCB ADJUSTMENT FACTOR         19000013
         SPACE 2                                                        19100013
*        STORE TOTAL NUMBER OF DCBS TO OPEN AS FIRST ENTRY IN OPEN LIST 19200013
         SPACE 1                                                        19300013
         LH    RB,PPIMRGMX          NUMBER OF OUTPUT DCBS TO GENERATE   19400013
         L     RC,PPIOPEN+4         ADDRESS OF OPEN LIST                19500013
         LA    RB,2(RB)             MAX MERGE ORDER + 2 = TOTAL NO DCBS 19600013
         ST    RB,0(RC)             STORE IN OPEN LIST                  19700013
         LA    RC,4(RC)             UPDATE OPEN LIST POINTER            19800013
         ST    RC,WADOPEN           STORE UPDATED POINTER               19900013
         SPACE 2                                                        20000013
*        ALLOCATE CORE FOR IOBS, ECBS, DCBS, AND TABLES. SETUP POINTERS 20100013
         SPACE 1                                                        20200013
         L     RB,PPISPGN1          STARTING ADDRESS OF GENERATED CORE  20300013
         LH    RE,PPIMRGMX          LOAD M                              20400013
         LA    RE,1(RE)             ADD ONE FOR NUMBER OF OUTPUT DCB'S  20500013
         L     RD,WOUTSIZE          GET SIZE OF OUTPUT DCB'S AND        20600013
         MR    RC,RE                    MULTIPLY                        20700013
         A     RD,WINSIZE           ADD SIZE OF INPUT DCB               20800013
         SR    RB,RD                UPDATE ADDRESS OF GEN CORE          20900013
         ST    RB,WDCBADR           SAVE ADDRESS OF DCB AREA            21000013
         NI    WDCBADR+3,X'F8'     ROUND TO DOUBLE WORD                 21100013
         L     RB,WDCBADR                                               21200013
         SPACE 1                                                        21300013
         LA    RD,40                LOAD SIZE OF ECB'S AND IOB'S        21400013
         MR    RC,RE                MULTIPLY BY M+1                     21500013
         SR    RB,RD                UPDATE ADDRESS OF GEN CORE          21600013
         ST    RB,WECBADR           SAVE ADDRESS OF IOB AREA            21700013
         SPACE 1                                                        21800013
         IC    RC,PPIBDSVA          LOAD TOTAL NUMBER OF WORK UNITS     21900013
         LA    RC,1(RC)             ADD ONE FOR INPUT TAPE UNIT         22000013
         SLL   RC,2                 MULTIPLY BY FOUR                    22100013
         SR    RB,RC                UPDATE ADDRESS OF GEN CORE          22200013
         ST    RB,WDCBTAB           SAVE ADDRESS OF DCB TABLE           22300013
         ST    RB,PPISPGN1          STORE UPDATED GEN CORE ADDRESS      22400013
         ST    RB,PPISTDCB                                              22500013
         SPACE 2                                                        22600013
*        IF DIAGNOSTICS, PRINT OUT ADDRESS OF DCB TABLE                 22700013
         SPACE 1                                                        22800013
         TM    PPISW1+6,X'01'      IS DIAGNOSTICS SWITCH ON?            22900013
         BZ    GN00                IF SWITCH OFF, BYPASS MESSAGE        23000013
         LR    RA,RB               LOAD NUMBER TO BE CONVERTED          23100013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   23200013
         BAL   RO,4(RP)           BRANCH TO HAVE NUMBER CONVERTED       23300013
         SPACE 1                                                        23400013
         L     RO,PPIAMA+4         ADDRESS OF MESSAGE MODULE            23500013
         MVC   DMSG906A(8),3(RB)   MOVE NUMBER INTO MESSAGE             23600013
         LM    RA,RB,DMSG906X      SET UP PARAMS FOR PRINTING           23700013
         L     RP,PPIRCV+4         ADDRESS OF PRINT ROUTINE             23800013
         BAL   RO,12(RP)           GO TO PRINT ROUTINE                  23900019
         SPACE 2                                                        24000013
*        SET INDICATOR BIT IN FIRST BYTE OF ALL DCB ADR TABLE SLOTS     24100013
         SPACE 1                                                        24200013
GN00     L     RB,PPISTDCB        ADDRESS OF DCB TABLE                  24300013
         L     RD,KSIGNBIT         SET SIGN BIT ON                      24400013
         SRL   RC,2                 GET TOTAL NUMBER OF TAPE UNITS      24500013
         SPACE 1                                                        24600013
GN01     ST    RD,0(RB)             SET SIGN BIT IN DCB TABLE ENTRY     24700013
         BCT   RC,GN02              IF MORE ENTRIES, BRANCH             24800013
         B     GN03                GO TO CONVERT WORK UNIT NOS.         24900019
         SPACE 1                                                        25000013
GN02     LA    RB,4(RB)             UPDATE POINTER                      25100013
         B     GN01                GO TO SET SIGN BIT IN DCB TBL ENTRY  25200019
         SPACE 2                                                        25300013
*          CONVERT WORK UNIT NUMBERS IN THE TAPE TABLE TO AN INCREMENT  25400013
*        USED TO REFERENCE THE DCB ADDRESS IN THE DCB ADDRESS TABLE     25500013
         SPACE 1                                                        25600013
GN03     LA    RB,PPITPTBL          LOAD ADDRESS OF TAPE TABLE          25700013
         IC    RC,PPIBDSVA          LOAD TOTAL NUMBER OF WORK UNITS     25800013
         SR    RD,RD                                                    25900013
         SPACE 1                                                        26000013
GN04     IC    RD,1(RB)             GET WORK UNIT NUMBER FROM TABLE     26100013
         SLL   RD,2                 CONVERT TO INCREMENT                26200013
         STC   RD,1(RB)             RESTORE                             26300013
         BCT   RC,GN05              IF MORE ENTRIES, BRANCH             26400013
         B     GN06                GO TO CONVERT DEPHO+3 TO INCREMENT   26500019
         SPACE 1                                                        26600013
GN05     LA    RB,2(RB)             UPDATE POINTER                      26700013
         B     GN04                GO TO GET WORT UNIT NO. FROM TAB     26800019
         SPACE 2                                                        26900013
*        CONVERT DEPHO+3 TO INCREMENT                                   27000013
         SPACE 1                                                        27100013
GN06     IC    RD,PPIDEPHO+3        LOAD NO OF FIRST OUTPUT UNIT        27200013
         SLL   RD,2                 CONVERT TO INCREMENT                27300013
         STC   RD,PPIDEPHO+3        RESTORE                             27400013
         SPACE 2                                                        27500013
*        GENERATE INPUT DCB                                             27600013
         SPACE 1                                                        27700013
GN07     LA    RM,WQSAMDCB          SET UP BASE ADDRESS FOR IHADCB      27800013
         MVC   DCBDDNAM(8),KINPID   MOVE IN DD NAME                     27900013
         MVC   DCBBUFNO(1),PPILAB03 MOVE IN NUMBER OF OUTPUT BUFFERS    28000013
         MVC   DCBBUFCB+1(3),PPILAB06+1 MOVE IN ADDRESS OF BUFFER POOL  28100013
         MVC   DCBBUFL(2),PPILAB03+2 MOVE IN SIZE OF INPUT BUFFER       28200013
         MVC   DCBBFTEK+1(3),PPIEOF+5   MOVE IN EOD ADDRESS             28300013
         MVI   DCBEROPT,X'20'       ERROR OPTION = ABORT PROGRAM        28400013
         L     RB,PPIRCV+4                                              28500013
         MVC   DCBSYNAD(4),24(RB)   MOVE IN ADDRESS OF ERROR ROUTINE    28600013
         TM    PPISW1+1,X'08'       IS THERE INPUT DATA CHAINING?       28700013
         BO    GN08                 BRANCH IF YES                       28800013
         SPACE 1                                                        28900013
         MVI   DCBBFTEK,X'40'       USE SIMPLE BUFFERING                29000013
         TM    PPIMODEX+2,X'02'   IS IT VRE INPUT                       29030017
         BO    AGNVRE              GO TO GET MOVE MODE                  29060019
         OI    DCBMACR,X'48'        USE GET LOCATE MODE                 29100013
         B     GN09                GO TO USE IOS ERROR ROUTINE          29160019
AGNVRE   OI    DCBMACR,X'50'      GET  MOVE MODE                        29230017
         B     GN09                                                     29260017
         SPACE 1                                                        29300013
GN08     MVI   DCBBFTEK,X'10'       USE EXCHANGE BUFFERING              29400013
         OI    DCBMACR,X'44'        USE GET SUBSTITUTE MODE             29500013
         SPACE 1                                                        29600013
GN09     MVI   DCBIFLG,X'00'        USE IOS ERROR ROUTINES              29700013
         TM    PPISW1+4,X'01'       FULL WORD BUFFER ALIGNMENT?         29800013
         BO    GN10                 BRANCH IF YES                       29900013
         SPACE 1                                                        30000013
         OI    DCBBFTEK,X'02'       DOUBLE WORD BUFFER ALIGNMENT        30100013
         B     GN11                GO TO TEST USER MOD TAB E18          30200019
         SPACE 1                                                        30300013
GN10     OI    DCBBFTEK,X'01'       FULL WORD BUFFER ALIGNMENT          30400013
         SPACE 1                                                        30500013
GN11     TM    PPIMODEX,X'08'       USER MODIFICATION E18?              30600013
         BZ    GN22                 BRANCH IF NO                        30700013
         SPACE 2                                                        30800013
*        BRANCH TO USER MODIFICATION EXIT E18                           30900013
         SPACE 1                                                        31000013
GN12     L     RP,PPIX18+4          LOAD ADDRESS OF USER EXIT E18       31100013
GN13     BALR  RO,RP               BRANCH TO USER MOD EXIT E18          31200019
         SPACE 2                                                        31300013
*        RETURN POINT FROM THE USER MODIFICATION PROGRAM                31400013
         SPACE 1                                                        31500013
GN14     LA    RC,TBRANCH           LOAD ADDRESS OF BRANCH TABLE        31600013
         LA    RD,TLDADR            LOAD ADDRESS OF LOAD ADDRESS TABLE  31700013
GN15     SR    RE,RE                                                    31800013
         IC    RE,0(RB)             LOAD OPTION NUMBER                  31900013
         LTR   RE,RE                ARE THERE MORE OPTIONS?             32000013
         BZ    GN22                 BRANCH ON NO                        32100013
         CL    RE,KFOUR             CHECK OPTION FOR LEGALITY           32200013
         BH    GN20                 BRANCH IF ILLEGAL                   32300013
         SLL   RE,2                 CONVERT OPTION NUMBER TO INDEX      32400013
         EX    0,0(RE,RD)           EXECUTE PROPER LOAD ADDRESS INSTRUC 32500013
         AR    RE,RC                ADD INDEX TO ADDRESS OF BRANCH TBL  32600013
         BR    RE                  BRANCH TO BRANCH TAB                 32700019
         SPACE 2                                                        32800013
*        BRANCH TABLE USED BY PROGRAM                                   32900013
         SPACE 1                                                        33000013
TBRANCH  DC    F'0'                B   T                                33100019
         B     GN17                 R   A                               33200019
         B     GN17                  A   B                              33300019
         B     GN19                   N   L                             33400019
         B     GN16                    CH  E                            33500019
         SPACE 2                                                        33600013
*        LOAD ADDRESS TABLE USED BY PROGRAM                             33700013
         SPACE 1                                                        33800013
TLDADR   DC    F'0'                LA TABLE                             33900019
         LA    RG,DCBSYNAD+1                                            34000013
         LA    RG,DCBEXLST+1                                            34100013
         LA    RG,DCBEROPT                                              34200013
         L     RG,PPIEOF+4                                              34300013
         SPACE 1                                                        34400013
GN16     LA    RG,9(RG)             UPDATE ADDRESS TO PROPER LOCATION   34500013
GN17     MVC   0(3,RG),1(RB)        MOVE ADDRESS INTO PROPER LOCATION   34600013
GN18     LA    RB,4(RB)             UPDATE POINTER TO USER LIST         34700013
         B     GN15                 GO THRU LOOP AGAIN                  34800013
         SPACE 1                                                        34900013
GN19     MVC   0(1,RG),3(RB)        MOVE ERROR OPTION INTO SORT EOD RTN 35000013
         B     GN18                GO TO UPDATE PTR TO USER LST         35100019
         SPACE 2                                                        35200013
*        SET UP ERROR PRINTOUT FOR PRINT MODULE IF FIRST ERROR          35300013
         SPACE 1                                                        35400013
GN20     TM    WFRSTERR,X'01'       FIRST ERROR OPTION....              35500013
         BO    GN18                 BRANCH ON NO                        35600013
         MVI   WFRSTERR,X'11'       ON YES, SET INDICATOR               35700013
         L     RO,PPIAMA+4         LOAD BASE REG. FOR MESSAGE MOD DSECT 35800013
         MVC   DCBERREX+16(2),KTAG  MOVE '18' INTO ERROR MESSAGE        35900013
GN21     STM   RP,RG,WREGS         SAVE REGISTERS                       36000013
         LM    RA,RB,DCBERAEX       LOAD ADDRESS OF PARAMETERS          36100013
         L     RP,PPIRCV+4          LOAD ADDRESS OF PRINT ROUTINE       36200013
         BAL   RO,12(RP)           GO TO PRINT ROUTINE                  36300019
         SPACE 2                                                        36400013
*        RETURN POINT FROM PRINT MODULE                                 36500013
         SPACE 1                                                        36600013
         LM    RP,RG,WREGS         SAVE REGISTERS                       36700013
         TM    WFRSTERR,X'80'       ERROR IN EXIT E29?                  36800013
         BO    GN39                 RETURN ON YES                       36900013
         TM    WFRSTERR,X'40'       ERROR IN EXIT E19?                  37000013
         BO    GN34                 RETURN ON YES                       37100013
         TM    WFRSTERR,X'20'       ERROR IN EXIT E28?                  37200013
         BO    GN24                 RETURN ON YES                       37300013
         B     GN18                 RETURN TO WORK ON EXIT E18 PARAMS   37400013
         SPACE 2                                                        37500013
*        MODIFICATION COMPLETE, RETURN TO MAIN PROGRAM                  37600013
         SPACE 1                                                        37700013
GN22     MVI   WFRSTERR,X'00'       RESTORE FIRST OPTION ERROR INDIC.   37800013
         TM    PPIMODEX+1,X'80'     USER MODIFICATION EXIT 28?          37900013
         BZ    GN27                BRANCH ON NO                         38000013
         SPACE 2                                                        38100013
*        BRANCH TO USER MODIFICATION EXIT E28                           38200013
         SPACE 1                                                        38300013
         L     RP,PPIX28+4          LOAD ADDRESS OF USER EXIT E28       38400013
         BALR  RO,RP               GO TO USER MOD EXIT E28              38500019
         SPACE 2                                                        38600013
*        RETURN POINT FROM USER MODIFICATION EXIT E28                   38700013
         SPACE 1                                                        38800013
GN23     CLI   0(RB),X'00'          ARE THERE MORE OPTIONS?             38900013
         BE    GN27                 BRANCH ON NO                        39000013
         L     RP,PPIOPEN+4         LOAD BASE REG FOR OPEN LIST DSECT   39100013
         CLI   0(RB),X'01'          IS THERE A USER SYNAD OPTION?       39200013
         BE    GN25                 BRANCH ON YES                       39300013
         CLI   0(RB),X'03'          IS THERE A USER EROPT OPTION?       39400013
         BE    GN26                 BRANCH ON YES                       39500013
         BNH   GN24                 BRANCH IF VALID OP CODE             39600013
         SPACE 2                                                        39700013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         39800013
         SPACE 1                                                        39900013
         TM    WFRSTERR,X'01'       FIRST ERROR OPTION?                 40000013
         BO    GN24                 BRANCH ON NO                        40100013
         MVI   WFRSTERR,X'21'       ON YES, SET INDICATOR               40200013
         L     RO,PPIAMA+4         LOAD BASE REG. FOR MESSAGE MOD DSECT 40300013
         MVC   DCBERREX+16(2),KTAG+2 MOVE '28' INTO ERROR MESSAGE       40400013
         B     GN21                 BRANCH TO BRANCH TO PRINT ROUTINE   40500013
         SPACE 1                                                        40600013
GN24     LA    RB,4(RB)             UPDATE POINTER TO USER PARAMS       40700013
         B     GN23                 GO THRU LOOP AGAIN                  40800013
         SPACE 1                                                        40900013
GN25     MVC   AP1RD2+1(3),1(RB)    MOVE USER SYNAD INTO OPEN LIST      41000013
         B     GN24                 DO I GO THRU THE LOOP AGAIN?        41100013
GN26     MVC   AP1RD2(1),3(RB)      MOVE USER EROPT INTO OPEN LIST      41200013
         B     GN24                 DO I GO THRU THE LOOP AGAIN?        41300013
         SPACE 2                                                        41400013
*        ENTRIES MADE, RETURN TO MAIN PROGRAM                           41500013
         SPACE 1                                                        41600013
GN27     MVI   WFRSTERR,X'00'       RESTORE FIRST ERROR OPTION INDIC.   41700013
         L     RB,WDCBADR           LOAD ADDRESS OF DCB AREA IN GEN COR 41800013
         S     RB,WINADJ            SUBTRACT INPUT DCB SIZE ADJ FACTOR  41900013
         L     RC,WDCBTAB           LOAD AD OF DCB TABLE IN GEN CORE    42000013
         ST    RB,0(RC)             ST AD OF INP DCB IN DCB TABLE       42100013
         L     RD,WADOPEN           LOAD UPDATED AD OF OPEN LIST        42200013
         ST    RB,0(RD)             ST ADDRESS OF INP DCB IN OPEN LIST  42300013
         LA    RD,4(RD)             UPDATE ADDRESS OF OPEN LIST         42400013
         ST    RD,WADOPEN           STORE                               42500013
         SPACE 2                                                        42600013
*        MOVE DCB INTO ALLOCATED CORE                                   42700013
         SPACE 1                                                        42800013
         L     RC,WINSIZE           LOAD SIZE OF INPUT DCB              42900013
         BCTR  RC,0                ADJUST SIZE OF DCB FOR EX INSTR      43000013
         L     RD,WDCBADR           NEXT USABLE ACTUAL DCB ADDRESS      43100013
         EX    RC,GNMOVE            MOVE DCB INTO ALLOCATED CORE        43200013
         LA    RC,1(RC)             SIZE OF INPUT DCB                   43300013
         AR    RD,RC                UPDATE ACTUAL DCB ADDRESS           43400013
         ST    RD,WDCBADR           STORE UPDATED DCB CORE ADDRESS      43500013
         SPACE 2                                                        43600013
*        GENERATE OUTPUT EXCP DCB'S                                     43700013
         SPACE 1                                                        43800013
GN28     LA    RM,WEXCPDCB          SET UP BASE ADDRESS FOR IHADCB DSEC 43900013
         MVC   DCBDDNAM(8),KOUTID   MOVE IN 'SORTWK--' FOR DD NAME      44000013
         TM    PPISW1+1,X'04'       IS THERE OUTPUT DATA CHAINING?      44100013
         BO    GN29                 BRANCH IF YES                       44200013
         MVI   DCBBFTEK,X'40'       USE SIMPLE BUFFERING                44300013
         B     GN30                GO TEST FOR FULL WORD BUF ALGN       44400019
         SPACE 1                                                        44500013
GN29     MVI   DCBBFTEK,X'10'       USE EXCHANGE BUFFERING              44600013
GN30     TM    PPISW1+4,X'01'       FULL WORD BUFFER ALIGNMENT?         44700013
         BO    GN31                 BRANCH ON YES                       44800013
         OI    DCBBFTEK,X'02'       USE DOUBLE WORD BUFFER ALIGNMENT    44900013
         B     GN32                GO TO USE IOS ERROR ROUTINE          45000019
         SPACE 1                                                        45100013
GN31     OI    DCBBFTEK,X'01'       USE FULL WORD BUFFER ALIGNMENT      45200013
GN32     MVI   DCBIFLG,X'00'        USE IOS ERROR ROUTINES              45300013
         TM    PPIMODEX+1,X'02'     USER EXIT E19 ACTIVATED?            45400013
         BZ    GN37                 BRANCH ON NO                        45500013
         SPACE 2                                                        45600013
*        BRANCH TO USER MODIFICATION EXIT E19                           45700013
         SPACE 1                                                        45800013
         L     RP,PPIX19+4          LOAD ADDRESS OF USER EXIT E19       45900013
         BALR  RO,RP               GO TO USER MOD EXIT E19              46000019
         SPACE 1                                                        46100013
GN33     CLI   0(RB),X'00'          ARE THERE MORE OPTIONS?             46200013
         BE    GN37                 BRANCH ON NO                        46300013
         CLI   0(RB),X'01'          IS THERE A USER SYNAD OPTION?       46400013
         BE    GN35                 BRANCH ON YES                       46500013
         CLI   0(RB),X'02'          IS THERE A USER EXLST OPTION?       46600013
         BE    GN36                 BRANCH ON YES                       46700013
         SPACE 2                                                        46800013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         46900013
         SPACE 1                                                        47000013
         TM    WFRSTERR,X'01'       FIRST ERROR OPTION?                 47100013
         BO    GN34                 BRANCH ON NO                        47200013
         OI    WFRSTERR,X'41'       ON YES, SET INDICATOR               47300013
         L     RO,PPIAMA+4         LOAD BASE REG. FOR MESSAGE MOD DSECT 47400013
         MVC   DCBERREX+16(2),KTAG+4 MOVE '19' INTO ERROR MESSAGE       47500013
         B     GN21                 BRANCH TO BRANCH TO PRINT ROUTINE   47600013
         SPACE 2                                                        47700013
*        ARE THERE MORE OPTIONS?                                        47800013
         SPACE 1                                                        47900013
GN34     TM    WFRSTERR,X'02'       IS THIS THE SECOND TIME THRU LOOP?  48000013
         BO    GN37                 BRANCH ON YES                       48100013
         OI    WFRSTERR,X'02'       SET ONCE THRU LOOP INDICATOR        48200013
         LA    RB,4(RB)             UPDATE POINTER TO USER PARAMS       48300013
         B     GN33                 GO THRU LOOP AGAIN                  48400013
         SPACE 1                                                        48500013
GN35     L     RP,PPIOPEN+4        LOAD BASE REG FOR OPEN LIST DSECT    48600013
         MVC   AP1WRT1+1(3),1(RB)  MOVE USER SYNAD INTO OPEN LIST       48700013
         B     GN34                 DO I GO THRU LOOP AGAIN?            48800013
GN36     MVI   WFRSTERR+1,X'FF'     SET USER EXIT E19 EXLST SWITCH      48900013
         MVC   DCBEXLST+1(3),1(RB)  STORE EXLST AD IN MODEL DCB         49000013
         B     GN34                 DO I GO THRU LOOP AGAIN?            49100013
         SPACE 2                                                        49200013
*        ENTRIES MADE, RETURN TO MAIN PROGRAM                           49300013
         SPACE 1                                                        49400013
GN37     MVI   WFRSTERR,X'00'       RESTORE FIRST ERROR OPTION INDIC.   49500013
         TM    PPIMODEX+1,X'01'     USER EXIT E29 ACTIVATED?            49600013
         BZ    GN42                 BRANCH ON NO                        49700013
         SPACE 2                                                        49800013
*        BRANCH TO USER MODIFICATION EXIT E29                           49900013
         SPACE 1                                                        50000013
         L     RP,PPIX29+4          LOAD ADDRESS OF USER EXIT E29       50100013
         BALR  RO,RP               GO TO USER MOD EXIT E29              50200019
         SPACE 1                                                        50300013
GN38     CLI   0(RB),X'00'          ARE THERE MORE OPTIONS?             50400013
         BE    GN42                 BRANCH ON NO                        50500013
         CLI   0(RB),X'01'          IS THERE A USER SYNAD OPTION?       50600013
         BE    GN40                 BRANCH ON YES                       50700013
         CLI   0(RB),X'02'          IS THERE A USER EXLST OPTION?       50800013
         BE    GN41                 BRANCH ON YES                       50900013
         SPACE 2                                                        51000013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         51100013
         SPACE 1                                                        51200013
         TM    WFRSTERR,X'01'       FIRST ERROR OPTION?                 51300013
         BO    GN39                 BRANCH ON NO                        51400013
         OI    WFRSTERR,X'81'       ON YES, SET INDICATOR               51500013
         L     RO,PPIAMA+4          MESSAGE ADDRESS                     51600013
         MVC   DCBERREX+16(2),KTAG+6 MOVE '29' INTO ERROR MESSAGE       51700013
         B     GN21                 BRANCH TO BRANCH TO PRINT ROUTINE   51800013
         SPACE 2                                                        51900013
*        ARE THERE MORE OPTIONS?                                        52000013
         SPACE 1                                                        52100013
GN39     TM    WFRSTERR,X'02'       IS THIS THE SECOND TIME THRU LOOP?  52200013
         BO    GN42                GO TO SET UP PARAM FOR LOOP          52300019
         OI    WFRSTERR,X'02'       SET ONCE THRU LOOP INDICATOR        52400013
         LA    RB,4(RB)             UPDATE POINTER TO USER PARAMS       52500013
         B     GN38                 GO THRU LOOP AGAIN                  52600013
         SPACE 1                                                        52700013
GN40     L     RP,PPIOPEN+4        LOAD BASE REG FOR OPEN LIST DSECT    52800013
         MVC   AP1WRT2+1(3),1(RB)  MOVE USER SYNAD INTO OPEN LIST       52900013
         B     GN39                 DO I GO THRU LOOP AGAIN?            53000013
GN41     TM    WFRSTERR+1,X'FF'     WAS USER EXIT E19 EXLST SWITCH SET? 53100013
         BO    GN39                IF ON, IGNORE. GO THRU LOOP AGAIN    53200013
         MVC   DCBEXLST+1(3),1(RB)  OTHERWISE, STORE EXLST AD IN DCB    53300013
         B     GN39                 DO I GO THRU LOOP AGAIN?            53400013
         SPACE 2                                                        53500013
*        ENTRIES MADE, RETURN TO MAIN AND SET UP PARAMS FOR LOOP        53600013
         SPACE 1                                                        53700013
GN42     LA    RA,1                INITIALIZE COUNTER FOR LOOP -        53800013
         AH    RA,PPIMRGMX           EQUALS NO. OUTPUR DCB'S            53900013
         L     RB,WOUTSIZE          LOAD SIZE OF EXCP DCB               54000013
         BCTR  RB,0                 DECREMENT BY ONE FOR EX INSTRUCTION 54100013
         L     RD,WDCBADR           LOAD ADDRESS OF DCB AREA IN CORE    54200013
         L     RC,WECBADR           LOAD ADDRESS OF ECB/IOB AREA IN COR 54300013
         LA    RE,KTABLE            LOAD ADDRESS OF SORTWK ID'S TABLE   54400013
         L     RF,WADOPEN           LOAD AD OF UPDATED OPEN LIST PTR    54500013
         L     RG,WDCBTAB           LOAD AD OF DCB ADDRESS TABLE        54600013
         LR    RH,RD                                                    54700013
         S     RH,WOUTADJ           LOAD AD OF AJUSTED DCB AREA IN CORE 54800013
         LR    RI,RC                                                    54900013
         LA    RI,8(RI)             LOAD ADDRESS OF FIRST IOB           55000013
         LA    RJ,PPITPTBL          LOAD ADDRESS OF THE TAPE TABLE      55100013
         SPACE 2                                                        55200013
*        LOOP                                                           55300013
         SPACE 1                                                        55400013
GN43     ST    RC,WECBPTR           STORE ECB ADDRESS IN MODEL IOB      55500013
         ST    RH,WDCBPTR           STORE DCB ADDRESS IN MODEL IOB      55600013
         ST    RI,DCBIOBAD          STORE IOB ADDRESS IN MODEL EXCP DCB 55700013
         SR    RK,RK                                                    55800013
         IC    RK,1(RJ)             PICK UP INCREMENT FROM TAPE TABLE   55900013
         ST    RH,0(RK,RG)          STORE DCB ADDRESS IN DCB AD TABLE   56000013
         SRL   RK,1                 DIVIDE INCREMENT BY TWO             56100013
         AR    RK,RE                ADD TO IT ADDRESS OF DCB ID TABLE   56200013
         MVC   DCBDDNAM+6(2),0(RK)  STORE DCB SORTWK IDENTITY NUMBER    56300013
         ST    RH,0(RF)             STORE DCB ADDRESS IN OPEN LIST      56400013
         EX    RB,GNMOVE            MOVE MODEL EXCP DCB MODEL INTO CORE 56500013
         MVC   0(40,RC),WIOBMDL     MOVE MODEL ECB/IOB INTO CORE        56600013
         BCT   RA,GN44              DO I GO THRU LOOP AGAIN             56700013
         SPACE 1                                                        56720017
         MVC   36(2,RC),K1         MOVE PLUS ONE INTO THE IOB BLK COUNT 56740017
*                                    INCREMENT                          56760017
         SPACE 2                                                        56800013
*        RETURN TO CALLING ROUTINE                                      56900013
         SPACE 1                                                        57000013
         LM    RA,RP,WSAVAREA      RESTORE REGISTERS                    57100013
         BR    RO                   RETURN TO LOAD ROUTINE, IERRC9      57200013
         SPACE 2                                                        57300013
*        UPDATE POINTERS TO GO THRU LOOP AGAIN                          57400013
         SPACE 1                                                        57500013
GN44     LA    RC,40(RC)            UPDATE ECB/IOB AREA PTR IN CORE     57600013
         A     RD,WOUTSIZE          UPDATE DCB AREA PTR IN CORE         57700013
         LA    RF,4(RF)             UPDATE OPEN LIST POINTER            57800013
         A     RH,WOUTSIZE          UPDATE ADJ DCB ADDRESS IN CORE      57900013
         LA    RI,40(RI)            UPDATE IOB PTR IN CORE              58000013
         LA    RJ,2(RJ)             UPDATE POINTER IN PPITPTBL          58100013
         B     GN43                 GO THRU LOOP AGAIN                  58200013
         SPACE 3                                                        58300013
*        EXECUTED MOVE INSTRUCTION                                      58400013
         SPACE 1                                                        58500013
GNMOVE   MVC   0(1,RD),0(RM)        MOVE MODEL DCB INTO ALLOCATED CORE  58600013
         SPACE 2                                                        58700013
*        LIST OF CONSTANTS USED BY THIS PROGRAM                         58800013
         SPACE 1                                                        58900013
K1       DC    H'1'                USED FOR OUTPUT IOB BLK COUNT INC.   58950017
KFOUR    DC    F'4'                 USED TO TEST VALID USER OPTION CODE 59000013
KSIGNBIT DC    X'80000000'                                              59100013
KINPID   DC    C'SORTIN  '          DDNAME FOR INPUT QSAM DCB           59200013
KOUTID   DC    C'SORTWK  '          DDNAME FOR OUTPUT EXCP DCB          59300013
KTABLE   DC    C'000102030405060708' NUMBERS FOR SORTWK DCB'S           59400013
         DC    C'091011121314151617'   DDNAME FIELD                     59500013
KTAG     DC    C'18281929'          USER EXIT NUMBER PUT IN ERROR MSG   59600013
         SPACE 2                                                        59700013
*        LIST  OF WORK AREAS USED BY THIS MODULE                        59800013
         SPACE 1                                                        59900013
WADOPEN  DC    F'0'                 UPDATED ADDRESS IN OPEN LIST        60000013
WDCBADR  DC    F'0'                 UPDATED ADDRESS OF DCB AREA IN CORE 60100013
WDCBTAB  DC    F'0'                 ADDRESS OF DCB AD TABLE IN GEN CORE 60200013
WECBADR  DC    F'0'                 ADDRESS OF ECB/IOB AREA IN GEN CORE 60300013
WFRSTERR DC    F'0'                 GENERAL SWITCH                      60400013
WINADJ   DC    F'0'                 INPUT DCB ADDRESS ADJUSTMENT FACTOR 60500013
WINSIZE  DC    F'0'                 SIZE OF INPUT QSAM DCB              60600013
WOUTADJ  DC    F'0'                 OUTPUT DCB AD ADJUSTMENT FACTOR     60700013
WOUTSIZE DC    F'0'                 SIZE OF OUTPUT EXCP DCB             60800013
WREGS    DC    8F'0'               SAVE AREA DURING PRINT ROUTINE       60900013
WSAVAREA DC    16F'0'               GENERAL REGISTER SAVE AREA          61000013
         SPACE 2                                                        61100013
*        IOB MODEL USED BY PROGRAM                                      61200013
         SPACE 1                                                        61300013
WIOBMDL  DC    3F'0'                IOB IS PRECEDED BY A FULL WORD      61400013
WECBPTR  DC    4F'0'                    EVENT CONTROL BLOCK AND A FULL  61500013
WDCBPTR  DC    X'00000000'         CON                                  61600019
         DC    X'00000000'            STA                               61700019
         DC    X'FFFF0000'               NTS                            61800019
         SPACE 2                                                        61900013
*        OPEN LIST DSECT USED BY MODULE                                 62000013
         SPACE 1                                                        62100013
OPENLIST DSECT                                                          62200013
         DC    19F'0'              OPEN LIST DSECT                      62300019
AP1RD2   DC    X'20000000'         USER SYNAD AND EROPT, READ - PH2     62400013
AP1WRT1  DC    F'0'                USER SYNAD, WRITE - PH1              62500013
AP1WRT2  DC    F'0'                USER SYNAD, WRITE - PH2              62600013
         SPACE 2                                                        62700013
*          DSECT OF MESSAGE MODULE, IERAMA. THIS MODULE CONTAINS ALL    62800013
*        OF THE MESSAGES THAT ARE REQUIRED FOR PHASE 1 ASSIGNMENT       62900013
*        MODULES.                                                       63000013
         SPACE 1                                                        63100013
DIERAMA  DSECT                                                          63200013
*                                                                       63300013
       COPY  AMAMAIN                                                    63400013
         SPACE 2                                                        63500013
*        MODEL DATA CONTROL BLOCKS USED BY PROGRAM                      63600013
         SPACE 1                                                        63700013
IERAGN   CSECT                                                          63800013
         DC    X'000000'           DATA CONTROL                         63900019
KMARK1   DC    X'FF'                  BLOCK                             64000019
WEXCPDCB DCB   MACRF=(E),DSORG=PS,DDNAME=SORTWK,REPOS=Y            I303 64100019
KMARK2   DC    X'FF0000'                                                64200013
         SPACE 2                                                        64300013
KMARK3   DC    X'FF'                                                    64400013
WQSAMDCB DCB   MACRF=(GL),DSORG=PS,DDNAME=SORTIN                        64500019
KMARK4   DC    X'FF'                                                    64600013
         SPACE 2                                                        64700013
*        DATA CONTROL BLOCK DSECT USED BY MODULE                        64800013
         DCBD  DSORG=PS                                                 64900013
         SPACE 2                                                        65000013
         SMPPI                                                          65100013
         END                                                            65200013
