         TITLE 'IERAOQ - OS/360 SORT/MERGE - 360-SM-023   04/26/65'     00100013
*MODULE NAME:*** IERAOQ ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3 ASSIGNMENT ROUTINE FOR A 1-16 00600013
*   WAY MERGE NETWORK RUNNING PROGRAM NAMED *** IERROQ *** (SEE DSECT)  00700013
*   WITH A SINGLE CONTROL FIELD . THE FUNCTION OF THIS MODULE IS TO SET 00800013
*   THE NETWORK COMPARE INSTRUCTIONS WITH A LENGTH AND DISPLACEMENT     00900013
*   ATTRIBUTE  ,  TO SET THE NETWORKS PHASE-2/PHASE-3 SWITCHES ACCORD-  01000013
*   ING TO THE PHASE , TO DETERMINE THE AMOUNT OF CORE REQUIRED FOR     01100013
*   EXTRACT POSITIONS IF EXTRACTING AND TO SET THE NETWORK EXTRACT      01200013
*   SWITCHES ACCORDING TO WHETHER EXTRACTION IS TO BE DONE OR NOT.      01300013
         SPACE 2                                                        01400013
*USED AS A DSECT IN  N/A                                                01500013
*                                                                       01600013
*                                                                       01700013
*MACROS USED'                                                           01800013
         SPACE 1                                                        01900013
*   SMPPI                                                               02000013
         SPACE 2                                                        02100013
*ENTRY POINTS:                                                          02200013
         SPACE 1                                                        02300013
*        ENTRY IERAOQ              ENTRY FROM:                          02400013
*                                    CALLING SEQUENCE-                  02500013
*                                      LA   RP,VALUE                    02600013
*                                      BALR RO,RP                       02700013
         SPACE 2                                                        02800013
*INPUT: PPI FIELDS REFERENCED-                                          02900013
         SPACE 1                                                        03000013
*    PPINETM   PPIDDOL1  PPILEXFF  PPIX61    PPISPGN1                   03100013
*    PPISW1    PPIAXERT  PPILEXFD  PPIMRGOP                             03200013
         SPACE 2                                                        03300013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03400013
         SPACE 1                                                        03500013
*    PPIBDSVA                                                           03600013
*    PPISPGN1                                                           03700013
         SPACE 2                                                        03800013
*EXTERNAL ROUTINES:                                                     03900013
         SPACE 1                                                        04000013
*        EXTRN IERROQ                                                   04100013
*        EXTRN IERRMC                                                   04200013
*        EXTRN E61                                                      04300013
         SPACE 2                                                        04400013
*EXTERNAL PARAMETERS: NONE                                              04500013
         SPACE 1                                                        04600013
*EXITS: NORMAL                                                          04700013
         SPACE 1                                                        04800013
*        IERRC9                    CALLER ROUTINE FOR ASSIGNMENT RTN    04900013
*        E61                       EXTRACT EXIT                         05000013
         SPACE 2                                                        05100013
*EXITS: ERROR                                                           05200013
         SPACE 1                                                        05300013
*        IERRMC                    MESSAGE MODULE                       05400013
         SPACE 2                                                        05500013
*TABLES/WORK AREAS: N/A                                                 05600013
         SPACE 1                                                        05700013
         SPACE 2                                                        05800013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  05900013
         SPACE 2                                                        06000013
*NOTES: NONE                                                            06100013
         SPACE 1                                                        06200013
         SPACE 2                                                        06300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06400013
         SPACE 1                                                        06500013
RA       EQU   0                   CONTENTS IN- N/A                     06600013
*                                  USE- UNUSED                          06700013
*                                  CONTENTS OUT- N/A                    06800013
RB       EQU   1                   CONTENTS IN- N/A                     06900013
*                                  USE- UNUSED                          07000013
*                                  CONTENTS OUT- N/A                    07100013
RC       EQU   2                   CONTENTS IN- N/A                     07200013
*                                  USE- GENERAL WORK REGISTER           07300013
*                                  CONTENTS OUT- N/A                    07400013
RD       EQU   3                   CONTENTS IN- N/A                     07500013
*                                  USE- GENERAL WORK REGISTER           07600013
*                                  CONTENTS OUT- N/A                    07700013
RE       EQU   4                   CONTENTS IN- N/A                     07800013
*                                  USE- GENERAL WORK REGISTER           07900013
*                                  CONTENTS OUT- N/A                    08000013
RF       EQU   5                   CONTENTS IN- N/A                     08100013
*                                  USE- UNUSED                          08200013
*                                  CONTENTS OUT- N/A                    08300013
RG       EQU   6                   CONTENTS IN- N/A                     08400013
*                                  USE- GENERAL WORK REGISTER           08500013
*                                  CONTENTS OUT- N/A                    08600013
RH       EQU   7                   CONTENTS IN- N/A                     08700013
*                                  USE- UNUSED                          08800013
*                                  CONTENTS OUT- N/A                    08900013
RI       EQU   8                   CONTENTS IN- N/A                     09000013
*                                  USE- UNUSED                          09100013
*                                  CONTENTS OUT- N/A                    09200013
RJ       EQU   9                   CONTENTS IN- N/A                     09300013
*                                  USE- UNUSED                          09400013
*                                  CONTENTS OUT- N/A                    09500013
RK       EQU   10                  CONTENTS IN- N/A                     09600013
*                                  USE- GENERAL WORK REGISTER           09700013
*                                  CONTENTS OUT- N/A                    09800013
RL       EQU   11                  CONTENTS IN- N/A                     09900013
*                                  USE- MODULE BASE ADDRESS REGISTER    10000013
*                                  CONTENTS OUT- ADDRESS OF THIS MODULE 10100013
RM       EQU   12                  CONTENTS IN- N/A                     10200013
*                                  USE-EXTRACT BASE ADDRESS REGISTER    10300013
*                                  CONTENTS OUT-EXTRACT ADDRESS         10400013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10500013
*                                  USE- PPI REFERENCE,REGISTER SAVE     10600013
*                                    AREA                               10700013
*                                  CONTENTS OUT- ADDRESS OF PPI         10800013
RO       EQU   14                  CONTENTS IN: RETURN ADDRESS TO SYST  10900013
*                                  USE- MERGE NETWORK BASE ADDRESS REG  11000013
*                                  CONTENTS OUT- RETURN ADDRESS TO SYST 11100013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  11200013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11300013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11400013
         SPACE 2                                                        11500013
*START OF MODULE CODE PROPER:                                           11600013
         SPACE 2                                                        11700013
IERAOQ   CSECT                                                          11800013
         USING *,RL                                                     11900013
         USING IERRCA,RN                                                12000013
         USING DIERRMC,RP                                               12100013
*    MODULE ENTRY POINT     CHART LC                                    12200013
IERMO1   LR    RL,RP                                                    12300013
         ST    RO,RKSAVC9                                               12400013
         L     RO,PPINET+4                                              12500013
         TM    PPISW1+2,X'04'      IS THIS PH 3                         12600013
         BO    *+8                 YES                                  12700013
         L     RO,PPINETM+4        NO                                   12800013
         USING AIERROQ,RO                                               12900013
         TM    PPISW1+3,X'40'      EXTRACTING OR NOT                    13000013
         BC    8,AONNEXT           FALL THRU IF EXTRACTING              13100013
         SPACE 1                                                        13200013
