         TITLE 'IERAOP - OS/360 SORT/MERGE - 360-SM-023   05/06/65'     00100013
*MODULE NAME:*** IERAOP ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3 ASSIGNMENT ROUTINE FOR A 1-16 00600013
*   WAY MERGE NETWORK RUNNING PROGRAM NAMED *** IERROP *** (SEE DSECT)  00700013
*   WITH MULTIPLE CONTROL FIELDS. THE FUNCTION OF THIS MODULE IS TO SET 00800013
*   THE NETWORK COMPARE INSTRUCTIONS WITH A LENGTH AND DISPLACEMENT     00900013
*   ATTRIBUTE AND TO SET THE NETWORKS PHASE-2/PHASE-3 SWITCHES ACCORD-  01000013
*   ING TO THE PHASE .                                                  01100013
         SPACE 2                                                        01200013
*USED AS A DSECT IN'  N/A                                               01300013
*                                                                       01400013
*MACROS USED                                                            01500013
         SPACE 1                                                        01600013
*   SMPPI                                                               01700013
         SPACE 2                                                        01800013
*ENTRY POINTS:                                                          01900013
         SPACE 1                                                        02000013
*        ENTRY                     ENTRY FROM:                          02100013
*                                    CALLING SEQUENCE-                  02200013
*                                      LA   RP,VALUE                    02300013
*                                      BALR RO,RP                       02400013
         SPACE 2                                                        02500013
*INPUT: PPI FIELDS REFERENCED-                                          02600013
         SPACE 1                                                        02700013
*    PPINETM   PPIDDOL1                                                 02800013
*    PPISW1    PPIAXERT                                                 02900013
         SPACE 2                                                        03000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED- NONE                        03100013
         SPACE 1                                                        03200013
*                                                                       03300013
*                                                                       03400013
         SPACE 2                                                        03500013
*EXTERNAL ROUTINES:                                                     03600013
         SPACE 1                                                        03700013
*        EXTRN IERROP                                                   03800013
*        EXTRN IERRMC                                                   03900013
         SPACE 2                                                        04000013
*EXTERNAL PARAMETERS: NONE                                              04100013
         SPACE 1                                                        04200013
*EXITS: NORMAL                                                          04300013
         SPACE 1                                                        04400013
*        IERRC9                    CALLER ROUTINE FOR ASSIGNMENT RTN    04500013
         SPACE 2                                                        04600013
*EXITS: ERROR                                                           04700013
         SPACE 1                                                        04800013
*        IERRMC                    MESSAGE MODULE                       04900013
         SPACE 2                                                        05000013
*TABLES/WORK AREAS: N/A                                                 05100013
         SPACE 1                                                        05200013
         SPACE 2                                                        05300013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  05400013
         SPACE 2                                                        05500013
*NOTES: NONE                                                            05600013
         SPACE 1                                                        05700013
         SPACE 2                                                        05800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            05900013
         SPACE 1                                                        06000013
RA       EQU   0                   CONTENTS IN- N/A                     06100013
*                                  USE- UNUSED                          06200013
*                                  CONTENTS OUT- N/A                    06300013
RB       EQU   1                   CONTENTS IN- N/A                     06400013
*                                  USE- UNUSED                          06500013
*                                  CONTENTS OUT- N/A                    06600013
RC       EQU   2                   CONTENTS IN- N/A                     06700013
*                                  USE- UNUSED                          06800013
*                                  CONTENTS OUT- N/A                    06900013
RD       EQU   3                   CONTENTS IN- N/A                     07000013
*                                  USE- UNUSED                          07100013
*                                  CONTENTS OUT- N/A                    07200013
RE       EQU   4                   CONTENTS IN- N/A                     07300013
*                                  USE- GENERAL WORK REGISTER           07400013
*                                  CONTENTS OUT- N/A                    07500013
RF       EQU   5                   CONTENTS IN- N/A                     07600013
*                                  USE- UNUSED                          07700013
*                                  CONTENTS OUT- N/A                    07800013
RG       EQU   6                   CONTENTS IN- N/A                     07900013
*                                  USE- UNUSED                          08000013
*                                  CONTENTS OUT- N/A                    08100013
RH       EQU   7                   CONTENTS IN- N/A                     08200013
*                                  USE- UNUSED                          08300013
*                                  CONTENTS OUT- N/A                    08400013
RI       EQU   8                   CONTENTS IN- N/A                     08500013
*                                  USE- UNUSED                          08600013
*                                  CONTENTS OUT- N/A                    08700013
RJ       EQU   9                   CONTENTS IN- N/A                     08800013
*                                  USE- UNUSED                          08900013
*                                  CONTENTS OUT- N/A                    09000013
RK       EQU   10                  CONTENTS IN- N/A                     09100013
*                                  USE- UNUSED                          09200013
*                                  CONTENTS OUT- N/A                    09300013
RL       EQU   11                  CONTENTS IN- N/A                     09400013
*                                  USE- MODULE BASE ADDRESS REGISTER    09500013
*                                  CONTENTS OUT- ADDRESS OF THIS MODULE 09600013
RM       EQU   12                  CONTENTS IN- N/A                     09700013
*                                  USE- EQUALS BASE ADDRESS REGISTER    09800013
*                                  CONTENTS OUT- EQUALS ADDRESS         09900013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     10100013
*                                    AREA                               10200013
*                                  CONTENTS OUT- ADDRESS OF PPI         10300013
RO       EQU   14                  CONTENTS IN: RETURN ADDRESS TO SYST  10400013
*                                  USE- MERGE NETWORK BASE ADDRESS REG  10500013
*                                  CONTENTS OUT- RETURN ADDRESS TO SYST 10600013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  10700013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 10800013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 10900013
         SPACE 2                                                        11000013
*START OF MODULE CODE PROPER:                                           11100013
         SPACE 2                                                        11200013
IERAOP   CSECT                                                          11300013
         USING *,RL                                                     11400013
         USING IERRCA,RN                                                11500013
         USING DIERRMC,RP                                               11600013
         SPACE 1                                                        11700013
*    MODULE ENTRY POINT                                                 11800013
         SPACE 1                                                        11900013
IERMO1   LR    RL,RP                                                    12000013
         ST    RO,RKSAVC9          SAVE RETURN ADDRESS                  12100013
         L     RO,PPINET+4                                              12200013
         USING DIERROP,RO                                               12300013
         TM    PPISW1+2,X'04'      IS THIS PH 3 OR MRG ONLY             12400013
         BO    AOPPH3              FALL THRU IF PHASE 2                 12500013
         L     RO,PPINETM+4                                             12600013
