         TITLE ' IERAOD - OS/360 SORT/MERGE - 360S-SM-023 03/02/65 '    00100013
         SPACE 1                                                        00200013
*MODULE NAME:*** IERAOD ***                                             00300013
         SPACE 2                                                        00400013
*STATUS: CHANGE LEVEL 000                                               00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT FOR VARIABLE LENGTH      00700013
*   REPLACEMENT WITH SINGLE CONTROL FIELD. THE FUNCTION OF THIS MODULE  00800013
*   IS TO SET UP THE APPROPRIATE LENGTH FIELDS, DISPLACEMENT FIELDS,    00900013
*   AND CONSTANTS, DEPENDING ON WHETHER THE EXTRACT ROUTINE WILL BE     01000013
*   USED OR NOT, GENERATE THE REPLACEMENT TREE IN GENERATED CORE,       01100013
*   CHANGE THE CONDITIONS FOR BRANCHING IN THE RUNNING PROGRAM IF THE   01200013
*   RECORDS ARE TO BE COLLATED IN DESCENDING ORDER IN THE FIRST         01300013
*   SEQUENCE, AND OTHERWISE INITIALIZE THE COMPARE INSTRUCTIONS IN THE  01400013
*   RUNNING PROGRAM.                                                    01500013
         SPACE 2                                                        01600013
*USED AS A DSECT IN'                                                    01700013
*                                                                       01800013
*    N/A                                                                01900013
*                                                                       02000013
*MACROS USED'                                                           02100013
         SPACE 1                                                        02200013
*   SMPPI                                                               02300013
         SPACE 2                                                        02400013
*ENTRY POINTS:                                                          02500013
         SPACE 1                                                        02600013
*        ENTRY IERMOA              ENTRY FROM: LOAD MODULE, IERRC9      02700013
*                                      LOAD  EO=IERAOD,DCB=             02800013
*                                      LR    RP,RA                      02900013
*                                      BALR  RO,RP                      03000013
         SPACE 2                                                        03100013
*INPUT: PPI FIELDS REFERENCED-                                          03200013
         SPACE 1                                                        03300013
*   PPISRTG    PPILEXFF                                                 03400013
*   PPIAXERT   PPIX61+4                                                 03500013
*   PPIDDOL1   PPIMODEX+1,X'04'                                         03600013
*   PPISPGN1   PPINET+4                                                 03700013
*   PPILEXFD   PPISW1+3,X'50'                                           03800013
         SPACE 2                                                        03900013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             04000013
         SPACE 1                                                        04100013
*   PPISPGN1                                                            04200013
*   REPLACEMENT TREE IS CREATED IN GENERATED CORE.                      04300013
         SPACE 2                                                        04400013
*EXTERNAL ROUTINES:                                                     04500013
         SPACE 1                                                        04600013
*        N/A                                                            04700013
         SPACE 2                                                        04800013
*EXTERNAL PARAMETERS:                                                   04900013
         SPACE 1                                                        05000013
*        N/A                                                            05100013
         SPACE 2                                                        05200013
*EXITS: NORMAL                                                          05300013
         SPACE 1                                                        05400013
*    BR  RO - RETURN TO LOAD ROUTINE, IERRC9                            05500013
         SPACE 2                                                        05600013
*EXITS: ERROR                                                           05700013
         SPACE 1                                                        05800013
*        N/A                                                            05900013
         SPACE 2                                                        06000013
*TABLES/WORK AREAS:                                                     06100013
         SPACE 1                                                        06200013
*      WOCDISP - FULL WORD USED TO HOLD DISPLACEMENT FIELD FOR ORING    06300013
*    THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN THE RUNNING 06400013
*    PROGRAM IN ORDER TO INITIALIZE THEM AS NECESSARY.                  06500013
*      WOCLGTH, A FULL WORD, IS USED TO HOLD LENGTH FIELD FOR COMPARE   06600013
*    INSTRUCTIONS.                                                      06700013
*      WRSAVC9, A FULL WORD, IS USED TO HOLD THE ADDRESS OF THE CALLING 06800013
*    ROUTINE, THE LOAD MODULE IERRC9.                                   06900013
         SPACE 2                                                        07000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07100013
         SPACE 2                                                        07200013
*NOTES:                                                                 07300013
         SPACE 1                                                        07400013
*   THIS MODULE IS USED WITH VARIABLE LENGTH RECORDS WITH A SINGLE      07500013
*   CONTROL FIELD.                                                      07600013
         SPACE 2                                                        07700013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07800013
         SPACE 1                                                        07900013
