         TITLE ' IERAOJ - OS/360 SORT/MERGE - 360S-SM-023 04/01/65 '    00200013
*MODULE NAME:*** IERAOJ ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT FOR THE POLYPHASE        01200013
*    SORT ALGORITHM. THE FUNCTION OF THIS MODULE IS TO SET UP           01400013
*    PARAMETER IN AND OTHERWISE INITIALIZE PPI AND THE RUNNING          01600013
*    PROGRAM.                                                           01800013
         SPACE 2                                                        02000013
*USED AS A DSECT IN'                                                    02200013
*                                                                       02400013
*    N/A                                                                02600013
*                                                                       02800013
*MACROS USED'                                                           03000013
         SPACE 1                                                        03200013
*    SMPPI                                                              03400013
         SPACE 2                                                        03600013
*ENTRY POINT:                                                           03800013
         SPACE 1                                                        04000013
*        ENTRY IERMOI              ENTRY FROM: LOAD MODULE, IERRC9      04200013
*                                    CALLING SEQUENCE-                  04400013
*                                      LOAD  EP=IERAOJ,DCB=             04600013
*                                      LR    RP,RA                      04800013
*                                      BALR  RO,RP                      05000013
         SPACE 2                                                        05200013
*INPUT: PPI FIELDS REFERENCED-                                          05400013
         SPACE 1                                                        05600013
*    PPITPTBL                                                           05800013
*    PPIMRGMX                                                           06000013
         SPACE 2                                                        06200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             06400013
         SPACE 1                                                        06600013
*    PPIDEPHO+3                                                         06800013
*    PPITPTBL                                                           07000013
*    PPIMRGMX                                                           07200013
*    PPIMRGAL                                                           07400013
*    PPIBDSVA                                                           07600013
         SPACE 2                                                        07800013
*EXTERNAL ROUTINES:                                                     08000013
         SPACE 1                                                        08200013
*        N/A                                                            08400013
         SPACE 2                                                        08600013
*EXTERNAL PARAMETERS:                                                   08800013
         SPACE 1                                                        09000013
*        N/A                                                            09200013
         SPACE 2                                                        09400013
*EXITS: NORMAL                                                          09600013
         SPACE 1                                                        09800013
*        BR    RO - RETURN TO LOAD ROUTINE, IERRC9                      10000013
         SPACE 2                                                        10200013
*EXITS: ERROR                                                           10400013
         SPACE 1                                                        10600013
*        N/A                                                            10800013
         SPACE 2                                                        11000013
*TABLES/WORK AREAS:                                                     11200013
         SPACE 1                                                        11400013
*        NONE                                                           11600013
         SPACE 2                                                        11800013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12000013
         SPACE 2                                                        12200013
*NOTES:                                                                 12400013
         SPACE 1                                                        12600013
*        NONE                                                           12800013
         SPACE 2                                                        13000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13200013
         SPACE 1                                                        13400013
