         TITLE ' IERAOG - OS/360 SORT/MERGE - 360S-SM-023 04/01/65 '    00100013
*MODULE NAME:*** IERAOG ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT FOR VARIABLE LENGTH      00600013
*   POLYPHASE REPLACEMENT WITH MULTIPLE CONTROL FIELDS. THE FUNCTION OF 00700013
*   THIS MODULE IS TO GENERATE THE REPLACEMENT TREE IN GENERATED CORE,  00800013
*   CHANGE THE CONDITIONS FOR BRANCHING IN THE RUNNING PROGRAM IF THE   00900013
*   RECORDS ARE TO BE COLLATED IN DESCENDING ORDER IN THE FIRST         01000013
*   SEQUENCE, AND OTHERWISE INITIALIZE THE COMPARE INSTRUCTIONS IN THE  01100013
*   RUNNING PROGRAM.                                                    01200013
         SPACE 2                                                        01300013
*USED AS A DSECT IN'                                                    01400013
*                                                                       01500013
*    N/A                                                                01600013
*                                                                       01700013
*MACROS USED'                                                           01800013
         SPACE 1                                                        01900013
*   SMPPI                                                               02000013
         SPACE 2                                                        02100013
*ENTRY POINTS:                                                          02200013
         SPACE 1                                                        02300013
*        ENTRY IERMOA              ENTRY FROM: LOAD MODULE, IERRC9      02400013
*                                    CALLING SEQUENCE-                  02500013
*                                      LOAD   EP=IERAOG,DCB=            02600013
*                                      LR     RP,RA                     02700013
*                                      BALR   RO,RP                     02800013
         SPACE 2                                                        02900013
*INPUT: PPI FIELDS REFERENCED-                                          03000013
         SPACE 1                                                        03100013
*    PPISRTG    PPISPGN1                                                03200013
*    PPIAXERT   PPINET+4                                                03300013
*    PPISW1+3,X'10'                                                     03400013
*    PPIDDOL1                                                           03500013
         SPACE 2                                                        03600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03700013
         SPACE 1                                                        03800013
*    PPISPGN1                                                           03900013
*    REPLACEMENT TREE IS CREATED IN GENERATED CORE.                     04000013
         SPACE 2                                                        04100013
*EXTERNAL ROUTINES:                                                     04200013
         SPACE 1                                                        04300013
*        N/A                                                            04400013
         SPACE 2                                                        04500013
*EXTERNAL PARAMETERS:                                                   04600013
         SPACE 1                                                        04700013
*        N/A                                                            04800013
         SPACE 2                                                        04900013
*EXITS: NORMAL                                                          05000013
         SPACE 1                                                        05100013
*        BR    RO - RETURN TO LOAD ROUTINE, IERRC9                      05200013
         SPACE 2                                                        05300013
*EXITS: ERROR                                                           05400013
         SPACE 1                                                        05500013
*        N/A                                                            05600013
         SPACE 2                                                        05700013
*TABLES/WORK AREAS:                                                     05800013
         SPACE 1                                                        05900013
*      WOCDISP - FULL WORD USED TO HOLD DISPLACEMENT FIELD FOR ORING    06000013
*    THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN THE RUNNING 06100013
*    PROGRAM IN ORDER TO INITIALIZE THEM AS MECESSARY.                  06200013
*      WRSAVC9, A FULL WORD, IS USED TO HOLD THE ADDRESS OF THE CALLING 06300013
*    ROUTINE, THE LOAD MODULE IERRC9.                                   06400013
         SPACE 2                                                        06500013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06600013
         SPACE 2                                                        06700013
*NOTES:                                                                 06800013
         SPACE 1                                                        06900013
*    THIS MODULE IS USED WITH VARIABLE LENGTH RECORDS WITH MULTIPLE     07000013
*    CONTROL FIELDS FOR A POLYPHASE SORT.                               07100013
         SPACE 2                                                        07200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07300013
         SPACE 1                                                        07400013
