         TITLE 'IERAOK  -  OS/360 SORT/MERGE - 360S-SM023 - 6/8/66'     00100013
*MODULE NAME:*** IERAOK ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 1 ALGORITHM ASSIGNMENT FOR DISK       00600013
*   THIS MODULE INITIALIZES AN INTERNAL CONTROL TABLE CONSISTING OF:    00700013
*   1. DISK ADDR TO START WRITING STRINGS FOR EACH AREA.                00800013
*   2. DISK AREA TO START WRITING DIRECTORY FOR EACH AREA.              00900013
*   3. DETERMINE BLOCKING FACTOR FOR DIRECTORY                          01000013
         SPACE 2                                                        01100013
*USED AS A DSECT IN  N/A                                                01200013
*                                                                       01300013
*MACROS USED'                                                           01400013
         SPACE 1                                                        01500013
*   SMPPI                                                               01600013
         SPACE 2                                                        01700013
*ENTRY POINTS:                                                          01800013
         SPACE 1                                                        01900013
*        ENTRY IERAOK              ENTRY FROM: LOAD MODULE (IERRC9)     02000013
*                                    CALLING SEQUENCE-                  02100013
*                                    L   15,0                           02200013
*                                    BALR 14,15                         02300013
         SPACE 2                                                        02400013
*INPUT: PPI FIELDS REFERENCED-                                          02500013
         SPACE 1                                                        02600013
*   PPIADSSC   PPISEQCT                                                 02700013
*   PPIBDSVA   PPISTAR                                                  02800013
*   PPIENDAR                                                            02900013
*   PPINDSKAR                                                           03000013
*   PPIPDWA                                                             03100013
         SPACE 2                                                        03200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03300013
         SPACE 1                                                        03400013
*   PPIDEPHO                                                            03500013
*   PPIDIRAD                                                            03600013
*   PPIDSKED                                                            03700013
*   PPIMRGMX                                                            03800013
*   PPIMRGOP                                                            03900013
         SPACE 2                                                        04000013
*EXTERNAL ROUTINES:                                                     04100013
         SPACE 1                                                        04200013
*        EXTRN IERRMA                                                   04300013
         SPACE 2                                                        04400013
*EXITS: NORMAL                                                          04500013
         SPACE 1                                                        04600013
*   IERRC9                                                              04700013
         SPACE 2                                                        04800013
*EXITS: ERROR                                                           04900013
         SPACE 1                                                        05000013
*        NONE                                                           05100013
         SPACE 2                                                        05200013
*TABLES/WORK AREAS:                                                     05300013
         SPACE 1                                                        05400013
*   PPI,                                                                05500013
*   INTERNAL CONTROL TABLE TO DETERMINE WHERE TO WRITE:                 05600013
*   1.STRINGS                                                           05700013
*   2.DIRECTORY                                                         05800013
         SPACE 2                                                        05900013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06000013
         SPACE 2                                                        06100013
*NOTES:                                                                 06200013
         SPACE 1                                                        06300013
*   ALL INITIALIZING TAKES PLACE BETWEEN IERAOK,DSECT OF IERROK AND PPI 06400013
         SPACE 2                                                        06500013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06600013
         SPACE 1                                                        06700013