RA       EQU   0                   CONTENTS IN- N/A                     13600013
*                                  USE- NONE                            13800013
*                                  CONTENTS OUT- N/A                    14000013
RB       EQU   1                   CONTENTS IN- N/A                     14200013
*                                  USE- NONE                            14400013
*                                  CONTENTS OUT- N/A                    14600013
RC       EQU   2                   CONTENTS IN- N/A                     14800013
*                                  USE- NONE                            15000013
*                                  CONTENTS OUT- N/A                    15200013
RD       EQU   3                   CONTENTS IN- N/A                     15400013
*                                  USE- NONE                            15600013
*                                  CONTENTS OUT- N/A                    15800013
RE       EQU   4                   CONTENTS IN- N/A                     16000013
*                                  USE- WORK REGISTER                   16200013
*                                  CONTENTS OUT- N/A                    16400013
RF       EQU   5                   CONTENTS IN- N/A                     16600013
*                                  USE- WORK REGISTER                   16800013
*                                  CONTENTS OUT- N/A                    17000013
RG       EQU   6                   CONTENTS IN- N/A                     17200013
*                                  USE- WORK REGISTER                   17400013
*                                  CONTENTS OUT- N/A                    17600013
RH       EQU   7                   CONTENTS IN- N/A                     17800013
*                                  USE- WORK REGISTER                   18000013
*                                  CONTENTS OUT- N/A                    18200013
RI       EQU   8                   CONTENTS IN- N/A                     18400013
*                                  USE- WORK REGISTER                   18600013
*                                  CONTENTS OUT- N/A                    18800013
RJ       EQU   9                   CONTENTS IN- NA/                     19000013
*                                  USE- BASE REG FOR DSECT OF IERROJ    19200013
*                                  CONTENTS OUT- N/A                    19400013
RK       EQU   10                  CONTENTS IN- N/A                     19600013
*                                  USE- BASE REG FOR DSECT OF IERRMA    19800013
*                                  CONTENTS OUT- N/A                    20000013
RL       EQU   11                  CONTENTS IN- N/A                     20200013
*                                  USE- PROGRAM BASE REGISTER           20400013
*                                  CONTENTS OUT- N/A                    20600013
RM       EQU   12                  CONTENTS IN- N/A                     20800013
*                                  USE- NONE                            21000013
*                                  CONTENTS OUT- N/A                    21200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          21400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     21600013
*                                    AREA                               21800013
*                                  CONTENTS OUT- ADDRESS OF PPI         22000013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      22200013
*                                                IERRC9                 22400013
*                                  USE- NONE                            22600013
*                                  CONTENTS OUT - RETURN ADDRESS IN     22800013
*                                                 IERRC9                23000013
RP       EQU   15                  CONTENTS IN- ADDRESS OF ENTRY IERMOI 23200013
*                                  USE- NONE                            23400013
*                                  CONTENTS OUT- N/A                    23600013
         SPACE 2                                                        23800013
*START OF MODULE CODE PROPER:                                           24000013
         SPACE 2                                                        24200013
         SPACE 1                                                        24400013
IERAOJ   CSECT                                                          24600013
*                                                                A27992 24700000
         USING *,RL                                                     24800013
         USING IERRCA,RN                                                25000013
         USING DIERROJ,RJ                                               25200013
         USING DIERRMA,RK                                               25400013
IERMOI   LR    RL,RP               SET PROGRAM BASE REGISTER            25600013
         L     RJ,PPIALG+4          SET DSECT REGISTER OF RUNNING MOD   25800013
         L     RK,PPIRMA+4         SET DSECT REGISTER OF MESSAGE MOD    26000013
         SPACE 1                                                        26200013
* SET THE MAXIMUM MERGE ORDER, THE TOTAL NO. OF WORK UNITS,             26400013
* AND ALTERNATE MERGE ORDER TO (ONE).                                   26600013
         SPACE 1                                                        26800013
         LH    RE,PPIMRGMX        MERGE ORDER = M                       27000013
         LR    RF,RE                                                    27200013
         LA    RE,1(RE)           INCRE BY 1 FOR NO. WORK UNITS         27400013
         STC   RE,PPIBDSVA         STORE FOR BLOCK/DEBLOCK              27600013
         LA    RH,1                CONSTANT OF 1                        27800013
         STH   RH,PPIMRGAL         SET ALTERNATE MERGE ORDER TO (ONE)   28000013
         SPACE 1                                                        28200013
* SET OPEN BIT ON IN FIRST (M) UNITS IN TAPE TABLE.                     28400013
         SPACE 1                                                        28600013
         LR    RG,RF               COUNTER OF (N-1) EQUALS (M)          28800013
         LA    RI,PPITPTBL         ADDRESS OF TAPE TABLE                29000013
OJSETON  OI    0(RI),X'40'         SET OPEN BIT ON IN FIRST UNIT ETC.   29200013
         LA    RI,2(0,RI)          INCREMENT ADDRESS TO NEXT UNIT       29400013
         BCT   RG,OJSETON          BRANCH IF MORE OPEN BITS TO BE SET   29600013
         SPACE 1                                                        29800013