*    IN PHASE 2, THE PHASE 2 SWITCHES ARE AS SHOWN IN LISTING           12700013
*    THE FOLLOWING SECTION SETS UP THE NETWORK COMPARE INSTRUCTIONS     12800013
         SPACE 1                                                        12900013
AOPCIS   IC    RE,PPIDD0L1+3                                            13000013
         STC   RE,IERROPWH+1       LENGTH ATTRIBUTE                     13100013
         OC    IERROPWH+2(2),PPIDD0L1   DISPLACEMENT ATTRIBUTE          13200013
         OC    IERROPWH+4(2),PPIDD0L1                                   13300013
         STC   RE,IERROPL4+1                                            13400013
         OC    IERROPL4+2(2),PPIDD0L1                                   13500013
         OC    IERROPL4+4(2),PPIDD0L1                                   13600013
         STC   RE,IERROPL2+1                                            13700013
         OC    IERROPL2+2(2),PPIDD0L1                                   13800013
         OC    IERROPL2+4(2),PPIDD0L1                                   13900013
         STC   RE,IERROPL1+1                                            14000013
         OC    IERROPL1+2(2),PPIDD0L1                                   14100013
         OC    IERROPL1+4(2),PPIDD0L1                                   14200013
         STC   RE,IERROC14+1                                            14300013
         OC    IERROC14+2(2),PPIDD0L1                                   14400013
         OC    IERROC14+4(2),PPIDD0L1                                   14500013
         STC   RE,IERROC13+1                                            14600013
         OC    IERROC13+2(2),PPIDD0L1                                   14700013
         OC    IERROC13+4(2),PPIDD0L1                                   14800013
         STC   RE,IERROC15+1                                            14900013
         OC    IERROC15+2(2),PPIDD0L1                                   15000013
         OC    IERROC15+4(2),PPIDD0L1                                   15100013
         STC   RE,IERROC11+1                                            15200013
         OC    IERROC11+2(2),PPIDD0L1                                   15300013
         OC    IERROC11+4(2),PPIDD0L1                                   15400013
         STC   RE,IERROPS4+1                                            15500013
         OC    IERROPS4+2(2),PPIDD0L1                                   15600013
         OC    IERROPS4+4(2),PPIDD0L1                                   15700013
         STC   RE,IERROPU4+1                                            15800013
         OC    IERROPU4+2(2),PPIDD0L1                                   15900013
         OC    IERROPU4+4(2),PPIDD0L1                                   16000013
         STC   RE,IERROPU2+1                                            16100013
         OC    IERROPU2+2(2),PPIDD0L1                                   16200013
         OC    IERROPU2+4(2),PPIDD0L1                                   16300013
         STC   RE,IERROPU1+1                                            16400013
         OC    IERROPU1+2(2),PPIDD0L1                                   16500013
         OC    IERROPU1+4(2),PPIDD0L1                                   16600013
         STC   RE,IERDOSCK+1                                            16700013
         OC    IERDOSCK+2(2),PPIDD0L1                                   16800013
         OC    IERDOSCK+4(2),PPIDD0L1                                   16900013
         STC   RE,IERROC6+1                                             17000013
         OC    IERROC6+2(2),PPIDD0L1                                    17100013
         OC    IERROC6+4(2),PPIDD0L1                                    17200013
         STC   RE,IERROC5+1                                             17300013
         OC    IERROC5+2(2),PPIDD0L1                                    17400013
         OC    IERROC5+4(2),PPIDD0L1                                    17500013
         STC   RE,IERROC7+1                                             17600013
         OC    IERROC7+2(2),PPIDD0L1                                    17700013
         OC    IERROC7+4(2),PPIDD0L1                                    17800013
         STC   RE,IERROC3+1                                             17900013
         OC    IERROC3+2(2),PPIDD0L1                                    18000013
         OC    IERROC3+4(2),PPIDD0L1                                    18100013
         STC   RE,IERROP4S+1                                            18200013
         OC    IERROP4S+2(2),PPIDD0L1                                   18300013
         OC    IERROP4S+4(2),PPIDD0L1                                   18400013
         STC   RE,IERDOICP+1                                            18500013
         OC    IERDOICP+2(2),PPIDD0L1                                   18600013
         OC    IERDOICP+4(2),PPIDD0L1                                   18700013
         SPACE 1                                                        18800013
         L     RM,PPIAXERT         SET BASE REG OF EQUALS RTN           18900013
*    EXIT TO NEXT ASSIGNMENT PHASE                                      19000013
         L     RO,RKSAVC9                                               19100013
         BR    RO                  NEXT ASSIGNMENT ROUTINE              19200018
         SPACE 2                                                        19300013
*    THE FOLLOWING SECTION SETS THE NETWORK FOR PHASE 3                 19400013
         SPACE 1                                                        19500013
AOPPH3   OI    IERDOBWR+1,X'F0'                                         19600013
         OI    IERDOM1+1,X'F0'                                          19700013
         OI    IERDOCPS+1,X'F0'                                         19800013
         OI    IERDOIP3+1,X'F0'                                         19900013
         B     AOPCIS              BRANCH TO SET COMPARE INSTR SECTION  20000013
         SPACE 2                                                        20100013
RKSAVC9  DS    1F                  NEXT ASSGN. RTN. ADDR.               20200018
         EJECT                                                          20300013
DIERROP  DSECT                                                          20400013
IERDO1   B     ROPSINIT            READ PRIME ENTRY BR TO INITIALIZAT   20500013
         B     ROPCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 20600013
*    NETWORK ENTRANCE SWITCH                                            20700013
         SPACE 1                                                        20800013
ROPNTENS BC    0,ROPLF8            FOR MRG ORD GT 8, FALL THRU          20900013
         SPACE 1                                                        21000013
*    DETERMINATION OF WHICH HALF OF MRG NTWK RCDS THE NEW RCD MUST CMP  21100013
         SPACE 1                                                        21200013
         L     RC,ROPMRGAM         ADDR OF ITEM 8                       21300013
IERROPWH CLC   0(1,RD),0(RC)       CMP NEW ITEM WITH ITEM 8             21400013
         BNE   ROPWHB              IF EQUAL GO TO EQUALS RTN            21500013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       21600013
         SPACE 1                                                        21700013
