         TITLE ' IERAOT - OS/360 SORT/MERGE - 360S-SM-023 02/10/65 '    00100013
*MODULE NAME:*** IERAOT ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 ALGORITHM ASSIGNMENT FOR DISK       00600013
*   THIS MODULE INITIALIZES AN INTERNAL CONTROL TABLE CONSISTING OF:    00700013
*   1.DISK ADDR TO START WRITING STRINGS FOR EACH AREA(OUTPUT)          00800013
*   2.DISK ADDR TO START READING STRINGS FOR EACH AREA(INPUT)           00900013
*   3.DISK ADDR TO START WRITING DIRECTORY FOR EACH AREA(OUTPUT)        01000013
*   4.DISK ADDR TO START READING DIRECTORY FOR EACH AREA %INPUT<        01100013
*   5.NO. STRINGS IN                                                    01200013
*   6.NO. STRINGS OUT                                                   01300013
         SPACE 2                                                        01400013
*USED AS A DSECT IN'  N/A                                               01500013
*                                                                       01600013
*MACROS USED  -                                                         01700013
         SPACE 1                                                        01800013
*   SMPPI                                                               01900013
         SPACE 2                                                        02000013
*ENTRY POINTS:                                                          02100013
         SPACE 1                                                        02200013
*        ENTRY IERAOT              ENTRY FROM: LOAD MODULE(IERRC9)      02300013
*                                    CALLING SEQUENCE-                  02400013
*                                    L 15,0                             02500013
*                                    BALR 14,15                         02600013
         SPACE 2                                                        02700013
*INPUT: PPI FIELDS REFERENCED-                                          02800013
         SPACE 1                                                        02900013
*   PPIENDAR    PPISW1                                                  03000013
*   PPILAB01    PPIWKARE                                                03100013
*   PPINDSKA                                                            03200013
*   PPISEQCT                                                            03300013
*   PPISTAR                                                             03400013
         SPACE 2                                                        03500013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03600013
         SPACE 1                                                        03700013
*   PPIDEPHO                                                            03800013
*   PPIDIRAD                                                            03900013
*   PPIMRGAL                                                            04000013
*   PPIMRGMX                                                            04100013
*   PPIMRGOP                                                            04200013
         SPACE 2                                                        04300013
*EXTERNAL ROUTINES:                                                     04400013
         SPACE 1                                                        04500013
*        EXTRN IERRMB                                                   04600013
         SPACE 2                                                        04700013
*EXTERNAL PARAMETERS'  N/A                                              04800013
*                                                                       04900013
*                                                                       05000013
*EXITS: NORMAL                                                          05100013
         SPACE 1                                                        05200013
*   IERRC9                                                              05300013
         SPACE 2                                                        05400013
*EXITS: ERROR                                                           05500013
         SPACE 1                                                        05600013
*   NONE                                                                05700013
         SPACE 2                                                        05800013
*TABLES/WORK AREAS:                                                     05900013
         SPACE 1                                                        06000013
*   PPI                                                                 06100013
*   INTERNAL CONTROL TABLE(IN IERROT) TO DETERMINE WHERE TO READ AND    06200013
*   WRITE:                                                              06300013
*   STRINGS                                                             06400013
*   DIRECTORY                                                           06500013
         SPACE 2                                                        06600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  06700013
         SPACE 2                                                        06800013
*NOTES:                                                                 06900013
         SPACE 1                                                        07000013
*   ALL INITIALIZING TAKES PLACE BETWEEN IERAOT,DSECT OF IERROT AND PPI 07100013
         SPACE 2                                                        07200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07300013
         SPACE 1                                                        07400013
