         TITLE ' IERAOH - OS/360 SORT/MERGE - 360S-SM-023 04/01/65 '    00100013
*MODULE NAME:*** IERAOH ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT FOR VARIABLE LENGTH      00600013
*    POLYPHASE REPLACEMENT WITH SINGLE CONTROL FIELD. THE FUNCTION OF   00700013
*    THIS MODULE IS TO SET UP APPROPRIATE LENGTH FIELDS, DISPLACEMENT   00800013
*    FIELDS, AND CONSTANTS, DEPENDING ON WHETHER THE EXTRACT ROUTINE    00900013
*    WILL BE USED OR NOT, GENERATE THE REPLACEMENT TREE IN GENERATED    01000013
*    CORE, CHANGE THE CONDITIONS FOR BRANCHING IN RUNNING PROGRAM IF    01100013
*    THE RECORDS ARE TO BE COLLATED IN DESCENDING ORDER IN THE FIRST    01200013
*    SEQUENCE, AND OTHERWISE INITIALIZE THE COMPARE INSTRUCTIONS IN THE 01300013
*    RUNNING PROGRAM.                                                   01400013
         SPACE 2                                                        01500013
*USED AS A DSECT IN'                                                    01600013
*                                                                       01700013
*    N/A                                                                01800013
*                                                                       01900013
*MACROS USED'                                                           02000013
         SPACE 1                                                        02100013
*   SMPPI                                                               02200013
         SPACE 2                                                        02300013
*ENTRY POINTS:                                                          02400013
         SPACE 1                                                        02500013
*        ENTRY IERMOA              ENTRY FROM: LOAD MODULE, IERRC9      02600013
*                                    CALLING SEQUENCE-                  02700013
*                                      LOAD  EP=IERAOH,DCB=             02800013
*                                      LR    RP,RA                      02900013
*                                      BALR  RO,RP                      03000013
         SPACE 2                                                        03100013
*INPUT: PPI FIELDS REFERENCED-                                          03200013
         SPACE 1                                                        03300013
*    PPISRTG   PPILEXFF                                                 03400013
*    PPIAXERT  PPIX61+4                                                 03500013
*    PPIDDOL1  PPIMODEX+1,X'04'                                         03600013
*    PPISPGN1  PPINET+4                                                 03700013
*    PPILEXFD  PPISW1+3,X'50'                                           03800013
         SPACE 2                                                        03900013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             04000013
         SPACE 1                                                        04100013
*    PPISPGN1                                                           04200013
*    REPLACEMENT TREE IS CREATED IN GENERATED CORE.                     04300013
         SPACE 2                                                        04400013
*EXTERNAL ROUTINES:                                                     04500013
         SPACE 1                                                        04600013
*        N/A                                                            04700013
         SPACE 2                                                        04800013
*EXTERNAL PARAMETERS:                                                   04900013
         SPACE 1                                                        05000013
*        N/A                                                            05100013
         SPACE 2                                                        05200013
*EXITS: NORMAL                                                          05300013
         SPACE 1                                                        05400013
*        BR    RO - RETURN TO LOAD ROUTINE, IERRC9                      05500013
         SPACE 2                                                        05600013
*EXITS: ERROR                                                           05700013
         SPACE 1                                                        05800013
*        N/A                                                            05900013
         SPACE 2                                                        06000013
*TABLES/WORK AREAS:                                                     06100013
         SPACE 1                                                        06200013
*      WOCDISP - FULL WORD USED TO HOLD DISPLACEMENT FIELD FOR ORING    06300013
*    THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN THE RUNNING 06400013
*    PROGRAM IN ORDER TO INITIALIZE THEM AS NECESSARY.                  06500013
*      WOCLGTH, A FULL WORD, IS USED TO HOLD LENGTH FIELD FOR COMPARE   06600013
*    INSTRUCTIONS.                                                      06700013
*      WRSAVC9, A FULL WORD, IS USED TO HOLD THE ADDRESS OF THE CALLING 06800013
*    ROUTINE, THE LOAD MODULE IERRC9.                                   06900013
         SPACE 2                                                        07000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07100013
         SPACE 2                                                        07200013
*NOTES:                                                                 07300013
         SPACE 1                                                        07400013
*   THIS MODULE IS USED WITH VARIABLE LENGTH RECORDS WITH A SINGLE      07500013
*    CONTROL FIELD FOR A POLYPHASE SORT.                                07600013
         SPACE 2                                                        07700013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07800013
         SPACE 1                                                        07900013