* SET TOTAL NUMBER OF SEQUENCES TO DISTRIBUTED TO (M) IN RUNNING ROUTIN 30000013
         SPACE 1                                                        30200013
         ST    RF,WOJTOTAL         NUMBER OF SEQUENCES TO DISTRIBUTE    30400013
         SPACE 1                                                        30600013
* SET THE UPDATED AND ORIGINAL FIBONACCI COUNT TO (ONE) IN THE          30800013
* RUNNING PROGRAM FOR THE FIRST M COUNTERS.                             31000013
         SPACE 1                                                        31200013
         LR    RG,RF               COUNTER OF (N-1) EQUALS (M)          31400013
         LA    RI,PPITPTBL         ADDRESS OF TAPE TABLE                31600013
OJSETFIB STH   RH,68(0,RI)         SET FIRST FUTURE FIB TO (ONE) ETC.   31800013
         STH   RH,102(0,RI)        SET FIRST ORIGINAL FIB TO (ONE) ETC. 32000013
         LA    RI,2(0,RI)          INCREMENT ADDRESS TO NEXT COUNTER    32200013
         BCT   RG,OJSETFIB         BRANCH IF MORE FIBS TO BE SET        32400013
         SPACE 1                                                        32600013
* SET A COUNT OF (N),(N-1),(N-2) IN THE RUNNING ROUTINE.                32800013
         SPACE 1                                                        33000013
         LR    RG,RF               COUNT OF (N-1)                       33200013
         SR    RG,RH               CALCULATE (N-2)                      33400013
         STH   RE,WOJCTN           COUNT OF (N) IN RUNNING ROUTINE      33600013
         STH   RF,WOJCTN1          COUNT OF (N-1) IN RUNNING ROUTINE    33800013
         STH   RG,WOJCTN2          COUNT OF (N-2) IN RUNNING ROUTINE    34000013
         SPACE 1                                                        34200013
* SET AN ALL ODD COUNT OF (N) AND A PERMUTE COUNT OF (N-1) IN ALGORITHM 34400013
         SPACE 1                                                        34600013
         STH   RE,WOJALODD         ALL ODD COUNT (N) IN ALGORITHM       34800013
         STH   RF,WOJPERM          PERMUTE COUNT (N-1) IN ALGORITHM     35000013
         SPACE 1                                                        35200013
* CALCULATE INCREMENT TO LAST UNIT IN TAPE TABLE AND STORE AS A POINTER 35400013
* AND AN INCREMENT  IN THE RUNNING ROUTINE.                             35600013
         SPACE 1                                                        35800013
         SLL   RG,1                MULTIPLY (N-2) BY 2                  36000013
         STH   RG,WOJPOINT         STORE AS A POINTER IN ALGORITHM      36200013
         STH   RG,WOJINCPT         STORE AS AN INCREMENT IN ALGORITHM   36400013
         SPACE 1                                                        36600013
* SET THE OUTPUT UNIT INDICATION IN PPIA FOR WRITE ROUTINE              36800013
         SPACE 1                                                        37000013
         IC    RE,PPITPTBL+1(RG)   OUTPUT UNIT DESIGNATOR               37200013
         STC   RE,PPIDEPHO+3       SET OUTPUT UNIT DESIGNATOR FOR WRITE 37400013
         SPACE 1                                                        37600013
* EXIT TO NEXT ASSIGNMENT ROUTINE                                       37800013
         SPACE 1                                                        38000013
         BR    RO                   RETURN TO LOAD ROUTINE              38200013
         EJECT                                                          38400013
*** IERROJ *** POLYPHASE SORT ALGORITHM                                 38600013
         SPACE 1                                                        38800013
*********************************************************************** 39000013
* THIS MODULE IS A DSECT OF THE RUNNING MODULE IERROJ                   39200013
*********************************************************************** 39400013
         SPACE 1                                                        39600013
DIERROJ  DSECT                                                          39800013
         SPACE 1                                                        40000013
*** ENTRY TABLE                                                         40200013
         SPACE 1                                                        40400013
IERDOK   B     OJEOF               ENTRY FROM WRITE ROUTINE AT EOF      40600013
         B     OJEOV               ENTRY FROM WRITE ROUTINE AT EOV      40800013
