         TITLE 'IERAOU - OS/360 SORT/MERGE - 360S-SM-023  03/11/65'     00100013
*MODULE NAME:*** IERAOU ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3 ASSIGNMENT ROUTINE FOR A 1-8  00600013
*   WAY MERGE NETWORK RUNNING PROGRAM NAMED *** IERROU *** (SEE DSECT)  00700013
*   WITH MULTIPLE CONTROL FIELDS. THE FUNCTION OF THIS MODULE IS TO SET 00800013
*   THE NETWORK COMPARE INSTRUCTIONS WITH A LENGTH AND DISPLACEMENT     00900013
*   ATTRIBUTE AND TO SET THE NETWORKS PHASE-2/PHASE-3 SWITCHES ACCORD-  01000013
*   ING TO THE PHASE .                                                  01100013
         SPACE 2                                                        01200013
*USED AS A DSECT IN'  N/A                                               01300013
*                                                                       01400013
*MACROS USED'                                                           01500013
         SPACE 1                                                        01600013
*   SMPPI                                                               01700013
         SPACE 2                                                        01800013
*ENTRY POINTS:                                                          01900013
         SPACE 1                                                        02000013
*        ENTRY IERAOU              ENTRY FROM:                          02100013
*                                    CALLING SEQUENCE-                  02200013
*                                      LA   RP,VALUE                    02300013
*                                      BALR RO,RP                       02400013
         SPACE 2                                                        02500013
*INPUT: PPI FIELDS REFERENCED-                                          02600013
         SPACE 1                                                        02700013
*    PPINETM   PPIDDOL1                                                 02800013
*    PPISW1    PPIAXERT                                                 02900013
         SPACE 2                                                        03000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED- NONE                        03100013
         SPACE 1                                                        03200013
         SPACE 2                                                        03300013
*EXTERNAL ROUTINES:                                                     03400013
         SPACE 1                                                        03500013
*        EXTRN IERROU                                                   03600013
*        EXTRN IERRMC                                                   03700013
         SPACE 2                                                        03800013
*EXTERNAL PARAMETERS: NONE                                              03900013
         SPACE 1                                                        04000013
*EXITS: NORMAL                                                          04100013
         SPACE 1                                                        04200013
*        IERRC9                    CALLER ROUTINE FOR ASSIGNMENT RTN    04300013
         SPACE 2                                                        04400013
*EXITS: ERROR                                                           04500013
         SPACE 1                                                        04600013
*        IERRMC                    MESSAGE MODULE                       04700013
         SPACE 2                                                        04800013
*TABLES/WORK AREAS: N/A                                                 04900013
         SPACE 1                                                        05000013
         SPACE 2                                                        05100013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  05200013
         SPACE 2                                                        05300013
*NOTES: NONE                                                            05400013
         SPACE 1                                                        05500013
         SPACE 2                                                        05600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            05700013
         SPACE 1                                                        05800013
RA       EQU   0                   CONTENTS IN- N/A                     05900013
*                                  USE- UNUSED                          06000013
*                                  CONTENTS OUT- N/A                    06100013
RB       EQU   1                   CONTENTS IN- N/A                     06200013
*                                  USE- UNUSED                          06300013
*                                  CONTENTS OUT- N/A                    06400013
RC       EQU   2                   CONTENTS IN- N/A                     06500013
*                                  USE- UNUSED                          06600013
*                                  CONTENTS OUT- N/A                    06700013
RD       EQU   3                   CONTENTS IN- N/A                     06800013
*                                  USE- UNUSED                          06900013
*                                  CONTENTS OUT- N/A                    07000013
RE       EQU   4                   CONTENTS IN- N/A                     07100013
*                                  USE- GENERAL WORK REGISTER           07200013
*                                  CONTENTS OUT- N/A                    07300013
RF       EQU   5                   CONTENTS IN- N/A                     07400013
*                                  USE- UNUSED                          07500013
*                                  CONTENTS OUT- N/A                    07600013
RG       EQU   6                   CONTENTS IN- N/A                     07700013
*                                  USE- UNUSED                          07800013
*                                  CONTENTS OUT- N/A                    07900013
RH       EQU   7                   CONTENTS IN- N/A                     08000013
*                                  USE- UNUSED                          08100013
*                                  CONTENTS OUT- N/A                    08200013
RI       EQU   8                   CONTENTS IN- N/A                     08300013
*                                  USE- UNUSED                          08400013
*                                  CONTENTS OUT- N/A                    08500013
RJ       EQU   9                   CONTENTS IN- N/A                     08600013
*                                  USE- UNUSED                          08700013
*                                  CONTENTS OUT- N/A                    08800013
RK       EQU   10                  CONTENTS IN- N/A                     08900013
*                                  USE- UNUSED                          09000013
*                                  CONTENTS OUT- N/A                    09100013
RL       EQU   11                  CONTENTS IN- N/A                     09200013
*                                  USE- MODULE BASE ADDRESS REGISTER    09300013
*                                  CONTENTS OUT- ADDRESS OF THIS MODULE 09400013
RM       EQU   12                  CONTENTS IN- N/A                     09500013
*                                  USE- EQUALS BASE ADDRESS REGISTER    09600013
*                                  CONTENTS OUT- EQUALS ADDRESS         09700013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          09800013
*                                  USE- PPI REFERENCE,REGISTER SAVE     09900013
*                                    AREA                               10000013
*                                  CONTENTS OUT- ADDRESS OF PPI         10100013
RO       EQU   14                  CONTENTS IN: RETURN ADDRESS TO SYST  10200013
*                                  USE- MERGE NETWORK BASE ADDRESS REG  10300013
*                                  CONTENTS OUT- RETURN ADDRESS TO SYST 10400013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  10500013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 10600013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 10700013
         SPACE 2                                                        10800013
