         TITLE 'IERRBA - OS/360 SORT/MERGE - 360S-SM023 04/21/66'       00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRBA ***                                             00600013
         SPACE 2                                                        00800013
*MODULE FUNCTION:  OSCILLATING/2314 BLOCK ROUTINE                       01000013
*   THIS MODULE IS USED BY OSCL. OR 2314 SORT FOR VARIABLE LENGTH RCDS. 01200013
*   THE FUNCTION OF THIS MODULE IS TO BLOCK VARIABLE LENGTH RECORDS IN  01400013
*   THE OUTPUT BUFFER(S). TO DO THIS IT LINKS TO THE VARIABLE MOVE      01600013
*   ROUTINE, IERRBF, WHICH MOVES THE RECORD FROM RSA(BINS) TO AN OUTPUT 01800013
*   TO THE DEBLOCK MODULE. NOW THAT THE BIN(S) IN RSA HAVE BEEN FREED   02000013
*   THIS MODULE UPDATES THE NEXT AVAILABLE RSA BIN POINTER AND COUNTER  02200013
*   LOCATED IN PPI.                                                     02400013
         SPACE 1                                                        02600013
*   INFORMATION COMMUNICATED BETWEEN MODULES ARE AS FOLLOWS:            02800013
         SPACE 1                                                        03000013
*   NETWORK TO BLOCK- RD CONTAINS WINNER ADDRESS IN RSA                 03200013
*   BLOCK TO MOVE- RF HAS ADDRESS OF RCD IN RSA,RB HAS ADDRESS IN OUT-  03400013
*     PUT BUFFER TO MOVE THE RECORD, RB HAS A 4 TO DENOTE BLOCK RTN.    03600013
*   MOVE TO BLOCK- RB HAS NUMBER OF BINS FREED,RF POINTS TO CHAIN ADDR  03800013
*     OF LAST BIN MOVED.                                                04000013
*   BLOCK TO WRITE- RB HAS OUTPUT BLOCK COUNT, RC HAS ADDR OF OUTPUT    04200013
*     BUFFER, RE HAS 4 FOR NORMAL EOS OTHERWISE HAS A ZERO.             04400013
*   WRITE TO BLOCK- RC HAS ENDING ADDRESS OF OUTPUT BLOCK+1.            04600013
         SPACE 2                                                        04800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05000013
         SPACE 1                                                        05200013
*   IERABA                                                              05400013
         SPACE 2                                                        05600013
*LIST OF MACROS USED BY MODULE:                                         05800013
         SPACE 1                                                        06000013
*   SMPPI                                                               06200013
         SPACE 2                                                        06400013
*ENTRY POINTS:                                                          06600013
         SPACE 1                                                        06800013
*   NETWORK TO BLOCK               ENTRY FROM NETWORK.                  07000013
*                                    CALLING SEQUENCE-                  07200013
*                                      L   RL,PPIBLK+4                  07400013
*                                      B   0(RL)       LAST RCD         07600013
*                                      B   4(RL)       EOS              07800013
*                                      B    12(RL)     NORMAL           08000013
*   MOVE RTN TO BLOCK              ENTRY FROM MOVE RTN.                 08200013
*                                    CALLING SEQUENCE                   08400013
*                                      BR   RO         RETURN           08600013
*   WRITE TO BLOCK                 ENTRY FROM WRITE.                    08800013
*                                    CALLING SEQUENCE.                  09000013
*                                      L   RL,PPIBLK+4                  09200013
*                                      B   8(0,RL)     NORMAL           09400013
         SPACE 2                                                        09600013
*INPUT: - PPI FIELDS REFERENCED                                         09800013
         SPACE 1                                                        10000013
*   PPIBDSVA   PPILEXFF                                                 10200013
*   PPIDEB     PPIWRT                                                   10400013
*   PPILAB07    PPIDEPHO                                                10600013
*   PPIUNTCT                                                            10800013
         SPACE 1                                                        11000013
