         TITLE ' IERAOF - OS/360 SORT/MERGE - 360-SM- 23 04/07/65 '     00100013
         SPACE 1                                                        00200013
*MODULE NAME:*** IERAOF ***                                             00300013
         SPACE 2                                                        00400013
*STATUS: CHANGE LEVEL 000                                               00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION: PHASE ONE ASSIGNMENT FOR FIXED LENGTH POLYPHASE       00700013
*   REPLACEMENT WITH SINGLE CONTROL FIELD. THE FUNCTION OF THIS MODULE  00800013
*   IS TO SET UP THE APPROPRIATE LENGTH FIELDS, DISPLACEMENT FIELDS,    00900013
*   AND CONSTANTS, DEPENDING ON WHETHER THE EXTRACT ROUTINE WILL BE     01000013
*   USED OR NOT, GENERATE THE REPLACEMENT TREE IN GENERATED CORE,       01100013
*   CHANGE THE CONDITIONS FOR BRANCHING IN THE RUNNING PROGRAM IF THE   01200013
*   RECORDS ARE TO BE COLLATED IN DESCENDING ORDER IN THE FIRST         01300013
*   SEQUENCE, AND OTHERWISE INITIALIZE THE COMPARE INSTRUCTIONS IN THE  01400013
*   RUNNING PROGRAM.                                                    01500013
         SPACE 2                                                        01600013
*USED AS A DSECT IN'                                                    01700013
*                                                                       01800013
*    N/A                                                                01900013
*                                                                       02000013
*MACROS USED'                                                           02100013
         SPACE 1                                                        02200013
*   SMPPI                                                               02300013
         SPACE 2                                                        02400013
*ENTRY POINTS:                                                          02500013
         SPACE 1                                                        02600013
*        ENTRY IERMOA              ENTRY FROM: LOAD MODULE, IERRC9      02700013
*                                    CALLING SEQUENCE-                  02800013
*                                      LOAD  EP=IERAOF,DCB=             02900013
*                                      LR    RP,RA                      03000013
*                                      BALR  RO,RP                      03100013
         SPACE 2                                                        03200013
*INPUT: PPI FIELDS REFERENCED-                                          03300013
         SPACE 1                                                        03400013
*    PPISRTG    PPILEXFF                                                03500013
*    PPIAXERT   PPIX61+4                                                03600013
*    PPIDDOL1   PPIMODEX+1,X'04'                                        03700013
*    PPISPGN1   PPINET+4                                                03800013
*    PPILEXFD   PPISW1+3,X'50'                                          03900013
         SPACE 2                                                        04000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             04100013
         SPACE 1                                                        04200013
*    PPISPGN1                                                           04300013
*    REPLACEMENT TREE IS CREATED IN GENERATED CORE.                     04400013
         SPACE 2                                                        04500013
*EXTERNAL ROUTINES:                                                     04600013
         SPACE 1                                                        04700013
*        N/A                                                            04800013
         SPACE 2                                                        04900013
*EXTERNAL PARAMETERS:                                                   05000013
         SPACE 1                                                        05100013
*        N/A                                                            05200013
         SPACE 2                                                        05300013
*EXITS: NORMAL                                                          05400013
         SPACE 1                                                        05500013
*    BR  RO - RETURN TO LOAD ROUTINE, IERRC9                            05600013
         SPACE 2                                                        05700013
*EXITS: ERROR                                                           05800013
         SPACE 1                                                        05900013
*        N/A                                                            06000013
         SPACE 2                                                        06100013
*TABLES/WORK AREAS:                                                     06200013
         SPACE 1                                                        06300013
*      WOADISP - FULL WORD USED TO HOLD DISPLACEMENT FIELD FOR ORING    06400013
*    THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN THE RUNNING 06500013
*    PROGRAM IN ORDER TO INITIALIZE THEM AS MECESSARY.                  06600013
*      WOALGTH, A FULL WORD, IS USED TO HOLD LENGTH FIELD FOR COMPARE   06700013
*    INSTRUCTIONS.                                                      06800013
*      WRSAVC9, A FULL WORD, IS USED TO HOLD THE ADDRESS OF THE CALLING 06900013
*    ROUTINE, THE LOAD MODULE IERRC9.                                   07000013
         SPACE 2                                                        07100013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07200013
         SPACE 2                                                        07300013
*NOTES:                                                                 07400013
         SPACE 1                                                        07500013
*    THIS MODULE IS USED WITH FIXED LENGTH RECORDS WITH SINGLE CONTROL  07600013
*    FIELD FOR A POLYPHASE SORT.                                        07700013
         SPACE 2                                                        07800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07900013
         SPACE 1                                                        08000013
RA       EQU   0                   CONTENTS IN- N/A                     08100013
*                                  USE- NOT USED                        08200013
*                                  CONTENTS OUT- N/A                    08300013
RB       EQU   1                   CONTENTS IN- N/A                     08400013
*                                  USE- NOT USED                        08500013
*                                  CONTENTS OUT- N/A                    08600013
RC       EQU   2                   CONTENTS IN- N/A                     08700013
*                                  USE- CONSTANT OF 20 - BYTES PER NODE 08800013
*                                  CONTENTS OUT- N/A                    08900013
RD       EQU   3                  CONTENTS IN - N/A                     09000013
*                                  USE- CONSTANT OF 3 - RECORDS ADDED   09100013
*                                       PER NODE                        09200013
*                                  CONTENTS OUT- N/A                    09300013
RE       EQU   4                   CONTENTS IN- N/A                     09400013
*                                  USE- WORK REGISTER, NEXT LEVEL       09500013
*                                       ADDRESS                         09600013
*                                  CONTENTS OUT- N/A                    09700013
RF       EQU   5                   CONTENTS IN- N/A                     09800013
*                                  USE- WORK REGISTER, FORMAT           09900013
*                                  CONTENTS OUT- N/A                    10000013
RG       EQU   6                   CONTENTS IN- N/A                     10100013
*                                  USE- WORK REGISTER                   10200013
*                                  CONTENTS OUT- N/A                    10300013
RH       EQU   7                   CONTENTS IN- N/A                     10400013
*                                  USE- NODE OR WAY COUNTER             10500013
*                                  CONTENTS OUT- N/A                    10600013
RI       EQU   8                   CONTENTS IN- N/A                     10700013
*                                  USE- G COUNT                         10800013
*                                  CONTENTS OUT- N/A                    10900013
RJ       EQU   9                   CONTENTS IN- N/A                     11000013
*                                  USE- WORK REGISTER                   11100013
*                                  CONTENTS OUT- N/A                    11200013
RK       EQU   10                  CONTENTS IN- N/A                     11300013
*                                  USE- RECORD COUNTER                  11400013
*                                  CONTENTS OUT- N/A                    11500013
RL       EQU   11                  CONTENTS IN- N/A                     11600013
*                                  USE- PROGRAM BASE REGISTER           11700013
*                                  CONTENTS OUT- N/A                    11800013
RM       EQU   12                  CONTENTS IN- N/A                     11900013
*                                  USE- EXTRACT BASE REGISTER           12000013
*                                  CONTENTS OUT- N/A                    12100013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          12200013
*                                  USE- PPI REFERENCE,REGISTER SAVE     12300013
*                                    AREA                               12400013
*                                  CONTENTS OUT- ADDRESS OF PPI         12500013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      12600013
*                                                IERRC9                 12700013
*                                  USE- BASE REGISTER FOR DSECT OF      12800013
*                                       IERROF                          12900013
*                                  CONTENTS OUT - RETURN ADDRESS IN     13000013
*                                                 IERRC9                13100013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMOA 13200013
*                                  USE- NOT USED                        13300013
*                                  CONTENTS OUT- N/A                    13400013
         SPACE 2                                                        13500013