RA       EQU   0                   CONTENTS IN- N/A                     08000013
*                                  USE- NOT USED                        08100013
*                                  CONTENTS OUT- N/A                    08200013
RB       EQU   1                   CONTENTS IN- N/A                     08300013
*                                  USE- NOT USED                        08400013
*                                  CONTENTS OUT- N/A                    08500013
RC       EQU   2                   CONTENTS IN- N/A                     08600013
*                                  USE- WORK REGISTER                   08700013
*                                  CONTENTS OUT- N/A                    08800013
RD       EQU   3                   CONTENTS IN- N/A                     08900013
*                                  USE- WORK REGISTER                   09000013
*                                  CONTENTS OUT- N/A                    09100013
RE       EQU   4                   CONTENTS IN- N/A                     09200013
*                                  USE- WORK REGISTER, NEXT LEVEL       09300013
*                                       ADDRESS                         09400013
*                                  CONTENTS OUT- N/A                    09500013
RF       EQU   5                   CONTENTS IN- N/A                     09600013
*                                  USE- WORK REGISTER, FORMAT           09700013
*                                  CONTENTS OUT- N/A                    09800013
RG       EQU   6                   CONTENTS IN- N/A                     09900013
*                                  USE- WORK REGISTER                   10000013
*                                  CONTENTS OUT- N/A                    10100013
RH       EQU   7                   CONTENTS IN- N/A                     10200013
*                                  USE- MODE OR WAY COUNTER             10300013
*                                  CONTENTS OUT- N/A                    10400013
RI       EQU   8                   CONTENTS IN- N/A                     10500013
*                                  USE- G COUNT                         10600013
*                                  CONTENTS OUT- N/A                    10700013
RJ       EQU   9                   CONTENTS IN- N/A                     10800013
*                                  USE- WORK REGISTER                   10900013
*                                  CONTENTS OUT- N/A                    11000013
RK       EQU   10                  CONTENTS IN- N/A                     11100013
*                                  USE- RECORD COUNTER                  11200013
*                                  CONTENTS OUT- N/A                    11300013
RL       EQU   11                  CONTENTS IN- N/A                     11400013
*                                  USE- PROGRAM BASE REGISTER           11500013
*                                  CONTENTS OUT- N/A                    11600013
RM       EQU   12                  CONTENTS IN- N/A                     11700013
*                                  USE- EXTRACT BASE REGISTER           11800013
*                                  CONTENTS OUT- N/A                    11900013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          12000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     12100013
*                                    AREA                               12200013
*                                  CONTENTS OUT- ADDRESS OF PPI         12300013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      12400013
*                                                IERRC9                 12500013
*                                  USE- BASE REGISTER FOR DSECT OF      12600013
*                                       IERROH                          12700013
*                                  CONTENTS OUT - RETURN ADDRESS IN     12800013
*                                                 IERRC9                12900013
RP       EQU   15                  CONTENTS IN- ADDRESS OF IERMOA       13000013
*                                  USE- NOT USED                        13100013
*                                  CONTENTS OUT- N/A                    13200013
         SPACE 2                                                        13300013
*START OF MODULE CODE PROPER:                                           13400013
         SPACE 2                                                        13500013
         SPACE 1                                                        13600013
IERAOH   CSECT                                                          13700013
         USING *,RL                                                     13800013
         USING IERRCA,RN                                                13900013
         USING DIERROH,RO                                               14000013
IERMOA   LR    RL,RP               SET PROGRAM BASE REGISTER            14100013
         ST    RO,WRSAVC9                                               14200013
         L     RO,PPINET+4          SET DSECT REGISTER OF RUNNING MOD   14300013
         SPACE 1                                                        14400013
* DETERMINE IF EXTRACTING AND SET SWITCH IN NETWORK ACCORDINGLY.        14500013
         SPACE 1                                                        14600013
         TM    PPISW1+3,X'40'      TEST BIT INDICATING EXTRACT OR NOT   14700013
         BZ    OCNOEXT             BRANCH IF BIT IS OFF. NOT EXTRACTING 14800013
         LA    RG,255              CONSTANT X'FF'                       14900013
         STH   RG,KCSWITCH+2       SET EXT SWITCH ON IN RUNNING MODULE  15000013
         SPACE 1                                                        15100013
* SET BASE REGISTER FOR EXTRACT ROUTINE.                                15200013
         SPACE 1                                                        15300013
         L     RM,PPIAXERT         SET BASE REGISTER OF EXTRACT ROUTINE 15400013
         SPACE 1                                                        15500013
* DETERMINE IF MODIFICATION EXIT 61 IS ACTIVE AND STORE ITS             15600013
* ADDRESS IN EXTRACT ROUTINE IF NECESSARY.                              15700013
         SPACE 1                                                        15800013
         TM    PPIMODEX+1,X'04'    TEST BIT INDICATING EXIT E61 ACTIVE  15900013
         BZ    OCNOUSER            BRANCH IF BIT IS OFF. NO EXIT        16000013
         L     RG,PPIX61+4          ADDRESS OF USER MODIFICATION        16100013
         ST    RG,0(0,RM)          ADDR OF USER MODIFICATION IN EXTRACT 16200013
         SPACE 1                                                        16300013
* SET UP LENGTH FIELDS,DISPLACEMENT FIELD,AND CONSTANTS                 16400013
* AS REQUIRED IF EXTRACTING.                                            16500013
         SPACE 1                                                        16600013
OCNOUSER LH    RG,PPILEXFF         LGTH OF EXTRACTED FIELD ROUNDED FULL 16700013
         LA    RG,4(0,RG)          INCREMENT BY 4 FOR TREE ADDRESS      16800013
         ST    RG,KCINCDEC         STORE IN NETWORK AS INC OR DEC       16900013
         LA    RG,4                CONSTANT OF 4 FOR DISPLACEMENT       17000013
         STH   RG,WOCDISP            SET UP DISPLACEMENT                17100013
         STH   RG,WOCDISP+2          FIELDS FOR ORING                   17200013
         LH    RG,PPILEXFD         LGTH OF EXTRACTED FIELD FOR COMPARES 17300013
         ST    RG,WOCLGTH          LENGTH FIELD FOR COMPARE INSTS.      17400013
         B     OCGOGO                                                   17500013
         SPACE 2                                                        17600013
* SET UP LENGTH FIELDS.DISPLACEMENT FIELDS. AND CONSTANTS               17700013
* AS REQUIRED IF NOT EXTRACTING.                                        17800013
         SPACE 1                                                        17900013