*   INFO IS NEEDED FOR LINKAGE TO OTHER MODULES AND FOR CALCULATIIONS   11200013
         SPACE 2                                                        11400013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            11600013
         SPACE 1                                                        11800013
*   PPIBDSVA                                                            12000013
*   UNIT COUNTERS IN GENERATED CORE ARE UPDATED FOR EACH RECORD BLOCKED 12200013
*   AVAILABLE BIN POINTER WITHIN THIS AREA.                             12400013
         SPACE 2                                                        12600013
*EXTERNAL ROUTINES:                                                     12800013
         SPACE 1                                                        13000013
*        EXTRN IERRBF              ADDR ALSO WITHIN PPIBDSVA. THIS RTN  13200013
*                                    MOVES THE RCD FORM RSA TO AN       13400013
*                                    OUTPUT BUFFER                      13600013
         SPACE 2                                                        13800013
*EXTERNAL PARAMETERS:                                                   14000013
         SPACE 1                                                        14200013
*   NONE                                                                14400013
         SPACE 2                                                        14600013
*EXITS-NORMAL:                                                          14800013
         SPACE 1                                                        15000013
*   BLOCK TO WRITE                 EXIT TO WRITE.                       15200013
*                                    CALLING SEQUENCE-                  15400013
*                                      L   RL,PPIWRT+4                  15600013
*                                      B   4(RL)       ANY EOS          15800013
*                                      B   8(RL)       NORMAL WRITE     16000013
*   BLOCK TO DEBLOCK               EXIT TO DEBLOCK                      16200013
*                                    CALLING SEQUENCE                   16400013
*                                      L   RL,PPIDEB+4                  16600013
*                                      B   8(RL)                        16800013
*   BLOCK TO MOVE RTN              EXIT TO IERABF                       17000013
*                                    CALLING SEQUENCE                   17200013
*                                      L   RP,PPIBDSVA+12               17400013
*                                      BALR RO,RP                       17600013
         SPACE 2                                                        17800013
*EXITS-ERROR                                                            18000013
         SPACE 1                                                        18200013
*   NONE                                                                18400013
         SPACE 2                                                        18600013
*TABLES/WORK AREAS:                                                     18800013
         SPACE 1                                                        19000013
*   WBLKCCNT-KEEPS TRACK OF THE NUMBER OF BYTES IN AN OUTPUT BUFFER     19200013
*   WINNER-ADDR OF THE NEXT RECORD IN RSA TO BE BLOCKED                 19400013
*   WLSTPTR-ADDR OF THE PRESENT OUTPUT BUFFER                           19600013
*   WLSTPTRD-ADDR OF AN AVAILABLE AREA IN THE OUTPUT BUFFER             19800013
*   WKEEPAVA-STARTING ADDR OF THE WINNER'S BIN IN RSA                   20000013
*   WHOLD-WORK AREA                                                     20200013
*   WLASTRCD-LAST RECORD SWITCH                                         20400013
         SPACE 2                                                        20600013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   20800013
         SPACE 2                                                        21000013
*NOTES:                                                                 21200013
*   THIS MODULE IS USED BY THE OSCILLATING SORT FOR A VARIABLE LENGTH   21400013
*   TAPE SORT OR THE 2314 FOR A VARIABLE DISK SORT.                     21600013
         EJECT                                                          21800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            22000013
         SPACE 1                                                        22200013