RA       EQU   0                   CONTENTS IN- N/A                     08000013
*                                  USE- NOT USED                        08100013
*                                  CONTENTS OUT- N/A                    08200013
RB       EQU   1                   CONTENTS IN- N/A                     08300013
*                                  USE- NOT USED                        08400013
*                                  CONTENTS OUT- N/A                    08500013
RC       EQU   2                   CONTENTS IN- N/A                     08600013
*                                  USE- WORK REGISTER                   08700013
*                                  CONTENTS OUT- N/A                    08800013
RD       EQU   3                   CONTENTS IN- N/A                     08900013
*                                  USE- WORK REGISTER                   09000013
*                                  CONTENTS OUT- N/A                    09100013
RE       EQU   4                   CONTENTS IN- N/A                     09200013
*                                  USE- WORK REGISTER, NEXT LEVEL       09300013
*                                       ADDRESS                         09400013
*                                  CONTENTS OUT- N/A                    09500013
RF       EQU   5                   CONTENTS IN- N/A                     09600013
*                                  USE- WORK REGISTER, FORMAT           09700013
*                                  CONTENTS OUT- N/A                    09800013
RG       EQU   6                   CONTENTS IN- N/A                     09900013
*                                  USE- WORK REGISTER                   10000013
*                                  CONTENTS OUT- N/A                    10100013
RH       EQU   7                   CONTENTS IN- N/A                     10200013
*                                  USE- NODE OR WAY COUNTER             10300013
*                                  CONTENTS OUT- N/A                    10400013
RI       EQU   8                   CONTENTS IN- N/A                     10500013
*                                  USE- G COUNT                         10600013
*                                  CONTENTS OUT- N/A                    10700013
RJ       EQU   9                   CONTENTS IN- N/A                     10800013
*                                  USE- WORK REGISTER                   10900013
*                                  CONTENTS OUT- N/A                    11000013
RK       EQU   10                  CONTENTS IN- N/A                     11100013
*                                  USE- RECORD COUNTER                  11200013
*                                  CONTENTS OUT- N/A                    11300013
RL       EQU   11                  CONTENTS IN- N/A                     11400013
*                                  USE- PROGRAM BASE REGISTER           11500013
*                                  CONTENTS OUT- N/A                    11600013
RM       EQU   12                  CONTENTS IN- N/A                     11700013
*                                  USE- EXTRACT BASE REGISTER           11800013
*                                  CONTENTS OUT- N/A                    11900013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          12000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     12100013
*                                    AREA                               12200013
*                                  CONTENTS OUT- ADDRESS OF PPI         12300013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      12400013
*                                                IERRC9                 12500013
*                                  USE- BASE REGISTER FOR DSECT OF      12600013
*                                       IERROD                          12700013
*                                  CONTENTS OUT - RETURN ADDRESS IN     12800013
*                                                 IERRC9                12900013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMOA 13000013
*                                  USE- NOT USED                        13100013
*                                  CONTENTS OUT- N/A                    13200013
         SPACE 2                                                        13300013
*START OF MODULE CODE PROPER:                                           13400013
         SPACE 2                                                        13500013
         SPACE 1                                                        13600013
IERAOD   CSECT                                                          13700013
         USING *,RL                                                     13800013
         USING IERRCA,RN                                                13900013
         USING DIERROD,RO                                               14000013
IERMOA   LR    RL,RP               SET PROGRAM BASE REGISTER            14100013
         ST    RO,WRSAVC9                                               14200013
         L     RO,PPINET+4          SET DSECT REGISTER OF RUNNING MOD   14300013
         SPACE 1                                                        14400013
* DETERMINE IF EXTRACTING AND SET SWITCH IN NETWORK ACCORDINGLY.        14500013
         SPACE 1                                                        14600013
         TM    PPISW1+3,X'40'      TEST BIT INDICATING EXTRACT OR NOT   14700013
         BZ    OCNOEXT             BRANCH IF BIT IS OFF. NOT EXTRACTING 14800013
         LA    RG,255              CONSTANT X'FF'                       14900013
         STH   RG,KCSWITCH+2       SET EXT SWITCH ON IN RUNNING MODULE  15000013
         SPACE 1                                                        15100013
* SET BASE REGISTER FOR EXTRACT ROUTINE.                                15200013
         SPACE 1                                                        15300013
         L     RM,PPIAXERT         SET BASE REGISTER OF EXTRACT ROUTINE 15400013
         SPACE 1                                                        15500013
* DETERMINE IF MODIFICATION EXIT 61 IS ACTIVE AND STORE ITS             15600013
* ADDRESS IN EXTRACT ROUTINE IF NECESSARY.                              15700013
         SPACE 1                                                        15800013
         TM    PPIMODEX+1,X'04'    TEST BIT INDICATING EXIT E61 ACTIVE  15900013
         BZ    OCNOUSER            BRANCH IF BIT IS OFF. NO EXIT        16000013
         L     RG,PPIX61+4         ADDRESS OF USER MODIFICATION         16100013
         ST    RG,0(0,RM)          ADDR OF USER MODIFICATION IN EXTRACT 16200013
         SPACE 1                                                        16300013
* SET UP LENGTH FIELDS,DISPLACEMENT FIELD,AND CONSTANTS                 16400013
* AS REQUIRED IF EXTRACTING.                                            16500013
         SPACE 1                                                        16600013