*                                  **EOS HAS NOT BEEN REACHED AND       41000013
*                                  **MORE WRITES ARE PENDING.           41200013
         B     OJEOV               ENTRY FROM WRITE ROUTINE AT EOV.     41400013
*                                  **EOS HAS BEEN REACHED BUT ALL       41600013
*                                  ** THE INPUT HAS NOT BEEN PROCESSED. 41800013
         SPACE 2                                                        42000013
*  ENTRY FROM WRITE ROUTINE AT END OF SEQUENCE                          42200013
         SPACE 1                                                        42400013
* INCREMENT COUNT OF SEQUENCES ON THIS UNIT                             42600013
         SPACE 1                                                        42800013
         LH    RE,WOJPOINT         TAPE TABLE POINTER(INC WITHIN TABLE) 43000013
         LH    RF,PPITPTBL+34(RE)  SEQUENCE COUNTER FOR THIS UNIT       43200013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY ONE             43400013
         STH   RF,PPITPTBL+34(RE)  RESTORE SEQUENCE COUNTER             43600013
         SPACE 1                                                        43800013
* DETERMINE IF ENOUGH SEQUENCES HAVE BEEN DISTRIBUTED TO SATISFY        44000013
* THE PRESENT SET OF FIBONACCI NUMBERS.                                 44200013
         SPACE 1                                                        44400013
         L     RF,WOJTOTAL         COUNT SEQUENCES TO DISTRIBUTE        44600013
         BCT   RF,OJNOUPDT         BRANCH IF FIBS DO NOT NEED UPDATING  44800013
         SPACE 1                                                        45000013
* CALCULATE NUMBER OF SEQUENCES TO BE DISTRIBUTED AFTER THIS UPDATE     45200013
* OF THE FIBONACCI NUMBERS.                                             45400013
         SPACE 1                                                        45600013
         LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     45800013
         LH    RH,PPITPTBL+102(RH) LAST OF ORIGINAL OLD FIBONACCI NOS.  46000013
         LH    RI,WOJCTN2          COUNT OF (N-2)                       46200013
         MR    RG,RI               MULTIPLY TO DETERMINE NEW SEQ. COUNT 46400013
         ST    RH,WOJTOTAL         RESET NEW COUNT OF SEQ TO DISTRIBUTE 46600013
         SPACE 1                                                        46800013
* UPDATE TO NEXT HIGHER SET OF FIBONACCI NUMBERS                        47000013
         SPACE 1                                                        47200013
OJUPDFIB LH    RF,WOJCTN2          COUNT OF (N-2)                       47400013
         LH    RE,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     47600013
         LA    RE,PPITPTBL+102(RE) ADDR OF LAST OF OLD FIB. NUMBERS     47800013
         LR    RG,RE               ADDR OF LAST OF OLD FIB. NUMBERS     48000013
         LH    RH,0(0,RE)          LAST OF OLD FIBONACCI NUMBERS        48200013
         LR    RJ,RH               LAST OF OLD FIBONACCI NUMBERS        48400013
         LA    RI,2                CONSTANT OF 2                        48600013
OJNEXFIB SR    RE,RI               DECREMENT ADDR TO PRECEEDING FIB.NO. 48800013
         AH    RH,0(0,RE)          LAST OLD FIB.PLUS NEXT TO LAST, ETC. 49000013
         STH   RH,0(0,RG)          TOATAL INTO LAST FIBS POSITION ETC.  49200013
         LR    RH,RJ               LAST OF OLD FIBONACCI NUMBERS        49400013
         SR    RG,RI               DECREMENT ADDR TO PRECEEDING FIB.NO. 49600013
         BCT   RF,OJNEXFIB         BRANCH IF ALL FIBS NOT UPDATED       49800013
         STH   RH,0(0,RE)          ORIGINAL OLD LAST FIB AS NEW 1ST FIB 50000013
         SPACE 1                                                        50200013