*    THIS FOLLOWING SECTION SETS THE EXTRACT SWITCHES TO YES IF NEEDED  13300013
*    THIS ALSO DETERMINES THE AMOUNT OF CORE REQD FOR THE EXTR POS      13400013
*    PPIMRGMX IS USED IF BALANCED TECHNIQUE                             13500013
*    PPIBDSVA MINUS ONE IS USED IF POLYPHASE TECHNIQUE                  13600013
*    PPIMRGOP IS USED IF A DISK SORT                                    13700013
         SPACE 1                                                        13800013
         TM    PPISW1+2,X'02'      IS THIS A MERGE ONLY?                13900013
         BO    AOQNPOLY            BRANCH IF YES.                       14000013
         SPACE 1                                                        14100013
         TM    PPISW1+1,X'40'      IS THIS A TAPE SORT?                 14200013
         BC    8,AOQDISK           BRANCH IF NO.                        14300013
         SPACE 1                                                        14400013
         TM    PPISW1,X'04'        CHECK FOR TECHNIQUE                  14500013
         BC    8,AOQNPOLY          FALL THRU IF POLYPHASE               14600013
         TM    PPISW1+2,X'04'      CHECK FOR WHICH PHASE                14700013
         BO    AOQNPOLY            GO TO STORE MERGE ORDER              14800018
         SR    RE,RE                                                    14900013
         IC    RE,PPIBDSVA         NUMBER OF ENTRIES IN TAPE TABLE      15000013
         S     RE,KAOONE                                                15100013
         ST    RE,KAOTECH          STORE IN DETERMINE AMT CORE CONSTANT 15200013
         B     AOQDET              ALIGN CNTRL FLDS                     15300018
         SPACE 2                                                        15400013
AOQDISK  MVC   KAOTECH+2(2),PPIMRGOP STORE MRG ORD IN AMT CORE CONST    15500013
         B     AOQDET              ALIGN CNTRL FLDS                     15600018
         SPACE 2                                                        15700013
AOQNPOLY MVC   KAOTECH+2(2),PPIMRGMX  STORE MRG ORD IN AMT CORE CON     15800013
AOQDET   XI    IERDOET+1,X'F0'                                          15900013
         LH    RD,PPILEXFF        LGH OF EXTR CTRL FLDS FROM PPI        16000013
         LA    RD,3(0,RD)          ALIGN EXTR CNTL FLDS UPWARD TO WORD  16100013
         N     RD,KAORNDUP         BOUNDARY IF THEY AREN'T ALREADY      16200013
         A     RD,KAOFOUR          ADD ACTUAL ADDR BYTES TO CNTRL FLD   16300013
         ST    RD,IERDOEXL         STORE IN MERGE NETWORK               16400013
         SR    RC,RC                                                    16500013
         L     RK,KAOTECH          MERGE ORDER FROM TECHNIQUE USED      16600013
         A     RK,KAOONE           MRG ORD + 1                          16700013
         MR    RC,RK               DETERM AMT CORE REQD FOR EXTR POS    16800013
         L     RG,PPISPGN1         PROGRAM GENERATOR ADDRESS            16900013
         SPACE 1                                                        17000013
*    THIS SECTION CHECKS WHETHER OR NOT PPISPGN1 IS ON A FULL WORD      17100013
*    BOUNDARY  IF NOT IT IS ROUNDED DOWNWARD TO A FULL WORD BOUNDARY    17200013
         SPACE 1                                                        17300013
         TM    PPISPGN1+3,X'03'                                         17400013
         BC    8,AOQNRNDU          NO ALIGNMENT NECESSARY               17500018
         LA    RG,3(0,RG)                                               17600013
         N     RG,KAORNDUP                                              17700013
         S     RG,KAOFOUR                                               17800013
AOQNRNDU SR    RG,RD               UPDATE PROG GEN ADDR                 17900013
         ST    RG,PPISPGN1         STORE PROG GEN ADDR                  18000013
         ST    RG,IERDOAGE         BEG ADDR OF GEN EXTR POS IN MRG NTWK 18100013
         L     RM,PPIAXERT         SET BASE REG FOR EXTR RTN            18200013
         L     RC,PPIX61+4                                              18300013
         ST    RC,0(0,RM)          SET USER EXIT ADDR IN EXTR RTN       18400013
         MVC   PPIDD0L1+3(1),PPILEXFD+1 MOVING THE LENGTH AND DISPLAC   18500013
         MVC   PPIDD0L1(2),KAOFOUR+2    ATTRIBUTE FOR CMP INSTR SET     18600013
         SPACE 1                                                        18700013
*    THIS SECTION DETERMINES WHICH PHASE IS BEING EXECUTED AND SETS     18800013
*       THE APPROPRIATE SWITCHES                                        18900013
         SPACE 1                                                        19000013
AOQPHT   TM    PPISW1+2,X'04'      PHASE 2                              19100013
         BO    AOQPH3              FALL THRU IF PH 2                    19200013
         SPACE 1                                                        19300013
*    THIS SECTION SETS THE NETWORK COMPARE INSTRUCTIONS                 19400013
         SPACE 1                                                        19500013
AOQCIS   IC    RE,PPIDD0L1+3                                            19600013
         STC   RE,IERROQWH+1            LENGTH ATTRIBUTE                19700013
         OC    IERROQWH+2(2),PPIDD0L1   DISPLACEMENT ATTRIBUTE          19800013
         OC    IERROQWH+4(2),PPIDD0L1                                   19900013
         STC   RE,IERROQL4+1                                            20000013
         OC    IERROQL4+2(2),PPIDD0L1                                   20100013
         OC    IERROQL4+4(2),PPIDD0L1                                   20200013
         STC   RE,IERROQL2+1                                            20300013
         OC    IERROQL2+2(2),PPIDD0L1                                   20400013
         OC    IERROQL2+4(2),PPIDD0L1                                   20500013
         STC   RE,IERROQL1+1                                            20600013
         OC    IERROQL1+2(2),PPIDD0L1                                   20700013
         OC    IERROQL1+4(2),PPIDD0L1                                   20800013
         STC   RE,IERDOSCK+1                                            20900013
         OC    IERDOSCK+2(2),PPIDD0L1                                   21000013
         OC    IERDOSCK+4(2),PPIDD0L1                                   21100013
         STC   RE,IERROC14+1                                            21200013
         OC    IERROC14+2(2),PPIDD0L1                                   21300013
         OC    IERROC14+4(2),PPIDD0L1                                   21400013
         STC   RE,IERROC13+1                                            21500013
         OC    IERROC13+2(2),PPIDD0L1                                   21600013
         OC    IERROC13+4(2),PPIDD0L1                                   21700013
         STC   RE,IERROC15+1                                            21800013
         OC    IERROC15+2(2),PPIDD0L1                                   21900013
         OC    IERROC15+4(2),PPIDD0L1                                   22000013
         STC   RE,IERROC11+1                                            22100013
         OC    IERROC11+2(2),PPIDD0L1                                   22200013
         OC    IERROC11+4(2),PPIDD0L1                                   22300013
         STC   RE,IERROQS4+1                                            22400013
         OC    IERROQS4+2(2),PPIDD0L1                                   22500013
         OC    IERROQS4+4(2),PPIDD0L1                                   22600013
         STC   RE,IERROQU4+1                                            22700013
         OC    IERROQU4+2(2),PPIDD0L1                                   22800013
         OC    IERROQU4+4(2),PPIDD0L1                                   22900013
         STC   RE,IERROQU2+1                                            23000013
         OC    IERROQU2+2(2),PPIDD0L1                                   23100013
         OC    IERROQU2+4(2),PPIDD0L1                                   23200013
         STC   RE,IERROQU1+1                                            23300013
         OC    IERROQU1+2(2),PPIDD0L1                                   23400013
         OC    IERROQU1+4(2),PPIDD0L1                                   23500013
         STC   RE,IERROC6+1                                             23600013
         OC    IERROC6+2(2),PPIDD0L1                                    23700013
         OC    IERROC6+4(2),PPIDD0L1                                    23800013
         STC   RE,IERROC5+1                                             23900013
         OC    IERROC5+2(2),PPIDD0L1                                    24000013
         OC    IERROC5+4(2),PPIDD0L1                                    24100013
         STC   RE,IERROC7+1                                             24200013
         OC    IERROC7+2(2),PPIDD0L1                                    24300013
         OC    IERROC7+4(2),PPIDD0L1                                    24400013
         STC   RE,IERROC3+1                                             24500013
         OC    IERROC3+2(2),PPIDD0L1                                    24600013
         OC    IERROC3+4(2),PPIDD0L1                                    24700013
         STC   RE,IERROQ4S+1                                            24800013
         OC    IERROQ4S+2(2),PPIDD0L1                                   24900013
         OC    IERROQ4S+4(2),PPIDD0L1                                   25000013
         STC   RE,IERDOICP+1                                            25100013
         OC    IERDOICP+2(2),PPIDD0L1                                   25200013
         OC    IERDOICP+4(2),PPIDD0L1                                   25300013
         SPACE 1                                                        25400013
