         TITLE 'IERAOV - OS/360 SORT/MERGE - 360S-SM-023  03/22/65'     00100013
*MODULE NAME:*** IERAOV ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: PHASE 2 AND 3 ASSIGNMENT ROUTINE FOR A 1-8  00600013
*   WAY MERGE NETWORK RUNNING PROGRAM NAMED *** IERROV *** (SEE DSECT)  00700013
*   WITH A SINGLE CONTROL FIELD . THE FUNCTION OF THIS MODULE IS TO SET 00800013
*   THE NETWORK COMPARE INSTRUCTIONS WITH A LENGTH AND DISPLACEMENT     00900013
*   ATTRIBUTE  ,  TO SET THE NETWORKS PHASE-2/PHASE-3 SWITCHES ACCORD-  01000013
*   ING TO THE PHASE , TO DETERMINE THE AMOUNT OF CORE REQUIRED FOR     01100013
*   EXTRACT POSITIONS IF EXTRACTING AND TO SET THE NETWORK EXTRACT      01200013
*   SWITCHES ACCORDING TO WHETHER EXTRACTION IS TO BE DONE OR NOT.      01300013
         SPACE 2                                                        01400013
*USED AS A DSECT IN'  N/A                                               01500013
*                                                                       01600013
*MACROS USED'                                                           01700013
         SPACE 1                                                        01800013
*   SMPPI                                                               01900013
         SPACE 2                                                        02000013
*ENTRY POINTS:                                                          02100013
         SPACE 1                                                        02200013
*        ENTRY IERAOV              ENTRY FROM:                          02300013
*                                    CALLING SEQUENCE-                  02400013
*                                      LA   RP,VALUE                    02500013
*                                      BALR RO,RP                       02600013
         SPACE 2                                                        02700013
*INPUT: PPI FIELDS REFERENCED-                                          02800013
         SPACE 1                                                        02900013
*    PPINETM   PPIDDOL1 PPIX61    PPILEXFF   PPIMRGOP                   03000013
*    PPISW1    PPIAXERT PPILEXFD  PPIMRGMX   PPISPGN1                   03100013
         SPACE 2                                                        03200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03300013
         SPACE 1                                                        03400013
*        PPIBDSVA                                                       03500013
*        PPISPGN1                                                       03600013
         SPACE 2                                                        03700013
*EXTERNAL ROUTINES:                                                     03800013
         SPACE 1                                                        03900013
*        EXTRN IERROV                                                   04000013
*        EXTRN IERRMC                                                   04100013
*        EXTRN E61                                                      04200013
         SPACE 2                                                        04300013
*EXTERNAL PARAMETERS: NONE                                              04400013
         SPACE 1                                                        04500013
*EXITS: NORMAL                                                          04600013
         SPACE 1                                                        04700013
*        IERRC9                    CALLER ROUTINE FOR ASSIGNMENT RTN    04800013
*        E61                       EXTRACT EXIT                         04900013
         SPACE 2                                                        05000013
*EXITS: ERROR                                                           05100013
         SPACE 1                                                        05200013
*        IERRMC                    MESSAGE MODULE                       05300013
         SPACE 2                                                        05400013
*TABLES/WORK AREAS: N/A                                                 05500013
         SPACE 1                                                        05600013
         SPACE 2                                                        05700013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  05800013
         SPACE 2                                                        05900013
*NOTES: NONE                                                            06000013
         SPACE 1                                                        06100013
         SPACE 2                                                        06200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            06300013
         SPACE 1                                                        06400013
RA       EQU   0                   CONTENTS IN- N/A                     06500013
*                                  USE- UNUSED                          06600013
*                                  CONTENTS OUT- N/A                    06700013
RB       EQU   1                   CONTENTS IN- N/A                     06800013
*                                  USE- UNUSED                          06900013
*                                  CONTENTS OUT- N/A                    07000013
RC       EQU   2                   CONTENTS IN- N/A                     07100013
*                                  USE- GENERAL WORK REGISTER           07200013
*                                  CONTENTS OUT- N/A                    07300013
RD       EQU   3                   CONTENTS IN- N/A                     07400013
*                                  USE- GENERAL WORK REGISTER           07500013
*                                  CONTENTS OUT- N/A                    07600013
RE       EQU   4                   CONTENTS IN- N/A                     07700013
*                                  USE- GENERAL WORK REGISTER           07800013
*                                  CONTENTS OUT- N/A                    07900013
RF       EQU   5                   CONTENTS IN- N/A                     08000013
*                                  USE- UNUSED                          08100013
*                                  CONTENTS OUT- N/A                    08200013
RG       EQU   6                   CONTENTS IN- N/A                     08300013
*                                  USE- GENERAL WORK REGISTER           08400013
*                                  CONTENTS OUT- N/A                    08500013
RH       EQU   7                   CONTENTS IN- N/A                     08600013
*                                  USE- UNUSED                          08700013
*                                  CONTENTS OUT- N/A                    08800013
RI       EQU   8                   CONTENTS IN- N/A                     08900013
*                                  USE- UNUSED                          09000013
*                                  CONTENTS OUT- N/A                    09100013
RJ       EQU   9                   CONTENTS IN- N/A                     09200013
*                                  USE- UNUSED                          09300013
*                                  CONTENTS OUT- N/A                    09400013
RK       EQU   10                  CONTENTS IN- N/A                     09500013
*                                  USE- GENERAL WORK REGISTER           09600013
*                                  CONTENTS OUT- N/A                    09700013
RL       EQU   11                  CONTENTS IN- N/A                     09800013
*                                  USE- MODULE BASE ADDRESS REGISTER    09900013
*                                  CONTENTS OUT- ADDRESS OF THIS MODULE 10000013
RM       EQU   12                  CONTENTS IN- N/A                     10100013
*                                  USE-EXTRACT BASE ADDRESS REGISTER    10200013
*                                  CONTENTS OUT-EXTRACT ADDRESS         10300013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          10400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     10500013
*                                    AREA                               10600013
*                                  CONTENTS OUT- ADDRESS OF PPI         10700013
RO       EQU   14                  CONTENTS IN: RETURN ADDRESS TO SYST  10800013
*                                  USE- MERGE NETWORK BASE ADDRESS REG  10900013
*                                  CONTENTS OUT- RETURN ADDRESS TO SYST 11000013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  11100013
*                                  USE- MESSAGE MODULE BASE ADDRESS REG 11200013
*                                  CONTENTS OUT- MESSAGE MODULE ADDRESS 11300013
         SPACE 2                                                        11400013
