         TITLE ' IERAOC - OS/360 SORT/MERGE - 360S-SM-023 02/24/65 '    00100013
         SPACE 1                                                        00200013
*MODULE NAME:*** IERAOC ***                                             00300013
         SPACE 2                                                        00400013
*STATUS: CHANGE LEVEL 000                                               00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT FOR VARIABLE LENGTH      00700013
*   REPLACEMENT WITH MULTIPLE CONTROL FIELDS. THE FUNCTION OF THIS      00800013
*   MODULE IS TO GENERATE THE REPLACEMENT TREE IN GENERATED CORE,       00900013
*   CHANGE THE CONDITIONS FOR BRANCHING IN THE RUNNING PROGRAM IF THE   01000013
*   RECORDS ARE TO BE COLLATED IN DESCENDING ORDER IN THE FIRST         01100013
*   SEQUENCE, AND OTHERWISE INITIALIZE THE COMPARE INSTRUCTIONS IN THE  01200013
*   RUNNING PROGRAM.                                                    01300013
         SPACE 2                                                        01400013
*USED AS A DSECT IN'                                                    01500013
*                                                                       01600013
*   N/A                                                                 01700013
*                                                                       01800013
*MACROS USED'                                                           01900013
*                                                                       02000013
*   N/A                                                                 02100013
*                                                                       02200013
*MACROS USED'                                                           02300013
         SPACE 1                                                        02400013
*   SMPPI                                                               02500013
         SPACE 2                                                        02600013
*ENTRY POINTS:                                                          02700013
         SPACE 1                                                        02800013
*        ENTRY IERMOA              ENTRY FROM: LOAD MODULE, IERRC9      02900013
*                                    CALLING SEQUENCE-                  03000013
*                                      LOAD   EP=IERAOC,DCB=            03100013
*                                      LR     RP,RA                     03200013
*                                      BALR   RO,RP                     03300013
         SPACE 2                                                        03400013
*   PPISW1&3,X@10@                                                      03500013
*   PPIDDOL1                                                            03600013
*   PPISRTG     PPISPGN1                                                03700013
*   PPIAXERT    PPINET+4                                                03800013
*   PPISW1&3,X@10@                                                      03900013
*   PPIDDOL1                                                            04000013
         SPACE 2                                                        04100013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             04200013
         SPACE 1                                                        04300013
*    PPISPGN1                                                           04400013
*    REPLACEMENT TREE IS CREATED IN GENERATED CORE.                     04500013
         SPACE 2                                                        04600013
*EXTERNAL ROUTINES:                                                     04700013
         SPACE 1                                                        04800013
*        N/A                                                            04900013
         SPACE 2                                                        05000013
*EXTERNAL PARAMETERS:                                                   05100013
         SPACE 1                                                        05200013
*        N/A                                                            05300013
         SPACE 2                                                        05400013
*EXITS: NORMAL                                                          05500013
         SPACE 1                                                        05600013
*        BR    RO - RETURN TO LOAD ROUTINE, IERRC9                      05700013
         SPACE 2                                                        05800013
*EXITS ERROR                                                            05900013
         SPACE 1                                                        06000013
*        N/A                                                            06100013
         SPACE 2                                                        06200013
*TABLES/WORK AREAS:                                                     06300013
         SPACE 1                                                        06400013
*      WOCDISP - FULL WORD USED TO HOLD DISPLACEMENT FIELD FOR ORING    06500013
*    THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN THE RUNNING 06600013
*    RPOGRAM IN ORDER TO INITIALIZE THEM AS NECESSARY.                  06700013
*      WRSAVC9, A FULL WORD, IS USED TO HOLD THE ADDRESS OF THE CALLING 06800013
*    ROUTINE, THE LOAD MODULE IERRC9.                                   06900013
         SPACE 2                                                        07000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07100013
         SPACE 2                                                        07200013
*NOTES:                                                                 07300013
         SPACE 1                                                        07400013
*   THIS MODULE IS USED WITH VARIABEL LENGTH RECORDS WITH MULTIPLE      07500013
*    CONTROL FIELDS.                                                    07600013
         SPACE 2                                                        07700013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07800013
         SPACE 1                                                        07900013