*    EXIT TO NEXT ASSIGNMENT ROUTINE                                    25500013
         SPACE 1                                                        25600013
         L     RO,RKSAVC9                                               25700013
         BR    RO                  NEXT ASSGN. RTN.                     25800018
         SPACE 2                                                        25900013
*    NOT EXTRACTING                                                     26000013
         SPACE 1                                                        26100013
AONNEXT  XI    IERROBWR+1,X'F0'                                         26200013
         XI    IERXTRT1+1,X'F0'                                         26300013
         XI    IERXTRT2+1,X'F0'                                         26400013
         XI    IERDOSET+1,X'F0'                                         26500013
         MVI   ROQMERG+1,X'F0'     MODIFY BRANCH CONDITION IN ROQ       26550017
         B     AOQPHT              BRANCH TO PHASE TEST                 26600013
         SPACE 2                                                        26700013
*    PHASE 3 SETTINGS                                                   26800013
         SPACE 1                                                        26900013
AOQPH3   XI    IERROBB1+1,X'F0'                                         27000013
         XI    IERNEXTR+1,X'F0'                                         27100013
         XI    IERDOCPS+1,X'F0'                                         27200013
         B     AOQCIS              GO TO SET COMPARE INSTR              27300013
         SPACE 2                                                        27400013
         DS    0F                                                       27500013
KAOTECH  DC    XL4'0'                                                   27600013
KAOONE   DC    XL4'1'                                                   27700013
KAOFOUR  DC    XL4'4'                                                   27800013
KAORNDUP DC    X'FFFFFFFC'                                              27900013
*********************************************************************** 28000013
RKSAVC9  DS    F                   NEXT ASSGN. RTN. ADDR.               28100018
AIERROQ  DSECT                                                          28200013
IERDO1   B     ROQSINIT            READ PRIME ENTRY BR TO INITIALIZAT   28300013
         B     ROQCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 28400013
IERDOET  B     ROQNTENS            DEBLOCK ENTRY FALL THRU IF EXTRACT   28500013
*                                  CHART L6                             28600013
         L     RC,ROQSVEXA         SET REG WITH EXTRACT ADDRESS         28700013
         ST    RD,0(0,RC)          STORE REC ADDR IN EXTRACT POS ADDR   28800013
         LR    RA,RC                                                    28900013
         LR    RC,RD               SET FROM AND TO REG FOR EXTRACT RTN  29000013
         LR    RD,RA                                                    29100013
         BAL   RO,4(0,RM)          EXIT TO EXTRACT ROUTINE              29200013
*    NETWORK ENTRANCE SWITCH                                            29300013
         SPACE 1                                                        29400013
ROQNTENS BC    0,ROQLF8            FOR MRG ORD > 8, FALL THRU           29500013
         SPACE 1                                                        29600013
*    DETERMINATION OF WHICH HALF OF MRG NTWK RCDS THE NEW RCD MUST CMP  29700013
         SPACE 1                                                        29800013
         L     RC,ROQMRGAM         ADDR OF ITEM 8                       29900013
IERROQWH CLC   0(1,RD),0(RC)                                            30000013
         SPACE 1                                                        30100013
*    THIS INSTR IS BC 10/12 DEPENDING ON THE INPUT SEQUENCE             30200013
         SPACE 1                                                        30300013
ROQWHB   BC    12,ROQLF8           IF NEW GT / LT ITEM 8, FALL THRU     30400013
ROQLF16  LM    0,0,ROQMRGAL        LOAD NTWK REG WITH THOSE NECESSARY   30500013
*                                  RCD FROM ITEMS 9 THRU 15.INSTR IS    30600013
*                                  SET BY THE CUTBACK RTN               30700013
         SPACE 1                                                        30800013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 9 THRU 15.               30900013
         SPACE 1                                                        31000013
ROQPNELA B     IERROQL4            PARTIAL NTWK ENTR SWITCH SET BY      31100013
*                                  CUTBACK RTN                          31200013
         SPACE 2                                                        31300013
*    ENTRANCE FOR A 14, 15, 16 WAY MERGE                                31400013
         SPACE 1                                                        31500013
IERROQL4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        31600013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             31700013
ROQ12B   BH    IERROC14            IF HI/LO GO TO CMP ITEM 14 OR 13     31800013
         SPACE 1                                                        31900013
*    ENTRANCE FOR 11, 12, 13 WAY MERGE                                  32000013
         SPACE 1                                                        32100013
IERROQL2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 10        32200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             32300013
ROQ10B   BH    IERROC11            IF HI/LO GO TO CMP ITEM 11,12/ UPDAT 32400013
         SPACE 1                                                        32500013
*    ENTRANCE FOR A 10 WAY MERGE                                        32600013
         SPACE 1                                                        32700013
IERROQL1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 9         32800013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             32900013
ROQ9B    BH    ROQMOV9             FIT INTO COLLATING SEQUENCE          33000018
         SPACE 1                                                        33100013
*    ENTRANCE FOR A 9 WAY MERGE AND NEW ITEM COLLATES AFT ITEM 8        33200013
         SPACE 1                                                        33300013
ROQ9WMRG LR    RC,RD                                                    33400013
         LM    RD,RK,ROQMRGAU                                           33500013
         STM   RE,RK,ROQMRGAU                                           33600013
         ST    RC,ROQMRGAM                                              33700013
         SPACE 1                                                        33800013
*    THIS SECTION OF CODE COMMUNICATES THE NETWORKS WINNING RECORD      33900013
*       ADDRESS TO THE BLOCK ROUTINE AFTER TAKING APPROPRIATE ACTION    34000013
*       IF EXTRACTING AND IF THERE IS TO BE A SEQUENCE CHECK. THE PHASE 34100013
*    AND EXTRACT SWITCHES ARE SET BY THE ASSGN RTN.                     34200013
         SPACE 1                                                        34300013
IERROBWR BC    0,IERNEXTR          IF EXTRACTING FALL THRU              34400013
IERROBB1 BC    0,ROQEPH3P          FALL THRU FOR PHASE 2                34500013
         ST    RD,ROQSVEXA         SAVE EXTRACT POSITION ADDR           34600013
         L     RD,0(0,RD)          LOAD ACTUAL ADDR OF WINNING RCD      34700013
ROQBBFIS BC    0,ROQISOUT          CHANGED FROM NO-OP TO UNCONDITIONAL  34800018
         L     RL,PPIBLK2+4                                             34900013
         SPACE 1                                                        35000013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RECORD     35100013
         SPACE 2                                                        35200013