OCNOEXT  LH    RE,PPIDD0L1         DISPLACEMENT OF FIRST CONTROL FIELD  18000013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT FOR TREE ADDR 18100013
         STH   RE,WOCDISP            SET UP DISPLACEMENT                18200013
         STH   RE,WOCDISP+2          FIELDS FOR ORING                   18300013
         LA    RE,4                CONSTANT OF 4                        18400013
         ST    RE,KCINCDEC         STORE LN NETWORK AS INC OR DEC       18500013
         SR    RE,RE               ZERO REGISTER                        18600013
         IC    RE,PPIDD0L1+3       LENGTH OF 1ST CONTROL FIELD FOR CLC  18700013
         ST    RE,WOCLGTH          LENGTH FIELD FOR COMPARE INSTS.      18800013
         SPACE 1                                                        18900013
* DETERMINE SIZE OF AREA FOR GENERATING THE TREE,RESET THE ADDRESS OF   19000013
* THE GENERATED AREA BY THIS AMOUNT,AND SAVE THIS ADDRESS FOR THE       19100013
* NETWORK AS THE TREE ADDRESS AND FOR THE NEXT ROUTINE AS THE           19200013
* ADDRESS OF THE GENERATED AREA.                                        19300013
         SPACE 1                                                        19400013
OCGOGO   L     RI,PPISRTG          G OR NUMBER OF RECORDS FOR TREE      19500013
         LA    RK,1                RECORD COUNTER-RECORDS TREE CAN HOLD 19600013
         LA    RC,12               BYTES PER NODE                       19700013
         LR    RF,RI               G OR NUMBER OF RECORDS FOR TREE      19800013
         SR    RF,RK               FORM G-1                             19900013
         SR    RE,RE               ZERO REGISTER                        20000013
         MR    RE,RC               CALCULATE NUMBER OF BYTES IN TREE    20100013
         LA    RJ,36               SIZE OF MINIMUM TREE                 20200013
         CR    RF,RJ               IS CALCULATED SIZE EQ OR G. MINIMUM  20300013
         BNL   OCOKSIZE            BRANCH IF IT IS                      20400013
         LR    RF,RJ               SET TREE SIZE TO MINIMUM             20500013
OCOKSIZE TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               20600013
         BNO   AOHNOMES            SWITCH OFF BYPASS MESSAGE            20700013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  20800013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       20900013
         STM   RO,RB,AOHSAVO       SAVE REGISTERS                       21000013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    21100013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           21200013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    21300013
         BAL   RO,4(RP)                                                 21400013
         MVC   DMSG904B(8),0(RB)       MOVE NUMBER INTO MESSAGE         21500013
         L     RJ,OASAVEJ         RESTORE RJ                            21600013
         LM    RO,RB,AOHSAVO       RESTORE REGESTERS                    21700013
         DROP  RJ                                                       21800013
AOHNOMES L     RG,PPISPGN1         ADDRESS OF GENERATED CODE            21900013
         SR    RG,RF               DECREMENT ADDRESS OF GENERATED CODE  22000013
         SRL   RG,2                  ROUND DOWN TO                      22100013
         SLL   RG,2                  FULL WORDS                         22200013
         ST    RG,PPISPGN1         RESET NEW ADDRESS OF GENERATED CODE  22300013
         ST    RG,WCTREE           STORE THIS TREE ADDRESS IN NETWORK   22400013
         TM    PPISW1+6,X'01'     TEST DIAGNOSTIC SWITCH                22500013
         BNO   OANOMESS           SWITCH OFF BYPASS MESSAGE             22600013
         USING DIERAMA,RJ         SET UP BASE REGISTER FOR MESSAGE MOD  22700013
         STM   RO,RB,AOHSAVO       SAVE REGESTERS                       22800013
         ST    RJ,OASAVEJ         SAVE REGISTER J                       22900013
         L     RJ,PPIAMA+4         SET MSG BASE REG.                    23000013
         L     RA,PPISPGN1        LOAD NUMBER TO BE CONVERTED           23100013
         L     RP,PPICONV+4       LOAD ADDRESS OF CONVERSION ROUTINE    23200013
         BAL   RO,4(RP)                                                 23300013
         MVC   DMSG904A(8),0(RB)       MOVE NUMBER INTO MESSAGE         23400013
         LM    RA,RB,DMSG904X     SET UP FOR BRANCH TO PRINT            23500013
         L     RP,PPIADSSC        LOAD ADDRESS OF PRINT ROUTINE         23600013
         BAL   RO,12(0,RP)        BRANCH TO PRINT MESSAGE               23700013
         L     RJ,OASAVEJ         RESTORE RJ                            23800013
         LM    RO,RB,AOHSAVO       RESTORE REGISTERS                    23900013
         DROP  RJ                                                       24000013
         SPACE 1                                                        24100013
* SET UP ANY ADDITIONAL CONSTANTS REQUIRED TO GENERATE TREE             24200013
         SPACE 1                                                        24300013
OANOMESS LR    RJ,RG              NEXT LEVEL ADDR FOR PREVIOUS LEVEL    24400013
         LA    RH,2                WAY OR NODE COUNTER                  24500013
         LA    RE,WCLTNODE         ADDRESS OF LAST TEST NODE            24600013
         SR    RF,RF               SET FORMAT OF THIS NODE TO ZERO      24700013
         SPACE 1                                                        24800013
* GENERATE THE REQUIRED TREE                                            24900013
         SPACE 1                                                        25000013
