         TITLE 'IERDM4 - OS/360 SORT/MERGE - 360S-SM023 04/26/66'       00700013
*MODULE NAME *** IERDM4;***                                             01400013
         SPACE 2                                                        02100013
*STATUS;CHANGE LEVEL 000                                                02800013
         SPACE 2                                                        03500013
*MODULE FUNCTION/OPERATION; THIS IS A CONVERSION ROUTINE TO CONVERT     04200013
*   MACHINE LANGUAGE ADDRESSES TO EITHER HEX OR DECIMAL FORMATS         04900013
*   FOR PRINTING DIAGNOSTIC MESSAGES. A BRANCH LIST IS USED TO          05600013
*   DETERMINE IF A HEX OR A DECIMAL CONVERSION IS PERFORMED. THE        06300013
*   CALLING MODULE SHOULD INCLUDE THE FOLLOWING CODE:                   07000013
*                                                                       07700013
*                   L    RA,NO. TO BE CONVERTED                         08400013
*                   L    RP,PPICONV+4   ADDRESS OF CONVERSION ROUTINE   09100013
*   THEN ONE OF THE FOLLOWING BRANCH STATEMENTS:                        09800013
*                                                                       10500013
*                   B    0(0,RP)    FOR DECIMAL CONVERSION              11200013
*                   B    4(0,RP)    FOR HEX CONVERSION.                 11900013
*   THE ADDRESS CONTAINING THE CONVERTED NUMBER WILL BE RETURNED IN     12600013
*   REGISTER 1. THE NUMBER WILL BE A DOUBLE WORD.                       13300013
         SPACE 2                                                        14000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT.               14700013
*   N/A                                                                 15400013
         SPACE 2                                                        16100013
*LIST OF MACROS USED BY MODULE;                                         16800013
*   N/A                                                                 17500013
         SPACE 2                                                        18200013
*ENTRY POINTS; N/A                                                      18900013
*                             CALLING SEQUENCE                          19600013
*                                  L  RA,NO. TO BE CONVERTED            20300013
*                                  L  RP,PPICONV+4  ADDR OF CONV. RTN.  21000013
*                           EITHER B  0(0,RP) FOR DECIMAL CONVERSION    21700013
*                             OR   B  4(0,RP) FOR HEX CONVERSION        22400013
         SPACE 2                                                        23100013
*INPUT; - PPI FIELDS REFERENCED - N/A                                   23800013
         SPACE 2                                                        24500013
*OUTPUT; - PPI FIELDS INITIALIZED OR ALTERED -  N/A                     25200013
         SPACE 2                                                        25900013
*EXTERNAL ROUTINES; N/A                                                 26600013
         SPACE 2                                                        27300013
*EXTERNAL PARAMETERS:                                                   28000013
         SPACE                                                          28700013
*   THE NUMBER TO BE CONVERTED IS PASSED IN REGISTER 0 (RA).            29400013
*   THE ADDRESS OF THE CONVERTED NUMBER IS RETURNED TO THE CALLING      30100013
*   ROUTINE IN REGISTER 1 (RA). IT IS A DOUBLE WORD.                    30800013
         SPACE 2                                                        31500013
*EXITS-NORMAL:                                                          32200013
         SPACE                                                          32900013
*   STANDARD RETURN TO CALLING ROUTINE VIA REGISTER 14.                 33600013
         SPACE 2                                                        34300013
*EXITS-ERROR: N/A                                                       35000013
         SPACE 2                                                        35700013
*TABLES/WORK AREAS: N/A                                                 36400013
         SPACE 2                                                        37100013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  37800013
         SPACE 2                                                        38500013
*NOTES: THIS MODULE IS LOADED INTO CORE WHEN THE GENERAL DIAGNOSTIC     39200013
*   SWITCH IS SET.                                                      39900013
         EJECT                                                          40600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            41300013
         SPACE                                                          42000013