RA       EQU   0                   CONTENTS IN - N/A                    22400013
*                                  USED - NOT USED                      22600013
*                                  CONTENTS OUT - N/A                   22800013
RB       EQU   1                   CONTENTS IN - N/A                    23000013
*                                  USED - PARAM TO WRITE MOD. NO. OF    23200013
*                                         BYTES IN OUTPUT BUFFER.       23400013
*                                       - PARAM SWITCH TO MOVE MOD      23600013
*                                       - PARAM REG FROM MOVE MOD. NO.  23800013
*                                         OF BINS VACATED               24000013
RC       EQU   2                   CONTENTS IN - N/A                    24200013
*                                  USED - PARAM TO WRITE MOD. ADDR OF   24400013
*                                         OUTPUT BFR                    24600013
*                                  CONTENTS OUT - N/A                   24800013
RD       EQU   3                   CONTENTS IN - PARAM FROM NTWK. ADDR  25000013
*                                                OF WINNER RCD IN RSA   25200013
*                                  USED - NOT USED                      25400013
*                                  CONTENTS OUT - PARAM TO DEBLOCK.ADDR 25600013
*                                                 OF AVIL. BIN IN RSA   25800013
RE       EQU   4                   CONTENTS IN - N/A                    26000013
*                                  USED - PARAM TO MOVE MOD.ADDR OF     26200013
*                                         FREE AREA IN OUTPUT BUFFER    26400013
*                                       - PARAM TO WRITE. SEQUENCE SW.  26600013
*                                  CONTENTS OUT - N/A                   26800013
RF       EQU   5                   CONTENTS IN - N/A                    27000013
*                                  USED - PARAM TO MOVE MOD. ADDR OF    27200013
*                                         WINNER IN RSA                 27400013
*                                       - GENERAL WORK REGISTER         27600013
RG       EQU   6                   CONTENTS IN - N/A                    27800013
*                                  USED - OUTPUT BUFFER CHARACTER CTR   28000013
*                                  CONTENTS OUT - N/A                   28200013
RH       EQU   7                   CONTENTS IN - N/A                    28400013
*                                  USED - GENERAL WORK REGISTER         28600013
*                                  CONTENTS OUT - N/A                   28800013
RI       EQU   8                   CONTENTS IN - N/A                    29000013
*                                  USED - GENERAL WORK REGISTER         29200013
*                                  CONTENTS OUT - N/A                   29400013
RJ       EQU   9                   CONTENTS IN - N/A                    29600013
*                                       USE - WORK REGISTER             29800013
*                                  CONTENTS OUT - N/A                   30000013
RK       EQU   10                  CONTENTS IN - N/A                    30200013
*                                       USE - WORK REGISTER             30400013
*                                  CONTENTS OUT - N/A                   30600013
RL       EQU   11                  CONTENTS IN - THIS MODULE ENTRY PT   30800013
*                                  USED - MODULE BASE REGISTER          31000013
*                                  CONTENTS OUT - DEBLOCK ENTRY PT      31200013
RM       EQU   12                  CONTENTS IN - EQUALS OR EXTRACT RTN  31400013
*                                  USED - NOT USED                      31600013
*                                  CONTENTS OUT - EQUALS OR EXTRACT RTN 31800013
RN       EQU   13                  CONTENTS IN - ADDR OF PPI            32000013
*                                  USED - PPI REFERENCES                32200013
*                                  CONTENTS OUT - ADDR OF PPI           32400013
RO       EQU   14                  CONTENTS IN - N/A                    32600013
*                                  USED - RETURN REG FROM MOVE RTN      32800013
*                                  CONTENTS OUT - N/A                   33000013
RP       EQU   15                  CONTENTS IN - N/A                    33200013
*                                  USED - BRANCH REG TO MOVE RTN        33400013
*                                  CONTENTS OUT - N/A                   33600013
         SPACE 2                                                        33800013
*START OF MODULE CODE PROPER:                                           34000013
         SPACE 2                                                        34200013
         SPACE 1                                                        34400013
IERRBA   CSECT                                                          34600013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    34800013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      35000013
         SPACE 1                                                        35200013
*   ENTRY TABLE                                                         35400013
         SPACE 1                                                        35600013
IERDB1   B     RBLSTRCD            LAST RCD ENTRY FROM REPLACEMENT      35800013
         B     RBEOS               EOS ENTRY FROM REPLACEMENT           36000013
         B     RBWRT               WRITE ENTRY.                         36200013