OCNOUSER LH    RG,PPILEXFF         LGTH OF EXTRACTED FIELD ROUNDED FULL 16700013
         LA    RG,4(0,RG)          INCREMENT BY 4 FOR TREE ADDRESS      16800013
         ST    RG,KCINCDEC         STORE IN NETWORK AS INC OR DEC       16900013
         LA    RG,4                CONSTANT OF 4 FOR DISPLACEMENT       17000013
         STH   RG,WOCDISP            SET UP DISPLACEMENT                17100013
         STH   RG,WOCDISP+2          FIELDS FOR ORING                   17200013
         LH    RG,PPILEXFD         LGTH OF EXTRACTED FIELD FOR COMPARES 17300013
         ST    RG,WOCLGTH          LENGTH FIELD FOR COMPARE INSTS.      17400013
         B     OCGOGO                                                   17500013
         SPACE 2                                                        17600013
* SET UP LENGTH FIELDS.DISPLACEMENT FIELDS. AND CONSTANTS               17700013
* AS REQUIRED IF NOT EXTRACTING.                                        17800013
         SPACE 1                                                        17900013
OCNOEXT  LH    RE,PPIDD0L1         DISPLACEMENT OF FIRST CONTROL FIELD  18000013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT FOR TREE ADDR 18100013
         STH   RE,WOCDISP            SET UP DISPLACEMENT                18200013
         STH   RE,WOCDISP+2          FIELDS FOR ORING                   18300013
         LA    RE,4                CONSTANT OF 4                        18400013
         ST    RE,KCINCDEC         STORE LN NETWORK AS INC OR DEC       18500013
         SR    RE,RE               ZERO REGISTER                        18600013
         IC    RE,PPIDD0L1+3       LENGTH OF 1ST CONTROL FIELD FOR CLC  18700013
         ST    RE,WOCLGTH          LENGTH FIELD FOR COMPARE INSTS.      18800013
         SPACE 1                                                        18900013
* DETERMINE SIZE OF AREA FOR GENERATING THE TREE,RESET THE ADDRESS OF   19000013
* THE GENERATED AREA BY THIS AMOUNT,AND SAVE THIS ADDRESS FOR THE       19100013
* NETWORK AS THE TREE ADDRESS AND FOR THE NEXT ROUTINE AS THE           19200013
* ADDRESS OF THE GENERATED AREA.                                        19300013
         SPACE 1                                                        19400013
OCGOGO   L     RI,PPISRTG          G OR NUMBER OF RECORDS FOR TREE      19500013
         LA    RK,1                RECORD COUNTER-RECORDS TREE CAN HOLD 19600013
         LA    RC,12               BYTES PER NODE                       19700013
         LR    RF,RI               G OR NUMBER OF RECORDS FOR TREE      19800013
         SR    RF,RK               FORM G-1                             19900013
         SR    RE,RE               ZERO REGISTER                        20000013
         MR    RE,RC               CALCULATE NUMBER OF BYTES IN TREE    20100013
         LA    RJ,36               SIZE OF MINIMUM TREE                 20200013
         CR    RF,RJ               IS CALCULATED SIZE EQ OR G. MINIMUM  20300013
         BNL   OCOKSIZE            BRANCH IF IT IS                      20400013
         LR    RF,RJ               SET TREE SIZE TO MINIMUM             20500013
OCOKSIZE TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               20600013
         BNO   AODNOMES            SWITCH OFF BYPASS MESSAGE            20700013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  20800013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       20900013
         STM   RO,RB,AODSAVO       SAVE REGISTER                        21000013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    21100013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           21200013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    21300013
         BAL   RO,4(RP)                                                 21400013
         MVC   DMSG904B(8),0(RB)       MOVE NUMBER INTO MESSAGE         21500013
         L     RJ,OASAVEJ         RESTORE RJ                            21600013
         LM    RO,RB,AODSAVO       RESTORE REGISTERS                    21700013
         DROP  RJ                                                       21800013
AODNOMES L     RG,PPISPGN1         ADDRESS OF GENERATED CODE            21900013
         SR    RG,RF               DECREMENT ADDRESS OF GENERATED CODE  22000013
         SRL   RG,2                  ROUND DOWN TO                      22100013
         SLL   RG,2                  FULL WORDS                         22200013
         ST    RG,PPISPGN1         RESET NEW ADDRESS OF GENERATED CODE  22300013
         ST    RG,WCTREE           STORE THIS TREE ADDRESS IN NETWORK   22400013
         TM    PPISW1+6,X'01'     TEST DIAGNOSTIC SWITCH                22500013
         BNO   OANOMESS           SWITCH OFF BYPASS MESSAGE             22600013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  22700013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       22800013
         STM   RO,RB,AODSAVO       SAVE REGISTERS                       22900013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    23000013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           23100013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    23200013
         BAL   RO,4(RP)                                                 23300013
         MVC   DMSG904A(8),0(RB)       MOVE NUMBER INTO MESSAGE         23400013
         LM    RA,RB,DMSG904X     SET UP FOR BRANCH TO PRINT            23500013
         L     RP,PPIADSSC        LOAD ADDRESS OF PRINT ROUTINE         23600013
         BAL   RO,12(0,RP)        BRANCH TO PRINT MESSAGE               23700013
         L     RJ,OASAVEJ         RESTORE RJ                            23800013
         LM    RO,RB,AODSAVO       RESTORE REGISTERS                    23900013
         DROP  RJ                                                       24000013
         SPACE 1                                                        24100013