ROQISOUT XI    ROQBBFIS+1,X'F0'                                         35300013
         L     RL,PPIBLK2+4                                             35400013
         B     12(0,RL)            EXIT IF USER MOD.                    35500018
         SPACE 2                                                        35600013
*    PHASE 3 + MERGE ONLY PROCEDURE IF EXTRACTING                       35700013
         SPACE 1                                                        35800013
ROQEPH3P L     RC,ROQSQCWD         AVAIL EXTRACT POS ADDR               35900013
         ST    RC,ROQSVEXA         SAVE AVAIL EXTRACT POS ADDR          36000013
         ST    RD,ROQSQCWD         SAVE WIN EXTRACT POS ADDR FOR SEQ CK 36100013
*    SWITCH SET BY INITIAL SEQUENCING RTN TO BYPASS CHK FOR SEQ CHK     36200013
         SPACE 1                                                        36300013
ROQFRSW1 BC    0,ROQFR1            FALL THRU IF NOT FIRST RECORD        36400013
         SPACE 1                                                        36500013
*    IF THE NEW RECORD IS THE WINNER,A SEQUENCE CHECK WILL BE PERFORMED 36600013
*       IF REQUESTED. IF THE NEW RECORD IS NOT THE WINNER,NO SEQUENCE   36700013
*       CHECK IS NECESSARY.                                             36800013
         SPACE 1                                                        36900013
ROQSCSW  BC    0,ROQNIW            FALL THRU IF NEW IS NOT WINNER       37000013
IERXTRT1 BC    0,ROQEPH3           FALL THRU IF EXTRACTING              37100013
ROQSAA   L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   37200013
ROQEPH3  L     RL,PPIBLK+4                                              37300013
         B     4(0,RL)             EXIT TO BLK RTN WANT NEXT RECORD     37400013
         SPACE 2                                                        37500013
ROQFR1   XI    ROQFRSW1+1,X'F0'    SET FIRST RCD SWITCH 1 TO FALL THRU  37600013
         B     ROQSAA              BRANCH TO SET ACTUAL ADDRESS         37700013
         SPACE 2                                                        37800013
ROQNIW   XI    ROQSCSW+1,X'F0'     SET ROQSCSW TO FALL THRU             37900013
         SPACE 1                                                        38000013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      38100013
*       WINNER. CHECK DONE USING REG RD AND RC.                         38200013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLOCK RTN. THE BLOCK RTN.    38300013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  38400013
*       EXITS ARE ACTIVATED,THE BLOCK RTN TAKES NO ACTION CONCERNING    38500013
*       PPIDOUO.                                                        38600013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        38700013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     38800013
*       PPIDOUO IS 0.                                                   38900013
         SPACE 1                                                        39000013
         L     RB,PPIDOUO                                               39100013
         B     ROQCKISC(RB)        BRANCH TO TEST                       39200018
ROQCKISC B     IERDOSCK            SEQUENCE CHECK                       39300018
         SPACE 2                                                        39400013
*    NO  SEQUENCE CHECK                                                 39500013
         SPACE 1                                                        39600013
IERXTRT2 BC    15,ROQSAA           IF EXTRACTING BRANCH TO ROQSAA       39700013
         B     ROQEPH3             IF NOT EXTRACTING BRANCH TO ROQEPH3  39800013
         SPACE 2                                                        39900013
IERDOSCK CLC   0(1,RD),0(RC)                                            40000013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   40100013
ROQSCB   BC    10,IERXTRT1         EXTRACT RTN.                         40200018
         SPACE 1                                                        40300013
*    OUT OF SEQUENCE ERROR                                              40400013
         SPACE 1                                                        40500013
         L     RO,PPIRMC+4                                              40600013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   40630017
         BO    ROQMERG             YES, BRANCH                          40660017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              40700013
ROQSEQ   L     RP,PPIADSSC                                              40800017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       40900013
         L     RP,PPIADSSC                                              41000013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  41100013
ROQMERG  BC    0,ROQ100            FALL THRU IF EXTRACTING              41103017
         SPACE 1                                                        41106017
         L     RD,0(RD)            LOAD RECORD ADDRESS FROM EXTRACT     41109017
*                                    WORK AREA                          41112017
ROQ100   SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     41115017
         CVD   RD,ROQCONV          CONVERT INDEX TO DECIMAL             41120017
         UNPK  ROQTEMP(2),ROQCONV+6(2) UNPACK FOR PRINTING              41130017
         OI    ROQTEMP+1,X'F0'     SET SIGN POSITIVE                    41140017
         MVC   MSGP3MA8(2),ROQTEMP      MOVE UNIT NUMBER INTO MESSAGE   41150017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                41160017
         B     ROQSEQ              GO PRINT MESSAGE                     41170017
         SPACE 2                                                        41200013
*    NOT EXTRACTING                                                     41300013
         SPACE 1                                                        41400013
IERNEXTR B     ROQBBFIS            IF PHASE 2 BRANCH                    41500013
ROQFRSW2 BC    0,ROQFR2            IF FIRST RCD BRANCH                  41600013
         L     RC,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         41700013
         B     ROQSCSW             BRANCH TO CHK IF SEQ CHK REQUIRED    41800013
         SPACE 2                                                        41900013
ROQFR2   XI    ROQFRSW2+1,X'F0'    SET FIRST RCD SW 2 TO FALL THRU      42000013
         B     ROQEPH3             BRANCH TO BLOCK RECORD               42100013
         SPACE 2                                                        42200013
IERROC14 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 14        42300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             42400013
ROQ14B   BH    IERROC15            IF HI/LO GO TO CMP ITM 15 OR UPDATE  42500013
         SPACE 1                                                        42600013
IERROC13 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 13        42700013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             42800013
ROQ13B   BH    ROQMOV13            IF HI/LO NEW COLLATES AFTER ITEM 13  42900013
         SPACE 1                                                        43000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 12 + BEFORE ITEM 13      43100013
         SPACE 1                                                        43200013
ROQMOV12 L     RK,ROQMRGAM                                              43300013
         LR    RI,RD                                                    43400013
         STM   RE,RI,ROQMRGAM                                           43500013
         LM    RD,RJ,ROQMRGAU                                           43600013
         STM   RE,RK,ROQMRGAU                                           43700013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              43800013
         SPACE 2                                                        43900013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 13 + BEFORE ITEM 14      44000013
         SPACE 1                                                        44100013
ROQMOV13 L     RK,ROQMRGAM                                              44200013
         LR    RJ,RD                                                    44300013
         STM   RE,RJ,ROQMRGAM                                           44400013
         LM    RD,RJ,ROQMRGAU                                           44500013
         STM   RE,RK,ROQMRGAU                                           44600013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              44700013
         SPACE 2                                                        44800013
IERROC15 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 15        44900013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      45000013
ROQ15B   BH    ROQMOV15            IF HI/LO NEW COLLATES AFTER ITEM 15  45100013
         SPACE 1                                                        45200013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 14 + BEFORE ITEM 15      45300013
ROQMOV14 L     RC,ROQMRGAM                                              45400013
         LR    RK,RD                                                    45500013
         STM   RE,RK,ROQMRGAM                                           45600013
         LM    RD,RJ,ROQMRGAU                                           45700013
         LR    RK,RC                                                    45800013
         STM   RE,RK,ROQMRGAU                                           45900013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              46000013
         SPACE 2                                                        46100013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 15                     46200013