RA       EQU   0                   CONTENTS IN- N/A                     07500013
*                                  USE- NOT USED                        07600013
*                                  CONTENTS OUT- N/A                    07700013
RB       EQU   1                   CONTENTS IN- N/A                     07800013
*                                  USE- NOT USED                        07900013
*                                  CONTENTS OUT- N/A                    08000013
RC       EQU   2                   CONTENTS IN- N/A                     08100013
*                                  USE- WORK REGISTER                   08200013
*                                  CONTENTS OUT- N/A                    08300013
RD       EQU   3                   CONTENTS IN- N/A                     08400013
*                                  USE- WORK REGISTER                   08500013
*                                  CONTENTS OUT- N/A                    08600013
RE       EQU   4                   CONTENTS IN- N/A                     08700013
*                                  USE- WORK REGISTER, NEXT LEVEL       08800013
*                                       ADDRESS                         08900013
*                                  CONTENTS OUT- N/A                    09000013
RF       EQU   5                   CONTENTS IN- N/A                     09100013
*                                  USE- WORK REGISTER, FORMAT           09200013
*                                  CONTENTS OUT- N/A                    09300013
RG       EQU   6                   CONTENTS IN- N/A                     09400013
*                                  USE- WORK REGISTER                   09500013
*                                  CONTENTS OUT- N/A                    09600013
RH       EQU   7                   CONTENTS IN- N/A                     09700013
*                                  USE- MODE OR WAY COUNTER             09800013
*                                  CONTENTS OUT- N/A                    09900013
RI       EQU   8                   CONTENTS IN- N/A                     10000013
*                                  USE- G COUNT                         10100013
*                                  CONTENTS OUT- N/A                    10200013
RJ       EQU   9                   CONTENTS IN- N/A                     10300013
*                                  USE- WORK REGISTER                   10400013
*                                  CONTENTS OUT- N/A                    10500013
RK       EQU   10                  CONTENTS IN- N/A                     10600013
*                                  USE- RECORD COUNTER                  10700013
*                                  CONTENTS OUT- N/A                    10800013
RL       EQU   11                  CONTENTS IN- N/A                     10900013
*                                  USE- PROGRAM BASE REGISTER           11000013
*                                  CONTENTS OUT- N/A                    11100013
RM       EQU   12                  CONTENTS IN- N/A                     11200013
*                                  USE- EQUALS BASE REGISTER            11300013
*                                  CONTENTS OUT- N/A                    11400013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          11500013
*                                  USE- PPI REFERENCE,REGISTER SAVE     11600013
*                                    AREA                               11700013
*                                  CONTENTS OUT- ADDRESS OF PPI         11800013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      11900013
*                                                IERRC9                 12000013
*                                  USE- BASE REGISTER FOR DSECT OF      12100013
*                                       IERROG                          12200013
*                                  CONTENTS OUT - RETURN ADDRESS IN     12300013
*                                                 IERRC9                12400013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMOA 12500013
*                                  USE- NOT USED                        12600013
*                                  CONTENTS OUT- N/A                    12700013
         SPACE 2                                                        12800013
*START OF MODULE CODE PROPER:                                           12900013
         SPACE 2                                                        13000013
         SPACE 1                                                        13100013
IERAOG   CSECT                                                          13200013
         USING *,RL                                                     13300013
         USING IERRCA,RN                                                13400013
         USING DIERROG,RO                                               13500013
IERMOA   LR    RL,RP               SET PROGRAM BASE REGISTER            13600013
         ST    RO,WRSAVC9                                               13700013
         L     RO,PPINET+4          SET DSECT REGISTER OF RUNNING MOD   13800013
         SPACE 1                                                        13900013
* DETERMINE SIZE OF AREA FOR GENERATING THE TREE,RESET THE ADDRESS OF   14000013
* THE GENERATED AREA BY THIS AMOUNT,AND SAVE THIS ADDRESS FOR THE       14100013
* NETWORK AS THE TREE ADDRESS AND FOR THE NEXT ROUTINE AS THE           14200013
* ADDRESS OF THE GENERATED AREA.                                        14300013
         SPACE 1                                                        14400013
         L     RI,PPISRTG          G OR NUMBER OF RECORDS FOR TREE      14500013
         LA    RK,1                RECORD COUNTER-RECORDS TREE CAN HOLD 14600013
         LA    RC,12               BYTES PER NODE                       14700013
         LR    RF,RI               G OR NUMBER OF RECORDS FOR TREE      14800013
         SR    RF,RK               FORM G-1                             14900013
         SR    RE,RE               ZERO REGISTER                        15000013
         MR    RE,RC               CALCULATE NUMBER OF BYTES IN TREE    15100013
         LA    RJ,36               SIZE OF MINIMUM TREE                 15200013
         CR    RF,RJ               IS CALCULATED SIZE EQ OR G. MINIMUM  15300013
         BNL   OCOKSIZE            BRANCH IF IT IS                      15400013
         LR    RF,RJ               SET TREE SIZE TO MINIMUM             15500013
OCOKSIZE TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               15600013
         BNO   AOGNOMES            SWITCH OFF BYPASS MESSAGE            15700013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  15800013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       15900013
         STM   RO,RB,AOGSAVO       SAVE REGISTER                        16000013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    16100013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           16200013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    16300013
         BAL   RO,4(RP)                                                 16400013
         MVC   DMSG904B(8),0(RB)       MOVE NUMBER INTO MESSAGE         16500013
         L     RJ,OASAVEJ         RESTORE RJ                            16600013
         LM    RO,RB,AOGSAVO       RESTORE REGESTERS                    16700013
         DROP  RJ                                                       16800013