RA       EQU   0                   CONTENTS IN- N/A                     06800013
*                                  USE- WORK                            06900013
*                                  CONTENTS OUT- N/A                    07000013
RB       EQU   1                   CONTENTS IN- N/A                     07100013
*                                  USE- WORK                            07200013
*                                  CONTENTS OUT- N/A                    07300013
RC       EQU   2                   CONTENTS IN- N/A                     07400013
*                                  USE- N/A                             07500013
*                                  CONTENTS OUT- N/A                    07600013
RD       EQU   3                   CONTENTS IN- N/A                     07700013
*                                  USE- N/A                             07800013
*                                  CONTENTS OUT- N/A                    07900013
RE       EQU   4                   CONTENTS IN- N/A                     08000013
*                                  USE- WORK                            08100013
*                                  CONTENTS OUT- N/A                    08200013
RF       EQU   5                   CONTENTS IN- N/A                     08300013
*                                  USE- WORK                            08400013
*                                  CONTENTS OUT- N/A                    08500013
RG       EQU   6                   CONTENTS IN- N/A                     08600013
*                                  USE- WORK                            08700013
*                                  CONTENTS OUT- N/A                    08800013
RH       EQU   7                   CONTENTS IN- N/A                     08900013
*                                  USE- WORK                            09000013
*                                  CONTENTS OUT- N/A                    09100013
RI       EQU   8                   CONTENTS IN- N/A                     09200013
*                                  USE- WORK                            09300013
*                                  CONTENTS OUT- N/A                    09400013
RJ       EQU   9                   CONTENTS IN- N/A                     09500013
*                                  USE- WORK                            09600013
*                                  CONTENTS OUT- N/A                    09700013
RK       EQU   10                  CONTENTS IN- N/A                     09800013
*                                  USE- N/A                             09900013
*                                  CONTENTS OUT- N/A                    10000013
RL       EQU   11                  CONTENTS IN- N/A                     10100013
*                                  USE- BASE                            10200013
*                                  CONTENTS OUT- N/A                    10300013
RM       EQU   12                  CONTENTS IN- N/A                     10400013
*                                  USE- N/A                             10500013
*                                  CONTENTS OUT- N/A                    10600013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10700013
*                                  USE- PPI REFERENCE,REGISTER SAVE     10800013
*                                    AREA                               10900013
*                                  CONTENTS OUT- ADDRESS OF PPI         11000013
RO       EQU   14                  CONTENTS IN- RETURN ADDR             11100013
*                                  USE- SAVE,WORK                       11200013
*                                  CONTENTS OUT- RETURN ADDR            11300013
RP       EQU   15                  CONTENTS IN- BASE                    11400013
*                                  USE- WORK                            11500013
*                                  CONTENTS OUT- N/A                    11600013
         SPACE 2                                                        11700013
*START OF MODULE CODE PROPER:                                           11800013
         SPACE 2                                                        11900013
IERAOK   CSECT                                                          12000013
*                                                                A27992 12050000
         USING *,RL                                                     12100013
         USING DIERROK,RJ                                               12200013
         USING IERRCA,RN                                                12300013
         USING DIERRMA,RO                                               12400013
IERMOI   LR    RL,RP                                                    12500013
         L     RJ,PPIALG+4                                              12600013
         TM    PPISW1+7,X'02'      2314 USING 2311 ALGORITHM            12610017
         BNO   AOKASSMT            NO                                   12620017
         SPACE 1                                                        12630017
         MVI   AOK100+1,X'12'      MODIFY INSTRUCTIONS IN AOK AND       12640017
         MVI   AOKHD9+1,X'13'      ROK TO REFLECT 20 TRACKS PER         12650017
         MVI   ROK100+1,X'2C'      CYLINDER FOR THE 2314.               12660017
         MVI   ROKBACK+5,X'13'                                          12670017
         MVI   ROKDECTK+1,X'13'                                         12680017
         MVI   ROK200+1,X'12'                                           12690017
         SPACE 3                                                        12700013
AOKASSMT LA    RH,1                GET CONSTANT 1                       12800013
         LH    RI,PPINDSKA         GET TOTAL NO.DISK AREAS USING        12900013
         SR    RI,RH               REDUCE BY 1                          13000013
         LA    RE,TABLE+4          GET ADDR OF FST SLOT IN TBL TO FILL  13100013
         LA    RF,PPISTAR          GET ADDR OF FST AREA TO FILL WITH    13200013