*START OF MODULE CODE PROPER:                                           13600013
         SPACE 2                                                        13700013
         SPACE 1                                                        13800013
IERAOF   CSECT                                                          13900013
* 20800-211000                                                   A27998 13920020
*1984743000                                                        3524 13950018
*CH743000                                                        A35577 13970021
         USING *,RL                                                     14000013
         USING IERRCA,RN                                                14100013
         USING DIERROF,RO                                               14200013
IERMOA   LR    RL,RP               SET PROGRAM BASE REGISTER            14300013
         ST    RO,WRSAVC9                                               14400013
         L     RO,PPINET+4         SET DSECT REGESTER OF RUNNING PRG.   14500013
         SPACE 1                                                        14600013
* DETERMINE IF EXTRACTING AND SET SWITCH IN NETWORK ACCORDINGLY.        14700013
         TM    PPISW1+3,X'40'      TEST BIT INDICATING EXTRACT OR NOT   14800013
         BZ    OANOEXT             BRANCH IF BIT IS OFF. NOT EXTRACTING 14900013
         LA    RG,255              CONSTANT X'FF'                       15000013
         STH   RG,KASWITCH+2       SET EXT SWITCH ON IN RUNNING MODULE  15100013
         SPACE 1                                                        15200013
* SET BASE REGISTER FOR EXTRACT ROUTINE.                                15300013
         SPACE 1                                                        15400013
         L     RM,PPIAXERT         SET BASE REGISTER OF EXTRACT ROUTINE 15500013
         SPACE 1                                                        15600013
* DETERMINE IF MODIFICATION EXIT E61 IS ACTIVE AND STORE ITS            15700013
* ADDRESS IN EXTRACT ROUTINE IF NECESSARY.                              15800013
         SPACE 1                                                        15900013
         TM    PPIMODEX+1,X'04'    TEST BIT INDICATING EXIT E61 ACTIVE  16000013
         BZ    OANOUSER            BRANCH IF BIT IS OFF. NO EXIT        16100013
         L     RG,PPIX61+4          ADDR OF USER MODIFICATION           16200013
         ST    RG,0(0,RM)          ADDR OF USER MODIFICATION IN EXTRACT 16300013
         SPACE 1                                                        16400013
* SET UP LENGTH FIELDS,DISPLACEMENT FIELDS,AND CONSTANTS                16500013
* AS REQUIRED IF EXTRACTING.                                            16600013
         SPACE 1                                                        16700013
OANOUSER LH    RG,PPILEXFF         LGTH OF EXTRACTED FIELD ROUNDED FULL 16800013
         LA    RG,4(0,RG)          INCREMENT BY 4 FOR TREE ADDRESS      16900013
         ST    RG,KAINCDEC         STORE IN NETWORK AS INC OR DEC       17000013
         LA    RG,4                CONSTANT OF 4 FOR DISPLACEMENT       17100013
         STH   RG,WOADISP            SET UP DISPLACEMENT                17200013
         STH   RG,WOADISP+2          FIELDS FOR ORING                   17300013
         LH    RG,PPILEXFD         LGTH OF EXTRACTED FIELD FOR COMPARES 17400013
         ST    RG,WOALGTH          LENGTH FIELD FOR COMPARE INSTS.      17500013
         B     OAGOGO                                                   17600013
         SPACE 2                                                        17700013
* SET UP LENGTH FIELDS,DISPLACEMENT FIELDS,AND CONSTANTS                17800013
* AS REQUIRED IF NOT EXTRACTING.                                        17900013
         SPACE 1                                                        18000013
OANOEXT  LH    RE,PPIDD0L1         DISPLACEMENT OF FIRST CONTROL FIELD  18100013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT FOR TREE ADDR 18200013
         STH   RE,WOADISP            SET UP DISPLACEMENT                18300013
         STH   RE,WOADISP+2          FIELDS FOR ORING                   18400013
         LA    RE,4                CONSTANT OF 4                        18500013
         ST    RE,KAINCDEC         STORE IN NETWORK AS INC OR DEC       18600013
         SR    RE,RE               ZERO REGISTER                        18700013
         IC    RE,PPIDD0L1+3       LENGTH OF 1ST CONTROL FIELD FOR CLC  18800013
         ST    RE,WOALGTH          LENGTH FIELD FOR COMPARE INSTS.      18900013
         SPACE 1                                                        19000013
* DETERMINE SIZE OF AREA FOR GENERATING THE TREE,RESET THE ADDRESS OF   19100013
* THE GENERATED AREA BY THIS AMOUNT,AND SAVE THIS ADDRESS FOR THE       19200013
* NETWORK AS THE TREE ADDRESS AND FOR THE NEXT ROUTINE AS THE           19300013
* ADDRESS OF THE GENERATED AREA.                                        19400013
         SPACE 1                                                        19500013
OAGOGO   L     RI,PPISRTG          G OR NUMBER OF RECORDS FOR TREE      19600013
         LA    RD,3                NUMBER OF RECORDS ADDED PER NODE     19700013
         LA    RC,20               BYTES PER NODE                       19800013
         LA    RK,1                RECORD COUNTER-RECORDS TREE CAN HOLD 19900013
         LR    RF,RI               G OR NUMBER OF RECORDS FOR TREE      20000013
         SR    RF,RK               FORM G-1                             20100013
         SR    RE,RE               ZERO REGISTER                        20200013
         DR    RE,RD               FORM (G-1)/3                         20300013
         LTR   RE,RE               TEST FOR REMAINDER                   20400013
         BE    OASKIP              ROUND TO FULL NO. OF NODES IF NOT 0  20500013
         AR    RF,RK               ROUND TO FULL NUMBER OF NODES        20600013
OASKIP   MR    RE,RC               CALCULATE NUMBER OF BYTES IN TREE    20700013
OAOKSIZE TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               21200013
         BNO   AOFNOMES            SWITCH OFF BYPASS MESSAGE            21300013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  21400013
         STM   RO,RB,WRSAVC10                                           21500013
         L     RO,WRSAVC9                                               21600013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       21700013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    21800013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           21900013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    22000013
         BAL   RO,4(RP)                                                 22100013
         MVC   DMSG904B(8),0(RB)       MOVE NUMBER INTO MESSAGE         22200013
         LM    RO,RB,WRSAVC10      RESTORE REGESTERS                    22300013
         L     RJ,OASAVEJ         RESTORE RJ                            22400013
         DROP  RJ                                                       22500013
AOFNOMES L     RG,PPISPGN1         ADDRESS OF GENERATED CORE            22600013
         SR    RG,RF               DECREMENT ADDRESS OF GENERATED CODE  22700013
         SRL   RG,2                  ROUND DOWN TO                      22800013
         SLL   RG,2                    FULL WORDS                       22900013
         ST    RG,PPISPGN1         RESET NEW ADDRESS OF GENERATED CODE  23000013
         ST    RG,WATREEAD         STORE THIS TREE ADDRESS IN NETWORK   23100013
         TM    PPISW1+6,X'01'     TEST DIAGNOSTIC SWITCH                23200013
         BNO   OANOMESS           SWITCH OFF BYPASS MESSAGE             23300013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  23400013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       23500013
         STM   RO,RB,WRSAVC10      SAVE REGESTERS                       23600013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    23700013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           23800013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    23900013
         BAL   RO,4(RP)                                                 24000013
         MVC   DMSG904A(8),0(RB)       MOVE NUMBER INTO MESSAGE         24100013
         LM    RA,RB,DMSG904X     SET UP FOR BRANCH TO PRINT            24200013
         L     RP,PPIADSSC        LOAD ADDRESS OF PRINT ROUTINE         24300013
         BAL   RO,12(0,RP)        BRANCH TO PRINT MESSAGE               24400013
         L     RJ,OASAVEJ         RESTORE RJ                            24500013
         LM    RO,RB,WRSAVC10                                           24600013
         DROP  RJ                                                       24700013
         SPACE 1                                                        24800013