ROQMOV15 L     RC,ROQMRGAM                                              46300013
         STM   RE,RK,ROQMRGAM                                           46400013
         ST    RD,ROQMRGAL+24                                           46500013
         LR    RK,RC                                                    46600013
         LM    RD,RJ,ROQMRGAU                                           46700013
         STM   RE,RK,ROQMRGAU                                           46800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              46900013
         SPACE 2                                                        47000013
IERROC11 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 11        47100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             47200013
ROQ11B   BH    ROQMOV11            FIT INTO COLLATING SEQUENCE          47300018
         SPACE 1                                                        47400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 10 + BEFORE ITEM 11      47500013
ROQMOV10 L     RK,ROQMRGAM                                              47600013
         LR    RG,RD                                                    47700013
         STM   RE,RG,ROQMRGAM                                           47800013
         LM    RD,RJ,ROQMRGAU                                           47900013
         STM   RE,RK,ROQMRGAU                                           48000013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              48100013
         SPACE 2                                                        48200013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 11 + BEFORE ITEM 12      48300013
ROQMOV11 L     RK,ROQMRGAM                                              48400013
         LR    RH,RD                                                    48500013
         STM   RE,RH,ROQMRGAM                                           48600013
         LM    RD,RJ,ROQMRGAU                                           48700013
         STM   RE,RK,ROQMRGAU                                           48800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              48900013
         SPACE 2                                                        49000013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 9 + BEFORE ITEM 10       49100013
ROQMOV9  L     RK,ROQMRGAM                                              49200013
         LR    RF,RD                                                    49300013
         STM   RE,RF,ROQMRGAM                                           49400013
         LM    RD,RJ,ROQMRGAU                                           49500013
         STM   RE,RK,ROQMRGAU                                           49600013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              49700013
         SPACE 2                                                        49800013
*    SPECIAL ITEM 12 COMPARE FOR 13 WAY MERGE                           49900013
         SPACE 1                                                        50000013
IERROQS4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 12        50100013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             50200013
ROQS12B  BH    ROQMOV12            IF HI/LO GO TO UPDATE                50300013
         B     IERROC11            GO TO COMPARE NEW ITEM WITH ITEM 11  50400013
         EJECT                                                          50500013
ROQLF8   LM    0,0,ROQMRGAU        LOAD NTWK REG WITH THOSE NECESSARY   50600013
*                                  RCD FROM ITEMS 1 THRU 7. INSTR IS    50700013
*                                  SET BY THE CUTBACK RTN               50800013
         SPACE 1                                                        50900013
*    PARTIAL NETWORK FOR CMP NEW AGAINST ITEMS 1 THRU 7                 51000013
         SPACE 1                                                        51100013
ROQPNEL9 B     IERROQU4            PARTIAL NTWK ENTR SWITCH SET BY      51200013
*                                  CUTBACK RTN                          51300013
         SPACE 1                                                        51400013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   51500013
         SPACE 1                                                        51600013
IERROQU4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM TO ITEM 4           51700013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             51800013
ROQ4B    BH    IERROC6             IF HI/ LO GO TO CMP ITEM 6 OR 5      51900013
         SPACE 1                                                        52000013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   52100013
         SPACE 1                                                        52200013
IERROQU2 CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         52300013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             52400013
ROQ2B    BH    IERROC3             IF HI/LO GO TO CMP ITEM 3,4 / UPDATE 52500013
         SPACE 1                                                        52600013
*    ENTRANCE FOR A 2 WAY MERGE                                         52700013
         SPACE 1                                                        52800013
IERROQU1 CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         52900013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             53000013
ROQ1B    BH    ROQMOV1             FIT INTO COLLATING SEQUENCE          53100018
         SPACE 1                                                        53200013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW IS WINNER                       53300013
         SPACE 1                                                        53400013
ROQ1WMRG XI    ROQSCSW+1,X'F0'     SET SEQ CHK SWITCH TO YES            53500013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              53600018
         SPACE 2                                                        53700013
IERROC6  CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         53800013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      53900013
ROQ6B    BH    IERROC7             IF HI/LO GO TO CMP ITEM 7 OR UPDATE  54000013
         SPACE 1                                                        54100013
IERROC5  CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         54200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             54300013
ROQ5B    BH    ROQMOV5             IF HI/ LO NEW COLLATES AFTER ITEM 5  54400013
         SPACE 1                                                        54500013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 4 + BEFORE ITEM 5        54600013
         SPACE 1                                                        54700013
ROQMOV4  LR    RI,RD                                                    54800013
         LR    RD,RE                                                    54900013
         STM   RF,RI,ROQMRGAU                                           55000013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              55100013
         SPACE 2                                                        55200013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 5 + BEFORE ITEM 6        55300013
         SPACE 1                                                        55400013
ROQMOV5  LR    RJ,RD                                                    55500013
         LR    RD,RE                                                    55600013
         STM   RF,RJ,ROQMRGAU                                           55700013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              55800013
         SPACE 2                                                        55900013
IERROC7  CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         56000013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             56100013
ROQ7B    BH    ROQMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   56200013
         SPACE 1                                                        56300013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 6 + BEFORE ITEM 7        56400013
         SPACE 1                                                        56500013
ROQMOV6  LR    RK,RD                                                    56600013
         LR    RD,RE                                                    56700013
         STM   RF,RK,ROQMRGAU                                           56800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              56900013
         SPACE 2                                                        57000013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      57100013
         SPACE 1                                                        57200013
ROQMOV7  ST    RD,ROQMRGAM-4                                            57300013
         LR    RD,RE                                                    57400013
         STM   RF,RK,ROQMRGAU                                           57500013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              57600013
         SPACE 2                                                        57700013
IERROC3  CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         57800013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             57900013
ROQ3B    BH    ROQMOV3             FIT INTO COLLATING SEQUENCE          58000018
         SPACE 1                                                        58100013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 2 + BEFORE ITEM 3        58200013
ROQMOV2  LR    RG,RD                                                    58300013
         LR    RD,RE                                                    58400013
         STM   RF,RG,ROQMRGAU                                           58500013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              58600013
         SPACE 2                                                        58700013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 3 + BEFORE ITEM 4        58800013
         SPACE 1                                                        58900013
ROQMOV3  LR    RH,RD                                                    59000013
         LR    RD,RE                                                    59100013
         STM   RF,RH,ROQMRGAU                                           59200013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              59300013
         SPACE 2                                                        59400013
*    UPDATING WHERE NEW ITEM COLLATES AFT ITEM 1 + BEFORE ITEM 2        59500013
         SPACE 1                                                        59600013
ROQMOV1  ST    RD,ROQMRGAU                                              59700013
         LR    RD,RE                                                    59800013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              59900013
         SPACE 2                                                        60000013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             60100013
IERROQ4S CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         60200013
*    THIS INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE             60300013
ROQS4B   BH    ROQMOV4             IF HI/LO GO TO UPDATE                60400013
         B     IERROC3             GO TO COMPARE NEW ITEM WITH ITEM 3   60500013
         EJECT                                                          60600013
*    THE NETWORK CUTBACK SECTION.                                       60700013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      60800013
         SPACE 1                                                        60900013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        61000013
         SPACE 1                                                        61100013
*    SET NETWORK FOR A 16 WAY MERGE                                     61200013
         SPACE 1                                                        61300013