OCSTTREE STM   RE,RF,0(RG)         STORE NLA AND FORMAT OF NODE         25100013
         LA    RK,1(0,RK)          INC RECORD COUNTER BY 1 EACH NODE    25200013
         CR    RK,RI               RECORDS TREE HOLDS NOW TO REQD NO.   25300013
         BNL   OCENOUGH            NO MORE NODES REQUIRED               25400013
         LA    RG,12(0,RG)         INCREMENT TO LOCATION OF NEXT NODE   25500013
         LR    RE,RJ               SET NEXT LEVEL ADDRESS               25600013
         BCT   RH,OCSTTREE         BRANCH IF NODE COUNTER NOT ZERO      25700013
         LA    RH,2                RESET NODE OR WAY COUNTER            25800013
         LA    RJ,12(0,RJ)         INCREMENT NEXT LEVEL ADDRESS         25900013
         B     OCSTTREE                                                 26000013
         SPACE 2                                                        26100013
* SAVE TREE INFORMATION FOR THE NETWORK                                 26200013
         SPACE 1                                                        26300013
OCENOUGH STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               26400013
         SPACE 1                                                        26500013
* IF COLLATING ORDER OF FIRST SEQUENCE IS TO BE DECENDING,REVERSE THE   26600013
* NECESSARY CONDITIONAL BRANCHES IN THE RUNNING ROUTINE.                26700013
         SPACE 1                                                        26800013
         TM    PPISW1+3,X'10'      TEST BIT INDICATING COLLATING ORDER  26900013
         BZ    OCASCEND            BRANCH IF BIT IS OFF-ORDER IS ASCEND 27000013
         XI    OCCASE24+7,X'60'    REVERSE CONDITIONAL BRANCH IN NETWOR 27100013
         XI    OCC14A+1,X'60'      REVERSE CONDITIONAL BRANCH IN NETWOR 27200013
         XI    OCNOTON2+27,X'60'   REVERSE CONDITIONAL BRANCH IN SEQCK  27300013
         SPACE 1                                                        27400013
* INITIALIZE THE DISPLACEMENT FIELDS IN THE COMPARE INSTRUCTIONS IN     27500013
* THE RUNNING ROUTINE AS NECESSARY.                                     27600013
         SPACE 1                                                        27700013
OCASCEND OC    OCCASE24+2(4),WOCDISP  INITIALIZE DISP IN CLC IN NETWORK 27800013
         OC    OCCASE14+10(4),WOCDISP INITIALIZE DISP IN CLC IN NETWORK 27900013
         OC    OCNOTON2+22(4),WOCDISP INITIALIZE DISP IN CLC IN SEQCK   28000013
         SPACE 1                                                        28100013
* INITIALIZE THE LENGTH FIELD SIN THE COMPARE INSTRUCTIONS IN           28200013
* THE RUNNING ROUTINE AS NECESSARY.                                     28300013
         SPACE 1                                                        28400013
         L     RE,WOCLGTH          LENGTH OF 1ST CONTROL FIELD FOR CLC  28500013
         STC   RE,OCCASE24+1       SET LENGTH FIELD IN CLC IN NETWORK   28600013
         STC   RE,OCCASE14+9       SET LENGTH FIELD IN CLC IN NETWORK   28700013
         STC   RE,OCNOTON2+21      SET LENGTH FIELD IN CLC IN SEQCK     28800013
         SPACE 1                                                        28900013
* EXIT TO NEXT ASSIGNMENT ROUTINE.                                      29000013
         SPACE 1                                                        29100013
         L     RO,WRSAVC9           RESTORE RETURN ADDRESS              29200013
         BR    RO                   RETURN TO LOAD ROUTINE              29300013
         SPACE 2                                                        29400013
         SPACE 1                                                        29500013
*** WORK AREAS ***                                                      29600013
         SPACE 1                                                        29700013
WOCDISP  DS    1F                  USED TO HOLD DISP FIELDS FOR ORING   29800013
WOCLGTH  DS    1F                  USED TO HOLD LENGTH FIELD FOR INIT.  29900013
WRSAVC9  DS    F                    USED TO SAVE REGISTER RO            30000013
OASAVEJ  DC    F'0'                                                     30100013
AOHSAVO  DC    4F'0'                                                    30200013
         EJECT                                                          30300013
         SPACE 1                                                        30400013
*** IERROH *** POLYPHASE REPLACEMENT NETWORK FOR VARIABLE LENGTH        30500013
*              RECORDS WHICH CONTAIN SINGLE CONTROL FIELDS AND/OR       30600013
*              REQUIRE EXTRACTING.                                      30700013
         SPACE 1                                                        30800013
*********************************************************************** 30900013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROH                   31000013
*********************************************************************** 31100013
         SPACE 1                                                        31200013
DICLOSE1 EQU   4                   DISP IN CLOSE BRANCH TABLE           31300013
DIDEBLK1 EQU   8                   DISP IN DEBLK BR TBL (GET TO FILL)   31400013
DIDEBLK2 EQU   0                   DISP IN DEBLK BR TBL (MODIFY + GET)  31500013
DIBLOCK1 EQU   12                  DISP IN BLOCK BR TBL (PUT INFER GET) 31600013
DIBLOCK2 EQU   4                   DISP IN BLOCK BR TBL (PUT EOS)       31700013
DIBLOCK3 EQU   0                   DISP IN BLOCK BR TBL (PUT EOF)       31800013
         SPACE 1                                                        31900013
DIERROH  DSECT                                                          32000013
         SPACE 1                                                        32100013
*** ENTRY TABLE                                                         32200013
         SPACE 1                                                        32300013