AOGNOMES L     RG,PPISPGN1         ADDRESS OF GENERATED CODE            16900013
         SR    RG,RF               DECREMENT ADDRESS OF GENERATED CODE  17000013
         SRL   RG,2                  ROUND DOWN TO                      17100013
         SLL   RG,2                  FULL WORDS                         17200013
         ST    RG,PPISPGN1         RESET NEW ADDRESS OF GENERATED CODE  17300013
         ST    RG,WCTREE           STORE THIS TREE ADDRESS IN NETWORK   17400013
         TM    PPISW1+6,X'01'     TEST DIAGNOSTIC SWITCH                17500013
         BNO   OANOMESS           SWITCH OFF BYPASS MESSAGE             17600013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  17700013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       17800013
         STM   RO,RB,AOGSAVO       SAVE REGESTERS                       17900013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    18000013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           18100013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    18200013
         BAL   RO,4(RP)                                                 18300013
         MVC   DMSG904A(8),0(RB)       MOVE NUMBER INTO MESSAGE         18400013
         LM    RA,RB,DMSG904X     SET UP FOR BRANCH TO PRINT            18500013
         L     RP,PPIADSSC        LOAD ADDRESS OF PRINT ROUTINE         18600013
         BAL   RO,12(0,RP)        BRANCH TO PRINT MESSAGE               18700013
         L     RJ,OASAVEJ         RESTORE RJ                            18800013
         LM    RO,RB,AOGSAVO       RESTORE REGISTERS                    18900013
         DROP  RJ                                                       19000013
         SPACE 1                                                        19100013
* SET BASE REGISTER FOR EQUALS ROUTINE                                  19200013
         SPACE 1                                                        19300013
OANOMESS L     RM,PPIAXERT        SET BASE REGISTER OF EQUALS ROUTINE   19400013
         SPACE 1                                                        19500013
* SET UP ANY ADDITIONAL CONSTANTS REQUIRED TO GENERATE TREE             19600013
         SPACE 1                                                        19700013
         LR    RJ,RG               NEXT LEVEL ADDR FOR PREVIOUS LEVEL   19800013
         LA    RH,2                WAY OR NODE COUNTER                  19900013
         LA    RE,WCLTNODE         ADDRESS OF LAST TEST NODE            20000013
         SR    RF,RF               SET FORMAT OF THIS NODE TO ZERO      20100013
         SPACE 1                                                        20200013
* GENERATE THE REQUIRED TREE                                            20300013
         SPACE 1                                                        20400013
OCSTTREE STM   RE,RF,0(RG)         STORE NLA AND FORMAT OF NODE         20500013
         LA    RK,1(0,RK)          INC RECORD COUNTER BY 1 EACH NODE    20600013
         CR    RK,RI               RECORDS TREE HOLDS NOW TO REQD NO.   20700013
         BNL   OCENOUGH            NO MORE NODES REQUIRED               20800013
         LA    RG,12(0,RG)         INCREMENT TO LOCATION OF NEXT NODE   20900013
         LR    RE,RJ               SET NEXT LEVEL ADDRESS               21000013
         BCT   RH,OCSTTREE         BRANCH IF NODE COUNTER NOT ZERO      21100013
         LA    RH,2                RESET NODE OR WAY COUNTER            21200013
         LA    RJ,12(0,RJ)         INCREMENT NEXT LEVEL ADDRESS         21300013
         B     OCSTTREE                                                 21400013
         SPACE 2                                                        21500013
* SAVE TREE INFORMATION FOR THE NETWORK                                 21600013
         SPACE 1                                                        21700013
OCENOUGH STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               21800013
         SPACE 1                                                        21900013
* IF COLLATING ORDER OF FIRST SEQUENCE IS TO BE DECENDING,REVERSE THE   22000013
* NECESSARY CONDITIONAL BRANCHES IN THE RUNNING ROUTINE.                22100013
         SPACE 1                                                        22200013
         TM    PPISW1+3,X'10'      TEST BIT INDICATING COLLATING ORDER  22300013
         BZ    OCASCEND            BRANCH IF BIT IS OFF-ORDER IS ASCEND 22400013
         XI    OCC24A+1,X'60'      REVERSE CONDITIONAL BRANCH IN NETWOR 22500013
         XI    OCC14A+1,X'60'      REVERSE CONDITIONAL BRANCH IN NETWOR 22600013
         XI    OCSCHECK+1,X'60'    REVERSE CONDITIONAL BRANCH IN SEQCK  22700013
         SPACE 1                                                        22800013
* INITIALIZE THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN     22900013
* THE RUNNING ROUTINE AS NECESSARY.                                     23000013
         SPACE 1                                                        23100013
OCASCEND LH    RE,PPIDD0L1         DISPLACEMENT OF FIRST CONTROL FIELD  23200013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT FOR TREE ADDR 23300013
         STH   RE,WOCDISP            SET UP DISPLACEMENT                23400013
         STH   RE,WOCDISP+2          FIELDS FOR ORING                   23500013
         OC    OCCASE24+2(4),WOCDISP  INITIALIZE DISP IN CLC IN NETWORK 23600013
         OC    OCCASE14+10(4),WOCDISP INITIALIZE DISP IN CLC IN NETWORK 23700013
         OC    OCGOTRUN+26(4),WOCDISP INITIALIZE DISP IN CLC IN SEQCK   23800013
         SPACE 1                                                        23900013