*    THIS INSTR IS BC 10/12 DEPENDING ON THE INPUT SEQUENCE             21800013
         SPACE 1                                                        21900013
ROPWHB   BC    12,ROPLF8           IF NEW GT / LT ITEM 8, FALL THRU     22000013
ROPLF16  LM    0,0,ROPMRGAL        LOAD NTWK REG WITH THOSE NECESSARY   22100013
*                                  RCD FROM ITEMS 9 THRU 15. INSTR IS   22200013
*                                  SET BY THE CUTBACK RTN               22300013
         SPACE 1                                                        22400013
*    PARTIAL NETWORK FOR CMP AGAINST ITEMS 9 THRU 15                    22500013
         SPACE 1                                                        22600013
ROPPNELA B     IERROPL4            PARTIAL NTWK ENTR SWITCH SET BY      22700013
*                                  CUTBACK RTN                          22800013
         SPACE 1                                                        22900013
*    ENTRANCE FOR A 14,15,16 WAY MERGE                                  23000013
         SPACE 1                                                        23100013
IERROPL4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        23200013
         BNE   ROP12B              IF EQUAL GO TO EQUALS RTN            23300013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 12 23400013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       23500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             23600013
ROP12B   BH    IERROC14            IF HI/LO GO TO CMP ITEM 14 OR 13     23700013
         SPACE 1                                                        23800013
*    ENTRANCE FOR 11,12,13 WAY MERGE                                    23900013
         SPACE 1                                                        24000013
IERROPL2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 10        24100013
         BNE   ROP10B              IF EQUAL GO TO EQUALS RTN            24200013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 10 24300013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       24400013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             24500013
ROP10B   BH    IERROC11            IF HI/LO GO TO CMP ITEM 11,12/UPDATE 24600013
         SPACE 1                                                        24700013
*    ENTRANCE FOR A 10 WAY MERGE                                        24800013
         SPACE 1                                                        24900013
IERROPL1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 9         25000013
         BNE   ROP9B               IF EQUAL GO TO EQUALS RTN            25100013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 9  25200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       25300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             25400013
ROP9B    BH    ROPMOV9             INSERT NEW ITEM IN SEQUENCE          25500018
         SPACE 1                                                        25600013
*    ENTRANCE FOR A 9 WAY MERGE AND NEW ITEM COLLATES AFT ITEM 8        25700013
         SPACE 1                                                        25800013
ROP9WMRG LR    RC,RD                                                    25900013
         LM    RD,RK,ROPMRGAU                                           26000013
         STM   RE,RK,ROPMRGAU                                           26100013
         ST    RC,ROPMRGAM                                              26200013
         SPACE 1                                                        26300013
*    PUTTING OUT THE NETWORK WINNER                                     26400013
*    SEQUENCE CHECKING IS NOT NECESSARY                                 26500013
*    THE ASSIGNMENT RTN SETS THE BRANCH INSTR ACCORDING TO THE PHASE    26600013
         SPACE 1                                                        26700013
IERDOBWR BC    0,ROPPH3NS          DROP THRU FOR PHASE 2                26800013
         L     RL,PPIBLK2+4                                             26900013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        27000013
         SPACE 2                                                        27100013
ROPPH3NS L     RL,PPIBLK+4                                              27200013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        27300013
         EJECT                                                          27400013
IERROC14 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 14        27500013
         BNE   ROP14B              IF EQUAL GO TO EQUALS RTN            27600013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 14 27700013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       27800013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             27900013
ROP14B   BH    IERROC15            IF HI/LO GO TO CMP ITM 15 OR UPDATE  28000013
         SPACE 1                                                        28100013
IERROC13 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 13        28200013
         BNE   ROP13B              IF EQUAL GO TO THE EQUALS RTN        28300013
         LR    RC,RI               LOAD EQ RTN COMPARE REG WITH ITEM 13 28400013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       28500013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             28600013
ROP13B   BH    ROPMOV13            IF HI/LO NEW COLLATES AFTER ITEM 13  28700013
         SPACE 1                                                        28800013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 12 + BEFORE ITEM 13      28900013
         SPACE 1                                                        29000013
ROPMOV12 L     RK,ROPMRGAM                                              29100013
         LR    RI,RD                                                    29200013
         STM   RE,RI,ROPMRGAM                                           29300013
         LM    RD,RJ,ROPMRGAU                                           29400013
         STM   RE,RK,ROPMRGAU                                           29500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              29600013
         SPACE 2                                                        29700013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 13 + BEFORE ITEM 14      29800013
         SPACE 1                                                        29900013
ROPMOV13 L     RK,ROPMRGAM                                              30000013
         LR    RJ,RD                                                    30100013
         STM   RE,RJ,ROPMRGAM                                           30200013
         LM    RD,RJ,ROPMRGAU                                           30300013
         STM   RE,RK,ROPMRGAU                                           30400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              30500013
         SPACE 2                                                        30600013
IERROC15 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 15        30700013
         BNE   ROP15B              IF EQUAL GO TO EQUALS RTN            30800013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 15 30900013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       31000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             31100013
ROP15B   BH    ROPMOV15            IF HI/LO NEW COLLATES AFTER ITEM 15  31200013
         SPACE 1                                                        31300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 14 + BEFORE ITEM 15      31400013
         SPACE 1                                                        31500013
ROPMOV14 L     RC,ROPMRGAM                                              31600013
         LR    RK,RD                                                    31700013
         STM   RE,RK,ROPMRGAM                                           31800013
         LM    RD,RJ,ROPMRGAU                                           31900013
         LR    RK,RC                                                    32000013
         STM   RE,RK,ROPMRGAU                                           32100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              32200013
         SPACE 2                                                        32300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 15                     32400013
         SPACE 1                                                        32500013
ROPMOV15 L     RC,ROPMRGAM                                              32600013
         STM   RE,RK,ROPMRGAM                                           32700013
         ST    RD,ROPMRGAL+24                                           32800013
         LR    RK,RC                                                    32900013
         LM    RD,RJ,ROPMRGAU                                           33000013
         STM   RE,RK,ROPMRGAU                                           33100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              33200013
         SPACE 2                                                        33300013
IERROC11 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 11        33400013
         BNE   ROP11B              IF EQUAL GO TO EQUALS RTN            33500013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 11 33600013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       33700013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             33800013
ROP11B   BH    ROPMOV11            INSERT NEW ITEM IN SEQUENCE          33900018
         SPACE 1                                                        34000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 10 + BEFORE ITEM 11      34100013
         SPACE 1                                                        34200013