RA       EQU   0                   CONTENTS IN- N/A                     08000013
*                                  USE- NOT USED                        08100013
*                                  CONTENTS OUT- N/A                    08200013
RB       EQU   1                   CONTENTS IN- N/A                     08300013
*                                  USE- NOT USED                        08400013
*                                  CONTENTS OUT- N/A                    08500013
RC       EQU   2                   CONTENTS IN- N/A                     08600013
*                                  USE- WORK REGISTER                   08700013
*                                  CONTENTS OUT- N/A                    08800013
RD       EQU   3                   CONTENTS IN- N/A                     08900013
*                                  USE- WORK REGISTER                   09000013
*                                  CONTENTS OUT- N/A                    09100013
RE       EQU   4                   CONTENTS IN- N/A                     09200013
*                                  USE- WORK REGISTER, NEXT LEVEL       09300013
*                                       ADDRESS                         09400013
*                                  CONTENTS OUT- N/A                    09500013
RF       EQU   5                   CONTENTS IN- N/A                     09600013
*                                  USE- WORK REGISTER, FORMAT           09700013
*                                  CONTENTS OUT- N/A                    09800013
RG       EQU   6                   CONTENTS IN- N/A                     09900013
*                                  USE- WORK REGISTER                   10000013
*                                  CONTENTS OUT- N/A                    10100013
RH       EQU   7                   CONTENTS IN- N/A                     10200013
*                                  USE- NODE OR WAY COUNTER             10300013
*                                  CONTENTS OUT- N/A                    10400013
RI       EQU   8                   CONTENTS IN- N/A                     10500013
*                                  USE- G COUNT                         10600013
*                                  CONTENTS OUT- N/A                    10700013
RJ       EQU   9                   CONTENTS IN- N/A                     10800013
*                                  USE- WORK REGISTER                   10900013
*                                  CONTENTS OUT- N/A                    11000013
RK       EQU   10                  CONTENTS IN- N/A                     11100013
*                                  USE- RECORD COUNTER                  11200013
*                                  CONTENTS OUT- N/A                    11300013
RL       EQU   11                  CONTENTS IN- N/A                     11400013
*                                  USE- PROGRAM BASE REGISTER           11500013
*                                  CONTENTS OUT- N/A                    11600013
RM       EQU   12                  CONTENTS IN- N/A                     11700013
*                                  USE- EQUALS BASE REGISTER            11800013
*                                  CONTENTS OUT- N/A                    11900013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          12000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     12100013
*                                    AREA                               12200013
*                                  CONTENTS OUT- ADDRESS OF PPI         12300013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      12400013
*                                                IERRC9                 12500013
*                                  USE- BASE REGISTER FOR DSECT OF      12600013
*                                       IERROC                          12700013
*                                  CONTENTS OUT - RETURN ADDRESS IN     12800013
*                                                 IERRC9                12900013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMOA 13000013
*                                  USE- NOT USED                        13100013
*                                  CONTENTS OUT- N/A                    13200013
         SPACE 2                                                        13300013
*START OF MODULE CODE PROPER:                                           13400013
         SPACE 2                                                        13500013
         SPACE 1                                                        13600013
IERAOC   CSECT                                                          13700013
         USING *,RL                                                     13800013
         USING IERRCA,RN                                                13900013
         USING DIERROC,RO                                               14000013
IERMOA   LR    RL,RP               SET PROGRAM BASE REGISTER            14100013
         ST    RO,WRSAVC9                                               14200013
         L     RO,PPINET+4          SET DSECT REGISTER OF RUNNING MOD   14300013
         SPACE 1                                                        14400013
* DETERMINE SIZE OF AREA FOR GENERATING THE TREE,RESET THE ADDRESS OF   14500013
* THE GENERATED AREA BY THIS AMOUNT,AND SAVE THIS ADDRESS FOR THE       14600013
* NETWORK AS THE TREE ADDRESS AND FOR THE NEXT ROUTINE AS THE           14700013
* ADDRESS OF THE GENERATED AREA.                                        14800013
         SPACE 1                                                        14900013
         L     RI,PPISRTG          G OR NUMBER OF RECORDS FOR TREE      15000013
         LA    RK,1                RECORD COUNTER-RECORDS TREE CAN HOLD 15100013
         LA    RC,12               BYTES PER NODE                       15200013
         LR    RF,RI               G OR NUMBER OF RECORDS FOR TREE      15300013
         SR    RF,RK               FORM G-1                             15400013
         SR    RE,RE               ZERO REGISTER                        15500013
         MR    RE,RC               CALCULATE NUMBER OF BYTES IN TREE    15600013
         LA    RJ,36               SIZE OF MINIMUM TREE                 15700013
         CR    RF,RJ               IS CALCULATED SIZE EQ OR G. MINIMUM  15800013
         BNL   OCOKSIZE            BRANCH IF IT IS                      15900013
         LR    RF,RJ               SET TREE SIZE TO MINIMUM             16000013