*START OF MODULE CODE PROPER:                                           10900013
         SPACE 2                                                        11000013
IERAOU   CSECT                                                          11100013
         USING *,RL                                                     11200013
         USING IERRCA,RN                                                11300013
         USING DIERRMC,RP          MESSAGE MODULE                       11400013
*    MODULE ENTRY POINT                                                 11500013
IERMO1   LR    RL,RP                                                    11600013
         ST    RO,RKSAVC9                                               11700013
         L     RO,PPINET+4         SET UP IF PHASE 3                    11800013
         USING DIERROU,RO                                               11900013
         TM    PPISW1+2,X'04'      IS THIS PHASE 3                      12000013
         BO    AOUPH3              FALL THRU IF PHASE 2                 12100013
         L     RO,PPINETM+4        RESET IF PHASE 2                     12200013
*    IN PHASE 2, THE PHASE 2 SWITCHES ARE AS SHOWN IN LISTING           12300013
*    THE FOLLOWING SECTION SETS UP THE NETWORK COMPARE INSTRUCTIONS     12400013
AOUCIS   IC    RE,PPIDD0L1+3                                            12500013
         STC   RE,IERDOM8+1        LENGTH ATTRIBUTE                     12600013
         OC    IERDOM8+2(2),PPIDD0L1  DISPLACEMENT ATTRIBUTE            12700013
         OC    IERDOM8+4(2),PPIDD0L1                                    12800013
         STC   RE,IERDOM4+1                                             12900013
         OC    IERDOM4+2(2),PPIDD0L1                                    13000013
         OC    IERDOM4+4(2),PPIDD0L1                                    13100013
         STC   RE,IERDOM2+1                                             13200013
         OC    IERDOM2+2(2),PPIDD0L1                                    13300013
         OC    IERDOM2+4(2),PPIDD0L1                                    13400013
         STC   RE,IERDOSCK+1                                            13500013
         OC    IERDOSCK+2(2),PPIDD0L1                                   13600013
         OC    IERDOSCK+4(2),PPIDD0L1                                   13700013
         STC   RE,IERDOCK6+1                                            13800013
         OC    IERDOCK6+2(2),PPIDD0L1                                   13900013
         OC    IERDOCK6+4(2),PPIDD0L1                                   14000013
         STC   RE,IERDOCK5+1                                            14100013
         OC    IERDOCK5+2(2),PPIDD0L1                                   14200013
         OC    IERDOCK5+4(2),PPIDD0L1                                   14300013
         STC   RE,IERDOCK7+1                                            14400013
         OC    IERDOCK7+2(2),PPIDD0L1                                   14500013
         OC    IERDOCK7+4(2),PPIDD0L1                                   14600013
         STC   RE,IERDOCK3+1                                            14700013
         OC    IERDOCK3+2(2),PPIDD0L1                                   14800013
         OC    IERDOCK3+4(2),PPIDD0L1                                   14900013
         STC   RE,IERDOCK4+1                                            15000013
         OC    IERDOCK4+2(2),PPIDD0L1                                   15100013
         OC    IERDOCK4+4(2),PPIDD0L1                                   15200013
         STC   RE,IERDOICP+1                                            15300013
         OC    IERDOICP+2(2),PPIDD0L1                                   15400013
         OC    IERDOICP+4(2),PPIDD0L1                                   15500013