*START OF MODULE CODE PROPER:                                           11500013
         SPACE 2                                                        11600013
IERAOV   CSECT                                                          11700013
         USING *,RL                                                     11800013
         USING IERRCA,RN                                                11900013
         USING DIERRMC,RP          MESSAGE MODULE                       12000013
*    MODULE ENTRY POINT                                                 12100013
IERMO1   LR    RL,RP                                                    12200013
         ST    RO,RKSAVC9                                               12300013
         L     RO,PPINET+4                                              12400013
         TM    PPISW1+2,X'04'      IS THIS PH 3                         12500013
         BO    *+8                 YES                                  12600013
         L     RO,PPINETM+4        NO                                   12700013
         USING AIERROV,RO                                               12800013
         TM    PPISW1+3,X'40'      EXTRACTING OR NOT                    12900013
         BC    8,AONNEXT           FALL THRU IF EXTRACTING              13000013
*    THIS FOLLOWING SECTION SETS THE EXTRACT SWITCHES TO YES IF NEEDED  13100013
*    THIS ALSO DETERMINES THE AMOUNT OF CORE REQD FOR THE EXTR POS      13200013
*    PPIMRGMX IS USED IF BALANCED TECHNIQUE                             13300013
*    PPIBDSVA MINUS ONE IS USED IF POLYPHASE TECHNIQUE                  13400013
*    PPIMRGOP IS USED IF A DISK SORT                                    13500013
         SPACE 1                                                        13600013
         SPACE 1                                                        13700013
         TM    PPISW1+2,X'02'      IS THIS A MERGE ONLY?                13800013
         BO    AOVNPOLY            BRANCH IF YES.                       13900013
         SPACE 1                                                        14000013
         TM    PPISW1+1,X'40'      IS THIS A TAPE SORT?                 14100013
         BC    8,AOVDISK           BRANCH IF A DISK SORT.               14200013
         TM    PPISW1,X'04'        CHECK FOR TECHNIQUE                  14300013
         BC    8,AOVNPOLY          FALL THRU IF POLYPHASE               14400013
         TM    PPISW1+2,X'04'      CHECK FOR WHICH PHASE                14500013
         BO    AOVNPOLY            BRANCH IF NOT PH 2                   14600013
         SR    RE,RE                                                    14700013
         IC    RE,PPIBDSVA         NUMBER OF ENTRIES IN TAPE TBL        14800013
         S     RE,KAOONE                                                14900013
         ST    RE,KAOTECH          STORE IN DETERMINE AMT CORE CONSTANT 15000013
         B     AOVDET              SET EXTRACT BRANCH IN ROV            15100018
         SPACE 2                                                        15200013
AOVDISK  MVC   KAOTECH+2(2),PPIMRGOP STORE MRG ORD IN AMT CORE CONST    15300013
         B     AOVDET              SET EXTRACT BRANCH IN ROV            15400018
         SPACE 2                                                        15500013
AOVNPOLY MVC   KAOTECH+2(2),PPIMRGMX  STORE MERGE ORD IN AMT CORE CON   15600013
AOVDET   XI    IERDOET+1,X'F0'                                          15700013
         LH    RD,PPILEXFF        LGH OF EXTR CTRL FLDS FROM PPI        15800013
         LA    RD,3(0,RD)          ALIGN EXTR CNTL FLDS UPWARD TO WORD  15900013
         N     RD,KAORNDUP         BOUNDARY IF THEY AREN'T ALREADY      16000013
         A     RD,KAOFOUR          ADD ACTUAL ADDR BYTES TO CNTRL FLD   16100013
         ST    RD,IERDOEXL         STORE IN MERGE NETWORK               16200013
         SR    RC,RC                                                    16300013
         L     RK,KAOTECH          MERGE ORDER FROM TECHNIQUE USED      16400013
         A     RK,KAOONE           MERGE ORDER + 1                      16500013
         MR    RC,RK               DETERM AMT CORE REQD FOR EXTR POS    16600013
         L     RG,PPISPGN1         PROGRAM GENERATOR ADDRESS            16700013
*    THIS SECTION CHECKS WHETHER OR NOT PPISPGN1 IS ON A FULL WORD      16800013
*    BOUNDARY  IF NOT IT IS ROUNDED DOWNWARD TO A FULL WORD BOUNDARY    16900013
         SPACE 1                                                        17000013
         TM    PPISPGN1+3,X'03'                                         17100013
         BC    8,AOVNRNDU          NO ALIGNMENT NECESSARY               17200018
         LA    RG,3(0,RG)                                               17300013
         N     RG,KAORNDUP                                              17400013
         S     RG,KAOFOUR                                               17500013
AOVNRNDU SR    RG,RD               UPDATE PROG GEN ADDR                 17600013
         ST    RG,PPISPGN1         STORE PROG GEN ADDR                  17700013
         ST    RG,IERDOAGE         BEG ADDR OF GEN EXTR POS IN MRG NTWK 17800013
         L     RM,PPIAXERT         SET BASE REG FOR EXTR RTN            17900013
         L     RC,PPIX61+4                                              18000013
         ST    RC,0(0,RM)          SET USER EXIT ADDR IN EXTR RTN       18100013
         MVC   PPIDD0L1+3(1),PPILEXFD+1   MOVING THE LENGTH AND DISPLAC 18200013
         MVC   PPIDD0L1(2),KAOFOUR+2      ATTRIBUTE FOR CMP INSTR SET   18300013
         SPACE 2                                                        18400013
*    THIS SECTION DETERMINES WHICH PHASE IS BEING EXECUTED AND SETS     18500013
*       THE APPROPRIATE SWITCHES                                        18600013
         SPACE 2                                                        18700013
AOVPHT   TM    PPISW1+2,X'04'      PHASE 2                              18800013
         BO    AOVPH3              FALL THRU IF PH 2                    18900013
         SPACE 1                                                        19000013
*    THIS SECTION SETS THE NETWORK COMPARE INSTRUCTIONS                 19100013
         SPACE 1                                                        19200013