* SET UP ANY ADDITIONAL CONSTANTS REQUIRED TO GENERATE TREE.            24900013
         SPACE 1                                                        25000013
OANOMESS LR    RJ,RG              NEXT LEVEL ADDR FOR PREVIOUS LEVEL    25100013
         LA    RH,4                WAY OR NODE COUNTER                  25200013
         LA    RE,WALTNODE         ADDRESS OF LAST TEST NODE            25300013
         SR    RF,RF               SET FORMAT OF THIS NODE TO ZERO      25400013
         SPACE 1                                                        25500013
* GENERATE THE REQUIRED TREE.                                           25600013
         SPACE 1                                                        25700013
OASTTREE STM   RE,RF,0(RG)         STORE NLA AND FORMAT OF NODE         25800013
         AR    RK,RD               INC RECORD COUNTER BY 3 EACH NODE    25900013
         CR    RK,RI               RECORDS TREE HOLDS NOW TO REQD NO.   26000013
         BNL   OAENOUGH            NO MORE NODES REQUIRED               26100013
         AR    RG,RC               INCREMENT TO LOCATION OF NEXT NODE   26200013
         LR    RE,RJ               SET NEXT LEVEL ADDRESS               26300013
         BCT   RH,OASTTREE         BRANCH IF NODE COUNTER NOT ZERO      26400013
         LA    RH,4                RESET NODE OR WAY COUNTER            26500013
         AR    RJ,RC               INCREMENT NEXT LEVEL ADDRESS         26600013
         B     OASTTREE                                                 26700013
         SPACE 2                                                        26800013
* SAVE TREE INFORMATION FOR THE NETWORK.                                26900013
         SPACE 1                                                        27000013
OAENOUGH STM   RH,RJ,WASAVE        SAVE FILLING REGISTERS               27100013
         SPACE 1                                                        27200013
* IF COLLATING ORDER OF FIRST SEQUENCE IS TO BE DECENDING,REVERSE THE   27300013
* NECESSARY  CONDITIONAL BRANCHES IN THE RUNNING ROUTINE.               27400013
         SPACE 1                                                        27500013
         TM    PPISW1+3,X'10'      TEST BIT INDICATING COLLATING ORDER  27600013
         BZ    OAASCEND            BRANCH IF BIT IS OFF-ORDER IS ASCEND 27700013
         XI    OACASE44+11,X'60'   REVERSE CONDITIONAL BRANCH IN NTWK   27800013
         XI    OACASE44+21,X'60'   SAME                                 27900013
         XI    OAC38A+7,X'60'       SAME                                28000013
         XI    OACASE34+19,X'60'    SAME                                28100013
         XI    OAC30A+1,X'60'       SAME                                28200013
         XI    OAC30B+1,X'60'       SAME                                28300013
         XI    OACASE28+7,X'60'     SAME                                28400013
         XI    OACASE27+19,X'60'   SAME                                 28500013
         XI    OAC27A+7,X'60'       SAME                                28600013
         XI    OACASE22+19,X'60'    SAME                                28700013
         XI    OAC18A+1,X'60'       SAME                                28800013
         XI    OACASE16+7,X'60'     SAME                                28900013
         XI    OACASE15+19,X'60'   SAME                                 29000013
         XI    OAC10A+1,X'60'       SAME                                29100013
         XI    OANOTON2+19,X'60'   REVERSE CONDITIONAL BRANCH IN SEQCK  29200013
         SPACE 1                                                        29300013
* INITIALIZE THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN     29400013
* THE RUNNING ROUTINE AS NECESSARY.                                     29500013
         SPACE 1                                                        29600013
OAASCEND OC    OACASE44+6(4),WOADISP  INIT DISP IN CLC IN NETWK         29700013
         OC    OACASE44+16(4),WOADISP  SAME                             29800013
         OC    OAC38A+2(4),WOADISP      SAME                            29900013
         OC    OACASE34+14(4),WOADISP   SAME                            30000013
         OC    OACASE30+10(4),WOADISP   SAME                            30100013
         OC    OAC30A+6(4),WOADISP      SAME                            30200013
         OC    OACASE28+2(4),WOADISP    SAME                            30300013
         OC    OACASE27+14(4),WOADISP  SAME                             30400013
         OC    OAC27A+2(4),WOADISP       SAME                           30500013
         OC    OACASE22+14(4),WOADISP   SAME                            30600013
         OC    OACASE18+10(4),WOADISP   SAME                            30700013
         OC    OACASE16+2(4),WOADISP    SAME                            30800013
         OC    OACASE15+14(4),WOADISP  SAME                             30900013
         OC    OAC10SS+2(4),WOADISP     SAME                            31000013
         OC    OANOTON2+14(4),WOADISP  INITIALIZE DISP IN CLC IN SEQCK  31100013
         SPACE 1                                                        31200013
* INITIALIZE THE LENGTH FIELDS IN THE COMPARE INSTRUCTIONS IN           31300013
* THE RUNNING ROUTINE AS NECESSARY.                                     31400013
         SPACE 1                                                        31500013
         L     RE,WOALGTH          LENGTH OF CONTROL FIELD FOR COMPARES 31600013
         STC   RE,OACASE44+5       SET LENGTH FIELD IN CLC IN NETWORK   31700013
         STC   RE,OACASE44+15      SAME                                 31800013
         STC   RE,OAC38A+1          SAME                                31900013
         STC   RE,OACASE34+13       SAME                                32000013
         STC   RE,OACASE30+9        SAME                                32100013
         STC   RE,OAC30A+5          SAME                                32200013
         STC   RE,OACASE28+1        SAME                                32300013
         STC   RE,OACASE27+13      SAME                                 32400013
         STC   RE,OAC27A+1          SAME                                32500013
         STC   RE,OACASE22+13       SAME                                32600013
         STC   RE,OACASE18+9        SAME                                32700013
         STC   RE,OACASE16+1        SAME                                32800013
         STC   RE,OACASE15+13      SAME                                 32900013
         STC   RE,OAC10SS+1         SAME                                33000013
         STC   RE,OANOTON2+13      SET LENGTH FIELD IN CLC IN SEQCK     33100013
         SPACE 1                                                        33200013
* EXIT TO NEXT ASSIGNMENT ROUTINE.                                      33300013
         SPACE 1                                                        33400013
         L     RO,WRSAVC9           RESTORE RETURN ADDRESS              33500013
         BR    RO                   RETURN TO LOAD ROUTINE              33600013
         SPACE 2                                                        33700013
         SPACE 1                                                        33800013
*** WORK AREAS ***                                                      33900013
         SPACE 1                                                        34000013
WOADISP  DS    1F                  USED TO HOLD DISP FIELD FOR ORING    34100013
WOALGTH  DS    1F                  USED TO HOLD LENGTH FIELD FOR INIT.  34200013
WRSAVC9  DS    F                    USED TO SAVE REGISTER RO            34300013
OASAVEJ  DC    F'0'                                                     34400013
WRSAVC10 DS    7F                                                       34500013
         EJECT                                                          34600013