ROPMOV10 L     RK,ROPMRGAM                                              34300013
         LR    RG,RD                                                    34400013
         STM   RE,RG,ROPMRGAM                                           34500013
         LM    RD,RJ,ROPMRGAU                                           34600013
         STM   RE,RK,ROPMRGAU                                           34700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              34800013
         SPACE 2                                                        34900013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 11 + BEFORE ITEM 12      35000013
         SPACE 1                                                        35100013
ROPMOV11 L     RK,ROPMRGAM                                              35200013
         LR    RH,RD                                                    35300013
         STM   RE,RH,ROPMRGAM                                           35400013
         LM    RD,RJ,ROPMRGAU                                           35500013
         STM   RE,RK,ROPMRGAU                                           35600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              35700013
         SPACE 2                                                        35800013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 9 + BEFORE ITEM 10       35900013
         SPACE 1                                                        36000013
ROPMOV9  L     RK,ROPMRGAM                                              36100013
         LR    RF,RD                                                    36200013
         STM   RE,RF,ROPMRGAM                                           36300013
         LM    RD,RJ,ROPMRGAU                                           36400013
         STM   RE,RK,ROPMRGAU                                           36500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              36600013
         SPACE 2                                                        36700013
*    SPECIAL ITEM 12 COMPARE FOR 13 WAY MERGE                           36800013
         SPACE 1                                                        36900013
IERROPS4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        37000013
         BNE   ROPS12B             IF EQUAL GO TO EQUALS RTN            37100013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 12 37200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       37300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             37400013
ROPS12B  BH    ROPMOV12            IF HI/LO GO TO UPDATE                37500013
         B     IERROC11            GO TO CMP NEW ITEM WITH ITEM 11      37600013
         EJECT                                                          37700013
ROPLF8   LM    0,0,ROPMRGAU        LOAD NTWK REG WITH THOSE NECESSARY   37800013
*                                  RCD FROM ITEMS 1 THRU 7. INSTR IS    37900013
*                                  SET BY THE CUTBACK RTN               38000013
         SPACE 1                                                        38100013
*    PARTIAL NETWORK FOR CMP AGAINST ITEMS 1 THRU 7                     38200013
         SPACE 1                                                        38300013
ROPPNEL9 B     IERROPU4            PARTIAL NTWK ENTR SWITCH SET BY      38400013
*                                  CUTBACK RTN                          38500013
         SPACE 1                                                        38600013
*    ENTRANCE FOR A 6,7,8 WAY MERGE                                     38700013
         SPACE 1                                                        38800013
IERROPU4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         38900013
         BNE   ROP4B               IF EQUAL GO TO EQUALS RTN            39000013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  39100013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       39200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             39300013
ROP4B    BH    IERROC6             IF HI/LO GO TO CMP ITEM 6 OR 5       39400013
         SPACE 1                                                        39500013
*    ENTRANCE FOR A 3,4,5 WAY MERGE                                     39600013
         SPACE 1                                                        39700013
IERROPU2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         39800013
         BNE   ROP2B               IF EQUAL GO TO EQ RTN                39900013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 2  40000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       40100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             40200013
ROP2B    BH    IERROC3             IF HI/LO GO TO CMP ITEM 3,4/UPDATE   40300013
         SPACE 1                                                        40400013
*    ENTRANCE FOR A 2 WAY MERGE                                         40500013
         SPACE 1                                                        40600013
IERROPU1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         40700013
         BNE   ROP1B               IF EQUAL GO TO EQ RTN                40800013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 1  40900013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       41000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             41100013
ROP1B    BH    ROPMOV1             INSERT NEW ITEM IN SEQUENCE          41200018
         SPACE 1                                                        41300013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW IS WINNER                       41400013
         SPACE 1                                                        41500013
*    IF PHASE 2 EXIT TO THE BLOCK RTN                                   41600013
*    IF PHASE 3 OR MERGE ONLY PERFORM SEQUENCE CHECK IF REQUESTED       41700013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 41800013
         SPACE 1                                                        41900013
IERDOM1  BC    0,ROPPH3            DROP THRU FOR PHASE 2                42000013
         L     RL,PPIBLK2+4                                             42100013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        42200013
         SPACE 2                                                        42300013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      42400013
*    WINNER. CHECK DONE USING REG RD AND RC                             42500013
         SPACE 1                                                        42600013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLK RTN. THE BLK RTN         42700013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  42800013
*       EXITS ARE ACTIVATED, THE BLK RTN TAKES NO ACTION CONCERNING     42900013
*       PPIDOUO.                                                        43000013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        43100013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     43200013
*       PPIDOUO IS 0.                                                   43300013
         SPACE 1                                                        43400013
ROPPH3   L     RC,PPIDOUO                                               43500013
         B     ROPCKISC(RC)        BRANCH TO EXIT                       43600018
ROPCKISC B     ROPSCK              SEQUENCE CHECK                       43700018
         SPACE 2                                                        43800013
*    NO SEQUENCE CHECK                                                  43900013
         SPACE 1                                                        44000013
ROPOUT   L     RL,PPIBLK+4                                              44100013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        44200013
         SPACE 2                                                        44300013
ROPSCK   L     RC,PPIDOOBA         ADDR OF REC IN OUTPUT BUFFER         44400013
IERDOSCK CLC   0(1,RD),0(RC)                                            44500013
         BNE   ROPSCB              IF EQUAL GO TO EQ RTN                44600013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    44700013
*    THIS INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE          44800013
ROPSCB   BC    10,ROPOUT           BLOCK RTN.                           44900018
         SPACE 1                                                        45000013
*    OUT OF SEQUENCE ERROR                                              45100013
         SPACE 1                                                        45200013
         L     RO,PPIRMC+4                                              45300013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   45330017
         BO    ROPMERG             YES, BRANCH                          45360017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              45400013
ROPSEQ   L     RP,PPIADSSC                                              45500017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       45600013
         L     RP,PPIADSSC                                              45700013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  45800013
ROPMERG  SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     45810017
         CVD   RD,ROPCONV          CONVERT INDEX TO DECIMAL             45820017
         UNPK  ROPTEMP(2),ROPCONV+6(2) UNPACK FOR PRINTING              45830017
         OI    ROPTEMP+1,X'F0'     SET SIGN POSITIVE                    45840017
         MVC   MSGP3MA8(2),ROPTEMP      MOVE UNIT NUMBER INTO MESSAGE   45850017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                45860017
         B     ROPSEQ              GO PRINT MESSAGE                     45870017
         EJECT                                                          45900013
