         TITLE 'IERAOL - OS/360 SORT/MERGE - 360S-SM-023 01/29/65 '     00400013
*MODULE NAME *** IERAOL ***                                             00800013
         SPACE 2                                                        01200013
*STATUS: CHANGE LEVEL 000                                               01600013
         SPACE 2                                                        02000013
*MODULE FUNCTION/OPERATION: THIS ROUTINE GENERATES THE REQUIRED EQUALS  02400013
*   ROUTINE TO BE USED BY THE RUNNING PROGRAMS. THIS IS DONE BY         02800013
*   INITIALIZING THE CODE FOUND AT THE END OF THIS ROUTINE AND MOVING   03200013
*   THIS CODE TO THE LOCATION SPECIFIED IN PPIA.                        03600013
         SPACE 2                                                        04000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04400013
*   N/A                                                                 04800013
         SPACE 2                                                        05200013
*LIST OF MACROS USED BY MODULE:                                         05600013
*   N/A                                                                 06000013
         SPACE 2                                                        06400013
*ENTRY POINTS:                                                          06800013
         SPACE                                                          07200013
         ENTRY IERAOL              THIS MODULE ENTRY POINT              07600013
         SPACE 2                                                        08000013
*INPUT: - PPI FIELDS REFERENCED -                                       08400013
         SPACE                                                          08800013
*   PPISW1    PPIPCF01    PPINUMCF                                      09200013
*   PPIFCF01  PPIAXERT                                                  09600013
         SPACE 2                                                        10000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED -                          10400013
         SPACE                                                          10800013
*    N/A                                                                11200013
         SPACE 2                                                        11600013
*EXTERNAL ROUTINES:                                                     12000013
*    N/A                                                                12400013
         SPACE 2                                                        12800013
*EXTERNAL PARAMETERS:                                                   13200013
*    N/A                                                                13600013
         SPACE 2                                                        14000013
*EXITS-NORMAL:                                                          14400013
*    BRANCH TO SSC VIA RETURN REGISTER RM                               14800013
         SPACE 2                                                        15200013
*TABLES/WORK AREAS:                                                     15600013
*    N/A                                                                16000013
         SPACE 2                                                        16400013
*ATTRIBUTES: THIS IS A CLASS A MODULE. (READ ONLY)                      16800013
         SPACE 2                                                        17200013
*NOTES:  N/A                                                            17600013
         EJECT                                                          18000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            18400013
         SPACE                                                          18800013
RA       EQU   0                     CONTENTS IN - N/A                  19200013
*                                    USED - NOT USED                    19600013
*                                  CONTENTS OUT - N/A                   20000013
RB       EQU   1                     CONTENTS IN - N/A                  20400013
*                                    USED - NOT USED                    20800013
*                                  CONTENTS OUT - N/A                   21200013
RC       EQU   2                     CONTENTS IN - N/A                  21600013
*                                    USED - NOT USED                    22000013
*                                  CONTENTS OUT - N/A                   22400013
RD       EQU   3                     CONTENTS IN - N/A                  22800013
*                                    USED - NOT USED                    23200013
*                                  CONTENTS OUT - N/A                   23600013
RE       EQU   4                     CONTENTS IN - N/A                  24000013
*                                    USED - WORK REGISTER               24400013
*                                  CONTENTS OUT - N/A                   24800013
RF       EQU   5                     CONTENTS IN - N/A                  25200013
*                                    USED - ADDR OF CONTROL FIELD DATA  25600013
*                                  CONTENTS OUT - N/A                   26000013
RG       EQU   6                     CONTENTS IN - N/A                  26400013
*                                    USED - NUMBER OF CONTROL FIELDS    26800013
*                                  CONTENTS OUT - N/A                   27200013
RH       EQU   7                     CONTENTS IN - N/A                  27600013
*                                    USED - CONSTANT 1                  28000013
*                                  CONTENTS OUT - N/A                   28400013
RI       EQU   8                     CONTENTS IN - N/A                  28800013
*                                    USED - ADDR OF CORE TO INITIALIZE  29200013
*                                  CONTENTS OUT - N/A                   29600013
RJ       EQU   9                     CONTENTS IN - N/A                  30000013
*                                    USED - WORK REGISTER               30400013
*                                  CONTENTS OUT - N/A                   30800013
RK       EQU   10                    CONTENTS IN - N/A                  31200013
*                                    USED - WORK REGISTER               31600013
*                                  CONTENTS OUT - N/A                   32000013
RL       EQU   11                    CONTENTS IN - N/A                  32400013
*                                    USED - PROGRAM BASE REGISTER       32800013
*                                  CONTENTS OUT - N/A                   33200013
RM       EQU   12                    CONTENTS IN - N/A                  33600013
*                                    USED - SSC REGISTER SAVE ADDRESS   34000013
*                                  CONTENTS OUT - N/A                   34400013
RN       EQU   13                    CONTENTS IN - ADDRESS OF PPIA      34800013
*                                    USED - ADDRESS OF PPIA             35200013
*                                  CONTENTS OUT - ADDRESS OF PPIA       35600013
RO       EQU   14                    CONTENTS IN - SSC RETURN ADDRESS   36000013
*                                    USED - SSC RETURN REGISTER         36400013
*                                  CONTENTS OUT - SSC RETURN ADDRESS    36800013
RP       EQU   15                    CONTENTS IN - ADDRESS OF ROUTINE   37200013
*                                    USED - N/A                         37600013
*                                  CONTENTS OUT - SSC RETURN CODE       38000013
*                                                                       38400013
IERAOL   CSECT                                                          38800013
         USING *,RP                                                     39200013
         STM   RC,RL,0(RM)         SAVE SSC REGISTERS                   39600013
         BALR  RL,0                                                     40000013
         USING *,RL                                                     40400013
         DROP  RP                                                       40800013
         USING IERRCA,RN                                                41200013