* INITIALIZE THE LENGTH FIELDS IN THE COMPARE INSTRUCTIONS IN           24000013
* THE RUNNING ROUTINE AS NECESSARY.                                     24100013
         SPACE 1                                                        24200013
         IC    RE,PPIDD0L1+3       LENGTH OF 1ST CONTROL FIELD FOR CLC  24300013
         STC   RE,OCCASE24+1       SET LENGTH FIELD IN CLC IN NETWORK   24400013
         STC   RE,OCCASE14+9       SET LENGTH FIELD IN CLC IN NETWORK   24500013
         STC   RE,OCGOTRUN+25      SET LENGTH FIELD IN CLC IN SEQCK     24600013
         SPACE 1                                                        24700013
* EXIT TO NEXT ASSIGNMENT ROUTINE.                                      24800013
         SPACE 1                                                        24900013
         L     RO,WRSAVC9           RESTORE RETURN ADDRESS              25000013
         BR    RO                   RETURN TO LOAD ROUTINE              25100013
         SPACE 2                                                        25200013
         SPACE 1                                                        25300013
*** WORK AREAS ***                                                      25400013
         SPACE 1                                                        25500013
WOCDISP  DS    1F                  USED TO HOLD DISP FIELDS FOR ORING   25600013
WRSAVC9  DS    F                    USED TO SAVE REGISTER RO            25700013
OASAVEJ  DC    F'0'                                                     25800013
AOGSAVO  DC    4F'0'                                                    25900013
         EJECT                                                          26000013
         SPACE 1                                                        26100013
*** IERROG *** POLYPHASE REPLACEMENT NETWORK FOR VARIABLE LENGTH        26200013
*              RECORDS WHICH CONTAIN MULTIPLE CONTROL FIELDS.           26300013
         SPACE 1                                                        26400013
*********************************************************************** 26500013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROG                   26600013
*********************************************************************** 26700013
         SPACE 1                                                        26800013
DICLOSE1 EQU   4                   DISP IN CLOSE BRANCH TABLE           26900013
DIDEBLK1 EQU   8                   DISP IN DEBLK BR TBL (GET TO FILL)   27000013
DIDEBLK2 EQU   0                   DISP IN DEBLK BR TBL (MODIFY + GET)  27100013
DIBLOCK1 EQU   12                  DISP IN BLOCK BR TBL (PUT INFER GET) 27200013
DIBLOCK2 EQU   4                   DISP IN BLOCK BR TBL (PUT EOS)       27300013
DIBLOCK3 EQU   0                   DISP IN BLOCK BR TBL (PUT EOF)       27400013
         SPACE 1                                                        27500013
DIERROG  DSECT                                                          27600013
         SPACE 1                                                        27700013
*** ENTRY TABLE                                                         27800013
         SPACE 1                                                        27900013
IERDOA   B     OCPICK              ENTRY TO FILL TREE                   28000013
         B     OCGOTFIL            ENTRY FROM DEBLK WHILE FILLING (FIT) 28100013
         B     OCEOF               ENTRY FROM DEBLK AT EOF              28200013
         B     OCGOTRUN            ENTRY FROM DEBLK WHILE RUNNING (FIT) 28300013
         B     OCRETEOF            ENTRY FROM DEBLK AFTER EOF           28400013
         B     OCREVERS            ENTRY FROM ALGORITHM TO REVERSE SEQ. 28500013
         B     OCNOGOFI            ENTRY FROM DEBLK WHILE FILLING-NOFIT 28600013
         B     OCNOGORN            ENTRY FROM DEBLK WHILE RUNNING-NOFIT 28700013
         SPACE 2                                                        28800013
* ENTRY FROM ALGORITHM TO INDICATE THE SEQUENCE AFTER THIS              28900013
* IS TO BE REVERSED.                                                    29000013
         SPACE 1                                                        29100013
* REVERSE CONDITIONAL BRANCH WHICH DETERMINES THE RESULT OF             29200013
* COMPARES BETWEEN RECORDS OF THE NEW OR NEXT SEQUENCE.                 29300013
         SPACE 1                                                        29400013
OCREVERS XI    OCC14A+1,X'60'      IN CASE 14                           29500013
         SPACE 1                                                        29600013
* SET A SWITCH ON IN THE END OF SEQUENCE CODE, CASE 6.                  29700013
         SPACE 1                                                        29800013
         LA    RK,255              CONSTANT 'FF'                        29900013
         ST    RK,KCREVSW          SET REVERSAL SWITCH ON IN CASE 6     30000013
         SPACE 1                                                        30100013
* INITIAL ENTRY  TO START FILLING OR ENTRY TO CONTINUE FILLING TREE.    30200013
         SPACE 1                                                        30300013
OCPICK   L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               30400013
         SPACE 1                                                        30500013
* EXIT TO DEBLOCK ROUTINE                                               30600013
         SPACE 1                                                        30700013
         B     DIDEBLK1(0,RL)      GET TO FILL                          30800013
         SPACE 2                                                        30900013