*   NORMAL REPLACEMENT ENTRY-INCR BLOCK CHAR CTR,CHECK IF RCD WILL FIT  36400013
*     IN OUTPUT BLOCK. IF NOT, WRITE THE BUFFER BEFORE MOVING THE RCD.  36600013
         SPACE 1                                                        36800013
RBLDCCNT L     RG,WBLKCCNT         OUTPUT BLOCK CHARACTER CTR INITIALLY 37000013
*                                    PRESET TO 8 BY A.P.                37200013
         B     RBBRANCH                                                 37400013
         SPACE 1                                                        37600013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   37800013
*                                    BLOCK ENDING ADDRESS + 1.          38000013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     38200013
         SPACE 1                                                        38400013
RBBRANCH AH    RG,0(RD)            ADD LENGTH OF RECORD TO BE MOVED     38600013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 38800013
         BC    2,RBWRTBLK          YES,BR TO WRITE THE BLOCK FIRST      39000013
RBSAVERD ST    RD,WINNER           SAVE ADDR OF RCD IN RSA TO BE BLOCKD 39200013
         L     RE,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD-    39400013
RBTAPE   SH    RE,0(0,RD)          DECR ADDR BY RCD LNGTH-FOR TAPE SORT 39600013
*                                    RCDS FILL OUTPUT BLOCK STARTING    39800013
*                                    FROM HIGH CORE TO LOW CORE. THIS   40000013
*                                    INST. WILL BE NOP BY A.P. IF DISK  40200013
         SPACE 1                                                        40400013
*   CALCULATE BEGINNING ADDR OF THIS BIN + STORE AS NEW AVAILABLE BIN   40600013
         SPACE 1                                                        40800013
         S     RD,KFOUR            SUBTR 4 BYTES FOR TREE ADDR IN RSA   41000013
         SH    RD,PPILEXFF         SUBTR LENGTH OF CONTROL FIELD        41200013
         ST    RD,WKEEPAVA         SAVE STRTG ADDR OF BIN IN WORK AREA  41400013
         SPACE 1                                                        41600013
*   LOAD PARAMETERS AND BRANCH TO MOVE MODULE TO MOVE RCD FROM RSA TO   41800013
*     THE OUTPUT BLOCK. TEST IF LAST RCD SWITCH SET.                    42000013
         SPACE 1                                                        42200013
         L     RF,WINNER           LOAD ADDR OF RCD IN RSA              42400013
         L     RB,KFOUR            A 4 DENOTES A BLOCK RTN TO MOVE MOD  42600013
         L     RP,PPIBDSVA+12      LOAD ADDR OF MOVE RTN                42800013
*                                                                       43000013
         LR    RI,RE               ELLIOTT I PUT THIS IN.  DLB          43200013
*                                                                       43400013
         BALR  RO,RP               BR TO MOVE RTN(WILL SAVE ALL REGS +  43600013
*                                    PASS = BINS VACATED IN RB,AND LINK 43800013
*                                    ADDR OF LAST BIN OF RCD IN RF)     44000013
*                                                                       44200013
         LR    RE,RI               ELLIOTT I PUT THIS IN.  DLB          44400013
         SR    RJ,RJ                                                    44600013
         IC    RJ,PPIDEPHO+3        INCREMENT FOR OUTPUT UNIT           44800013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       45000013
         L     RI,0(RJ,RH)          LOAD COUNT FOR THIS UNIT            45200013
         LA    RI,1(RI)           INCREMENT BY ONE                      45400013
         ST    RI,0(RJ,RH)          RESTORE                             45600013
*                                                                       45800013
         CLI   WLASTRCD,X'00'      LAST RCD SWITCH ON                   46000013
         BC    7,RBSEQSW           YES,BR TO SET FINAL EOS SW FOR WRITE 46200013
         L     RI,WINNER           DISK SORT ONLY - ADD RCD. LENGTH     46400013