IERROC6  CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         46000013
         BNE   ROP6B               IF EQUAL GO TO EQUALS RTN            46100013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 6  46200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       46300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             46400013
ROP6B    BH    IERROC7             IF HI/LO GO TO CMP ITEM 7 OR UPDATE  46500013
         SPACE 1                                                        46600013
IERROC5  CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         46700013
         BNE   ROP5B               IF EQ GO TO EQ RTN                   46800013
         LR    RC,RI               LOAD EQ RTN CMP REG WITH ITEM 5      46900013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       47000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             47100013
ROP5B    BH    ROPMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   47200013
         SPACE 1                                                        47300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 4 + BEFORE ITEM 5        47400013
         SPACE 1                                                        47500013
ROPMOV4  LR    RI,RD                                                    47600013
         LR    RD,RE                                                    47700013
         STM   RF,RI,ROPMRGAU                                           47800013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              47900013
         SPACE 2                                                        48000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 5 + BEFORE ITEM 6        48100013
         SPACE 1                                                        48200013
ROPMOV5  LR    RJ,RD                                                    48300013
         LR    RD,RE                                                    48400013
         STM   RF,RJ,ROPMRGAU                                           48500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              48600013
         SPACE 2                                                        48700013
IERROC7  CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         48800013
         BNE   ROP7B               IF EQ GO TO EQ RTN                   48900013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 7  49000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       49100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             49200013
ROP7B    BH    ROPMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   49300013
         SPACE 1                                                        49400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 6 + BEFORE ITEM 7        49500013
         SPACE 1                                                        49600013
ROPMOV6  LR    RK,RD                                                    49700013
         LR    RD,RE                                                    49800013
         STM   RF,RK,ROPMRGAU                                           49900013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              50000013
         SPACE 2                                                        50100013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      50200013
         SPACE 1                                                        50300013
ROPMOV7  ST    RD,ROPMRGAM-4                                            50400013
         LR    RD,RE                                                    50500013
         STM   RF,RK,ROPMRGAU                                           50600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              50700013
         SPACE 2                                                        50800013
IERROC3  CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         50900013
         BNE   ROP3B               IF EQ GO TO EQ RTN                   51000013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 3  51100013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       51200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             51300013
ROP3B    BH    ROPMOV3             INSERT NEW ITEM IN SEQUENCE          51400018
         SPACE 1                                                        51500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 2 + BEFORE ITEM 3        51600013
         SPACE 1                                                        51700013
ROPMOV2  LR    RG,RD                                                    51800013
         LR    RD,RE                                                    51900013
         STM   RF,RG,ROPMRGAU                                           52000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              52100013
         SPACE 2                                                        52200013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 3 + BEFORE ITEM 4        52300013
         SPACE 1                                                        52400013
ROPMOV3  LR    RH,RD                                                    52500013
         LR    RD,RE                                                    52600013
         STM   RF,RH,ROPMRGAU                                           52700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              52800013
         SPACE 2                                                        52900013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 1 + BEFORE ITEM 2        53000013
         SPACE 1                                                        53100013
ROPMOV1  ST    RD,ROPMRGAU                                              53200013
         LR    RD,RE                                                    53300013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              53400013
         SPACE 2                                                        53500013
*    SPECIAL ITEM 4 COMPARE FOR A 5 WAY MERGE                           53600013
         SPACE 1                                                        53700013
IERROP4S CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         53800013
         BNE   ROPS4B              IF EQ GO TO EQ RTN                   53900013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  54000013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       54100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             54200013
ROPS4B   BH    ROPMOV4             IF HI/LO GO TO UPDATE                54300013
         B     IERROC3             GO TO COMPARE NEW ITEM WITH ITEM 3   54400013
         EJECT                                                          54500013
*    THE NETWORK CUTBACK SECTION.                                       54600013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      54700013
         SPACE 1                                                        54800013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        54900013
         SPACE 1                                                        55000013
*    SET NETWORK FOR A 16 WAY MERGE                                     55100013
         SPACE 1                                                        55200013
ROPCSSWM MVC   ROPNTENS(4),ROPSESC8 SET NTWK ENTR SW FOR NEW/ITM 8 CMP  55300013
         MVI   ROPLF16+1,X'4A'     LOAD NTWK REG WITH ITEMS 9 THRU 15   55400013
         MVI   ROPLF8+1,X'4A'      LOAD NTWK REG WITH ITEMS 1 THRU 7    55500013
         MVC   ROP12B(4),ROP12SB   SET BR TO CMP ITEM 14 AFT ITEM 12    55600013
         MVC   ROP4B(4),ROPST4B    SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  55700013
         MVC   ROP14B(4),ROPS14B   SET BR TO CMP ITEM 15 AFT ITEM 14    55800013
         MVC   ROP6B(4),ROPS6B     SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  55900013
         MVC   ROP10B(4),ROPS10B   SET BR TO CMP ITEM 11 AFT ITEM 10    56000013
         MVC   ROP2B(4),ROPS2B     SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  56100013
         MVC   ROPPNELA(4),ROPSPNS1 SET NTWK ENTR FOR ITEMS 9 TO 15     56200013
         MVC   ROPPNEL9(4),ROPSPNS2 SET NTWK ENTR FOR ITEMS 1 TO 7      56300013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 56400013
         SPACE 1                                                        56500013
*    SET NETWORK FOR A 15 WAY MERGE                                     56600013
         SPACE 1                                                        56700013
         MVC   ROP14B(4),ROPFTWM   SET BR TO UPDATE AFTER ITEM 14 CMP   56800013
         MVI   ROPLF16+1,X'49'     LOAD NTWK REG WITH ITEMS 9 THRU 14   56900013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 57000013
         SPACE 1                                                        57100013
*    SET NETWORK FOR A 14 WAY MERGE                                     57200013
         SPACE 1                                                        57300013
         MVC   ROP12B(4),ROP14WM   SET BR TO CMP ITEM 13 AFT ITEM 12    57400013
         MVI   ROPLF16+1,X'48'     LOAD NTWK REG WITH ITEMS 9 TO 13     57500013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 57600013
         SPACE 1                                                        57700013