* SETS UP TO FILL THE TREE WITH REAL OR IMAGINARY RECORDS AND           31000013
* DETERMINES WHEN THE TREE IS FILLED.                                   31100013
         SPACE 1                                                        31200013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD FITS)                        31300013
         SPACE 1                                                        31400013
OCGOTFIL LM    RH,RJ,WCSAVE        FILLING REGISTERS                    31500013
         L     RE,OCSAME           UPDATE MODE                          31600013
         S     RD,KCFOUR           DECREMENT NEW ADDR BY FOUR BYTES     31700013
         ST    RJ,0(0,RD)          ADDRESS OF TREE WITH RECORD          31800013
OCSUBFIT LR    RF,RJ               ADDRESS OF TREE (NEXT LEVEL ADDR)    31900013
         BCT   RH,OCGCT            DECREMENT WAY COUNTER                32000013
         LA    RH,2                RESET WAY COUNTER                    32100013
         LA    RJ,12(0,RJ)         INCREMENT TO NEXT NODE               32200013
OCGCT    BCT   RI,OCFILREG         DECREMENT G COUNTER                  32300013
         STM   RH,RJ,WCSAVE                                             32400013
         B     OCNEXT2                                                  32500013
         SPACE 2                                                        32600013
OCFILREG STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               32700013
         B     OCNEXT2                                                  32800013
         SPACE 2                                                        32900013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD DOES NOT FIT)                33000013
         SPACE 1                                                        33100013
OCNOGOFI LM    RH,RJ,WCSAVE        FILLING REGISTERS                    33200013
         L     RE,OCSTEMP          UPDATE MODE                          33300013
         LR    RD,RJ               USE TREE ADDRESS AS WINNER           33400013
         B     OCSUBFIT                                                 33500013
         SPACE 2                                                        33600013
* DETERMINES IF EOF SITUATION IS A NORMAL ONE, FILE SIZE LESS           33700013
* THEN G, OR FILE SIZE IS ZERO AND BRANCHES ACCORDINGLY.                33800013
         SPACE 1                                                        33900013
* ENTRY FROM DEBLOCK AT EOF                                             34000013
         SPACE 1                                                        34100013
OCEOF    CLC   PPISRTG(4),WCSAVE+4 COMPARE G COUNT IN PPIA TO FILL NO.  34200013
         BNE   OCNOZERO                                                 34300013
         L     RP,PPIRCV+4          CLOSE BASE REGISTER                 34400013
         SPACE 1                                                        34500013
* EXIT TO CLOSE ROUTINE                                                 34600013
         SPACE 1                                                        34700013
         LA    RB,4                 SET CODE TO CALL PHASE 3            34800013
         B     20(RP)              INPUT FILE WAS ZERO                  34900013
         SPACE 2                                                        35000013
OCNOZERO MVC   OCC7A(8),OCC7EOF    MODIFY CASE7 TO FORCE TREE FLUSHING  35100013
         LA    RK,0                CONSTANT OF 0                        35200013
         CL    RK,WCSAVE+4         COMPARE TO FILL COUNT                35300013
         BE    OCRETEOF                                                 35400013
         SPACE 1                                                        35500013
* FILE SIZE IS LESS THAN G. THE CODING IS MODIFIED TO FILL THE          35600013
* REMAINDER OF THE TREE WITH IMAGINARY RECORDS (T1).                    35700013
         SPACE 1                                                        35800013
         OI    OCC8A+1,X'F0'       INITIALIZE BRANCH INST IN CASE8      35900013
         MVC   OCPICK(4),OCMODIFY  MODIFY FILLING RETURN LOCATION       36000013
OCMODIFY B     OCNOGOFI                                                 36100013
         SPACE 2                                                        36200013
* MODE POSITIONS AND BRANCH TABLE.                                      36300013
* THROUGH THE COMBINATION OF MODE AND FORMAT AN INDEXED                 36400013
* BRANCH IS PERFORMED WHICH BRANCHES TO THE CASE WHICH                  36500013
* HANDLES THE INDICATED SITUATION.                                      36600013
         SPACE 1                                                        36700013
OCNTEMP  DC    A(OCBTABLE)                                              36800013
OCNEW    DC    A(OCBTABLE+4)                                            36900013
OCSTEMP  DC    A(OCBTABLE+8)                                            37000013
OCSAME   DC    A(OCBTABLE+12)                                           37100013
OCBTABLE DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 37200013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 37300013
         B     OCCASE3                                                  37400013
         B     OCCASE4                                                  37500013
         B     OCCASE5                                                  37600013
         B     OCCASE6                                                  37700013
         B     OCCASE7                                                  37800013