ROQCSSWM MVC   ROQNTENS(4),ROQSESC8  SET NTWK ENTR SW FOR NEW/ITM 8 CMP 61400013
         MVI   ROQLF16+1,X'4A'     LOAD NTWK REG WITH ITEMS 9 THRU 15   61500013
         MVI   ROQLF8+1,X'4A'      LOAD NTWK REG WITH ITEMS 1 THRU 7    61600013
         MVC   ROQ12B(4),ROQ12SB   SET BR TO CMP ITEM 14 AFT ITEM 12    61700013
         MVC   ROQ4B(4),ROQST4B    SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  61800013
         MVC   ROQ14B(4),ROQS14B   SET BR TO CMP ITEM 15 AFT ITEM 14    61900013
         MVC   ROQ6B(4),ROQS6B     SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  62000013
         MVC   ROQ10B(4),ROQS10B   SET BR TO CMP ITEM 11 AFT ITEM 10    62100013
         MVC   ROQ2B(4),ROQS2B     SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  62200013
         MVC   ROQPNELA(4),ROQSPNS1 SET NTWK ENTRANCE FOR ITMS 9 TO 15  62300013
         MVC   ROQPNEL9(4),ROQSPNS2 SET NTWK ENTRANCE FOR ITMS 1 TO 7   62400013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 62500013
         SPACE 1                                                        62600013
*    SET NETWORK FOR A 15 WAY MERGE                                     62700013
         SPACE 1                                                        62800013
         MVC   ROQ14B(4),ROQFTWM   SET BR TO UPDATE AFTER ITEM 14 CMP   62900013
         MVI   ROQLF16+1,X'49'     LOAD NTWK REG WITH ITEMS 9 THRU 14   63000013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 63100013
         SPACE 1                                                        63200013
*    SET NETWORK FOR A 14 WAY MERGE                                     63300013
         SPACE 1                                                        63400013
         MVC   ROQ12B(4),ROQ14WM   SET BR TO CMP ITEM 13 AFT ITEM 12    63500013
         MVI   ROQLF16+1,X'48'     LOAD NTWK REG WITH ITEMS 9 TO 13     63600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 63700013
         SPACE 1                                                        63800013
*    SET NETWORK FOR A 13 WAY MERGE                                     63900013
         SPACE 1                                                        64000013
         MVC   ROQ10B(4),ROQ13WM   SET BR TO CMP ITEM 12 AFT ITM 10 CMP 64100013
         MVI   ROQLF16+1,X'47'     LOAD NTWK REG WITH ITEMS 9 TO 12     64200013
         MVC   ROQPNELA(4),ROQE13WM SET NTWK ENTR FOR A 13 WAY MERGE    64300013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 64400013
         SPACE 1                                                        64500013
*    SET NETWORK FOR A 12 WAY MERGE                                     64600013
         SPACE 1                                                        64700013
         MVC   ROQ10B(4),ROQS10B   SET BR TO CMP ITEM 11 AFT ITM 10 CMP 64800013
         MVI   ROQLF16+1,X'46'     LOAD NTWK REG WITH ITEMS 9 TO 11     64900013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 65000013
         SPACE 1                                                        65100013
*    SET NETWORK FOR AN 11 WAY MERGE                                    65200013
         SPACE 1                                                        65300013
         MVC   ROQ10B(4),ROQ11WM   SET BR TO UPDATE AFT ITEM 10 CMP     65400013
         MVI   ROQLF16+1,X'45'     LOAD NTWK REG WITH ITEMS 9 + 10      65500013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 65600013
         SPACE 1                                                        65700013
*    SET NETWORK FOR A 10 WAY MERGE                                     65800013
         SPACE 1                                                        65900013
         MVC   ROQPNELA(4),ROQE10WM SET NTWK ENTR FOR A 10 WAY MRG      66000013
         MVI   ROQLF16+1,X'44'     LOAD NTWK REG WITH ITEM 9            66100013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 66200013
         SPACE 1                                                        66300013
*    SET NETWORK FOR A 9 WAY MERGE                                      66400013
         SPACE 1                                                        66500013
         MVC   ROQPNELA(4),ROQE9WM SET NTWK ENTR FOR A 9 WAY MERGE      66600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 66700013
         SPACE 1                                                        66800013
*    SET NETWORK FOR AN 8 WAY MERGE                                     66900013
         SPACE 1                                                        67000013
         XI    ROQNTENS+1,X'F0'    SET NTWK ENTR SW FOR 8/LESS MRG ORD  67100013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 67200013
         SPACE 1                                                        67300013
*    SET NETWORK FOR A 7 WAY MERGE                                      67400013
         SPACE 1                                                        67500013
         MVC   ROQ6B(4),ROQ7WM     BR TO UPDATE IF GT ITEM 7            67600013
         MVI   ROQLF8+1,X'49'      LOAD NTWK REG WITH ITEMS 1 TO 6      67700013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 67800013
         SPACE 1                                                        67900013
*    SET NETWORK FOR A 6 WAY MERGE                                      68000013
         SPACE 1                                                        68100013
         MVC   ROQ4B(4),ROQ6WM     BR TO CMP ITEM 5 IF GT ITEM 4        68200013
         MVI   ROQLF8+1,X'48'      LOAD NETWORK REG WITH ITEMS 1 TO 5   68300013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 68400013
         SPACE 1                                                        68500013
*    SET NETWORK FOR A 5 WAY MERGE                                      68600013
         SPACE 1                                                        68700013
         MVC   ROQ2B(4),ROQ5WM     BR TO CMP ITEM 4 IF GT ITEM 2        68800013
         MVI   ROQLF8+1,X'47'      LOAD NTWK REG WITH ITEMS 1 TO 4      68900013
         MVC   ROQPNEL9(4),ROQE5WM SET NTWK ENTR FOR A 5 WAY MRG        69000013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 69100013
         SPACE 1                                                        69200013
*    SET NETWORK FOR A 4 WAY MERGE                                      69300013
         SPACE 1                                                        69400013
         MVC   ROQ2B(4),ROQS2B     BR TO CMP ITEM 3 IF GT ITEM 2        69500013
         MVI   ROQLF8+1,X'46'      LOAD NTWK REG WITH ITEMS 1 TO 3      69600013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 69700013
         SPACE 1                                                        69800013
*    SET NETWORK FOR A 3 WAY MERGE                                      69900013
         SPACE 1                                                        70000013
         MVC   ROQ2B(4),ROQ3WM     BR TO UPDATE IF GT ITEM 2            70100013
         MVI   ROQLF8+1,X'45'      LOAD NTWK REG WITH ITEMS 1 + 2       70200013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 70300013
         SPACE 1                                                        70400013
*    SET NETWORK FOR A 2 WAY MERGE                                      70500013
         SPACE 1                                                        70600013
         MVC   ROQPNEL9(4),ROQE2WM SET NTWK ENTR FOR A 2 WAY MERGE      70700013
         MVI   ROQLF8+1,X'44'      LOAD NTWK REG WITH ITEM 1            70800013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 70900013
         SPACE 1                                                        71000013
*    SET NETWORK FOR A 1 WAY MERGE                                      71100013
         SPACE 1                                                        71200013
         MVC   ROQPNEL9(4),ROQE1WM SET NTWK ENTR FOR A 1 WAY MERGE      71300013
         BAL   RC,ROQFMUDS         SAVE ADDRESS OF NEXT CUTBACK ADDRESS 71400013
         SPACE 1                                                        71500013
*    A ZERO WAY MERGE                                                   71600013
         SPACE 1                                                        71700013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    71800013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        71900013
         SPACE 1                                                        72000013
IERDOCPS BC    0,ROQCPH3           FALL THRU IF PHASE 2                 72100013
         L     RL,PPIBLK2+4                                             72200013
         BR    RL                  BLOCK/DEBLOCK                        72300018
         SPACE 2                                                        72400013
ROQCPH3  L     RL,PPIBLK+4                                              72500013
         BR    RL                  BLOCK                                72600018
         SPACE 2                                                        72700013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     72800013
         SPACE 1                                                        72900013