*    SET NETWORK FOR A 13 WAY MERGE                                     57800013
         SPACE 1                                                        57900013
         MVC   ROP10B(4),ROP13WM   SET BR TO CMP ITEM 12 AFT ITM 10 CMP 58000013
         MVI   ROPLF16+1,X'47'     LOAD NTWK REG WITH ITEMS 9 TO 12     58100013
         MVC   ROPPNELA(4),ROPE13WM SET NTWK ENTR FOR A 13 WAY MERGE    58200013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 58300013
         SPACE 1                                                        58400013
*    SET NETWORK FOR A 12 WAY MERGE                                     58500013
         SPACE 1                                                        58600013
         MVC   ROP10B(4),ROPS10B   SET BR TO CMP ITEM 11 AFT ITM 10 CMP 58700013
         MVI   ROPLF16+1,X'46'     LOAD NTWK REG WITH ITEMS 9 TO 11     58800013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 58900013
         SPACE 1                                                        59000013
*    SET NETWORK FOR AN 11 WAY MERGE                                    59100013
         SPACE 1                                                        59200013
         MVC   ROP10B(4),ROP11WM   SET BR TO UPDATE AFT ITEM 10 CMP     59300013
         MVI   ROPLF16+1,X'45'     LOAD NTWK REG WITH ITEMS 9 + 10      59400013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 59500013
         SPACE 1                                                        59600013
*    SET NETWORK FOR A 10 WAY MERGE                                     59700013
         SPACE 1                                                        59800013
         MVC   ROPPNELA(4),ROPE10WM SET NTWK ENTR FOR A 10 WAY MRG      59900013
         MVI   ROPLF16+1,X'44'     LOAD NTWK REG WITH ITEM 9            60000013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 60100013
         SPACE 1                                                        60200013
*    SET NETWORK FOR A 9 WAY MERGE                                      60300013
         SPACE 1                                                        60400013
         MVC   ROPPNELA(4),ROPE9WM SET NTWK ENTR FOR A 9 WAY MERGE      60500013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 60600013
         SPACE 1                                                        60700013
*    SET NETWORK FOR AN 8 WAY MERGE                                     60800013
         SPACE 1                                                        60900013
         XI    ROPNTENS+1,X'F0'    SET NTWK ENTR SW FOR 8/LESS MRG ORD  61000013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 61100013
         SPACE 1                                                        61200013
*    SET NETWORK FOR A 7 WAY MERGE                                      61300013
         SPACE 1                                                        61400013
         MVC   ROP6B(4),ROP7WM     BR TO UPDATE IF GT ITEM 7            61500013
         MVI   ROPLF8+1,X'49'      LOAD NTWK REG WITH ITEMS 1 TO 6      61600013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 61700013
         SPACE 1                                                        61800013
*    SET NETWORK FOR A 6 WAY MERGE                                      61900013
         SPACE 1                                                        62000013
         MVC   ROP4B(4),ROP6WM     BR TO CMP ITEM 5 IF GT ITEM 4        62100013
         MVI   ROPLF8+1,X'48'      LOAD NETWORK REG WITH ITEMS 1 TO 5   62200013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 62300013
         SPACE 1                                                        62400013
*    SET NETWORK FOR A 5 WAY MERGE                                      62500013
         SPACE 1                                                        62600013
         MVC   ROP2B(4),ROP5WM     BR TO CMP ITEM 4 IF GT ITEM 2        62700013
         MVI   ROPLF8+1,X'47'      LOAD NTWK REG WITH ITEMS 1 TO 4      62800013
         MVC   ROPPNEL9(4),ROPE5WM SET NTWK ENTR FOR A 5 WAY MRG        62900013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 63000013
         SPACE 1                                                        63100013
*    SET NETWORK FOR A 4 WAY MERGE                                      63200013
         SPACE 1                                                        63300013
         MVC   ROP2B(4),ROPS2B     BR TO CMP ITEM 3 IF GT ITEM 2        63400013
         MVI   ROPLF8+1,X'46'      LOAD NTWK REG WITH ITEMS 1 TO 3      63500013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 63600013
         SPACE 1                                                        63700013
*    SET NETWORK FOR A 3 WAY MERGE                                      63800013
         SPACE 1                                                        63900013
         MVC   ROP2B(4),ROP3WM     BR TO UPDATE IF GT ITEM 2            64000013
         MVI   ROPLF8+1,X'45'      LOAD NTWK REG WITH ITEMS 1 + 2       64100013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 64200013
         SPACE 1                                                        64300013
*    SET NETWORK FOR A 2 WAY MERGE                                      64400013
         SPACE 1                                                        64500013
         MVC   ROPPNEL9(4),ROPE2WM SET NTWK ENTR FOR A 2 WAY MERGE      64600013
         MVI   ROPLF8+1,X'44'      LOAD NTWK REG WITH ITEM 1            64700013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 64800013
         SPACE 1                                                        64900013
*    SET NETWORK FOR A 1 WAY MERGE                                      65000013
         SPACE 1                                                        65100013
         MVC   ROPPNEL9(4),ROPE1WM SET NTWK ENTR FOR A 1 WAY MERGE      65200013
         BAL   RC,ROPFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 65300013
         SPACE 1                                                        65400013
*    A ZERO WAY MERGE                                                   65500013
         SPACE 1                                                        65600013
IERDOCPS BC    0,ROPCPH3           FALL THRU IF PHASE 2                 65700013
         L     RL,PPIBLK2+4                                             65800013
         BR    RL                  EXIT TO BLK RTN  RELEASE BLK TO WRIT 65900013
         SPACE 2                                                        66000013
ROPCPH3  L     RL,PPIBLK+4                                              66100013
         BR    RL                  EXIT TO BLK RTN (END OF JOB)         66200013
         SPACE 2                                                        66300013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     66400013
         SPACE 1                                                        66500013
ROPCUTEN L     RC,ROPSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 66600013
         BR    RC                  GO TO NEXT CUTBACK ADDR.             66700018
         SPACE 2                                                        66800013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERATON 66900013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    67000013
*    MERGE ORDER, SUBSEQUENTLY AN UPDATE IS EXECUTED.                   67100013
         SPACE 1                                                        67200013
ROPFMUDS BC    0,ROPFDMO           SET TO BRANCH BY INITIALIZATION RTN  67300013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           67400013
         SPACE 1                                                        67500013
         ST    RC,ROPSVCBA                                              67600013
         L     RD,ROPMRGAU                                              67700013
         L     RE,ROPACMO          MERGE ORDER LESS 1 MINUS 1           67800013
         S     RE,KROONE                                                67900013
         ST    RE,ROPACMO                                               68000013
         SLL   RE,2                TOTAL NO. BYTES TO BE UPDATED        68100013
         EX    RE,ROPUPDT          EXECUTE MOVE INSTR                   68200013
         SPACE 1                                                        68300013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              68400013
         SPACE 2                                                        68500013
         EJECT                                                          68600013