RBDISK   AH    RE,0(0,RI)            TO BLOCK PTR. -NOP AH FOR TAPE     46600013
         ST    RE,WLSTPTR          SAVE UPDATED OUTPUT BLK ADDR PTR     46800013
         SPACE 1                                                        47000013
*   UPDATE BIN COUNT AND PTR TO NEXT AVAILABLE AREA IN RSA.UPDATE CHAIN 47200013
*     ADDRESS OF LAST BIN VACATED IN RSA IF BIN COUNT IS NOT ZERO       47400013
         SPACE 1                                                        47600013
         L     RI,PPIBDSVA+8       LOAD BIN COUNT                       47800013
         AR    RI,RB               INCR BY = OF BINS JUST VACATED       48000013
         ST    RI,PPIBDSVA+8       STORE UPDATED BIN COUNT FOR DEBLOCK  48200013
         CR    RI,RB               WAS BIN COUNT ZERO BEFORE INCR(IF SO 48400013
*                                    RI WILL NOW EQUAL RB)              48600013
         BC    8,RBSTOKEP          YES,BR TO UPDATE NEXT AVAILABLE BIN  48800013
*                                    PTR ONLY,BECAUSE ALL BINS ARE      49000013
*                                    LINKED TOGETHER ALREADY            49200013
         MVC   0(4,RF),PPIBDSVA+4  STORE ADDR OF NEXT AVAIL BIN IN LINK 49400013
*                                    ADDR OF LAST BIN VACATED           49600013
RBSTOKEP MVC   PPIBDSVA+4(4),WKEEPAVA  ADDR OF AVAIL BIN                49800013
         ST    RG,WBLKCCNT         SAVE CHARACTER COUNTER               50000013
         SPACE 1                                                        50200013
*   INTERFACE TO DEBLOCK MODULE                                         50400013
         SPACE 1                                                        50600013
RBOVLAY1 L     RL,PPIDEB+4         ADDR OF DEBLOCK MOD. THIS INSTR WILL 50800013
*                                    BE OVLAYED BY B RBLDLPTR ON NORMAL 51000013
*                                    EOS, THEN RESTORED FOR NEXT SEQ.   51200013
         B     8(RL)               BR TO DEBLOCK MOD                    51400013
         SPACE 2                                                        51600013
*   FINAL SEQUENCE ROUTINE FOR LAST RECORD                              51800013
         SPACE 1                                                        52000013
RBSEQSW  ST    RE,WLSTPTR          SAVE STRTG ADDR OF LAST RCD IN OUT-  52200013
*                                   PUT BLOCK.                          52400013
         SR    RE,RE               SET LAST SEQ SWITCH FOR WRITE MODULE 52600013
         L     RH,WLSTPTR                                               52800013
         B     RBDCRLST            BR TO DECR OUTPUT BLOCK PTR          53000013
         SPACE 2                                                        53200013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK.                  53400013
         SPACE 1                                                        53600013
RBWRTBLK SH    RG,0(0,RD)          SUBTRACT LENGTH OF RCD THAT CANT FIT 53800013
*                                    FROM OUTPUT BLOCK COUNT            54000013
RBOVLAY2 L     RC,WLSTPTR          LOAD OUTPUT BLK PTR.FOR DISK,WLSTPTR 54200013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   54400013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            54600013
         MVC   0(2,RC),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     54800013
         LR    RB,RG                 ALSO,IN RB FOR WRITE PARAM         55000013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 55200013
         B     8(RL)               BR TO WRITE MODULE                   55400013
         SPACE 2                                                        55600013
*   WRITE MODULE REENTER VIA BRANCH TABLE. RC,FOR TAPE,HAS ADDR OF AN   55800013
*   OUTPUT BLOCK ENDING ADDRESS+1.                                      56000013
         SPACE 1                                                        56200013
RBWRT    ST    RC,WLSTPTRD         SAVE AS INITIAL OUTPUT BLK POINTER   56400013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLOCK WORK PTR       56600013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          56800013
         AH    RG,0(0,RD)          ADD RCD LENGTH OF RCD TO BE MOVED    57000013