RA       EQU   0                   CONTENTS IN- N/A                     07500013
*                                                                       07600013
*                                  USE- N/A                             07700013
*                                                                       07800013
*                                  CONTENTS OUT- N/A                    07900013
*                                                                       08000013
RB       EQU   1                   CONTENTS IN- N/A                     08100013
*                                                                       08200013
*                                  USE- WORK                            08300013
*                                                                       08400013
*                                  CONTENTS OUT- N/A                    08500013
*                                                                       08600013
RC       EQU   2                   CONTENTS IN- N/A                     08700013
*                                                                       08800013
*                                  USE- N/A                             08900013
*                                                                       09000013
*                                  CONTENTS OUT- N/A                    09100013
*                                                                       09200013
RD       EQU   3                   CONTENTS IN- N/A                     09300013
*                                                                       09400013
*                                  USE- N/A                             09500013
*                                                                       09600013
*                                  CONTENTS OUT- N/A                    09700013
*                                                                       09800013
RE       EQU   4                   CONTENTS IN- N/A                     09900013
*                                                                       10000013
*                                  USE- WORK                            10100013
*                                                                       10200013
*                                  CONTENTS OUT- N/A                    10300013
*                                                                       10400013
RF       EQU   5                   CONTENTS IN- N/A                     10500013
*                                                                       10600013
*                                  USE- WORK                            10700013
*                                                                       10800013
*                                  CONTENTS OUT- N/A                    10900013
*                                                                       11000013
RG       EQU   6                   CONTENTS IN- N/A                     11100013
*                                                                       11200013
*                                  USE- WORK                            11300013
*                                                                       11400013
*                                  CONTENTS OUT- N/A                    11500013
*                                                                       11600013
RH       EQU   7                   CONTENTS IN- N/A                     11700013
*                                                                       11800013
*                                  USE- WORK                            11900013
*                                                                       12000013
*                                  CONTENTS OUT- N/A                    12100013
*                                                                       12200013
RI       EQU   8                   CONTENTS IN- N/A                     12300013
*                                                                       12400013
*                                  USE- WORK                            12500013
*                                                                       12600013
*                                  CONTENTS OUT- N/A                    12700013
*                                                                       12800013
RJ       EQU   9                   CONTENTS IN- N/A                     12900013
*                                                                       13000013
*                                  USE- WORK                            13100013
*                                                                       13200013
*                                  CONTENTS OUT- N/A                    13300013
*                                                                       13400013
RK       EQU   10                  CONTENTS IN- N/A                     13500013
*                                                                       13600013
*                                  USE- WORK                            13700013
*                                                                       13800013
*                                  CONTENTS OUT- N/A                    13900013
*                                                                       14000013
RL       EQU   11                  CONTENTS IN- N/A                     14100013
*                                                                       14200013
*                                  USE- BASE                            14300013
*                                                                       14400013
*                                  CONTENTS OUT- N/A                    14500013
*                                                                       14600013
RM       EQU   12                  CONTENTS IN- N/A                     14700013
*                                                                       14800013
*                                  USE- N/A                             14900013
*                                                                       15000013
*                                  CONTENTS OUT- N/A                    15100013
*                                                                       15200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          15300013
*                                  USE- PPI REFERENCE,REGISTER SAVE     15400013
*                                    AREA                               15500013
*                                  CONTENTS OUT- ADDRESS OF PPI         15600013
RO       EQU   14                  CONTENTS IN- RETURN ADDR             15700013
*                                                                       15800013
*                                  USE- SAVE,WORK                       15900013
*                                                                       16000013
*                                  CONTENTS OUT- RETURN ADDR            16100013
*                                                                       16200013
RP       EQU   15                  CONTENTS IN- BASE                    16300013
*                                                                       16400013
*                                  USE- WORK                            16500013
*                                                                       16600013
*                                  CONTENTS OUT- N/A                    16700013
*                                                                       16800013
         SPACE 2                                                        16900013
*START OF MODULE CODE PROPER:                                           17000013
         SPACE 2                                                        17100013
IERAOT   CSECT                                                          17200013
         USING *,RL                                                     17300013
         USING IERRCA,RN                                                17400013
         LR    RL,RP               PRIME AOT BASE REGESTER.             17500013
         ST    RO,RKSAVC9                                               17600013
         L     RO,PPIALG+4                                              17700013
         USING DIERROT,RO                                               17800013
         SPACE 2                                                        17800717
*   CHECK IF CHECKPOINT HAS BEEN INDICATED. IF IT HAS,OVERLAY           17801417
*     THE NECESSARY INSTRUCTIONS IN ROT SO THAT WE WILL LINK            17802117
*     TO THE CHECKPOINT MODULE.                                         17802817
         SPACE 2                                                        17803517
         TM    PPISW1+2,X'01'      HAS CHECKPOINT BEEN IND.             17804217
         BNO   AOT500              NO                                   17804917
         SPACE 1                                                        17805617
         MVI   ROT300+1,X'00'      MODIFY BRANCH IN ROT                 17806317
         SPACE 2                                                        17807017
*   CHECK FOR A 2314 USING THE BALANCED TECH. IF IT IS OVERLAY          17814017
*     THE NECESSARY INSTRUCTIONS FOR THE INCREASED NUMBER OF            17821017
*     TRACKS AND NUMBER OF DIRECTORY BLOCK PER TRACK.                   17828017
         SPACE 2                                                        17835017
AOT500   EQU   *                                                        17838017
         TM    PPISW1+7,X'02'      2314 USING BALN                      17842017
         BNO   AOT100              NO                                   17849017
         SPACE 1                                                        17856017
         MVI   ROT100+1,X'2C'                                           17863017
         MVI   ROTINCTK+7,X'13'                                         17870017
         MVI   ROT200+1,X'2C'                                           17877017
         MVI   ROTBMPTK+3,X'13'                                         17884017
         SPACE 3                                                        17900013
*  PUT START ADDRS IN TABLE- WHERE TO RECORD NXT STRING                 18000013
         SPACE 2                                                        18030017
AOT100   EQU   *                                                        18060017
         LA    RE,WTABLE                                                18100013
         LH    RF,PPINDSKA                                              18200013
         LA    RG,PPISTAR                                               18300013