*** IERROF *** POLYPHASE REPLACEMENT NETWORK FOR FIXED LENGTH           34700013
*              RECORDS WHICH CONTAIN SINGLE CONTROL FIELDS AND/OR       34800013
*              REQUIRE EXTRACTING.                                      34900013
         SPACE 1                                                        35000013
**********************************************************************  35100013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROF                   35200013
**********************************************************************  35300013
         SPACE 1                                                        35400013
DICLOSE1 EQU   4                   DISP IN CLOSE BRANCH TABLE           35500013
DIDEBLK1 EQU   8                   DISP IN DEBLK BR TBL (GET TO FILL)   35600013
DIDEBLK2 EQU   0                   DISP IN DEBLK BR TBL (MODIFY + GET)  35700013
DIBLOCK1 EQU   12                  DISP IN BLOCK BR TBL (PUT INFER GET) 35800013
DIBLOCK2 EQU   4                   DISP IN BLOCK BR TBL (PUT EOS)       35900013
DIBLOCK3 EQU   0                   DISP IN BLOCK BR TBL (PUT EOF)       36000013
         SPACE 1                                                        36100013
DIERROF  DSECT                                                          36200013
         SPACE 1                                                        36300013
*** ENTRY TABLE                                                         36400013
         SPACE 1                                                        36500013
IERDOA   B     OAPICK              ENTRY TO FILL TREE                   36600013
         B     OAFIRET             ENTRY FROM DEBLOCK WHILE FILLING     36700013
         B     OAEOF               ENTRY FROM DEBLOCK AT EOF            36800013
         B     OARETRUN            ENTRY FROM DEBLOCK WHILE RUNNING     36900013
         B     OARETEOF            ENTRY FROM DEBLOCK AFTER EOF         37000013
         SPACE 2                                                        37100013
*  ENTRY FROM ALGORITHM TO INDICATE THE SEQUENCE AFTER THIS             37200013
*  IS TO BE REVERSED.                                                   37300013
         SPACE 1                                                        37400013
* REVERSE CONDITIONAL BRANCHES WHICH DETERMINE THE RESULTS OF           37500013
* COMPARES BETWEEN RECORDS OF THE NEW OR NEXT SEQUENCE.                 37600013
         SPACE 1                                                        37700013
         XI    OAC10A+1,X'60'      IN CASE 10                           37800013
         XI    OAC18A+1,X'60'      IN CASE18                            37900013
         XI    OACASE22+19,X'60'   IN CASE22                            38000013
         XI    OAC30A+1,X'60'      IN CASE30                            38100013
         XI    OAC30B+1,X'60'      IN CASE30                            38200013
         XI    OACASE34+19,X'60'   IN CASE34                            38300013
         XI    OAC38A+7,X'60'      IN CASE38                            38400013
         SPACE 1                                                        38500013
* SET A SWITCH ON IN THE END OF SEQUENCE CODE, CASE 6                   38600013
         SPACE 1                                                        38700013
         LA    RK,255              CONSTANT 'FF'                        38800013
         ST    RK,KAREVSW          SET REVERSAL SWITCH ON IN CASE 6     38900013
         SPACE 1                                                        39000013
*  INITIAL ENTRY TO START  FILLING OR ENTRY TO CONTINUE FILLING TREE    39100013
         SPACE 1                                                        39200013
OAPICK   L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               39300013
         SPACE 1                                                        39400013
* EXIT TO DEBLOCK ROUTINE                                               39500013
         SPACE 1                                                        39600013
         B     DIDEBLK1(0,RL)      GET TO FILL OR GET FOR REVERSAL      39700013
         SPACE 2                                                        39800013
*  ENTRY FROM DEBLOCK WHILE FILLING                                     39900013
         SPACE 1                                                        40000013
* SETS UP TO FILL THE TREE AND DETERMINES WHEN THE TREE IS FILLED.      40100013
         SPACE 1                                                        40200013
OAFIRET  S     RD,KAINCDEC         DECREMENT NEW ADDR BY EXTRACT INC+4  40300013
         CLI   KASWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 40400013
         BNE   OANOTON1            BRANCH IF OFF                        40500013
         SPACE 1                                                        40600013
* EXIT TO EXTRACT ROUTINE                                               40700013
         SPACE 1                                                        40800013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              40900013
         SPACE 2                                                        41000013
OANOTON1 LM    RH,RJ,WASAVE        FILLING REGISTERS                    41100013
         ST    RJ,0(0,RD)          ADDRESS OF TREE WITH RECORD          41200013
OAFILDUM LR    RF,RJ               ADDRESS OF TREE (NLA)                41300013
         BCT   RH,OAGCT            DECREMENT WAY COUNTER                41400013
         LA    RH,4                RESET WAY COUNTER                    41500013
         LA    RJ,20(0,RJ)         INCREMENT TO NEXT NODE               41600013
OAGCT    BCT   RI,OAMORE           DECREMENT G COUNTER                  41700013
         L     RE,OASAME           SET MODE                             41800013
         STM   RH,RJ,WASAVE                                             41900013
         CLC   OAGCT+4(4),OANOSAME  ARE WE RUNNING OR FLUSHING          42000013
         BNE   OANEXT2             RUNNING SITUATION                    42100013
         MVC   OACASE44(4),OA44FLSH OVERLAY TO BRANCH TO FLUSH ROUTINE  42200013
         MVC   OACAS27(2),KNOP     NOP THE BR INSTR TO THE FILL ROUTINE 42300013
         MVC   OACAS15(2),KNOP     NOP THE BR INSTR TO THE FILL ROUTINE 42400013
         MVC   OACASE41(4),OA41FLSH  OVERLAY TO BR TO FLUSH RTN CASE 41 42500013
         B     OANEXT2             FLUSHING SITUATION                   42600013
         SPACE 2                                                        42700013
OAMORE   L     RE,OAFILL           SET MODE                             42800013
         STM   RH,RJ,WASAVE        SAVE FILLING REGISTERS               42900013
         B     OANEXT2                                                  43000013
         SPACE 2                                                        43100013
*  ENTRY FROM DEBLOCK AT EOF                                            43200013
         SPACE 1                                                        43300013
* DETERMINES IF EOF SITUATION IS A NORMAL ONE, FILE SIZE LESS           43400013
* THEN G, OR FILE SIZE IS ZERO AND BRANCHES ACCORDINGLY.                43500013
         SPACE 1                                                        43600013
OAEOF    CLC   PPISRTG(4),WASAVE+4 COMPARE G COUNT IN PPI TO FILL NO.   43700013
         BNE   OANOZERO                                                 43800013
         L     RP,PPIRCV+4          CLOSE BASE REGISTER                 43900013
         SPACE 1                                                        44000013
*EXIT TO CLOSE ROUTINE                                                  44100013
         SPACE 1                                                        44200013
         LA    RB,4                 SET CODE TO CALL PHASE 3            44300013
         B     20(RP)              INPUT FILE WAS ZERO                  44400013
         SPACE 2                                                        44500013
OANOZERO LA    RK,0                CONSTANT OF 0                        44600013
         CL    RK,WASAVE+4         COMPARE TO FILL COUNT                44700013
         BE    OARETEOF                                                 44800013
         SPACE 2                                                        44900013