*    THE END OF THE SECTION WHICH SETS UP THE COMPARE INSTRUCTIONS      15600013
         SPACE 1                                                        15700013
         L     RM,PPIAXERT         SET BASE REG OF EQUALS ROUTINE       15800013
*    EXIT TO NEXT ASSIGNMENT RTN                                        15900013
         L     RO,RKSAVC9                                               16000013
         BR    RO                  NEXT ASSGN. RTN.                     16100018
         SPACE 2                                                        16200013
*    THE FOLLOWING SECTION SETS THE NETWORK FOR PHASE 3                 16300013
AOUPH3   OI    IERDOM1+1,X'F0'                                          16400013
         OI    IERDOBWR+1,X'F0'                                         16500013
         OI    IERDOCPS+1,X'F0'                                         16600013
         OI    IERDOIP3+1,X'F0'                                         16700013
         B     AOUCIS             BRANCH TO SET COMPARE INSTR SECTION   16800013
         SPACE 2                                                        16900013
RKSAVC9  DS    F                   NEXT ASSGN. RTN. ADDR.               17000018
         EJECT                                                          17100013
DIERROU  DSECT                                                          17200013
IERDO1   B     ROUSINIT            READ PRIME ENTRY  BR TO INITIALIZAT  17300013
         B     ROUCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 17400013
         LM    RE,RK,ROUSVREG      DEBLOCK ENTRY - RESTORE REGISTERS    17500013
ROUNTENS B     IERDOM8             NETWORK ENTR SWTCH SET BY CUTBACK    17600013
         SPACE 2                                                        17700013
*    THE FIND THE WINNER LOOP                                           17800013
         SPACE 1                                                        17900013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   18000013
         SPACE 1                                                        18100013
IERDOM8  CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         18200013
         BNE   ROUNOEQ8            IF EQUAL GO TO EQUALS ROUTINE        18300013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  18400013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    18500013
*    THIS BRANCH INSTR IS BH OF BL DEPENDING ON THE INPUT SEQUENCE      18600013
ROUNOEQ8 BH    IERDOCK6            IF HI/LO GO TO CMP ITEM 6 OR 5       18700013
         SPACE 1                                                        18800013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   18900013
         SPACE 1                                                        19000013
IERDOM4  CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         19100013
         BNE   ROUNOEQ4            IF EQUAL GO TO EQUALS ROUTINE        19200013
         LR    RC,RF               LOAD EQ RTN COMPARE REG WITH ITEM 2  19300013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    19400013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      19500013
ROUNOEQ4 BH    IERDOCK3            IF HI/LO GO TO CMP ITEM 3,4 OR UPDAT 19600013
         SPACE 1                                                        19700013
*    ENTRANCE FOR A 2 WAY MERGE                                         19800013
         SPACE 1                                                        19900013
IERDOM2  CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         20000013
         BNE   ROUNOEQ2            IF EQUAL GO TO EQUALS ROUTINE        20100013
         LR    RC,RE               LOAD EQ RTN COMPARE REG WITH ITEM 1  20200013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    20300013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      20400013
ROUNOEQ2 BH    ROUMOV1             IF HI/LO NEW COLLATES AFTER ITEM 1   20500013
         SPACE 1                                                        20600013
*    ENTRANCE FOR A 1 WAY MERGE AND NEW ITEM IS THE WINNER              20700013
         SPACE 1                                                        20800013
*    IF PHASE 2 EXIT TO THE BLOCK RTN                                   20900013
*    IF PHASE 3 OR MERGE ONLY PERFORM RECORD SEQUENCE CHECK             21000013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 21100013
IERDOM1  BC    0,ROUPH3            DROP THRU FOR PHASE 2                21200013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               21300013
         L     RL,PPIBLK2+4                                             21400013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RECORD     21500013
         SPACE 2                                                        21600013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      21700013
*    WINNER. CHECK DONE USING REG RD AND RC.                            21800013
         SPACE 1                                                        21900013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLK RTN. THEBLK RTN          22000013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  22100013
*       EXITS ARE ACTIVATED, THE BLK RTN TAKES NO ACTION CONCERNING     22200013
*       PPIDOUO                                                         22300013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        22400013
*    SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,        22500013
*       PPIDOUO IS 0.                                                   22600013
         SPACE 2                                                        22700013
ROUPH3   L     RC,PPIDOUO                                               22800013
         B     ROUCKISC(RC)        BRANCH TO EXIT                       22900018
ROUCKISC B     ROUSCK              SEQUENCE CHECK                       23000018
         SPACE 2                                                        23100013