* SET UP ANY ADDITIONAL CONSTANTS REQUIRED TO GENERATE TREE             24200013
         SPACE 1                                                        24300013
OANOMESS LR    RJ,RG              NEXT LEVEL ADDR FOR PREVIOUS LEVEL    24400013
         LA    RH,2                WAY OR NODE COUNTER                  24500013
         LA    RE,WCLTNODE         ADDRESS OF LAST TEST NODE            24600013
         SR    RF,RF               SET FORMAT OF THIS NODE TO ZERO      24700013
         SPACE 1                                                        24800013
* GENERATE THE REQUIRED TREE                                            24900013
         SPACE 1                                                        25000013
OCSTTREE STM   RE,RF,0(RG)         STORE NLA AND FORMAT OF NODE         25100013
         LA    RK,1(0,RK)          INC RECORD COUNTER BY 1 EACH NODE    25200013
         CR    RK,RI               RECORDS TREE HOLDS NOW TO REQD NO.   25300013
         BNL   OCENOUGH            NO MORE NODES REQUIRED               25400013
         LA    RG,12(0,RG)         INCREMENT TO LOCATION OF NEXT NODE   25500013
         LR    RE,RJ               SET NEXT LEVEL ADDRESS               25600013
         BCT   RH,OCSTTREE         BRANCH IF NODE COUNTER NOT ZERO      25700013
         LA    RH,2                RESET NODE OR WAY COUNTER            25800013
         LA    RJ,12(0,RJ)         INCREMENT NEXT LEVEL ADDRESS         25900013
         B     OCSTTREE                                                 26000013
         SPACE 2                                                        26100013
* SAVE TREE INFORMATION FOR THE NETWORK                                 26200013
         SPACE 1                                                        26300013
OCENOUGH STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               26400013
         SPACE 1                                                        26500013
* IF COLLATING ORDER OF FIRST SEQUENCE IS TO BE DECENDING,REVERSE THE   26600013
* NECESSARY CONDITIONAL BRANCHES IN THE RUNNING ROUTINE.                26700013
         SPACE 1                                                        26800013
         TM    PPISW1+3,X'10'      TEST BIT INDICATING COLLATING ORDER  26900013
         BZ    OCASCEND            BRANCH IF BIT IS OFF-ORDER IS ASCEND 27000013
         XI    OCCASE24+7,X'60'    REVERSE CONDITIONAL BRANCH IN NETWOR 27100013
         XI    OCNOTON2+27,X'60'   REVERSE CONDITIONAL BRANCH IN SEQCK  27200013
         SPACE 1                                                        27300013
* INITIALIZE THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN     27400013
* THE RUNNING ROUTINE AS NECESSARY.                                     27500013
         SPACE 1                                                        27600013
OCASCEND OC    OCCASE24+2(4),WOCDISP  INITIALIZE DISP IN CLC IN NETWORK 27700013
         OC    OCNOTON2+22(4),WOCDISP INITIALIZE DISP IN CLC IN SEQCK   27800013
         SPACE 1                                                        27900013
* INITIALIZE THE LENGTH FIELD SIN THE COMPARE INSTRUCTIONS IN           28000013
* THE RUNNING ROUTINE AS NECESSARY.                                     28100013
         SPACE 1                                                        28200013
         L     RE,WOCLGTH          LENGTH OF 1ST CONTROL FIELD FOR CLC  28300013
         STC   RE,OCCASE24+1       SET LENGTH FIELD IN CLC IN NETWORK   28400013
         STC   RE,OCNOTON2+21      SET LENGTH FIELD IN CLC IN SEQCK     28500013
         SPACE 1                                                        28600013
* EXIT TO NEXT ASSIGNMENT ROUTINE.                                      28700013
         SPACE 1                                                        28800013
         L     RO,WRSAVC9           RESTORE RETURN ADDRESS              28900013
         BR    RO                   RETURN TO LOAD ROUTINE              29000013
         SPACE 2                                                        29100013
         SPACE 1                                                        29200013
*** WORK AREAS ***                                                      29300013
         SPACE 1                                                        29400013
WOCDISP  DS    1F                  USED TO HOLD DISP FIELDS FOR ORING   29500013
WOCLGTH  DS    1F                  USED TO HOLD LENGTH FIELD FOR INIT.  29600013
WRSAVC9  DS    F                    USED TO SAVE REGISTER RO            29700013
OASAVEJ  DC    F'0'                                                     29800013
AODSAVO  DC    4F'0'                                                    29900013
         EJECT                                                          30000013
         SPACE 1                                                        30100013