* FILE SIZE IS LESS THAN G. THE CODING IS MODIFIED TO FILL THE          45000013
* REMAINDER OF THE TREE WITH FAKE RECORDS. THESE RECORDS ARE            45100013
* THE TREE ADDRESSES.                                                   45200013
         SPACE 1                                                        45300013
         MVC   OACASE44(4),OA44FILL  MOD TO CHECK FOR DUMMY RCD         45400013
         MVC   OACAS27(4),OAMODC27  MOD TO CHECK FOR DUMMY RCD          45500013
         MVC   OACAS15(4),OAMODC15  MOD TO CHECK FOR DUMMY RCD          45600013
         MVC   OAC8A(6),OACHMVC    MODIFICATION TO CHECK FOR DUMMY REC  45700013
         OI    OACSUB8+1,X'F0'     INITIALIZE BRANCH INST IN CASE 8     45800013
         MVC   OAGCT+4(4),OANOSAME MODIFICATION TO START TREE FLUSHING  45900013
         MVC   OAPICK(12),OAMODIFY MODIFY FILLING RETURN LOCATION       46000013
OAMODIFY LM    RH,RJ,WASAVE        FILLING REGISTERS                    46100013
         L     RD,WATREE           DUMMY ADDRESS                        46200013
         B     OAFILDUM                                                 46300013
         SPACE 2                                                        46400013
* MODE POSITIONS AND BRANCH TABLE.                                      46500013
* THROUGH THE COMBINATION OF MODE AND FORMAT AN INDEXED                 46600013
* BRANCH IS PERFORMED WHICH BRANCHES TO THE CASE WHICH HANDLES          46700013
* THE INDICATED SITUATION.                                              46800013
         SPACE 1                                                        46900013
OAFLUSH  DC    A(OABTABLE)                                              47000013
OANEW    DC    A(OABTABLE+4)                                            47100013
OAFILL   DC    A(OABTABLE+8)                                            47200013
OASAME   DC    A(OABTABLE+12)                                           47300013
OABTABLE B     OANEXT                                                   47400013
         B     OANEXT                                                   47500013
         B     OACASE3                                                  47600013
         B     OANEXT                                                   47700013
         B     OACASE5                                                  47800013
         B     OACASE6                                                  47900013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 48000013
OAMODLOC B     OACASE8                                                  48100013
         B     OACASE9                                                  48200013
         B     OACASE10                                                 48300013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 48400013
         B     OANEXT                                                   48500013
         B     OACASE13                                                 48600013
         B     OACASE14                                                 48700013
         B     OACASE15                                                 48800013
         B     OACASE16                                                 48900013
         B     OACASE17                                                 49000013
         B     OACASE18                                                 49100013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 49200013
         B     OANEXT                                                   49300013
         B     OACASE21                                                 49400013
         B     OACASE22                                                 49500013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 49600013
         B     OACASE16                                                 49700013
         B     OACASE25                                                 49800013
         B     OACASE26                                                 49900013
         B     OACASE27                                                 50000013
         B     OACASE28                                                 50100013
         B     OACASE29                                                 50200013
         B     OACASE30                                                 50300013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 50400013
         B     OANEXT                                                   50500013
         B     OACASE33                                                 50600013
         B     OACASE34                                                 50700013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 50800013
         B     OACASE16                                                 50900013
         B     OACASE37                                                 51000013
         B     OACASE38                                                 51100013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 51200013
         B     OACASE28                                                 51300013
         B     OACASE41                                                 51400013
         B     OACASE42                                                 51500013
         B     OACASE44                                                 51600013
         B     OACASE44                                                 51700013
         SPACE 2                                                        51800013
* THIS CASE HANDLES AN S/SSS SITUATION WHILE RUNNING                    51900013
         SPACE 1                                                        52000013
OACASE44 BC    0,*+4               WILL BE BAL RO,OASUB1 ON FILE L.T. G 52100013
*                                    (FILL), OR BAL RO,OASUB44 (FLUSH)  52200013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            52300013
         BNH   OACASE16                                                 52400013
         CLC   0(1,RD),0(RJ)       COMPARE WINNER TO LOSER 3            52500013
         BNH   OASHIFT3                                                 52600013
OASHIFT4 STM   RI,RJ,8(RF)         LOSER 2 + 3 TO LOSER 1 + 2           52700013
         ST    RD,16(0,RF)         WINNER TO LOSER 3                    52800013
         LR    RD,RH               LOSER 1 TO WINNER                    52900013
OANEXT   L     RF,0(0,RF)          ADDRESS OF NEXT NODE                 53000013
OANEXT2  LM    RG,RJ,4(RF)         LOAD NODE                            53100013
         B     0(RE,RG)            GO TO PROPER CASE                    53200013
         SPACE 2                                                        53300013
* THIS CASE HANDLES AN N/SSS SITUATION WHILE RUNNING                    53400013
         SPACE 1                                                        53500013
OACASE42 L     RE,OASAME           UPDATE MODE                          53600013
         LA    RK,144              FORMAT SSN                           53700013
         ST    RK,4(0,RF)          UPDATE FORMAT                        53800013
         B     OASHIFT4                                                 53900013
         SPACE 2                                                        54000013
* THIS CASE HANDLES AN -/SSS SITUATION WHILE FLUSHING                   54100013
         SPACE 1                                                        54200013
OACASE41 BC    0,OASUBF41          WILL BE BAL RO,OASUBF41 WHEN FLUSHG  54300013
OASUB41  L     RE,OASAME           UPDATE MODE                          54400013
         LA    RK,96               FORMAT SS-                           54500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        54600013
         B     OASHIFT4                                                 54700013
         SPACE 2                                                        54800013
* THIS CASE HANDLES AN N/SSN SITUATION WHILE RUNNING                    54900013
         SPACE 1                                                        55000013
OACASE38 L     RE,OASAME           UPDATE MODE                          55100013
         LA    RK,128              FORMAT SNN                           55200013
         ST    RK,4(0,RF)          UPDATE FORMAT                        55300013
OAC38A   CLC   0(1,RD),0(RJ)       COMPARE WINNER TO LOSER 3            55400013
         BNL   OASHIFT3                                                 55500013
         B     OASHIFT4                                                 55600013
         SPACE 2                                                        55700013
* THIS CASE HANDLES AN -/SSN SITUATION WHILE FLUSHING                   55800013
         SPACE 1                                                        55900013
OACASE37 L     RE,OASAME           UPDATE MODE                          56000013
         LA    RK,80               FORMAT SN-                           56100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        56200013
         B     OASHIFT4                                                 56300013
         SPACE 2                                                        56400013
* THIS CASE HANDLES AN N/SNN SITUATION WHILE RUNNING                    56500013
         SPACE 1                                                        56600013
OACASE34 L     RE,OASAME           UPDATE MODE                          56700013
         LA    RK,112              FORMAT NNN                           56800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        56900013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            57000013
         BNL   OASHIFT2                                                 57100013
         B     OAC38A                                                   57200013
         SPACE 2                                                        57300013
* THIS CASE HANDLES AN -/SNN SITUATION WHILE FLUSHING                   57400013
         SPACE 1                                                        57500013
OACASE33 L     RE,OASAME           UPDATE MODE                          57600013
         LA    RK,64               FORMAT NN-                           57700013
         ST    RK,4(0,RF)          UPDATE FORMAT                        57800013
         B     OASHIFT4                                                 57900013
         SPACE 2                                                        58000013
* THIS CASE HANDLES AN N/NNN SITUATION WHILE RUNNING                    58100013
         SPACE 1                                                        58200013
OACASE30 LA    RK,160              FORMAT SSS                           58300013
         ST    RK,4(0,RF)          UPDATE FORMAT                        58400013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            58500013