OCMODLOC B     OCCASE8                                                  37900013
         B     OCCASE9                                                  38000013
         B     OCCASE10                                                 38100013
         B     OCNEXT                                                   38200013
         B     OCNEXT                                                   38300013
         B     OCCASE13                                                 38400013
         B     OCCASE14                                                 38500013
         B     OCNEXT                                                   38600013
         B     OCNEXT                                                   38700013
         B     OCCASE17                                                 38800013
         B     OCCASE18                                                 38900013
         B     OCNEXT                                                   39000013
         B     OCNEXT                                                   39100013
         B     OCCASE21                                                 39200013
         B     OCCASE22                                                 39300013
         B     OCCASE23                                                 39400013
         B     OCCASE24                                                 39500013
         SPACE 2                                                        39600013
* THIS CASE HANDLES AN S1/S1 SITUATION.                                 39700013
         SPACE 1                                                        39800013
OCCASE24 CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              39900013
         BNE   OCC24A                                                   40000013
         LR    RC,RH               LOAD ADDRESS FOR EQUALS              40100013
         SPACE 1                                                        40200013
* EXIT TO EQUALS ROUTINE                                                40300013
         SPACE 1                                                        40400013
         BALR  RO,RM               LINK TO EQUALS ROUTINE               40500013
         SPACE 2                                                        40600013
OCC24A   BNH   OCNEXT                                                   40700013
OCEXCH   ST    RD,8(0,RF)          WINNER TO LOSER                      40800013
         LR    RD,RH               LOSER TO WINNER                      40900013
OCNEXT   L     RF,0(0,RF)          ADDRRSS OF NEXT NODE                 41000013
OCNEXT2  LM    RG,RH,4(RF)         LOAD NODE                            41100013
         B     0(RE,RG)            GO TO PROPER CASE                    41200013
         SPACE 2                                                        41300013
* THIS CASE HANDLES A T1/S1 SITUATION.                                  41400013
         SPACE 1                                                        41500013
OCCASE23 L     RE,OCSAME           UPDATE MODE                          41600013
         LA    RK,64               FORMAT T1                            41700013
         ST    RK,4(0,RF)          UPDATE FORMAT                        41800013
         B     OCEXCH                                                   41900013
         SPACE 2                                                        42000013
* THIS CASE HANDLES AN S2/S1 SITUATION.                                 42100013
         SPACE 1                                                        42200013
OCCASE22 L     RE,OCSAME           UPDATE MODE                          42300013
         LA    RK,48               FORMAT S2                            42400013
         ST    RK,4(0,RF)          UPDATE FORMAT                        42500013
         B     OCEXCH                                                   42600013
         SPACE 2                                                        42700013
* THIS CASE HANDLES A T2/S1 SITUATION.                                  42800013
         SPACE 1                                                        42900013
OCCASE21 L     RE,OCSAME           UPDATE MODE                          43000013
         LA    RK,32               FORMAT T2                            43100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        43200013
         B     OCEXCH                                                   43300013
         SPACE 2                                                        43400013
* THIS CASE HANDLES AN S2/T1 SITUATION.                                 43500013
         SPACE 1                                                        43600013
OCCASE18 L     RE,OCSTEMP          UPDATE MODE                          43700013
         LA    RK,48               FORMAT S2                            43800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        43900013
         B     OCEXCH                                                   44000013
         SPACE 2                                                        44100013
* THIS CASE HANDLES A T2/T1 SITUATION.                                  44200013
         SPACE 1                                                        44300013
OCCASE17 L     RE,OCSTEMP          UPDATE MODE                          44400013
         LA    RK,32               FORMAT T2                            44500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        44600013
         B     OCEXCH                                                   44700013
         SPACE 2                                                        44800013
* THIS CASE HANDLES AN S2/S2 SITUATION.                                 44900013
         SPACE 1                                                        45000013
OCCASE14 LA    RK,80               FORMAT S1                            45100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        45200013
         CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              45300013
         BNE   OCC14A                                                   45400013
         LR    RC,RH               LOAD ADDRESS FOR EQUALS              45500013
         SPACE 1                                                        45600013
* EXIT TO EQUALS ROUTINE                                                45700013
         SPACE 1                                                        45800013
         BALR  RO,RM               LINK TO EQUALS ROUTINE               45900013
         SPACE 2                                                        46000013
OCC14A   BNL   OCNEXT                                                   46100013
         B     OCEXCH                                                   46200013
         SPACE 2                                                        46300013
* THIS CASE HANDLES A T2/S2 SITUATION.                                  46400013
         SPACE 1                                                        46500013
OCCASE13 L     RE,OCNEW            UPDATE MODE                          46600013
         SPACE 1                                                        46700013
* THIS CASE HANDLES A T2/T2 SITUATION.                                  46800013
         SPACE 1                                                        46900013
OCCASE9  LA    RK,64               FORMAT T1                            47000013
         ST    RK,4(0,RF)          UPDATE FORMAT                        47100013
         B     OCEXCH                                                   47200013
         SPACE 2                                                        47300013
* THIS CASE HANDLES AN S2/T2 SITUATION.                                 47400013
         SPACE 1                                                        47500013