OCOKSIZE TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               16100013
         BNO   AOCNOMES            SWITCH OFF BYPASS MESSAGE            16200013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  16300013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       16400013
         STM   RO,RB,AOCSAVO       SAVE REGISTER                        16500013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    16600013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           16700013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    16800013
         BAL   RO,4(RP)                                                 16900013
         MVC   DMSG904B(8),0(RB)       MOVE NUMBER INTO MESSAGE         17000013
         L     RJ,OASAVEJ         RESTORE RJ                            17100013
         LM    RO,RB,AOCSAVO       RESTORE REGISTERS                    17200013
         DROP  RJ                                                       17300013
AOCNOMES L     RG,PPISPGN1         ADDRESS OF GENERATED CODE            17400013
         SR    RG,RF               DECREMENT ADDRESS OF GENERATED CODE  17500013
         SRL   RG,2                  ROUND DOWN TO                      17600013
         SLL   RG,2                  FULL WORDS                         17700013
         ST    RG,PPISPGN1         RESET NEW ADDRESS OF GENERATED CODE  17800013
         ST    RG,WCTREE           STORE THIS TREE ADDRESS IN NETWORK   17900013
         TM    PPISW1+6,X'01'     TEST DIAGNOSTIC SWITCH                18000013
         BNO   OANOMESS           SWITCH OFF BYPASS MESSAGE             18100013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  18200013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       18300013
         STM   RO,RB,AOCSAVO       SAVE REGISTERS                       18400013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    18500013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           18600013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    18700013
         BAL   RO,4(RP)                                                 18800013
         MVC   DMSG904A(8),0(RB)       MOVE NUMBER INTO MESSAGE         18900013
         LM    RA,RB,DMSG904X     SET UP FOR BRANCH TO PRINT            19000013
         L     RP,PPIADSSC        LOAD ADDRESS OF PRINT ROUTINE         19100013
         BAL   RO,12(0,RP)        BRANCH TO PRINT MESSAGE               19200013
         L     RJ,OASAVEJ         RESTORE RJ                            19300013
         LM    RO,RB,AOCSAVO       RESTORE REGISTERS                    19400013
         DROP  RJ                                                       19500013
         SPACE 1                                                        19600013
* SET BASE REGISTER FOR EQUALS ROUTINE                                  19700013
         SPACE 1                                                        19800013
OANOMESS L     RM,PPIAXERT        SET BASE REGISTER OF EQUALS ROUTINE   19900013
         SPACE 1                                                        20000013
* SET UP ANY ADDITIONAL CONSTANTS REQUIRED TO GENERATE TREE             20100013
         SPACE 1                                                        20200013
         LR    RJ,RG               NEXT LEVEL ADDR FOR PREVIOUS LEVEL   20300013
         LA    RH,2                WAY OR NODE COUNTER                  20400013
         LA    RE,WCLTNODE         ADDRESS OF LAST TEST NODE            20500013
         SR    RF,RF               SET FORMAT OF THIS NODE TO ZERO      20600013
         SPACE 1                                                        20700013
* GENERATE THE REQUIRED TREE                                            20800013
         SPACE 1                                                        20900013
OCSTTREE STM   RE,RF,0(RG)         STORE NLA AND FORMAT OF NODE         21000013
         LA    RK,1(0,RK)          INC RECORD COUNTER BY 1 EACH NODE    21100013
         CR    RK,RI               RECORDS TREE HOLDS NOW TO REQD NO.   21200013
         BNL   OCENOUGH            NO MORE NODES REQUIRED               21300013
         LA    RG,12(0,RG)         INCREMENT TO LOCATION OF NEXT NODE   21400013
         LR    RE,RJ               SET NEXT LEVEL ADDRESS               21500013
         BCT   RH,OCSTTREE         BRANCH IF NODE COUNTER NOT ZERO      21600013
         LA    RH,2                RESET NODE OR WAY COUNTER            21700013
         LA    RJ,12(0,RJ)         INCREMENT NEXT LEVEL ADDRESS         21800013
         B     OCSTTREE                                                 21900013
         SPACE 2                                                        22000013
* SAVE TREE INFORMATION FOR THE NETWORK                                 22100013
         SPACE 1                                                        22200013
OCENOUGH STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               22300013
         SPACE 1                                                        22400013
