         TITLE       'IERAOO - OS/360 SORT/MERGE - 360S-SM023 04/18/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERAOO                                                 00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 0                                                  01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: DISK SORT ALGORITHM ASSIGNMENT.             01400013
*   THIS MODULE INITIALIZES THE RUNNING PROGRAM FOR THE FOLLOWING:      01600013
*        ITEMS AS'                                                      01800013
*         STARTING AND ENDING DRUM ADDRESSES IN THE SORT TABLE.         02000013
*         INITIALIZING POINTERS AND BLOCKING FOR ADDRESSES.             02200013
*         ESTABLISHING SIZE OF SORT TABLE (NO. OF AREAS INVOLVED)       02400013
         SPACE 2                                                        02600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT: N/A           02800013
         SPACE 2                                                        03000013
*LIST OF MACROS USED BY MODULE: N/A                                     03200013
         SPACE 2                                                        03400013
*ENTRY POINTS:                                                          03600013
         SPACE 1                                                        03800013
*        ENTRY IERMOI                                                   04000013
         SPACE 2                                                        04200013
*INPUT - PPI FIELDS REFERENCED:                                         04400013
         SPACE 1                                                        04600013
*   PPINDSKA    PPISTAR    PPIENDAR                                     04800013
*   PPILAB01    PPISEQCT   PPISW1+3                                     05000013
*   PPIMRGOP                                                            05200013
         SPACE 2                                                        05400013
*OUTPUT - PPI FIELDS ALTERED OR INITIALIZED:                            05600013
         SPACE 1                                                        05800013
*   PPIMRGMX    PPIWKARE                                                06000013
         SPACE 2                                                        06200013
*EXTERNAL ROUTINES: N/A                                                 06400013
         SPACE 2                                                        06600013
*EXTERNAL PARAMETERS:                                                   06800013
         SPACE 1                                                        07000013
*        DSECT IERRCA              MODEL PPI.                           07200013
*        DSECT IERRO3              MODEL RUNNING PROG.                  07400013
         SPACE 2                                                        07600013
*EXITS-NORMAL:                                                          07800013
         SPACE 1                                                        08000013
*   EXIT TO NEXT ASSIGNMENT ROUTINE.                                    08200013
         SPACE 2                                                        08400013
*EXITS-ERROR: N/A                                                       08600013
         SPACE 2                                                        08800013
*TABLES/WORK AREAS: N/A                                                 09000013
         SPACE 2                                                        09200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  09400013
         SPACE 2                                                        09600013
*NOTES: THIS MODULE IS RESTRICTED TO 2301 DRUM OPERATIONS ONLY.         09800013
         EJECT                                                          10000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            10200013
         SPACE 1                                                        10400013
RA       EQU   0                   CONTENTS IN - N/A                    10600013
*                                  USED - N/A                           10800013
*                                  CONTENTS OUT- N/A                    11000013
RB       EQU   1                   CONTENTS IN - CHARACTER COUNT        11200013
*                                  USED - CHARACTER COUNT               11400013
*                                  CONTENTS OUT- CHARACTER COUNT        11600013
RC       EQU   2                   CONTENTS IN - LOW BUFFER ADDRESS     11800013
*                                  USED - WORK                          12000013
*                                  CONTENTS OUT- EMPTY BUFFER ADDRESS   12200013
RD       EQU   3                   CONTENTS IN - IOB LIST INCREMENT     12400013
*                                  USED - ADDRESSING IOB                12600013
*                                  CONTENTS OUT- IOB LIST INCREMENT     12800013
RE       EQU   4                   CONTENTS IN - FINAL OR NORMAL EOS    13000013
*                                  USED - WORK                          13200013
*                                  CONTENTS OUT- FINAL OR NORMAL EOS    13400013
RF       EQU   5                   CONTENTS IN - N/A                    13600013
*                                  USED - WORK                          13800013
*                                  CONTENTS OUT- N/A                    14000013
RG       EQU   6                   CONTENTS IN - N/A                    14200013
*                                  USED - WORK                          14400013
*                                  CONTENTS OUT- N/A                    14600013
RH       EQU   7                   CONTENTS IN - N/A                    14800013
*                                  USED - WORK                          15000013
*                                  CONTENTS OUT- N/A                    15200013
RI       EQU   8                   CONTENTS IN - N/A                    15400013
*                                  USED - WORK                          15600013
*                                  CONTENTS OUT- N/A                    15800013
RJ       EQU   9                   CONTENTS IN - N/A                    16000013
*                                  USED - WORK                          16200013
*                                  CONTENTS OUT- N/A                    16400013
RK       EQU   10                  CONTENTS IN - N/A                    16600013
*                                  USED - DCB BASE REG.                 16800013
*                                  CONTENTS OUT- N/A                    17000013
RL       EQU   11                  CONTENTS IN - PROGRAM BASE           17200013
*                                  USED - PROGRAM BASE                  17400013
*                                  CONTENTS OUT- NEXT PROGRAM BASE      17600013
RM       EQU   12                  CONTENTS IN - EQUAL/EXTRACT ADDR     17800013
*                                  USED - IOB BASE REG.                 18000013
*                                  CONTENTS OUT- EQUAL/EXTRACT ADDR     18200013
RN       EQU   13                  CONTENTS IN - PPI BASE               18400013
*                                  USED - PPI BASE                      18600013
*                                  CONTENTS OUT- PPI BASE               18800013
RO       EQU   14                  CONTENTS IN - ALGORITHM RETURN REG   19000013
*                                  USED - N/A                           19200013
*                                  CONTENTS OUT- RETURN REG             19400013
RP       EQU   15                  CONTENTS IN - N/A                    19600013
*                                  USED - N/A                           19800013
*                                  CONTENTS OUT- N/A                    20000013
         SPACE 1                                                        20200013
         SPACE 2                                                        20400013