OCCASE10 LA    RK,64               FORMAT T1                            47600013
         ST    RK,4(0,RF)          UPDATE FORMAT                        47700013
         B     OCNEXT                                                   47800013
         SPACE 2                                                        47900013
* INDICATES THE TREE IS FILLED AND FORCES THE NETWORK                   48000013
* INTO A RUNNING SITUATION.                                             48100013
         SPACE 1                                                        48200013
OCCASE8  ST    RD,WCLTNODE         SAVE ADDR OF RECD IN LAST TEST NODE  48300013
         MVC   OCMODLOC(4),OCMODC8 MODIFY BRANCH TABLE                  48400013
OCC8A    BC    0,OCRETEOF          INITIALIZED TO BRANCH AT FILE L.T. G 48500013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               48600013
         SPACE 1                                                        48700013
* EXIT TO DEBLOCK ROUTINE                                               48800013
         SPACE 1                                                        48900013
         B     DIDEBLK2(0,RL)      MODIFY AND GET                       49000013
         SPACE 2                                                        49100013
* INDICATES THERE IS A RECORD TO BE BLOCKED                             49200013
         SPACE 1                                                        49300013
OCCASE8A L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  49400013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  49500013
         LR    RD,RK               ADDRESS TO WINNER POSITION           49600013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         49700013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 49800013
         SPACE 1                                                        49900013
* EXIT TO BLOCK ROUTINE                                                 50000013
         SPACE 1                                                        50100013
         B     DIBLOCK1(0,RL)      PUT INFERS GET                       50200013
         SPACE 2                                                        50300013
* INDICATES THAT A T1 (IMAGINARY) HAS BEEN FORCED OUT OF THE TREE.      50400013
         SPACE 1                                                        50500013
OCCASE7  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  50600013
         ST    RD,0(0,RK)          NODE ADDR (T1) WITH RECORD HELD BACK 50700013
         LR    RF,RD               NODE ADDRESS AS NEXT LEVEL ADDRESS   50800013
OCC7A    L     RK,OCNTEMP          MODE NTEMP                           50900013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO NTEMP       51000013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               51100013
         SPACE 1                                                        51200013
* EXIT TO DEBLOCK ROUTINE                                               51300013
         SPACE 1                                                        51400013
         B     DIDEBLK1(0,RL)      GET TO FILL (DEBLOCK EXIT MODIFIED)  51500013
         SPACE 2                                                        51600013
* INDICATES THAT IT IS THE END OF A SEQUENCE.                           51700013
         SPACE 1                                                        51800013
OCCASE6  L     RK,OCSTEMP          MODE STEMP                           51900013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       52000013
         L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  52100013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  52200013
         LR    RD,RK               ADDRESS TO WINNER POSITION           52300013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         52400013
         SPACE 1                                                        52500013
* CHECK SEQUENCE REVERSING SWITCH. IF IT IS ON COMPLETE                 52600013
* THE SEQUENCE REVERSING CYCLE.                                         52700013
         SPACE 1                                                        52800013
         CLI   KCREVSW+3,X'00'     CHECK REVERSAL SWITCH                52900013
         BE    OCSWOFF             IF OFF REVERSAL IS NOT IN PROCESS    53000013
         SPACE 1                                                        53100013
* TURN OFF REVERSAL SWITCH. REVERSE THE CONDITIONAL BRANCH WHICH        53200013
* DETERMINES THE RESULTS OF COMPARES BETWEEN RECORDS OF THE PRESENT     53300013
* SEQUENCE. REVERSE THE CONDITIONAL BRANCH WHICH DETERMINES THE         53400013
* RESULTS OF THE SEQUENCE CHECK OF THE INCOMING RECORD.                 53500013
         SPACE 1                                                        53600013
         SR    RK,RK               ZERO A REGISTER                      53700013
         ST    RK,KCREVSW          TURN REVERSAL SWITCH OFF             53800013
         XI    OCC24A+1,X'60'      IN CASE 24                           53900013
         XI    OCSCHECK+1,X'60'    IN SEQUENCE CHECK                    54000013
         SPACE 1                                                        54100013
OCSWOFF  L     RL,PPIBLK+4          BLOCK BASE REGISTER                 54200013
         SPACE 1                                                        54300013
* EXIT TO BLOCK ROUTINE                                                 54400013
         SPACE 1                                                        54500013
         B     DIBLOCK2(0,RL)      PUT EOS                              54600013
         SPACE 2                                                        54700013
* INDICATES THAT IT IS END OF FILE.                                     54800013
         SPACE 1                                                        54900013
OCCASE5  L     RD,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  55000013
         LA    RD,4(0,RD)          INCREMENT ADDRESS BY 4 BYTES         55100013
         L     RL,PPIBLK+4          BLOCK BASE REGOSTER                 55200013
         SPACE 1                                                        55300013
* EXIT TO BLOCK ROUTINE                                                 55400013
         SPACE 1                                                        55500013
         B     DIBLOCK3(0,RL)      PUT EOF                              55600013
         SPACE 2                                                        55700013
