         TITLE ' IERAOR - OS/360 SORT /MERGE - 360S-SM-023 02/15/65 '   00200013
*MODULE NAME:*** IERAOR ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: PHASE 2 BALANCED ALGORITHM ASSIGNMENT -     01200013
*   TAPE. THIS MODULE CONTROLS:                                         01400013
*   1.ODD OR EVEN PASS OF PHASE 2 MERGE                                 01600013
*   2.MERGE ORDERS                                                      01800013
*   3.SETTING POINTERS TO INITIAL OUTPUT UNITS IN TAPE TABLE            02000013
*   4.FLIP INPUT-OUTPUT BITS IN TABLE DEPENDING ON ODD OR EVEN PASS     02200013
*   5.INITIALIZE COUNTERS FOR CONTROL OF DROPPING OUT UNITS AS THEY     02400013
*   BECOME FULL DURING A PASS                                           02600013
         SPACE 2                                                        02800013
*USED AS A DSECT IN  N/A                                                03000013
*                                                                       03200013
*                                                                       03400013
*MACROS USED                                                            03600013
         SPACE 1                                                        03800013
*   SMPPI                                                               04000013
         SPACE 2                                                        04200013
*ENTRY POINTS:                                                          04400013
         SPACE 1                                                        04600013
*        ENTRY IERAOR              ENTRY FROM: LOAD MODULE (IERRC9)     04800013
*                                    CALLING SEQUENCE-                  05000013
*                                    L   15,0                           05200013
*                                    BALR 14,15                         05400013
         SPACE 2                                                        05600013
*INPUT: PPI FIELDS REFERENCED-                                          05800013
         SPACE 1                                                        06000013
*   PPIADSSC    PPISEQCT                                                06200013
*   PPITPTBL    PPISW1                                                  06400013
         SPACE 2                                                        06600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             06800013
         SPACE 1                                                        07000013
*   PPIDEPHO                                                            07200013
*   PPIMRGAL                                                            07400013
*   PPIMRGMX                                                            07600013
*   PPIMRGOP                                                            07800013
*   PPITPPT                                                             08000013
         SPACE 2                                                        08200013
*EXTERNAL ROUTINES:                                                     08400013
         SPACE 1                                                        08600013
*        EXTRN IERRMB              ERROR MESSAGE PRINT ROUTINE.         08800013
         SPACE 2                                                        09000013
*EXTERNAL PARAMETERS'                                                   09200013
*                                                                       09400013
*   N/A                                                                 09600013
*                                                                       09800013
*EXITS: NORMAL                                                          10000013
         SPACE 1                                                        10200013
*   IERRC9                                                              10400013
         SPACE 2                                                        10600013
*EXITS: ERROR                                                           10800013
         SPACE 1                                                        11000013
*        NONE                                                           11200013
         SPACE 2                                                        11400013
*TABLES/WORK AREAS:                                                     11600013
         SPACE 1                                                        11800013
*   ALL CONTAINED IN PPI                                                12000013
         SPACE 2                                                        12200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12400013
         SPACE 2                                                        12600013
*NOTES:                                                                 12800013
         SPACE 1                                                        13000013
*   ALL INITIALIZING TAKES PLACE BETWEEN IERAOR,DSECT OF IERROR AND PPI 13200013
         SPACE 2                                                        13400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13600013
         SPACE 1                                                        13800013