IERAOO   CSECT                                                          20600013
*                                                                A27992 20700000
         USING DIERROO,RJ                                               20800013
         USING *,RL                                                     21000013
         USING IERRCA,RN                                                21200013
         USING DIERRMA,RO                                               21400013
         SPACE 2                                                        21600013
IERMOI   LR    RL,RP                                                    21800013
         L     RJ,PPIALG+4         SET BASE REGESTER FOR RUNNING DSECT. 22000013
AOOASSMT LH    RI,PPINDSKA         GET TOTAL NUMBER OF AREAS.           22200013
         BCTR  RI,0                REDUCE BY 1.                         22400013
         LA    RE,TABLE+4          GET ADDR OF FST SLOT IN TBL TO FILL  22600013
         LA    RF,PPISTAR          GET ADDR OF FST AREA TO FILL WITH    22800013
AOOLOOPA MVC   0(8,RE),0(RF)       FILL TABLE SLOT                      23000013
         LA    RE,20(0,RE)         BUMP ADDR TO NXT SLOT IN TABLE       23200013
         LA    RF,8(0,RF)          BUMP ADDR TO NXT AREA IN PPI         23400013
         BCT   RI,AOOLOOPA         LOOP IF TABLE NOT FULL.              23600013
         MVC   PPIDEPHO(8),PPISTAR PUT FIRST SEQ WRITE ADDR IN PPI.     23800013
         SPACE 2                                                        24000013
*    * LOAD TABLE WITH STRTG ADDRS FOR DICTY WRTS,FR ENDG ADDRS IN PPI* 24200013
         SPACE 2                                                        24400013
         LH    RI,PPINDSKA         GET TOTAL NUMBER OF AREAS.           24600013
         BCTR  RI,0                REDUCE BY 1.                         24800013
         LA    RE,TABLE+12         GET ADDR OF FST SLOT IN DIRECTORY    25000013
         LA    RF,PPIENDAR         GET ADDR OF FST END ADDR IN PPI      25200013
AOOLOOPB MVC   0(8,RE),0(RF)       FILL TABLE SLOT                      25400013
         LA    RE,20(0,RE)         BUMP ADDR TO NXT SLOT IN TABLE       25600013
         LA    RF,8(0,RF)          BUMP ADDR TO NXT AREA IN PPI         25800013
         BCT   RI,AOOLOOPB         LOOP IF TABLE NOT FULL.              26000013
         MVC   WCLBKAR(8),PPISTAR  BLOCK FST AREA IN DICTY              26200013
         SPACE 2                                                        26400013
*  REDUCE ALL ENDG ADDRS IN PPI BY 2 TRACKS                             26600013
         SPACE 2                                                        26800013
         LH    RI,PPINDSKA         GET TOTAL NUMBER OF AREAS.           27000013
         BCTR  RI,0                REDUCE BY 1.                         27200013
         LA    RF,PPIENDAR         GET ADDR OF FST ENDG ADDR IN PPI     27400013
