         TITLE '  IERAOM - OS/360 SORT/MERGE - 360S-SM-023 02/10/65 '   00080013
*MODULE NAME *** IERAOM ***                                             00160013
         SPACE 2                                                        00240013
*STATUS: CHANGE LEVEL 000                                               00320013
         SPACE 2                                                        00400013
*MODULE FUNCTION/OPERATION: THIS ROUTINE GENERATES THE REQUIRED EXTRACT 00480013
*   ROUTINE TO BE USED BY THE RUNNING PROGRAMS. THIS IS DONE BY         00560013
*   INITIALIZING THE CODE FOUND AT THE END OF THIS ROUTINE FOR THE      00640013
*   PROPER CONTROL FIELD AND MOVING THIS CODE TO THE LOCATION SPECIFIED 00720013
*   IN PPIA.                                                            00800013
         SPACE 2                                                        00880013
*FLOWCHART CROSS REFERENCES - EF,EG,EH,EI,EJ,EK,EL,EM                   00960013
         SPACE 2                                                        01040013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               01120013
*   N/A                                                                 01200013
         SPACE 2                                                        01280013
*LIST OF MACROS USED BY MODULE:                                         01360013
         SPACE 1                                                        01440013
*   SMPPI                                                               01520013
         SPACE 2                                                        01600013
*ENTRY POINTS:                                                          01680013
         SPACE                                                          01760013
         ENTRY IERAOM              THIS MODULE ENTRY POINT              01840013
         SPACE 2                                                        01920013
*INPUT: - PPI FIELDS AEFERENCED -                                       02000013
*   PPIPBUFF    PPIFFF      PPIPCF01                                    02080013
*   PPINUMCF    PPIAXERT                                                02160013
         SPACE 2                                                        02240013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED-                           02320013
         SPACE                                                          02400013
*   PPILEXFD                                                            02480013
*    PPILEXFF                                                           02560013
*    PPILAB01                                                           02640013
         SPACE 2                                                        02720013
*EXTERNAL ROUTINES:                                                     02800013
*    N/A                                                                02880013
         SPACE 2                                                        02960013
*EXTERNAL PARAMETERS:                                                   03040013
*    N/A                                                                03120013
         SPACE 2                                                        03200013
*EXITS-NORMAL:                                                          03280013
         SPACE                                                          03360013
*    RETURN TO SSC VIA RETURN REGISTER RO                               03440013
         SPACE 2                                                        03520013
*EXITS-ERROR:                                                           03600013
         SPACE                                                          03680013
*    N/A                                                                03760013
         SPACE 2                                                        03840013
*TABLES/WORK AREAS:                                                     03920013
         SPACE                                                          04000013
*    WOMHOLD IS USED TO CONTAIN DISP FIELD FOR ORING                    04080013
*    WOMRETNR IS USED TO SAVE REGISTER SAVE ADDRESS                     04160013
         SPACE 2                                                        04240013
*ATTRIBUTES: THIS IS A CLASS A MODULE. (READ ONLY)                      04320013
         SPACE 2                                                        04400013
*NOTES: N/A                                                             04480013
         SPACE 2                                                        04560013
         EJECT                                                          04640013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            04720013
         SPACE                                                          04800013
RA       EQU   0                     CONTENTS IN - N/A                  04880013
*                                    USED - N/A                         04960013
*                                  CONTENTS OUT - N/A                   05040013
RB       EQU   1                     CONTENTS IN - N/A                  05120013
*                                    USED - N/A                         05200013
*                                  CONTENTS OUT - N/A                   05280013
RC       EQU   2                     CONTENTS IN - N/A                  05360013
*                                    USED - WORK REGISTER               05440013
*                                  CONTENTS OUT - N/A                   05520013
RD       EQU   3                     CONTENTS IN - N/A                  05600013
*                                    USED - WORK REGISTER               05680013
*                                  CONTENTS OUT - N/A                   05760013
RE       EQU   4                     CONTENTS IN - N/A                  05840013
*                                    USED - WORK REGISTER               05920013
*                                  CONTENTS OUT - N/A                   06000013
RF       EQU   5                     CONTENTS IN - N/A                  06080013
*                                    USED - DISPLACEMENT IN EXTRACT RTN 06160013
*                                  CONTENTS OUT - N/A                   06240013
RG       EQU   6                     CONTENTS IN - N/A                  06320013
*                                    USED - DISPLACEMENT OF PACKING     06400013
*                                         - BUFFER IN EXTRACT ROUTINE   06480013
*                                  CONTENTS OUT - N/A                   06560013
RH       EQU   7                     CONTENTS IN - N/A                  06640013
*                                    USED - DISPLACEMENT OF CONSTANTS   06720013
*                                         - OF F'S IN EXTRACT ROUTINE   06800013
*                                  CONTENTS OUT - N/A                   06880013
RI       EQU   8                     CONTENTS IN - N/A                  06960013
*                                    USED -ADDRESS OF CONTROL FIELD     07040013
*                                         -DATA IN PPIA                 07120013
*                                  CONTENTS OUT - N/A                   07200013
RJ       EQU   9                     CONTENTS IN - N/A                  07280013
*                                    USED - NUMBER OF CONTROL FIELDS    07360013
*                                  CONTENTS OUT - N/A                   07440013
RK       EQU   10                    CONTENTS IN - N/A                  07520013
*                                    USED - DISP IN THE EXT PORTION     07600013
*                                  CONTENTS OUT - N/A                   07680013
RL       EQU   11                    CONTENTS IN - N/A                  07760013
*                                    USED - PROGRAM BASE REGISTER       07840013
*                                  CONTENTS OUT - N/A                   07920013
RM       EQU   12                    CONTENTS IN - ADDR REG SAVE AREA   08000013
*                                    USED - ADDR EXTRACT ROUTINE        08080013
*                                  CONTENTS OUT -  ADDR REG SAVE AREA   08160013
RN       EQU   13                    CONTENTS IN - ADDRESS OF PPIA      08240013
*                                    USED - ADDRESS OF PPIA             08320013
*                                  CONTENTS OUT - ADDRESS OF PPIA       08400013
RO       EQU   14                    CONTENTS IN - SSC RETURN ADDRESS   08480013
*                                    USED - SSC RETURN REGISTER         08560013
*                                  CONTENTS OUT - SSC RETURN ADDRESS    08640013
RP       EQU   15                    CONTENTS IN - ADDRESS OF ROUTINE   08720013
*                                    USED - SSC RETURN CODE REGISTER    08800013
*                                  CONTENTS OUT - SSC RETURN CODE       08880013
*                                                                       08960013
IERAOM   CSECT                                                          09040013
*1590679200,733600                                                 6155 09080016
         USING *,RP                                                     09120013
         STM   RC,RL,0(RM)         SAVE SSC REGISTERS                   09200013
         BALR  RL,0                                                     09280013
         USING *,RL                                                     09360013
         DROP  RP                                                       09440013
         USING IERRCA,RN                                                09520013
         ST    RM,WOMRETNR         SAVE REGISTER SAVE ADDRESS           09600013
*                                                                       09680013
* SET UP NECESSARY REGISTERS FOR INITIALIZING THE CODE FOR THE EXTRACT  09760013
* ROUTINE, AND GENERATE THE CONSTANT OF F'S IN THE EXTRACT ROUTINE.     09840013
*                                                                       09920013
         L     RG,PPIPBUFF         DISP TO PACKING BUFFER IN EXT ROUT   10000013
         L     RH,PPIFFF           DISP TO CONSTANT IN EXTRACT ROUTINE  10080013
         LH    RJ,PPINUMCF                                              10160013
         CH    RJ,K12              MORE THAN 12 CONTROL FIELDS          10240013
         BC    2,OM002             YES - BRANCH                         10320013
         SPACE 1                                                        10400013
         LA    RI,PPIPCF01         ADDRESS OF CONTROL FIELD DATA        10480013
OM001    L     RM,PPIAXERT         ADDRESS OF EXTRACT ROUTINE           10560013
         LR    RE,RG               DISPLACEMENT OF PACKING BUFFER       10640013
         SR    RE,RH               DISP OF CONSTANT ' RESULT EQ LENGTH  10720013
         LTR   RE,RE               TEST REGISTER                        10800013
         BZ    OMBYPASS            NO CONSTANT NEEDED IF ZERO           10880013
         LA    RD,255              CONSTANT X'FF'                       10960013
         LR    RC,RM               ADDRESS OF EXTRACT ROUTINE           11040013
         AR    RC,RH               DISP OF CONSTANT ' RESULT EQ START   11120013
OMSTOFF  STC   RD,0(0,RC)          STORE A BYTE OF THE CONSTANT         11200013
         LA    RC,1(0,RC)          INCREMENT ADDRESS OF CONSTANT        11280013
         BCT   RE,OMSTOFF          IF COUNT NOT ZERO STORE ANOTHER BYTE 11360013
OMBYPASS LA    RM,4(0,RM)          INC FOR SPACE FOR ADDR OF USER ROUT  11440013
         LA    RK,4                DISPLACEMENT IN EXTRACTED PORTION    11520013
         LR    RF,RK               DISPLACEMENT IN EXTRACT ROUTINE      11600013
*                                                                       11680013
* THROUGH THE COMBINATION OF THE IDENTIFICATION  BYTE AND THE FOLLOWING 11760013
* BRANCH TABLE AN INDEXED BRANCH IS PERFORMED WHICH BRANCHES TO THE     11840013
* CASE WHICH INITIALIZES THE CODE FOR THE CONTROL FIELD IDENTIFIED.     11920013
*                                                                       12000013
OMNOLAST LA    RE,OMBTABLE         ADDRESS OF BRANCH TABLE              12080013
         LA    RB,LONGINIT              LOAD BASEREGISTER               12100018
         USING OMCASE7L,RB                                              12120018
         SR    RD,RD               ZERO REGISTER                        12160013
         IC    RD,5(0,RI)          FORMAT AND SEQUENCE BYTE OF THIS CF  12240013
         B     0(RD,RE)            BRANCH TO PROPER CASE THRU TABLE     12320013
         SPACE 2                                                        12400013
OM002    L     RI,PPIADDCF         ADDRESS OF CONTROL FIELD DAT - GR 12 12480013
         B     OM001                                                    12560013
*                                                                       12640013
* BRANCH TABLE                                                          12720013
*                                                                       12800013
OMBTABLE B     OMCASE1                                                  12880013
         B     OMCASE2                                                  12960013
         B     OMCASE3                                                  13040013
         B     OMCASE4                                                  13120013
         B     OMCASE5                                                  13200013
         B     OMCASE6                                                  13280013
         B     OMCASE7                                                  13360013
         B     OMCASE8                                                  13440013
         B     OMCASE9                                                  13520013
         B     OMCASE10                                                 13600013
         B     OMCASE11                                                 13680013
         B     OMCASE12                                                 13760013
         B     OMCASE13                                                 13840013
         B     OMCASE14                                                 13920013
         B     OMCASE15                                                 14000013
         B     OMCASE16                                                 14080013
         B     OMCASE17                                                 14160013
         B     OMCASE17                                                 14240013
         B     OMCASE17                                                 14320013
         B     OMCASE17                                                 14400013
         B     OMCASE17                                                 14480013
         B     OMCASE17                                                 14560013
         B     OMCASE17                                                 14640013
         B     OMCASE24                                                 14720013
*                                                                       14800013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT ALPHAMERIC OR           14880013
* UNSIGNED BINARY BYTE FIELDS WHICH ARE ASCENDING.                      14960013
*                                                                       15040013
OMCASE1  NC    OMAOUBBA+2(4),KOMZERO ZERO D FIELDS IN CODE TO BE INIT   15120013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           15200013
         OC    OMAOUBBA(4),WOMHOLD SET DISP OF 1ST OP IN MOVE INST      15280013
         MVC   OMAOUBBA+1(1),3(RI) SET LENGTH IN MOVE INSTRUCTION       15360013
         OC    OMAOUBBA+4(2),0(RI) SET DISP OF 2ND OP IN MOVE INST      15440013
         MVC   0(6,RM),OMAOUBBA    MOVE SEGMENT TO EXTRACT ROUTINE      15520013
         LA    RM,6(0,RM)          INCREMENT ADDRESS OF EXTRACT ROUTINE 15600013
         LA    RF,6(0,RF)          INCREMENT DISPLACEMENT IN EXT ROUT   15680013
         B     OMISITND                                                 15760013