IERDOA   B     OCPICK              ENTRY TO FILL TREE                   32400013
         B     OCGOTFIL            ENTRY FROM DEBLK WHILE FILLING (FIT) 32500013
         B     OCEOF               ENTRY FROM DEBLK AT EOF              32600013
         B     OCGOTRUN            ENTRY FROM DEBLK WHILE RUNNING (FIT) 32700013
         B     OCRETEOF            ENTRY FROM DEBLK AFTER EOF           32800013
         B     OCREVERS            ENTRY FROM ALGORITHM TO REVERSE SEQ. 32900013
         B     OCNOGOFI            ENTRY FROM DEBLK WHILE FILLING-NOFIT 33000013
         B     OCNOGORN            ENTRY FROM DEBLK WHILE RUNNING-NOFIT 33100013
         SPACE 2                                                        33200013
* ENTRY FROM ALGORITHM TO INDICATE THE SEQUENCE AFTER THIS              33300013
* IS TO BE REVERSED.                                                    33400013
         SPACE 1                                                        33500013
* REVERSE CONDITIONAL BRANCH WHICH DETERMINES THE RESULT OF             33600013
* COMPARES BETWEEN RECORDS OF THE NEW OR NEXT SEQUENCE.                 33700013
         SPACE 1                                                        33800013
OCREVERS XI    OCC14A+1,X'60'      IN CASE 14                           33900013
         SPACE 1                                                        34000013
* SET A SWITCH ON IN THE END OF SEQUENCE CODE, CASE 6.                  34100013
         SPACE 1                                                        34200013
         LA    RK,255              CONSTANT 'FF'                        34300013
         ST    RK,KCREVSW          SET REVERSAL SWITCH ON IN CASE 6     34400013
         SPACE 1                                                        34500013
* INITIAL ENTRY  TO START FILLING OR ENTRY TO CONTINUE FILLING TREE.    34600013
         SPACE 1                                                        34700013
OCPICK   L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               34800013
         SPACE 1                                                        34900013
* EXIT TO DEBLOCK ROUTINE                                               35000013
         SPACE 1                                                        35100013
         B     DIDEBLK1(0,RL)      GET TO FILL                          35200013
         SPACE 2                                                        35300013
* SETS UP TO FILL THE TREE WITH REAL OR IMAGINARY RECORDS AND           35400013
* DETERMINES WHEN THE TREE IS FILLED.                                   35500013
         SPACE 1                                                        35600013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD FITS)                        35700013
         SPACE 1                                                        35800013
OCGOTFIL S     RD,KCINCDEC         DECREMENT NEW ADDR BY EXTRACT INC +4 35900013
         CLI   KCSWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 36000013
         BNE   OCNOTON1            BRANCH IF OFF                        36100013
         SPACE 1                                                        36200013
* EXIT TO EXTRACT ROUTINE                                               36300013
         SPACE 1                                                        36400013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              36500013
         SPACE 2                                                        36600013
OCNOTON1 LM    RH,RJ,WCSAVE        FILLING REGISTERS                    36700013
         L     RE,OCSAME           UPDATE MODE                          36800013
         ST    RJ,0(0,RD)          ADDRESS OF TREE WITH RECORD          36900013
OCSUBFIT LR    RF,RJ               ADDRESS OF TREE (NEXT LEVEL ADDR)    37000013
         BCT   RH,OCGCT            DECREMENT WAY COUNTER                37100013
         LA    RH,2                RESET WAY COUNTER                    37200013
         LA    RJ,12(0,RJ)         INCREMENT TO NEXT NODE               37300013
OCGCT    BCT   RI,OCFILREG         DECREMENT G COUNTER                  37400013
         STM   RH,RJ,WCSAVE                                             37500013
         B     OCNEXT2                                                  37600013
         SPACE 2                                                        37700013
OCFILREG STM   RH,RJ,WCSAVE        SAVE FILLING REGISTERS               37800013
         B     OCNEXT2                                                  37900013
         SPACE 2                                                        38000013
* ENTRY FROM DEBLOCK WHILE FILLING (RECORD DOES NOT FIT)                38100013
         SPACE 1                                                        38200013
OCNOGOFI LM    RH,RJ,WCSAVE        FILLING REGISTERS                    38300013
         L     RE,OCSTEMP          UPDATE MODE                          38400013
         LR    RD,RJ               USE TREE ADDRESS AS WINNER           38500013
         B     OCSUBFIT                                                 38600013
         SPACE 2                                                        38700013
* DETERMINES IF EOF SITUATION IS A NORMAL ONE, FILE SIZE LESS           38800013
* THEN G, OR FILE SIZE IS ZERO AND BRANCHES ACCORDINGLY.                38900013
         SPACE 1                                                        39000013
* ENTRY FROM DEBLOCK AT EOF                                             39100013
         SPACE 1                                                        39200013
OCEOF    CLC   PPISRTG(4),WCSAVE+4 COMPARE G COUNT IN PPIA TO FILL NO.  39300013
         BNE   OCNOZERO                                                 39400013
         L     RP,PPIRCV+4          CLOSE BASE REGISTER                 39500013
         SPACE 1                                                        39600013
* EXIT TO CLOSE ROUTINE                                                 39700013
         SPACE 1                                                        39800013
         LA    RB,4                 SET CODE TO CALL PHASE 3            39900013
         B     20(RP)              INPUT FILE WAS ZERO                  40000013
         SPACE 2                                                        40100013
OCNOZERO MVC   OCC7A(8),OCC7EOF    MODIFY CASE7 TO FORCE TREE FLUSHING  40200013
         LA    RK,0                CONSTANT OF 0                        40300013
         CL    RK,WCSAVE+4         COMPARE TO FILL COUNT                40400013
         BE    OCRETEOF                                                 40500013
         SPACE 1                                                        40600013