* DETERMINE IF THE UPDATED FIBONACCI NUMBERS ARE ALL ODD. IF THEY ARE   50400013
* ALL ODD, ANOTHER UPDATE MUST BE PERFORMED NOW.                        50600013
         SPACE 1                                                        50800013
         LH    RE,WOJALODD         ALL ODD COUNTER (EVERY N UPDATES THE 51000013
*                                  **FIBONACCI NUMBERS ARE ALL ODD)     51200013
         BCT   RE,OJNOTODD         BRANCH IF NOT ALL ODD                51400013
         MVC   WOJALODD(2),WOJCTN  RESET ALL ODD COUNTER TO N           51600013
         SPACE 1                                                        51800013
* CALCULATE NUMBER OF ADDITIONAL SEQUENCES TO BE DISTRIBUTED AFTER      52000013
* THIS UPDATE AND ADD THEM TO PREVIOUS COUNT.                           52200013
         SPACE 1                                                        52400013
         LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     52600013
         LH    RH,PPITPTBL+102(RH) LAST OF ORIGINAL OLD FIBONACCI NOS.  52800013
         LH    RI,WOJCTN2          COUNT OF (N-2)                       53000013
         MR    RG,RI               MULTIPLY TO DETERMINE NEW SEQ. COUNT 53200013
         A     RH,WOJTOTAL         OLD COUNT OF SEQUENCES TO DISTRIBUTE 53400013
         ST    RH,WOJTOTAL         RESET NEW COUNT OF SEQ.TO DISTRIBUTE 53600013
         B     OJUPDFIB            BRANCH TO UPDATE FIBONACCI NUMBERS   53800013
         SPACE 2                                                        54000013
OJNOTODD STH   RE,WOJALODD         SAVE ALL ODD COUNTER                 54200013
         SPACE 1                                                        54400013
* MOVE THE UPDATED FIBONACCI NUMBERS TO THE FUTURE NUMBERS POSITION     54600013
* OF TABLE AND PERMUTE THEM AS NECESSARY FOR THIS UPDATE.               54800013
         SPACE 1                                                        55000013
         MVC   PPITPTBL+68(32),PPITPTBL+102 UPDATED FIBS TO FUTURE FIBS 55200013
         LH    RE,WOJPERM          COUNT OF TIMES TO PERMUTE THIS SET   55400013
         BCT   RE,OJPERMUT         BRANCH IF FUTURE FIBS NEED PERMUTING 55600013
         MVC   WOJPERM(2),WOJCTN1  RESET PERMUTING COUNTER TO (N-1)     55800013
         B     OJRESET             BRANCH TO RESET TAPE TABLE POINTER   56000013
         SPACE 2                                                        56200013
OJPERMUT STH   RE,WOJPERM          SAVE PERMUTING COUNTER               56400013
         MVC   OJMOVER+1(1),WOJINCPT+1 SET LENGTH FIELD IN MOVE INST.   56600013
*                                     *TO MOVE (N-1) FIB.NUMBERS.       56800013
OJPERONE LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     57000013
         LH    RF,PPITPTBL+68(RH)  LAST OF FUTURE FIBONACCI NUMBERS     57200013
         MVC   PPIWKARE+1(32),PPITPTBL+68 SAVE THE UNPERMUTED FUTURE    57400013
*                                        *FIBS.THIS IS DONE TO AVOID    57600013
*                                        *MOVING OVERLAPPING FIELDS.    57800013
OJMOVER  MVC   PPITPTBL+69(1),PPIWKARE MOVE 1ST (N-1) FUTURE FIBS BACK  58000013
*                                     *TO TABLE,SHIFTED BY 1 POSITION   58200013
         STH   RF,PPITPTBL+68      LAST OF FUTURE FIB AS 1ST FUTURE FIB 58400013
         BCT   RE,OJPERONE         BRANCH TO PERMUTE ONE MORE POSITION  58600013
         B     OJRESET                                                  58800013
         SPACE 2                                                        59000013
* SAVE COUNT OF SEQUENCES TO DISTRIBUTE.                                59200013
         SPACE 1                                                        59400013
OJNOUPDT ST    RF,WOJTOTAL         SAVE COUNT OF SEQS. TO DISTRIBUTE    59600013
         SPACE 1                                                        59800013