AOOLOOPC SR    RG,RG               CLEAR REG.                           27600013
         IC    RG,6(0,RF)          GET HEAD NO. FROM ENDG DISK ADDR     27800013
         LA    RH,2                GET CONSTANT.                        28000013
         SR    RG,RH               REDUCE TRACKS FOR DIRECTORY.         28200013
         STC   RG,6(0,RF)          RESTORE HEAD NO. TO ENDG ADDR IN PPI 28400013
         LA    RF,8(0,RF)          BUMP TO NEXT PPI AREA ADDR.          28600013
         BCT   RI,AOOLOOPC         LOOP IF ALL ENDG AREAS NOT REDUCED.  28800013
         SPACE 2                                                        29000013
         LA    RG,TABLE            GET TABLE ADDR.                      29200013
         ST    RG,WPOINT           SET POINTER TO FIRST TABLE POSITION. 29400013
         LA    RI,20                                                    29600013
         LH    RF,PPINDSKA         GET TOTAL NUMBER OF AREAS.           29800013
         BCTR  RF,0                REDUCE BY 1.                         30000013
         MR    RE,RI               MLTPY RI(20)XRF (NO.AREAS)=RF PROD.  30200013
         AR    RG,RF               ADD TBL LGTH(PROD)TO BEG TABLE ADDR. 30400013
         ST    RG,WTBLLIMT         RESTRICT SORT TBL TO # AREAS LESS 1. 30600013
         BR    RO                                                       30800013
         SPACE 2                                                        31000013
         EJECT                                                          31200013
*        THIS IS A DUMMY RUNNING MODULE FOR PURPOSES OF LINK ONLY       31400013
         SPACE 2                                                        31600013
DIERROO  DSECT                                                          31800013
         USING *,RL                SET BASE RG                          32000013
IERDOK   B     ROOEOF              GO TO OUTPUT END OF FILE.            32200013
         B     ROOEOA              GO TO END OF AREA                    32400013
         B     ROOEOASQ            GO TO END OF AREA-END OF SEQUENCE.   32600013