OAC30A   BNL   OAC10SS                                                  58600013
         CLC   0(1,RD),0(RJ)       COMPARE WINNER TO LOSER 3            58700013
OAC30B   BNL   OASHIFT3                                                 58800013
         B     OASHIFT4                                                 58900013
         SPACE 2                                                        59000013
* THIS CASE HANDLES AN -/NNN SITUATION WHILE FLUSHING                   59100013
         SPACE 1                                                        59200013
OACASE29 L     RE,OANEW            UPDATE MODE                          59300013
         LA    RK,96               FORMAT SS-                           59400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        59500013
         B     OASHIFT4                                                 59600013
         SPACE 2                                                        59700013
* THIS CASE HANDLES AN S/SS- SITUATION WHILE RUNNING                    59800013
         SPACE 1                                                        59900013
OACASE28 CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            60000013
         BNH   OACASE16                                                 60100013
OASHIFT3 ST    RI,8(0,RF)          LOSER 2 TO LOSER 1                   60200013
         ST    RD,12(0,RF)         WINNER TO LOSER 2                    60300013
         LR    RD,RH               LOSER 1 TO WINNER                    60400013
         L     RF,0(0,RF)          ADDRESS OF NEXT NODE                 60500013
         LM    RG,RJ,4(RF)         LOAD NODE                            60600013
         B     0(RE,RG)            GO TO PROPER CASE                    60700013
         SPACE 2                                                        60800013
* THIS CASE HANDLES AN S/SS- SITUATION WHILE FILLING                    60900013
         SPACE 1                                                        61000013
OACASE27 LA    RK,160              FORMAT SSS                           61100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        61200013
OACAS27  BC    0,*+4               WILL BE BAL RO,OASUB2 ON FILE L.T. G 61300013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO HIGH 2             61400013
         BNH   OAC27A                                                   61500013
OASUB2R  ST    RD,16(0,RF)         WINNER TO LOSER 3                    61600013
         B     OAPICK                                                   61700013
         SPACE 2                                                        61800013
OAC27A   CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER 1            61900013
         BNH   OAC27B                                                   62000013
         ST    RI,16(0,RF)         LOSER 2 TO LOSER 3                   62100013
         ST    RD,12(0,RF)         WINNER TO LOSER 2                    62200013
         B     OAPICK                                                   62300013
         SPACE 2                                                        62400013
OAC27B   STM   RH,RI,12(RF)        LOSER 1 + 2 TO LOSER 2 + 3           62500013
         ST    RD,8(0,RF)          WINNER TO LOSER 1                    62600013
         B     OAPICK                                                   62700013
         SPACE 2                                                        62800013
* THIS CASE HANDLES AN N/SS- SITUATION WHILE RUNNING                    62900013
         SPACE 1                                                        63000013
OACASE26 L     RE,OASAME           UPDATE MODE                          63100013
         LA    RK,80               FORMAT SN-                           63200013
         ST    RK,4(0,RF)          UPDATE FORMAT                        63300013
         B     OASHIFT3                                                 63400013
         SPACE 2                                                        63500013
* THIS CASE HANDLES AN -/SS- SITUATION WHILE FLUSHING                   63600013
         SPACE 1                                                        63700013
OACASE25 L     RE,OASAME           UPDATE MODE                          63800013
         LA    RK,48               FORMAT S--                           63900013
         ST    RK,4(0,RF)          UPDATE FORMAT                        64000013
         B     OASHIFT3                                                 64100013
         SPACE 2                                                        64200013
* THIS CASE HANDLES AN N/SN- SITUATION WHILE RUNNING                    64300013
         SPACE 1                                                        64400013
OACASE22 L     RE,OASAME           UPDATE MODE                          64500013
         LA    RK,64               FORMAT NN-                           64600013
         ST    RK,4(0,RF)          UPDATE FORMAT                        64700013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            64800013
         BNL   OASHIFT2                                                 64900013
         B     OASHIFT3                                                 65000013
         SPACE 2                                                        65100013
* THIS CASE HANDLES AN -/SN- SITUATION WHILE FLUSHING                   65200013
         SPACE 1                                                        65300013
OACASE21 L     RE,OASAME           UPDATE MODE                          65400013
         LA    RK,32               FORMAT N--                           65500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        65600013
         B     OASHIFT3                                                 65700013
         SPACE 2                                                        65800013
* THIS CASE HANDLES AN N/NN- SITUATION WHILE RUNNING                    65900013
         SPACE 1                                                        66000013
OACASE18 LA    RK,96               FORMAT SS-                           66100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        66200013
         CLC   0(1,RD),0(RI)       COMPARE WINNER TO LOSER 2            66300013
OAC18A   BNL   OAC10SS                                                  66400013
         B     OASHIFT3                                                 66500013
         SPACE 2                                                        66600013
* THIS CASE HANDLES AN -/NN- SITUATION WHILE FLUSHING                   66700013
         SPACE 1                                                        66800013
OACASE17 L     RE,OANEW            UPDATE MODE                          66900013
         LA    RK,48               FORMAT S--                           67000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        67100013
         B     OASHIFT3                                                 67200013
         SPACE 2                                                        67300013
* THIS CASE HANDLES AN S/S-- SITUATION WHILE RUNNING                    67400013
         SPACE 1                                                        67500013
OACASE16 CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER 1            67600013
         BNH   OANEXT                                                   67700013
OASHIFT2 ST    RD,8(0,RF)          WINNER TO LOSER 1                    67800013
         LR    RD,RH               LOSER 1 TO WINNER                    67900013
         L     RF,0(0,RF)          ADDRESS OF NEXT NODE                 68000013
         LM    RG,RJ,4(RF)         LOAD NODE                            68100013
         B     0(RE,RG)            GO TO PROPER CASE                    68200013
         SPACE 2                                                        68300013
* THIS CASE HANDLES AN S/S-- SITUATION WHILE FILLING                    68400013
         SPACE 1                                                        68500013
OACASE15 LA    RK,96               FORMAT SS-                           68600013
         ST    RK,4(0,RF)          UPDATE FORMAT                        68700013
OACAS15  BC    0,*+4               WILL BE BAL RO,OASUB3 ON FILE L.T. G 68800013
         CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER 1            68900013
         BH    OAC15A                                                   69000013
         ST    RH,12(0,RF)         LOSER 1 TO LOSER 2                   69100013
         ST    RD,8(0,RF)          WINNER TO LOSER 1                    69200013
         B     OAPICK                                                   69300013
         SPACE 2                                                        69400013
OAC15A   ST    RD,12(0,RF)         WINNER TO LOSER 2                    69500013
         B     OAPICK                                                   69600013
         SPACE 2                                                        69700013
* THIS CASE HANDLES AN N/S-- SITUATION WHILE RUNNING                    69800013
         SPACE 1                                                        69900013
OACASE14 LA    RK,32               FORMAT N--                           70000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        70100013
         L     RE,OASAME           UPDATE MODE                          70200013
         B     OASHIFT2                                                 70300013
         SPACE 2                                                        70400013
* THIS CASE HANDLES AN -/S-- SITUATION WHILE FLUSHING                   70500013
         SPACE 1                                                        70600013
OACASE13 L     RE,OASAME           UPDATE MODE                          70700013
OAC13A   LA    RK,0                FORMAT ---                           70800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        70900013
         LR    RD,RH               LOSER 1 TO WINNER                    71000013
         B     OANEXT                                                   71100013
         SPACE 2                                                        71200013