*    NO SEQUENCE CHECK                                                  23200013
ROUOUT   STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               23300013
         L     RL,PPIBLK+4                                              23400013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RECORD   23500013
         SPACE 2                                                        23600013
ROUSCK   L     RC,PPIDOOBA        ADDR OF REC IN OUTPUT BUFFER          23700013
IERDOSCK CLC   0(1,RD),0(RC)                                            23800013
         BNE   ROUSCB              IF UNEQUAL BYPASS NSI                23900018
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    24000013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   24100013
ROUSCB   BC    10,ROUOUT           BLOCK RTN.                           24200018
*    OUT OF SEQUENCE ERROR                                              24300013
         L     RO,PPIRMC+4                                              24400013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   24430017
         BO    ROUMERG             YES, BRANCH                          24460017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              24500013
ROUSEQ   L     RP,PPIADSSC                                              24600017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       24700013
         L     RP,PPIADSSC                                              24800013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  24900013
ROUMERG  SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     24910017
         CVD   RD,ROUCONV          CONVERT INDEX TO DECIMAL             24920017
         UNPK  ROUTEMP(2),ROUCONV+7(1)  UNPACK FOR PRINTING             24930017
         OI    ROUTEMP+1,X'F0'     SET SIGN POSITIVE                    24940017
         MVC   MSGP3MA8(2),ROUTEMP      MOVE UNIT NUMBER INTO MESSAGE   24950017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQUENCE                24960017
         B     ROUSEQ              GO PRINT MESSAGE                     24970017
         EJECT                                                          25000013
IERDOCK6 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         25100013
         BNE   ROUNOEQ6            IF EQUAL GO TO EQUALS ROUTINE        25200013
         LR    RC,RJ               LOAD EQ RTN COMPARE REG WITH ITEM 6  25300013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    25400013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      25500013
ROUNOEQ6 BH    IERDOCK7            IF HI/LO GO TO CMP ITEM 7 OR UPDATE  25600013
IERDOCK5 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         25700013
         BNE   ROUNOEQ5            IF EQUAL GO TO EQUALS ROUTINE        25800013
         LR    RC,RI               LOAD EQ RTN COMPARE REG WITH ITEM 5  25900013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    26000013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      26100013
ROUNOEQ5 BH    ROUMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   26200013
         SPACE 1                                                        26300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 4 + BEFORE ITEM 5      26400013
         SPACE 1                                                        26500013
ROUMOV4  LR    RC,RD                                                    26600013
         LR    RD,RE                                                    26700013
         LR    RE,RF                                                    26800013
         LR    RF,RG                                                    26900013
         LR    RG,RH                                                    27000013
         LR    RH,RC                                                    27100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              27200013
         SPACE 2                                                        27300013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 5 + BEFORE ITEM 6      27400013
ROUMOV5  LR    RC,RD                                                    27500013
         LR    RD,RE                                                    27600013
         LR    RE,RF                                                    27700013
         LR    RF,RG                                                    27800013
         LR    RG,RH                                                    27900013
         LR    RH,RI                                                    28000013
         LR    RI,RC                                                    28100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              28200013
         SPACE 2                                                        28300013
IERDOCK7 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         28400013
         BNE   ROUNOEQ7            IF EQUAL GO TO EQUALS ROUTINE        28500013
         LR    RC,RK               LOAD EQ RTN COMPARE REG WITH ITEM 7  28600013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    28700013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      28800013
ROUNOEQ7 BH    ROUMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   28900013
         SPACE 1                                                        29000013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 6 + BEFORE ITEM 7      29100013
         SPACE 1                                                        29200013
ROUMOV6  LR    RC,RD                                                    29300013
         LR    RD,RE                                                    29400013
         LR    RE,RF                                                    29500013
         LR    RF,RG                                                    29600013
         LR    RG,RH                                                    29700013
         LR    RH,RI                                                    29800013
         LR    RI,RJ                                                    29900013
         LR    RJ,RC                                                    30000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              30100013
         SPACE 2                                                        30200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      30300013
         SPACE 1                                                        30400013
ROUMOV7  LR    RC,RD                                                    30500013
ROUMMOV7 LR    RD,RE               UPDATE EXECUTED AFT CUTBACK OPERAT   30600013
         LR    RE,RF                                                    30700013
         LR    RF,RG                                                    30800013
         LR    RG,RH                                                    30900013
         LR    RH,RI                                                    31000013
         LR    RI,RJ                                                    31100013
         LR    RJ,RK                                                    31200013
         LR    RK,RC                                                    31300013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              31400013
         SPACE 2                                                        31500013