* FILE SIZE IS LESS THAN G. THE CODING IS MODIFIED TO FILL THE          40700013
* REMAINDER OF THE TREE WITH IMAGINARY RECORDS (T1).                    40800013
         SPACE 1                                                        40900013
         OI    OCC8A+1,X'F0'       INITIALIZE BRANCH INST IN CASE8      41000013
         MVC   OCPICK(4),OCMODIFY  MODIFY FILLING RETURN LOCATION       41100013
OCMODIFY B     OCNOGOFI                                                 41200013
         SPACE 2                                                        41300013
* MODE POSITIONS AND BRANCH TABLE.                                      41400013
* THROUGH THE COMBINATION OF MODE AND FORMAT AN INDEXED                 41500013
* BRANCH IS PERFORMED WHICH BRANCHES TO THE CASE WHICH                  41600013
* HANDLES THE INDICATED SITUATION.                                      41700013
         SPACE 1                                                        41800013
OCNTEMP  DC    A(OCBTABLE)                                              41900013
OCNEW    DC    A(OCBTABLE+4)                                            42000013
OCSTEMP  DC    A(OCBTABLE+8)                                            42100013
OCSAME   DC    A(OCBTABLE+12)                                           42200013
OCBTABLE DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 42300013
         DC    A(0)                SPACE TO MAINTAIN POSITIONS IN TABLE 42400013
         B     OCCASE3                                                  42500013
         B     OCCASE4                                                  42600013
         B     OCCASE5                                                  42700013
         B     OCCASE6                                                  42800013
         B     OCCASE7                                                  42900013
OCMODLOC B     OCCASE8                                                  43000013
         B     OCCASE9                                                  43100013
         B     OCCASE10                                                 43200013
         B     OCNEXT                                                   43300013
         B     OCNEXT                                                   43400013
         B     OCCASE13                                                 43500013
         B     OCCASE14                                                 43600013
         B     OCNEXT                                                   43700013
         B     OCNEXT                                                   43800013
         B     OCCASE17                                                 43900013
         B     OCCASE18                                                 44000013
         B     OCNEXT                                                   44100013
         B     OCNEXT                                                   44200013
         B     OCCASE21                                                 44300013
         B     OCCASE22                                                 44400013
         B     OCCASE23                                                 44500013
         B     OCCASE24                                                 44600013
         SPACE 2                                                        44700013
* THIS CASE HANDLES AN S1/S1 SITUATION.                                 44800013
         SPACE 1                                                        44900013
OCCASE24 CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              45000013
         BNH   OCNEXT                                                   45100013
OCEXCH   ST    RD,8(0,RF)          WINNER TO LOSER                      45200013
         LR    RD,RH               LOSER TO WINNER                      45300013
OCNEXT   L     RF,0(0,RF)          ADDRRSS OF NEXT NODE                 45400013
OCNEXT2  LM    RG,RH,4(RF)         LOAD NODE                            45500013
         B     0(RE,RG)            GO TO PROPER CASE                    45600013
         SPACE 2                                                        45700013
* THIS CASE HANDLES A T1/S1 SITUATION.                                  45800013
         SPACE 1                                                        45900013
OCCASE23 L     RE,OCSAME           UPDATE MODE                          46000013
         LA    RK,64               FORMAT T1                            46100013
         ST    RK,4(0,RF)          UPDATE FORMAT                        46200013
         B     OCEXCH                                                   46300013
         SPACE 2                                                        46400013
* THIS CASE HANDLES AN S2/S1 SITUATION.                                 46500013
         SPACE 1                                                        46600013
OCCASE22 L     RE,OCSAME           UPDATE MODE                          46700013
         LA    RK,48               FORMAT S2                            46800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        46900013
         B     OCEXCH                                                   47000013
         SPACE 2                                                        47100013
* THIS CASE HANDLES A T2/S1 SITUATION.                                  47200013
         SPACE 1                                                        47300013
OCCASE21 L     RE,OCSAME           UPDATE MODE                          47400013
         LA    RK,32               FORMAT T2                            47500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        47600013
         B     OCEXCH                                                   47700013
         SPACE 2                                                        47800013
* THIS CASE HANDLES AN S2/T1 SITUATION.                                 47900013
         SPACE 1                                                        48000013
OCCASE18 L     RE,OCSTEMP          UPDATE MODE                          48100013
         LA    RK,48               FORMAT S2                            48200013
         ST    RK,4(0,RF)          UPDATE FORMAT                        48300013
         B     OCEXCH                                                   48400013
         SPACE 2                                                        48500013
* THIS CASE HANDLES A T2/T1 SITUATION.                                  48600013
         SPACE 1                                                        48700013
OCCASE17 L     RE,OCSTEMP          UPDATE MODE                          48800013
         LA    RK,32               FORMAT T2                            48900013
         ST    RK,4(0,RF)          UPDATE FORMAT                        49000013
         B     OCEXCH                                                   49100013
         SPACE 2                                                        49200013
* THIS CASE HANDLES AN S2/S2 SITUATION.                                 49300013
         SPACE 1                                                        49400013
OCCASE14 LA    RK,80               FORMAT S1                            49500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        49600013
         CLC   0(1,RD),0(RH)       COMPARE WINNER TO LOSER              49700013
OCC14A   BNL   OCNEXT                                                   49800013
         B     OCEXCH                                                   49900013
         SPACE 2                                                        50000013
* THIS CASE HANDLES A T2/S2 SITUATION.                                  50100013
         SPACE 1                                                        50200013
OCCASE13 L     RE,OCNEW            UPDATE MODE                          50300013
         SPACE 1                                                        50400013
* THIS CASE HANDLES A T2/T2 SITUATION.                                  50500013
         SPACE 1                                                        50600013