* DETERMINE NEXT UNIT TO GET A SEQUENCE                                 60000013
         SPACE 1                                                        60200013
OJBACK1  LTR   RE,RE               TEST TAPE TABLE POINTER FOR ZERO     60400013
         BZ    OJRESET             BRANCH IF ZERO                       60600013
         LA    RF,2                CONSTANT OF 2                        60800013
         SR    RE,RF               DEC TAPE TABLE POINTER 1 POSITION    61000013
         B     OJSTPT                                                   61200013
         SPACE 2                                                        61400013
OJRESET  LH    RE,WOJINCPT         RESET TAPE TABLE POINTER TO LAST POS 61600013
OJSTPT   STH   RE,WOJPOINT         SAVE TAPE TABLE POINTER              61800013
         LH    RF,PPITPTBL+34(RE)  COUNT OF SEQUENCES ON THIS TAPE      62000013
         LH    RG,PPITPTBL+68(RE)  FUTURE COUNT OF SEQUENCES FOR TAPE   62200013
         CLR   RF,RG               COMPARE THE COUNTS                   62400013
         BE    OJBACK1             DEC POSITION IN TAPE TABLE IF EQUAL  62600013
         SPACE 1                                                        62800013
* DETERMINE THE MUNBER OF UNITS THAT STILL REQUIRE SEQUENCES            63000013
* THIS PASS OF THE TAPE TABLE.                                          63200013
         SPACE 1                                                        63400013
         SR    RF,RF               ZERO A REGISTER                      63600013
         LA    RG,2(0,RE)          SAVE TP TBL POINTER+2 AS INC         63800013
OJDEC1   LA    RH,2                CONSTANT OF 2                        64000013
         SR    RG,RH               DECREMENT TAPE TABLE POINTER ONE POS 64200013
         LH    RI,PPITPTBL+34(RG)  COUNT OF SEQUENCES ON THIS TAPE      64400013
         LH    RJ,PPITPTBL+68(RG)  FUTURE COUNT OF SEQS FOR THIS TAPE   64600013
         CLR   RI,RJ               COMPARE THE COUNTS                   64800013
         BE    OJCKLAST            IF EQUAL DO NOT INC COUNTER          65000013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY 1               65200013
OJCKLAST LTR   RG,RG               TEST TAPE TABLE POINTER FOR ZERO     65400013
         BNE   OJDEC1              IF NOT ZERO CONTINUE  CHECKING       65600013
         SPACE 1                                                        65800013
* SET OUTPUT UNIT INDICATOR IN PPIA                                     66000013
         SPACE 1                                                        66200013
         IC    RG,PPITPTBL+1(RE)   OUTPUT UNIT DESIGNATOR               66400013
         STC   RG,PPIDEPHO+3       SET OUTPUT UNIT DESIGNATOR FOR WRITE 66600013
         SPACE 1                                                        66800013
* CHECK COUNT OF TAPES THAT STILL REQUIRE SEQUENCES THIS PASS           67000013
* OF TAPE TABLE AND PROCEED ACCORDINGLY.                                67200013
         SPACE 1                                                        67400013
         BCT   RF,OJDEBLCK         CHECK COUNTER                        67600013
         L     RL,PPINET+4          REPLACEMENT NETWORKS BASE REGISTER  67800013
         SPACE 1                                                        68000013
* EXIT TO REPLACEMENT NETWORK TO REVERSE THE SEQUENCE AFTER THIS        68200013
         SPACE 1                                                        68400013
         B     20(0,RL)            REVERSE THE NEXT SEQUENCE            68600013
         SPACE 2                                                        68800013
OJDEBLCK L     RL,PPIDEB+4         DEBLOCK BASE REGISTER                69000013
         SPACE 1                                                        69200013
* EXIT TO DEBLOCK ROUTINE (NO REVERSAL OF SEQUENCES NECESSARY)          69400013
         SPACE 1                                                        69600013
         B     8(0,RL)             DEBLOCK A RECORD                     69800013
         SPACE 2                                                        70000013
* ENTRY FROM WRITE ROUTINE AT EOV                                       70200013
         SPACE 1                                                        70400013