AOTLOOPA MVC   4(8,RE),0(RG)                                            18400013
         LA    RE,36(0,RE)        BUMP PTR TO NXT AREA                  18500013
         LA    RG,8(0,RG)         BUMP PTR TO NXT AREA                  18600013
         BCT   RF,AOTLOOPA         GO TO LOOPA                          18700018
*  PUT ENDING ADDRS IN TABLE - (1) WHERE TO WRITE DICTY                 18800013
*                              (2) WHERE TO READ DICTY FROM PH 1        18900013
         LA    RE,WTABLE                                                19000013
         LH    RF,PPINDSKA                                              19100013
         LA    RG,PPIENDAR                                              19200013
AOTLOOPB MVC   12(8,RE),0(RG)     PUT IN 'WRITE' DICTY SLOT             19300013
         MVC   20(8,RE),0(RG)     PUT IN 'READ' DICTY SLOT              19400013
         LA    RE,36(0,RE)        BUMP TO NXT AREA IN TBL               19500013
         LA    RG,8(0,RG)         BUMP TO NXT AREA IN PPIENDAR          19600013
         BCT   RF,AOTLOOPB         GO TO LOOPB                          19700018
*  INITIALIZE POS-IN-BLK TO ADDR OF PPILAB01, WHERE READ PUTS BLK/DICTY 19800013
         LA    RE,WTABLE                                                19900013
         LH    RF,PPINDSKA                                              20000013
         LA    RG,PPILAB01                                              20100013
AOTLOOPC ST    RG,28(0,RE)        PUT ADDR/LAB01 IN BLK-POS,ALL AREAS   20200013
         LA    RE,36(0,RE)        BUMP TO NXT AREA IN TABLE             20300013
         BCT   RF,AOTLOOPC         GO TO LOOPC                          20400018
*  INITIALIZE NEW SEQ. CTS. IN TABLE TO ZERO IN ALL AREAS               20500013
         LA    RE,0                                                     20600013
         LH    RK,PPINDSKA         GET NO.DSK AREAS                     20700013
         LA    RJ,WTABLE                                                20800013
         LA    RJ,32(0,RJ)         GET SLOT IN TBL.                     20900013
AOTLOOPD STH   RE,0(0,RJ)         FILL SLOT                             21000013
         LA    RJ,36(0,RJ)         BUMP ADDR TO NXT SLOT                21100013
         BCT   RK,AOTLOOPD         GO TO LOOPD                          21200018
*  STORE SEQ.COUNTERS IN TABLE (OLD SEQS.) **************************** 21300013
         LH    RK,PPINDSKA         GET NO. AREAS                        21400013
         LA    RE,PPISEQCT         GET ADDR OF COUNTERS                 21500013
         LA    RJ,WTABLE                                                21600013
         LA    RJ,34(0,RJ)         GET SLOT IN TABLE                    21700013
AOTLOOPE MVC   0(2,RJ),0(RE)       FILL 1 SLOT                          21800013
         LA    RJ,36(0,RJ)         BUMP TO NXT SLOT                     21900013
         LA    RE,2(0,RE)                                               22000013
         BCT   RK,AOTLOOPE         TABLE FULL, NO -LOOP                 22100013
         LH    RE,PPINDSKA                                              22200013
         ST    RE,WNODSKA          STORE NO. DSK AREAS IN RUN. PROG.    22300013