IERDOCK3 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         31600013
         BNE   ROUNOEQ3            IF EQUAL GO TO EQUALS ROUTINE        31700013
         LR    RC,RG               LOAD EQ RTN COMPARE REG WITH ITEM 3  31800013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    31900013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      32000013
ROUNOEQ3 BH    ROUMOV3             IF HI/LO NEW COLLATES AFTER ITEM 3   32100013
         SPACE 1                                                        32200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 2 + BEFORE ITEM 3      32300013
         SPACE 1                                                        32400013
ROUMOV2  LR    RC,RD                                                    32500013
         LR    RD,RE                                                    32600013
         LR    RE,RF                                                    32700013
         LR    RF,RC                                                    32800013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              32900013
         SPACE 2                                                        33000013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 3 + BEFORE ITEM 4      33100013
         SPACE 1                                                        33200013
ROUMOV3  LR    RC,RD                                                    33300013
         LR    RD,RE                                                    33400013
         LR    RE,RF                                                    33500013
         LR    RF,RG                                                    33600013
         LR    RG,RC                                                    33700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              33800013
         SPACE 2                                                        33900013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 1 + BEFORE ITEM 2      34000013
         SPACE 1                                                        34100013
ROUMOV1  LR    RC,RD                                                    34200013
         LR    RD,RE                                                    34300013
         LR    RE,RC                                                    34400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              34500013
         SPACE 2                                                        34600013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             34700013
         SPACE 1                                                        34800013
IERDOCK4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         34900013
         BNE   ROUNOEQS            IF EQUAL GO TO EQUALS ROUTINE        35000013
         LR    RC,RH               LOAD EQ RTN COMPARE REG WITH ITEM 4  35100013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    35200013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      35300013
ROUNOEQS BH    ROUMOV4             IF HI/LO GO TO UPDATE                35400013
         B     IERDOCK3            IF NOT HI/LO GO TO CMP ITEM 3        35500013
         SPACE 2                                                        35600013
*    COMPLETION OF THE FIND THE LOW LOOP                                35700013
         EJECT                                                          35800013
*    PUTTING OUT THE NETWORK WINNER                                     35900013
*    SEQUENCE CHECKING IS NOT NECESSARY                                 36000013
*    IF PHASE 2 EXIT TO THE BLOCK ROUTINE                               36100013
*    THE ASSIGNMENT ROUTINE SETS THE BRANCH INSTR ACCORDING TO THE PHAS 36200013
IERDOBWR BC    0,ROUPH3NS          DROP THRU FOR PHASE 2                36300013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               36400013
         L     RL,PPIBLK2+4                                             36500013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        36600013
         SPACE 2                                                        36700013
ROUPH3NS STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               36800013
         L     RL,PPIBLK+4                                              36900013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RECORD   37000013
         EJECT                                                          37100013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 37200013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    37300013
*    MERGE ORDER. SUBSEQUENTLY A BRANCH TO UPDATE IS EXECUTED.          37400013
         SPACE 1                                                        37500013
ROUFMUDS BC    0,ROUFDMO           SET TO BRANCH BY INITIALIZATION RTN  37600013
*    FALL THROUGH FOR UPDATING NETWORK AFTER A CUTBACK OPERATION        37700013
         ST    RC,ROUSVCBA         SAVE NEXT CUTBACK ADDRESS            37800013
         B     ROUMMOV7            MODIFIED MOVE AFTER ITEM 7 NOTE BELO 37900013
*                                  ALL REGISTERS EXCEPT RC INVOLVED     38000013
         SPACE 1                                                        38100013
         SPACE 1                                                        38200013
         SPACE 1                                                        38300013
ROUFDMO  L     RF,ROUIDMO          SET TO 8 BY INITIALIZATION RTN       38400013
         C     RF,ROUACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 38500013
         BE    ROUSFTTU            SET FALL THRU TO UPDATE              38600013
         S     RF,KROONE           CONSTANT OF ONE                      38700013
         ST    RF,ROUIDMO                                               38800013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           38900013
         SPACE 2                                                        39000013
ROUSFTTU XI    ROUFMUDS+1,X'F0'    SET ROUFMUDS BRANCH TO FALL THRU     39100013
         ST    RC,ROUSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    39200013
         B     ROUINTSQ            EXIT TO INIT SEQ THE RECORDS ID FLC1 39300013
         EJECT                                                          39400013
*    THE NETWORK CUTBACK SECTION                                        39500013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      39600013
         SPACE 1                                                        39700013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        39800013
         SPACE 1                                                        39900013