* IF COLLATING ORDER OF FIRST SEQUENCE IS TO BE DECENDING,REVERSE THE   22500013
* NECESSARY CONDITIONAL BRANCHES IN THE RUNNING ROUTINE.                22600013
         SPACE 1                                                        22700013
         TM    PPISW1+3,X'10'      TEST BIT INDICATING COLLATING ORDER  22800013
         BZ    OCASCEND            BRANCH IF BIT IS OFF-ORDER IS ASCEND 22900013
         XI    OCC24A+1,X'60'      REVERSE CONDITIONAL BRANCH IN NETWOR 23000013
         XI    OCSCHECK+1,X'60'    REVERSE CONDITIONAL BRANCH IN SEQCK  23100013
         SPACE 1                                                        23200013
* INITIALIZE THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN     23300013
* THE RUNNING ROUTINE AS NECESSARY.                                     23400013
         SPACE 1                                                        23500013
OCASCEND LH    RE,PPIDD0L1         DISPLACEMENT OF FIRST CONTROL FIELD  23600013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT FOR TREE ADDR 23700013
         STH   RE,WOCDISP            SET UP DISPLACEMENT                23800013
         STH   RE,WOCDISP+2          FIELDS FOR ORING                   23900013
         OC    OCCASE24+2(4),WOCDISP  INITIALIZE DISP IN CLC IN NETWORK 24000013
         OC    OCGOTRUN+26(4),WOCDISP INITIALIZE DISP IN CLC IN SEQCK   24100013
         SPACE 1                                                        24200013
* INITIALIZE THE LENGTH FIELDS IN THE COMPARE INSTRUCTIONS IN           24300013
* THE RUNNING ROUTINE AS NECESSARY.                                     24400013
         SPACE 1                                                        24500013
         IC    RE,PPIDD0L1+3       LENGTH OF 1ST CONTROL FIELD FOR CLC  24600013
         STC   RE,OCCASE24+1       SET LENGTH FIELD IN CLC IN NETWORK   24700013
         STC   RE,OCGOTRUN+25      SET LENGTH FIELD IN CLC IN SEQCK     24800013
         SPACE 1                                                        24900013
* EXIT TO NEXT ASSIGNMENT ROUTINE.                                      25000013
         SPACE 1                                                        25100013
         L     RO,WRSAVC9           RESTORE RETURN ADDRESS              25200013
         BR    RO                   RETURN TO LOAD ROUTINE              25300013
         SPACE 2                                                        25400013
         SPACE 1                                                        25500013
*** WORK AREAS ***                                                      25600013
         SPACE 1                                                        25700013
WOCDISP  DS    1F                  USED TO HOLD DISP FIELDS FOR ORING   25800013
WRSAVC9  DS    F                    USED TO SAVE REGISTER RO            25900013
OASAVEJ  DC    F'0'                                                     26000013
AOCSAVO  DC    4F'0'                                                    26100013
         EJECT                                                          26200013
         SPACE 1                                                        26300013
*** IERROC *** REPLACEMENT NETWORK FOR VARIABLE LENGTH RECORDS          26400013
*              CONTAINING MULTIPLE CONTROL FIELDS.                      26500013
         SPACE 1                                                        26600013
*********************************************************************** 26700013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROC                   26800013
*********************************************************************** 26900013
         SPACE 1                                                        27000013
DICLOSE1 EQU   4                   DISP IN CLOSE BRANCH TABLE           27100013
DIDEBLK1 EQU   8                   DISP IN DEBLK BR TBL (GET TO FILL)   27200013
DIDEBLK2 EQU   0                   DISP IN DEBLK BR TBL (MODIFY + GET)  27300013
DIBLOCK1 EQU   12                  DISP IN BLOCK BR TBL (PUT INFER GET) 27400013
DIBLOCK2 EQU   4                   DISP IN BLOCK BR TBL (PUT EOS)       27500013
DIBLOCK3 EQU   0                   DISP IN BLOCK BR TBL (PUT EOF)       27600013
         SPACE 1                                                        27700013
DIERROC  DSECT                                                          27800013
         SPACE 1                                                        27900013
*** ENTRY TABLE                                                         28000013
         SPACE 1                                                        28100013
IERDOA   B     OCPICK              ENTRY TO FILL TREE                   28200013
         B     OCGOTFIL            ENTRY FROM DEBLK WHILE FILLING (FIT) 28300013
         B     OCEOF               ENTRY FROM DEBLK AT EOF              28400013
         B     OCGOTRUN            ENTRY FROM DEBLK WHILE RUNNING (FIT) 28500013
         B     OCRETEOF            ENTRY FROM DEBLK AFTER EOF           28600013
         DC    A(0)                SPACE TO KEEP INC IN ENTRY TABLE     28700013
         B     OCNOGOFI            ENTRY FROM DEBLK WHILE FILLING-NOFIT 28800013
         B     OCNOGORN            ENTRY FROM DEBLK WHILE RUNNING-NOFIT 28900013
         SPACE 2                                                        29000013