*  SW1(BIT 29)ON,OR OFF{*********************************************** 22400013
         TM    PPISW1+3,X'08'                                           22500013
         BO    AOTDECND            SW 1 ON, FLIP TABLE,GO DECENDING     22600013
         B     AOTOUT             GO SET MRG ORDER, DON'T FLIP TABLE    22700013
         SPACE 2                                                        22800013
*  REVERSE DATA IN TABLE FOR DECENDING PROCESS ************************ 22900013
AOTDECND LA    RJ,WTABLE           GET TABLE ADDR                       23000013
         LH    RF,PPINDSKA         GET NO./AREAS                        23100013
         LA    RH,1                CONSTANT 1                           23200013
         SR    RF,RH               REDUCE NO./AREAS BY 1                23300013
         LA    RG,36               GENERATE MULTIPLIER CONSTANT         23400013
         MR    RE,RG               MULTIPICAND IN RF,PROD= RF (DISPLCMT 23500013
*                                    TO NTH ADDR IN TABLE               23600013
         LA    RK,0(RF,RJ)         GET ADDR OF NTH POS.IN TABLE         23700013
AOTLOOPF MVC   PPIWKARE(36),0(RK)  MOVE DATA FROM NTH POS. TO WORK AREA 23800013
         MVC   0(36,RK),0(RJ)      MOVE DATA FROM 1ST POS. TO NTH POS.  23900013
         MVC   0(36,RJ),PPIWKARE   MOVE DATA FROM WORK AREA TO 1ST POS. 24000013
         LA    RJ,36(0,RJ)         INCRMT 1ST POS.REG TO NXT AREA ADDR. 24100013
         LA    RH,36               CONSTANT DECREMENT                   24200013
         SR    RK,RH               DECRMT NTH POS.REG TO PREVIOUS POS.  24300013
         CLR   RJ,RK               COMP. 1ST REG TO NTH REG.            24400013
         BL    AOTLOOPF            REVERSAL NOT COMPLETE,LOOP           24500013
*                                  TABLE COMPLETELY REVERSED            24600013
AOTOUT   LA    RJ,WTABLE          GET TABLE ADDR.                       24700013
         LH    RF,PPINDSKA        GET NO. AREAS                         24800013
         LA    RH,2                                                     24900013
         SR    RF,RH              REDUCE NO./AREAS BY 2 (TO BEG. N-1)   25000013
         LA    RG,36              MULTIPLIER CONSTANT                   25100013
         MR    RE,RG              DISPLACEMENT TO N-1 POS --- PROD=RF   25200013
         AR    RJ,RF              GET ADDR/N-1 POS.                     25300013
         MVC   PPIMRGMX(2),34(RJ)  SET MRG MAX=SEQCT IN POS. N-1.       25400013
         L     RO,RKSAVC9                                               25500013
         BR    RO                  RETURN                               25600018
         SPACE 1                                                        25700013
         DS    0F                                                       25800013
RKSAVC9  DS    1F                  RETURN ADDR                          25900018
         EJECT                                                          26000013
*  THIS IS A DUMMY RUNNING MODULE ************************************* 26100013
*                                                                       26200013
*                                                                       26300013
*                                                                       26400013
*********************************************************************** 26500013
DIERROT  DSECT                                                          26600013
IERDOT   B     ROTSTART            ENTRY FROM ASSMT ROUTINE             26700013
         DC    A(0)                NO ENTRY POINT                       26800013
         DC    A(0)                NO ENTRY POINT                       26900013
         DC    A(0)                NO ENTRY POINT                       27000013
         B     ROTEOS              ENTRY FROM WRITE ROUTINE             27100013
*                                                                       27200013
*  SET REG. I TO NTH POS. OF TABLE ************************************ 27300013
ROTSTART LA    RI,WTABLE           GET BEG.ADDR/TABLE                   27400013
         L     RF,WNODSKA                                               27500013
         LA    RH,1                CONSTANT 1                           27600013
         SR    RF,RH               REDUCE NO./AREAS BY 1                27700013
         ST    RF,WNODSKA          SET UP COUNTER TO DETERMINE END/PASS 27800013
         LA    RG,36               GENERATE MULTIPLIER CONST.           27900013
         MR    RE,RG               DISPLCMT TO NTH POS./TABLE           28000013
         LA    RH,0(RF,RI)         GET ADDR OF NTH POS. IN TABLE        28100013
         LR    RI,RH               HENCEFORTH RI= ADDR/NTH POS.         28200013
         SR    RH,RG               HENCEFORTH RH= ADDR/N-1 POS.         28300013
*  SEQ. CT. AT N-1 = 0                                                  28400013
         LH    RE,34(0,RH)        GET SEQ CT IN                         28500013
         LTR   RE,RE                                                    28600013
         BC    7,ROTGOA            BRANCH IF NOT EQUAL.                 28700013
         SPACE 1                                                        28800013
         L     RE,0(0,RI)          GET 'N' AREA KEY.                    28900013
         SLL   RE,1                MULTIPLY BY 2.                       29000013
         LA    RF,PPISEQCT         GET START POINT OF PPI SEQUENCE CTRS 29100013
         AR    RF,RE               GET PPI SEQ CT LOCATION.             29200013
         MVC   0(2,RF),34(RH)      STORE IN PPI.                        29300013
         B     ROTGOB              GO TO GET N CT.                      29400018
         SPACE 2                                                        29500013
ROTGOA   LA    RE,4(0,RI)          GET NEXT SEQ ADDR FROM NTH POS.      29600013
         MVC   WCLBKAR(8),0(RE)    BLOCK ONE ADDRESS.                   29700013
         MVC   PPIDEPHO(8),0(RE)   STOW NEXT SEQ ADDR FOR WRITE IN PPI. 29800013
ROTGON   CLC   PPIMRGOP(2),34(RH)  IS OPT MRG ORD=NO./SEQ IN AREA N-1.  29900013
         BNL   ROTGOC              GO TO STORE NO/SEQ                   30000018
         MVC   PPIMRGMX(2),PPIMRGOP  STOW OPT MRG ORDER IN MAX MRG ORD. 30100013
*  DECREMENT NO./SEQS. IN POS. N-1 BY MAX MRG ORD.                      30200013
ROTGOE   LH    RE,34(0,RH)         GET NO./SEQ IN N-1 POS.              30300013
         SH    RE,PPIMRGMX                                              30400013
         STH   RE,34(0,RH)         PUT BACK                             30500013
         B     ROTGOF                                                   30600018
*                                                                       30700013
* STORE NO/SEQ IN N-1 POS.,IN MAX                                       30800013
ROTGOC   MVC   PPIMRGMX(2),34(RH)                                       30900013
         B     ROTGOE              GO TO DECREMENT NO/SEQ               31000018
*                                                                       31100013
*  DETAIL CHART ******************************************************* 31200013
*  SAVE REG'RI'=NTH ADDR ********************************************** 31300013
ROTGOF   ST    RI,WSAVERI                                               31400013
*  GET ADDR. OF PPI SEQ WORK AREA -'TO'ADDR *************************** 31500013
         LA    RG,PPIWKARE                                              31600013
*  GET ADDR/NXT POS.IN BLK RETRIEVED,FOR N-1 POS-'FROM ADDR'*********** 31700013
         L     RF,28(0,RH)                                              31800013
*  PUT ADDR/NXT DICTY BLK FR.TBL. INTO PPI FOR'READ'******************* 31900013
         MVC   PPIDIRAD(8),20(RH)                                       32000013
*  SAVE REGS RF,RG,RH ************************************************* 32100013
         STM   RF,RH,WSAVERF                                            32200013
*  READ ROUTINE ******************************************************* 32300013
         L     RL,PPIRD+4                                               32400013
         BALR  RO,RL               GO TO READ DIRECTORY                 32500018
*  RESTORE REGS RF,RG,RH ********************************************** 32600013
         LM    RF,RH,WSAVERF                                            32700013
*  GET MAX MRG ORDER                                                    32800013
         LH    RB,PPIMRGMX                                              32900013
*  MOVE 1 DISK ADDR FR.'FROM',TO'TO'IN WORK AREA (PPI) **************** 33000013
ROTGOK   MVC   0(8,RG),0(RF)                                            33100013
*  BUMP'FROM'ADDR.***************************************************** 33200013
         LA    RF,8(0,RF)                                               33300013
*  BUMP 'TO' ADDR.                                                      33400013
         LA    RG,8(0,RG)                                               33500013
         B     ROTGOG                                                   33600018
*  DECREMENT MERGE ORDER CT., CHECK IF ZERO                             33700013
ROTGOX   BCT   RB,ROTGOK           GO TO MOVE DISK ADDR IN WORK AREA    33800018
*  STORE INDEXED 'FROM' ADDR INTO TABLE (NXT-POS-IN-BLK)                33900013
         ST    RF,28(0,RH)                                              34000013
*  SAVE REG RH (N-1)                                                    34100013
         ST    RH,WSAVERH                                               34200013
         L     RL,PPIRD+4                                               34300013
         B     4(0,RL)             GO TO READ PH2 AND PH3               34400018
         SPACE 2                                                        34500013
*  LIMIT OF NEW BLOCK{ ************************************************ 34600013
ROTGOG   LA    RE,PPILAB01+64                                           34700013
         CLR   RF,RE                                                    34800013
         BL    ROTGOX             NO                                    34900013
*  RESET'FROM'ADDR.TO BEG/BLK ***************************************** 35000013
         LA    RF,PPILAB01                                              35100013
*  WAS LAST BLOCK,LAST ON TRACK{ ************************************** 35200013
         SPACE 2                                                        35230017
ROT100   EQU   *                                                        35260017
         CLI   27(RH),X'1C'       IS TRACK CT = 28 (IN N-1)             35300013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     35320017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             35340017
*        CLI   27(RH),X'2C'                                             35360017
         SPACE 2                                                        35380017
         BE    ROTNEWTK            NO,BRANCH                            35400013
*  INCREMENT TO NXT BLK ADDR(RECD CT) BY 1 (IN TABLE)                   35500013
         L     RE,24(0,RH)         GET RIGHT HALF OF NXT DIR BLK (N-1)  35600013
         LA    RJ,1               GET A 1                               35700013
         AR    RE,RJ              ADD TO TRACK CT.                      35800013
         ST    RE,24(0,RH)         PUT BACK                             35900013
*  MUST ANOTHER BLOCK OF DIRCTY BE READ?                                36000013
ROTGOH   LA    RE,1                                                     36100013
         CLR   RB,RE                                                    36200013
         BE    ROTGOX             NO,                                   36300013
*  SET UP 'DIRAD' FOR ANOTHER READ                                      36400013
         MVC   PPIDIRAD(8),20(RH)                                       36500013
*  SAVE REGS RF,RG,RH ************************************************* 36600013
         STM   RF,RH,WSAVERF                                            36700013
*  SAVE DECREMENTED MRG ORDER                                           36800013
         ST    RB,WSAVERB                                               36900013
*  READ ROUTINE ******************************************************* 37000013
         L     RL,PPIRD+4                                               37100013
         BALR  RO,RL               GO TO READ DIRECTORY                 37200018
*  RESTORE REGS RF,RG,RH ********************************************** 37300013
         LM    RF,RH,WSAVERF                                            37400013
*  RESTORE DECREMENTED MRG ORDER                                        37500013
         L     RB,WSAVERB                                               37600013
         B     ROTGOX              GO TO DECREMENT MERGE ORDER          37700018
*                                                                       37800013
*  DECREMENT NXT BLOCK ADDR BACK 1 TRK AND RESET RECD CT TO 1           37900013
ROTNEWTK LA    RE,1                                                     38000013
         STC   RE,27(0,RH)                                              38100013
         CLI   26(RH),X'00'        IS TRACK NO.= 0                      38200013
         BNE   ROTREDTK            NO, REDUCE TRACK NO.                 38300013
*  REDUCE CYLINDER NO. ************************************************ 38400013
         SR    RE,RE                                                    38500013
         IC    RE,24(0,RH)         GET CYL NO.                          38600013
         BCT   RE,ROTINCTK         REDUCE BY 1                          38700013
*  NO FALL THRU POS.---JOB WOULD HAVE ABORTED IN PHASE 1 ************** 38800013
ROTINCTK STC   RE,24(0,RH)         REPLACE UPDATED CYL. NO.             38900013
         LA    RE,9                                                     39000013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     39020017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             39040017
*        LA    RE,19                                                    39060017
         STC   RE,26(0,RH)         RESET HEAD NO.=9                     39100013
         B     ROTGOH              GO TO CHK IF ANOTHER DICTY TO BE RD  39200018
*                                                                       39300013
*  REDUCE TRACK NO. *************************************************** 39400013
ROTREDTK SR    RE,RE               CLEAR REG                            39500013
         IC    RE,26(0,RH)         GET TRACK NO.                        39600013
         LA    RO,1                CONSTANT 1                           39700013
         SR    RE,RO               REDUCE BY 1                          39800013
         STC   RE,26(0,RH)         PUT TRACK NO. BACK                   39900013
         B     ROTGOH              GO TO CHK IF ANOTHER DICTY TO BE RD  40000018
*                                                                       40100013
*  EOS ROUTINE ******************************************************** 40200013
*  RESET REGS RH,RI= N-1,N ******************************************** 40300013
ROTEOS   LM    RH,RI,WSAVERH                                            40400013
*  BUMP NO.NEW SEQS IN TABLE ****************************************** 40500013
         LH    RE,32(0,RI)         GET NO.NEW SEQ                       40600013
         LA    RE,1(0,RE)          BUMP BY 1                            40700013
         STH   RE,32(0,RI)         PUT BACK                             40800013
*  DECREMENT BLKG CTR FOR DICTY BY 1 --- IS BLOCK FILLED{ ************* 40900013
         L     RE,WBLKCT                                                41000013
         BCT   RE,ROTGOL           NO,BRANCH                            41100013
         B     ROTGOM              GO TO SAVE ADDR OF NXT SEQ           41200018
*                                                                       41300013
*  BLOCK NEXT OUTPUT SEQ. DISK ADDR *********************************** 41400013
ROTGOL   LA    RF,8                GET DISPLCMT IN BLKG AREA VIA BLKCTR 41500013
         SR    RF,RE                                                    41600013
         ST    RE,WBLKCT          STORE DECRM'TD BLOCK COUNT            41700013
         SLL   RF,3                                                     41800013
         LA    RG,WCLBKAR          GET ST.PT.                           41900013
         AR    RG,RF                                                    42000013
         MVC   0(8,RG),PPIDEPHO    MOVE INTO BLOCK                      42100013
*  ALL SEQS FR. TABLE POS.N-1 PASSED{ *                                 42200013
         LH    RE,34(0,RH)                                              42300013
         LTR   RE,RE                                                    42400013
         BNE   ROTGON              GO TO CHK OPT MRG ORD                42500018
         SPACE 2                                                        42600013
*   THIS SERIES OF INSTRUCTIONS IS EXECUTED WHEN WRITING A PARTIALLY    42700013
*   FILLED BLOCK OF DIRECTORY.                                          42800013
         SPACE 2                                                        42900013
         BAL   RO,ROTSETDR         BRANCH TO DIRECTORY SET UP SUBRTNE.  43000013
         SPACE 1                                                        43100013
         L     RL,PPIWRT+4         LOAD ADR OF WRITE ROUTINE (IERRPE).  43200013
         BAL   RO,12(0,RL)         GO TO WRITE A BLOCK OF DIRECTORY.    43300013
         SPACE 1                                                        43400013
         LM    RH,RI,WSAVERH       RESTORE REGS.                        43500013
*  STORE NO.NEW SEQS FOR POS.N IN ITS COUNTER IN PPI ****************** 43600013
ROTGOR   L     RE,0(0,RI)          GET N AREA KEY                       43700017
         SLL   RE,1                MULTPY BY 2                          43800013
         LA    RF,PPISEQCT         GET ST.PT.                           43900013
         AR    RF,RE               DISPLACE TO PROPER ADDR.             44000013
         MVC   0(2,RF),32(RI)                                           44100013
ROTGOB   LA    RE,1                CONSTANT 1                           44200013
         L     RF,WNODSKA          GET N CT.                            44300013
*  END OF PASS{,(NO/AREA CTR=1)                                         44400013
         CLR   RF,RE                                                    44500013
         BNE   ROT300              NO- LOOP TO BEG PT AND CONT. PASS    44600017
*  STORE A ZERO IN POS. 1'S AREA IN PPI COUNTERS ********************** 44700013
         L     RE,0(0,RH)          GET 'N'1 AREA KEY                    44800013
         SLL   RE,1                MULTPY BY 2                          44900013
         LA    RF,PPISEQCT         GET ST. PT.                          45000013
         AR    RF,RE               DISPLC.                              45100013
         MVC   0(2,RF),32(RH)                                           45200013
*  SUM SEQUENCE COUNTERS ********************************************** 45300013
         SR    RF,RF                                                    45400013
         LH    RE,PPINDSKA                                              45500013
         LA    RG,PPISEQCT                                              45600013
ROTLOOPH AH    RF,0(0,RG)          0UM IN RF                            45700013
         LA    RG,2(0,RG)          BUMP TO NXT CTR                      45800013
         BCT   RE,ROTLOOPH         BRANCH BACK TO THE LOOP              45900018
* SUM VS. ALT                                                           46000013
         LH    RG,PPIMRGAL                                              46100013
         CLR   RF,RG                                                    46200013
         BH    ROTPHAS2            GO SET INDICATOR TO PHASE 2          46300018
*  CLOSE ROUTINE ****************************************************** 46400013
         STH   RF,PPIMRGOP         STORE NO. STRINGS FOR MERGE          46500013
         STH   RF,PPIMRGMX         UPDATE MRGMX WITH SUM OF SEQ CNTS.   46600013
ROTGOP   L     RP,PPIADSSC                                              46700013
         LA    RB,4                                                     46800013
         B     20(0,RP)            GO TO SSC                            46900013
*                                                                       47000013
*  REVERSE A OR D SWITCH ********************************************** 47100013
ROTPHAS2 XI    PPISW1+3,X'08'     TURN BIT 29 TO OPPOSITE               47200013
*  SET INDICATOR TO PHASE 2 ******************************************* 47300013
         L     RP,PPIADSSC                                              47400013
         LA    RB,0                                                     47500013
         B     20(0,RP)            GO TO SSC                            47600013
ROT300   B     ROTSTART            GO SET RI TO NTH POS OF TABLE        47610018
*   THE ABOVE INSTRUCTION WILL BE MODIFIED TO A NO-OP IF CHECKPOINT     47620017
*    HAS BEEN INDICATED. IF CHECKPOINTS ARE BEING TAKEN WE WILL LINK TO 47630017
*    THE CHECKPOINT MODULE.                                             47640017
         SPACE 2                                                        47650017
         L     RP,PPICHKAD         LOAD BASE ADDRESS                    47660017
         BALR  RO,RP               ISSUE CHECKPOINT                     47670017
         SPACE 1                                                        47680017
         B     ROTSTART            GO SET RI TO NTH POS OF TABLE        47690018
*                                                                       47700013
*  SAVE THE ADDR OF WHERE TO WRITE NXT SEQ IN TABLE ******************* 47800013
ROTGOM   MVC   4(8,RI),PPIDEPHO   PUT IN 'N' POS.                       47900013
*  STORE ADDR OF WHERE TO RECD NXT DICTY BLK IN PPI FOR'N'POS.********* 48000013
         SPACE 2                                                        48100013
*   THIS SERIES OF INSTRUCTIONS IS ENTERED WHEN WRITING A FULL BLOCK    48200013
*   OF DIRECTORY.                                                       48300013
         SPACE 2                                                        48400013
         BAL   RO,ROTSETDR         BRANCH TO DIRECTORY SET UP SUBRTNE.  48500013
         SPACE 1                                                        48600013
         L     RL,PPIWRT+4         LOAD ADR OF WRITE ROUTINE (IERRPE).  48700013
         BAL   RO,12(0,RL)         GO TO WRITE A BLOCK OF DIRECTORY.    48800013
         SPACE 1                                                        48900013
         LM    RH,RI,WSAVERH       RESTORE REGS.                        49000013
*  ALL SEQ'S FROM TABLE (POS N-1) PASSED{ ***************************** 49100013
         LH    RE,34(0,RH)                                              49200013
         LTR   RE,RE                                                    49300013
         BE    ROTGOR              GO STORE NO OF NEW SEQS              49400018
*  IS THIS TRACK OF DICTY FILLED{ ************************************* 49500013
         SPACE 2                                                        49530017
ROT200   EQU   *                                                        49560017
         CLI   19(RI),X'1C'       IS RECORD CT = 28 (LAST POSS RECD)    49600013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     49620017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             49640017
*        CLI   19(RI),X'2C'                                             49660017
         SPACE 2                                                        49680017
         BNE   ROTGOS              NO,BRANCH                            49700013
*  RESET RECORD CT FOR POS. 'N' IN TABLE TO 1                           49800013
         LA    RE,1                                                     49900013
         STC   RE,19(0,RI)                                              50000013
*  DECREMENT TRACK ADDR BY 1,TO'N' POS. IN TABLE ********************** 50100013
         CLI   18(RI),X'00'        TRACK NO.= 0{                        50200013
         BNE   ROTDECTK            NO                                   50300013
         SR    RF,RF               CLEAR REG                            50400013
         IC    RF,16(0,RI)         GET CYL. NO.                         50500013
         BCT   RF,ROTBMPTK         REDUCE BY 1                          50600013
*  NO FALL THRU POS.---JOB WOULD HAVE ABORTED IN PHASE 1 ************** 50700013
*  RESET TRACK NO. TO 9 *********************************************** 50800013
ROTBMPTK LA    RE,9                CONSTANT 9                           50900013
*   THE ABOVE INSTRUCTION WILL BE MODIFIED IF A 2314 IS PRESENT AND     50920017
*     USING THE 2311 ALGORITHM. THE NEW INSTRUCTION WILL BE             50940017
*        LA    RE,19                                                    50960017
         SPACE 2                                                        50980017
         STC   RE,18(0,RI)                                              51000013
         B     ROTGOA              GO SET NXT SEQ ADDR                  51100018
*                                                                       51200013
*  DECREMENT TRACK NO. BY 1 ******************************************* 51300013
ROTDECTK LA    RE,1                                                     51400013
         IC    RF,18(0,RI)         GET TRK NO.                          51500013
         SR    RF,RE               DECR BY 1                            51600013
         STC   RF,18(0,RI)         PUT BACK                             51700013
         B     ROTGOA              GO SET NXT SEQ ADDR                  51800018
*  BUMP RECORD CT FOR POS. 'N',CONT. TO WRITE ON SAME TRACK             51900013
ROTGOS   IC    RE,19(0,RI)        GET RECORD CT.                        52000013
         LA    RE,1(0,RE)          ADD 1                                52100013
         STC   RE,19(0,RI)         PUT BACK                             52200013
         B     ROTGOA              GO GET NXT SEQ ADDR                  52300018
         SPACE 2                                                        52400013
*   THIS SUBROUTINE IS ENTERED EACH TIME A BLOCK OF DIRECTORY IS TO BE  52500013
*   WRITTEN. ITS FUNCTION IS TO MOVE THE DIRECTORY TO PPI, STORE THE    52600013
*   DISK ADDRESS IN PPI, AND RESET THE DIRECTORY BLOCKING COUNTER.      52700013
         SPACE 2                                                        52800013
ROTSETDR MVC   PPIDIRAD(8),12(RI)  PUT DIRECTORY ADDR IN PPI.           52900013
         MVC   PPIWKARE(64),WCLBKAR  PUT BLOCK OF DIRECTORY IN PPI.     53000013
         STM   RH,RI,WSAVERH       SAVE REGS.                           53100013
         LA    RE,8                                                     53200013
         ST    RE,WBLKCT           RESET DIRECTORY BLOCKING COUNTER.    53300013
         BR    RO                  RETURN TO MAIN LINE.                 53400013
         SPACE 2                                                        53500013
         DS    0F                                                       53600013
WTABLE   DC    X'00000000'         MERGE TABLE    FIRST AREA            53700013
         DS    8F                                ENTRY                  53800018
         DC    X'00000001'                        SECOND AREA           53900013
         DS    8F                                ENTRY                  54000018
         DC    X'00000002'                        THIRD AREA            54100013
         DS    8F                                ENTRY                  54200018
         DC    X'00000003'                        FOURTH AREA           54300013
         DS    8F                                ENTRY                  54400018
         DC    X'00000004'                        FIFTH AREA            54500013
         DS    8F                                ENTRY                  54600018
         DC    X'00000005'                        SIXTH AREA            54700013
         DS    8F                                ENTRY                  54800018
WSAVERB  DS    1F                  SAVE AREA FOR REG.RB WHEN LINKING    54900018
WSAVERF  DS    1F                  SAVE AREA FOR REG.RF WHEN LINKING    55000013
WSAVERG  DS    1F                  SAVE AREA FOR REG.RG WHEN LINKING    55100013
WSAVERH  DS    1F                  SAVE AREA FOR REG.RH WHEN LINKING    55200013
WSAVERI  DS    1F                  SAVE AREA FOR REG.RI WHEN LINKING    55300013
WCLBKAR  DS    16F                 DICTY BLOCKING AREA=64 BYTES         55400013
WBLKCT   DC    X'00000008'         DICTY BLOCKING COUNTER               55500013
WNODSKA  DC    X'00000000'         NO. DISK AREAS COUNT.-DET. END/PASS  55600013
         EJECT                                                          55700013
         SMPPI                                                          55800013
         END                                                            55900013