ROPFDMO  L     RF,ROPIDMO          SET TO 16 BY INITIALIZATION RTN      68700013
         C     RF,ROPACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 68800013
         BE    ROPSFTTU            SET FALL THRU TO UPDATE              68900013
         S     RF,KROONE                                                69000013
         ST    RF,ROPIDMO                                               69100013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           69200013
         SPACE 2                                                        69300013
ROPSFTTU XI    ROPFMUDS+1,X'F0'    SET ROPFMUDS BRANCH TO FALL THRU     69400013
         ST    RC,ROPSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    69500013
         B     ROPINTSQ            GO TO INIT SEQ THE RECORDS           69600013
         SPACE 2                                                        69700013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 69800013
*    EACH MERGE OPERATION.                                              69900013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         70000013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  70100013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   70200013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   70300013
*       PPI IS UTILIZED.                                                70400013
         SPACE 1                                                        70500013
ROPINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   70600013
         L     RB,ROPACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   70700013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    70800013
ROPRETRN L     RF,ROPACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  70900013
*                                  CHECKED WITH ALL THE OTHER ITEMS     71000013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          71100013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 71200013
         SR    RH,RH               INDEX USED TO COMPARE ALL OTHER ITEM 71300013
ROPANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      71400013
IERDOICP CLC   0(1,RD),0(RC)                                            71500013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQ        71600013
ROPISNLH BC    10,ROPHIEQ          HI/LO AND EQUAL CASE TREATED SAME    71700013
ROPDECR  LA    RH,4(0,RH)                                               71800013
         BCT   RF,ROPANOTH         TRY NEXT ITEM                        71900018
ROPCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   72000013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  72100013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   72200013
         BE    ROPINSRT            IF ZERO STORE ITEM                   72300013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   72400013
         B     ROPCHEK             CONTINUE CHECKING FOR ZEROS          72500018
         SPACE 2                                                        72600013
ROPINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                72700013
         BCT   RB,ROPINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 72800013
         B     ROPOUTIS            BRANCH TO SET NETWORK ADDRESS        72900013
         SPACE 2                                                        73000013
*    THIS BRANCH INSTR IS BC 2 OR 4 DEPENDING ON THE INPUT SEQUENCE     73100013
ROPHIEQ  BC    2,ROPRND            IF NOT EQ INCR STORE POS POINTER     73200013
         BALR  RO,RM               SET NTWK RETURN REG FOR EQ RTN       73300013
*    THIS BRANCH INSTR IS BC 4 OR 2 DEPENDING ON THE INPUT SEQUENCE     73400013
ROPLOHI  BC    4,ROPDECR           CHECK NEXT ITEM                      73500018
ROPRND   LA    RE,4(0,RE)                                               73600013
         B     ROPDECR             DECREMENT RF AND CHECK FOR ZEROS     73700018
         SPACE 2                                                        73800013
ROPINCR  LA    RI,4(0,RI)                                               73900013
         B     ROPRETRN            LAST COMPARE                         74000018
         SPACE 2                                                        74100013
*    SET NETWORK AREA WITH ADDRESSES OF PRIMED RECORDS                  74200013
         SPACE 1                                                        74300013
ROPOUTIS L     RD,PPIPSVA          SET REG WITH WINNING RECORD ADDR     74400013
         L     RE,ROPACMO                                               74500013
         S     RE,KROONE                                                74600013
         LR    RF,RE                                                    74700013
         SLL   RE,2                                                     74800013
         LTR   RE,RE                                                    74900013
         BZ    ROPSTM              BYPASS NSI                           75000018
         S     RE,KROONE           DET NO. BYTES TO BE MOVED TO MRG ARA 75100013
         EX    RE,ROPSANW                                               75200013
ROPSTM   ST    RF,ROPACMO          SET ACTUAL MERGE ORDER MINUS ONE FOR 75300013
*                                  UPDATING AFTER A CUTBACK OPERATION   75400013
IERDOIP3 BC    0,ROPINSP3          FALL THRU IF PHASE 2                 75500013
         L     RL,PPIBLK2+4                                             75600013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        75700013
         SPACE 2                                                        75800013
ROPINSP3 L     RL,PPIBLK+4                                              75900013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RCD        76000013
         SPACE 2                                                        76100013
         EJECT                                                          76200013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     76300013
*    OF EACH PASS OR SUB-PASS.                                          76400013
         SPACE 1                                                        76500013
ROPSINIT MVC   ROPIDMO(4),KROSXTN  SET MAX MERGE ORDER TO 16            76600013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          76700013
         ST    RE,ROPACMO                                               76800013
         SR    RE,RE                                                    76900013
         ST    RE,PPIPSVA                                               77000013
         MVC   PPIPSVA+4(60),PPIPSVA  ZERO INT SEQ STORE AREA           77100013
         XI    ROPFMUDS+1,X'F0'    SET ROPFMUDS TO BRANCH               77200013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG          77300013
         BC    1,ROPISD            FALL THRU IF INPUT SEQ IS ASDNG      77400013
         TM    ROP12B+1,X'20'      IS ROUTINE SET FOR ASDNG             77500013