* INITIAL ENTRY  TO START FILLING OR ENTRY TO CONTINUE FILLING TREE.    29100013
         SPACE 1                                                        29200013
OCPICK   L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               29300013
         SPACE 1                                                        29400013
* EXIT TO DEBLOCK ROUTINE                                               29500013
         SPACE 1                                                        29600013
         B     DIDEBLK1(0,RL)      GET TO FILL                          29700013
         SPACE 2                                                        29800013
* SETS UP TO FILL THE TREE WITH REAL OR IMAGINARY RECORDS AND           29900013
* DETERMINES WHEN THE TREE IS FILLED.                                   30000013
         SPACE 1                                                        30100013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD FITS)                        30200013
         SPACE 1                                                        30300013
OCGOTFIL LM    RH,RJ,WCSAVE        FILLING REGISTERS                    30400013
         L     RE,OCSAME           UPDATE MODE                          30500013
         S     RD,KCFOUR           DECREMENT NEW ADDR BY FOUR BYTES     30600013
         ST    RJ,0(0,RD)          ADDRESS OF TREE WITH RECORD          30700013
OCSUBFIT LR    RF,RJ               ADDRESS OF TREE (NEXT LEVEL ADDR)    30800013
         BCT   RH,OCGCT            DECREMENT WAY COUNTER                30900013
         LA    RH,2                RESET WAY COUNTER                    31000013
         LA    RJ,12(0,RJ)         INCREMENT TO NEXT NODE               31100013
OCGCT    BCT   RI,OCFILREG         DECREMENT G COUNTER                  31200013
         STM   RH,RJ,WCSAVE                                             31300013
         B     OCNEXT2                                                  31400013
         SPACE 2                                                        31500013
OCFILREG STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               31600013
         B     OCNEXT2                                                  31700013
         SPACE 2                                                        31800013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD DOES NOT FIT)                31900013
         SPACE 1                                                        32000013
OCNOGOFI LM    RH,RJ,WCSAVE        FILLING REGISTERS                    32100013
         L     RE,OCSTEMP          UPDATE MODE                          32200013
         LR    RD,RJ               USE TREE ADDRESS AS WINNER           32300013
         B     OCSUBFIT                                                 32400013
         SPACE 2                                                        32500013
* DETERMINES IF EOF SITUATION IS A NORMAL ONE, FILE SIZE LESS           32600013
* THEN G, OR FILE SIZE IS ZERO AND BRANCHES ACCORDINGLY.                32700013
         SPACE 1                                                        32800013
* ENTRY FROM DEBLOCK AT EOF                                             32900013
         SPACE 1                                                        33000013
OCEOF    CLC   PPISRTG(4),WCSAVE+4 COMPARE G COUNT IN PPIA TO FILL NO.  33100013
         BNE   OCNOZERO                                                 33200013
         L     RP,PPIRCV+4          CLOSE BASE REGISTER                 33300013
         SPACE 1                                                        33400013
* EXIT TO CLOSE ROUTINE                                                 33500013
         SPACE 1                                                        33600013
         LA    RB,4                 SET CODE TO CALL PHASE 3            33700013
         B     20(RP)              INPUT FILE WAS ZERO                  33800013
         SPACE 2                                                        33900013
OCNOZERO MVC   OCC7A(8),OCC7EOF    MODIFY CASE7 TO FORCE TREE FLUSHING  34000013
         LA    RK,0                CONSTANT OF 0                        34100013
         CL    RK,WCSAVE+4         COMPARE TO FILL COUNT                34200013
         BE    OCRETEOF                                                 34300013
         SPACE 1                                                        34400013
* FILE SIZE IS LESS THAN G. THE CODING IS MODIFIED TO FILL THE          34500013
* REMAINDER OF THE TREE WITH IMAGINARY RECORDS (T1).                    34600013
         SPACE 1                                                        34700013
         OI    OCC8A+1,X'F0'       INITIALIZE BRANCH INST IN CASE8      34800013
         MVC   OCPICK(4),OCMODIFY  MODIFY FILLING RETURN LOCATION       34900013
OCMODIFY B     OCNOGOFI                                                 35000013
         SPACE 2                                                        35100013
* MODE POSITIONS AND BRANCH TABLE.                                      35200013
* THROUGH THE COMBINATION OF MODE AND FORMAT AN INDEXED                 35300013
* BRANCH IS PERFORMED WHICH BRANCHES TO THE CASE WHICH                  35400013
* HANDLES THE INDICATED SITUATION.                                      35500013
         SPACE 1                                                        35600013