*                                    TO OUTPUT BLOCK                    57200013
         B     RBSAVERD                                                 57400013
         SPACE 2                                                        57600013
*   FROM REPLACEMENT. LAST RECORD                                       57800013
         SPACE 1                                                        58000013
RBLSTRCD OI    WLASTRCD,X'01'      TURN ON LAST RCD SWITCH              58200013
         B     RBLDCCNT                                                 58400013
         SPACE 2                                                        58600013
*   FROM REPLACEMENT. NORMAL EOS                                        58800013
         SPACE 1                                                        59000013
RBEOS    MVC   RBOVLAY1,KLDLPTR    OVLAY EXIT TO DEBLOCK FOR NORMAL EOS 59200013
         B     RBLDCCNT            BR TO MOVE LAST RCD OF THIS SEQUENCE 59400013
         SPACE 2                                                        59600013
*   RETURN FROM RBOVLAY1 WHICH WAS OVERLAYED ON THIS NORMAL EOS.        59800013
         SPACE 1                                                        60000013
RBLDLPTR L     RH,WLSTPTR                                               60200013
         LA    RE,4                SET SWITCH TO NORMAL EOS FOR WRITE   60400013
RBDCRLST MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           60600013
         MVC   RBOVLAY1,KIERDD1    RESET RBOVLAY1 TO ORIGINAL INSTR     60800013
         SPACE 1                                                        61000013
*   CONTINUATION POINT FOR LAST RCD. RH POINTS TO BYTE AFTER EOS ENTRY  61200013
         SPACE 1                                                        61400013
         S     RH,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   61600013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      61800013
         MVC   WBLKCCNT,KEIGHT    REINITIALIZE BLOCK CHAR CTR TO 8      62000013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            62200013
         MVI   WLASTRCD,X'00'     RESET LAST RECORD SWITCH TO ZERO      62400013
         MVC   0(2,RH),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     62600013
         LR    RB,RG               LOAD BLOCK CHAR CNT FOR WRITE        62800013
         LR    RC,RH               LOAD OUTPUT BLOCK PTR FOR WRITE MOD  63000013
         SPACE 1                                                        63200013
*   INTERFACE TO WRITE MODULE FOR EOS                                   63400013
         SPACE 1                                                        63600013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 63800013
         B     4(RL)               BR TO WRITE MODULE                   64000013
         SPACE 2                                                        64200013
*   LIST OF CONSTANTS USED BY THE MODULE                                64400013
         SPACE 1                                                        64600013
KFOUR    DC    F'4'                                                     64800013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  65000013
KIERDD1  L     RL,PPIDEB+4         RESTORE RBOVLAY1 AFTER NORMAL EOS.   65200013
KLDLPTR  B     RBLDLPTR            OVLAY RBOVLAY1 EVERY NORMAL EOS      65400013
         SPACE 1                                                        65600013
*   LIST OF WORK AREAS USED BY THE MODULE                               65800013
         SPACE 1                                                        66000013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHARACTER CTR INITIALLY 66200013
*                                    PRESET TO 8 BY A.P.(2-BCC,2-SYSTEM 66400013
*                                      CHECK,4-EOS)                     66600013
*                                  IF 2314, INITIALLY SET TO 16 TO      66800013
*                                    INCLUDE CHAIN DISK ADDRESS TOO     67000013
WINNER   DC    F'0'                ADDR OF RCD IN RSA TO BE BLOCKED     67200013
*                                    POINTS TO 2 BYTE LENGTH FIELD      67400013
WKEEPAVA DC    F'0'                STARTG ADDR OF BIN                   67600013
WHOLD    DC    H'0'               HALF-WORD BOUNDARY WORK AREA          67800013
WLASTRCD DC    X'00'               LAST RCD SWITCH                      68000013
         EJECT                                                          68200013
         SMPPI                                                          68400013
         END                                                            68600013