*** IERROD *** REPLACEMENT NETWORK FOR VARIABLE LENGTH RECORDS WHICH    30200013
*              CONTAIN SINGLE CONTROL FIELDS AND/OR REQUIRE EXTRACTING. 30300013
         SPACE 1                                                        30400013
*********************************************************************** 30500013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROD                   30600013
*********************************************************************** 30700013
         SPACE 1                                                        30800013
DICLOSE1 EQU   4                   DISP IN CLOSE BRANCH TABLE           30900013
DIDEBLK1 EQU   8                   DISP IN DEBLK BR TBL (GET TO FILL)   31000013
DIDEBLK2 EQU   0                   DISP IN DEBLK BR TBL (MODIFY + GET)  31100013
DIBLOCK1 EQU   12                  DISP IN BLOCK BR TBL (PUT INFER GET) 31200013
DIBLOCK2 EQU   4                   DISP IN BLOCK BR TBL (PUT EOS)       31300013
DIBLOCK3 EQU   0                   DISP IN BLOCK BR TBL (PUT EOF)       31400013
         SPACE 1                                                        31500013
DIERROD  DSECT                                                          31600013
         SPACE 1                                                        31700013
*** ENTRY TABLE                                                         31800013
         SPACE 1                                                        31900013
IERDOA   B     OCPICK              ENTRY TO FILL TREE                   32000013
         B     OCGOTFIL            ENTRY FROM DEBLK WHILE FILLING (FIT) 32100013
         B     OCEOF               ENTRY FROM DEBLK AT EOF              32200013
         B     OCGOTRUN            ENTRY FROM DEBLK WHILE RUNNING (FIT) 32300013
         B     OCRETEOF            ENTRY FROM DEBLK AFTER EOF           32400013
         DC    A(0)                SPACE TO KEEP INC IN ENTRY TABLE     32500013
         B     OCNOGOFI            ENTRY FROM DEBLK WHILE FILLING-NOFIT 32600013
         B     OCNOGORN            ENTRY FROM DEBLK WHILE RUNNING-NOFIT 32700013
         SPACE 2                                                        32800013
* INITIAL ENTRY  TO START FILLING OR ENTRY TO CONTINUE FILLING TREE.    32900013
         SPACE 1                                                        33000013
OCPICK   L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               33100013
         SPACE 1                                                        33200013
* EXIT TO DEBLOCK ROUTINE                                               33300013
         SPACE 1                                                        33400013
         B     DIDEBLK1(0,RL)      GET TO FILL                          33500013
         SPACE 2                                                        33600013
* SETS UP TO FILL THE TREE WITH REAL OR IMAGINARY RECORDS AND           33700013
* DETERMINES WHEN THE TREE IS FILLED.                                   33800013
         SPACE 1                                                        33900013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD FITS)                        34000013
         SPACE 1                                                        34100013
OCGOTFIL S     RD,KCINCDEC         DECREMENT NEW ADDR BY EXTRACT INC +4 34200013
         CLI   KCSWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 34300013
         BNE   OCNOTON1            BRANCH IF OFF                        34400013
         SPACE 1                                                        34500013
* EXIT TO EXTRACT ROUTINE                                               34600013
         SPACE 1                                                        34700013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              34800013
         SPACE 2                                                        34900013
OCNOTON1 LM    RH,RJ,WCSAVE        FILLING REGISTERS                    35000013
         L     RE,OCSAME           UPDATE MODE                          35100013
         ST    RJ,0(0,RD)          ADDRESS OF TREE WITH RECORD          35200013
OCSUBFIT LR    RF,RJ               ADDRESS OF TREE (NEXT LEVEL ADDR)    35300013
         BCT   RH,OCGCT            DECREMENT WAY COUNTER                35400013
         LA    RH,2                RESET WAY COUNTER                    35500013
         LA    RJ,12(0,RJ)         INCREMENT TO NEXT NODE               35600013
OCGCT    BCT   RI,OCFILREG         DECREMENT G COUNTER                  35700013
         STM   RH,RJ,WCSAVE                                             35800013
         B     OCNEXT2                                                  35900013
         SPACE 2                                                        36000013
OCFILREG STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               36100013
         B     OCNEXT2                                                  36200013
         SPACE 2                                                        36300013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD DOES NOT FIT)                36400013
         SPACE 1                                                        36500013
OCNOGOFI LM    RH,RJ,WCSAVE        FILLING REGISTERS                    36600013
         L     RE,OCSTEMP          UPDATE MODE                          36700013
         LR    RD,RJ               USE TREE ADDRESS AS WINNER           36800013
         B     OCSUBFIT                                                 36900013
         SPACE 2                                                        37000013
* DETERMINES IF EOF SITUATION IS A NORMAL ONE, FILE SIZE LESS           37100013
* THEN G, OR FILE SIZE IS ZERO AND BRANCHES ACCORDINGLY.                37200013
         SPACE 1                                                        37300013
* ENTRY FROM DEBLOCK AT EOF                                             37400013
         SPACE 1                                                        37500013