*    SET NETWORK FOR AN 8 WAY MERGE                                     40000013
         SPACE 1                                                        40100013
ROUCSEWM MVC   ROUNOEQ8(4),ROUEGW1 SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  40200013
         MVC   ROUNOEQ6(4),ROUEGW2 SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  40300013
         MVC   ROUNOEQ4(4),ROUEGW3 SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  40400013
         MVC   ROUNTENS(4),ROUANT8 SET NETWORK ENTRANCE FOR 8 WAY MERGE 40500013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 40600013
         SPACE 1                                                        40700013
*    SET NETWORK FOR AN 7 WAY MERGE                                     40800013
         SPACE 1                                                        40900013
         MVC   ROUNOEQ6(4),ROUSVWM SET BR TO UPDATE AFTER ITEM 6 CMP    41000013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 41100013
         SPACE 1                                                        41200013
*    SET NETWORK FOR A 6 WAY MERGE                                      41300013
         SPACE 1                                                        41400013
         MVC   ROUNOEQ8(4),ROUSXWM SET BR TO CMP ITEM 5 AFT ITEM 4 CMP  41500013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 41600013
         SPACE 1                                                        41700013
*    SET NETWORK FOR A 5 WAY MERGE                                      41800013
         SPACE 1                                                        41900013
         MVC   ROUNOEQ4(4),ROUFVWM SET BR TO CMP ITEM 4 AFT ITEM 2 CMP  42000013
         MVC   ROUNTENS(4),ROUANT4 SET NETWORK ENTRANCE FOR 5 WAY MERGE 42100013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 42200013
         SPACE 1                                                        42300013
*    SET NETWORK FOR A 4 WAY MERGE                                      42400013
         SPACE 1                                                        42500013
         MVC   ROUNOEQ4(4),ROUEGW3 SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  42600013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 42700013
         SPACE 1                                                        42800013
*    SET NETWORK FOR A 3 WAY MERGE                                      42900013
         SPACE 1                                                        43000013
         MVC   ROUNOEQ4(4),ROUTHWM SET BR TO UPDATE AFTER ITEM 2 CMP    43100013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 43200013
         SPACE 1                                                        43300013
*    SET NETWORK FOR A 2 WAY MERGE                                      43400013
         SPACE 1                                                        43500013
         MVC   ROUNTENS(4),ROUANT2 SET NETWORK ENTRANCE FOR 2 WAY MERGE 43600013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 43700013
         SPACE 1                                                        43800013
*    SET NETWORK FOR A 1 WAY MERGE                                      43900013
         SPACE 1                                                        44000013
         MVC   ROUNTENS(4),ROUANT1 SET NETWORK ENTRANCE FOR 1 WAY MERGE 44100013
         BAL   RC,ROUFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 44200013
         SPACE 1                                                        44300013
*    A ZERO WAY MERGE                                                   44400013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    44500013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        44600013
*    THIS BRANCH INSTR IS SET BY THE ASSIGNMENT ROUTINE ACCORD TO PHASE 44700013
         SPACE 1                                                        44800013
IERDOCPS BC    0,ROUCPH3           FALL THRU FOR PHASE 2                44900013
         L     RL,PPIBLK2+4                                             45000013
         BR    RL                  EXIT TO BLOCK RTN (WRITE THE BLK)    45100013
         SPACE 2                                                        45200013
ROUCPH3  L     RL,PPIBLK+4                                              45300013
         BR    RL                  EXIT TO BLOCK RTN (END OF JOB)       45400013
         SPACE 2                                                        45500013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGOR         45600013
ROUCUTEN LM    RE,RK,ROUSVREG      RESTORE NETWORK REGISTERS            45700013
         L     RC,ROUSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 45800013
         BR    RC                  BRANCH TO APPROPRIATE CUTBACK SECTN  45900013
*    THIS IS THE END OF THE CUTBACK SECTION                             46000013
         EJECT                                                          46100013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 46200013
*    EACH MERGE OPERATION                                               46300013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING          46400013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  46500013
*       THE REMAINDER OF THE ITEMS AND, THEREBY, DETERMINING ITS PROPER 46600013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS, A TWO AREA SYSTEM IN  46700013
*       PPI IS UTILIZED.                                                46800013
         SPACE 1                                                        46900013
ROUINTSQ SR    RI,RI               INDEX USED TO GET ITEM S TO BE SEQD  47000013
         L     RB,ROUACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   47100013
         LA    RG,PPIPDWA          BEGINNING ADDR OF REC ADDR IN PPI    47200013