AOVCIS   IC    RE,PPIDD0L1+3                                            19300013
         STC   RE,IERDOM8+1        LENGTH ATTRIBUTE                     19400013
         OC    IERDOM8+2(2),PPIDD0L1  DISPLACEMENT ATTRIBUTE            19500013
         OC    IERDOM8+4(2),PPIDD0L1                                    19600013
         STC   RE,IERDOM4+1                                             19700013
         OC    IERDOM4+2(2),PPIDD0L1                                    19800013
         OC    IERDOM4+4(2),PPIDD0L1                                    19900013
         STC   RE,IERDOM2+1                                             20000013
         OC    IERDOM2+2(2),PPIDD0L1                                    20100013
         OC    IERDOM2+4(2),PPIDD0L1                                    20200013
         STC   RE,IERDOSCK+1                                            20300013
         OC    IERDOSCK+2(2),PPIDD0L1                                   20400013
         OC    IERDOSCK+4(2),PPIDD0L1                                   20500013
         STC   RE,IERDOCK6+1                                            20600013
         OC    IERDOCK6+2(2),PPIDD0L1                                   20700013
         OC    IERDOCK6+4(2),PPIDD0L1                                   20800013
         STC   RE,IERDOCK5+1                                            20900013
         OC    IERDOCK5+2(2),PPIDD0L1                                   21000013
         OC    IERDOCK5+4(2),PPIDD0L1                                   21100013
         STC   RE,IERDOCK7+1                                            21200013
         OC    IERDOCK7+2(2),PPIDD0L1                                   21300013
         OC    IERDOCK7+4(2),PPIDD0L1                                   21400013
         STC   RE,IERDOCK3+1                                            21500013
         OC    IERDOCK3+2(2),PPIDD0L1                                   21600013
         OC    IERDOCK3+4(2),PPIDD0L1                                   21700013
         STC   RE,IERDOCK4+1                                            21800013
         OC    IERDOCK4+2(2),PPIDD0L1                                   21900013
         OC    IERDOCK4+4(2),PPIDD0L1                                   22000013
         STC   RE,IERDOICP+1                                            22100013
         OC    IERDOICP+2(2),PPIDD0L1                                   22200013
         OC    IERDOICP+4(2),PPIDD0L1                                   22300013
         SPACE 1                                                        22400013
*    EXIT TO NEXT ASSIGNMENT RTN                                        22500013
         L     RO,RKSAVC9                                               22600013
         BR    RO                  NEXT ASSIGNMENT RTN,                 22700018
         SPACE 2                                                        22800013
*    NOT EXTRACTING                                                     22900013
         SPACE 1                                                        23000013
AONNEXT  XI    IERXTRT1+1,X'F0'                                         23100013
         XI    IERXTRT2+1,X'F0'                                         23200013
         MVI   ROVMERG+1,X'F0'     MODIFY BRANCH CONDITION IN ROV       23250017
         XI    IERDOBWR+1,X'F0'                                         23300013
         XI    IERDOSET+1,X'F0'                                         23400013
         B     AOVPHT              BRANCH TO PHASE TEST                 23500013
         SPACE 2                                                        23600013
*    PHASE 3 SETTINGS                                                   23700013
         SPACE 1                                                        23800013
AOVPH3   XI    IERDOCPS+1,X'F0'                                         23900013
         XI    IERDOBB1+1,X'F0'                                         24000013
         XI    IERNEXTR+1,X'F0'                                         24100013
         B     AOVCIS              GO TO SET COMPARE INSTR              24200013
         EJECT                                                          24300013
         DS    0F                                                       24400013
KAOFOUR  DC    XL4'4'              CONSTANT OF FOUR                     24500018
KAOTECH  DC    XL4'0'              DETERMINE AMT CORE CONSTANT          24600013
KAOONE   DC    XL4'1'              CONSTANT OF ONE                      24700018
KAORNDUP DC    X'FFFFFFFC'         USED FOR BOUNDARY ALIGNMENT          24800018
RKSAVC9  DS    F                   ADDR. OF NEXT ASSIGNMENT RTN.        24900018
         EJECT                                                          25000013
AIERROV  DSECT                                                          25100013
IERDO1   B     ROVSINIT            READ PRIME ENTRY BR TO INITIALIZAT   25200013
         B     ROVCUTEN            READ + ALGORITHM ENTRY BR TO CUTBACK 25300013
         LM    RE,RK,ROVSVREG      DEBLOCK ENTRY - RESTORE REGISTERS    25400013
IERDOET  B     ROVNTENS            FALL THRU IF EXTRACTING  CHRT FQC1   25500013
         L     RC,ROVSVEXA         SET RC WITH EXTR POS ADDR            25600013
         ST    RD,0(0,RC)          STORE RCD ADDR IN EXTRACT POS ADDR   25700013
         LR    RA,RC                                                    25800013
         LR    RC,RD               SET FROM AND TO REG FOR EXTRACT RTN  25900013
         LR    RD,RA                                                    26000013
         BAL   RO,4(0,RM)          EXIT TO EXTRACT ROUTINE              26100013
         LM    RE,RK,ROVSVREG      RESTORE MERGE REGISTERS              26200013
ROVNTENS B     IERDOM8             NETWORK ENTR SWTCH SET BY CUTBACK    26300013
         SPACE 2                                                        26400013
*    THE FIND THE WINNER LOOP                                           26500013
         SPACE 1                                                        26600013
*    ENTRANCE FOR A 6, 7, 8 WAY MERGE                                   26700013
         SPACE 1                                                        26800013
IERDOM8  CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         26900013
*    THIS BRANCH INSTR IS BH BL DEPENDING ON THE INPUT SEQUENCE         27000013
ROVI4B   BH    IERDOCK6            IF HI/LO GO TO CMP ITEM 6 OR 5       27100013
*    ENTRANCE FOR A 3, 4, 5 WAY MERGE                                   27200013
IERDOM4  CLC   0(1,RD),0(RF)       COMPARE NEW ITEM WITH ITEM 2         27300013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      27400013
ROVI2B   BH    IERDOCK3            IF HI/LO GO TO CMP ITEM 3,4 OR UPDAT 27500013
*    ENTRANCE FOR A 2 WAY MERGE                                         27600013
IERDOM2  CLC   0(1,RD),0(RE)       COMPARE NEW ITEM WITH ITEM 1         27700013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      27800013
ROVI1B   BH    ROVMOV1             IF HI/LO NEW COLLATES AFTER ITEM 1   27900013
         SPACE 1                                                        28000013