ROQCUTEN L     RC,ROQSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 73000013
         BR    RC                  NEXT WORD OF CUTBACK                 73100018
         SPACE 2                                                        73200013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 73300013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    73400013
*    MERGE ORDER. SUBSEQUENTLY AN UPDATE IS EXECUTED.                   73500013
         SPACE 1                                                        73600013
ROQFMUDS BC    0,ROQFDMO           SET TO BRANCH BY INITIALIZATION RTN  73700013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           73800013
         SPACE 1                                                        73900013
         ST    RC,ROQSVCBA                                              74000013
         L     RD,ROQMRGAU                                              74100013
         L     RE,ROQACMO          MERGE ORDER LESS 1 MINUS 1           74200013
         S     RE,KROONE                                                74300013
         ST    RE,ROQACMO                                               74400013
         SLL   RE,2                TOTAL NO. BYTES TO BE UPDATED        74500013
         EX    RE,ROQUPDT          EXECUTE MOVE INSTR                   74600013
         SPACE 1                                                        74700013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              74800013
         SPACE 2                                                        74900013
         SPACE 2                                                        75000013
ROQFDMO  L     RF,ROQIDMO          SET TO 16 BY INITIALIZATION RTN      75100013
         C     RF,ROQACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 75200013
         BE    ROQSFTTU            SET FALL THRU TO UPDATE              75300013
         S     RF,KROONE                                                75400013
         ST    RF,ROQIDMO                                               75500013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           75600013
         SPACE 2                                                        75700013
ROQSFTTU XI    ROQFMUDS+1,X'F0'    SET ROQFMUDS BRANCH TO FALL THRU     75800013
         ST    RC,ROQSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    75900013
         B     ROQINTSQ            GO TO INIT SEQ THE RECORDS           76000013
         EJECT                                                          76100013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 76200013
*    EACH MERGE OPERATION.                                              76300013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         76400013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  76500013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   76600013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   76700013
*       PPI IS UTILIZED.                                                76800013
         SPACE 1                                                        76900013
ROQINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   77000013
         L     RB,ROQACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   77100013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    77200013
ROQRETRN L     RF,ROQACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  77300013
*                                  CHECKED WITH ALL THE OTHER ITEMS     77400013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          77500013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 77600013
         SR    RH,RH               INDEX USED TO COMPARE ALL OTHER ITEM 77700013
ROQANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      77800013
IERDOICP CLC   0(1,RD),0(RC)                                            77900013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   78000013
ROQISNLH BC    10,ROQHIEQ          HI/LO AND EQUAL CASE TREATED SAME    78100013
ROQDECR  LA    RH,4(0,RH)                                               78200013
         BCT   RF,ROQANOTH         DECREMENT MERGE ORDER                78300018
ROQCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   78400013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  78500013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   78600013
         BE    ROQINSRT            IF ZERO STORE ITEM                   78700013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   78800013
         B     ROQCHEK             CHECK NEXT ITEM                      78900018
         SPACE 2                                                        79000013
ROQINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                79100013
         BCT   RB,ROQINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 79200013
         B     ROQOUTIS            BRANCH TO SET NETWORK ADDRESS        79300013
         SPACE 2                                                        79400013
ROQHIEQ  LA    RE,4(0,RE)                                               79500013
         B     ROQDECR             GO TO DECREMENT MERGE ORDER          79600018
         SPACE 2                                                        79700013
ROQINCR  LA    RI,4(0,RI)                                               79800013
         B     ROQRETRN            BRANCH FOR END OF COMPARE            79900018
         SPACE 2                                                        80000013
*    SET NETWORK AREA WITH ADDRESSES OF PRIMED RECORDS                  80100013
         SPACE 1                                                        80200013
ROQOUTIS L     RD,PPIPSVA          SET REG WITH WINNING RECORD ADDR     80300013
         L     RE,ROQACMO                                               80400013
         S     RE,KROONE                                                80500013
         LR    RF,RE                                                    80600013
         SLL   RE,2                                                     80700013
         LTR   RE,RE                                                    80800013
         BZ    ROQSTM              IF ZERO BYPASS NSI                   80900018
         S     RE,KROONE           DET NO. BYTES TO BE MOVED TO MRG ARA 81000013
         EX    RE,ROQSANW          EXECUTE MOVE OF ADDR TO MOVE AREA    81100013
ROQSTM   ST    RF,ROQACMO          SET ACTUAL MERGE ORDER MINUS ONE FOR 81200013
*                                  UPDATING AFTER A CUTBACK OPERATION   81300013
         XI    ROQFRSW1+1,X'F0'    SETTING OF FIRST RCD SW TO BRANCH    81400013
         XI    ROQFRSW2+1,X'F0'                                         81500013
         XI    ROQBBFIS+1,X'F0'                                         81600013
         B     IERROBWR            BRANCH TO OUTPUT WINNER              81700013
         SPACE 2                                                        81800013
         EJECT                                                          81900013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     82000013
*    OF EACH PASS OR SUB PASS.                                          82100013
         SPACE 1                                                        82200013
ROQSINIT MVC   ROQIDMO(4),KROSXTN  SET MAX MERGE ORDER TO 16            82300013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          82400013
         ST    RE,ROQACMO                                               82500013
         SR    RE,RE                                                    82600013
         ST    RE,PPIPSVA                                               82700013
         MVC   PPIPSVA+4(60),PPIPSVA   ZERO INT SEQ STORE AREA          82800013
         XI    ROQFMUDS+1,X'F0'    SET ROQFMUDS TO BRANCH               82900013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG          83000013
         BC    1,ROQISD            FALL THRU IF INPUT SEQ IS ASDNG      83100013
         TM    ROQ12B+1,X'20'      IS ROUTINE SET FOR ASDNG             83200013
ROQFDSQ  BC    1,IERDOSET          IF THE ROUTINE IS SET FOR THE INPUT  83300013
         XI    ROQWHB+1,X'60'      SEQUENCE,BRANCH TO EXTRACT TEST. IF  83400013
         XI    ROQ12B+1,X'60'      THE ROUTINE IS NOT SET FOR THE INPUT 83500013
         XI    ROQ10B+1,X'60'      CHANGE THE MASK OF THE BRANCH ON     83600013
         XI    ROQ9B+1,X'60'       CONDITION INSTR.                     83700013
         XI    ROQSCB+1,X'60'                                           83800013
         XI    ROQ14B+1,X'60'                                           83900013
         XI    ROQ13B+1,X'60'                                           84000013
         XI    ROQ15B+1,X'60'                                           84100013
         XI    ROQ11B+1,X'60'                                           84200013
         XI    ROQS12B+1,X'60'                                          84300013
         XI    ROQ4B+1,X'60'                                            84400013
         XI    ROQ2B+1,X'60'                                            84500013
         XI    ROQ1B+1,X'60'                                            84600013
         XI    ROQ6B+1,X'60'                                            84700013
         XI    ROQ5B+1,X'60'                                            84800013
         XI    ROQ7B+1,X'60'                                            84900013
         XI    ROQ3B+1,X'60'                                            85000013
         XI    ROQS4B+1,X'60'                                           85100013
         XI    ROQISNLH+1,X'60'                                         85200013
         XI    ROQ12SB+1,X'60'                                          85300013
         XI    ROQST4B+1,X'60'                                          85400013
         XI    ROQS14B+1,X'60'                                          85500013
         XI    ROQS6B+1,X'60'                                           85600013
         XI    ROQS10B+1,X'60'                                          85700013
         XI    ROQS2B+1,X'60'                                           85800013
         XI    ROQFTWM+1,X'60'                                          85900013
         XI    ROQ14WM+1,X'60'                                          86000013
         XI    ROQ13WM+1,X'60'                                          86100013
         XI    ROQ11WM+1,X'60'                                          86200013
         XI    ROQ7WM+1,X'60'                                           86300013
         XI    ROQ6WM+1,X'60'                                           86400013
         XI    ROQ5WM+1,X'60'                                           86500013
         XI    ROQ3WM+1,X'60'                                           86600013