*                                                                       15840013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT ALPHAMERIC OR           15920013
* UNSIGNED BINARY BYTE FIELDS WHICH ARE DECENDING.                      16000013
*                                                                       16080013
OMCASE2  NC    OMAOUBBD+2(4),KOMZERO ZERO DISPLACEMENT FIELDS           16160013
         NC    OMAOUBBD+8(4),KOMZERO IN CODE TO BE INITIALIZED          16240013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           16320013
         OC    OMAOUBBD(4),WOMHOLD SET DISP OF 1ST OP IN MOVE INST      16400013
         MVC   OMAOUBBD+1(1),3(RI) SET LENGTH IN MOVE INSTRUCTION       16480013
         OC    OMAOUBBD+4(2),0(RI) SET DISP OF 2ND OP IN MOVE INST      16560013
         OC    OMAOUBBD+6(4),WOMHOLD SET DISP OF 1ST OP IN XC INST      16640013
         MVC   OMAOUBBD+7(1),3(RI) SET LENGTH IN XC INSTRUCTION         16720013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 16800013
         OC    OMAOUBBD+8(4),WOMHOLD SET DISP OF 2ND OP IN XC INST      16880013
         MVC   0(12,RM),OMAOUBBD   MOVE SEGMENT TO EXTRACT ROUTINE      16960013
         LA    RM,12(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 17040013
         LA    RF,12(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   17120013
         B     OMISITND                                                 17200013
*                                                                       17280013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT NORMALIZED              17360013
* FLOATING POINT FIELDS WHICH ARE ASCENDING                             17440013
*                                                                       17520013
OMCASE3  NC    OMFLPTA+2(4),KOMZERO  ZERO DISPLACEMENT                  17600013
         NC    OMFLPTA+8(2),KOMZERO  FIELDS IN                          17680013
         NC    OMFLPTA+12(2),KOMZERO CODE TO BE                         17760013
         NC    OMFLPTA+16(4),KOMZERO INITIALIZED                        17840013
         NC    OMFLPTA+22(2),KOMZERO                                    17920013
         NC    OMFLPTA+26(2),KOMZERO                                    18000013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           18080013
         OC    OMFLPTA(4),WOMHOLD  SET DISP OF 1ST OP IN MOVE INST      18160013
         MVC   OMFLPTA+1(1),3(RI)  SET LENGTH IN MOVE INSTRUCTION       18240013
         OC    OMFLPTA+4(2),0(RI)  SET DISP OF 2ND OP IN MOVE INST      18320013
         OC    OMFLPTA+8(2),0(RI)  SET DISP IN TM INSTRUCTION           18400013
         OC    OMFLPTA+14(4),WOMHOLD SET DISP OF 1ST OP IN XC INST      18480013
         OC    OMFLPTA+24(4),WOMHOLD SET DISP IN XI INSTRUCTION         18560013
         MVC   OMFLPTA+15(1),3(RI) SET LENGTH IN XC INSTRUCTION         18640013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 18720013
         OC    OMFLPTA+16(4),WOMHOLD SET DISP OF 2ND OP IN XC INST      18800013
         LA    RE,24(0,RF)         INC DISP IN EXTRACT ROUTINE          18880013
         ST    RE,WOMHOLD          DISP IN RUNNING EXTRACT FOR BRANCH   18960013
         OC    OMFLPTA+10(4),WOMHOLD SET DISP IN BZ INSTRUCTION         19040013
         LA    RE,4(0,RE)          INC BY 4 BYTES                       19120013
         ST    RE,WOMHOLD          DISP IN RUNNING EXTRACT FOR BRANCH   19200013
         OC    OMFLPTA+20(4),WOMHOLD SET DISP IN BRANCH INSTRUCTION     19280013
         MVC   0(28,RM),OMFLPTA    MOVE SEGMENT TO EXTRACT ROUTINE      19360013
         LA    RM,28(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 19440013
         LA    RF,28(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   19520013
         B     OMISITND                                                 19600013
*                                                                       19680013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT NORMALIZED              19760013
* FLOATING POINT FIELDS WHICH ARE DECENDING                             19840013
*                                                                       19920013
OMCASE4  NC    OMFLPTD+2(4),KOMZERO  ZERO DISPLACEMENT                  20000013
         NC    OMFLPTD+8(2),KOMZERO  FIELDS IN                          20080013
         NC    OMFLPTD+12(2),KOMZERO CODE TO BE                         20160013
         NC    OMFLPTD+16(2),KOMZERO INITIALIZED                        20240013
         NC    OMFLPTD+20(2),KOMZERO                                    20320013
         NC    OMFLPTD+24(4),KOMZERO                                    20400013
         MVI   OMFLPTD+19,X'00'    SET CONDITIONAL BRANCH TO A NO-OP    20480013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           20560013
         OC    OMFLPTD(4),WOMHOLD  SET DISP OF 1ST OP IN MOVE INST      20640013
         MVC   OMFLPTD+1(1),3(RI)  SET LENGTH IN MOVE INSTRUCTION       20720013
         OC    OMFLPTD+4(2),0(RI)  SET DISP OF 2ND OP IN MOVE INST      20800013
         OC    OMFLPTD+8(2),0(RI)  SET DISP IN TM INSTRUCTION           20880013
         OC    OMFLPTD+14(4),WOMHOLD SET DISP IN XI INSTRUCTION         20960013
         LA    RE,1(0,RK)          INC BY 1 IN EXTRACTED PORTION        21040013
         ST    RE,WOMHOLD          DISP FOR D1 FIELD IN XC INST         21120013
         OC    OMFLPTD+22(4),WOMHOLD SET DISP OF 1ST OP IN XC INST      21200013
         LA    RD,1                CONSTANT  OF 1                       21280013
         IC    RE,3(0,RI)          LENGTH OF CONTROL FIELD              21360013
         SR    RE,RD               DECREMENT LENGTH BY 1                21440013
         STC   RE,OMFLPTD+23       SET LENGTH FIELD IN XC INST          21520013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 21600013
         OC    OMFLPTD+24(4),WOMHOLD SET DISP OF 2ND OP IN XC INST      21680013
         LA    RE,28(0,RF)         INC DISP IN EXTRACT RTN              21760013
         ST    RE,WOMHOLD          DISP IN RUNNING EXTRACT FOR BRANCH   21840013
         OC    OMFLPTD+10(4),WOMHOLD SET DISP IN BO INSTRUCTION         21920013
         LA    RE,28(0,RF)         INC DISPLACEMENT IN EXTRACT ROUTINE  22000013
         ST    RE,WOMHOLD          DISP FOR BC INSTRUCTION              22080013
         OC    OMFLPTD+18(4),WOMHOLD SET D2 FIELD IN BC INST            22160013
         CLI   3(RI),X'00'         TEST CONTROL FIELD LENGTH FOR 1 BYTE 22240013
         BNE   *+8                                                      22320013
         MVI   OMFLPTD+19,X'F0'    SET BC INSTRUCTION TO BRANCH         22400013
         MVC   0(28,RM),OMFLPTD    MOVE SEGMENT TO EXTRACT ROUTINE      22480013
         LA    RM,28(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 22560013
         LA    RF,28(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   22640013
         B     OMISITND                                                 22720013
*                                                                       22800013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SIGNED BINARY           22880013
* BYTE FIELDS WHICH ARE ASCENDING.                                      22960013
*                                                                       23040013
OMCASE5  NC    OMSBBA+2(4),KOMZERO  ZERO DISPLACEMENT FIELDS IN         23120013
         NC    OMSBBA+8(2),KOMZERO  CODE TO BE INITIALIZED              23200013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           23280013
         OC    OMSBBA(4),WOMHOLD   SET DISP OF 1ST OP IN MOVE INST      23360013
         MVC   OMSBBA+1(1),3(RI)   SET LENGTH IN MOVE INSTRUCTION       23440013
         OC    OMSBBA+4(2),0(RI)   SET DISP OF 2ND OP IN MOVE INST      23520013
         OC    OMSBBA+6(4),WOMHOLD SET DISP IN XI INSTRUCTION           23600013
         MVC   0(10,RM),OMSBBA     MOVE SEGMENT TO EXTRACT ROUTINE      23680013
         LA    RM,10(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 23760013
         LA    RF,10(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   23840013
         B     OMISITND                                                 23920013
*                                                                       24000013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SIGNED BINARY           24080013
* BYTE FIELDS WHICH ARE DECENDING.                                      24160013
*                                                                       24240013
OMCASE6  NC    OMSBBD+2(4),KOMZERO  ZERO DISPLACEMENT                   24320013
         NC    OMSBBD+8(2),KOMZERO  FIELDS IN CODE                      24400013
         NC    OMSBBD+12(2),KOMZERO TO BE INITIALIZED                   24480013
         NC    OMSBBD+16(4),KOMZERO                                     24560013
         MVI   OMSBBD+11,X'00'     SET CONDITIONAL BRANCH TO A NO-OP    24640013
         ST    RK,WOMHOLD          DISPLACEMENT OF TO ADDRESS           24720013
         OC    OMSBBD(4),WOMHOLD   SET DISP OF 1ST OP IN MOVE INST      24800013
         MVC   OMSBBD+1(1),3(RI)   SET LENGTH IN MOVE INSTRUCTION       24880013
         OC    OMSBBD+4(2),0(RI)   SET DISP OF 2ND OP IN MOVE INST      24960013
         OC    OMSBBD+6(4),WOMHOLD SET DISP IN XI INSTRUCTION           25040013
         LA    RE,1(0,RK)          INC BY 1 IN EXTRACTED PORTION        25120013
         ST    RE,WOMHOLD          DISP FOR D1 FIELD IN XC INST         25200013
         OC    OMSBBD+14(4),WOMHOLD SET DISP OF 1ST OP IN XC INST       25280013
         LA    RD,1                CONSTANT  OF 1                       25360013
         IC    RE,3(0,RI)          LENGTH OF CONTROL FIELD              25440013
         SR    RE,RD               DECREMENT LENGTH BY 1                25520013
         STC   RE,OMSBBD+15        SET LENGTH FIELD IN XC INST          25600013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 25680013
         OC    OMSBBD+16(4),WOMHOLD SET DISP OF 2ND OP IN XC INST       25760013
         LA    RE,20(0,RF)         INC DISP IN EXTRACT ROUTINE          25840013
         ST    RE,WOMHOLD          DISP FOR BC INSTRUCTION              25920013
         OC    OMSBBD+10(4),WOMHOLD SET D2 FIELD IN BC INST             26000013
         CLI   3(RI),X'00'         TEST CONTROL FIELD LENGTH FOR 1 BYTE 26080013
         BNE   *+8                                                      26160013
         MVI   OMSBBD+11,X'F0'     SET BC INSTRUCTION TO BRANCH         26240013
         MVC   0(20,RM),OMSBBD     MOVE SEGMENT TO EXTRACT ROUTINE      26320013
         LA    RM,20(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 26400013
         LA    RF,20(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   26480013
         B     OMISITND                                                 26560013
*                                                                       26640013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT MULTI-BYTE              26720013
* UNPACKED DECIMAL FIELDS WHICH ARE ASCENDING.                          26800013
*                                                                       26880013
OMCASE7  CLI   3(RI),X'0F'              MORE THAN 16 BYTES              26920018
         BH    OMCASE7L                 BRANCH IF YES                   26960018
         NC    OMUDMBA+2(4),KOMZERO  ZERO DISPLACEMENT                  27000018
         NC    OMUDMBA+8(4),KOMZERO  FIELDS IN                          27040013
         NC    OMUDMBA+14(4),KOMZERO CODE TO BE                         27120013
         NC    OMUDMBA+20(2),KOMZERO INITIALIZED                        27200013
         NC    OMUDMBA+24(2),KOMZERO                                    27280013
         NC    OMUDMBA1+2(2),KOMZERO                                    27360013
         NC    OMUDMBA1+6(2),KOMZERO                                    27440013
         NC    OMUDMBA1+10(2),KOMZERO                                   27520013
         NC    OMUDMBA1+14(4),KOMZERO                                   27600013
         NC    OMUDMBA1+20(2),KOMZERO                                   27680013
         NC    OMUDMBA1+24(2),KOMZERO                                   27760013
         SR    RD,RD               ZERO REGISTER                        27840013
         IC    RD,3(0,RI)          BYTE PORTION OF LENGTH OF THIS CF    27920013
         LA    RE,1(0,RD)          INC FIELD BY ONE FOR ROUNDING        28000013
         SRL   RE,1                DIVIDE BY 2                          28080013
         LR    RC,RE               SAVE LENGTH OF L1 FIELD              28160013
         SLL   RE,4                MOVE TO POSITION FOR L1 FIELD        28240013
         OR    RE,RD               COMBINE L1 AND L2  FIELD IN ONE BYTE 28320013
         STC   RE,OMUDMBA+1        SET LENGTH FIELDS IN PACK INST       28400013
         LA    RE,9(0,RG)          DISPLACEMENT TO END OF PACKING BUFF  28480013
         SR    RE,RC               SUB REAL LENGTH OF FIELD LESS ONE    28560013
         LA    RD,1                CONSTANT OF 1                        28640013
         SR    RE,RD               DECREMENT TO DISP BY ONE             28720013
         ST    RE,WOMHOLD          DISP OF 1 ST OPERAND                 28800013
         OC    OMUDMBA(4),WOMHOLD  SET D1 FIELD IN PACK INST            28880013
         OC    OMUDMBA+4(2),0(RI)  SET D2 FIELD IN PACK INST            28960013
         OC    OMUDMBA+14(4),WOMHOLD SET D2 FIELD IN MVO INST           29040013
         LA    RE,0(RC,RK)         DISP TO LAST BYTE IN TO LOCATION     29120013
         ST    RE,WOMHOLD          DISP OF 1 ST OPERAND IN UNPACK INSTR 29200013
         OC    OMUDMBA+6(4),WOMHOLD SET D1 FIELD IN UNPACK INST         29280013
         LA    RE,8(0,RG)          DISP TO SIGN BYTE                    29360013
         ST    RE,WOMHOLD          DISP OF 2 ND OPERAND OF UNPACK INSTR 29440013
         OC    OMUDMBA+8(4),WOMHOLD SET D2 FIELD IN UNPACK INST         29520013
         OC    OMUDMBA+18(4),WOMHOLD SET D1 FIELD IN FIRST TM INST      29600013
         OC    OMUDMBA1(4),WOMHOLD SET D1 FIELD IN SECOND TM INST       29680013
         ST    RK,WOMHOLD          DISP OF 1 ST OPERAND IN MVO INST     29760013
         OC    OMUDMBA+12(4),WOMHOLD SET D1 FIELD IN MVO INST           29840013
         LR    RE,RC               L1 FIELD                             29920013
         LA    RD,1                CONSTANT OF 1                        30000013
         SR    RE,RD               CALC L2 FIELD FOR MVO INST           30080013
         STC   RE,OMUDMBA1+13      SET LENGTH FIELD IN XC INST          30160013
         SLL   RC,4                MOVE TO POSITION FOR L1 FIELD        30240013
         OR    RE,RC               COMBINE L1 AND L2 FIELD INTO 1 BYTE  30320013
         STC   RE,OMUDMBA+13       SET LENGTH FIELDS IN MVO INST        30400013
         OC    OMUDMBA1+8(4),WOMHOLD SET D1 FIELD IN XI INST            30480013
         OC    OMUDMBA1+22(4),WOMHOLD SET D1 FIELD IN OI INST           30560013
         LA    RE,1(0,RK)          INC BY 1 IN EXTRACTED PORTION        30640013
         ST    RE,WOMHOLD          STORE DISP                           30720013
         OC    OMUDMBA1+12(4),WOMHOLD SET D1 FIELD IN XC INST           30800013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 30880013
         OC    OMUDMBA1+14(4),WOMHOLD SET D2 FIELD IN XC INST           30960013
         LA    RE,48(0,RF)         INC DISP IN EXTRACT ROUTINE          31040013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      31120013
         OC    OMUDMBA+22(4),WOMHOLD SET D2 FIELD IN BZ INST            31200013
         OC    OMUDMBA1+4(4),WOMHOLD SET D2 FIELD IN BO INST            31280013
         LA    RE,4(0,RE)          INCREMENT BY 4 BYTES                 31360013
         ST    RE,WOMHOLD          DISP FOR BRANCH INSTRUCTION          31440013
         OC    OMUDMBA1+18(4),WOMHOLD SET D2 FIELD IN BRANCH INST       31520013
         MVC   0(52,RM),OMUDMBA    MOVE SEGMENT TO EXTRACT ROUTINE      31600013
         LA    RF,52(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   31680013
         LA    RM,52(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 31760013
         B     OMISITND                                                 31840013
*                                                                       31920013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT MULTI-BYTE              32000013
* UNPACKED DECIMAL FIELDS WHICH ARE DECENDING.                          32080013
*                                                                       32160013
OMCASE8  CLI   3(RI),X'0F'              MORE THAN 16 BYTES              32200018
         BH    OMCASE8L                 BRANCH IF YES                   32240018
         NC    OMUDMBD+2(4),KOMZERO  ZERO DISPLACEMENT                  32280018
         NC    OMUDMBD+8(4),KOMZERO  FIELDS IN                          32320013
         NC    OMUDMBD+14(4),KOMZERO CODE TO BE                         32400013
         NC    OMUDMBD+20(2),KOMZERO INITIALIZED                        32480013
         NC    OMUDMBD+24(2),KOMZERO                                    32560013
         NC    OMUDMBD1+2(2),KOMZERO                                    32640013
         NC    OMUDMBD1+6(2),KOMZERO                                    32720013
         NC    OMUDMBD1+10(2),KOMZERO                                   32800013
         NC    OMUDMBD1+14(2),KOMZERO                                   32880013
         NC    OMUDMBD1+18(2),KOMZERO                                   32960013
         NC    OMUDMBD1+22(4),KOMZERO                                   33040013
         SR    RD,RD               ZERO REGISTER                        33120013
         IC    RD,3(0,RI)          BYTE PORTION OF LENGTH OF THIS CF    33200013
         LA    RE,1(0,RD)          INC FIELD BY ONE FOR ROUNDING        33280013
         SRL   RE,1                DIVIDE BY 2                          33360013
         LR    RC,RE               SAVE LENGTH OF L1 FIELD              33440013
         SLL   RE,4                MOVE TO POSITION FOR L1 FIELD        33520013
         OR    RE,RD               COMBINE L1 AND L2  FIELD IN ONE BYTE 33600013
         STC   RE,OMUDMBD+1        SET LENGTH FIELDS IN PACK INST       33680013
         LA    RE,9(0,RG)          DISPLACEMENT TO END OF PACKING BUFF  33760013
         SR    RE,RC               SUB REAL LENGTH OF FIELD LESS ONE    33840013
         LA    RD,1                CONSTANT OF 1                        33920013
         SR    RE,RD               DECREMENT TO DISP BY ONE             34000013
         ST    RE,WOMHOLD          DISP OF 1 ST OPERAND                 34080013
         OC    OMUDMBD(4),WOMHOLD  SET D1 FIELD IN PACK INST            34160013
         OC    OMUDMBD+4(2),0(RI)  SET D2 FIELD IN PACK INST            34240013
         OC    OMUDMBD+14(4),WOMHOLD SET D2 FIELD IN MVO INST           34320013
         LA    RE,0(RC,RK)         DISP TO LAST BYTE IN TO LOCATION     34400013
         ST    RE,WOMHOLD          DISP OF 1 ST OPERAND IN UNPACK INSTR 34480013
         OC    OMUDMBD+6(4),WOMHOLD SET D1 FIELD IN UNPACK INST         34560013
         LA    RE,8(0,RG)          DISP TO SIGN BYTE                    34640013
         ST    RE,WOMHOLD          DISP OF 2 ND OPERAND OF UNPACK INSTR 34720013
         OC    OMUDMBD+8(4),WOMHOLD SET D2 FIELD IN UNPACK INST         34800013
         OC    OMUDMBD+18(4),WOMHOLD SET D1 FIELD IN FIRST TM INST      34880013
         OC    OMUDMBD1(4),WOMHOLD SET D1 FIELD IN SECOND TM INST       34960013
         ST    RK,WOMHOLD          DISP OF 1 ST OPERAND IN MVO INST     35040013
         OC    OMUDMBD+12(4),WOMHOLD SET D1 FIELD IN MVO INST           35120013
         LR    RE,RC               L1 FIELD                             35200013
         LA    RD,1                CONSTANT OF 1                        35280013
         SR    RE,RD               CALC L2 FIELD FOR MVO INST           35360013
         STC   RE,OMUDMBD1+21      SET LENGTH FIELD IN XC INST          35440013
         SLL   RC,4                MOVE TO POSITION FOR L1 FIELD        35520013
         OR    RE,RC               COMBINE L1 AND L2 FIELD INTO 1 BYTE  35600013
         STC   RE,OMUDMBD+13       SET LENGTH FIELDS IN MVO INST        35680013
         OC    OMUDMBD1+16(4),WOMHOLD SET D1 FIELD IN XI INST           35760013
         OC    OMUDMBD1+8(4),WOMHOLD SET D1 FIELD IN OI INST            35840013
         LA    RE,1(0,RK)          INC BY 1 IN EXTRACTED PORTION        35920013
         ST    RE,WOMHOLD          STORE DISP                           36000013
         OC    OMUDMBD1+20(4),WOMHOLD SET D1 FIELD IN XC INST           36080013
         ST    RH,WOMHOLD          DISP IN RUNNING EXT OF STRING OF F'S 36160013
         OC    OMUDMBD1+22(4),WOMHOLD SET D2 FIELD IN XC INST           36240013
         LA    RE,42(0,RF)         INC DISP IN EXTRACT ROUTINE          36320013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      36400013
         OC    OMUDMBD+22(4),WOMHOLD SET D2 FIELD IN BZ INST            36480013
         OC    OMUDMBD1+4(4),WOMHOLD SET D2 FIELD IN BO INST            36560013
         LA    RE,10(0,RE)         INCREMENT BY 10 BYTES                36640013
         ST    RE,WOMHOLD          DISP FOR BRANCH INSTRUCTION          36720013
         OC    OMUDMBD1+12(4),WOMHOLD SET D2 FIELD IN BRANCH INST       36800013
         MVC   0(52,RM),OMUDMBD    MOVE SEGMENT TO EXTRACT ROUTINE      36880013
         LA    RM,52(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 36960013
         LA    RF,52(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   37040013
         B     OMISITND                                                 37120013
*                                                                       37200013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT MULTI-BYTE              37280013
* PACKED DECIMAL FIELDS WHICH ARE ASCENDING                             37360013
*                                                                       37440013
OMCASE9  NC    OMPDMBA+2(4),KOMZERO  ZERO DISPLACEMENT                  37520013
         NC    OMPDMBA+8(4),KOMZERO  FIELDS IN                          37600013
         NC    OMPDMBA+14(2),KOMZERO CODE TO BE                         37680013
         NC    OMPDMBA+18(2),KOMZERO INITIALIZED                        37760013
         NC    OMPDMBA+22(2),KOMZERO                                    37840013
         NC    OMPDMBA1+2(2),KOMZERO                                    37920013
         NC    OMPDMBA1+6(2),KOMZERO                                    38000013
         NC    OMPDMBA1+10(4),KOMZERO                                   38080013
         NC    OMPDMBA1+16(2),KOMZERO                                   38160013
         NC    OMPDMBA1+20(2),KOMZERO                                   38240013
         SR    RE,RE               ZERO REGISTER                        38320013
         IC    RE,3(0,RI)          BYTE PORTION OF LENGTH OF THIS CF    38400013
         LR    RD,RE               SAVE LENGTH OF THIS CF               38480013
         AH    RE,0(0,RI)          DISPLACEMENT OF THIS CF              38560013
         ST    RE,WOMHOLD          DISPLACEMENT OF SIGN BYTE OF THIS CF 38640013
         OC    OMPDMBA+2(4),WOMHOLD SET D2 FIELD OF UNPACK INST         38720013
         OC    OMPDMBA+12(4),WOMHOLD SET D1 FIELD OF FIRST TM INST      38800013
         OC    OMPDMBA+20(4),WOMHOLD SET D1 FIELD OF SECOND TM INST     38880013
         OC    OMPDMBA+10(2),0(RI) SET D2 FIELD OF MVO INST             38960013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    39040013
         OC    OMPDMBA+6(4),WOMHOLD SET D1 FIELD IN MVO INST            39120013
         OC    OMPDMBA1+4(4),WOMHOLD SET D1 FIELD IN XI INST            39200013
         OC    OMPDMBA1+18(4),WOMHOLD SET D1 FIELD IN OI INST           39280013
         LA    RE,1(0,RK)          DISP IN EXTRACTED PORTION PLUS 1     39360013
         ST    RE,WOMHOLD          STORE DISPLACEMENT                   39440013
         OC    OMPDMBA1+8(4),WOMHOLD SET D1 FIELD IN XC INST            39520013
         LR    RE,RD               LENGTH OF CF                         39600013
         AR    RE,RK               DISP IN EXTRACTED PORTION            39680013
         ST    RE,WOMHOLD          DISPLACEMENT TO SIGN BYTE            39760013
         OC    OMPDMBA(4),WOMHOLD  SET D1 FIELD IN UNPACK INST          39840013
         LA    RC,1                CONSTANT OF 1                        39920013
         LR    RE,RD               LENGTH OF CF                         40000013
         SR    RE,RC               DECREMENT BY ONE                     40080013
         STC   RE,OMPDMBA1+9       SET LENGTH FIELD IN XC INST          40160013
         SLL   RD,4                PREPARE L1 FIELD FOR MVO INST        40240013
         OR    RE,RD               COMBINE LI AND L2 FIELDS             40320013
         STC   RE,OMPDMBA+7        SET LENGTH FIELDS IN MVO INST        40400013
         ST    RH,WOMHOLD          DISPLACEMENT TO CONSTANT OF F'S      40480013
         OC    OMPDMBA1+10(4),WOMHOLD SET D2 FIELD IN XC INST           40560013
         LA    RE,42(0,RF)         INC DISP IN EXTRACT ROUTINE          40640013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      40720013
         OC    OMPDMBA+16(4),WOMHOLD SET D2 FIELD IN BZ INST            40800013
         OC    OMPDMBA1(4),WOMHOLD SET D2 FIELD IN BO INST              40880013
         LA    RE,4(0,RE)          INC DISPLACEMENT BY 4                40960013
         ST    RE,WOMHOLD          DISP FOR BRANCH INST                 41040013
         OC    OMPDMBA1+14(4),WOMHOLD SET D2 FIELD IN BRANCH INST       41120013
         MVC   0(46,RM),OMPDMBA    MOVE SEGMENT TO EXTRACT ROUTINE      41200013
         LA    RM,46(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 41280013
         LA    RF,46(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   41360013
         B     OMISITND                                                 41440013
*                                                                       41520013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT MULTI-BYTE              41600013
* PACKED DECIMAL FIELDS WHICH ARE DECENDING.                            41680013
*                                                                       41760013
OMCASE10 NC    OMPDMBD+2(4),KOMZERO  ZERO DISPLACEMENT                  41840013
         NC    OMPDMBD+8(4),KOMZERO  FIELDS IN                          41920013
         NC    OMPDMBD+14(2),KOMZERO CODE TO BE                         42000013
         NC    OMPDMBD+18(2),KOMZERO INITIALIZED                        42080013
         NC    OMPDMBD+22(2),KOMZERO                                    42160013
         NC    OMPDMBD1+2(2),KOMZERO                                    42240013
         NC    OMPDMBD1+6(2),KOMZERO                                    42320013
         NC    OMPDMBD1+10(2),KOMZERO                                   42400013
         NC    OMPDMBD1+14(2),KOMZERO                                   42480013
         NC    OMPDMBD1+18(4),KOMZERO                                   42560013
         SR    RE,RE               ZERO REGISTER                        42640013
         IC    RE,3(0,RI)          BYTE PORTION OF LENGTH OF THIS CF    42720013
         LR    RD,RE               SAVE LENGTH OF THIS CF               42800013
         AH    RE,0(0,RI)          DISPLACEMENT OF THIS CF              42880013
         ST    RE,WOMHOLD          DISPLACEMENT TO SIGN BYTE OF THIS CF 42960013
         OC    OMPDMBD+2(4),WOMHOLD SET D2 FIELD OF UNPACK INST         43040013
         OC    OMPDMBD+12(4),WOMHOLD SET D1 FIELD OF FIRST TM INST      43120013
         OC    OMPDMBD+20(4),WOMHOLD SET D1 FIELD OF SECOND TM INST     43200013
         OC    OMPDMBD+10(2),0(RI) SET D2 FIELD IN MVO INST             43280013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    43360013
         OC    OMPDMBD+6(4),WOMHOLD SET D1 FIELD IN MVO INST            43440013
         OC    OMPDMBD1+12(4),WOMHOLD SET D1 FIELD IN XI INST           43520013
         OC    OMPDMBD1+4(4),WOMHOLD SET D1 FIELD IN OI INST            43600013
         LA    RE,1(0,RK)          DISP IN EXTRACTED PORTION PLUS 1     43680013
         ST    RE,WOMHOLD          STORE DISPLACEMENT                   43760013
         OC    OMPDMBD1+16(4),WOMHOLD SET D1 FIELD IN XC INST           43840013
         LR    RE,RD               LENGTH OF CONTROL FIELD              43920013
         AR    RE,RK               DISP IN EXTRACTED PORTION            44000013
         ST    RE,WOMHOLD          DISPLACEMENT TO SIGN BYTE            44080013
         OC    OMPDMBD(4),WOMHOLD  SET D1 FIELD IN UNPACK INST          44160013
         LA    RC,1                CONSTANT OF 1                        44240013
         LR    RE,RD               LENGTH OF CONTROL FIELD              44320013
         SR    RE,RC               DECREMENT BY ONE                     44400013
         STC   RE,OMPDMBD1+17      SET LENGTH FIELD IN XC INST          44480013
         SLL   RD,4                PREPARE L1 FIELD FOR MVO INST        44560013
         OR    RE,RD               COMBINE LI AND L2 FIELDS             44640013
         STC   RE,OMPDMBD+7        SET LENGTH FIELDS IN MVO INST        44720013
         ST    RH,WOMHOLD          DISPLACEMENT TO CONSTANT OF F'S      44800013
         OC    OMPDMBD1+18(4),WOMHOLD SET D2 FIELD IN XC INST           44880013
         LA    RE,36(0,RF)         INC DISP IN EXTRACT ROUTINE          44960013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      45040013
         OC    OMPDMBD+16(4),WOMHOLD SET D2 FIELD IN BZ INST            45120013
         OC    OMPDMBD1(4),WOMHOLD SET D2 FIELD IN BO INST              45200013
         LA    RE,10(0,RE)         INC DISPLACEMENT BY 10               45280013
         ST    RE,WOMHOLD          DISP FOR BRANCH INST                 45360013
         OC    OMPDMBD1+8(4),WOMHOLD SET D2 FIELD IN BRANCH INST        45440013
         MVC   0(46,RM),OMPDMBD    MOVE SEGMENT TO EXTRACT ROUTINE      45520013
         LA    RM,46(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 45600013
         LA    RF,46(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   45680013
         B     OMISITND                                                 45760013
*                                                                       45840013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SINGLE BYTE             45920013
* PACKED DECIMAL FIELDS WHICH ARE ASCENDING.                            46000013
*                                                                       46080013
OMCASE11 NC    OMPDSBA+2(4),KOMZERO  ZERO DISPLACEMENT                  46160013
         NC    OMPDSBA+8(2),KOMZERO  FIELDS IN                          46240013
         NC    OMPDSBA+12(2),KOMZERO CODE TO BE                         46320013
         NC    OMPDSBA+16(2),KOMZERO INITIALIZED                        46400013
         NC    OMPDSBA1+2(2),KOMZERO                                    46480013
         NC    OMPDSBA1+6(2),KOMZERO                                    46560013
         NC    OMPDSBA1+10(2),KOMZERO                                   46640013
         NC    OMPDSBA1+14(2),KOMZERO                                   46720013
         NC    OMPDSBA1+18(2),KOMZERO                                   46800013
         OC    OMPDSBA+4(2),0(RI)  SET D2 FIELD IN UNPK INST            46880013
         OC    OMPDSBA+8(2),0(RI)  SET D1 FIELD IN FIRST TM INST        46960013
         OC    OMPDSBA+16(2),0(RI) SET D1 FIELD IN SECOND TM INST       47040013
         ST    RK,WOMHOLD          DISP IN EXTRACTED PORTION            47120013
         OC    OMPDSBA(4),WOMHOLD  SET D1 FIELD IN UNPK INST            47200013
         OC    OMPDSBA1+4(4),WOMHOLD SET D1 FIELD IN NI INST            47280013
         OC    OMPDSBA1+8(4),WOMHOLD SET D1 FIELD IN XI INST            47360013
         OC    OMPDSBA1+16(4),WOMHOLD SET D1 FIELD IN OI INST           47440013
         LA    RE,34(0,RF)         INC DISP IN EXTRACT ROUTINE          47520013
         ST    RE,WOMHOLD          DISP FOR BZ INSTRUCTION              47600013
         OC    OMPDSBA+10(4),WOMHOLD SET D2 FIELD IN BZ INST            47680013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT BY 4          47760013
         ST    RE,WOMHOLD          DISP FOR BO AND BRANCH INSTRUCTIONS  47840013
         OC    OMPDSBA1(4),WOMHOLD SET D2 FIELD IN BO INST              47920013
         OC    OMPDSBA1+12(4),WOMHOLD SET D2 FIELD IN BRANCH INST       48000013
         MVC   0(38,RM),OMPDSBA    MOVE SEGMENT TO EXTRACT ROUTINE      48080013
         LA    RM,38(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 48160013
         LA    RF,38(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   48240013
         B     OMISITND                                                 48320013
*                                                                       48400013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SINGLE BYTE             48480013
* PACKED DECIMAL FIELDS  WHICH ARE DECENDING.                           48560013
*                                                                       48640013
OMCASE12 NC    OMPDSBD+2(4),KOMZERO  ZERO DISPLACEMENT                  48720013
         NC    OMPDSBD+8(2),KOMZERO  FIELDS IN                          48800013
         NC    OMPDSBD+12(2),KOMZERO CODE TO BE                         48880013
         NC    OMPDSBD+16(2),KOMZERO INITIALIZED                        48960013
         NC    OMPDSBD1+2(2),KOMZERO                                    49040013
         NC    OMPDSBD1+6(2),KOMZERO                                    49120013
         NC    OMPDSBD1+10(2),KOMZERO                                   49200013
         NC    OMPDSBD1+14(2),KOMZERO                                   49280013
         NC    OMPDSBD1+18(2),KOMZERO                                   49360013
         OC    OMPDSBD+4(2),0(RI)  SET D2 FIELD IN IC INST              49440013
         OC    OMPDSBD+8(2),0(RI)  SET D1 FIELD IN FIRST TM INST        49520013
         OC    OMPDSBD+16(2),0(RI) SET D1 FIELD IN SECOND TM INST       49600013
         ST    RK,WOMHOLD          DISP IN EXTRACTED PORTION            49680013
         OC    OMPDSBD(4),WOMHOLD  SET D1 FIELD IN UNPK INST            49760013
         OC    OMPDSBD1+12(4),WOMHOLD SET D1 FIELD IN NI INST           49840013
         OC    OMPDSBD1+16(4),WOMHOLD SET D1 FIELD IN XI INST           49920013
         OC    OMPDSBD1+4(4),WOMHOLD SET D1 FIELD IN OI INST            50000013
         LA    RE,30(0,RF)         INC DISP IN EXTRACT ROUTINE          50080013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      50160013
         OC    OMPDSBD+10(4),WOMHOLD SET D2 FIELD IN BZ INST            50240013
         OC    OMPDSBD1(4),WOMHOLD SET D2 FIELD IN BO INST              50320013
         LA    RE,8(0,RE)          INCREMENT DISPLACEMENT BY 8          50400013
         ST    RE,WOMHOLD          DISP FOR BRANCH INSTRUCTION          50480013
         OC    OMPDSBD1+8(4),WOMHOLD SET D2 FIELD IN BRANCH INST        50560013
         MVC   0(38,RM),OMPDSBD    MOVE SEGMENT TO EXTRACT ROUTINE      50640013
         LA    RM,38(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 50720013
         LA    RF,38(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   50800013
         B     OMISITND                                                 50880013
*                                                                       50960013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SINGLE BYTE             51040013
* UNPACKED DECIMAL FIELDS WHICH ARE ASCENDING.                          51120013
*                                                                       51200013
OMCASE13 NC    OMUDSBA+2(2),KOMZERO  ZERO DISPLACEMENT                  51280013
         NC    OMUDSBA+6(2),KOMZERO  FIELDS IN                          51360013
         NC    OMUDSBA+10(2),KOMZERO CODE TO BE                         51440013
         NC    OMUDSBA+14(2),KOMZERO INITIALIZED                        51520013
         NC    OMUDSBA+18(2),KOMZERO                                    51600013
         NC    OMUDSBA1+2(2),KOMZERO                                    51680013
         NC    OMUDSBA1+6(2),KOMZERO                                    51760013
         NC    OMUDSBA1+10(2),KOMZERO                                   51840013
         NC    OMUDSBA1+14(2),KOMZERO                                   51920013
         NC    OMUDSBA1+18(2),KOMZERO                                   52000013
         OC    OMUDSBA+2(2),0(RI)  SET D2 FIELD IN IC INST              52080013
         OC    OMUDSBA+10(2),0(RI) SET D1 FIELD IN FIRST TM INST        52160013
         OC    OMUDSBA+18(2),0(RI) SET D1 FIELD IN SECOND TM INST       52240013
         ST    RK,WOMHOLD          DISP IN EXTRACTED PORTION            52320013
         OC    OMUDSBA+4(4),WOMHOLD SET D2 FIELD IN STC INST            52400013
         OC    OMUDSBA1+4(4),WOMHOLD SET D1 FIELD IN NI INST            52480013
         OC    OMUDSBA1+8(4),WOMHOLD SET D1 FIELD IN XI INST            52560013
         OC    OMUDSBA1+16(4),WOMHOLD SET D1 FIELD IN OI INST           52640013
         LA    RE,36(0,RF)         INC DISP IN EXTRACT ROUTINE          52720013
         ST    RE,WOMHOLD          DISP FOR BZ INSTRUCTION              52800013
         OC    OMUDSBA+12(4),WOMHOLD SET D2 FIELD IN BZ INST            52880013
         LA    RE,4(0,RE)          INCREMENT DISPLACEMENT BY 4          52960013
         ST    RE,WOMHOLD          DISP FOR BO AND BRANCH INSTRUCTIONS  53040013
         OC    OMUDSBA1(4),WOMHOLD SET D2 FIELD IN BO INST              53120013
         OC    OMUDSBA1+12(4),WOMHOLD SET D2 FIELD IN BRANCH INST       53200013
         MVC   0(40,RM),OMUDSBA    MOVE SEGMENT TO EXTRACT ROUTINE      53280013
         LA    RM,40(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 53360013
         LA    RF,40(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   53440013
         B     OMISITND                                                 53520013
*                                                                       53600013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT SINGLE BYTE             53680013
* UNPACKED DECIMAL FIELDS WHICH ARE DECENDING.                          53760013
*                                                                       53840013
OMCASE14 NC    OMUDSBD+2(2),KOMZERO  ZERO DISPLACEMENT                  53920013
         NC    OMUDSBD+6(2),KOMZERO  FIELDS IN                          54000013
         NC    OMUDSBD+10(2),KOMZERO CODE TO BE                         54080013
         NC    OMUDSBD+14(2),KOMZERO INITIALIZED                        54160013
         NC    OMUDSBD+18(2),KOMZERO                                    54240013
         NC    OMUDSBD1+2(2),KOMZERO                                    54320013
         NC    OMUDSBD1+6(2),KOMZERO                                    54400013
         NC    OMUDSBD1+10(2),KOMZERO                                   54480013
         NC    OMUDSBD1+14(2),KOMZERO                                   54560013
         NC    OMUDSBD1+18(2),KOMZERO                                   54640013
         OC    OMUDSBD+2(2),0(RI)  SET D2 FIELD IN IC INST              54720013
         OC    OMUDSBD+10(2),0(RI) SET D1 FIELD IN FIRST TM INST        54800013
         OC    OMUDSBD+18(2),0(RI) SET D1 FIELD IN SECOND TM INST       54880013
         ST    RK,WOMHOLD          DISP IN EXTRACTED PORTION            54960013
         OC    OMUDSBD+4(4),WOMHOLD SET D2 FIELD IN STC INST            55040013
         OC    OMUDSBD1+12(4),WOMHOLD SET D1 FIELD IN NI INST           55120013
         OC    OMUDSBD1+16(4),WOMHOLD SET D1 FIELD IN XI INST           55200013
         OC    OMUDSBD1+4(4),WOMHOLD SET D1 FIELD IN OI INST            55280013
         LA    RE,32(0,RF)         INC DISP IN EXTRACT ROUTINE          55360013
         ST    RE,WOMHOLD          DISP FOR BZ AND BO INSTRUCTIONS      55440013
         OC    OMUDSBD+12(4),WOMHOLD SET D2 FIELD IN BZ INST            55520013
         OC    OMUDSBD1(4),WOMHOLD SET D2 FIELD IN BO INST              55600013
         LA    RE,8(0,RE)          INCREMENT DISPLACEMENT BY 8          55680013
         ST    RE,WOMHOLD          DISP FOR BRANCH INSTRUCTION          55760013
         OC    OMUDSBD1+8(4),WOMHOLD SET D2 FIELD IN BRANCH INST        55840013
         MVC   0(40,RM),OMUDSBD    MOVE SEGMENT TO EXTRACT ROUTINE      55920013
         LA    RM,40(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 56000013
         LA    RF,40(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   56080013
         B     OMISITND                                                 56160013
*                                                                       56240013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT UNSIGNED BINARY         56320013
* BIT FIELDS WHICH ARE ASCENDING.                                       56400013
*                                                                       56480013
OMCASE15 NC    OMUBBITA+2(4),KOMZERO  ZERO DISPLACEMENT                 56560013
         NC    OMUBBITA+8(2),KOMZERO  FIELDS IN                         56640013
         NC    OMUBBITA+12(2),KOMZERO CODE TO BE                        56720013
         NC    OMUBBITA+16(2),KOMZERO INITIALIZED                       56800013
         NC    OMUBBITA+20(2),KOMZERO                                   56880013
         SR    RD,RD               ZERO REGISTER                        56960013
         STC   RD,OMUBBITA+7       ZERO MASK IN FIRST BRANCH INST       57040013
         STC   RD,OMUBBITA+15      ZERO MASK IN SECOND BRANCH INST      57120013
         OC    OMUBBITA+4(2),0(RI) SET D2 FIELD IN MVC INST             57200013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    57280013
         OC    OMUBBITA(4),WOMHOLD SET D1 FIELD IN MVC INST             57360013
         OC    OMUBBITA+10(4),WOMHOLD SET D1 FIELD IN FIRST NI INST     57440013
         LA    RE,14(0,RF)         INC DISP IN EXTRACT ROUTINE          57520013
         ST    RE,WOMHOLD          DISP FOR FIRST BRANCH INST           57600013
         OC    OMUBBITA+6(4),WOMHOLD SET D2 FIELD IN FIRST BRANCH INST  57680013
         LA    RE,8(0,RE)          INC BY 8                             57760013
         ST    RE,WOMHOLD          DISP FOR SECOND BRANCH INST          57840013
         OC    OMUBBITA+14(4),WOMHOLD SET D2 FIELD IN SECOND BC INST    57920013
         IC    RD,3(0,RI)          BYTE PORTION OF LENGTH OF CF         58000013
         SLL   RD,3                MULTIPLY BY 8                        58080013
         SR    RE,RE               ZERO REGISTER                        58160013
         IC    RE,4(0,RI)          BITS PORTION OF LENGTH OF CF         58240013
         AR    RE,RD               TOTAL THE BITS                       58320013
         SR    RD,RD               ZERO REGISTER                        58400013
         IC    RD,2(0,RI)          BITS PORTION OF DISP OF CF           58480013
         AR    RE,RD               TOTAL THE BITS                       58560013
         LR    RC,RE               SAVE THIS BIT TOTAL                  58640013
         LA    RE,7(0,RE)          INCREMENT TOTAL BY 7 FOR ROUNDING    58720013
         SRL   RE,3                DIVIDE BY 8                          58800013
         STC   RE,OMUBBITA+1       SET LENGTH FIELD IN MVC INST         58880013
         LR    RB,RE               MOVE TO OTHER REGISTER               58960013
         LA    RE,255              CONSTANT X'FF'                       59040013
         NR    RB,RE               MASK OUT HIGH ORDER BITS             59120013
         AR    RB,RK               ADD DISP IN EXTRACTED PORTION        59200013
         ST    RB,WOMHOLD          DISP FOR D1 FIELD OF SECOND NI INST  59280013
         OC    OMUBBITA+18(4),WOMHOLD SET D1 FIELD IN SECOND NI INST    59360013
         SRL   RE,0(RD)            FORM MASK FOR HIGH ORDER BITS        59440013
         STC   RE,OMUBBITA+11      SET MASK IN FIRST NI INST            59520013
         LTR   RD,RD               TEST REGISTER FOR NON ZERO           59600013
         BNE   OMHIGHA             BRANCH IF BITS TO ZERO               59680013
         LA    RE,240              CONSTANT X'F0'                       59760013
         STC   RE,OMUBBITA+7       SET FIRST BC INST TO BRANCH          59840013
OMHIGHA  LA    RD,7                CONSTANT X'07'                       59920013
         NR    RC,RD               MASK OUT HIGH ORDER BITS             60000013
         LA    RE,8                CONSTANT X'08'                       60080013
         SR    RE,RC               FORM SHIFT FOR LOW ORDER MASK        60160013
         LA    RD,255              CONSTANT X'FF'                       60240013
         SLL   RD,0(RE)            FORM MASK FOR LOW ORDER BITS         60320013
         STC   RD,OMUBBITA+19      SET MASK IN SECOND NI INST           60400013
         LTR   RC,RC               TEST REGISTER FOR NON ZERO           60480013
         BNE   OMLOWA              BRANCH IF BITS TO ZERO               60560013
         LA    RE,240              CONSTANT X'F0'                       60640013
         STC   RE,OMUBBITA+15      SET SECOND BC INST TO BRANCH         60720013
OMLOWA   MVC   0(22,RM),OMUBBITA   MOVE SEGMENT TO EXTRACT ROUTINE      60800013
         LA    RM,22(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 60880013
         LA    RF,22(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   60960013
         B     OMISITND                                                 61040013
*                                                                       61120013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT UNSIGNED BINARY         61200013
* BIT FIELDS WHICH ARE DECENDING.                                       61280013
*                                                                       61360013
OMCASE16 NC    OMUBBITD+2(4),KOMZERO  ZERO DISPLACEMENT                 61440013
         NC    OMUBBITD+8(2),KOMZERO  FIELDS IN                         61520013
         NC    OMUBBITD+12(2),KOMZERO CODE TO BE                        61600013
         NC    OMUBBITD+16(2),KOMZERO INITIALIZED                       61680013
         NC    OMUBBITD+20(2),KOMZERO                                   61760013
         NC    OMUBBITD+24(4),KOMZERO                                   61840013
         SR    RD,RD               ZERO REGISTER                        61920013
         STC   RD,OMUBBITD+7       ZERO MASK IN FIRST BRANCH INST       62000013
         STC   RD,OMUBBITD+15      ZERO MASK IN SECOND BRANCH INST      62080013
         OC    OMUBBITD+4(2),0(RI) SET D2 FIELD IN MVC INST             62160013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    62240013
         OC    OMUBBITD(4),WOMHOLD SET D1 FIELD IN MVC INST             62320013
         OC    OMUBBITD+10(4),WOMHOLD SET D1 FIELD IN FIRST NI INST     62400013
         OC    OMUBBITD+22(4),WOMHOLD SET D1 FIELD IN XC INST           62480013
         LA    RE,14(0,RF)         INC DISP IN EXTRACT ROUTINE          62560013
         ST    RE,WOMHOLD          DISP FOR FIRST BRANCH INST           62640013
         OC    OMUBBITD+6(4),WOMHOLD SET D2 FIELD IN FIRST BRANCH INST  62720013
         LA    RE,8(0,RE)          INC BY 8                             62800013
         ST    RE,WOMHOLD          DISP FOR SECOND BRANCH INST          62880013
         OC    OMUBBITD+14(4),WOMHOLD SET D2 FIELD IN SECOND BC INST    62960013
         ST    RH,WOMHOLD          DISP TO CONSTANT OF F'S              63040013
         OC    OMUBBITD+24(4),WOMHOLD SET D2 FIELD IN XC INST           63120013
         IC    RD,3(0,RI)          BYTE PORTION OF LENGTH OF CF         63200013
         SLL   RD,3                MULTIPLY BY 8                        63280013
         SR    RE,RE               ZERO REGISTER                        63360013
         IC    RE,4(0,RI)          BITS PORTION OF LENGTH OF CF         63440013
         AR    RE,RD               TOTAL THE BITS                       63520013
         SR    RD,RD               ZERO REGISTER                        63600013
         IC    RD,2(0,RI)          BITS PORTION OF DISP OF CF           63680013
         AR    RE,RD               TOTAL THE BITS                       63760013
         LR    RC,RE               SAVE THIS BIT TOTAL                  63840013
         LA    RE,7(0,RE)          INCREMENT TOTAL BY 7 FOR ROUNDING    63920013
         SRL   RE,3                DIVIDE BY 8                          64000013
         STC   RE,OMUBBITD+1       SET LENGTH FIELD IN MVC INST         64080013
         STC   RE,OMUBBITD+23      SET LENGTH FIELD IN XC INST          64160013
         LR    RB,RE               MOVE TO OTHER REGISTER               64240013
         LA    RE,255              CONSTANT X'FF'                       64320013
         NR    RB,RE               MASK OUT HIGH ORDER BITS             64400013
         AR    RB,RK               ADD DISP IN EXTRACTED PORTION        64480013
         ST    RB,WOMHOLD          DISP FOR D1 FIELD OF SECOND NI INST  64560013
         OC    OMUBBITD+18(4),WOMHOLD SET D1 FIELD IN SECOND NI INST    64640013
         SRL   RE,0(RD)            FORM MASK FOR HIGH ORDER BITS        64720013
         STC   RE,OMUBBITD+11      SET MASK IN FIRST NI INST            64800013
         LTR   RD,RD               TEST REGISTER FOR NON ZERO           64880013
         BNE   OMHIGHD             BRANCH IF BITS TO ZERO               64960013
         LA    RE,240              CONSTANT X'F0'                       65040013
         STC   RE,OMUBBITD+7       SET FIRST BC INST TO BRANCH          65120013
OMHIGHD  LA    RD,7                CONSTANT X'07'                       65200013
         NR    RC,RD               MASK OUT HIGH ORDER BITS             65280013
         LA    RE,8                CONSTANT X'08'                       65360013
         SR    RE,RC               FORM SHIFT FOR LOW ORDER MASK        65440013
         LA    RD,255              CONSTANT X'FF'                       65520013
         SLL   RD,0(RE)            FORM MASK FOR LOW ORDER BITS         65600013
         STC   RD,OMUBBITD+19      SET MASK IN SECOND NI INST           65680013
         LTR   RC,RC               TEST REGISTER FOR NON ZERO           65760013
         BNE   OMLOWD              BRANCH IF BITS TO ZERO               65840013
         LA    RE,240              CONSTANT X'F0'                       65920013
         STC   RE,OMUBBITD+15      SET SECOND BC INST TO BRANCH         66000013
OMLOWD   MVC   0(28,RM),OMUBBITD   MOVE SEGMENT TO EXTRACT ROUTINE      66080013
         LA    RM,28(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 66160013
         LA    RF,28(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   66240013
         B     OMISITND                                                 66320013
*                                                                       66400013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT THE TYPE                66480013
* CONTROL FIELD LISTED.                                                 66560013
*        1 ALPHAMERIC OR UNSIGNED BINARY BYTES WITH USER EXIT           66640013
*        2 SIGNED BINARY BYTES WITH USER EXIT                           66720013
*        3 FLOATING POINT WITH USER EXIT                                66800013
*        4 UNPACKED DECIMAL MULTI-BYTE WITH USER EXIT                   66880013
*        5 PACKED DECIMAL MULTI-BYTE WITH USER EXIT                     66960013
*        6 UNPACKED DECIMAL SINGLE-BYTE WITH USER EXIT                  67040013
*        7 PACKED DECIMAL SINGLE-BYTE WITH USER EXIT                    67120013
*                                                                       67200013
OMCASE17 NC    OMEXITS+2(4),KOMZERO  ZERO DISPLACEMENT FIELDS           67280013
         NC    OMEXITS+8(2),KOMZERO  IN CODE TO BE                      67360013
         NC    OMEXITS+12(2),KOMZERO INITIALIZED                        67440013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    67520013
         OC    OMEXITS(4),WOMHOLD  SET D1 FIELD IN MVC INST             67600013
         OC    OMEXITS+4(2),0(RI)  SET D2 FIELD IN MVC INST             67680013
         MVC   OMEXITS+1(1),3(RI)  SET LENGTH FIELD IN MVC INST         67760013
         OC    OMEXITS+10(4),WOMHOLD SET D2 FIELD IN SECOND LA INST     67840013
         LH    RE,PPINUMCF     GET NUMBER OF CONTROL FIELDS +      6155 67880016
         LA    RE,1(RE)        FOR USE AS COUNTER OF ORDER         6155 67920016
*                              FOR CONTROL FIELD FOR USER EXIT     6155 67960016
         SR    RE,RJ               CALC WHICH CONTROL FIELD THIS IS     68000013
         STH   RE,OMEXITS+8        SET D2 FIELD IN FIRST LA INST        68080013
         MVC   0(32,RM),OMEXITS    MOVE SEGMENT TO EXTRACT ROUTINE      68160013
         LA    RM,32(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 68240013
         LA    RF,32(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   68320013
         B     OMISITND                                                 68400013
*                                                                       68480013
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT UNSIGNED BINARY         68560013
* BIT FIELDS WITH USER EXIT.                                            68640013
*                                                                       68720013
OMCASE24 NC    OMUBBITE+2(4),KOMZERO  ZERO DISPLACEMENT                 68800013
         NC    OMUBBITE+8(2),KOMZERO  FIELDS IN                         68880013
         NC    OMUBBITE+12(2),KOMZERO CODE TO BE                        68960013
         NC    OMUBBITE+16(2),KOMZERO INITIALIZED                       69040013
         NC    OMUBBITE+20(2),KOMZERO                                   69120013
         NC    OMUBBIT1+2(2),KOMZERO                                    69200013
         NC    OMUBBIT1+6(2),KOMZERO                                    69280013
         SR    RD,RD               ZERO REGISTER                        69360013
         STC   RD,OMUBBITE+7       ZERO MASK IN FIRST BRANCH INST       69440013
         STC   RD,OMUBBITE+15      ZERO MASK IN SECOND BRANCH INST      69520013
         OC    OMUBBITE+4(2),0(RI) SET D2 FIELD IN MVC INST             69600013
         ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    69680013
         OC    OMUBBITE(4),WOMHOLD SET D1 FIELD IN MVC INST             69760013
         OC    OMUBBITE+10(4),WOMHOLD SET D1 FIELD IN FIRST NI INST     69840013
         LA    RE,14(0,RF)         INC DISP IN EXTRACT ROUTINE          69920013
         ST    RE,WOMHOLD          DISP FOR FIRST BRANCH INST           70000013
         OC    OMUBBITE+6(4),WOMHOLD SET D2 FIELD IN FIRST BRANCH INST  70080013
         LA    RE,8(0,RE)          INC BY 8                             70160013
         ST    RE,WOMHOLD          DISP FOR SECOND BRANCH INST          70240013
         OC    OMUBBITE+14(4),WOMHOLD SET D2 FIELD IN SECOND BC INST    70320013
         IC    RD,3(0,RI)          BYTE PORTION OF LENGTH OF CF         70400013
         SLL   RD,3                MULTIPLY BY 8                        70480013
         SR    RE,RE               ZERO REGISTER                        70560013
         IC    RE,4(0,RI)          BITS PORTION OF LENGTH OF CF         70640013
         AR    RE,RD               TOTAL THE BITS                       70720013
         SR    RD,RD               ZERO REGISTER                        70800013
         IC    RD,2(0,RI)          BITS PORTION OF DISP OF CF           70880013
         AR    RE,RD               TOTAL THE BITS                       70960013
         LR    RC,RE               SAVE THIS BIT TOTAL                  71040013
         LA    RE,7(0,RE)          INCREMENT TOTAL BY 7 FOR ROUNDING    71120013
         SRL   RE,3                DIVIDE BY 8                          71200013
         STC   RE,OMUBBITE+1       SET LENGTH FIELD IN MVC INST         71280013
         LR    RB,RE               MOVE TO OTHER REGISTER               71360013
         LA    RE,255              CONSTANT X'FF'                       71440013
         NR    RB,RE               MASK OUT HIGH ORDER BITS             71520013
         AR    RB,RK               ADD DISP IN EXTRACTED PORTION        71600013
         ST    RB,WOMHOLD          DISP FOR D1 FIELD OF SECOND NI INST  71680013
         OC    OMUBBITE+18(4),WOMHOLD SET D1 FIELD IN SECOND NI INST    71760013
         SRL   RE,0(RD)            FORM MASK FOR HIGH ORDER BITS        71840013
         STC   RE,OMUBBITE+11      SET MASK IN FIRST NI INST            71920013
         LTR   RD,RD               TEST REGISTER FOR NON ZERO           72000013
         BNE   OMHIGHE             BRANCH IF BITS TO ZERO               72080013
         LA    RE,240              CONSTANT X'F0'                       72160013
         STC   RE,OMUBBITE+7       SET FIRST BC INST TO BRANCH          72240013
OMHIGHE  LA    RD,7                CONSTANT X'07'                       72320013
         NR    RC,RD               MASK OUT HIGH ORDER BITS             72400013
         LA    RE,8                CONSTANT X'08'                       72480013
         SR    RE,RC               FORM SHIFT FOR LOW ORDER MASK        72560013
         LA    RD,255              CONSTANT X'FF'                       72640013
         SLL   RD,0(RE)            FORM MASK FOR LOW ORDER BITS         72720013
         STC   RD,OMUBBITE+19      SET MASK IN SECOND NI INST           72800013
         LTR   RC,RC               TEST REGISTER FOR NON ZERO           72880013
         BNE   OMLOWE              BRANCH IF BITS TO ZERO               72960013
         LA    RE,240              CONSTANT X'F0'                       73040013
         STC   RE,OMUBBITE+15      SET SECOND BC INST TO BRANCH         73120013
OMLOWE   ST    RK,WOMHOLD          DISPLACEMENT IN EXTRACTED PORTION    73200013
         OC    OMUBBIT1+4(4),WOMHOLD SET D2 FIELD IN SECOND LA INST     73280013
         LH    RE,PPINUMCF     GET NUMBER OF CONTROL FIELDS +      6155 73320016
         LA    RE,1(RE)        FOR USE AS COUNTER OF ORDER         6155 73360016
*                              FOR CONTROL FIELD FOR USER EXIT     6155 73400016
         SR    RE,RJ               CALC WHICH CONTROL FIELD THIS IS     73440013
         STH   RE,OMUBBIT1+2       SET D2 FIELD IN FIRST LA INST        73520013
         MVC   0(48,RM),OMUBBITE   MOVE SEGMENT TO EXTRACT ROUTINE      73600013
         LA    RM,48(0,RM)         INCREMENT ADDRESS OF EXTRACT ROUTINE 73680013
         LA    RF,48(0,RF)         INCREMENT DISPLACEMENT IN EXT ROUT   73760013
         B     OMISITND                                                 73840013
*                                                                       73920013
*                                                                       74000013
* INCREMENT POSITION IN EXTRACTED PORTION BY LENGTH OF THIS             74080013
* CONTROL FIELD.                                                        74160013
*                                                                       74240013
*                                                                       74320013
OMISITND CLI   5(RI),X'18'         IS CF UNPACKED DECIMAL ASCENDING     74400013
         BE    OMITISUD                                                 74480013
         CLI   5(RI),X'1C'         IS CF UNPACKED DECIMAL DECENDING     74560013
         BNE   OMNOTUD                                                  74640013
OMITISUD SR    RE,RE               ZERO REGISTER                        74720013
         IC    RE,3(0,RI)          BYTE PORTION OF LENGTH OF LAST CF    74800013
         LA    RE,1(0,RE)          INCREMENT BY ONE BYTE                74880013
         SRL   RE,1                DIVIDE BY 2                          74960013
         B     OMSKIP                                                   75040013
OMNOTUD  SR    RE,RE               ZERO REGISTER                        75120013
         IC    RE,3(0,RI)          BYTE PORTION OF LENGTH OF LAST CF    75200013
         SLL   RE,3                MULTIPLY BY 8                        75280013
         SR    RD,RD               ZERO REGISTER                        75360013
         IC    RD,4(0,RI)          BITS PORTION OF LENGTH OF LAST CF    75440013
         AR    RE,RD               TOTAL THE BITS                       75520013
         IC    RD,2(0,RI)          BITS PORTION OF DISP OF LAST CF      75600013
         AR    RE,RD               TOTAL THE BITS                       75680013
         LA    RE,7(0,RE)          INCREMENT TOTAL BY 7 FOR ROUNDING    75760013
         SRL   RE,3                DIVIDE BY 8                          75840013
OMSKIP   LA    RE,1(0,RE)          INC BY ONE BYTE FOR ACTUAL DISP      75920013
         CL    RE,K256             IS IT A 256 BYTE FIELD               76000013
         BE    OMNOBIT                                                  76080013
         LA    RD,255              CONSTANT OF X'FF'                    76160013
         B     OMNOBIT+4                                                76240013
         SPACE 2                                                        76320013
OMNOBIT  LA    RD,511              CONSTANT OF X'1FF' FOR 256 BYTE FLD  76400013
         NR    RE,RD               KEEP LAST BYTE                       76480013
OMNOBIT1 AR    RK,RE                    INC DISP IN EXT PORTION BY LTH  76560018
*                                                                       76640013
* INCREMENT TO CONTROL FIELD DATA FOR NEXT CONTROL FIELD AND CHECK      76720013
* IF THE PREVIOUS FIELD WAS THE LAST.                                   76800013
*                                                                       76880013
         LA    RI,6(0,RI)          INCREMENT TO DATA FOR NEXT C.F.      76960013
         BCT   RJ,OMNOLAST         LAST CONTROL FIELD                   77040013
*                                                                       77120013
* MOVE THE ENDING SEGMENT TO THE GENERATED EXTRACT ROUTINE AND STORE    77200013
* THE LENGTH OF THE EXTRACTED FIELDS AS REQUIRED FOR THE COMPARE        77280013
* INSTRUCTIONS AND AS AN ADDRESS INCREMENT ROUNDED TO FULL WORDS        77360013
* IN PPIA.                                                              77440013
*                                                                       77520013
         LA    RD,5                CONSTANT OF 1+4                      77600013
         SR    RK,RD               DECREMENT BY 1+4 (4 IS TREE ADDR)    77680013
         STH   RK,PPILEXFD         LTH OF EXTRACTED FIELDS FOR COMPARES 77760013
         LA    RK,4(0,RK)          INC BY 3+1 BYTES TO ROUND TO FULL WD 77840013
         SRL   RK,2                SHIFT OFF 2 BITS                     77920013
         SLL   RK,2                RESTORE TO POSITION                  78000013
         STH   RK,PPILEXFF         LTH OF EXTRACTED FIELDS ROUNDED FULL 78080013
         MVC   0(2,RM),OMEND       MOVE ENDING SEGMENT TO EXTRACT ROUT  78160013
*                                                                       78240013
* RETURN TO SSC                                                         78320013
*                                                                       78400013
OMRETRN  L     RM,WOMRETNR         RESET REGISTER SAVE ADDRESS          78480013
         SR    RP,RP               SET RETURN CODE REGISTER TO ZERO     78560013
         LM    RC,RL,0(RM)         RESET SSC REGISTERS                  78640013
         BR    RO                  RETURN TO SSC                        78720013
*                                                                       78800013
*                                                                       78880013
*                                                                       78960013
*  THE FOLLOWING CODE IS USED TO EXTRACT ALPHAMERIC OR UNSIGNED BINARY  79040013
*  BYTE FIELDS WHICH ARE ASCENDING.                                     79120013
*                                                                       79200013
OMAOUBBA MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  79280013
*                                                                       79360013
*  THE FOLLOWING CODE IS USED TO EXTRACT ALPHAMERIC OR UNSIGNED BINARY  79440013
*  BYTE FIELDS WHICH ARE DECENDING.                                     79520013
*                                                                       79600013
OMAOUBBD MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  79680013
         XC    0(1,RD),0(RM)       INVERT THIS CONTROL FIELD            79760013
*                                                                       79840013
*  THE FOLLOWING CODE IS USED TO EXTRACT NORMALIZED FLOATING POINT      79920013
*  FIELDS WHICH ARE ASCENDING.                                          80000013
*                                                                       80080013
OMFLPTA  MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  80160013
         TM    0(RC),X'80'         TEST SIGN                            80240013
         BZ    0(0,RM)             BRANCH IF PLUS                       80320013
         XC    0(1,RD),0(RM)       INVERT THIS CONTROL FIELD            80400013
         B     0(0,RM)                                                  80480013
         XI    0(RD),X'80'         INVERT SIGN BIT                      80560013
*                                                                       80640013
*  THE FOLLOWING CODE IS USED TO EXTRACT NORMALIZED FLOATING POINT      80720013
*  FIELDS WHICH ARE DECENDING.                                          80800013
*                                                                       80880013
OMFLPTD  MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  80960013
         TM    0(RC),X'80'         TEST SIGN                            81040013
         BO    0(0,RM)             BRANCH IF MINUS                      81120013
         XI    0(RD),X'7F'         INVERT ALL BUT SIGN BIT OF BYTE ONE  81200013
         BC    0,0(0,RM)           BRANCH IF C.F. IS ONLY 1 BYTE        81280013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            81360013
*                                                                       81440013
*  THE FOLLOWING CODE IS USED TO EXTRACT SIGNED BINARY BYTE FIELDS      81520013
*  WHICH ARE ASCENDING.                                                 81600013
*                                                                       81680013
OMSBBA   MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  81760013
         XI    0(RD),X'80'         INVERT SIGN BIT                      81840013
*                                                                       81920013
*  THE FOLLOWING CODE IS USED TO EXTRACT SIGNED BINARY BYTE FIELDS      82000013
*  WHICH ARE DECENDING.                                                 82080013
*                                                                       82160013
OMSBBD   MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  82240013
         XI    0(RD),X'7F'         INVERT ALL BUT SIGN BIT OF BYTE ONE  82320013
         BC    0,0(0,RM)           BRANCH IF C.F. IS ONLY 1 BYTE        82400013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            82480013
*                                                                       82560013
*  THE FOLLOWING CODE IS USED TO EXTRACT MULTI-BYTE UNPACKED DECIMAL    82640013
*  FIELDS WHICH ARE ASCENDING.                                          82720013
*                                                                       82800013
OMUDMBA  PACK  0(1,RM),0(1,RC)     PACK CONTROL FIELD IN PACKING BUFFER 82880013
         UNPK  0(1,RD),0(1,RM)     SIGN BYTE FROM BUFFER TO EXTRACT POS 82960013
         MVO   0(2,RD),0(1,RM)     REMAINDER OF FIELD TO EXTRACT POSIT  83040013
         TM    0(RM),X'01'         TEST SIGN IN PACKING BUFFER          83120013
         BZ    0(0,RM)             BRANCH IF PLUS                       83200013
OMUDMBA1 TM    0(RM),X'0F'         TEST SIGN IN PACKING BUFFER          83280013
         BO    0(0,RM)             BRANCH IF PLUS                       83360013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE ONE    83440013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            83520013
         B     0(0,RM)                                                  83600013
         OI    0(RD),X'F0'         SET SIGN TO PLUS                     83680013
*                                                                       83760013
*  THE FOLLOWING CODE IS USED TO EXTRACT MULTIPLE-BYTE UNPACKED DECIMAL 83840013
*  FIELDS WHICH ARE DECENDING.                                          83920013
*                                                                       84000013
OMUDMBD  PACK  0(1,RM),0(1,RC)     PACK CONTROL FIELD IN PACKING BUFFER 84080013
         UNPK  0(1,RD),0(1,RM)     SIGN BYTE FROM BUFFER TO EXTRACT POS 84160013
         MVO   0(2,RD),0(1,RM)     REMAINDER OF FIELD TO EXTRACT POSIT  84240013
         TM    0(RM),X'01'         TEST SIGN IN PACKING BUFFER          84320013
         BZ    0(0,RM)             BRANCH IF PLUS                       84400013
OMUDMBD1 TM    0(RM),X'0F'         TEST SIGN IN PACKING BUFFER          84480013
         BO    0(0,RM)             BRANCH IF PLUS                       84560013
         OI    0(RD),X'F0'         SET SIGN TO PLUS                     84640013
         B     0(0,RM)                                                  84720013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE ONE    84800013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            84880013
*                                                                       84960013
*  THE FOLLOWING CODE IS USED TO EXTRACT MULTI-BYTE PACKED DECIMAL      85040013
*  FIELDS WHICH ARE ASCENDING.                                          85120013
*                                                                       85200013
OMPDMBA  UNPK  0(1,RD),0(1,RC)     SIGN BYTE TO EXTRACT POSITION        85280013
         MVO   0(2,RD),0(1,RC)     REMAINDER OF FIELD TO EXTRACT POSIT  85360013
         TM    0(RC),X'01'         TEST SIGN'WITH RECORD                85440013
         BZ    0(0,RM)             BRANCH IF PLUS                       85520013
         TM    0(RC),X'0F'         TEST SIGN'WITH RECORD                85600013
OMPDMBA1 BO    0(0,RM)             BRANCH IF PLUS                       85680013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE ONE    85760013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            85840013
         B     0(0,RM)                                                  85920013
         OI    0(RD),X'F0'         SET SIGN TO PLUS                     86000013
*                                                                       86080013
*  THE FOLLOWING CODE IS USED TO EXTRACT MULTIPLE-BYTE PACKED DECIMAL   86160013
*  FIELDS WHICH ARE DECENDING.                                          86240013
*                                                                       86320013
OMPDMBD  UNPK  0(1,RD),0(1,RC)     SIGN BYTE TO EXTRACT POSITION        86400013
         MVO   0(2,RD),0(1,RC)     REMAINDER OF FIELD TO EXTRACT POSIT  86480013
         TM    0(RC),X'01'         TEST SIGN'WITH RECORD                86560013
         BZ    0(0,RM)             BRANCH IF PLUS                       86640013
         TM    0(RC),X'0F'         TEST SIGN'WITH RECORD                86720013
OMPDMBD1 BO    0(0,RM)             BRANCH IF PLUS                       86800013
         OI    0(RD),X'F0'         SET SIGN TO PLUS                     86880013
         B     0(0,RM)                                                  86960013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE ONE    87040013
         XC    0(1,RD),0(RM)       INVERT REMAINDER OF FIELD            87120013
*                                                                       87200013
*  THE FOLLOWING CODE IS USED TO EXTRACT SINGLE BYTE PACKED DECIMAL     87280013
*  FIELDS WHICH ARE ASCENDING.                                          87360013
*                                                                       87440013
OMPDSBA  UNPK  0(1,RD),0(1,RC)     SIGN BYTE TO EXTRACT POSITION        87520013
         TM    0(RC),X'01'         TEST SIGN'WITH RECORD                87600013
         BZ    0(0,RM)             BRANCH IF PLUS                       87680013
         TM    0(RC),X'0F'         TEST SIGN'WITH RECORD                87760013
OMPDSBA1 BO    0(0,RM)             BRANCH IF PLUS                       87840013
         NI    0(RD),X'0F'         SET SIGN MINUS                       87920013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE        88000013
         B     0(0,RM)                                                  88080013
         OI    0(RD),X'F0'         SET SIGN PLUS                        88160013
*                                                                       88240013
*  THE FOLLOWING CODE IS USED TO EXTRACT SINGLE BYTE PACKED DECIMAL     88320013
*  FIELDS WHICH ARE DECENDING                                           88400013
*                                                                       88480013
OMPDSBD  UNPK  0(1,RD),0(1,RC)     SIGN BYTE TO EXTRACT POSITION        88560013
         TM    0(RC),X'01'         TEST SIGN'WITH RECORD                88640013
         BZ    0(0,RM)             BRANCH IF PLUS                       88720013
         TM    0(RC),X'0F'         TEST SIGN'WITH RECORD                88800013
OMPDSBD1 BO    0(0,RM)             BRANCH IF PLUS                       88880013
         OI    0(RD),X'F0'         SET SIGN PLUS                        88960013
         B     0(0,RM)                                                  89040013
         NI    0(RD),X'0F'         SET SIGN MINUS                       89120013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE        89200013
*                                                                       89280013
*  THE FOLLOWING CODE IS USED TO EXTRACT SINGLE BYTE UNPACKED DECIMAL   89360013
*  FIELDS WHICH ARE ASCENDING.                                          89440013
*                                                                       89520013
OMUDSBA  IC    RF,0(0,RC)          LOAD CONTROL FIELD                   89600013
         STC   RF,0(0,RD)          STORE CONTROL FIELD IN EXTRACT POSIT 89680013
         TM    0(RC),X'10'         TEST SIGN WITH RECORD                89760013
         BZ    0(0,RM)             BRANCH IF PLUS                       89840013
         TM    0(RC),X'F0'         TEST SIGN WITH RECORD                89920013
OMUDSBA1 BO    0(0,RM)             BRANCH IF PLUS                       90000013
         NI    0(RD),X'0F'         SET SIGN MINUS                       90080013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE        90160013
         B     0(0,RM)                                                  90240013
         OI    0(RD),X'F0'         SET SIGN PLUS                        90320013
*                                                                       90400013
*  THE FOLLOWING CODE IS USED TO EXTRACT SINGLE BYTE UNPACKED DECIMAL   90480013
*  FIELDS WHICH ARE DECENDING.                                          90560013
*                                                                       90640013
OMUDSBD  IC    RF,0(0,RC)          LOAD CONTROL FIELD                   90720013
         STC   RF,0(0,RD)          STORE CONTROL FIELD IN EXTRACT POSIT 90800013
         TM    0(RC),X'10'         TEST SIGN WITH RECORD                90880013
         BZ    0(0,RM)             BRANCH IF PLUS                       90960013
         TM    0(RC),X'F0'         TEST SIGN WITH RECORD                91040013
OMUDSBD1 BO    0(0,RM)             BRANCH IF PLUS                       91120013
         OI    0(RD),X'F0'         SET SIGN PLUS                        91200013
         B     0(0,RM)                                                  91280013
         NI    0(RD),X'0F'         SET SIGN MINUS                       91360013
         XI    0(RD),X'0F'         INVERT LAST FOUR BITS OF BYTE        91440013
*                                                                       91520013
*  THE FOLLOWING CODE IS USED TO EXTRACT UNSIGNED BINARY BIT FIELDS     91600013
*  WHICH ARE ASCENDING.                                                 91680013
*                                                                       91760013
OMUBBITA MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  91840013
         BC    0,0(0,RM)           BRANCH IF NO HIGH ORDER BITS TO ZERO 91920013
         NI    0(RD),X'00'         ZERO NECESSARY HIGH ORDER BITS       92000013
         BC    0,0(0,RM)           BRANCH IF NO LOW ORDER BITS TO ZERO  92080013
         NI    0(RD),X'00'         ZERO NECESSARY LOW ORDER BITS        92160013
*                                                                       92240013
*  THE FOLLOWING CODE IS USED TO EXTRACT UNSIGNED BINARY BIT FIELDS     92320013
*  WHICH ARE DECENDING.                                                 92400013
*                                                                       92480013
OMUBBITD MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  92560013
         BC    0,0(0,RM)           BRANCH IF NO HIGH ORDER BITS TO ZERO 92640013
         NI    0(RD),X'00'         ZERO NECESSARY HIGH ORDER BITS       92720013
         BC    0,0(0,RM)           BRANCH IF NO LOW ORDER BITS TO ZERO  92800013
         NI    0(RD),X'00'         ZERO NECESSARY LOW ORDER BITS        92880013
         XC    0(1,RD),0(RM)       INVERT ALL OF FIELD                  92960013
*                                                                       93040013
*  THE FOLLOWING CODE IS USED TO EXTRACT THE TYPE CONTROL FIELD LISTED. 93120013
*       1 ALPHAMERIC OR UNSIGNED BINARY BYTES WITH USER EXIT            93200013
*       2 SIGNED BINARY BYTES WITH USER EXIT                            93280013
*       3 FLOATING POINT WITH USER EXIT                                 93360013
*       4 UNPACKED DECIMAL MULTI-BYTE WITH USER EXIT                    93440013
*       5 PACKED DECIMAL MULTI-BYTE WITH USER EXIT                      93520013
*       6 UNPACKED DECIMAL SINGLE-BYTE WITH USER EXIT                   93600013
*       7 PACKED DECIMAL SINGLE-BYTE WITH USER EXIT                     93680013
*                                                                       93760013
OMEXITS  MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  93840013
         LA    RA,0                WHICH CONTROL FIELD THIS IS          93920013
         LA    RB,0(0,RD)          ADDR OF THIS CF IN EXTRACTED PORTION 94000013
         STM   RA,RB,PPILAB01      STORE AS PARAMETER LIST FOR USER     94080013
         LA    RB,PPILAB01         SET ADDRESS OF PARAMETER LIST        94160013
         LR    RE,RO               SAVE NETWORK RETURN ADDRESS          94240013
         L     RP,0(0,RM)          ADDR OF USER EXIT                    94320013
         BALR  RO,RP               LINK TO USER EXIT                    94400013
         LR    RO,RE               RESTORE NETWORK RETURN ADDRESS       94480013
*                                                                       94560013
*  THE FOLLOWING CODE IS USED TO EXTRACT UNSIGNED BINARY BIT FIELDS     94640013
*  WITH USER EXIT.                                                      94720013
*                                                                       94800013
OMUBBITE MVC   0(1,RD),0(RC)       MOVE CONTROL FIELD TO EXTRACT POSIT  94880013
         BC    0,0(0,RM)           BRANCH IF NO HIGH ORDER BITS TO ZERO 94960013
         NI    0(RD),X'00'         ZERO NECESSARY HIGH ORDER BITS       95040013
         BC    0,0(0,RM)           BRANCH IF NO LOW ORDER BITS TO ZERO  95120013
         NI    0(RD),X'00'         ZERO NECESSARY LOW ORDER BITS        95200013
OMUBBIT1 LA    RA,0                WHICH CONTROL FIELD THIS IS          95280013
         LA    RB,0(0,RD)          ADDR OF THIS CF IN EXTRACTED PORTION 95360013
         STM   RA,RB,PPILAB01      STORE AS PARAMETER LIST FOR USER     95440013
         LA    RB,PPILAB01         SET ADDRESS OF PARAMETER LIST        95520013
         LR    RE,RO               SAVE NETWORK RETURN ADDRESS          95600013
         L     RP,0(0,RM)          ADDR OF USER EXIT                    95680013
         BALR  RO,RP               LINK TO USER EXIT                    95760013
         LR    RO,RE               RESTORE NETWORK RETURN ADDRESS       95840013
*                                                                       95920013
*  THE FOLLOWING CODE IS INSERTED AT THE END OF THE PREVIOUSLY          96000013
*  GENERATED EXTRACT SEGMENTS.THIS CODE IS FOLLOWED BY THE REQUIRED     96080013
*  CONSTANTS WHICH WERE GENERATED INTO THE EXTRACT AREA AT THE START.   96160013
*                                                                       96240013
OMEND    BR    RO                  RETURN TO NETWORK                    96320013
*                                                                       96400013
*** CONSTANTS                                                           96480013
*                                                                       96560013
KOMZERO  DC    X'F000F000'         USED TO ZERO DISPLACEMENT FIELDS     96640013
K256     DC    A(256)              CONSTANT OF 256                      96720013
K12      DC    H'12'                                                    96800013
K16      DC    H'15'                                                    96840018
*                                                                       96880013
*** WORK AREAS                                                          96960013
*                                                                       97040013
WOMHOLD  DS    1F                  USED TO CONTAIN DISP FIELD FOR ORING 97120013
WOMRETNR DS    1F                  USED TO SAVE REGISTER SAVE ADDRESS   97200013
*                                                                       97280013
         EJECT                                                          97280418
LONGINIT DS    0F                                                       97280818
*                                                                       97281218
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT UNPACKED DECIMAL        97281618
* FIELDS WHICH ARE ASCENDING AND WHOSE LENGTHS ARE BETWEEN              97282018
* 17 AND 32 BYTES                                                       97282418
*                                                                       97282818
OMCASE7L NC    OMUDLA+2(4),KOMZERO      ZERO DISPLACEMENT               97283218
         NC    OMUDLA+8(4),KOMZERO      FIELDS IN CODE                  97283618
         NC    OMUDLA+14(4),KOMZERO     TO BE INITIALIZED               97284018
         NC    OMUDLA+20(4),KOMZERO                                     97284418
         NC    OMUDLA+26(2),KOMZERO                                     97284818
         NC    OMUDLA+30(2),KOMZERO                                     97285218
         NC    OMUDLA1+2(2),KOMZERO                                     97285618
         NC    OMUDLA1+6(2),KOMZERO                                     97286018
         NC    OMUDLA1+10(2),KOMZERO                                    97286418
         NC    OMUDLA1+14(4),KOMZERO                                    97286818
         NC    OMUDLA1+20(2),KOMZERO                                    97287218
         NC    OMUDLA1+24(2),KOMZERO                                    97287618
         SR    RD,RD                    ZERO REGISTER                   97288018
         IC    RD,3(0,RI)               BYTE PORTION OF LENGTH OF CF    97288418
         SH    RD,K16                   SUBTRACT 16                     97288818
         LA    RE,1(0,RD)               ADD ONE FOR ROUNDING            97289218
         SRL   RE,1                     DIVIDE BY TWO                   97289618
         LR    RC,RE                    SAVE L1 FIELD FOR FIRST PACK    97290018
*                                       INSTRUCTION                     97290418
         SLL   RE,4                     MOVE TO POSITION FOR L1 FIELD   97290818
         BCTR  RD,0                     DECREMENT BY ONE TO OBTAIN L2   97291218
         OR    RE,RD                    COMBINE L1 AND L2 IN ONE BYTE   97291618
         STC   RE,OMUDLA+1              SET LENGTH FIELDS IN FIRST PACK 97292018
         LA    RE,7(0,RC)               L FIELD FOR                     97292418
         STC   RE,OMUDLA1+13            XC INSTRUCTION                  97292818
         ST    RK,WOMHOLD               DISP IN THE EXTRACTED PORTION   97293218
         OC    OMUDLA(4),WOMHOLD        D1 FIELD IN FIRST PACK          97293618
         OC    OMUDLA1+8(4),WOMHOLD     D FIELD IN XI                   97294018
         OC    OMUDLA1+22(4),WOMHOLD    D FIELD IN OI                   97294418
         LA    RE,1(0,RK)               OBTAIN D1 FIELD                 97294818
         ST    RE,WOMHOLD               FOR                             97295218
         OC    OMUDLA1+12(4),WOMHOLD    XC INSTRUCTION                  97295618
         LA    RE,8(RC,RK)              OBTAIN D1 FIELD                 97296018
         ST    RE,WOMHOLD               FOR                             97296418
         OC    OMUDLA+12(4),WOMHOLD     UNPK INSTRUCTION                97296818
         LA    RE,1(RC,RK)              OBTAIN D1 FILD                  97297218
         ST    RE,WOMHOLD               FOR                             97297618
         OC    OMUDLA+18(4),WOMHOLD     MVO INSTRUCTION                 97298018
         OC    OMUDLA+4(2),0(RI)        D2 FIELD IN FIRST PACK          97298418
         LH    RE,0(RI)                 OBTAIN DISP TO CF               97298818
         LA    RE,1(RE,RD)              CALCULATE D2 FOR SECOND PACK    97299218
         ST    RE,WOMHOLD               INIT SECOND                     97299618
         OC    OMUDLA+8(4),WOMHOLD      PACK INSTRUCTION                97300018
         ST    RG,WOMHOLD               DISP TO PACKINGBUFFER           97300418
         OC    OMUDLA+6(4),WOMHOLD      D1 FIELD FOR SECOND PACK        97300818
         OC    OMUDLA+20(4),WOMHOLD     D2 FIELD FOR MVO                97301218
         LA    RE,8(0,RG)               OBTAIN DISPLACEMENT TO LAST     97301618
         ST    RE,WOMHOLD               BYTE OF THE PACKING BUFFER      97302018
         OC    OMUDLA+14(4),WOMHOLD     D2 FIELD FOR UNPK               97302418
         OC    OMUDLA+24(4),WOMHOLD     D FIELD IN FIRST TM             97302818
         OC    OMUDLA1(4),WOMHOLD       D FIELD IN SECOND TM            97303218
         ST    RH,WOMHOLD               DISP TO STRING OF FFS           97303618
         OC    OMUDLA1+14(4),WOMHOLD    D2 FIELD IN XC                  97304018
         LA    RE,54(0,RF)              INC DISP IN EXTRACT ROUTINE     97304418
         ST    RE,WOMHOLD               DISP FOR BZ AND BO              97304818
         OC    OMUDLA+28(4),WOMHOLD     D FIELD IN BZ                   97305218
         OC    OMUDLA1+4(4),WOMHOLD     D FIELD IN BO                   97305618
         LA    RE,4(0,RE)               INCREMENT BY FOUR               97306018
         ST    RE,WOMHOLD               DISP FOB B INSTRUCTION          97306418
         OC    OMUDLA1+18(4),WOMHOLD    D FIELD IN B INSTRUCTION        97306818
         MVC   0(58,RM),OMUDLA          MOVE SEGMENT TO EXTRACT ROUTINE 97307218
OMZDLEX  LA    RF,58(0,RF)              INCREMENT DISP IN EXT ROUTINE   97307618
         LA    RM,58(0,RM)              INCREMENT ADDRESS OF EXT ROUT   97308018
         LR    RE,RC                    CALCULATE ACTUAL LENGTH OF      97308418
         LA    RE,9(0,RE)               EXTRACTED PORTION OF CF         97308818
         B     OMNOBIT1                                                 97309218
         EJECT                                                          97309618
*                                                                       97310018
* INITIALIZES THE CODE WHICH IS USED TO EXTRACT UNPACKED DECIMAL        97310418
* FIELDS WHICH ARE DESCENDING AND WHOSE LENGTHS ARE BETWEEN             97310818
* 17 AND 32 BYTES                                                       97311218
*                                                                       97311618
OMCASE8L NC    OMUDLD+2(4),KOMZERO      ZERO DISPLACEMENT               97312018
         NC    OMUDLD+8(4),KOMZERO      FIELDS IN CODE                  97312418
         NC    OMUDLD+14(4),KOMZERO     TO BE INITIALIZED               97312818
         NC    OMUDLD+20(4),KOMZERO                                     97313218
         NC    OMUDLD+26(2),KOMZERO                                     97313618
         NC    OMUDLD+30(2),KOMZERO                                     97314018
         NC    OMUDLD1+2(2),KOMZERO                                     97314418
         NC    OMUDLD1+6(2),KOMZERO                                     97314818
         NC    OMUDLD1+10(2),KOMZERO                                    97315218
         NC    OMUDLD1+14(2),KOMZERO                                    97315618
         NC    OMUDLD1+18(2),KOMZERO                                    97316018
         NC    OMUDLD1+22(4),KOMZERO                                    97316418
         SR    RD,RD                    ZERO REGISTER                   97316818
         IC    RD,3(0,RI)               BYTE PORTION OF LENGTH OF CF    97317218
         SH    RD,K16                   SUBTRACT 16                     97317618
         LA    RE,1(0,RD)               ADD ONE FOR ROUNDING            97318018
         SRL   RE,1                     DIVIDE BY TWO                   97318418
         LR    RC,RE                    SAVE L1 FIELD FOR FIRST PACK    97318818
*                                       INSTRUCTION                     97319218
         SLL   RE,4                     MOVE TO POSITION FOR L1 FIELD   97319618
         BCTR  RD,0                     DECREMENT BY ONE TO OBTAIN L2   97320018
         OR    RE,RD                    COMBINE L1 AND L2 IN ONE BYTE   97320418
         STC   RE,OMUDLD+1              SET LENGTH FIELDS IN FIRST PACK 97320818
         LA    RE,7(0,RC)               L FIELD FOR                     97321218
         STC   RE,OMUDLD1+21            XC INSTRUCTION                  97321618
         ST    RK,WOMHOLD               DISP IN THE EXTRACTED PORTION   97322018
         OC    OMUDLD(4),WOMHOLD        D1 FIELD IN FIRST PACK          97322418
         OC    OMUDLD1+8(4),WOMHOLD     D FIELD IN OI                   97322818
         OC    OMUDLD1+16(4),WOMHOLD    D FIELD IN XI                   97323218
         LA    RE,1(0,RK)               OBTAIN D1 FIELD                 97323618
         ST    RE,WOMHOLD               FOR                             97324018
         OC    OMUDLD1+20(4),WOMHOLD    XC INSTRUCTION                  97324418
         LA    RE,8(RC,RK)              OBTAIN D1 FIELD                 97324818
         ST    RE,WOMHOLD               FOR                             97325218
         OC    OMUDLD+12(4),WOMHOLD     UNPK INSTRUCTION                97325618
         LA    RE,1(RC,RK)              OBTAIN D1 FIELD                 97326018
         ST    RE,WOMHOLD               FOR                             97326418
         OC    OMUDLD+18(4),WOMHOLD     MVO INSTRUCTION                 97326818
         OC    OMUDLD+4(2),0(RI)        D2 FIELD IN FIRST PACK          97327218
         LH    RE,0(RI)                 OBTAIN DISP TO CF               97327618
         LA    RE,1(RE,RD)              CALCULATE D2 FOR SECOND PACK    97328018
         ST    RE,WOMHOLD               INIT SECOND                     97328418
         OC    OMUDLD+8(4),WOMHOLD      PACK INSTRUCTION                97328818
         ST    RG,WOMHOLD               DISP TO PACKING BUFFER          97329218
         OC    OMUDLD+6(4),WOMHOLD      D1 FIELD FOR SECOND PACK        97329618
         OC    OMUDLD+20(4),WOMHOLD     D2 FIELD FOR MVO                97330018
         LA    RE,8(0,RG)               OBTAIN DISPLACEMENT TO LAST     97330418
         ST    RE,WOMHOLD               BYTE OF THE PACKING BUFFER      97330818
         OC    OMUDLD+14(4),WOMHOLD     D2 FIELD FOR UNPK               97331218
         OC    OMUDLD+24(4),WOMHOLD     D FIELD IN FIRST TM             97331618
         OC    OMUDLD1(4),WOMHOLD       D FIELD IN SECOND TM            97332018
         ST    RH,WOMHOLD               DISP TO STRING OF FFS           97332418
         OC    OMUDLD1+22(4),WOMHOLD    D2 FIELD IN XC                  97332818
         LA    RE,48(0,RF)              INC DISP IN EXTRACT ROUTINE     97333218
         ST    RE,WOMHOLD               DISP FOR BZ AND BO              97333618
         OC    OMUDLD+28(4),WOMHOLD     D FIELD IN BZ                   97334018
         OC    OMUDLD1+4(4),WOMHOLD     D FIELD IN BO                   97334418
         LA    RE,10(0,RE)              INCREMENT BY TEN                97334818
         ST    RE,WOMHOLD               DISP FOR B INSTRUCTION          97335218
         OC    OMUDLD1+12(4),WOMHOLD    D FIELD IN B INSTRUCTION        97335618
         MVC   0(58,RM),OMUDLD          MOVE SEGMENT TO EXTRACT ROUTINE 97336018
         B OMZDLEX                                                      97336418
         EJECT                                                          97336818
*                                                                       97337218
* THE FOLLOWING CODE IS USED TO EXTRACT UNPACKED DECIMAL                97337618
* FIELDS WHICH ARE ASCENDING AND WHOSE LENGTHS ARE BETWEEN              97338018
* 17 AND 32 BYTES                                                       97338418
*                                                                       97338818
OMUDLA   PACK  0(1,RD),0(1,RC)          PACK THE FIRST (LENGTH-16)      97339218
*                                       BYTES OF CF INTO EXTRACT POS    97339618
         PACK  0(9,RM),0(16,RC)         PACK REMAINING 16 BYTES         97340018
*                                       INTO PACKING BUFFER             97340418
         UNPK  0(1,RD),0(1,RM)          SIGN BYTE FROM BUF TO EXT POS   97340818
         MVO   0(8,RD),0(8,RM)          REMAINDER OF PACK BUF TO EXT PO 97341218
         TM    0(RM),X'01'              TEST SIGN IN PACK BUF           97341618
         BZ    0(0,RM)                  BRANCH IF PLUS                  97342018
OMUDLA1  TM    0(RM),X'0F'              TEST SIGN IN PACK BUF           97342418
         BO    0(0,RM)                  BRANCH IF PLUS                  97342818
         XI    0(RD),X'0F'              INVERT LAST 4 BITS OF BYTE ONE  97343218
         XC    0(1,RD),0(RM)            INVERT REMAINDER OF FIELD       97343618
         B     0(0,RM)                  BRANCH *+8                      97344018
         OI    0(RD),X'F0'              SET SIGN TO PLUS                97344418
         EJECT                                                          97344818
*                                                                       97345218
* THE FOLLOWING CODE IS USED TO EXTRACT UNPACKED DECIMAL                97345618
* FIELDS WHICH ARE DESCENDING AND WHOSE LENGTHS ARE BETWEEN             97346018
* 17 AND 32 BYTES                                                       97346418
*                                                                       97346818
OMUDLD   PACK  0(1,RD),0(1,RC)          PACK THE FIRST (LENGTH-16)      97347218
*                                       BYTES OF CF INTO EXTRACT POS    97347618
         PACK  0(9,RM),0(16,RC)         PACK REMAINING 16 BYTES         97348018
*                                       INTO PACKING BUFFER             97348418
         UNPK  0(1,RD),0(1,RM)          SIGN BYTE FROM BUF TO EXT POS   97348818
         MVO   0(8,RD),0(8,RM)          REMAINDER OF PACK BUF TO EXT PO 97349218
         TM    0(RM),X'01'              TEST SIGN IN PACK BUF           97349618
         BZ    0(0,RM)                  BRANCH IF PLUS TO XI            97350018
OMUDLD1  TM    0(RM),X'0F'              TEST SIGN IN PACK BUF           97350418
         BO    0(0,RM)                  BRANCH IF PLUS TO XI            97350818
         OI    0(RD),X'F0'              SET SIGN TO PLUS                97351218
         B     0(0,RM)                  BRANCH *+14                     97351618
         XI    0(RD),X'0F'              INVERT LAST FOUR BITS OF BYTE 1 97352018
         XC    0(0,RD),0(RM)            INVERT REMAINDER OF FIELD       97352418
         EJECT                                                          97360013
         SMPPI                                                          97440013
         END                                                            97520013