ROOEOSQ  L     RE,WPOINT           GET TABLE AREA ADDRESS.              32800013
         L     RF,0(0,RE)          GET AREA KEY (EG.0,1,2,3,4,OR5)      33000013
         SLL   RF,1                CALC. DISPLC.(AREA KEY X CTR SIZE)   33200013
         LA    RG,PPISEQCT         GET ST PT OF COUNTERS                33400013
         LH    RH,0(RF,RG)         GET DATA FROM COUNTER                33600013
         LA    RH,1(0,RH)          INCRMT CTR                           33800013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   34000013
         L     RE,WBLKCT           GET DIRECTORY BLOCKING COUNTER.      34200013
         BCT   RE,ROODRBLK         REDUCE BLOCKING COUNTER.             34400013
         SPACE 2                                                        34600013
         L     RE,WPOINT                                                34800013
         MVC   4(8,RE),PPIDEPHO    SV NXT SEQ IN TBL                    35000013
         MVC   PPIDIRAD(8),12(RE)  PUT NXT DICTY BLOCK ADDR IN PPI      35200013
         MVC   PPIPDWA(64),WCLBKAR    PUT DICTY BLKG AREA IN PPI        35400013
         L     RL,PPIWRT+4         SET WRITE ROUTINE BASE REGESTER.     35600013
         BAL   RO,12(0,RL)         GO TO WRITE ROUTINE.                 35800013
         SPACE 1                                                        36000013
         LA    RE,8                RESET BLKG CTR TO 8                  36200013
         ST    RE,WBLKCT           RESET BLKG CTR TO 8                  36400013
         L     RG,WPOINT           GET AREA ADDR FROM TABLE             36600013
         CLI   19(RG),X'52'        HAVE 82 DIRECTORYS BEEN WRITTEN.     36800013
         BNE   ROOSMTK             BRANCH IF NO.                        37000013
         SPACE 2                                                        37200013
         L     RH,0(0,RG)          YES,TRACK IS FILLED.                 37400013
         SLL   RH,3                CALC.DISPLC(AREA X DSK ADDR SIZE -8) 37600013
         LA    RI,PPIENDAR         GET START.ADDR IN PPI                37800013
         AR    RI,RH               ADD DISPLC.                          38000013
         CLC   4(3,RI),PPIDEPHO+4  HAS SEQ.AREA REACHED END ADDR IN PPI 38200013
         BNH   ROONOTRK            BRANCH IF NO TRACKS AVAILABLE.       38400013
         SPACE 2                                                        38600013
         MVI   19(RG),X'01'                                             38800013
         CLI   6(RI),X'00'         IS TRACK NO.= 0{                     39000013
         BE    ROOABORT            ABORT JOB IF ZERO.                   39200013
         SPACE 1                                                        39400013
         IC    RH,6(0,RI)          GET HD NO. FROM PPI (ENDAR)          39600013
         LA    RH,1(0,RH)          ADD 1                                39800013
         STC   RH,18(0,RG)         STORE IN TABLE (NEW DICTRY)          40000013
         IC    RG,6(0,RI)          GET PPIENDAR TRACK NUMBER.           40200013
         BCTR  RG,0                REDUCE TRACK NUMBER.                 40400013
         STC   RG,6(0,RI)          STOW NEW TRACK IN PPIENDAR.          40600013
         B     ROOGOB              GO TO INCREMENT POINTER.             40800013
         SPACE 2                                                        41000013
ROOSMTK  IC    RH,19(0,RG)         GET RECORD NUMBER.                   41200013
         LA    RH,1(0,RH)          INCREMENT BY 1.                      41400013
         STC   RH,19(0,RG)         STOW NEW RECORD NUMBER.              41600013
         B     ROOGOB              GO TO INCREMENT POINTER.             41800013
         SPACE 2                                                        42000013
ROODRBLK ST    RE,WBLKCT           RESTORE DIRECTORY BLOCKING COUNTER.  42200013
         LA    RF,8                CALC.DISPLC.TO REACH PROPER ADDR IN  42400013
         SR    RF,RE                 DICTY BLOCK,TO FILL NXT BLOCK      42600013
         SLL   RF,3                MLTPY TIMES ADDR SIZE (8)            42800013
         LA    RG,WCLBKAR          GET ST PT OF DICTY BLKG AREA         43000013
         AR    RG,RF               DECIDE NEXT SEQ ADDR AREA IN TABLE.  43200013
         MVC   0(8,RG),PPIDEPHO    INSERT ADDR.                         43400013
ROODEBL  L     RL,PPIDEB+4         GET DEBLOCK ROUTINE ADDRESS.         43600013
         B     8(RL)               GO TO DEBLOCK.                       43800013
         SPACE 2                                                        44000013
ROOGOB   L     RE,WPOINT           GET TABLE POINTER.                   44200013
         LA    RE,20(0,RE)         INCREMT TABLE POINTER                44400013
         ST    RE,WPOINT           INCREMT TABLE POINTER                44600013
         CL    RE,WTBLLIMT         IS TABLE FINISHED.                   44800013
         BE    ROOSETPT            BRANCH TO RESET POINTER IF YES.      45000013
         SPACE 1                                                        45200013
ROONXT1  L     RE,WPOINT           GET TABLE POINTER.                   45400013
         MVC   PPIDEPHO(8),4(RE)   STOW NEXT SEQ ADDR IN PPI.           45600013
         MVC   WCLBKAR(8),4(RE)                                         45800013
         TM    KSWA7E4,X'01'       DID LAST 'WRITE'HAVE AREA ENOUGH{    46000013
         BO    ROODEBL             GET NEXT SEQ FOR DEBLK IF SW IS ON.  46200013
         SPACE 1                                                        46400013
         OI    KSWA7E4,X'01'       TURN SWITCH ON.                      46600013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE.       46800013
         B     0(0,RL)             GO TO WRITE ROUTINE                  47000013
         SPACE 2                                                        47200013
ROOSETPT LA    RG,TABLE            SET POINTER TO 1ST POS IN SORT       47400013
         ST    RG,WPOINT             TABLE                              47600013
         B     ROONXT1             GO TO MAIN LINE.                     47800013
         SPACE 2                                                        48000013
ROOEOF   L     RE,WPOINT           GET AREA ADDR FROM TABLE.            48200013
         L     RF,0(0,RE)          GET AREA KEY                         48400013
         SLL   RF,1                CALC DISPLC IN CTR AREA IN PPI       48600013
         LA    RG,PPISEQCT         GET ST PT OF CTRS                    48800013
         LH    RH,0(RF,RG)         GET NO.FR CTR                        49000013
         LA    RH,1(0,RH)          INCRMT CTR                           49200013
         STH   RH,0(RF,RG)         RESTORE CTR TO PPI                   49400013
         MVC   PPIDIRAD(8),12(RE)  PUT DIRECTORY ADDR IN PPI.           49600013
         MVC   PPIPDWA(64),WCLBKAR PUT BLOCKING AREA IN PPI.            49800013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE.       50000013
         BAL   RO,12(0,RL)         GO TO WRITE DIRECTORY.               50200013
         SPACE 1                                                        50400013
         LH    RI,PPINDSKA                                              50600013
         SR    RE,RE                                                    50800013
         LA    RG,PPISEQCT                                              51000013
ROOLOOPD LH    RF,0(0,RG)          GET SEQUENCE COUNT.                  51200013
         AR    RE,RF               SUM THE SEQUENCE COUNTS.             51400013
         LA    RG,2(0,RG)          BUMP TO NXT CTR                      51600013
         BCT   RI,ROOLOOPD         BRANCH IF ALL NOT ADDED.             51800013
         SPACE 1                                                        52000013
         MVC   PPIENDAR(48),PPIDSKED                                    52200013
         LH    RH,PPIMRGMX                                              52400013
         LA    RH,1(0,RH)         PLUS ONE                              52600013
         STC   RH,PPIBDSVA                                              52800013
         CH    RE,PPIMRGMX         IS SUM HIGHER THAN MERGE MAX?        53000013
         BH    ROOGOF              BRANCH TO CLOSE IF YES.              53200013
         SPACE 1                                                        53400013
         STH   RE,PPIMRGOP                                              53600013
         LA    RB,4              SET REGESTER TO 4                      53800013
         B     ROOBYPAS                                                 54000013
ROOGOF   SR    RB,RB               CLEAR REG TO ZERO.                   54200013
ROOBYPAS L     RP,PPIADSSC         LOAD ADDRESS OF SSC                  54400013
         B     20(0,RP)            GO TO SORT SYSTEM CONTROL.           54600013
         SPACE 2                                                        54800013
ROOEOA   NI    KSWA7E4,X'00'       TURN SWITCH OFF.                     55000013
ROOEOASQ L     RE,WPOINT           GET POINTER.                         55200013
         L     RF,0(0,RE)                                               55400013
         SLL   RF,1                                                     55600013
         LA    RG,PPISEQCT                                              55800013
         LH    RH,0(RF,RG)                                              56000013
         LA    RH,1(0,RH)                                               56200013
         STH   RH,0(RF,RG)                                              56400013
         MVC   PPIDIRAD(8),12(RE)  PUT DIRECTORY ADDR IN PPI.           56600013
         MVC   PPIPDWA(64),WCLBKAR                                      56800013
         L     RL,PPIWRT+4         SET BASE REGESTER.                   57000013
         BAL   RO,12(0,RL)         GO TO WRITE ROUTINE.                 57200013
         SPACE 1                                                        57400013
         LA    RE,8                                                     57600013
         ST    RE,WBLKCT                                                57800013
ROONOTRK LA    RF,20               SET UP TO CHECK FOR LAST AREA.       58000013
         LA    RE,TABLE                                                 58200013
         ALR   RE,RF                                                    58400013
         CL    RE,WTBLLIMT                                              58600013
         BNE   ROOGOH              BRANCH ON MORE AREAS REMAINING.      58800013
         SPACE 2                                                        59000013
ROOABORT L     RO,PPIRMA+4         SET MASSAGE BASE.                    59200013
         LM    RA,RB,MSGP1A02                                           59400013
         L     RP,PPIADSSC                                              59600013
         BAL   RO,12(0,RP)         GO TO PRINT MESSAGE.                 59800013
         SPACE 1                                                        60000013
*SORT CAPACITY REACHED                                                  60200013
         SPACE 1                                                        60400013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   60600013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        60800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   61000013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      61200013
         SPACE 1                                                        61400013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             61600013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 61660000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 61720000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      61800013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             62000013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                62200013
         BO    ROI031                                                   62400013
         SPACE 1                                                        62600013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      62800013
         SR    RO,RO                                                    63000013
         DR    RO,RA                 RCDS. IN BLOCK                     63200013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         63400013
         BH    ROI032                NEGATIVE                           63600013
         SPACE 1                                                        63800013
         AR    RB,RP               ADD B TO CNT                         64000013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           64200013
         BNL   ROI033                                                   64400013
         SPACE 1                                                        64600013
         LR    RB,RP               SET CNT TO B                         64800013
         B     ROI033                                                   65000013
         SPACE 2                                                        65200013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      65400013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           65600013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       65800013
         OI    PPIWKARE+15,X'F0'                                        66000013
         SPACE 2                                                        66200013
         L     RO,PPIRMA+4                                              66400013
         LM    RA,RB,MSGP1A06                                           66600013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                66800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        67000013
         BAL   RO,12(0,RP)                                              67200013
         SPACE 1                                                        67400013
         L     RP,PPIADSSC                                              67600013
         B     16(0,RP)            GO TO ABORT JOB.                     67800013
         SPACE 2                                                        68000013
ROOGOH   L     RE,WPOINT           GET POINTER.                         68200013
         L     RG,WPOINT                                                68400013
         LA    RG,20(0,RG)                                              68600013
         CL    RG,WTBLLIMT         IS TABLE LIMIT REACHED.              68800013
         BE    ROORESET            GO TO RESET TABLE POINTER.           69000013
         SPACE 1                                                        69200013
         L     RF,WTBLLIMT         GET TABLE LIMIT.                     69400013
         LA    RG,20                                                    69600013
         SLR   RF,RG               SET LIMIT OF TABLE.                  69800013
         MVC   0(20,RE),0(RF)                                           70000013
ROOGOG   L     RF,WTBLLIMT         GET TABLE LIMIT.                     70200013
         LA    RE,20                                                    70400013
         SLR   RF,RE                                                    70600013
         ST    RF,WTBLLIMT         STORE TABLE LIMIT MINUS 1.           70800013
         B     ROONXT1                                                  71000013
         SPACE 2                                                        71200013
ROORESET LA    RG,TABLE            GET TABLE ADDR TO RESET TO 1ST POS.  71400013
         ST    RG,WPOINT                                                71600013
         B     ROOGOG                                                   71800013
         SPACE 2                                                        72000013
         DS    0F                                                       72200013
WPOINT   DC    X'00000000'         SET UP POINTER                       72400013
         DS    0F                                                       72600013
WBLKCT   DC    X'00000008'         SET UP DIRECTORY BLK CTR.            72800013
         DS    0F                                                       73000013
WCLBKAR  DS    16F                 DICTY BLOCKING AREA=64 BYTES         73200013
         DS    0F                                                       73400013
WTBLLIMT DC    X'00000000'         SET UP TABLE LIMIT POINTER           73600013
         DS    0F                                                       73800013
KSWA7E4  DC    X'01'              SWITCH A7-E4 NORMALLY ON              74000013
         DS    0F                                                       74200013
TABLE    DC    X'00000000'         SET UP TABLE -FIRST AREA             74400013
         DS    4F                  SET UP TABLE -FIRST AREA             74600013
         DC    X'00000001'         SET UP TABLE -SECOND AREA            74800013
         DS    4F                  SET UP TABLE -SECOND AREA            75000013
         DC    X'00000002'         SET UP TABLE -THIRD AREA             75200013
         DS    4F                  SET UP TABLE -THIRD AREA             75400013
         DC    X'00000003'         SET UP TABLE -FOURTH AREA            75600013
         DS    4F                  SET UP TABLE -FOURTH AREA            75800013
         DC    X'00000004'         SET UP TABLE -FIFTH AREA             76000013
         DS    4F                  SET UP TABLE -FIFTH AREA             76200013
         DS    0F                                                       76400013
DIERRMA  DSECT                                                          76600013
*                                                                       76800013
*                                                                       77000013
* MODULE NAME ***IERRMA***                                              77200013
*                                                                       77400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        77600013
* PHASE 1 RUNNING PROGRAM.                                              77800013
         SPACE 1                                                        78000013
         COPY  RMAMAIN                                                  78200013
         EJECT                                                          78400013
         SMPPI                                                          78600013
         END                                                            78800013
         SMPPI                                                          79000013