ROURETRN L     RF,ROUACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  47300013
*                                  CHECKED WITH ALL THE OTHER ITEMS     47400013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          47500013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 47600013
         SR    RH,RH               INDEX USED TO CMP ALL OTHER ITEMS    47700013
ROUANOTH L     RC,0(RH,RG)         ADDR OF ITEM S CMP TO ITEM IN RC     47800013
IERDOICP CLC   0(1,RD),0(RC)                                            47900013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   48000013
ROUISNLH BC    10,ROUHIEQ          HI/LO AND EQUAL CASE TREATED SAME    48100013
ROUDECR  LA    RH,4(0,RH)                                               48200013
         BCT   RF,ROUANOTH         TRY NEXT ITEM                        48300018
ROUCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   48400013
*                                  ZERO CHECK TO INSURE ANOTHER ITEM    48500013
*                                  DOES NOT OCCUPY THIS POSITION        48600013
         BE    ROUINSRT            IF ZERO STORE ITEM                   48700013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   48800013
         B     ROUCHEK             CONTINUE CHECKING FOR ZEROS          48900018
         SPACE 2                                                        49000013
ROUINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                49100013
         BCT   RB,ROUINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 49200013
         B     ROUOUTIS            BRANCH TO SET NETWORK REG IF DONE    49300013
         SPACE 2                                                        49400013
*    THIS BRANCH INSTR IS BC 2 OR 4 DEPENDING ON THE INPUT SEQUENCE     49500013
ROUHIEQ  BC    2,ROURND            IF NOT EQ INCR STORE POS POINTER     49600013
         BALR  RO,RM               SET NETWORK RETURN REG FOR EQ RTN    49700013
*    THIS BRANCH INSTR IS BC 4 OR 2 DEPENDING ON THE INPUT SEQUENCE     49800013
ROULOHI  BC    4,ROUDECR           CHECK NEXT ITEM                      49900018
ROURND   LA    RE,4(0,RE)                                               50000013
         B     ROUDECR             DECREMENT AND CHECK FOR ZEROS        50100018
         SPACE 2                                                        50200013
ROUINCR  LA    RI,4(0,RI)                                               50300013
         B     ROURETRN            LAST COMPARE                         50400018
         SPACE 2                                                        50500013
*    THE END OF THE INITIAL SEQUENCING SECTION                          50600013
         SPACE 2                                                        50700013
*    MOVE ADDRESSES OF SEQUENCED ITEMS  TO MERGE NETWORK REGISTERS      50800013
ROUOUTIS LA    RB,PPIPSVA          ADDR OF FIRST SEQUENCED ITEM         50900013
         L     RC,ROUACMO          MERGE ORDER                          51000013
         A     RC,KROTWO                                                51100013
         EX    RC,ROULODMR         EXECUTE LOAD REGISTERS INSTR         51200013
*    THIS BRANCH INSTR SET BY THE ASSIGN RTN ACCORDING TO THE PHASE     51300013
IERDOIP3 BC    0,ROUINSP3          FALL THRU IF PHASE 2                 51400013
         STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               51500013
         L     RL,PPIBLK2+4                                             51600013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        51700013
*    PHASE 3 PROCEDURE                                                  51800013
ROUINSP3 STM   RE,RK,ROUSVREG      SAVE NETWORK REGISTERS               51900013
         L     RL,PPIBLK+4                                              52000013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RCD      52100013
         SPACE 2                                                        52200013
         EJECT                                                          52300013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     52400013
*    OF EACH PASS OR SUB PASS                                           52500013
         SPACE 1                                                        52600013
ROUSINIT MVC   ROUIDMO(4),KROEIGHT SET MAX MRG ORD TO 8  A FIND M PARAM 52700013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          52800013
         ST    RE,ROUACMO                                               52900013
         SR    RE,RE                                                    53000013
         ST    RE,PPIPSVA                                               53100013
         MVC   PPIPSVA+4(60),PPIPSVA      ZERO INT SEQ STORE AREA       53200013
         XI    ROUFMUDS+1,X'F0'    SET ROUFMUDS TO BRANCH               53300013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG BIT 28   53400013
         BC    1,ROUISD            FALL THRU IF INPUT SEQ IS ASDNG      53500013
         TM    ROUNOEQ8+1,X'20'    IS RTN SET FOR ASDNG                 53600013