OCCASE9  LA    RK,64               FORMAT T1                            50700013
         ST    RK,4(0,RF)          UPDATE FORMAT                        50800013
         B     OCEXCH                                                   50900013
         SPACE 2                                                        51000013
* THIS CASE HANDLES AN S2/T2 SITUATION.                                 51100013
         SPACE 1                                                        51200013
OCCASE10 LA    RK,64               FORMAT T1                            51300013
         ST    RK,4(0,RF)          UPDATE FORMAT                        51400013
         B     OCNEXT                                                   51500013
         SPACE 2                                                        51600013
* INDICATES THE TREE IS FILLED AND FORCES THE NETWORK                   51700013
* INTO A RUNNING SITUATION.                                             51800013
         SPACE 1                                                        51900013
OCCASE8  ST    RD,WCLTNODE         SAVE ADDR OF RECD IN LAST TEST NODE  52000013
         MVC   OCMODLOC(4),OCMODC8 MODIFY BRANCH TABLE                  52100013
OCC8A    BC    0,OCRETEOF          INITIALIZED TO BRANCH AT FILE L.T. G 52200013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               52300013
         SPACE 1                                                        52400013
* EXIT TO DEBLOCK ROUTINE                                               52500013
         SPACE 1                                                        52600013
         B     DIDEBLK2(0,RL)      MODIFY AND GET                       52700013
         SPACE 2                                                        52800013
* INDICATES THERE IS A RECORD TO BE BLOCKED                             52900013
         SPACE 1                                                        53000013
OCCASE8A L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  53100013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  53200013
         LR    RD,RK               ADDRESS TO WINNER POSITION           53300013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     53400013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 53500013
         SPACE 1                                                        53600013
* EXIT TO BLOCK ROUTINE                                                 53700013
         SPACE 1                                                        53800013
         B     DIBLOCK1(0,RL)      PUT INFERS GET                       53900013
         SPACE 2                                                        54000013
* INDICATES THAT A T1 (IMAGINARY) HAS BEEN FORCED OUT OF THE TREE.      54100013
         SPACE 1                                                        54200013
OCCASE7  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  54300013
         ST    RD,0(0,RK)          NODE ADDR (T1) WITH RECORD HELD BACK 54400013
         LR    RF,RD               NODE ADDRESS AS NEXT LEVEL ADDRESS   54500013
OCC7A    L     RK,OCNTEMP          MODE NTEMP                           54600013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO NTEMP       54700013
         L     RL,PPIDEB+4          DEBLOCK BASE REGISTER               54800013
         SPACE 1                                                        54900013
* EXIT TO DEBLOCK ROUTINE                                               55000013
         SPACE 1                                                        55100013
         B     DIDEBLK1(0,RL)      GET TO FILL (DEBLOCK EXIT MODIFIED)  55200013
         SPACE 2                                                        55300013
* INDICATES THAT IT IS THE END OF A SEQUENCE.                           55400013
         SPACE 1                                                        55500013
OCCASE6  L     RK,OCSTEMP          MODE STEMP                           55600013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       55700013
         L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  55800013
         ST    RD,WCLTNODE         ADDR OF NEXT RECD TO LAST TEST NODE  55900013
         LR    RD,RK               ADDRESS TO WINNER POSITION           56000013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     56100013
         SPACE 1                                                        56200013
* CHECK SEQUENCE REVERSING SWITCH. IF IT IS ON COMPLETE                 56300013
* THE SEQUENCE REVERSING CYCLE.                                         56400013
         SPACE 1                                                        56500013
         CLI   KCREVSW+3,X'00'     CHECK REVERSAL SWITCH                56600013
         BE    OCSWOFF             IF OFF REVERSAL IS NOT IN PROCESS    56700013
         SPACE 1                                                        56800013
* TURN OFF REVERSAL SWITCH. REVERSE THE CONDITIONAL BRANCH WHICH        56900013
* DETERMINES THE RESULTS OF COMPARES BETWEEN RECORDS OF THE PRESENT     57000013
* SEQUENCE. REVERSE THE CONDITIONAL BRANCH WHICH DETERMINES THE         57100013
* RESULTS OF THE SEQUENCE CHECK OF THE INCOMING RECORD.                 57200013
         SPACE 1                                                        57300013
         SR    RK,RK               ZERO A REGISTER                      57400013
         ST    RK,KCREVSW          TURN REVERSAL SWITCH OFF             57500013
         XI    OCCASE24+7,X'60'    IN CASE 24                           57600013
         XI    OCNOTON2+27,X'60'   IN SEQUENCE CHECK                    57700013
         SPACE 1                                                        57800013
OCSWOFF  L     RL,PPIBLK+4          BLOCK BASE REGISTER                 57900013
         SPACE 1                                                        58000013
* EXIT TO BLOCK ROUTINE                                                 58100013
         SPACE 1                                                        58200013
         B     DIBLOCK2(0,RL)      PUT EOS                              58300013
         SPACE 2                                                        58400013
* INDICATES THAT IT IS END OF FILE.                                     58500013
         SPACE 1                                                        58600013
OCCASE5  L     RD,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  58700013
         A     RD,KCINCDEC         INC ADDR BY EXTRACT INCREMENT +4     58800013
         L     RL,PPIBLK+4          BLOCK BASE REGISTER                 58900013
         SPACE 1                                                        59000013
* EXIT TO BLOCK ROUTINE                                                 59100013
         SPACE 1                                                        59200013
         B     DIBLOCK3(0,RL)      PUT EOF                              59300013
         SPACE 2                                                        59400013