* THIS CASE HANDLES AN S1/- SITUATION                                   55800013
         SPACE 1                                                        55900013
OCCASE4  ST    RD,8(0,RF)          WINNER TO LOSER                      56000013
         LA    RK,80               FORMATS1                             56100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        56200013
         B     OCPICK                                                   56300013
         SPACE 2                                                        56400013
* THIS CASE HANDLES A T1/- SITUATION                                    56500013
         SPACE 1                                                        56600013
OCCASE3  ST    RD,8(0,RF)          WINNER TO LOSER                      56700013
         LA    RK,64               FORMAT T1                            56800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        56900013
         B     OCPICK                                                   57000013
         SPACE 2                                                        57100013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD FITS)                        57200013
         SPACE 1                                                        57300013
* SEQUENCE CHECKS THE NEW RECORD AND STARTS IT                          57400013
* THROUGH THE REPLACEMENT NETWORK.                                      57500013
         SPACE 1                                                        57600013
OCGOTRUN S     RD,KCFOUR           DECREMENT NEW ADDR BY FOUR BYTES     57700013
         L     RK,OCSTEMP          MODE STEMP                           57800013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       57900013
         L     RC,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  58000013
         L     RF,0(0,RC)          NODE ADDRESS WITH RECORD HELD BACK   58100013
         ST    RF,0(0,RD)          NODE ADDRESS WITH NEW RECORD         58200013
         CLC   0(1,RD),0(RC)       COMPARE NEW RECORD TO ONE HELD BACK  58300013
         BNE   OCSCHECK                                                 58400013
         SPACE 1                                                        58500013
* EXIT TO EQUALS ROUTINE                                                58600013
         SPACE 1                                                        58700013
         BALR  RO,RM               LINK TO EQUALS ROUTINE               58800013
         SPACE 2                                                        58900013
OCSCHECK BL    OCMODNEW                                                 59000013
         L     RE,OCSAME           UPDATE MODE                          59100013
         B     OCNEXT2                                                  59200013
         SPACE 2                                                        59300013
OCMODNEW L     RE,OCNEW            UPDATE MODE                          59400013
         B     OCNEXT2                                                  59500013
         SPACE 2                                                        59600013
* SET UP TO FLUSH ANOTHER RECORD FROM THE TREE AFTER END OF             59700013
* FILE OR BECAUSE THE INCOMONG RECORD WILL NOT FIT.                     59800013
         SPACE 1                                                        59900013
* ENTRY FROM DEBLOCK AFTER EOF                                          60000013
         SPACE 1                                                        60100013
OCRETEOF L     RE,OCNTEMP          UPDATE MODE                          60200013
         B     OCSUBNO                                                  60300013
         SPACE 2                                                        60400013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD DOES NOT FIT)                60500013
         SPACE 1                                                        60600013
OCNOGORN L     RE,WCSPECL          UPDATE MODE                          60700013
OCSUBNO  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  60800013
         L     RF,0(0,RK)          NODE ADDRESS WITH RECORD HELD BACK   60900013
         LR    RD,RF               TREE ADDRESS AS WINNER               61000013
         B     OCNEXT2                                                  61100013
         SPACE 2                                                        61200013
         SPACE 1                                                        61300013
         SPACE 1                                                        61400013
*** CONSTANTS                                                           61500013
         SPACE 1                                                        61600013
KCFOUR   DC    F'4'                ADDRESS DECREMENT                    61700013
KCREVSW  DC    X'000000FF'         SWITCH USED WHILE REVERSING SEQUENCE 61800013
*                                  THIS SWITCH IS INITIALLY ON.         61900013
         SPACE 1                                                        62000013
*** WORK AREAS *** THE ORDERING OF THESE WORK AREAS MUST BE MAINTAINED  62100013
         SPACE 1                                                        62200013
WCSAVE   DS    3F                  FILLING REGISTER SAVE AREA           62300013
WCTREE   DS    1F                  LOCATION OF TREE                     62400013
WCLTNODE DS    1F                  LAST TEST NODE                       62500013
         DC    A(16)               FORMAT OF LAST TEST NODE             62600013
WCSPECL  DC    A(OCBTABLE+8)       SPECIAL (MODE) INDICATOR             62700013
         SPACE 1                                                        62800013
*** MODIFICATION INSTRUCTIONS *** THE ORDERING OF THESE INSTRUCTIONS    62900013
*                             *** MUST BE MAINTAINED.                   63000013
         SPACE 1                                                        63100013
OCMODC8  B     OCCASE8A            MODIFICATION TO HOLD BACK A RECORD   63200013
OCC7EOF  L     RE,OCNTEMP          UPDATE MODE * MODIFICATION TO CASE7  63300013
         B     OCNEXT2                         * TO FORCE TREE FLUSHING 63400013
DIERAMA  DSECT                                                          63500013
*                                                                       63600013
       COPY  AMAMAIN                                                    63700013
         EJECT                                                          63800013
         SMPPI                                                          63900013
         END                                                            64000013