IERDOSET BC    0,ROQCSSWM          FALL THRU IF EXTRACTING              86700013
*                                  IF NOT EXTRACTING,GO TO CUTBACK CODE 86800013
         LM    RD,RE,IERDOAGE      ADDR + LGH OF EXTRACT INFO           86900013
         LA    RK,PPIPDWA          ADDR OF RCDS IN PPI                  87000013
         L     RG,KROONE           INDEX TO DETERMINE WHEN DONE         87100013
         LR    RI,RG                                                    87200013
         L     RJ,ROQACMO                                               87300013
ROQRLD   L     RC,0(0,RK)          SET FROM ADDR FOR EXTR RTN           87400013
         STM   RE,RK,ROQSVREG      SAVE MERGE REG                       87500013
         BAL   RO,4(0,RM)          EXTRACT THIS RECORD                  87600013
         LM    RE,RK,ROQSVREG      RESTORE MERGE REG                    87700013
         ST    RC,0(0,RD)          STORE ADDR OF RCD AT EXTR POS        87800013
         ST    RD,0(0,RK)          STORE EXTR POS ADDR IN PPIPDWA AREA  87900013
         AR    RD,RE               INCR EXTR POS LENGTH                 88000013
         A     RK,KROFOUR          INCR TO NEXT RCD ADDR IN PPIPDWA     88100013
         BXLE  RG,RI,ROQRLD        ARE WE DONE EXTR THE RCDS IN PPIPDWA 88200013
         ST    RD,ROQSQCWD         SAVE NEXT EXTR POS ADDR              88300013
         B     ROQCSSWM            BRANCH TO CUTBACK SECTION            88400013
         SPACE 2                                                        88500013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          88600013
         SPACE 1                                                        88700013
ROQISD   TM    ROQ12B+1,X'40'      IS ROUTINE SET FOR DESCG             88800013
         B     ROQFDSQ             GO TO MODIFY BRANCHES                88900018
         SPACE 2                                                        89000013
*    EXECUTED MOVE INSTRUCTIONS                                         89100013
         SPACE 1                                                        89200013
ROQUPDT  MVC   ROQMRGAU(1),ROQMRGAU+4  UPDATING NETWORK ADDRESSES       89300013
ROQSANW  MVC   ROQMRGAU(1),PPIPSVA+4   SET NETWORK WITH PRIMED ADDRS    89400013
         EJECT                                                          89500013
         DS    0F                                                       89600013
ROQSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   89700013
ROQMRGAU DS    7F                  ADDR OF FIRST 7 RCDS FOR MRG NTWK    89800013
ROQMRGAM DS    1F                  ADDR OF RECORD 8 OF MRG NTWK         89900013
ROQMRGAL DS    7F                  ADDR OF LAST 7 RCDS FOR MRG NTWK     90000013
ROQSVEXA DS    1F                  SAVE AREA FOR ADDR OF EXTR POS       90100013
ROQSQCWD DS    1F                  WORD TO SAVE ADDRESS OF EXTRACT POS  90200013
*                                  OF RCD FOR SEQUENCE CHECK            90300013
ROQSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       90400013
IERDOAGE DS    1F                  BEGIN ADDR FOR GENERATED EXTRACT POS 90500013
IERDOEXL DS    1F                  LGH OF EXTR CTRL FLDS + 4 ADDR BYTES 90600013
ROQIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   90700013
ROQACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    90800013
*********************************************************************** 90900013
KROSXTN  DC    X'00000010'         MAXIMUM MERGE ORDER                  91000018
KROONE   DC    XL4'1'              CONSTANT OF ONE                      91100018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     91200018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     91260018
ROQTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         91330017
ROQCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      91360017
*********************************************************************** 91400013
         SPACE 2                                                        91500013
ROQSESC8 BC    0,ROQLF8            SET NTWK ENTR SW TO CMP NEW VS ITM 8 91600013
*    THE FOLLOWING 14 INSTR ARE SET DEPENDING ON THE INPUT SEQUENCE     91700013
*       TO BH OR BL                                                     91800013
ROQ12SB  BH    IERROC14            BR TO CMP ITEM 14 AFT ITEM 12 CMP    91900013
ROQST4B  BH    IERROC6             BR TO CMP ITEM 6 AFT ITEM 4 CMP      92000013
ROQS14B  BH    IERROC15            BR TO CMP ITEM 15 AFT ITEM 14 CMP    92100013
ROQS6B   BH    IERROC7             BR TO CMP ITEM 7 AFT ITEM 6 CMP      92200013
ROQS10B  BH    IERROC11            BR TO CMP ITEM 11 AFT ITEM 10 CMP    92300013
ROQS2B   BH    IERROC3             BR TO CMP ITEM 3 AFT ITEM 2 CMP      92400013
ROQFTWM  BH    ROQMOV14            BR TO UPDATE IF GT ITEM 14           92500013
ROQ14WM  BH    IERROC13            BR TO CMP ITEM 13 AFT ITEM 12 CMP    92600013
ROQ13WM  BH    IERROQS4            BR TO CMP ITEM 12 AFT ITEM 10 CMP    92700013
ROQ11WM  BH    ROQMOV10            BR TO UPDATE AFT ITEM 10 CMP         92800013
ROQ7WM   BH    ROQMOV6             BR TO UPDATE IF GT ITEM 7            92900013
ROQ6WM   BH    IERROC5             BR TO CMP ITEM 5 AFT ITEM 4 CMP      93000013
ROQ5WM   BH    IERROQ4S            BR TO CMP ITEM 4 IF GT ITEM 2        93100013
ROQ3WM   BH    ROQMOV2             BR TO UPDATE AFT ITEM 10 CMP         93200013
         SPACE 1                                                        93300013
         SPACE 2                                                        93400013
         SPACE 2                                                        93500013
ROQSPNS1 B     IERROQL4            SET ENTRANCE SW FOR PARTIAL NTWK     93600013
ROQSPNS2 B     IERROQU4            SET ENTRANCE SW FOR PARTIAL NTWK     93700013
ROQE13WM B     IERROQL2            ENTRANCE FOR A 11,12,13 WAY MRG      93800013
ROQE10WM B     IERROQL1            ENTRANCE FOR A 10 WAY MERGE          93900013
ROQE9WM  B     ROQ9WMRG            ENTRANCE FOR A 9 WAY MERGE           94000013
ROQE5WM  B     IERROQU2            ENTRANCE FOR A 3,4,5 WAY MERGE       94100013
ROQE2WM  B     IERROQU1            ENTRANCE FOR A 2 WAY MRG             94200013
ROQE1WM  B     ROQ1WMRG            ENTRANCE FOR A 1 WAY MRG             94300013
*********************************************************************** 94400013
*    MODULE EXTERNAL REFERENCES ADDRESS CONSTANTS                       94500013
         SPACE 1                                                        94600013
         EJECT                                                          94700013
*                                                                       94800013
* MODULE NAME ***IERRMC***                                              94900013
*                                                                       95000013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        95100013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                95200013
         SPACE 1                                                        95300013
DIERRMC  DSECT                                                          95400013
*                                                                       95500013
       COPY  RMCMAIN                                                    95600013
*                                                                       95700013
         SMPPI                                                          95800013
         END                                                            95900013