*                                                                       41600013
* CHECK FOR MERGE ONLY AND SET BRANCH TO BY PASS THE INCREMENTING       42000013
* OF THE CONTROL FIELD DISPLACEMENTS FOR A SORT.                        42400013
*                                                                       42800013
         TM    PPISW1+2,X'02'      IS THIS A MERGE ONLY                 43200013
         BZ    OLSORT              BRANCH IF IT IS NOT A MERGE ONLY     43600013
         OI    OLSETBC+1,X'F0'     SET BRANCH INSTRUCTION TO BRANCH     44000013
*                                                                       44400013
*  SET UP NECESSARY REGISTERS FOR INITIALIZING THE CODE FOR THE         44800013
*  EQUALS ROUTINE.                                                      45200013
*                                                                       45600013
OLSORT   LA    RI,OLCF2            ADDRESS OF CODE TO INITIALIZE        46000013
         LA    RF,PPIPCF01         ADDRESS OF CONTROL FIELD DATA        46400013
         LH    RG,PPINUMCF         NUMBER OF CONTROL FIELDS             46800013
         LA    RH,1                CONSTANT OF 1                        47200013
*                                                                       47600013
*  INITIALIZE THE INDICATED COMPARE INSTRUCTION.                        48000013
*                                                                       48400013
OLNEXTCF SR    RG,RH               DECREMENT COUNT OF CONTROL FIELD     48800013
         LA    RF,6(0,RF)          INCREMENT TO DATA FOR NEXT C.F.      49200013
         LH    RJ,0(0,RF)          DISPLACEMENT OF THIS CONTROL FIELD   49600013
OLSETBC  BC    0,OLMERGE           INITIALIZED TO BRANCH IF MERGE ONLY  50000013
         LA    RJ,4(0,RJ)          INC DISPLACEMENT FOR TREE ADDRESS    50400013
OLMERGE  STH    RJ,WOLHOLD           SET UP DISPLACEMENT                50800013
         STH   RJ,WOLHOLD            SET UP DISPLACEMENT                51200013
         STH   RJ,WOLHOLD+2          FIELDS FOR ORING                   51600013
         OC    2(4,RI),WOLHOLD     INITIALIZE DISPLACEMENTS IN CLC INST 52000013
         IC    RJ,3(0,RF)          LENGTH OF THIS CONTROL FIELD         52400013
         STC   RJ,1(0,RI)          SET LENGTH IN CLC INSTRUCTION        52800013
*                                                                       53200013
*  DETERMINE IF IT IS NECESSARY TO REVERSE THE OPERANDS OF THIS         53600013
*  COMPARE INSTRUCTION, AND REVERSE AS NECESSARY.                       54000013
*                                                                       54400013
         SR    RJ,RJ               ZERO REGISTER RJ                     54800013
         SR    RK,RK               ZERO REGISTER RK                     55200013
         IC    RJ,PPIFCF01         FORMAT AND SEQUENCE BYTE OF CF1      55600013
         IC    RK,5(0,RF)          FORMAT AND SEQUENCE BYTE OF THIS CF  56000013
         LA    RJ,4(0,RJ)            ADD 4 TO EACH BYTE                 56400013
         LA    RK,4(0,RK)            AND DIVIDE                         56800013
         SRL   RJ,2                  EACH BYTE                          57200013
         SRL   RK,2                  BY 4                               57600013
         LA    RE,17               CONSTANT 17                          58000013
         CR    RJ,RE                 IF THE                             58400013
         BNH   OLCKRK                VALUES IN                          58800013
         LR    RJ,RH                 REGISTERS                          59200013
OLCKRK   CR    RK,RE                 RK OR RJ ARE                       59600013
         BNH   OLCKIFEQ              GREATER THAN 17                    60000013
         LR    RK,RH                 SET THEM TO 1                      60400013