*    ENTRANCE FOR A ONE WAY MERGE AND NEW ITEM IS THE WINNER            28100013
         SPACE 1                                                        28200013
ROV1WM   XI    ROVSCSW+1,X'F0'     SET SEQ CHK SWITCH TO YES            28300013
         SPACE 1                                                        28400013
*    THIS SECTION OF CODE COMMUNICATES THE NETWORKS WINNING RECORD      28500013
*       ADDRESS TO THE BLOCK ROUTINE AFTER TAKING APPROPRIATE ACTION    28600013
*       IF EXTRACTING AND IF THERE IS TO BE A SEQUENCE CHECK. THE PHASE 28700013
*    AND EXTRACT SWITCHES ARE SET BY THE ASSGN RTN                      28800013
         SPACE 1                                                        28900013
IERDOBWR BC    0,IERNEXTR          IF EXTRACTING FALL THRU              29000013
IERDOBB1 BC    0,ROVEPH3P          FALL THRU FOR PHASE 2                29100013
         ST    RD,ROVSVEXA         SAVE EXTRACT POS ADDR                29200013
         L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   29300013
ROVBBLK2 STM   RE,RK,ROVSVREG      SAVE NETWORK REGISTERS               29400013
ROVBBFIS BC    0,ROVISOUT          IF RCD FROM INT SEQ BRANCH           29500013
         SPACE 1                                                        29600013
         L     RL,PPIBLK2+4                                             29700013
         B     16(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        29800013
         SPACE 2                                                        29900013
ROVISOUT XI    ROVBBFIS+1,X'F0'    SET FALL THRU                        30000013
         L     RL,PPIBLK2+4                                             30100013
         B     12(0,RL)            EXIT TO BLK RTN WANT NEXT RCD        30200013
         SPACE 2                                                        30300013
*    PHASE 3 + MERGE ONLY PROCEDURE IF EXTRACTING                       30400013
         SPACE 1                                                        30500013
ROVEPH3P L     RC,ROVSQCWD         PUT EXTRACT POS ADDR IN RC           30600013
         ST    RC,ROVSVEXA                                              30700013
         ST    RD,ROVSQCWD         SAVE WIN EXTRACT POS ADDR FOR SEQ CK 30800013
*    SWITCH SET BY INITIAL SEQUENCING RTN TO BYPASS CHK FOR SEQ CHK     30900013
ROVFRSW1 BC    0,ROVFR1            FALL THRU IF NOT FIRST RECORD        31000013
         SPACE 1                                                        31100013
*    IF THE NEW RECORD IS THE WINNER,A SEQUENCE CHECK WILL BE PERFORMED 31200013
*       IF REQUESTED. IF THE NEW RECORD IS NOT THE WINNER,NO SEQUENCE   31300013
*       CHECK IS NECESSARY.                                             31400013
         SPACE 1                                                        31500013
ROVSCSW  BC    0,ROVNIW            FALL THRU IF NEW IS NOT WINNER       31600013
IERXTRT1 BC    0,ROVSVR            FALL THRU IF EXTRACTING              31700013
ROVSAA   L     RD,0(0,RD)          LOAD ACTUAL ADDRESS OF WINNING RCD   31800013
ROVSVR   STM   RE,RK,ROVSVREG      SAVE NETWORK REGISTERS               31900013
         L     RL,PPIBLK+4                                              32000013
         B     4(0,RL)             EXIT TO BLOCK RTN WANT NEXT RECORD   32100013
         SPACE 2                                                        32200013
ROVFR1   XI    ROVFRSW1+1,X'F0'    SET FIRST RCD SWITCH 1 TO FALL THRU  32300013
         B     ROVSAA              BRANCH TO SET ACTUAL ADDRESS         32400013
         SPACE 2                                                        32500013
ROVNIW   XI    ROVSCSW+1,X'F0'     SET ROVSCSW TO FALL THRU             32600013
         SPACE 1                                                        32700013
*    SEQUENCE CHECK OF CURRENT NETWORK WINNER AND PREVIOUS NETWORK      32800013
*       WINNER. CHECK DONE USING REG RD AND RC.                         32900013
*    THE USER COMMUNICATES A 0 OR 4 TO THE BLOCK RTN. THE BLOCK RTN.    33000013
*       SETS PPIDOUO IF A RECORD MODIFICATION EXIT IS ACTIVATED. IF NO  33100013
*       EXITS ARE ACTIVATED,THE BLOCK RTN TAKES NO ACTION CONCERNING    33200013
*       PPIDOUO.                                                        33300013
*    A 0 MEANS A SEQUENCE CHECK IS TO BE PERFORMED. A 4 MEANS NO        33400013
*       SEQUENCE CHECK. IF NO RCD MODIFICATION EXITS ARE ACTIVATED,     33500013
*       PPIDOUO IS 0.                                                   33600013
         SPACE 2                                                        33700013
         L     RB,PPIDOUO                                               33800013
         B     ROVCKISC(RB)        USER MOD.                            33900018
ROVCKISC B     IERDOSCK            SEQUENCE CHECK                       34000018
         SPACE 1                                                        34100013
*    NO SEQUENCE CHECK                                                  34200013
         SPACE 1                                                        34300013
IERXTRT2 BC    15,ROVSAA           IF EXTRACTING BRANCH TO ROVSAA       34400013
         B     ROVSVR              IF NOT EXTRACTING BRANCH TO ROVSVR   34500013
         SPACE 2                                                        34600013
IERDOSCK CLC   0(1,RD),0(RC)                                            34700013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   34800013
ROVSCB   BC    10,IERXTRT1         GET NEXT RECORD FROM BLOCK RTN.      34900018
*    OUT OF SEQUENCE ERROR                                              35000013
         L     RO,PPIRMC+4                                              35100013
         TM    PPISW1+2,X'02'      TEST FOR MERGE RUN                   35120017
         BO    ROVMERG             YES, BRANCH                          35140017
         SPACE                                                          35160017
         LM    RA,RB,MSGP3A04      OUT OF SEQUENCE MESSAGE              35200013
ROVSEQ   L     RP,PPIADSSC                                              35300017
         BAL   RO,12(0,RP)         SORT SYS CNTRL                       35400013
         L     RP,PPIADSSC                                              35500013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  35600013
         SPACE 2                                                        35700013
ROVMERG  BC    0,ROV100            FALL THRU IF EXTRACTING              35703017
         SPACE 1                                                        35706017
         L     RD,0(RD)            LOAD RECORD ADDRESS FROM EXTRACT     35709017
*                                    WORK AREA                          35712017
ROV100   SRL   RD,26               CONVERT DCB INDEX TO UNIT NUMBER     35715017
         CVD   RD,ROVCONV          CONVERT INDEX TO DECIMAL             35720017
         UNPK  ROVTEMP(2),ROVCONV+7(1)  UNPACK FOR PRINTING             35730017
         OI    ROVTEMP+1,X'F0'     SET SIGN POSITIVE                    35740017
         MVC   MSGP3MA8(2),ROVTEMP      MOVE UNIT NUMBER INTO MESSAGE   35750017
         LM    RA,RB,MSGP3A08      MERGE OUT OF SEQ MESSAGE             35760017
         B     ROVSEQ              GO PRINT MESSAGE                     35770017
         SPACE 2                                                        35780017
*    NOT EXTRACTING                                                     35800013
IERNEXTR B     ROVBBLK2            IF PHASE 2 BRANCH                    35900013
ROVFRSW2 BC    0,ROVFR2            IF FIRST RECORD BRANCH               36000013
         L     RC,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         36100013
         B     ROVSCSW             BRANCH TO CHK IF SEQ CHK REQUIRED    36200013
         SPACE 2                                                        36300013
ROVFR2   XI    ROVFRSW2+1,X'F0'    SET FIRST RCD SW 2 TO FALL THRU      36400013
         B     ROVSVR              BRANCH TO BLOCK RECORD               36500013
         SPACE 2                                                        36600013
IERDOCK6 CLC   0(1,RD),0(RJ)       COMPARE NEW ITEM WITH ITEM 6         36700013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      36800013
ROVI6B   BH    IERDOCK7            IF HI/LO GO TO CMP ITEM 7 OR UPDATE  36900013
IERDOCK5 CLC   0(1,RD),0(RI)       COMPARE NEW ITEM WITH ITEM 5         37000013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      37100013
ROVI5B   BH    ROVMOV5             IF HI/LO NEW COLLATES AFTER ITEM 5   37200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 4 + BEFORE ITEM 5      37300013
         SPACE 1                                                        37400013
ROVMOV4  LR    RC,RD                                                    37500013
         LR    RD,RE                                                    37600013
         LR    RE,RF                                                    37700013
         LR    RF,RG                                                    37800013
         LR    RG,RH                                                    37900013
         LR    RH,RC                                                    38000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              38100013
         SPACE 1                                                        38200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 5 + BEFORE ITEM 6      38300013
ROVMOV5  LR    RC,RD                                                    38400013
         LR    RD,RE                                                    38500013
         LR    RE,RF                                                    38600013
         LR    RF,RG                                                    38700013
         LR    RG,RH                                                    38800013
         LR    RH,RI                                                    38900013
         LR    RI,RC                                                    39000013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              39100013
         SPACE 2                                                        39200013
IERDOCK7 CLC   0(1,RD),0(RK)       COMPARE NEW ITEM WITH ITEM 7         39300013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      39400013
ROVI7B   BH    ROVMOV7             IF HI/LO NEW COLLATES AFTER ITEM 7   39500013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 6 + BEFORE ITEM 7      39600013
ROVMOV6  LR    RC,RD                                                    39700013
         LR    RD,RE                                                    39800013
         LR    RE,RF                                                    39900013
         LR    RF,RG                                                    40000013
         LR    RG,RH                                                    40100013
         LR    RH,RI                                                    40200013
         LR    RI,RJ                                                    40300013
         LR    RJ,RC                                                    40400013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              40500013
         SPACE 1                                                        40600013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 7                      40700013
ROVMOV7  LR    RC,RD                                                    40800013
ROVMMOV7 LR    RD,RE               UPDATE EXECUTED AFT CUTBACK OPERAT   40900013
         LR    RE,RF                                                    41000013
         LR    RF,RG                                                    41100013
         LR    RG,RH                                                    41200013
         LR    RH,RI                                                    41300013
         LR    RI,RJ                                                    41400013
         LR    RJ,RK                                                    41500013
         LR    RK,RC                                                    41600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              41700013
         SPACE 2                                                        41800013
IERDOCK3 CLC   0(1,RD),0(RG)       COMPARE NEW ITEM WITH ITEM 3         41900013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      42000013
ROVI3B   BH    ROVMOV3             INSERT INTO COLLATING SEQUENCE       42100018
         SPACE 1                                                        42200013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 2 + BEFORE ITEM 3      42300013
ROVMOV2  LR    RC,RD                                                    42400013
         LR    RD,RE                                                    42500013
         LR    RE,RF                                                    42600013
         LR    RF,RC                                                    42700013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              42800013
         SPACE 1                                                        42900013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 3 + BEFORE ITEM 4      43000013
ROVMOV3  LR    RC,RD                                                    43100013
         LR    RD,RE                                                    43200013
         LR    RE,RF                                                    43300013
         LR    RF,RG                                                    43400013
         LR    RG,RC                                                    43500013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              43600013
         SPACE 1                                                        43700013
*    UPDATING WHERE NEW ITEM COLLATES AFTER ITEM 1 + BEFORE ITEM 2      43800013
ROVMOV1  LR    RC,RD                                                    43900013
         LR    RD,RE                                                    44000013
         LR    RE,RC                                                    44100013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              44200013
         SPACE 1                                                        44300013
*    SPECIAL ITEM 4 COMPARE FOR 5 WAY MERGE                             44400013
IERDOCK4 CLC   0(1,RD),0(RH)       COMPARE NEW ITEM WITH ITEM 4         44500013
*    THIS BRANCH INSTR IS BH OR BL DEPENDING ON THE INPUT SEQUENCE      44600013
ROVSI4B  BH    ROVMOV4             IF HI/LO GO TO UPDATE                44700013
         B     IERDOCK3            GO TO COMPARE NEW ITEM WITH ITEM 3   44800013
         EJECT                                                          44900013
         SPACE 2                                                        45000013
*    THE NETWORK CUTBACK OPERATION                                      45100013
*    IT IS THAT CODE WHICH TAILORS THE NETWORK FOR THE MERGE ORDER      45200013
         SPACE 2                                                        45300013
*    THE INITIAL ENTRANCE TO THE CUTBACK SECTION                        45400013
         SPACE 1                                                        45500013
*    SET NETWORK FOR AN 8 WAY MERGE                                     45600013
         SPACE 1                                                        45700013
ROVCSEWM MVC   ROVI4B(4),ROVEGW1   SET BR TO CMP ITEM 6 AFT ITEM 4 CMP  45800013
         MVC   ROVI6B(4),ROVEGW2   SET BR TO CMP ITEM 7 AFT ITEM 6 CMP  45900013
         MVC   ROVI2B(4),ROVEGW3   SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  46000013
         MVC   ROVNTENS(4),ROVANT8 SET NETWORK ENTRANCE FOR 8 WAY MERGE 46100013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 46200013
         SPACE 1                                                        46300013
*    SET NETWORK FOR AN 7 WAY MERGE                                     46400013
         SPACE 1                                                        46500013
         MVC   ROVI6B(4),ROVSVWM   SET BR TO UPDATE AFTER ITEM 6 CMP    46600013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 46700013
         SPACE 1                                                        46800013
*    SET NETWORK FOR A 6 WAY MERGE                                      46900013
         SPACE 1                                                        47000013
         MVC   ROVI4B(4),ROVSXWM   SET BR TO CMP ITEM 5 AFT ITEM 4 CMP  47100013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 47200013
         SPACE 1                                                        47300013
*    SET NETWORK FOR A 5 WAY MERGE                                      47400013
         SPACE 1                                                        47500013
         MVC   ROVI2B(4),ROVFVWM   SET BR TO CMP ITEM 4 AFT ITEM 2 CMP  47600013
         MVC   ROVNTENS(4),ROVANT4 SET NETWORK ENTRANCE FOR A 5 WAY MRG 47700013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 47800013
         SPACE 1                                                        47900013
*    SET NETWORK FOR A 4 WAY MERGE                                      48000013
         SPACE 1                                                        48100013
         MVC   ROVI2B(4),ROVEGW3   SET BR TO CMP ITEM 3 AFT ITEM 2 CMP  48200013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 48300013
         SPACE 1                                                        48400013
*    SET NETWORK FOR A 3 WAY MERGE                                      48500013
         SPACE 1                                                        48600013
         MVC   ROVI2B(4),ROVTHWM   SET BR TO UPDATE AFTER ITEM 2 CMP    48700013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 48800013
         SPACE 1                                                        48900013
*    SET NETWORK FOR A 2 WAY MERGE                                      49000013
         SPACE 1                                                        49100013
         MVC   ROVNTENS(4),ROVANT2 SET NETWORK ENTRANCE FOR A 2 WAY MRG 49200013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 49300013
         SPACE 1                                                        49400013
*    SET NETWORK FOR A 1 WAY MERGE                                      49500013
         SPACE 1                                                        49600013
         MVC   ROVNTENS(4),ROVANT1 SET NETWORK ENTRANCE FOR A 1 WAY MRG 49700013
         BAL   RC,ROVFMUDS         SAVE ADDRESS OF NEXT CUTBACK SECTION 49800013
         SPACE 1                                                        49900013
*    A ZERO WAY MERGE                                                   50000013
         SPACE 1                                                        50100013
*    IF PHASE 2 EXIT TO THE BLOCK RTN (RELEASE CURRENT BLK TO WRITE)    50200013
*    IF PHASE 3 OR MERGE ONLY EXIT TO THE BLOCK RTN (END OF JOB)        50300013
         SPACE 1                                                        50400013
IERDOCPS BC    0,ROVCPH3           FALL THRU FOR PHASE 2                50500013
         L     RL,PPIBLK2+4                                             50600013
         BR    RL                  PH2 BLOCK/DEBLOCK                    50700018
         SPACE 2                                                        50800013
ROVCPH3  L     RL,PPIBLK+4                                              50900013
         BR    RL                  BLOCK RTN.                           51000018
         SPACE 2                                                        51100013
*    THIS IS ENTRY TO THE CUTBACK RTN FROM READ RTN + THE ALGORITHM     51200013
         SPACE 1                                                        51300013
ROVCUTEN LM    RE,RK,ROVSVREG      RESTORE NETWORK REGISTERS            51400013
         L     RC,ROVSVCBA         SET APPROPRIATE CUTBACK SECTION ADDR 51500013
         BR    RC                  CUTBACK                              51600018
         EJECT                                                          51700013
*    THIS SECTION OF CODE ENTERED UPON COMPLETION OF A CUTBACK OPERTION 51800013
*    THIS SECTION INITIALLY CHECKS FOR THE NETWORK BEING SET FOR THE    51900013
*    MERGE ORDER. SUBSEQUENTLY A BRANCH TO UPDATE IS EXECUTED           52000013
         SPACE 1                                                        52100013
ROVFMUDS BC    0,ROVFDMO           SET TO BRANCH BY INITIALIZATION RTN  52200013
*    FALL THRU FOR UPDATING NETWORK AFTER A CUTBACK OPERATION           52300013
         SPACE 1                                                        52400013
         ST    RC,ROVSVCBA         SAVE NEXT CUTBACK ADDRESS            52500013
         B     ROVMMOV7            MODIFIED MOVE AFTER ITEM 7           52600013
         SPACE 2                                                        52700013
ROVFDMO  L     RF,ROVIDMO          SET TO 8 BY INITIALIZATION RTN       52800013
         C     RF,ROVACMO          SET TO ACTUAL MERGE ORDER BY INITIAL 52900013
         BE    ROVSFTTU            SET FALL THRU TO UPDATE              53000013
         S     RF,KROONE           CONSTANT OF ONE                      53100013
         ST    RF,ROVIDMO                                               53200013
         BR    RC                  BRANCH BACK TO CUTBACK RTN           53300013
         SPACE 2                                                        53400013
ROVSFTTU XI    ROVFMUDS+1,X'F0'    SET ROVFMUDS BRANCH TO FALL THRU     53500013
         ST    RC,ROVSVCBA         SAVE ADDRESS OF NEXT CUTBACK CODE    53600013
         B     ROVINTSQ            EXIT TO INIT SEQ THE RECORDS         53700013
         EJECT                                                          53800013
*    INITIAL SEQUENCING OF RECORDS SECTION EXECUTED AT THE BEGINNING OF 53900013
*    EACH MERGE OPERATION.                                              54000013
*    A RELATIVE POSITION METHOD IS EMPLOYED FOR THE SEQUENCING.         54100013
*    THIS METHOD CAN BE DESCRIBED AS COMPARING ONE ITEM OF A LIST WITH  54200013
*       THE REMAINDER OF THE ITEMS AND,THEREBY,DETERMINING ITS PROPER   54300013
*       POSITION IN THE LIST. TO ACCOMPLISH THIS,A TWO AREA SYSTEM IN   54400013
*       PPI IS UTILIZED.                                                54500013
         SPACE 2                                                        54600013
ROVINTSQ SR    RI,RI               INDEX USED TO GET ITEMS TO BE SEQD   54700013
         L     RB,ROVACMO          DETERMINES WHEN ALL ITEMS ARE SEQD   54800013
         LA    RG,PPIPDWA          BEGINNING ADDR OF RCD ADDR IN PPI    54900013
ROVRETRN L     RF,ROVACMO          USED TO CHECK WHEN AN ITEM HAS BEEN  55000013
*                                  CHECKED WITH ALL THE OTHER ITEMS     55100013
         L     RD,0(RI,RG)         THE ITEM WE ARE POSITIONING          55200013
         LA    RE,PPIPSVA-4        ADDR WHERE ITEM IS STORED AFT POS FD 55300013
         SR    RH,RH               INDEX USED TO CMP ALL OTHER ITEMS    55400013
ROVANOTH L     RC,0(RH,RG)         ADDR OF ITEMS CMP TO ITEM IN RC      55500013
IERDOICP CLC   0(1,RD),0(RC)                                            55600013
*    THIS BRANCH INSTR IS BC 10 OR 12 DEPENDING ON THE INPUT SEQUENCE   55700013
ROVISNLH BC    10,ROVHIEQ          HI/LO AND EQUAL CASE TREATED SAME    55800013
ROVDECR  LA    RH,4(0,RH)                                               55900013
         BCT   RF,ROVANOTH         CHECK NEXT ITEM                      56000018
ROVCHEK  CLC   0(4,RE),KROZERO     STORAGE AREA OF ITEMS IS INITIALLY   56100013
*                                  ZERO CHECKED TO INSURE THAT ANOTHER  56200013
*                                  ITEM DOES NOT OCCUPY THIS POSITION   56300013
         BE    ROVINSRT            IF ZERO STORE ITEM                   56400013
         S     RE,KROFOUR          IF EQUAL CHECK NEXT LOWER POSITION   56500013
         B     ROVCHEK             CHECK NEXT POSITION                  56600018
ROVINSRT ST    RD,0(0,RE)          STORE POSITIONED ITEM                56700013
         BCT   RB,ROVINCR          IF NOT DONE GET NEXT ITEM TO POSITIN 56800013
         B     ROVOUTIS            BRANCH TO SET NETWORK REG            56900013
         SPACE 2                                                        57000013
ROVHIEQ  LA    RE,4(0,RE)                                               57100013
         B     ROVDECR             CHECK NEXT ITEM                      57200018
         SPACE 2                                                        57300013
ROVINCR  LA    RI,4(0,RI)                                               57400013
         B     ROVRETRN            BRANCH FOR LAST CHECK                57500018
         SPACE 2                                                        57600013
*    THE END OF THE INITIAL SEQUENCING SECTION                          57700013
         SPACE 2                                                        57800013
*    MOVE ADDRESSES OF SEQUENCED ITEMS TO MERGE NETWORK REGISTERS       57900013
ROVOUTIS LA    RB,PPIPSVA          ADDR OF FIRST SEQUENCED ITEM         58000013
         L     RC,ROVACMO          MERGE ORDER                          58100013
         A     RC,KROTWO                                                58200013
         EX    RC,ROVLODMR         EXECUTE LOAD REGISTERS INSTR         58300013
         XI    ROVFRSW1+1,X'F0'    SETTING FIRST RCD SWITCHES TO BRANCH 58400013
         XI    ROVFRSW2+1,X'F0'                                         58500013
         XI    ROVBBFIS+1,X'F0'    SET INT SEQ BRANCH FOR BLK INTERFACE 58600013
         B     IERDOBWR            BRANCH TO OUTPUT WINNER              58700013
         SPACE 2                                                        58800013
         EJECT                                                          58900013
*    THIS IS SELF INITIALIZATION SECTION PERFORMED AT THE BEGINNING     59000013
*    OF EACH PASS OR SUB PASS.                                          59100013
         SPACE 2                                                        59200013
ROVSINIT MVC   ROVIDMO(4),KROEIGHT SET MAX MERGE ORDER TO 8             59300013
         LH    RE,PPIMRGMX         SET ACTUAL MRG ORD FROM PPI          59400013
         ST    RE,ROVACMO                                               59500013
         SR    RE,RE                                                    59600013
         ST    RE,PPIPSVA                                               59700013
         MVC   PPIPSVA+4(60),PPIPSVA    ZERO INT SEQ STORE AREA         59800013
         XI    ROVFMUDS+1,X'F0'    SET ROVFMUDS TO BRANCH               59900013
         TM    PPISW1+3,X'10'      IS INPUT SEQ ASDNG OR DESCG BIT 28   60000013
         BC    1,ROVISD            FALL THRU IF INPUT SEQ IS ASDNG      60100013
         TM    ROVI4B+1,X'20'      IS ROUTINE SET FOR ASDNG             60200013
ROVFDSQ  BC    1,IERDOSET          IF THE ROUTINE IS SET FOR THE INPUT  60300013
         XI    ROVI4B+1,X'60'      SEQUENCE, BRANCH TO EXTRACT TEST.IF  60400013
         XI    ROVI2B+1,X'60'      THE ROUTINE IS NOT SET FOR THE INPUT 60500013
         XI    ROVI1B+1,X'60'      CHANGE THE MASK OF THE BRANCH ON     60600013
         XI    ROVSCB+1,X'60'      CONDITION INSTR.                     60700013
         XI    ROVI6B+1,X'60'                                           60800013
         XI    ROVI5B+1,X'60'                                           60900013
         XI    ROVI7B+1,X'60'                                           61000013
         XI    ROVI3B+1,X'60'                                           61100013
         XI    ROVSI4B+1,X'60'                                          61200013
         XI    ROVISNLH+1,X'60'                                         61300013
         XI    ROVEGW1+1,X'60'                                          61400013
         XI    ROVEGW2+1,X'60'                                          61500013
         XI    ROVEGW3+1,X'60'                                          61600013
         XI    ROVSVWM+1,X'60'                                          61700013
         XI    ROVSXWM+1,X'60'                                          61800013
         XI    ROVFVWM+1,X'60'                                          61900013
         XI    ROVTHWM+1,X'60'                                          62000013
IERDOSET BC    0,ROVCSEWM          FALL THRU IF EXTRACTING              62100013
*                                  IF NOT EXTRACTING,GO TO CUTBACK CODE 62200013
         LM    RD,RE,IERDOAGE      ADDR + LGH OF EXTRACT INFO           62300013
         LA    RK,PPIPDWA          ADDR OF RCDS IN PPI                  62400013
         L     RG,KROONE           INDEX TO DETERMINE WHEN DONE         62500013
         LR    RI,RG                                                    62600013
         L     RJ,ROVACMO                                               62700013
ROVRLD   L     RC,0(0,RK)          SET FROM ADDR FOR EXTR RTN           62800013
         STM   RE,RK,ROVSVREG      SAVE MERGE REG                       62900013
         BAL   RO,4(0,RM)          EXTRACT THIS RECORD                  63000013
         LM    RE,RK,ROVSVREG      RESTORE MERGE REG                    63100013
         ST    RC,0(0,RD)          STORE ADDR OF RCD AT EXTR POS        63200013
         ST    RD,0(0,RK)          STORE EXTR POS ADDR IN PPIPDWA AREA  63300013
         AR    RD,RE               INCR EXTR POS LENGTH                 63400013
         A     RK,KROFOUR          INCR TO NEXT RCD ADDR IN PPIPDWA     63500013
         BXLE  RG,RI,ROVRLD        ARE WE DONE EXTR THE RCDS IN PPIPDWA 63600013
         ST    RD,ROVSQCWD         SAVE NEXT EXTR POS ADDR              63700013
         B     ROVCSEWM            BRANCH TO CUTBACK SECTION            63800013
         SPACE 2                                                        63900013
*    THE INPUT SEQUENCE IS IN DESCENDING ORDER                          64000013
         SPACE 1                                                        64100013
ROVISD   TM    ROVI4B+1,X'40'      IS ROUTINE SET FOR DESCG             64200013
         B     ROVFDSQ             MODIFY BRANCH INSTURCTIONS           64300018
         SPACE 2                                                        64400013
*    EXECUTED MOVE INSTRUCTION                                          64500013
         SPACE 1                                                        64600013
ROVLODMR LM    RD,0,0(RB)          LOAD NETWORK REGISTERS               64700013
         EJECT                                                          64800013
         DS    0F                  ALIGNMENT                            64900013
ROVSVREG DS    7F                  REGISTER SAVE AREA FOR INTERFACING   65000013
ROVSQCWD DS    1F                  WORD TO SAVE ADDRESS OF EXTRACT POS  65100013
*                                  OF RCD FOR SEQUENCE CHECK            65200013
IERDOAGE DS    1F                  BEGIN ADDR FOR GENERATED EXTRACT POS 65300013
IERDOEXL DS    1F                  LGH OF EXTR CTRL FLDS + 4 ADDR BYTES 65400013
         SPACE 1                                                        65500013
*    THE FOLLOWING 7 INSTR ARE BH OR BL DEPENDING ON THE INPUT SEQUENCE 65600013
         SPACE 1                                                        65700013
ROVEGW1  BH    IERDOCK6            BRANCH TO COMPARE ITEM 6 SET BY INIT 65800013
ROVEGW2  BH    IERDOCK7            BRANCH TO COMPARE ITEM 7 SET BY INIT 65900013
ROVEGW3  BH    IERDOCK3            BRANCH TO COMPARE ITEM 3 SET BY INIT 66000013
ROVSVWM  BH    ROVMOV6             BRANCH TO UPDATE RD TO RI SET BY INT 66100013
ROVSXWM  BH    IERDOCK5            BRANCH TO COMPARE ITEM 5 SET BY INIT 66200013
ROVFVWM  BH    IERDOCK4            BRANCH TO COMPARE ITEM 4 SET BY INIT 66300013
ROVTHWM  BH    ROVMOV2             BRANCH TO UPDATE RE TO RF SET BY INT 66400013
         SPACE 2                                                        66500013
ROVANT8  B     IERDOM8             NETWORK ENTR ADDR FOR 6,7,8 WAY MRG  66600013
ROVANT4  B     IERDOM4             NETWORK ENTR ADDR FOR 3,4,5 WAY MRG  66700013
ROVANT2  B     IERDOM2             NETWORK ENTR ADDR FOR 2 WAY MERGE    66800013
ROVANT1  B     ROV1WM              NETWORK ENTR ADDR FOR 1 WAY MERGE    66900013
ROVSVCBA DS    1F                  SAVE NEXT CUTBACK ADDRESS WORD       67000013
ROVIDMO  DS    1F                  MAXIMUM MERGE ORDER SET BY INITIAL   67100013
ROVACMO  DS    1F                  ACTUAL MERGE ORDER SET BY INITIAL    67200013
ROVSVEXA DS    1F                  EXT POS ADDR SAVE AREA               67300013
KROONE   DC    XL4'1'              CONSTANT OF ONE                      67400018
KROZERO  DC    XL4'0'              CONSTANT OF ZERO                     67500018
KROTWO   DC    XL4'2'              CONSTANT OF TWO                      67600018
KROFOUR  DC    XL4'4'              CONSTANT FOUR                        67700018
KROEIGHT DC    XL4'8'              CONSTANT OF EIGHT                    67760018
ROVTEMP  DC    H'0'                TEMP STORAGE FOR UNIT NUMBER         67830017
ROVCONV  DC    D'0'                CONVERSION AREA FOR UNIT NUMBER      67860017
         EJECT                                                          67900013
*                                                                       68000013
* MODULE NAME ***IERRMC***                                              68100013
*                                                                       68200013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        68300013
* PHASE 3 OR MERGE ONLY RUNNING PROGRAM.                                68400013
         SPACE 1                                                        68500013
DIERRMC  DSECT                                                          68600013
*                                                                       68700013
       COPY  RMCMAIN                                                    68800013
*                                                                       68900013
         SMPPI                                                          69000013
         END                                                            69100013