ROUFDSQ  BC    1,ROUCSEWM          IF THE ROUTINE IS SET FOR THE INPUT  53700013
         XI    ROUNOEQ8+1,X'60'    SEQUENCE  BRANCH TO THE CUTBACK      53800013
         XI    ROUNOEQ4+1,X'60'    SECTION.  IF THE ROUTINE IS NOT SET  53900013
         XI    ROUNOEQ2+1,X'60'    FOR THE INPUT   CHANGE THE MASK OF   54000013
         XI    ROUSCB+1,X'60'      THE BRANCH ON CONDITION INSTR.       54100013
         XI    ROUNOEQ6+1,X'60'                                         54200013
         XI    ROUNOEQ5+1,X'60'                                         54300013
         XI    ROUNOEQ7+1,X'60'                                         54400013
         XI    ROUNOEQ3+1,X'60'                                         54500013
         XI    ROUNOEQS+1,X'60'                                         54600013
         XI    ROUISNLH+1,X'60'                                         54700013
         XI    ROUHIEQ+1,X'60'                                          54800013
         XI    ROULOHI+1,X'60'                                          54900013
         XI    ROUEGW1+1,X'60'                                          55000013
         XI    ROUEGW2+1,X'60'                                          55100013
         XI    ROUEGW3+1,X'60'                                          55200013
         XI    ROUSVWM+1,X'60'                                          55300013
         XI    ROUSXWM+1,X'60'                                          55400013
         XI    ROUFVWM+1,X'60'                                          55500013
         XI    ROUTHWM+1,X'60'                                          55600013
         B     ROUCSEWM            BRANCH TO CUTBACK SECTION            55700013
         SPACE 2                                                        55800013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          55900013
ROUISD   TM    ROUNOEQ8+1,X'40'    IS ROUTINE SET FOR DESCG             56000013
         B     ROUFDSQ             MODIFY BRANCHES IF NECESSARY         56100018
         SPACE 2                                                        56200013
*    EXECUTED MOVE INSTRUCTION                                          56300013
         SPACE 1                                                        56400013
ROULODMR LM    RD,0,0(RB)          LOAD NETWORK REGISTERS               56500013
         EJECT                                                          56600013
         SPACE 2                                                        56700013
         DS    0F                  ALIGNMENT TO WORD BOUNDARY           56800013
ROUSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   56900013
ROUANT8  B     IERDOM8             NETWORK ENTR ADDR FOR 6,7,8 WAY MRG  57000013
ROUANT4  B     IERDOM4             NETWORK ENTR ADDR FOR 3,4,5 WAY MRG  57100013
ROUANT2  B     IERDOM2             NETWORK ENTR ADDR FOR 2 WAY MERGE    57200013
ROUANT1  B     IERDOM1             NETWORK ENTR ADDR FOR 1 WAY MERGE    57300013
ROUIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   57400013
ROUACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    57500013
ROUSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       57600013
*    THE FOLLOWING 7 INSTR ARE BH OR BL DEPENDING ON THE INPUT SEQUENCE 57700013
ROUEGW1  BH    IERDOCK6            BRANCH TO COMPARE TIME 6 SET BY INIT 57800013
ROUEGW2  BH    IERDOCK7            BRANCH TO COMPARE ITEM 7 SET BY INIT 57900013
ROUEGW3  BH    IERDOCK3            BRANCH TO COMPARE ITEM 3 SET BY INIT 58000013
ROUSVWM  BH    ROUMOV6             BRANCH TO UPDATE RD TO RI SET BY INT 58100013
ROUSXWM  BH    IERDOCK5            BRANCH TO COMPARE ITEM 5 SET BY INIT 58200013
ROUFVWM  BH    IERDOCK4            BRANCH TO COMPARE ITEM 4 SET BY INIT 58300013
ROUTHWM  BH    ROUMOV2             BRANCH TO UPDATE RE TO RF SET BY INT 58400013
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     58500018
KROFOUR  DC    XL4'4'              CONSTANT OF FOUR                     58600018
KROEIGHT DC    XL4'8'              CONSTANT OF EIGHT                    58700018
KROTWO   DC    XL4'2'              CONSTANT OF TWO                      58800018
KROONE   DC    XL4'1'              CONSTANT OF ONE                      58860018
ROUTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         58930017
ROUCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      58960017
         SPACE 2                                                        59000013
         SPACE 2                                                        59100013
*    MODULE EXTERNAL REFERENCES ADDRESS CONSTANTS                       59200013
         EJECT                                                          59300013
*                                                                       59400013
* MODULE NAME ***IERRMC***                                              59500013
*                                                                       59600013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        59700013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                59800013
         SPACE 1                                                        59900013
DIERRMC  DSECT                                                          60000013
*                                                                       60100013
         COPY  RMCMAIN                                                  60200013
*                                                                       60300013
         SMPPI                                                          60400013
         END                                                            60500013