ROPFDSQ  BC    1,ROPCSSWM          IF THE ROUTINE IS SET FOR THE INPUT  77600013
         XI    ROPWHB+1,X'60'      SEQUENCE BRANCH TO THE CUTBACK       77700013
         XI    ROP12B+1,X'60'      SECTION. IF THE ROUTINE IS NOT SET   77800013
         XI    ROP10B+1,X'60'      FOR THE INPUT  CHANGE THE MASK OF    77900013
         XI    ROP9B+1,X'60'       THE BRANCH ON CONDITION INSTR.       78000013
         XI    ROP14B+1,X'60'                                           78100013
         XI    ROP13B+1,X'60'                                           78200013
         XI    ROP15B+1,X'60'                                           78300013
         XI    ROP11B+1,X'60'                                           78400013
         XI    ROPS12B+1,X'60'                                          78500013
         XI    ROP4B+1,X'60'                                            78600013
         XI    ROP2B+1,X'60'                                            78700013
         XI    ROP1B+1,X'60'                                            78800013
         XI    ROPSCB+1,X'60'                                           78900013
         XI    ROP6B+1,X'60'                                            79000013
         XI    ROP5B+1,X'60'                                            79100013
         XI    ROP7B+1,X'60'                                            79200013
         XI    ROP3B+1,X'60'                                            79300013
         XI    ROPS4B+1,X'60'                                           79400013
         XI    ROPISNLH+1,X'60'                                         79500013
         XI    ROPHIEQ+1,X'60'                                          79600013
         XI    ROPLOHI+1,X'60'                                          79700013
         XI    ROP12SB+1,X'60'                                          79800013
         XI    ROPST4B+1,X'60'                                          79900013
         XI    ROPS14B+1,X'60'                                          80000013
         XI    ROPS6B+1,X'60'                                           80100013
         XI    ROPS10B+1,X'60'                                          80200013
         XI    ROPS2B+1,X'60'                                           80300013
         XI    ROPFTWM+1,X'60'                                          80400013
         XI    ROP14WM+1,X'60'                                          80500013
         XI    ROP13WM+1,X'60'                                          80600013
         XI    ROP11WM+1,X'60'                                          80700013
         XI    ROP7WM+1,X'60'                                           80800013
         XI    ROP6WM+1,X'60'                                           80900013
         XI    ROP5WM+1,X'60'                                           81000013
         XI    ROP3WM+1,X'60'                                           81100013
         B     ROPCSSWM            BRANCH TO CUTBACK SECTION            81200013
         SPACE 2                                                        81300013
*    INPUT IS IN DESCENDING ORDER                                       81400013
         SPACE 1                                                        81500013
ROPISD   TM    ROP12B+1,X'40'      IS ROUTINE SET FOR DESCG             81600013
         B     ROPFDSQ             CHANGE BRANCHES IF NECESSARY         81700018
         SPACE 2                                                        81800013
*    EXECUTED MOVE INSTRUCTIONS                                         81900013
         SPACE 1                                                        82000013
ROPUPDT  MVC   ROPMRGAU(1),ROPMRGAU+4  UPDATING NETWORK ADDRESSES       82100013
ROPSANW  MVC   ROPMRGAU(1),PPIPSVA+4   SET NETWORK WITH PRIMED ADDRS    82200013
         EJECT                                                          82300013
         DS    0F                                                       82400013
ROPMRGAU DS    7F                  ADDR OF FIRST 7 RCDS FOR MRG NTWK    82500013
ROPMRGAM DS    1F                  ADDR OF RECORD 8 OF MRG NTWK         82600013
ROPMRGAL DS    7F                  ADDR OF LAST 7 RCDS FOR MRG NTWK     82700013
ROPSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       82800013
ROPIDMO  DS    1F                  MAX MRG ORD SET BY INITIAL           82900013
ROPACMO  DS    1F                  ACTUAL MRG ORD SET BY INITIAL        83000013
*********************************************************************** 83100013
KROSXTN  DC    X'00000010'         MAX. MERGE ORDER                     83200018
KROONE   DC    XL4'1'              CONSTANT ON ONE                      83300018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     83400018
KROFOUR  DC    XL4'4'              CONSTANT FOR FOUR                    83460018
ROPTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         83530017
ROPCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      83560017
*********************************************************************** 83600013
ROPSESC8 BC    0,ROPLF8            SET NTWK ENTR SW TO CMP NEW VS ITM 8 83700013
*    THE FOLLOWING 14 INSTR ARE SET DEPENDING ON THE INPUT SEQUENCE     83800013
ROP12SB  BH    IERROC14            BR TO CMP ITEM 14 AFT ITEM 12 CMP    83900013
ROPST4B  BH    IERROC6             BR TO CMP ITEM 6 AFT ITEM 4 CMP      84000013
ROPS14B  BH    IERROC15            BR TO CMP ITEM 15 AFT ITEM 14 CMP    84100013
ROPS6B   BH    IERROC7             BR TO CMP ITEM 7 AFT ITEM 6 CMP      84200013
ROPS10B  BH    IERROC11            BR TO CMP ITEM 11 AFT ITEM 10 CMP    84300013
ROPS2B   BH    IERROC3             BR TO CMP ITEM 3 AFT ITEM 2 CMP      84400013
ROPFTWM  BH    ROPMOV14            BR TO UPDATE IF GT ITEM 14           84500013
ROP14WM  BH    IERROC13            BR TO CMP ITEM 13 AFT ITEM 12 CMP    84600013
ROP13WM  BH    IERROPS4            BR TO CMP ITEM 12 AFT ITEM 10 CMP    84700013
ROP11WM  BH    ROPMOV10            BR TO UPDATE AFT ITEM 10 CMP         84800013
ROP7WM   BH    ROPMOV6             BR TO UPDATE IF GT ITEM 7            84900013
ROP6WM   BH    IERROC5             BR TO CMP ITEM 5 AFT ITEM 4 CMP      85000013
ROP5WM   BH    IERROP4S            BR TO CMP ITEM 4 IF GT ITEM 2        85100013
ROP3WM   BH    ROPMOV2             BR TO UPDATE AFT ITEM 10 CMP         85200013
         SPACE 2                                                        85300013
ROPSPNS1 B     IERROPL4            SET ENTR SW FOR PARTIAL NTWK         85400013
ROPSPNS2 B     IERROPU4            SET ENTR SW FOR PARTIAL NTWK         85500013
ROPE13WM B     IERROPL2            ENTR FOR A 11,12,13 WAY MRG          85600013
ROPE10WM B     IERROPL1            ENTR FOR A 10 WAY MRG                85700013
ROPE9WM  B     ROP9WMRG            ENTR FOR A 9 WAY MRG                 85800013
ROPE5WM  B     IERROPU2            ENTR FOR A 3,4,5 WAY MRG             85900013
ROPE2WM  B     IERROPU1            ENTR FOR A 2 WAY MRG                 86000013
ROPE1WM  B     IERDOM1             ENTR FOR A 1 WAY MRG                 86100013
*                                                                       86200013
* MODULE NAME ***IERRMC***                                              86300013
*                                                                       86400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        86500013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                86600013
         SPACE 1                                                        86700013
DIERRMC  DSECT                                                          86800013
*                                                                       86900013
       COPY  RMCMAIN                                                    87000013
*                                                                       87100013
         SMPPI                                                          87200013
         END                                                            87300013