OCNTEMP  DC    A(OCBTABLE)                                              35700013
OCNEW    DC    A(OCBTABLE+4)                                            35800013
OCSTEMP  DC    A(OCBTABLE+8)                                            35900013
OCSAME   DC    A(OCBTABLE+12)                                           36000013
OCBTABLE DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 36100013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 36200013
         B     OCCASE3                                                  36300013
         B     OCCASE4                                                  36400013
         B     OCCASE5                                                  36500013
         B     OCCASE6                                                  36600013
         B     OCCASE7                                                  36700013
OCMODLOC B     OCCASE8                                                  36800013
         B     OCCASE9                                                  36900013
         B     OCCASE10                                                 37000013
         B     OCNEXT                                                   37100013
         B     OCNEXT                                                   37200013
         B     OCCASE13                                                 37300013
         B     OCCASE14                                                 37400013
         B     OCNEXT                                                   37500013
         B     OCNEXT                                                   37600013
         B     OCCASE17                                                 37700013
         B     OCCASE18                                                 37800013
         B     OCNEXT                                                   37900013
         B     OCNEXT                                                   38000013
         B     OCCASE21                                                 38100013
         B     OCCASE22                                                 38200013
         B     OCCASE23                                                 38300013
         B     OCCASE24                                                 38400013
         SPACE 2                                                        38500013
* THIS CASE HANDLES AN S1/S1 SITUATION.                                 38600013
         SPACE 1                                                        38700013
OCCASE24 CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              38800013
         BNE   OCC24A                                                   38900013
         LR    RC,RH               LOAD ADDRESS FOR EQUALS              39000013
         SPACE 1                                                        39100013
* EXIT TO EQUALS ROUTINE                                                39200013
         SPACE 1                                                        39300013
         BALR  RO,RM               LINK TO EQUALS ROUTINE               39400013
         SPACE 2                                                        39500013
OCC24A   BNH   OCNEXT                                                   39600013
OCEXCH   ST    RD,8(0,RF)          WINNER TO LOSER                      39700013
         LR    RD,RH               LOSER TO WINNER                      39800013
OCNEXT   L     RF,0(0,RF)          ADDRRSS OF NEXT NODE                 39900013
OCNEXT2  LM    RG,RH,4(RF)         LOAD NODE                            40000013
         B     0(RE,RG)            GO TO PROPER CASE                    40100013
         SPACE 2                                                        40200013
* THIS CASE HANDLES A T1/S1 SITUATION.                                  40300013
         SPACE 1                                                        40400013
OCCASE23 L     RE,OCSAME           UPDATE MODE                          40500013
         LA    RK,64               FORMAT T1                            40600013
         ST    RK,4(0,RF)          UPDATE FORMAT                        40700013
         B     OCEXCH                                                   40800013
         SPACE 2                                                        40900013
* THIS CASE HANDLES AN S2/S1 SITUATION.                                 41000013
         SPACE 1                                                        41100013
OCCASE22 L     RE,OCSAME           UPDATE MODE                          41200013
         LA    RK,48               FORMAT S2                            41300013
         ST    RK,4(0,RF)          UPDATE FORMAT                        41400013
         B     OCEXCH                                                   41500013
         SPACE 2                                                        41600013
* THIS CASE HANDLES A T2/S1 SITUATION.                                  41700013
         SPACE 1                                                        41800013
OCCASE21 L     RE,OCSAME           UPDATE MODE                          41900013
         LA    RK,32               FORMAT T2                            42000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        42100013
         B     OCEXCH                                                   42200013
         SPACE 2                                                        42300013
* THIS CASE HANDLES AN S2/T1 SITUATION.                                 42400013
         SPACE 1                                                        42500013
OCCASE18 L     RE,OCSTEMP          UPDATE MODE                          42600013
         LA    RK,48               FORMAT S2                            42700013
         ST    RK,4(0,RF)          UPDATE FORMAT                        42800013
         B     OCEXCH                                                   42900013
         SPACE 2                                                        43000013
* THIS CASE HANDLES A T2/T1 SITUATION.                                  43100013
         SPACE 1                                                        43200013
OCCASE17 L     RE,OCSTEMP          UPDATE MODE                          43300013
         LA    RK,32               FORMAT T2                            43400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        43500013
         B     OCEXCH                                                   43600013
         SPACE 2                                                        43700013