OJEOV    L     RK,PPIRMA+4          SET DSECT REGISTER OF MESSAGE MOD   70600013
         LM    RA,RB,MSGP1A02      ADDRESS AND LENGTH OF MESSAGE        70800013
*                                  ' SORT CAPACITY EXCEEDED '           71000013
         SPACE 1                                                        71200013
* EXIT TO SSC TO PRINT ERROR MESSAGE.                                   71400013
         SPACE 1                                                        71600013
         L     RP,PPIADSSC         SSC BASE REGISTER                    71800013
         BAL   RO,12(0,RP)         EXIT TO SSC TO PRINT ERROR MESSAGE   72000013
         SPACE 2                                                        72200013
         SPACE 1                                                        72400013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   72600013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        72800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   73000013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      73200013
         SPACE 1                                                        73400013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             73600013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 73660000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 73720000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      73800013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             74000013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                74200013
         BO    ROI031                                                   74400013
         SPACE 1                                                        74600013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      74800013
         SR    RO,RO                                                    75000013
         DR    RO,RA                 RCDS. IN BLOCK                     75200013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         75400013
         BH    ROI032                NEGATIVE                           75600013
         SPACE 1                                                        75800013
         AR    RB,RP               ADD B TO CNT                         76000013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           76200013
         BNL   ROI033                                                   76400013
         SPACE 1                                                        76600013
         LR    RB,RP               SET CNT TO B                         76800013
         B     ROI033                                                   77000013
         SPACE 2                                                        77200013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      77400013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           77600013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       77800013
         OI    PPIWKARE+15,X'F0'                                        78000013
         SPACE 2                                                        78200013
         L     RO,PPIRMA+4                                              78400013
         LM    RA,RB,MSGP1A06                                           78600013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                78800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        79000013
         BAL   RO,12(0,RP)                                              79200013
         SPACE 1                                                        79400013
* EXIT TO SSC  TO ABORT JOB, PHYSICAL N(MAX) EXCEEDED                   79600013
         SPACE 1                                                        79800013
         L     RP,PPIADSSC         SSC BASE REGISTER                    80000013
         B     16(0,RP)            EXIT TO SSC TO ABORT THE SORT        80200013
         SPACE 2                                                        80400013
* ENTRY FROM WRITE ROUTINE AT EOF                                       80600013
         SPACE 1                                                        80800013
* INCREMENT COUNT OF SEQUENCES ON THIS UNIT                             81000013
         SPACE 1                                                        81200013
OJEOF    LH    RE,WOJPOINT         TAPE TABLE POINTER(INC WITHIN TABLE) 81400013
         LH    RF,PPITPTBL+34(RE)  SEQUENCE COUNTER FOR THIS UNIT       81600013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY ONE             81800013
         STH   RF,PPITPTBL+34(RE)  RESTORE SEQUENCE COUNTER             82000013
         SPACE 1                                                        82200013
* SET OPEN BIT ON IN LAST UNIT IN TAPE TABLE.                           82400013
         SPACE 1                                                        82600013
         LH    RE,WOJINCPT         INCREMENT TO LAST POSITIONS IN TABLE 82800013
         LA    RF,PPITPTBL+2(RE)   ADDR OF BYTE IN TAPE TABLE FOR BIT   83000013
         OI    0(RF),X'40'         SET OPEN BIT ON                      83200013
         SPACE 1                                                        83400013
* TURN OFF OPEN BITS IN FIRST (N-1) UNITS IN TAPE TABLE                 83600013
* THAT DID NOT RECEIVE SEQUENCES.                                       83800013
         SPACE 1                                                        84000013
         LH    RF,WOJCTN1          COUNT OF (N-1)                       84200013
         LA    RG,PPITPTBL         ADDRESS OF TAPE TABLE                84400013
OJMOROFF SR    RH,RH               ZERO THE REGISTER                    84600013
         SH    RH,34(0,RG)         FIRST SEQUENCE COUNTER               84800013
         BNE   OJLEAVON            IF NOT ZERO LEAVE OPEN BIT ON        85000013
         NI    0(RG),X'BF'         TURN OPEN BIT OFF                    85200013