* THIS CASE HANDLES AN N/N-- SITUATION WHILE RUNNING                    71300013
         SPACE 1                                                        71400013
OACASE10 LA    RK,48               FORMAT S--                           71500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        71600013
OAC10SS  CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER 1            71700013
OAC10A   BNL   OANEXT                                                   71800013
         B     OASHIFT2                                                 71900013
         SPACE 2                                                        72000013
* THIS CASE HANDLES AN -/N-- SITUATION WHILE FLUSHING                   72100013
         SPACE 1                                                        72200013
OACASE9  L     RE,OANEW            UPDATE MODE                          72300013
         B     OAC13A                                                   72400013
         SPACE 2                                                        72500013
* INDICATES THE TREE IS FILLED AND FORCES THE NETWORK INTO              72600013
* A RUNNING SITUATION.                                                  72700013
         SPACE 1                                                        72800013
OACASE8  LR    RF,RD               TREE ADDRESS EQUALS DUMMY RECORD     72900013
         CL    RD,WATREE           IS THIS A REAL RECORD OR TREE ADDR   73000013
         BC    10,OARETEOF+8       BRANCH IF IT IS A TREE ADDRESS       73100013
         ST    RD,WALTNODE         SAVE ADDR OF RECD IN LAST TEST NODE  73200013
OAC8A    MVC   OAMODLOC(4),OAMODC8B MODIFY BRANCH TABLE                 73300013
OACSUB8  BC    0,OARETEOF          INITIALIZED TO BRANCH AT FILE L.T. G 73400013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               73500013
         SPACE 1                                                        73600013
* EXIT TO DEBLOCK ROUTINE                                               73700013
         SPACE 1                                                        73800013
         B     DIDEBLK2(0,RL)      MODIFY AND GET                       73900013
         SPACE 2                                                        74000013
* INDICATES THERE IS A RECORD TO BE BLOCKED                             74100013
         SPACE 1                                                        74200013
OACASE8A LR    RF,RH               ADDRESS OF THE TREE           A35577 74300021
         CL    RD,WATREE           IS THIS A REAL RECORD,NOT TREE ADDR  74400013
         BC    10,OARETEOF+8       BRANCH IF IT IS A TREE ADDRESS       74500013
OACASE8B L     RK,WALTNODE         ADDRESS OF RECORD IN LAST TEST NODE  74600013
         ST    RD,WALTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  74700013
         LR    RD,RK               ADDRESS TO WINNER POSITION           74800013
         A     RD,KAINCDEC         INC ADDR BY EXTRACT INCREMENT +4     74900013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 75000013
         SPACE 1                                                        75100013
* EXIT TO BLOCK ROUTINE                                                 75200013
         SPACE 1                                                        75300013
         B     DIBLOCK1(0,RL)      PUT INFERS GET                       75400013
         SPACE 2                                                        75500013
* INDICATES THAT IT IS THE END OF A SEQUENCE                            75600013
         SPACE 1                                                        75700013
OACASE6  L     RK,WALTNODE         ADDRESS OF RECORD IN LAST TEST NODE  75800013
         ST    RD,WALTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  75900013
         LR    RD,RK               ADDRESS TO WINNER POSITION           76000013
         A     RD,KAINCDEC         INC ADDR BY EXTRACT INCREMENT +4     76100013
         SPACE 1                                                        76200013
* CHECK SEQUENCE REVERSING SWITCH. IF IT IS ON COMPLETE                 76300013
* THE SEQUENCE REVERSING CYCLE.                                         76400013
         SPACE 1                                                        76500013
         CLI   KAREVSW+3,X'00'     CHECK REVERSAL SWITCH                76600013
         BE    OASWOFF             IF OFF REVERSAL IS NOT IN PROCESS    76700013
         SPACE 1                                                        76800013
* TURN OFF RERVERSAL SWITCH. REVERSE THE CONDITIONAL BRANCHES WHICH     76900013
* DETERMINE THE RESULTS OF COMPARES BETWEEN RECORDS OF THE PRESENT      77000013
* SEQUENCE. REVERSE THE CONDITIONAL BRANCH WHICH DETERMINES THE         77100013
* RESULT OF THE SEQUENCE CHECK OF THE INCOMING RECORD.                  77200013
         SPACE 1                                                        77300013
         SR    RK,RK               ZERO A REGISTER                      77400013
         ST    RK,KAREVSW          TURN REVERSAL SWITCH OFF             77500013
         XI    OACASE16+7,X'60'    IN CASE16                            77600013
         XI    OACASE28+7,X'60'    IN CASE28                            77700013
         XI    OACASE44+11,X'60'   IN CASE 44                           77800013
         XI    OACASE44+21,X'60'   IN CASE 44                           77900013
         XI    OANOTON2+19,X'60'   IN SEQUENCE CHECK                    78000013
         SPACE 1                                                        78100013
OASWOFF  L     RL,PPIBLK+4          BLOCK BASE REGISTER                 78200013
         SPACE 1                                                        78300013
* EXIT TO BLOCK ROUTINE                                                 78400013
         SPACE 1                                                        78500013
         B     DIBLOCK2(0,RL)      PUT EOS                              78600013
         SPACE 2                                                        78700013
* INDICATES THAT IT IS END OF FILE                                      78800013
         SPACE 1                                                        78900013
OACASE5  L     RD,WALTNODE         ADDR OF RECORD IN LAST TEST NODE     79000013
         A     RD,KAINCDEC         INC ADDR BY EXTRACT INCREMENT +4     79100013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 79200013
         SPACE 1                                                        79300013
* EXIT TO BLOCK ROUTINE                                                 79400013
         SPACE 1                                                        79500013
         B     DIBLOCK3(0,RL)      PUT EOF                              79600013
         SPACE 2                                                        79700013
* THIS SITUATION HANDLES AN S/--- SITUATION WHILE FILLING               79800013
         SPACE 1                                                        79900013
OACASE3  LA    RK,48               FORMAT S--                           80000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        80100013
         ST    RD,8(0,RF)          WINNER TO LOSER 1                    80200013
         B     OAPICK                                                   80300013
         SPACE 2                                                        80400013
*  ENTRY FROM DEBLOCK WHILE RUNNING                                     80500013
         SPACE 1                                                        80600013
* SEQUENCE CHECKS THE NEW RECORD AND STARTS IT THROUGH THE              80700013
* REPLACEMENT NETWORK.                                                  80800013
         SPACE 1                                                        80900013
OARETRUN S     RD,KAINCDEC         DECREMENT NEW ADDR BY EXTRACT INC+4  81000013
         CLI   KASWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 81100013
         BNE   OANOTON2            BRANCH IF OFF                        81200013
         SPACE 1                                                        81300013
* EXIT TO EXTRACT ROUTINE                                               81400013
         SPACE 1                                                        81500013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              81600013
         SPACE 2                                                        81700013
OANOTON2 L     RC,WALTNODE         ADDRESS OF RECORD IN LAST TEST NODE  81800013
         L     RF,0(0,RC)          NODE ADDRESS WITH RECORD HELD BACK   81900013
         ST    RF,0(0,RD)          NODE ADDRESS WITH NEW RECORD         82000013
         CLC   0(1,RD),0(RC)       COMPARE NEW RECORD TO ONE HELD BACK  82100013
         BL    OAMODNEW                                                 82200013
         L     RE,OASAME           UPDATE MODE                          82300013
         B     OANEXT2                                                  82400013
         SPACE 2                                                        82500013