* THIS CASE HANDLES AN S2/S2 SITUATION.                                 43800013
         SPACE 1                                                        43900013
OCCASE14 LA    RK,80               FORMAT S1                            44000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        44100013
         B     OCCASE24                                                 44200013
         SPACE 2                                                        44300013
* THIS CASE HANDLES A T2/S2 SITUATION.                                  44400013
         SPACE 1                                                        44500013
OCCASE13 L     RE,OCNEW            UPDATE MODE                          44600013
         SPACE 1                                                        44700013
* THIS CASE HANDLES A T2/T2 SITUATION.                                  44800013
         SPACE 1                                                        44900013
OCCASE9  LA    RK,64               FORMAT T1                            45000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        45100013
         B     OCEXCH                                                   45200013
         SPACE 2                                                        45300013
* THIS CASE HANDLES AN S2/T2 SITUATION.                                 45400013
         SPACE 1                                                        45500013
OCCASE10 LA    RK,64               FORMAT T1                            45600013
         ST    RK,4(0,RF)          UPDATE FORMAT                        45700013
         B     OCNEXT                                                   45800013
         SPACE 2                                                        45900013
* INDICATES THE TREE IS FILLED AND FORCES THE NETWORK                   46000013
* INTO A RUNNING SITUATION.                                             46100013
         SPACE 1                                                        46200013
OCCASE8  ST    RD,WCLTNODE         SAVE ADDR OF RECD IN LAST TEST NODE  46300013
         MVC   OCMODLOC(4),OCMODC8 MODIFY BRANCH TABLE                  46400013
OCC8A    BC    0,OCRETEOF          INITIALIZED TO BRANCH AT FILE L.T. G 46500013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               46600013
         SPACE 1                                                        46700013
* EXIT TO DEBLOCK ROUTINE                                               46800013
         SPACE 1                                                        46900013
         B     DIDEBLK2(0,RL)      MODIFY AND GET                       47000013
         SPACE 2                                                        47100013
* INDICATES THERE IS A RECORD TO BE BLOCKED                             47200013
         SPACE 1                                                        47300013
OCCASE8A L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  47400013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  47500013
         LR    RD,RK               ADDRESS TO WINNER POSITION           47600013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         47700013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 47800013
         SPACE 1                                                        47900013
* EXIT TO BLOCK ROUTINE                                                 48000013
         SPACE 1                                                        48100013
         B     DIBLOCK1(0,RL)      PUT INFERS GET                       48200013
         SPACE 2                                                        48300013
* INDICATES THAT A T1 (IMAGINARY) HAS BEEN FORCED OUT OF THE TREE.      48400013
         SPACE 1                                                        48500013
OCCASE7  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  48600013
         ST    RD,0(0,RK)          NODE ADDR (T1) WITH RECORD HELD BACK 48700013
         LR    RF,RD               NODE ADDRESS AS NEXT LEVEL ADDRESS   48800013
OCC7A    L     RK,OCNTEMP          MODE NTEMP                           48900013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO NTEMP       49000013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               49100013
         SPACE 1                                                        49200013
* EXIT TO DEBLOCK ROUTINE                                               49300013
         SPACE 1                                                        49400013
         B     DIDEBLK1(0,RL)      GET TO FILL (DEBLOCK EXIT MODIFIED)  49500013
         SPACE 2                                                        49600013
* INDICATES THAT IT IS THE END OF A SEQUENCE.                           49700013
         SPACE 1                                                        49800013
OCCASE6  L     RK,OCSTEMP          MODE STEMP                           49900013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       50000013
         L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  50100013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  50200013
         LR    RD,RK               ADDRESS TO WINNER POSITION           50300013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         50400013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 50500013
         SPACE 1                                                        50600013
* EXIT TO BLOCK ROUTINE                                                 50700013
         SPACE 1                                                        50800013
         B     DIBLOCK2(0,RL)      PUT EOS                              50900013
         SPACE 2                                                        51000013
* INDICATES THAT IT IS END OF FILE.                                     51100013
         SPACE 1                                                        51200013
OCCASE5  L     RD,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  51300013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         51400013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 51500013
         SPACE 1                                                        51600013
* EXIT TO BLOCK ROUTINE                                                 51700013
         SPACE 1                                                        51800013
         B     DIBLOCK3(0,RL)      PUT EOF                              51900013
         SPACE 2                                                        52000013
* THIS CASE HANDLES AN S1/- SITUATION                                   52100013
         SPACE 1                                                        52200013
OCCASE4  ST    RD,8(0,RF)          WINNER TO LOSER                      52300013
         LA    RK,80               FORMATS1                             52400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        52500013
         B     OCPICK                                                   52600013
         SPACE 2                                                        52700013