OCEOF    CLC   PPISRTG(4),WCSAVE+4 COMPARE G COUNT IN PPIA TO FILL NO.  37600013
         BNE   OCNOZERO                                                 37700013
         L     RP,PPIRCV+4          CLOSE BASE REGISTER                 37800013
         SPACE 1                                                        37900013
* EXIT TO CLOSE ROUTINE                                                 38000013
         SPACE 1                                                        38100013
         LA    RB,4                 SET CODE TO CALL PHASE 3            38200013
         B     20(RP)              INPUT FILE WAS ZERO                  38300013
         SPACE 2                                                        38400013
OCNOZERO MVC   OCC7A(8),OCC7EOF    MODIFY CASE7 TO FORCE TREE FLUSHING  38500013
         LA    RK,0                CONSTANT OF 0                        38600013
         CL    RK,WCSAVE+4         COMPARE TO FILL COUNT                38700013
         BE    OCRETEOF                                                 38800013
         SPACE 1                                                        38900013
* FILE SIZE IS LESS THAN G. THE CODING IS MODIFIED TO FILL THE          39000013
* REMAINDER OF THE TREE WITH IMAGINARY RECORDS (T1).                    39100013
         SPACE 1                                                        39200013
         OI    OCC8A+1,X'F0'       INITIALIZE BRANCH INST IN CASE8      39300013
         MVC   OCPICK(4),OCMODIFY  MODIFY FILLING RETURN LOCATION       39400013
OCMODIFY B     OCNOGOFI                                                 39500013
         SPACE 2                                                        39600013
* MODE POSITIONS AND BRANCH TABLE.                                      39700013
* THROUGH THE COMBINATION OF MODE AND FORMAT AN INDEXED                 39800013
* BRANCH IS PERFORMED WHICH BRANCHES TO THE CASE WHICH                  39900013
* HANDLES THE INDICATED SITUATION.                                      40000013
         SPACE 1                                                        40100013
OCNTEMP  DC    A(OCBTABLE)                                              40200013
OCNEW    DC    A(OCBTABLE+4)                                            40300013
OCSTEMP  DC    A(OCBTABLE+8)                                            40400013
OCSAME   DC    A(OCBTABLE+12)                                           40500013
OCBTABLE DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 40600013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 40700013
         B     OCCASE3                                                  40800013
         B     OCCASE4                                                  40900013
         B     OCCASE5                                                  41000013
         B     OCCASE6                                                  41100013
         B     OCCASE7                                                  41200013
OCMODLOC B     OCCASE8                                                  41300013
         B     OCCASE9                                                  41400013
         B     OCCASE10                                                 41500013
         B     OCNEXT                                                   41600013
         B     OCNEXT                                                   41700013
         B     OCCASE13                                                 41800013
         B     OCCASE14                                                 41900013
         B     OCNEXT                                                   42000013
         B     OCNEXT                                                   42100013
         B     OCCASE17                                                 42200013
         B     OCCASE18                                                 42300013
         B     OCNEXT                                                   42400013
         B     OCNEXT                                                   42500013
         B     OCCASE21                                                 42600013
         B     OCCASE22                                                 42700013
         B     OCCASE23                                                 42800013
         B     OCCASE24                                                 42900013
         SPACE 2                                                        43000013
* THIS CASE HANDLES AN S1/S1 SITUATION.                                 43100013
         SPACE 1                                                        43200013
OCCASE24 CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              43300013
         BNH   OCNEXT                                                   43400013
OCEXCH   ST    RD,8(0,RF)          WINNER TO LOSER                      43500013
         LR    RD,RH               LOSER TO WINNER                      43600013
OCNEXT   L     RF,0(0,RF)          ADDRRSS OF NEXT NODE                 43700013
OCNEXT2  LM    RG,RH,4(RF)         LOAD NODE                            43800013
         B     0(RE,RG)            GO TO PROPER CASE                    43900013
         SPACE 2                                                        44000013
* THIS CASE HANDLES A T1/S1 SITUATION.                                  44100013
         SPACE 1                                                        44200013
OCCASE23 L     RE,OCSAME           UPDATE MODE                          44300013
         LA    RK,64               FORMAT T1                            44400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        44500013
         B     OCEXCH                                                   44600013
         SPACE 2                                                        44700013
* THIS CASE HANDLES AN S2/S1 SITUATION.                                 44800013
         SPACE 1                                                        44900013
OCCASE22 L     RE,OCSAME           UPDATE MODE                          45000013
         LA    RK,48               FORMAT S2                            45100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        45200013
         B     OCEXCH                                                   45300013
         SPACE 2                                                        45400013
* THIS CASE HANDLES A T2/S1 SITUATION.                                  45500013
         SPACE 1                                                        45600013
OCCASE21 L     RE,OCSAME           UPDATE MODE                          45700013
         LA    RK,32               FORMAT T2                            45800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        45900013
         B     OCEXCH                                                   46000013
         SPACE 2                                                        46100013
* THIS CASE HANDLES AN S2/T1 SITUATION.                                 46200013
         SPACE 1                                                        46300013