* THIS CASE HANDLES AN S1/- SITUATION                                   59500013
         SPACE 1                                                        59600013
OCCASE4  ST    RD,8(0,RF)          WINNER TO LOSER                      59700013
         LA    RK,80               FORMATS1                             59800013
         ST    RK,4(0,RF)          UPDATE FORMAT                        59900013
         B     OCPICK                                                   60000013
         SPACE 2                                                        60100013
* THIS CASE HANDLES A T1/- SITUATION                                    60200013
         SPACE 1                                                        60300013
OCCASE3  ST    RD,8(0,RF)          WINNER TO LOSER                      60400013
         LA    RK,64               FORMAT T1                            60500013
         ST    RK,4(0,RF)          UPDATE FORMAT                        60600013
         B     OCPICK                                                   60700013
         SPACE 2                                                        60800013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD FITS)                        60900013
         SPACE 1                                                        61000013
* SEQUENCE CHECKS THE NEW RECORD AND STARTS IT                          61100013
* THROUGH THE REPLACEMENT NETWORK.                                      61200013
         SPACE 1                                                        61300013
OCGOTRUN S     RD,KCINCDEC         DECREMENT NEW ADDR BY EXTRACT INC +4 61400013
         CLI   KCSWITCH+3,X'FF'    CHECK EXTRACT SWITCH                 61500013
         BNE   OCNOTON2            BRANCH IF OFF                        61600013
         SPACE 1                                                        61700013
* EXIT TO EXTRACT ROUTINE                                               61800013
         SPACE 1                                                        61900013
         BAL   RO,4(0,RM)          LINK TO EXTRACT ROUTINE              62000013
         SPACE 2                                                        62100013
OCNOTON2 L     RK,OCSTEMP          MODE STEMP                           62200013
         ST    RK,WCSPECL          SET SPECIAL INDICATOR TO STEMP       62300013
         L     RC,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  62400013
         L     RF,0(0,RC)          NODE ADDRESS WITH RECORD HELD BACK   62500013
         ST    RF,0(0,RD)          NODE ADDRESS WITH NEW RECORD         62600013
         CLC   0(1,RD),0(RC)       COMPARE NEW RECORD TO ONE HELD BACK  62700013
         BL    OCMODNEW                                                 62800013
         L     RE,OCSAME           UPDATE MODE                          62900013
         B     OCNEXT2                                                  63000013
         SPACE 2                                                        63100013
OCMODNEW L     RE,OCNEW            UPDATE MODE                          63200013
         B     OCNEXT2                                                  63300013
         SPACE 2                                                        63400013
* SET UP TO FLUSH ANOTHER RECORD FROM THE TREE AFTER END OF             63500013
* FILE OR BECAUSE THE INCOMONG RECORD WILL NOT FIT.                     63600013
         SPACE 1                                                        63700013
* ENTRY FROM DEBLOCK AFTER EOF                                          63800013
         SPACE 1                                                        63900013
OCRETEOF L     RE,OCNTEMP          UPDATE MODE                          64000013
         B     OCSUBNO                                                  64100013
         SPACE 2                                                        64200013
* ENTRY FROM DEBLOCK WHILE RUNNING (RECORD DOES NOT FIT)                64300013
         SPACE 1                                                        64400013
OCNOGORN L     RE,WCSPECL          UPDATE MODE                          64500013
OCSUBNO  L     RK,WCLTNODE         ADDRESS OF RECORD IN LAST TEST NODE  64600013
         L     RF,0(0,RK)          NODE ADDRESS WITH RECORD HELD BACK   64700013
         LR    RD,RF               TREE ADDRESS AS WINNER               64800013
         B     OCNEXT2                                                  64900013
         SPACE 2                                                        65000013
         SPACE 1                                                        65100013
         SPACE 1                                                        65200013
*** CONSTANTS                                                           65300013
         SPACE 1                                                        65400013
KCSWITCH DC    X'00000000'         EXTRACT SWITCH                       65500013
KCINCDEC DS    1F                  ADDRESS INC OR DEC OF EXTRACT INC +4 65600013
KCREVSW  DC    X'000000FF'         SWITCH USED WHILE REVERSING SEQUENCE 65700013
*                                  THIS SWITCH IS INITIALLY ON.         65800013
         SPACE 1                                                        65900013
*** WORK AREAS *** THE ORDERING OF THESE WORK AREAS MUST BE MAINTAINED  66000013
         SPACE 1                                                        66100013
WCSAVE   DS    3F                  FILLING REGISTER SAVE AREA           66200013
WCTREE   DS    1F                  LOCATION OF TREE                     66300013
WCLTNODE DS    1F                  LAST TEST NODE                       66400013
         DC    A(16)               FORMAT OF LAST TEST NODE             66500013
WCSPECL  DC    A(OCBTABLE+8)       SPECIAL (MODE) INDICATOR             66600013
         SPACE 1                                                        66700013
*** MODIFICATION INSTRUCTIONS *** THE ORDERING OF THESE INSTRUCTIONS    66800013
*                             *** MUST BE MAINTAINED.                   66900013
         SPACE 1                                                        67000013
OCMODC8  B     OCCASE8A            MODIFICATION TO HOLD BACK A RECORD   67100013
OCC7EOF  L     RE,OCNTEMP          UPDATE MODE * MODIFICATION TO CASE7  67200013
         B     OCNEXT2                         * TO FORCE TREE FLUSHING 67300013
DIERAMA  DSECT                                                          67400013
*                                                                       67500013
       COPY  AMAMAIN                                                    67600013
         EJECT                                                          67700013
         SMPPI                                                          67800013
         END                                                            67900013