RA       EQU   0                   CONTENTS IN - NUMBER TO BE CONVERTED 42700013
*                                  USED - PARAMETER PASSING             43400013
*                                  CONTENTS OUT - N/A                   44100013
RB       EQU   1                   CONTENTS IN - N/A                    44800013
*                                  USED - PARAMETER PASSING             45500013
*                                  CONTENTS OUT - ADDRESS OF DOUBLE     46200013
*                                  WORD CONTAINING CONVERTED NUMBER     46900013
RC       EQU   2                   CONTENTS IN - N/A                    47600013
*                                  USED - N/A                           48300013
*                                  CONTENTS OUT - N/A                   49000013
RD       EQU   3                   CONTENTS IN - N/A                    49700013
*                                  USED - N/A                           50400013
*                                  CONTENTS OUT - N/A                   51100013
RE       EQU   4                   CONTENTS IN - N/A                    51800013
*                                  USED - N/A                           52500013
*                                  CONTENTS OUT - N/A                   53200013
RF       EQU   5                   CONTENTS IN - N/A                    53900013
*                                  USED - N/A                           54600013
*                                  CONTENTS OUT - N/A                   55300013
RG       EQU   6                   CONTENTS IN - N/A                    56000013
*                                  USED - N/A                           56700013
*                                  CONTENTS OUT - N/A                   57400013
RH       EQU   7                   CONTENTS IN - N/A                    58100013
*                                  USED - N/A                           58800013
*                                  CONTENTS OUT - N/A                   59500013
RI       EQU   8                   CONTENTS IN - N/A                    60200013
*                                  USED - N/A                           60900013
*                                  CONTENTS OUT - N/A                   61600013
RJ       EQU   9                   CONTENTS IN - N/A                    62300013
*                                  USED - N/A                           63000013
*                                  CONTENTS OUT - N/A                   63700013
RK       EQU   10                  CONTENTS IN - N/A                    64400013
*                                  USED - N/A                           65100013
*                                  CONTENTS OUT -N/A                    65800013
RL       EQU   11                  CONTENTS IN - N/A                    66500013
*                                  USED - N/A                           67200013
*                                  CONTENTS OUT - N/A                   67900013
RM       EQU   12                  CONTENTS IN - N/A                    68600013
*                                  USED - N/A                           69300013
*                                  CONTENTS OUT - N/A                   70000013
RN       EQU   13                  CONTENTS IN - N/A                    70700013
*                                  USED - N/A                           71400013
*                                  CONTENTS OUT - N/A                   72100013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS         72800013
*                                  USED - PARAMETER PASSING             73500013
*                                  CONTENTS OUT - RETURN ADDRESS        74200013
RP       EQU   15                  CONTENTS IN - ADDRESS OF THIS MODULE 74900013
*                                  USED - MODULE BASE REGISTER          75600013
*                                  CONTENTS OUT - N/A                   76300013
         SPACE 2                                                        77000013
*START OF MODULE CODE PROPER                                            77700013
         SPACE 2                                                        78400013
IERDM4   CSECT                                                          79100013
         USING *,RP                SPECIFIES REG 15 AS BASE             79800013
         B     DM4DEC00            BRANCH TO DECIMAL CONVERT IF TAKEN   80500013
*START OF HEX CONVERSION ROUTINE                                        81200013
         ST    RA,DM4HEX           STORE NUMBER TO BE CONVERTED         81900013
         UNPK  DM4TEMP(9),DM4HEX+1(4)        UNPACK NUMBER              82600013
         NC    DM4TEMP(8),DM4MASK                                       83300013
         TR    DM4TEMP(8),DM4HTBL                                       84000013
         B     DM4RTN              GO TO RETURN CODE                    84700013
         EJECT                                                          85400013
*START OF DECIMAL CONVERSION ROUTINE                                    86100013
DM4DEC00 CVD   RA,DM4DEWK          CONVERT NUMBER TO PACKED DECIMAL     86800013
         UNPK  DM4TEMP(8),DM4DEWK+3(5)       UNPACK NUMBER              87500013
         OI    DM4TEMP+7,X'F0'     SET SIGN POSITIVE                    88200013
DM4RTN   LA    RB,DM4TEMP          LOAD ADDRESS OF NUMBER IN REG 1      88900013
         BR    RO                  RETURN TO CALLING ROUTINE            89600013
         EJECT                                                          90300013
*LIST OF CONSTANTS USING BY MODULE                                      91000013
         DS    D'0'                ALIGN ON DOUBLE WORD BOUNDRY         91700013
DM4TEMP  DC    2F'0'               STORAGE FOR CONVERTED NUMBER         92400013
DM4DEWK  DC    2F'0'               WORK AREA FOR DECIMAL CONVERSION     93100013
DM4HTBL  DC    C'0123456789ABCDEF'      TRANSLATE TABLE FOR HEX CONVERT 93800013
DM4HEX   DC    F'0'                WORK AREA FOR HEX CONVERSION         94500013
         DS    D'0'                                                     95200013
DM4MASK  DC    X'0F0F0F0F0F0F0F0F'                                      95900013
         SPACE                                                          96600013
         END                                                            97300013