RA       EQU   0                   CONTENTS IN- N/A                     14000013
*                                  USE- WORK                            14200013
*                                  CONTENTS OUT- N/A                    14400013
RB       EQU   1                   CONTENTS IN- N/A                     14600013
*                                  USE- WORK                            14800013
*                                  CONTENTS OUT- N/A                    15000013
RC       EQU   2                   CONTENTS IN- N/A                     15200013
*                                  USE- WORK                            15400013
*                                  CONTENTS OUT- N/A                    15600013
RD       EQU   3                   CONTENTS IN- N/A                     15800013
*                                  USE- N/A                             16000013
*                                  CONTENTS OUT- N/A                    16200013
RE       EQU   4                   CONTENTS IN- N/A                     16400013
*                                  USE- WORK                            16600013
*                                  CONTENTS OUT- N/A                    16800013
RF       EQU   5                   CONTENTS IN- N/A                     17000013
*                                  USE- WORK                            17200013
*                                  CONTENTS OUT- N/A                    17400013
RG       EQU   6                   CONTENTS IN- N/A                     17600013
*                                  USE- WORK                            17800013
*                                  CONTENTS OUT- N/A                    18000013
RH       EQU   7                   CONTENTS IN- N/A                     18200013
*                                  USE- N/A                             18400013
*                                  CONTENTS OUT- N/A                    18600013
RI       EQU   8                   CONTENTS IN- N/A                     18800013
*                                  USE- N/A                             19000013
*                                  CONTENTS OUT- N/A                    19200013
RJ       EQU   9                   CONTENTS IN- N/A                     19400013
*                                  USE- N/A                             19600013
*                                  CONTENTS OUT- N/A                    19800013
RK       EQU   10                  CONTENTS IN- N/A                     20000013
*                                  USE- N/A                             20200013
*                                  CONTENTS OUT- N/A                    20400013
RL       EQU   11                  CONTENTS IN- N/A                     20600013
*                                  USE- BASE                            20800013
*                                  CONTENTS OUT- N/A                    21000013
RM       EQU   12                  CONTENTS IN- N/A                     21200013
*                                  USE- N/A                             21400013
*                                  CONTENTS OUT- N/A                    21600013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          21800013
*                                  USE- PPI REFERENCE,REGISTER SAVE     22000013
*                                    AREA                               22200013
*                                  CONTENTS OUT- ADDRESS OF PPI         22400013
RO       EQU   14                  CONTENTS IN- RETURN ADDR             22600013
*                                  USE- SAVE                            22800013
*                                  CONTENTS OUT- RETURN ADDR            23000013
RP       EQU   15                  CONTENTS IN- BASE                    23200013
*                                  USE- WORK                            23400013
*                                  CONTENTS OUT- N/A                    23600013
         SPACE 2                                                        23800013
*START OF MODULE CODE PROPER:                                           24000013
         SPACE 2                                                        24200013
IERAOR   CSECT                                                          24400013
* 800000                                                         A24560 24500019
         USING *,RL                                                     24600013
IERMOT   LR    RL,RP                                                    24800013
         ST    RO,RKSAVC9                                               25000013
         USING DIERROR,RO                                               25200013
         USING IERRCA,RN                                                25400013
         L     RO,PPIALG+4                                              25600013
         SPACE 3                                                        25800013
AORASSMT MVC   KSVMAX(2),PPIMRGMX  SV MAX TO RESET WITH BEFORE EOP EXIT 26000013
*  FIRST PASS.                                                          26200013
         SPACE 1                                                        26400013
         CLI   PPITPPT+3,X'00'                                          26600013
         BNE   AORGOA              NO,BRANCH                            26800013
*  SAVE  MAX MERGE ORDER AND ALT MRG ORD-SET PERPETUAL MRG CTR ******** 27000013
         MVC   PPITPPT(2),PPIMRGMX                                      27200013
         MVC   PPITPPT+2(2),PPIMRGAL                                    27400013
         LA    RG,2                                                     27600013
         STH   RG,PPISEQCT+8                                            27800013
         B     AORGOB                                                   28000013
         SPACE 2                                                        28200013
*  EVEN NUMBERED PHASE 2 PASS.                                          28400013
         SPACE 1                                                        28600013