AOKLOOPA MVC   0(8,RE),0(RF)       FILL TABLE SLOT                      13300013
         LA    RE,20(0,RE)         BUMP ADDR TO NXT SLOT IN TABLE       13400013
         LA    RF,8(0,RF)          BUMP ADDR TO NXT AREA IN PPI         13500013
         BCT   RI,AOKLOOPA         IS TABLE FULL{,NO LOOP               13600013
*    * STORE FST SEQ AREA ADDR TO WRITE IN PPI ************************ 13700013
         MVC   PPIDEPHO(8),PPISTAR PUT ADDR OF WHERE TO WRITE FIRST SEQ 13800013
*                                    INTO PPI                           13900013
*    * LOAD TABLE WITH STRTG ADDRS FOR DICTY WRTS,FR ENDG ADDRS IN PPI* 14000013
         LH    RI,PPINDSKA         GET TOTAL NO.DISK AREAS USING        14100013
         SR    RI,RH               REDUCE BY 1 (RH CONTAINS 1 FR ABOVE) 14200013
         LA    RE,TABLE+12         GET ADDR OF FST SLOT IN DIRECTORY    14300013
         LA    RF,PPIENDAR         GET ADDR OF FST END ADDR IN PPI      14400013
AOKLOOPB MVC   0(8,RE),0(RF)       FILL TABLE SLOT                      14500013
         LA    RE,20(0,RE)         BUMP ADDR TO NXT SLOT IN TABLE       14600013
         LA    RF,8(0,RF)          BUMP ADDR TO NXT AREA IN PPI         14700013
         BCT   RI,AOKLOOPB         IS TABLE FULL{ NO,LOOP               14800013
*    * BLOCK ADDR OF FST DICTY IN DICTY BLOCK ************************* 14900013
         MVC   WCLBKAR(8),PPISTAR  BLOCK FST AREA IN DICTY              15000013
*  REDUCE ALL ENDG ADDRS IN PPI BY 2 TRACKS                             15100013
         LH    RI,PPINDSKA         GET NO.DISK AREAS USING              15200013
         SR    RI,RH               DECMT NO.BY 1                        15300013
         LA    RF,PPIENDAR         GET ADDR OF FST ENDG ADDR IN PPI     15400013
AOKLOOPC SR    RG,RG               CLEAR REG.                           15500013
         IC    RG,6(0,RF)          GET HEAD NO. FROM ENDG DISK ADDR     15600013
         CLR   RG,RH              IS HEAD NO. = 1                       15700013
         BH    AOKDECHD           NO, HEAD = 2 OR MORE,DECRM'T HD BY 2  15800013
         SR    RG,RG               CLEAR REG.                           15900013
         IC    RG,4(0,RF)          GET CYL NO.                          16000013
         BCT   RG,AOKCHGTK         DECRMT CYL NO. BY 1                  16100013
AOKCHGTK STC   RG,4(0,RF)         RESTORE DECMT'D CYL. NO.              16200013
         IC    RG,6(0,RF)         GET HEAD NO. AGAIN                    16300013
         CLR   RG,RH              IS HEAD = 1                           16400013
         BE    AOKHD9             YES, RESET HEAD = 9                   16500013
*  HEAD WAS 0, RESET HEAD = 8                                           16600013
AOK100   EQU   *                                                        16650017
         MVI   6(RF),X'08'                                              16700013
         SPACE 2                                                        16720017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       16740017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   MVI  6(RF),X'12'      16760017
         SPACE 2                                                        16780017
         B     AOKGOE              GO TO BUMP ADDR TO NXT AREA IN PP1   16840018
         SPACE 2                                                        16900013
AOKHD9   MVI   6(RF),X'09'        RESET HEAD = 9                        17000013
         SPACE 2                                                        17020017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       17040017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   MVI  6(RF),X'13'      17060017
         SPACE 2                                                        17080017
         B     AOKGOE              GO TO BUMP ADDR TO NXT AREA IN PP1   17140018
*                                                                       17200013
*                                                                       17300013
AOKDECHD SR    RG,RH               REDUCE HEAD NO.BY 1                  17400013
         SR    RG,RH               REDUCE HEAD NO.BY ANOTHER 1 (TOTAL=2 17500013
         STC   RG,6(0,RF)          RESTORE HEAD NO. TO ENDG ADDR IN PPI 17600013
AOKGOE   LA    RF,8(0,RF)          BUMP ADDR TO NXT AREA IN PPI         17700013
         BCT   RI,AOKLOOPC         ARE ALL ENDG ADDR AREAS IN PPI REDU- 17800013
*                                    CED BY 2 TRACKS YET?, NO--LOOP     17900013
*    * SET POINTER TO FST POS. IN TABLE ******************************* 18000013
         LA    RG,TABLE            GET ADDR OF TBL                      18100013
         ST    RG,WPOINT           LOAD IN POINTER                      18200013
*    * SET LIMIT OF SORT TABLE TO NO.OF AREAS,LESS 1 ****************** 18300013
         LA    RI,20                                                    18400013
         LH    RF,PPINDSKA         GET NO.DISK AREAS USING              18500013
         SR    RF,RH               SUBTRCT 1                            18600013
         MR    RE,RI               MLTPY RI(20)XRF (NO.AREAS)=RF PROD.  18700013
         AR    RG,RF               ADD TBL LGTH(PROD)TO BEG TABLE ADDR. 18800013
         ST    RG,WTBLLIMT                                              18900013
         BR    RO                  GO BACK TO LOADER IERRC9             19000018
         DS    0F                                                       19100013
         EJECT                                                          19200013
*        THIS IS A DUMMY RUNNING MODULE FOR PURPOSES OF LINK ONLY       19300013
*                                                                       19400013
*                                                                       19500013
*                                                                       19600013
*                                                                       19700013
*********************************************************************** 19800013
DIERROK  DSECT                                                          19900013
         USING *,RL                SET BASE RG                          20000013
IERDOK   B     ROKEOF              OUTPUT END OF FILE                   20100013
         B     ROKEOA              END OF AREA,DETERMINED BY'WRITE'     20200013
         B     ROKEOASQ            END OF AREA+ SEQ,DET.BY'WRITE'       20300013
ROKEOSQ  L     RE,WPOINT           GET ADDR OF AN AREA IN TABLE         20400013
         L     RF,0(0,RE)          GET AREA KEY (EG.0,1,2,3,4,OR5)      20500013
         SLL   RF,1                CALC. DISPLC.(AREA KEY X CTR SIZE)   20600013
         LA    RG,PPISEQCT         GET ST PT OF COUNTERS                20700013
         LH    RH,0(RF,RG)         GET DATA FROM COUNTER                20800013
         LA    RH,1(0,RH)          INCRMT CTR                           20900013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   21000013
*       * DECRMT BLKG COUNTER - BLOCK OF ADDRS FILLED{ **************** 21100013
         L     RE,WBLKCT           GET DICTY BLKG CTR                   21200013
         BCT   RE,ROKDRBLK         DECRMT BLKG CTR/BLK FILLED{          21300013
*            * SV ADDR IN TBL-PUT DICTY ADDR IN PPI-MV DICTY BLK TO PPI 21400013
*  WRITE DICTY BLK OF ADDRS ******************************************* 21500013
         L     RE,WPOINT                                                21600013
         MVC   4(8,RE),PPIDEPHO    SV NXT SEQ IN TBL                    21700013
         MVC   PPIDIRAD(8),12(RE)  PUT NXT DICTY BLOCK ADDR IN PPI      21800013
         MVC   PPIPDWA(64),WCLBKAR    PUT DICTY BLKG AREA IN PPI        21900013
         L     RL,PPIWRT+4                                              22000013
         BAL   RO,12(0,RL)         WRITE DICTY BLK OF ADDRS             22100018
*    * RESET DICTY BLKG CTR TO 8 ************************************** 22200013
         LA    RE,8                RESET BLKG CTR TO 8                  22300013
         ST    RE,WBLKCT           RESET BLKG CTR TO 8                  22400013
*    * TRACK OF DICTY FILLED{ ***************************************** 22500013
         L     RG,WPOINT           GET AREA ADDR FROM TABLE             22600013
ROK100   EQU   *                                                        22650017
         CLI   19(RG),X'1C'       IS RECORD CT ALREADY AT 28 (LST BLK)  22700013
         SPACE 2                                                        22720017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       22740017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  19(RG),X'2C'     22760017
         SPACE 2                                                        22780017
         BNE   ROKSMTK             NO,BRANCH                            22800013
*    * GET PROPER ENDG ADDR IN PPI ************************************ 22900013
         L     RH,0(0,RG)          YES,TRACK IS FILLED.                 23000013
         SLL   RH,3                CALC.DISPLC(AREA X DSK ADDR SIZE -8) 23100013
         LA    RI,PPIENDAR         GET START.ADDR IN PPI                23200013
         AR    RI,RH               ADD DISPLC.                          23300013
*    * IS ANOTHER TRACK AVAILABLE ************************************* 23400013
         CLC   4(3,RI),PPIDEPHO+4  HAS SEQ.AREA REACHED END ADDR IN PPI 23500013
         BNH   ROKNOTRK            YES,NO TRACKS AVAILABLE              23600013
*  RESET RCD CT FOR NXT WRITE OF DICTY (IN TBL) = 1 ---REGARDLESS       23700013
         MVI   19(RG),X'01'                                             23800013
         CLI   6(RI),X'00'         IS TRACK NO.= 0{                     23900013
         BNE   ROKDECTK            NO, BRANCH AND REDUCE TRACK NO.      24000013
* SUPPLY TABLE,(NEW DICTY ADDR),USING ENDAR IN PPI AND ADDING 1 TRACK   24100013
*  TO IT SO AS TO LEAVE THE 1 TRACK BUFFER ALWAYS OPEN (AT ASSIGNMENT   24200013
*  TIME THE REAL ENDAR IS PUSHED BACK BY 2 TRACKS)SO NOW BY USING ENDAR 24300013
*  AND ADDING 1 TRACK, WE ARE POSITIONED READY TO WRITE THE NXT OPEN    24400013
*  TRACK OF DIRECTORY EG. TRK 8=LAST TRACK FOR STRINGS,TRK 9=EOF BUFFER 24500013
*  AND TRACK 10=DIRECTORY ---- WHEN TRK 10 IS FULL,ALL 3 TRACKS SHIFT   24600013
*  DOWN 1 IN THE FOLLOWING MANNER:                                      24700013
*   1.DIRCTY ADDR (IN TABLE) IS REDUCED 1 TRACK BY'ADDING 1 TRACK'TO    24800013
*     THE ENDAR IN PPI (SINCE IT IS ALREADY 2 TRACKS AWAY FROM THE      24900013
*     DIRCTY TRACK JUST FILLED)AND CLOBBERING OLD DIRCTY ADDR IN TABLE  25000013
*     TO PROVIDE A NEW (THE NEXT OPEN)TRACK  TO WRITE DIRCTY IN.        25100013
*   2.THEN THE ENDAR IS REDUCED BY 1 TRACK SO THAT PRIOR TO THE FIRST   25200013
*     WRITE IN THE NEW DICTY TRACK (USING ABOVE EXP.)THE TRACKS ARE     25300013
*     ASSIGNED: TRK 7=LAST TRACK FOR STRINGS (ENDAR), TRK 8=EOF BUFFER, 25400013
*     TRACK 9=NEW EMPTY DIRCTY TRK,AND TRK 10=OLD FILLED DICTY TRK.     25500013
         SPACE 2                                                        25600013
* USING ADDR AT ENDAR,ADD 1 TO HEAD NO.AND PLUG INTO TABLE (NEW DIRCTY) 25700013
         SR    RH,RH               CLEAR REG.                           25800013
         IC    RH,6(0,RI)          GET HD NO. FROM PPI (ENDAR)          25900013
         LA    RH,1(0,RH)          ADD 1                                26000013
         STC   RH,18(0,RG)         STORE IN TABLE (NEW DICTRY)          26100013
*  DECRM'T ENDAR BY 1 TRACK (DECRM'T CYL BY 1, RESET TRK=9)             26200013
         SR    RF,RF                                                    26300013
         IC    RF,4(0,RI)         GET CYL NO.                           26400013
         BCT   RF,ROKBACK         REDUCE BY 1                           26500013
         B     ROKABORT            SORT CAPACITY REACHED -ABORT JOB     26600013
         SPACE 2                                                        26700013
ROKBACK  STC   RF,4(0,RI)         RESTORE NEW CYL NO. TO ENDAR IN PPI   26800013
         MVI   6(RI),X'09'        RESTORE ENDAR TRACK NO. TO 9          26900013
         SPACE 2                                                        26920017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       26940017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   MVI  6(RI),X'13'      26960017
         SPACE 2                                                        26980017
         B     ROKGOB              GO TO INCREMENT TABLE POINTER        27040018
         SPACE 2                                                        27100013
ROKDECTK CLI   6(RI),X'09'        IS TRACK NO. IN ENDAR =9?             27200013
         SPACE 2                                                        27220017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       27240017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  6(RI),X'13'      27260017
         SPACE 2                                                        27280017
         BE    ROKHNINE           YES,RESET TRK=0,ENDAR CYL+1 INTO TBL  27300013
* USING ADDR AT ENDAR,ADD 1 TO HEAD NO.AND PLUG INTO TABLE (NEW DIRCTY) 27400013
         SR    RH,RH               CLEAR REG.                           27500013
         IC    RH,6(0,RI)          GET HD NO. FROM PPI (ENDAR)          27600013
         LA    RH,1(0,RH)          ADD 1                                27700013
         STC   RH,18(0,RG)         STORE IN TABLE (NEW DICTRY)          27800013
ROK200   EQU   *                                                        27850017
         CLI   6(RI),X'08'        ENDAR HD. NO. = 8                     27900013
         SPACE 2                                                        27920017
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS USING THE       27940017
*   2311 ALGORITHM. THE NEW INSTRUCTION WILL BE   CLI  6(RI),X'12'      27960017
         SPACE 2                                                        27980017
         BNE   ROKRETN2            GO TO DECR TRK BY 1                  28040018
*  DECRM'T CYL NO. IN TBL BY 1 (NOW EQUAL TO CYL NO. IN ENDAR)          28100013
         MVC   16(1,RG),4(RI)                                           28200013
         B     ROKRETN2            GO TO DECR TRK BY 1                  28300018
         SPACE 3                                                        28400013
ROKHNINE MVI   18(RG),X'00'        SET HEAD NO.=ZERO IN TABLE           28500013
         SPACE 3                                                        28600013
ROKRETN2 IC    RG,6(0,RI)         GET ENDAR TRK NO. AND DECRM'T BY 1    28700013
         LA    RF,1                                                     28800013
         SR    RG,RF              DECR. TRK BY 1                        28900013
         STC   RG,6(0,RI)                                               29000013
         B     ROKGOB              GO TO INCREMENT TABLE POINTER        29100018
         SPACE 3                                                        29200013
*  INCRM'T RCD COUNT FOR NXT WRITE ON SAME TRACK( IN TABLE)             29300013
ROKSMTK  IC    RH,19(0,RG)                                              29400013
         LA    RH,1(0,RH)                                               29500013
         STC   RH,19(0,RG)                                              29600013
         B     ROKGOB              GO TO INCREMENT TABLE POINTER        29700018
         SPACE 3                                                        29800013
*     BLOCK THE NXT SEQ. ADDR PASSED BY THE WRITE RTN.                  29900013
ROKDRBLK ST    RE,WBLKCT          RESTORE DICTY BLKG. CTR.              30000013
         LA    RF,8                                                     30100013
         SR    RF,RE              CALC. DISPLC TO REACH PROPER ADDR IN  30200013
         SLL   RF,3               DICTY BLK, TO FILL NXT BLK.           30300013
         LA    RG,WCLBKAR         GET ST PT OF DICTY BLKG AREA          30400013
         AR    RG,RF              DETERMINE WHERE TO INSERT NXT SEQ.    30500013
         MVC   0(8,RG),PPIDEPHO                                         30600013
*    * DEBLOCK ******************************************************** 30700013
ROKDEBL  L     RL,PPIDEB+4                                              30800013
         B     8(RL)               GO TO DEBLOCK ROUTINE                30900018
*                                                                       31000013
*    * INCREMENT TABLE POINTER **************************************** 31100013
ROKGOB   L     RE,WPOINT           INCREMT TABLE POINTER                31200013
         LA    RE,20(0,RE)         INCREMT TABLE POINTER                31300013
         ST    RE,WPOINT           INCREMT TABLE POINTER                31400013
* C4 * EXCEED LIMIT OF TABLE{****************************************** 31500013
         CL    RE,WTBLLIMT         AT END OF TABLE{                     31600013
         BE    ROKSETPT            YES,GO TO RESET POINTER              31700013
*    * STORE ADDR OF WHERE TO RECORD FIRST OF NXT SEQUENCES *********** 31800013
ROKNXT1  L     RE,WPOINT                                                31900013
         MVC   PPIDEPHO(8),4(RE)   STORE ADDR OF WHERE TO WRITE NEXT SQ 32000013
*                                    INTO PPI                           32100013
*    * BLOCK ADDR OF FIRST SEQUENCE *********************************** 32200013
         MVC   WCLBKAR(8),4(RE)                                         32300013
*                                    DICTY BLOCK                        32400013
*    * IS SWITCH ON{ ************************************************** 32500013
         TM    KSWA7E4,X'01'       DID LAST 'WRITE'HAVE AREA ENOUGH{    32600013
         BO    ROKDEBL            YES,SW IS ON,GET NXT SQ FR DEBLK RTN  32700013
*   * TURN SWITCH ON ************************************************** 32800013
         OI    KSWA7E4,X'01'      NO,TURN ON SW, WRITE SEQ IN NXT AREA  32900013
*   * GO TO WRITE ***************************************************** 33000013
         L     RL,PPIWRT+4                                              33100013
         BR    RL                  GO TO WRITE                          33200018
*                                                                       33300013
* C5 * SET POINTER TO FST POS. IN TABLE ******************************* 33400013
ROKSETPT LA    RG,TABLE            SET POINTER TO FIRST POS. OF SORT-   33500013
         ST    RG,WPOINT             TABLE                              33600013
         B     ROKNXT1             GO BACK TO MAIN FLOW                 33700013
*                                                                       33800013
*                                                                       33900013
*          * OUTPUT END OF FILE *************************************** 34000013
*    * UPDATE COUNTER OF SEQUENCES FOR CURRENT AREA ******************* 34100013
ROKEOF   L     RE,WPOINT           GET ADDR OF AN AREA IN TABLE         34200013
         L     RF,0(0,RE)          GET AREA KEY                         34300013
         SLL   RF,1                CALC DISPLC IN CTR AREA IN PPI       34400013
         LA    RG,PPISEQCT         GET ST PT OF CTRS                    34500013
         LH    RH,0(RF,RG)         GET NO.FR CTR                        34600013
         LA    RH,1(0,RH)          INCRMT CTR                           34700013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   34800013
*    * PUT DIRECTORY ADDR INTO PPI ************************************ 34900013
         MVC   PPIDIRAD(8),12(RE)                                       35000013
*    * MOVE BLKG AREA TO PPI ****************************************** 35100013
         MVC   PPIPDWA(64),WCLBKAR                                      35200013
*    * GO TO WRITE BLOCK OF DICTY ADDRS.                                35300013
         L     RL,PPIWRT+4                                              35400013
         BAL   RO,12(0,RL)         GO TO WRITE BLOCK OF DICTY ADDRS     35500018
*    * SUM SEQUENCE COUNTERS ****************************************** 35600013
         LH    RI,PPINDSKA                                              35700013
         LA    RG,PPISEQCT                                              35800013
         SR    RE,RE                                                    35900013
ROKLOOPD LH    RF,0(0,RG)          GET DATA IN CTR                      36000013
         AR    RE,RF               SUM IN RE                            36100013
         LA    RG,2(0,RG)          BUMP TO NXT CTR                      36200013
         BCT   RI,ROKLOOPD         ADDED ALL CTRS{ NO,LOOP              36300013
*    * RESTORE END ADDRS TO PPI FROM PPI SAVE AREA ******************** 36400013
         MVC   PPIENDAR(48),PPIDSKED                                    36500013
         LH    RH,PPIMRGMX                                              36600013
         LA    RH,1(0,RH)         PLUS ONE                              36700013
         STC   RH,PPIBDSVA                                              36800013
*    * SUM VS M ******************************************************* 36900013
         CH    RE,PPIMRGMX                                              37000013
         BH    ROKGOF              GO TO CLOSE ROUTINE                  37100018
         STH   RE,PPIMRGOP                                              37200013
*    * SET INDICATOR TO PHASE 3 *************************************** 37300013
         L     RP,PPIADSSC                                              37400013
         LA    RB,4                                                     37500013
         BAL   RO,20(0,RP)         GO TO SORT CONTROL                   37600018
*                                                                       37700013
*    * CLOSE ROUTINE ************************************************** 37800013
ROKGOF   L     RP,PPIADSSC                                              37900013
         LA    RB,0                                                     38000013
         BAL   RO,20(0,RP)         GO TO SORT CONTROL                   38100018
*          * END OF AREA AS DETERMINED BY WRITE ROUTINE *************** 38200013
*    * TURN SWITCH A7-E4 OFF ****************************************** 38300013
ROKEOA   NI    KSWA7E4,X'00'                                            38400013
*    * UPDATE COUNT OF SEQUENCES FOR CURRENT AREA ********************* 38500013
ROKEOASQ L     RE,WPOINT                                                38600013
         L     RF,0(0,RE)                                               38700013
         SLL   RF,1                                                     38800013
         LA    RG,PPISEQCT                                              38900013
         LH    RH,0(RF,RG)                                              39000013
         LA    RH,1(0,RH)                                               39100013
         STH   RH,0(RF,RG)                                              39200013
*    * PUT DIRECTORY ADDR INTO PPI ************************************ 39300013
         MVC   PPIDIRAD(8),12(RE)                                       39400013
*    * MOVE BLKG AREA TO PPI ****************************************** 39500013
         MVC   PPIPDWA(64),WCLBKAR                                      39600013
*    * GO TO WRITE BLOCK OF DICTY ADDRS ******************************* 39700013
         L     RL,PPIWRT+4                                              39800013
         BAL   RO,12(0,RL)         GO TO WRITE BLOCK OF DICTY ADDRS     39900018
*    * RESET DICTY BLKG CTR TO 8 ************************************** 40000013
         LA    RE,8                                                     40100013
         ST    RE,WBLKCT                                                40200013
*    * LAST AREA{-CHECK LIMIT. **************************************** 40300013
ROKNOTRK LA    RF,20                                                    40400013
         LA    RE,TABLE                                                 40500013
         ALR   RE,RF                                                    40600013
         CL    RE,WTBLLIMT                                              40700013
         BE    ROKABORT            NO MORE AREAS-ABORT JOB              40800013
         B     ROKGOH              SORT CAPACITY HAS BEEN REACHED       40900018
*SORT CAPACITY REACHED                                                  41000013
         SPACE 1                                                        41100013
ROKABORT L     RO,PPIRMA+4                                              41200013
         LM    RA,RB,MSGP1A02                                           41300013
         L     RP,PPIADSSC                                              41400013
         BAL   RO,12(0,RP)         GO TO SORT CONTROL                   41500018
         SPACE 1                                                        41600013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   41700013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        41800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   41900013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      42000013
         SPACE 1                                                        42100013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             42200013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 42230000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 42260000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      42300013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             42400013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                42500013
         BO    ROI031              MAKE SURE CNT IS NOT NEG             42600018
         SPACE 1                                                        42700013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      42800013
         SR    RO,RO                                                    42900013
         DR    RO,RA                 RCDS. IN BLOCK                     43000013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         43100013
         BH    ROI032                NEGATIVE                           43200013
         SPACE 1                                                        43300013
         AR    RB,RP               ADD B TO CNT                         43400013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           43500013
         BNL   ROI033              GO TO SET UP CNT FOR PRINTING        43600018
         SPACE 1                                                        43700013
         LR    RB,RP               SET CNT TO B                         43800013
         B     ROI033              GO TO SET UP CNT FOR PRINTING        43900018
         SPACE 2                                                        44000013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      44100013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           44200013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       44300013
         OI    PPIWKARE+15,X'F0'                                        44400013
         SPACE 2                                                        44500013
         L     RO,PPIRMA+4                                              44600013
         LM    RA,RB,MSGP1A06                                           44700013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                44800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        44900013
         BAL   RO,12(0,RP)         GO TO PRINT MESSAGE                  45000018
         SPACE 1                                                        45100013
         L     RP,PPIADSSC                                              45200013
         B     16(0,RP)            GO TO SORT CONTROL                   45300018
*    * LIMIT OF SORT TABLE{ ******************************************* 45400013
ROKGOH   L     RE,WPOINT                                                45500013
         L     RG,WPOINT                                                45600013
         LA    RG,20(0,RG)                                              45700013
         CL    RG,WTBLLIMT                                              45800013
         BE    ROKRESET            YES,RESET POINTER TO BEG. POS.       45900013
*    * PUT LIMIT PORTION OF SORT TABLE IN FILLED AREA'S POS. ********** 46000013
         L     RF,WTBLLIMT                                              46100013
         LA    RG,20    MT                                              46200013
         SLR   RF,RG                                                    46300013
         MVC   0(20,RE),0(RF)                                           46400013
*    * DECREMT LIMIT OF SORT TABLE BY 1 ******************************* 46500013
ROKGOG   L     RF,WTBLLIMT                                              46600013
         LA    RE,20                                                    46700013
         SLR   RF,RE                                                    46800013
         ST    RF,WTBLLIMT                                              46900013
         B     ROKNXT1             GO TO ST PTR OF WHERE TO WT NXT SEQ  47000018
*                                                                       47100013
*    * RESET POINTER TO FIRST POS. IN SORT TABLE ********************** 47200013
ROKRESET LA    RG,TABLE                                                 47300013
         ST    RG,WPOINT                                                47400013
         B     ROKGOG              GO TO DECREMENT SORT TABLE BY 1      47500018
*                                                                       47600013
*                                                                       47700013
         DS    0F                                                       47800013
WPOINT   DC    X'00000000'         SET UP POINTER                       47900013
         DS    0F                                                       48000013
WBLKCT   DC    X'00000008'         SET UP DIRECTORY BLK CTR.            48100013
         DS    0F                                                       48200013
WCLBKAR  DS    16F                 DICTY BLOCKING AREA=64 BYTES         48300013
         DS    0F                                                       48400013
WTBLLIMT DC    X'00000000'         SET UP TABLE LIMIT POINTER           48500013
         DS    0F                                                       48600013
KSWA7E4  DC    X'01'              SWITCH A7-E4 NORMALLY ON              48700013
         DS    0F                                                       48800013
TABLE    DC    X'00000000'         SET UP TABLE -FIRST AREA             48900013
         DS    4F                  SET UP TABLE -FIRST AREA             49000013
         DC    X'00000001'         SET UP TABLE -SECOND AREA            49100013
         DS    4F                  SET UP TABLE -SECOND AREA            49200013
         DC    X'00000002'         SET UP TABLE -THIRD AREA             49300013
         DS    4F                  SET UP TABLE -THIRD AREA             49400013
         DC    X'00000003'         SET UP TABLE -FOURTH AREA            49500013
         DS    4F                  SET UP TABLE -FOURTH AREA            49600013
         DC    X'00000004'         SET UP TABLE -FIFTH AREA             49700013
         DS    4F                  SET UP TABLE -FIFTH AREA             49800013
         DS    0F                                                       49900013
DIERRMA  DSECT                                                          50000013
*                                                                       50100013
* MODULE NAME ***IERRMA***                                              50200013
*                                                                       50300013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        50400013
* PHASE 1 RUNNING PROGRAM.                                              50500013
         SPACE 1                                                        50600013
         COPY  RMAMAIN                                                  50700013
         EJECT                                                          50800013
         SMPPI                                                          50900013
         END                                                            51000013