OLCKIFEQ NR    RJ,RH               MASK OFF ALL BUT LAST BIT            60800013
         NR    RK,RH               MASK OFF ALL BUT LAST BIT            61200013
         CR    RJ,RK               CHECK FOR EQUALS                     61600013
         BE    OLLASTCK            IF EQ THE OPERANDS IN CLC INST OK    62000013
         LH    RJ,2(0,RI)          FIRST OPERAND OF CLC INST            62400013
         LH    RK,4(0,RI)          SECOND OPERAND OF CLC INST           62800013
         STH   RJ,4(0,RI)            RESTORE THE OPERANDS               63200013
         STH   RK,2(0,RI)            IN REVERSE ORDER                   63600013
*                                                                       64000013
*  CHECK IF ALL COMPARE INSTRUCTIONS ARE INITIALIZED.                   64400013
*                                                                       64800013
OLLASTCK CR    RG,RH               CHECK IF COUNT OF CF'S IS ONE        65200013
         BE    OLSETBR             IF EQ IT IS THE LAST CONTROL FIELD   65600013
         LA    RI,8(0,RI)          INC ADDR OF CODE TO BE INIT BY 8     66000013
         B     OLNEXTCF            CONTINUE INITIALIZING THE CLC INSTS  66400013
*                                                                       66800013
*                                                                       67200013
*  INITIALIZE THE BRANCH INSTRUCTION FOLLOWING THE LAST COMPARE         67600013
*  TO AN UNCONDITIONAL BRANCH.                                          68000013
*                                                                       68400013
OLSETBR  LA    RJ,254              CONSTANT X'FE'                       68800013
         STC   RJ,7(0,RI)          FORCE AN UNCONDITIONAL BRANCH        69200013
*                                                                       69600013
*  MOVE THE INITIALIZED EQUALS ROUTINE TO ITS DESIGNATED                70000013
*  LOCATION AND RETURN TO SSC.                                          70400013
*                                                                       70800013
         L     RE,PPIAXERT         ADDRESS OF EQUALS ROUTINE            71200013
         MVC   0(88,RE),OLCF2      MOVE INITIALIZED EQ ROUT INTO POSIT  71600013
OLRETRN  SR    RP,RP               SET RETURN CODE REGISTER TO ZERO     72000013
         LM    RC,RL,0(RM)         RESET SSC REGISTERS                  72400013
         BR    RO                  RETURN TO SSC                        72800013
*                                                                       73200013
*                                                                       73600013
*                                                                       74000013
*  THE FOLLOWING CODE IS INITIALIZED AS NECESSARY BY THIS ROUTINE.      74400013
*  THE INITIALIZED CODE IS THEN MOVED TO THE LOCATION DESIGNATED        74800013
*  IN THE PPIA. THIS IS THEN USED AS THE RUNNING EQUALS ROUTINE.        75200013
*                                                                       75600013
*                                                                       76000013
OLCF2    CLC   0(1,RD),0(RC)       COMPARE SECOND CTRL FLDS OF RECDS    76400013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       76800013
OLCF3    CLC   0(1,RD),0(RC)       COMPARE THIRD CTRL FLDS OF RECDS     77200013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       77600013
OLCF4    CLC   0(1,RD),0(RC)       COMPARE FOURTH CTRL FLDS OF RECDS    78000013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       78400013
OLCF5    CLC   0(1,RD),0(RC)       COMPARE FIFTH CTRL FLDS OF RECDS     78800013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       79200013
OLCF6    CLC   0(1,RD),0(RC)       COMPARE SIXTH CTRL FLDS OF RECDS     79600013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       80000013
OLCF7    CLC   0(1,RD),0(RC)       COMPARE SEVENTH CTRL FLDS OF RECDS   80400013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       80800013
OLCF8    CLC   0(1,RD),0(RC)       COMPARE EIGTH CTRL FLDS OF RECDS     81200013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       81600013
OLCF9    CLC   0(1,RD),0(RC)       COMPARE NINTH CTRL FLDS OF RECDS     82000013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       82400013
OLCF10   CLC   0(1,RD),0(RC)       COMPARE TENTH CTRL FLDS OF RECDS     82800013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       83200013
OLCF11   CLC   0(1,RD),0(RC)       COMPARE ELEVENTH CTRL FLDS OF RECDS  83600013
         BCR   7,RO                RETURN TO NETWORK IF NOT EQUAL       84000013
OLCF12   CLC   0(1,RD),0(RC)       COMPARE TWELFTH CTRL FLDS OF RECDS   84400013
         BR    RO                  UNCONDITIONAL RETURN TO NETWORK      84800013
*                                                                       85200013
*                                                                       85600013
*  WORK AREA                                                            86000013
*                                                                       86400013
WOLHOLD  DS    1F                  USED TO CONTAIN DISPS FOR ORING      86800013
*                                                                       87200013
         EJECT                                                          87600013
         SMPPI                                                          88000013
         END                                                            88400013