AORGOA   TM    PPISW1+5,X'20'      SWITCH 1 -BIT 43 ON{                 28800013
         BO    AORGOC              YES,BRANCH                           29000013
         SPACE 1                                                        29200013
*  SET '1' IN LOAD CHARACTER.                                           29400013
         SPACE 1                                                        29600013
AORGOB   MVI   PPIMRGOP+1,X'C0'    SECOND BYTE OF 2 BYTE AREA           29800013
*  SET POINTER FOR RUNNING PROG TO ST.PT. ON RIGHT SIDE OF TABLE ****** 30000013
         LA    RE,PPITPTBL                                              30200013
         ST    RE,KTBLPTCX         SET PTR. AT ST PT OF INPUT SIDE      30400013
         LH    RF,PPITPPT          GET MAX MRG                          30600013
         SLL   RF,1                MULTPY BY 2 (BYTES PER UNIT OF TBL)  30800013
         AR    RE,RF                                                    31000013
         ST    RE,KTBLPTAX                                              31200013
         ST    RE,KTBLPTBX                                              31400013
         ST    RE,KTBL2            SAVE POINTER TO 2ND HALF OF TABLE    31600013
*  SET CTR = ORIG MAX MRG FOR PROPAGATING LOAD CHAR******************** 31800013
AORRT    MVC   PPIDEPHO+3(1),1(RE)                                      32000013
         LH    RE,PPITPPT                                               32200013
         SPACE 1                                                        32400013
*  GET START POINTER OF TABLE.                                          32600013
         SPACE 1                                                        32800013
AORGOF   LA    RF,PPITPTBL                                              33000013
*  PROPAGATE 'LOAD CHAR' TO LEFT SIDE OF TABLE ************************ 33200013
AORLOOPA MVC   0(1,RF),PPIMRGOP+1                                       33400013
         SPACE 1                                                        33600013
*  BUMP TABLE POINTER.                                                  33800013
         SPACE 1                                                        34000013
         LA    RF,2(0,RF)                                               34200013
*  DECREMENT CTR BY 1,DOES IT = ZERO ********************************** 34400013
         BCT   RE,AORLOOPA         NO,LOOP                              34600013
         SPACE 1                                                        34800013
*  SWITCH EOTBL ON.                                                     35000013
         SPACE 1                                                        35200013
SWEOTBL  BC    0,AORGOE            NO,FALL THRU                         35400013
*  SET CTR= ALT MRG ORDER ********************************************* 35600013
         LH    RE,PPITPPT+2                                             35800013
*  REVERSE LOAD CHAR ************************************************** 36000013
         XI    PPIMRGOP+1,X'80'                                         36200013
*  TURN ON SWEOTBL **************************************************** 36400013
         XI    SWEOTBL+1,X'F0'                                          36600013
         L     RF,KTBL2            ADDR. OF 2ND HALF OF TABLE           36800013
         B     AORLOOPA                                                 37000013
         SPACE 2                                                        37200013
*  LOAD CHAR LEFT AT '40' FROM LAST PASS (ODD)                          37400013
*  SET POINTER FOR RUNNING PROG TO ST.PT. ON LEFT SIDE OF TABLE ******* 37600013
AORGOC   LA    RE,PPITPTBL                                              37800013
         ST    RE,KTBLPTAX         ST.PT.(USED FOR RESETTING TRVLG PTR) 38000013
         ST    RE,KTBLPTBX         TRAVELING POINTER                    38200013
         LH    RF,PPITPPT          GET MAX MRG                          38400013
         SLL   RF,1                                                     38600013
         AR    RE,RF                                                    38800013
         ST    RE,KTBLPTCX                                              39000013
         ST    RE,KTBL2            SAVE POINTER TO 2ND HALF OF TABLE    39200013
         LA    RE,PPITPTBL                                              39400013
         B     AORRT                                                    39600013
         SPACE 2                                                        39800013
*  REVERSE ODD-EVEN PASS SWITCH (BIT 43 IN SW1)************************ 40000013
AORGOE   XI    PPISW1+5,X'20'                                           40200013
*  SET UP CTR OF ORIGINAL MAX MRG TO DET. EOP,WHEN LOAD PT. REACHED *** 40400013
         MVC   KMRGCTRX(2),PPIMRGMX                                     40600013
*  SET TABLE-LIMIT CTR IN RUNNING PROG= CHGING ALT MRG ORD ************ 40800013
         LH    RE,PPIMRGAL                                              41000013
         STH   RE,KLIMITX                                               41200013
*  SET COUNTER TO KNOW WHEN ALL UNITS REACH EOV,E.G. NMAX EXCEEDED ***  41400013
         MVC   KEOVCTX+2(2),PPIMRGAL                                    41600013
*  MOVE NO. STRINGS 'OUT' TO'IN' SLOT AND ZERO 'OUT'SLOT FOR NXT PASS * 41800013
         MVC   PPISEQCT(4),PPISEQCT+4                                   42000013
         SR    RE,RE                                                    42200013
         ST    RE,PPISEQCT+4                                            42400013
         L     RO,RKSAVC9                                               42600013
         BR    RO                                                       42800013
         SPACE 1                                                        43000013
         DS    0F                                                       43200013
RKSAVC9  DS    F                                                        43400013
KTBL2    DC    A(0)                POINTER TO 2ND HALF OF TAPE TABLE    43600013
         EJECT                                                          43800013
*********************************************************************** 44000013
*                                                                     * 44200013
*    THIS IS A DUMMY RUNNING MODULE - FOR PURPOSES OF LINK ONLY       * 44400013
*                                                                     * 44600013
*                                                                     * 44800013
*********************************************************************** 45000013
DIERROR  DSECT                                                          45200013
IERDOT   B     RORSKIP                                                  45400013
         B     RORNLST                                                  45600013
         B     RORLST                                                   45800013
         B     RORLDPT                                                  46000013
*  END OF SEQUENCE - ENTRY VIA WRITE ROUTINE ************************** 46200013
*  BUMP NO. SEQ OUT BY 1 ********************************************** 46400013
ROREOSQ  L     RE,PPISEQCT+4                                            46600013
         LA    RE,1(0,RE)                                               46800013
         ST    RE,PPISEQCT+4                                            47000013
*  IS POINTER AT LIMIT OF TABLE { ************************************* 47200013
RORNORM  LH    RE,KLIMITX                                               47400013
         BCT   RE,RORGOB                                                47600013
*  SET POINTER TO ST. PT. ********************************************* 47800013
         MVC   KTBLPTBX(4),KTBLPTAX                                     48000013
*  RESET TABLE LIMIT CTR = CHGING ALT MRG ORDER *********************** 48200013
         LH    RE,PPIMRGAL                                              48400013
         STH   RE,KLIMITX                                               48600013
*  IS OPEN BYTE OFF IN THIS NEW UNIT{ ********************************* 48800013
RORGOC   L     RE,KTBLPTBX                                              49000013
         TM    0(RE),X'40'                                              49200013
         BZ    RORNORM             YES,BYTE OFF,SKIP UNIT               49400013
*  PUT'X'IN PPIDEPHO ************************************************** 49600013
         MVC   PPIDEPHO+3(1),1(RE)                                      49800013
*  IS'S'SWITCH ON{ **************************************************** 50000013
RORSSW   BC    0,RORSWOFF          IF YES,BRANCH                        50200013
*  EXIT TO READ PRIME ROUTINE ***************************************** 50400013
RORSKIP  L     RL,PPIRD+4                                               50600013
         B     4(0,RL)                                                  50800013
         SPACE 2                                                        51000013
*  RESTORE DECREMENTED COUNTER **************************************** 51200013
RORGOB   STH   RE,KLIMITX                                               51400013
*  INCREMENT TAPE POINTER ********************************************* 51600013
         L     RF,KTBLPTBX         GET TRVLG PTR.                       51800013
         LA    RF,2(0,RF)          BUMP BY 2                            52000013
         ST    RF,KTBLPTBX                                              52200013
         B     RORGOC                                                   52400013
         SPACE 2                                                        52600013
* THIS ROUTINE HAS THE RESPONSIBILITY OF DETERMINING IF PHASE 3 SHOULD  52800013
* BE CALLED. IF NOT,IT DETERMINES WHETHER WE ARE ABOUT TO ENTER EITHER  53000013
* THE LAST PASS OR THE NEXT TO LAST PASS OF PHASE 2 AND SETS SWITCHES   53200013
* IN PPI TO INDICATE IF FORWARD BLOCKING, REWINDING AND FORWARD READING 53400013
* IS REQUIRED TO ELIMINATE A PHASE 3 COPY PASS. THE TEST USED HERE CAN  53600013
* FAIL IF ANY REEL(S) CONTAINS A SINGLE SEQUENCE WHICH COMPLETELY FILLS 53800013
* THE REEL. IN THIS CASE, NEEDLESS REWINDING COULD OCCUR,BUT THE FINAL  54000013
* RESULT WILL BE CORRECT ANYWAY. THIS UNUSUAL CONDITION IS CONSIDERED   54200013
* UNLIKELY, SINCE SUCH FILES NORMALLY WILL BE HANDLED BY OSCILLATING,   54400013
* NOT BALANCED TAPE SORTS.                                              54600013
         SPACE 2                                                        54800013
* IS.THE NUMBER OF STRINGS OUT GREATER OR EQUAL TO NO. OF STRINGS IN    55000013
         SPACE 1                                                        55200013
RORGOA   CLC   PPISEQCT+4(4),PPISEQCT                                   55400013
         BNL   RORGOE              BRANCH TO UNENDING MERGE TEST        55600013
* SINCE COUNT OF SEQUENCES WAS REDUCED,RESET ERROR COUNTER FOR 2 RETRY. 55800013
         LA    RE,2                                                     56000013
         STH   RE,PPISEQCT+8                                            56200013
RORGOF   NI    PPISW1+6,X'8F'      TURN OFF BLK FRWD,READ FRWD & REWIND 56400013
         MVC   PPIMRGMX(2),KSVMAX  RESET M                              56600013
         TM    PPISW1+6,X'08'      IS READ FRWD LATER SW ON OR OFF      56800013
         BZ    RORX1               SKIP OVER SWITCH SETTING IF OFF      57000013
         XI    PPISW1+6,X'68'      TURN ON RD FRWD,REWIND,OFF RD LATER  57200013
         XI    PPISW1+3,X'10'      INVERT SEQ BIT (TO BYPASS INVERT)    57400013
         SPACE 1                                                        57600013
* IS S/M READY TO ENTER FINAL MERGE (IS SEQCT .LE. MRGAL).              57800013
         SPACE 1                                                        58000013
RORX1    LH    RE,PPIMRGAL         IS ALTERNAT5 MERGE .GE. TO           58200013
         CL    RE,PPISEQCT+4         STRINGS OUT.                       58400013
         BNL   RORPH3              BRANCH TO ENTER PHASE 3 IF TRUE.     58600013
         SPACE 2                                                        58800013
         MH    RE,KSVMAX           FORM MRGAL*KSVMAX(MAX SIZE OF ANY    59000013
         CL    RE,PPISEQCT+4         CASE WHERE S/M IS ABOUT TO ENTER   59200013
         BNL   RORLPASS              THE LAST PASS OF PHASE 2.)         59400013
         SPACE 2                                                        59600013
         MH    RE,PPIMRGAL         FORM MRGAL*KSVMAX*MRGAL (MAX SIZE    59800013
         CL    RE,PPISEQCT+4         CASE WHERE S/M IS ABOUT TO ENTER   60000013
         BNL   RORNXT2L            THE NEXT TO LAST PASS OF PHASE 2     60200013
         SPACE 2                                                        60400013
RORPH2NM NOP   RORPH2NM            THIS WAS CHANGED TO CORRECT COPY     60600013
*                                    PASS TROUBLE                       60800013
         B     RORGOG              GO EXIT TO SSC                       61000013
         SPACE 2                                                        61200013
RORNXT2L TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      61400013
         BC    14,RORCHK2            ASCENDING SEQUENCE GO TO CHK2      61600013
RORCHK1  TM    PPISW1+3,X'30'      IF USER SEQ IS OPPOSITE TO PRES SEQ  61800013
         BC    11,RORPH2NM         DO NOT PERFORM SPECIAL ROUTINES      62000013
RORSET   OI    PPISW1+6,X'18'      TURN ON READ FORW LATER & BLOCK      62200013
         B     RORGOG                FORWARD AND SET UP FOR PHASE 2     62400013
RORCHK2  TM    PPISW1+3,X'30'      IF USER SEQ IS SAME AS PRESENT SEQ   62600013
         BM    RORPH2NM            DO NOT PERFORM SPECIAL ROUTINES      62800013
         B     RORSET                                                   63000013
         SPACE 1                                                        63200013
RORLPASS TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      63400013
         BC    14,RORCHK1            ASCENDING SEQUENCE GO TO CHK1,     63600013
         B     RORCHK2               ELSE GO TO CHK2.                   63800013
         SPACE 2                                                        64000013
*  CALL PHASE 2 --- EXIT TO CLOSE RTN ********************************* 64200013
RORCLOSE L     RP,PPIADSSC                                              64400013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       64600013
         LA    RB,0                RETURN TO SSC REQUESTING PHASE 2.    64800013
         BAL   RO,20(0,RP)                                              65000013
         SPACE 2                                                        65200013
*  SET MRG ORD.(REVERSE MAX AND ALT FOR ANOTHER PHASE 2)*************** 65400013
RORGOG   LH    RE,PPIMRGMX                                              65600013
         MVC   PPIMRGMX(2),PPIMRGAL                                     65800013
         STH   RE,PPIMRGAL                                              66000013
         B     RORCLOSE                                                 66200013
         SPACE 2                                                        66400013
*  CALL PHASE 3 ******************************************************* 66600013
RORPH3   MVC   PPIMRGMX(2),PPISEQCT+6   SET CORRECT MERGE ORDER.        66800013
         TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      67000013
         BC    14,RORA               ASCENDING SEQUENCE GO TO RORA      67200013
         TM    PPISW1+3,X'30'      IS USER SEQ = INPUT SEQ              67400013
         BM    RORCLOSE              IF NOT GO TO PHASE TWO             67600013
RORB     L     RF,KTBLPTCX                                              67800013
         XI    0(RF),X'80'         TURN ON BIT FOR PH 3 TO INDIC INP-   68000013
*                                 UUT SIDE OF TABLE                     68200013
         L     RP,PPIADSSC                                              68400013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       68600013
         LA    RB,4                RETURN TO SSC REQUESTING PHASE 3.    68800013
         BAL   RO,20(0,RP)                                              69000013
RORA     TM    PPISW1+3,X'30'      IS USER SEQ = INPUT SEQ              69200013
         BM    RORB                  IF NOT GO TO PHASE THREE           69400013
         B     RORCLOSE              ELSE GOT TO PHASE TWO              69600013
         SPACE 2                                                        69800013
*  DECREMENT ERROR CTR BY 1--- IS COUNT= ZERO{ ************************ 70000013
RORGOE   LH    RE,PPISEQCT+8                                            70200013
         BCT   RE,RORGOJ           NO,BRANCH + RESTORE CTR FR REG.      70400013
*  EXIT TO SSC--- UNENDING MERGE ************************************** 70600013
         USING DIERRMB,RC                                               70800013
         L     RC,PPIRMB+4                                              71000013
         LM    RA,RB,MSGP2A05                                           71200013
         L     RP,PPIADSSC                                              71400013
         BAL   RO,12(0,RP)                                              71600013
         L     RP,PPIADSSC                                              71800013
         BAL   RO,16(0,RP)         RETURN TO SSC REQUESTING AN ABORT.   72000013
         SPACE 2                                                        72200013
*  RESTORE ERROR CTR FROM REG.***************************************** 72400013
RORGOJ   STH   RE,PPISEQCT+8                                            72600013
         B     RORGOF                                                   72800013
*                                                                       73000013
*********************************************************************** 73200013
*  ENTRY FROM READ RTN---REACHED LOAD POINT *************************** 73400013
* FIND UNIT AT LOAD PT AND TURN OFF INPUT BIT  VIA INCRMT IN REG D      73600013
RORLDPT  LH    RE,KSVMAX                                                73800013
         L     RF,KTBLPTCX                                              74000013
         STC   RD,KINCRMT                                               74200013
RORSCAN  CLC   KINCRMT(1),1(RF)                                         74400013
         BE    RORDROP                                                  74600013
         LA    RF,2(0,RF)          BUMP TO NEXT UNIT                    74800013
         BCT   RE,RORSCAN          IF NOT AT END OF TBL, LOOK AT NXT UT 75000013
* IF FALL THRU,INCRMT NOT IN TBL = ERROR                                75200013
RORDROP  XI    0(RF),X'80'         TURN OFF INPUT BYTE                  75400013
         SPACE 1                                                        75600013
* CUTBACK MERGE ORDER,IF ZERO,DECIDE ABOUT ENTRY INTO COPY PASS ELIM.   75800013
* ROUTINES,NORMAL PHASE TWO ROUTINES OR INTO PHASE 3.                   76000013
         SPACE 1                                                        76200013
         LH    RE,PPIMRGMX                                              76400013
         BCT   RE,RORREAD          SOME UNIT(S) POSSIBLY NOT AT LD PT   76600013
         B     RORGOA              ALL UNITS AT LOAD POINT,HENCE EOP    76800013
         SPACE 1                                                        77000013
* EXIT BACK TO READ-PRIME TO SEE IF MORE INPUTS AT EOF(LOAD POINT).     77200013
         SPACE 1                                                        77400013
RORREAD  L     RL,PPIRD+4                                               77600013
         STH   RE,PPIMRGMX                                              77800013
         BR    RO                                                       78000013
         SPACE 2                                                        78200013
*********************************************************************** 78400013
*  ENTRY FROM WRITE RTN---EOV DETECT, MIDDLE OF A STRING ************** 78600013
*  SET'S'SWITCH ON **************************************************** 78800013
RORNLST  XI    RORSSW+1,X'F0'                                           79000013
         B     RORGOM                                                   79200013
         SPACE 2                                                        79400013
*  ENTRY FROM WRITE RTN---EOV DETECT, END OF STRING,NOT END OF PASS *** 79600013
*  SET 'S' SWITCH OFF  ************************************************ 79800013
RORLST   NI    RORSSW+1,X'F0'                                    A24560 80000019
*  INCREMENT NO. OF STRINGS OUT BY 1 ********************************** 80200013
RORGOM   L     RE,PPISEQCT+4                                            80400013
         LA    RE,1(0,RE)                                               80600013
         ST    RE,PPISEQCT+4                                            80800013
*  DECREMENT EOV CTR---IS CTR=ZERO{(NMAX EXCEEDED) ******************** 81000013
         L     RF,KEOVCTX                                               81200013
         BCT   RF,RORUPDT          NO,BRANCH TO UPDATE                  81400013
*  EXIT TO SSC NMAX EXCEEDED ****************************************** 81600013
         L     RC,PPIRMB+4                                              81800013
         LM    RA,RB,MSGP2A01                                           82000013
         L     RP,PPIADSSC                                              82200013
         BAL   RO,12(0,RP)                                              82400013
*APROX RCD CNT IS PPICOUNT - B, WHERE B IS A MAX. VALUE.  SO            82600013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO B.                             82800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   83000013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      83200013
         SPACE 1                                                        83400013
         L     RB,PPICOUNT         NO. RCD. BLOCKED                     83600013
         LH    RP,PPISRTBL         B - F = NO. RCDS/BLOCK               83800013
         TM    PPISW1,X'80'            V = BYTES/BLOCK                  84000013
         BO    RORGOM1                                                  84200013
         SPACE 1                                                        84400013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      84600013
         SR    RO,RO                                                    84800013
         DR    RO,RA                 RCDS. IN BLOCK                     85000013
RORGOM1  CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         85200013
         BH    RORGOM2               NEGATIVE                           85400013
         SPACE 1                                                        85600013
         LR    RB,RP               SET CNT TO B                         85800013
         B     RORGOM3                                                  86000013
         SPACE 2                                                        86200013
RORGOM2  SR    RB,RP               APROX RCD CNT = PPICOUNT - B         86400013
RORGOM3  CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           86600013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       86800013
         OI    PPIWKARE+15,X'F0'                                        87000013
         SPACE 2                                                        87200013
         L     RC,PPIRMB+4                                              87400013
         LM    RA,RB,MSGP2A06                                           87600013
         MVC   MSGP2R06+24(7),PPIWKARE+9                                87800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        88000013
         BAL   RO,12(0,RP)                                              88200013
         SPACE 1                                                        88400013
         L     RP,PPIADSSC                                              88600013
         B     16(0,RP)            RETURN TO SSC AFTER NMAX EXCEEDED    88800013
         SPACE 2                                                        89000013
* UPDATE TAPE TABLE---SET OPEN BYTE OFF ON FULL UNIT ****************** 89200013
RORUPDT  ST    RF,KEOVCTX                                               89400013
         L     RF,KTBLPTBX                                              89600013
         XI    0(RF),X'40'                                              89800013
         B     RORNORM                                                  90000013
         SPACE 2                                                        90200013
*  TURN OFF SSWITCH *************************************************** 90400013
RORSWOFF XI    RORSSW+1,X'F0'                                           90600013
*  EXIT TO WRITE RTN ---MORE WRITES PENDING *************************** 90800013
         L     RL,PPIWRT+4                                              91000013
         B     0(0,RL)                                                  91200013
         SPACE 2                                                        91400013
         DS    0F                                                       91600013
KMRGCTRX DC    X'0000'             COUNTER=MAX MRG TO DET. EOP(LOAD PT) 91800013
         DS    0F                                                       92000013
KTBLPTAX DC    X'00000000'         START POINT (TO RESET TRVLG PTR)     92200013
KLIMITX  DC    X'0000'             COUNTER TO DETERMINE LIMIT OF TABLE  92400013
         DS    0F                                                       92600013
KTBLPTBX DC    X'00000000'         TRAVELING PTR.                       92800013
KTBLPTCX DC    X'00000000'         POINTER TO INPUT SIDE OF TABLE       93000013
KEOVCTX  DC    X'00000000'         SORT CAP.EXCEEDED CTR.               93200013
*                                     ARE FILLED AND MORE INPUT TO GO   93400013
KINCRMT  DC    X'0000'             HOLD AREA FOR DCB INCRMT PASSED      93600013
KSVMAX   DC    X'0000'             HOLD AREA FOR RESETTING A CUT BK MRG 93800013
         EJECT                                                          94000013
DIERRMB  DSECT                                                          94200013
*                                                                       94400013
* MODULE NAME ***IERRMB***                                              94600013
*                                                                       94800013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        95000013
* PHASE 2 RUNNING PROGRAM.                                              95200013
         SPACE 1                                                        95400013
         COPY  RMBMAIN                                                  95600013
*                                                                       95800013
         SMPPI                                                          96000013
         END                                                            96200013