OCCASE18 L     RE,OCSTEMP          UPDATE MODE                          46400013
         LA    RK,48               FORMAT S2                            46500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        46600013
         B     OCEXCH                                                   46700013
         SPACE 2                                                        46800013
* THIS CASE HANDLES A T2/T1 SITUATION.                                  46900013
         SPACE 1                                                        47000013
OCCASE17 L     RE,OCSTEMP          UPDATE MODE                          47100013
         LA    RK,32               FORMAT T2                            47200013
         ST    RK,4(0,RF)          UPDATE FORMAT                        47300013
         B     OCEXCH                                                   47400013
         SPACE 2                                                        47500013
* THIS CASE HANDLES AN S2/S2 SITUATION.                                 47600013
         SPACE 1                                                        47700013
OCCASE14 LA    RK,80               FORMAT S1                            47800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        47900013
         B     OCCASE24                                                 48000013
         SPACE 2                                                        48100013
* THIS CASE HANDLES A T2/S2 SITUATION.                                  48200013
         SPACE 1                                                        48300013
OCCASE13 L     RE,OCNEW            UPDATE MODE                          48400013
         SPACE 1                                                        48500013
* THIS CASE HANDLES A T2/T2 SITUATION.                                  48600013
         SPACE 1                                                        48700013
OCCASE9  LA    RK,64               FORMAT T1                            48800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        48900013
         B     OCEXCH                                                   49000013
         SPACE 2                                                        49100013
* THIS CASE HANDLES AN S2/T2 SITUATION.                                 49200013
         SPACE 1                                                        49300013
OCCASE10 LA    RK,64               FORMAT T1                            49400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        49500013
         B     OCNEXT                                                   49600013
         SPACE 2                                                        49700013
* INDICATES THE TREE IS FILLED AND FORCES THE NETWORK                   49800013
* INTO A RUNNING SITUATION.                                             49900013
         SPACE 1                                                        50000013
OCCASE8  ST    RD,WCLTNODE         SAVE ADDR OF RECD IN LAST TEST NODE  50100013
         MVC   OCMODLOC(4),OCMODC8 MODIFY BRANCH TABLE                  50200013
OCC8A    BC    0,OCRETEOF          INITIALIZED TO BRANCH AT FILE L.T. G 50300013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               50400013
         SPACE 1                                                        50500013
* EXIT TO DEBLOCK ROUTINE                                               50600013
         SPACE 1                                                        50700013
         B     DIDEBLK2(0,RL)      MODIFY AND GET                       50800013
         SPACE 2                                                        50900013
* INDICATES THERE IS A RECORD TO BE BLOCKED                             51000013
         SPACE 1                                                        51100013
OCCASE8A L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  51200013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  51300013
         LR    RD,RK               ADDRESS TO WINNER POSITION           51400013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     51500013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 51600013
         SPACE 1                                                        51700013
* EXIT TO BLOCK ROUTINE                                                 51800013
         SPACE 1                                                        51900013
         B     DIBLOCK1(0,RL)      PUT INFERS GET                       52000013
         SPACE 2                                                        52100013
* INDICATES THAT A T1 (IMAGINARY) HAS BEEN FORCED OUT OF THE TREE.      52200013
         SPACE 1                                                        52300013
OCCASE7  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  52400013
         ST    RD,0(0,RK)          NODE ADDR (T1) WITH RECORD HELD BACK 52500013
         LR    RF,RD               NODE ADDRESS AS NEXT LEVEL ADDRESS   52600013
OCC7A    L     RK,OCNTEMP          MODE NTEMP                           52700013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO NTEMP       52800013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               52900013
         SPACE 1                                                        53000013
* EXIT TO DEBLOCK ROUTINE                                               53100013
         SPACE 1                                                        53200013
         B     DIDEBLK1(0,RL)      GET TO FILL (DEBLOCK EXIT MODIFIED)  53300013
         SPACE 2                                                        53400013
* INDICATES THAT IT IS THE END OF A SEQUENCE.                           53500013
         SPACE 1                                                        53600013
OCCASE6  L     RK,OCSTEMP          MODE STEMP                           53700013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       53800013
         L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  53900013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  54000013
         LR    RD,RK               ADDRESS TO WINNER POSITION           54100013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     54200013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 54300013
         SPACE 1                                                        54400013
* EXIT TO BLOCK ROUTINE                                                 54500013
         SPACE 1                                                        54600013
         B     DIBLOCK2(0,RL)      PUT EOS                              54700013
         SPACE 2                                                        54800013
* INDICATES THAT IT IS END OF FILE.                                     54900013
         SPACE 1                                                        55000013
OCCASE5  L     RD,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  55100013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     55200013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 55300013
         SPACE 1                                                        55400013
* EXIT TO BLOCK ROUTINE                                                 55500013
         SPACE 1                                                        55600013
         B     DIBLOCK3(0,RL)      PUT EOF                              55700013
         SPACE 2                                                        55800013