OJLEAVON LA    RG,2(0,RG)          INCREMENT TO NEXT TABLE POSITION     85400013
         BCT   RF,OJMOROFF         BRANCH IF MORE COUNTERS TO CHECK     85600013
         SPACE 1                                                        85800013
* SET UP COUNTERS FOR DUMMY SEQUENCES AS NECESSARY FOR PHASE 2          86000013
* IF FIBONACCI LEVEL IS ALL ONES GO TO NEXT LEVEL BEFORE SETTING DUMMYS 86200013
         SPACE 1                                                        86400013
         LA    RF,2                CONSTANT OF 2                        86600013
         LA    RG,1                CONSTANT OF 1                        86800013
         SH    RG,PPITPTBL+68      FIRST OF FUTURE FIBS                 87000013
         BNE   OJNOTONE            BRANCH IF COUNT WAS NOT ONE          87200013
         LH    RH,WOJCTN2          COUNT OF (N-2)                       87400013
         LA    RG,PPITPTBL+68      ADDRESS OF FIRST FUTURE FIB          87600013
OJSETTWO STH   RF,0(0,RG)          SET FUTURE FIB TO TWO                87800013
         LA    RG,2(0,RG)          INCREMENT TO NEXT FUTURE FIB         88000013
         BCT   RH,OJSETTWO         BRANCH IF MORE FIBS TO BE UPDATED    88200013
OJNOTONE LH    RG,WOJCTN1          COUNT OF (N-1)                       88400013
OJMORDUM LH    RH,PPITPTBL+68(RE)  LAST OF FUTURE FIBONACCI NUMBERS,ETC 88600013
         SH    RH,PPITPTBL+34(RE)  COUNT OF SEQUENCES ALREADY ON UNIT   88800013
         STH   RH,PPITPTBL+68(RE)  COUNT OF DUMMYS FOR THIS UNIT        89000013
         SR    RE,RF               DECREMENT INCREMENT POINTER BY 1 POS 89200013
         BCT   RG,OJMORDUM         BRANCH IF MORE DUMMYS TO CALCULATE   89400013
         SPACE 1                                                        89600013
* REVERSE SEQUENCE INDICATOR BIT AND EXIT TO CLOSE ROUTINE              89800013
* WHICH WILL PRINT A MESSAGE AND EXIT TO SSC TO CALL PHASE 2.           90000013
         SPACE 1                                                        90200013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       90400013
         L     RP,PPIADSSC                                              90600013
         LA    RB,0                RETURN TO SSC REQUESTING PHASE 2     90800013
         BAL   RO,20(0,RP)                                              91000013
         SPACE 3                                                        91200013
         SPACE 1                                                        91400013
*** WORK AREAS                                                          91600013
         SPACE 1                                                        91800013
WOJCTN   DS    1H                  COUNT OF N                           92000013
WOJCTN1  DS    1H                  COUNT OF (N-1)                       92200013
WOJCTN2  DS    1H                  COUNT OF (N-2)                       92400013
WOJALODD DS    1H                  ALL ODD COUNTER (INITIALLY N)        92600013
WOJPERM  DS    1H                  PERMUTE COUNTER (INITIALLY N-1)      92800013
WOJPOINT DS    1H                  TAPE TABLE POINTER (INCREMENT)       93000013
WOJINCPT DS    1H                  INCREMENT TO LAST ITEMS IN TABLE     93200013
WOJTOTAL DS    1F                  COUNT OF SEQUENCES TO DISTRIBUTE     93400013
         EJECT                                                          93600013
*** IERRMA *** MESSAGE MODULE                                           93800013
         SPACE 1                                                        94000013
*********************************************************************   94200013
* THIS MODULE IS A DSECT OF RUNNING MODULE IERRMA                       94400013
*********************************************************************   94600013
         SPACE 1                                                        94800013
DIERRMA  DSECT                                                          95000013
         SPACE 1                                                        95200013
         COPY  RMAMAIN                                                  95400013
         EJECT                                                          95600013
         SMPPI                                                          95800013
         END                                                            96000013