OAMODNEW L     RE,OANEW            UPDATE MODE                          82600013
         B     OANEXT2                                                  82700013
         SPACE 2                                                        82800013
*  ENTRY FROM DEBLOCK AFTER EOF                                         82900013
         SPACE 1                                                        83000013
* SET UP TO FLUSH ANOTHER RECORD FROM THE TREE                          83100013
         SPACE 1                                                        83200013
OARETEOF L     RK,WALTNODE         ADDRESS OF RECORD IN LAST TEST NODE  83300013
         L     RF,0(0,RK)          NODE ADDRESS WITH RECORD HELD BACK   83400013
         L     RE,OAFLUSH          UPDATE MODE                          83500013
         L     RD,WATREE           SET DUMMY RCD AS NEXT INPUT RCD      83600013
         B     OANEXT2                                                  83700013
         SPACE 2                                                        83800013
*  IF RD HAS DUMMY RCD TREAT AS THE AUTO LOSER (FILE L. T. G)           83900013
         SPACE 1                                                        84000013
OASUB1   CL    RD,WATREE           IS THIS A REAL OR DUMMY RCD          84100013
         BC    10,OASHIFT4         BR IF RD HAS A DUMMY RCD             84200013
         BR    RO                  RD HAS A REAL RCD. CONTINUE NORMALLY 84300013
         SPACE 1                                                        84400013
OASUB2   CL    RD,WATREE           IS THIS A REAL OR DUMMY RCD          84500013
         BC    10,OASUB2R          BR IF RD HAS A DUMMY RCD             84600013
         BR    RO                  RD HAS A REAL RCD. CONTINUE NORMALLY 84700013
         SPACE 1                                                        84800013
OASUB3   CL    RD,WATREE           IS THIS A REAL OR DUMMY RECORD       84900013
         BC    10,OAC15A           BR IF RD HAS A DUMMY RCD(EQ OR GTR)  85000013
         BR    RO                  RD HAS A REAL RCD. CONTINUE NORMALLY 85100013
         SPACE 2                                                        85200013
OASUBF41 CLC   16(4,RF),WATREE     IS IT A -/SSS CONDITION              85300013
         BCR   4,RO                YES IT IS A -/SSS                    85400013
         CLC   12(4,RF),WATREE     NO IS IT A -/SS- CONDITION           85500013
         BC    4,OACASE25          YES IT IS A -/SS-                    85600013
         CLC   8(4,RF),WATREE      NO IS IT A -/S-- CONDITION           85700013
         BC    4,OACASE13          YES IT IS A -/S--                    85800013
         B     OAC13A              NO IT IS A -/--- CONDITION           85900013
         SPACE 2                                                        86000013
OASUBF44 CLC   16(4,RF),WATREE     IS IT A /SSS CONDITION               86100013
         BC    4,OARSSS            YES NOW CHECK IF IN RCD IS REAL      86200013
         CLC   12(4,RF),WATREE     NO IT IS A /SS- CONDITION            86300013
         BC    4,OARSS             YES NOW CHECK IF IN RCD IS REAL      86400013
         CLC   8(4,RF),WATREE      NO IT IS A /S-- CONDITION            86500013
         BC    4,OARS              YES CHECK IF IN RCD IS REAL          86600013
         B     OAR                 NO IT IS A /--- CHK IF IN IS REAL    86700013
         SPACE 2                                                        86800013
OARSSS   CL    RD,WATREE           IS THIS A REAL OR DUMMY RCD          86900013
         BC    10,OASUB41          IN RCD IS DUMMY GO TO CASE -/SSS     87000013
         BR    RO                  IN RCD IS REAL GO TO CASE S/SSS      87100013
         SPACE 2                                                        87200013
OARSS    CL    RD,WATREE           IS THIS A REAL OR DUMMY RCD          87300013
         BC    10,OACASE25         IN RCD IS DUMMY GO TO CASE -/SS-     87400013
         LA    RK,96               UPDATE FORMAT                        87500013
         ST    RK,4(0,RF)          SET FORMAT OF S/SS-                  87600013
         B     OACASE28            GO TO CASE S/SS-                     87700013
         SPACE 2                                                        87800013
OARS     CL    RD,WATREE           IS IN A REAL OR DUMMY                87900013
         BC    10,OACASE13         IN RCD IS A DUMMY GO TO CASE -/S--   88000013
         LA    RK,48               INPT RCD IS REAL. UPDATE FORMAT TO   88100013
         ST    RK,4(0,RF)            S/S--                              88200013
         B     OACASE16            BR TO CASE S/S--                     88300013
         SPACE 2                                                        88400013
OAR      CL    RD,WATREE           IS THIS A REAL OR DUMMY IN RCD X/--- 88500013
         BC    10,OAC13A           INPUT RCD IS DUMMY,BR TO CASE -/---  88600013
         L     RE,OASAME           UPDATE MODE                          88700013
         LA    RK,0                INPUT RCD IS REAL.UPDATE FORMAT      88800013
         ST    RK,4(0,RF)            TO  /---                           88900013
         B     OANEXT                                                   89000013
         SPACE 1                                                        89100013
         SPACE 1                                                        89200013
*** CONSTANTS                                                           89300013
         SPACE 1                                                        89400013
KAINCDEC DS    1F                  ADDRESS INC OR DEC OF EXTRACT INC+4  89500013
KASWITCH DC    X'00000000'         EXTRACT SWITCH                       89600013
KAREVSW  DC    X'000000FF'         SWITCH USED WHILE REVERSING SEQUENCE 89700013
*                                  THIS SWITCH IS INITIALLY ON.         89800013
KNOP     DC    X'4700'             NOP                                  89900013
         SPACE 1                                                        90000013
*** WORK AREAS *** THE ORDERING OF THESE WORK AREAS MUST BR MAINTAINED  90100013
         SPACE 1                                                        90200013
WASAVE   DS    3F                  FILLING REGISTER SAVE AREA           90300013
WATREE   DC    X'7FFFFFFF'         USED FOR DUMMY RECORDS               90400013
WALTNODE DS    1F                  LAST TEST NODE                       90500013
         DC    A(16)               FORMAT OF LAST TEST NODE             90600013
WATREEAD DS    1F                  LOCATION OF TREE                     90650013
         SPACE 1                                                        90700013
*** MODIFICATION INSTRUCTIONS                                           90800013
         SPACE 1                                                        90900013
OAMODC8  B     OACASE8A            MOD TO CK FOR DUMMY AND HOLD BACK    91000013
OAMODC8B B     OACASE8B            MODIFICATION TO SKIP DUMMY CHECK     91100013
OACHMVC  MVC   OAMODLOC(4),OAMODC8 MODIFY BRANCH TABLE                  91200013
OANOSAME L     RE,OAFLUSH          MODIFICATION TO START FLUSHING TREE  91300013
OA44FILL BAL   RO,OASUB1           FILE L.T. G CHECK IF RD A DUMMY      91400013
OAMODC27 BAL   RO,OASUB2           FILE L.T. G CHECK IF RD A DUMMY      91500013
OAMODC15 BAL   RO,OASUB3           FILE L.T. G CHECK IF RD A DUMMY      91600013
OA44FLSH BAL   RO,OASUBF44         BR TO FLUSH RTN CASE44               91700013
OA41FLSH BAL   RO,OASUBF41         BR TO FLUSH RTN CASE 41              91800013
DIERAMA  DSECT                                                          91900013
*                                                                       92000013
       COPY  AMAMAIN                                                    92100013
         EJECT                                                          92200013
         SMPPI                                                          92300013
         END                                                            92400013