* THIS CASE HANDLES AN S1/- SITUATION                                   55900013
         SPACE 1                                                        56000013
OCCASE4  ST    RD,8(0,RF)          WINNER TO LOSER                      56100013
         LA    RK,80               FORMATS1                             56200013
         ST    RK,4(0,RF)          UPDATE FORMAT                        56300013
         B     OCPICK                                                   56400013
         SPACE 2                                                        56500013
* THIS CASE HANDLES A T1/- SITUATION                                    56600013
         SPACE 1                                                        56700013
OCCASE3  ST    RD,8(0,RF)          WINNER TO LOSER                      56800013
         LA    RK,64               FORMAT T1                            56900013
         ST    RK,4(0,RF)          UPDATE FORMAT                        57000013
         B     OCPICK                                                   57100013
         SPACE 2                                                        57200013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD FITS)                        57300013
         SPACE 1                                                        57400013
* SEQUENCE CHECKS THE NEW RECORD AND STARTS IT                          57500013
* THROUGH THE REPLACEMENT NETWORK.                                      57600013
         SPACE 1                                                        57700013
OCGOTRUN S     RD,KCINCDEC         DECREMENT NEW ADDR BY EXTRACT INC +4 57800013
         CLI   KCSWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 57900013
         BNE   OCNOTON2            BRANCH IF OFF                        58000013
         SPACE 1                                                        58100013
* EXIT TO EXTRACT ROUTINE                                               58200013
         SPACE 1                                                        58300013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              58400013
         SPACE 2                                                        58500013
OCNOTON2 L     RK,OCSTEMP          MODE STEMP                           58600013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       58700013
         L     RC,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  58800013
         L     RF,0(0,RC)          NODE ADDRESS WITH RECORD HELD BACK   58900013
         ST    RF,0(0,RD)          NODE ADDRESS WITH NEW RECORD         59000013
         CLC   0(1,RD),0(RC)       COMPARE NEW RECORD TO ONE HELD BACK  59100013
         BL    OCMODNEW                                                 59200013
         L     RE,OCSAME           UPDATE MODE                          59300013
         B     OCNEXT2                                                  59400013
         SPACE 2                                                        59500013
OCMODNEW L     RE,OCNEW            UPDATE MODE                          59600013
         B     OCNEXT2                                                  59700013
         SPACE 2                                                        59800013
* SET UP TO FLUSH ANOTHER RECORD FROM THE TREE AFTER END OF             59900013
* FILE OR BECAUSE THE INCOMONG RECORD WILL NOT FIT.                     60000013
         SPACE 1                                                        60100013
* ENTRY FROM DEBLOCK AFTER EOF                                          60200013
         SPACE 1                                                        60300013
OCRETEOF L     RE,OCNTEMP          UPDATE MODE                          60400013
         B     OCSUBNO                                                  60500013
         SPACE 2                                                        60600013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD DOES NOT FIT)                60700013
         SPACE 1                                                        60800013
OCNOGORN L     RE,WCSPECL          UPDATE MODE                          60900013
OCSUBNO  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  61000013
         L     RF,0(0,RK)          NODE ADDRESS WITH RECORD HELD BACK   61100013
         LR    RD,RF               TREE ADDRESS AS WINNER               61200013
         B     OCNEXT2                                                  61300013
         SPACE 2                                                        61400013
         SPACE 1                                                        61500013
         SPACE 1                                                        61600013
*** CONSTANTS                                                           61700013
         SPACE 1                                                        61800013
KCSWITCH DC    X'00000000'         EXTRACT SWITCH                       61900013
KCINCDEC DS    1F                  ADDRESS INC OR DEC OF EXTRACT INC +4 62000013
         SPACE 1                                                        62100013
*** WORK AREAS *** THE ORDERING OF THESE WORK AREAS MUST BE MAINTAINED  62200013
         SPACE 1                                                        62300013
WCSAVE   DS    3F                  FILLING REGISTER SAVE AREA           62400013
WCTREE   DS    1F                  LOCATION OF TREE                     62500013
WCLTNODE DS    1F                  LAST TEST NODE                       62600013
         DC    A(16)               FORMAT OF LAST TEST NODE             62700013
WCSPECL  DC    A(OCBTABLE+8)       SPECIAL (MODE) INDICATOR             62800013
         SPACE 1                                                        62900013
*** MODIFICATION INSTRUCTIONS *** THE ORDERING OF THESE INSTRUCTIONS    63000013
*                             *** MUST BE MAINTAINED.                   63100013
         SPACE 1                                                        63200013
OCMODC8  B     OCCASE8A            MODIFICATION TO HOLD BACK A RECORD   63300013
OCC7EOF  L     RE,OCNTEMP          UPDATE MODE * MODIFICATION TO CASE7  63400013
         B     OCNEXT2                         * TO FORCE TREE FLUSHING 63500013
DIERAMA  DSECT                                                          63600013
*                                                                       63700013
       COPY  AMAMAIN                                                    63800013
         EJECT                                                          63900013
         SMPPI                                                          64000013
         END                                                            64100013