* THIS CASE HANDLES A T1/- SITUATION                                    52800013
         SPACE 1                                                        52900013
OCCASE3  ST    RD,8(0,RF)          WINNER TO LOSER                      53000013
         LA    RK,64               FORMAT T1                            53100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        53200013
         B     OCPICK                                                   53300013
         SPACE 2                                                        53400013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD FITS)                        53500013
         SPACE 1                                                        53600013
* SEQUENCE CHECKS THE NEW RECORD AND STARTS IT                          53700013
* THROUGH THE REPLACEMENT NETWORK.                                      53800013
         SPACE 1                                                        53900013
OCGOTRUN S     RD,KCFOUR           DECREMENT NEW ADDR BY FOUR BYTES     54000013
         L     RK,OCSTEMP          MODE STEMP                           54100013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       54200013
         L     RC,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  54300013
         L     RF,0(0,RC)          NODE ADDRESS WITH RECORD HELD BACK   54400013
         ST    RF,0(0,RD)          NODE ADDRESS WITH NEW RECORD         54500013
         CLC   0(1,RD),0(RC)       COMPARE NEW RECORD TO ONE HELD BACK  54600013
         BNE   OCSCHECK                                                 54700013
         SPACE 1                                                        54800013
* EXIT TO EQUALS ROUTINE                                                54900013
         SPACE 1                                                        55000013
         BALR  RO,RM               LINK TO EQUALS ROUTINE               55100013
         SPACE 2                                                        55200013
OCSCHECK BL    OCMODNEW                                                 55300013
         L     RE,OCSAME           UPDATE MODE                          55400013
         B     OCNEXT2                                                  55500013
         SPACE 2                                                        55600013
OCMODNEW L     RE,OCNEW            UPDATE MODE                          55700013
         B     OCNEXT2                                                  55800013
         SPACE 2                                                        55900013
* SET UP TO FLUSH ANOTHER RECORD FROM THE TREE AFTER END OF             56000013
* FILE OR BECAUSE THE INCOMONG RECORD WILL NOT FIT.                     56100013
         SPACE 1                                                        56200013
* ENTRY FROM DEBLOCK AFTER EOF                                          56300013
         SPACE 1                                                        56400013
OCRETEOF L     RE,OCNTEMP          UPDATE MODE                          56500013
         B     OCSUBNO                                                  56600013
         SPACE 2                                                        56700013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD DOES NOT FIT)                56800013
         SPACE 1                                                        56900013
OCNOGORN L     RE,WCSPECL          UPDATE MODE                          57000013
OCSUBNO  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  57100013
         L     RF,0(0,RK)          NODE ADDRESS WITH RECORD HELD BACK   57200013
         LR    RD,RF               TREE ADDRESS AS WINNER               57300013
         B     OCNEXT2                                                  57400013
         SPACE 2                                                        57500013
         SPACE 1                                                        57600013
         SPACE 1                                                        57700013
*** CONSTANTS                                                           57800013
         SPACE 1                                                        57900013
KCFOUR   DC    F'4'                ADDRESS DECREMENT                    58000013
         SPACE 1                                                        58100013
*** WORK AREAS *** THE ORDERING OF THESE WORK AREAS MUST BE MAINTAINED  58200013
         SPACE 1                                                        58300013
WCSAVE   DS    3F                  FILLING REGISTER SAVE AREA           58400013
WCTREE   DS    1F                  LOCATION OF TREE                     58500013
WCLTNODE DS    1F                  LAST TEST NODE                       58600013
         DC    A(16)               FORMAT OF LAST TEST NODE             58700013
WCSPECL  DC    A(OCBTABLE+8)       SPECIAL (MODE) INDICATOR             58800013
         SPACE 1                                                        58900013
*** MODIFICATION INSTRUCTIONS *** THE ORDERING OF THESE INSTRUCTIONS    59000013
*                             *** MUST BE MAINTAINED.                   59100013
         SPACE 1                                                        59200013
OCMODC8  B     OCCASE8A            MODIFICATION TO HOLD BACK A RECORD   59300013
OCC7EOF  L     RE,OCNTEMP          UPDATE MODE * MODIFICATION TO CASE7  59400013
         B     OCNEXT2                         * TO FORCE TREE FLUSHING 59500013
DIERAMA  DSECT                                                          59600013
*                                                                       59700013
       COPY  AMAMAIN                                                    59800013
         EJECT                                                          59900013
         SMPPI                                                          60000013
         END                                                            60100013
