         TITLE 'IERRBE - OS/360 SORT/MERGE - 360S-SM-023 - 4/21/66'     00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRBE ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 1 RUNNING MODULE. ANY V.L. SORT       01400013
*   THE FUNCTION OF THIS MODULE IS TO BLOCK VARIABLE LENGTH RECORDS IN  01600013
*   THE OUTPUT BUFFER(S). TO DO THIS IT LINKS TO THE VARIABLE MOVE      01800013
*   ROUTINE, IERRBF, WHICH MOVES THE RECORD FROM RSA(BINS) TO AN OUTPUT 02000013
*   TO THE DEBLOCK MODULE. NOW THAT THE BIN(S) IN RSA HAVE BEEN FREED   02200013
*   THIS MODULE UPDATES THE NEXT AVAILABLE RSA BIN POINTER AND COUNTER  02400013
*   LOCATED IN PPI.                                                     02600013
         SPACE 1                                                        02800013
*   INFORMATION COMMUNICATED BETWEEN MODULES ARE AS FOLLOWS:            03000013
         SPACE 1                                                        03200013
*   NETWORK TO BLOCK- RD CONTAINS WINNER ADDRESS IN RSA                 03400013
*   BLOCK TO MOVE- RF HAS ADDRESS OF RCD IN RSA,RB HAS ADDRESS IN OUT-  03600013
*     PUT BUFFER TO MOVE THE RECORD, RB HAS A 4 TO DENOTE BLOCK RTN.    03800013
*   MOVE TO BLOCK- RB HAS NUMBER OF BINS FREED,RF POINTS TO CHAIN ADDR  04000013
*     OF LAST BIN MOVED.                                                04200013
*   BLOCK TO WRITE- RB HAS OUTPUT BLOCK COUNT, RC HAS ADDR OF OUTPUT    04400013
*     BUFFER, RE HAS 4 FOR NORMAL EOS OTHERWISE HAS A ZERO.             04600013
*   WRITE TO BLOCK- RC HAS STARTING ADDRESS OF OUTPUT BLOCK+8 FOR DISK  04800013
*     OR ENDING ADDRESS OF OUTPUT BLOCK+1 FOR TAPE.                     05000013
         SPACE 2                                                        05200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05400013
         SPACE 1                                                        05600013
*   IERABE                                                              05800013
         SPACE 2                                                        06000013
*LIST OF MACROS USED BY MODULE:                                         06200013
         SPACE 1                                                        06400013
*   SMPPI                                                               06600013
         SPACE 2                                                        06800013
*ENTRY POINTS:                                                          07000013
         SPACE 1                                                        07200013
*   NETWORK TO BLOCK               ENTRY FROM NETWORK.                  07400013
*                                    CALLING SEQUENCE-                  07600013
*                                      L   RL,PPIBLK+4                  07800013
*                                      B   0(RL)       LAST RCD         08000013
*                                      B   4(RL)       EOS              08200013
*                                      B    12(RL)     NORMAL           08400013
*   MOVE RTN TO BLOCK              ENTRY FROM MOVE RTN.                 08600013
*                                    CALLING SEQUENCE                   08800013
*                                      BR   RO         RETURN           09000013
*   WRITE TO BLOCK                 ENTRY FROM WRITE.                    09200013
*                                    CALLING SEQUENCE.                  09400013
*                                      L   RL,PPIBLK+4                  09600013
*                                      B   8(0,RL)     NORMAL           09800013
         SPACE 2                                                        10000013
*INPUT: - PPI FIELDS REFERENCED                                         10200013
         SPACE 1                                                        10400013
*   PPIBDSVA   PPILEXFF                                                 10600013
*   PPIDEB     PPIWRT                                                   10800013
*   PPILAB07                                                            11000013
         SPACE 1                                                        11200013
*   INFO IS NEEDED FOR LINKAGE TO OTHER MODULES AND FOR CALCULATIIONS   11400013
         SPACE 2                                                        11600013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            11800013
         SPACE 1                                                        12000013
*   PPIBDSVA                                                            12200013
         SPACE 1                                                        12400013
*   AVAILABLE BIN POINTER WITHIN THIS AREA.                             12600013
         SPACE 2                                                        12800013
*EXTERNAL ROUTINES:                                                     13000013
         SPACE 1                                                        13200013
*        EXTRN IERRBF              ADDR ALSO WITHIN PPIBDSVA. THIS RTN  13400013
*                                    MOVES THE RCD FORM RSA TO AN       13600013
*                                    OUTPUT BUFFER                      13800013
         SPACE 2                                                        14000013
*EXTERNAL PARAMETERS:                                                   14200013
         SPACE 1                                                        14400013
*   NONE                                                                14600013
         SPACE 2                                                        14800013
*EXITS-NORMAL:                                                          15000013
         SPACE 1                                                        15200013
*   BLOCK TO WRITE                 EXIT TO WRITE.                       15400013
*                                    CALLING SEQUENCE-                  15600013
*                                      L   RL,PPIWRT+4                  15800013
*                                      B   4(RL)       ANY EOS          16000013
*                                      B   8(RL)       NORMAL WRITE     16200013
*   BLOCK TO DEBLOCK               EXIT TO DEBLOCK                      16400013
*                                    CALLING SEQUENCE                   16600013
*                                      L   RL,PPIDEB+4                  16800013
*                                      B   8(RL)                        17000013
*   BLOCK TO MOVE RTN              EXIT TO IERABF                       17200013
*                                    CALLING SEQUENCE                   17400013
*                                      L   RP,PPIBDSVA+12               17600013
*                                      BALR RO,RP                       17800013
         SPACE 2                                                        18000013
*EXITS-ERROR                                                            18200013
         SPACE 1                                                        18400013
*   NONE                                                                18600013
         SPACE 2                                                        18800013
*TABLES/WORK AREAS:                                                     19000013
         SPACE 1                                                        19200013
*   WBLKCCNT-KEEPS TRACK OF THE NUMBER OF BYTES IN AN OUTPUT BUFFER     19400013
*   WINNER-ADDR OF THE NEXT RECORD IN RSA TO BE BLOCKED                 19600013
*   WLSTPTR-ADDR OF THE PRESENT OUTPUT BUFFER                           19800013
*   WLSTPTRD-ADDR OF AN AVAILABLE AREA IN THE OUTPUT BUFFER             20000013
*   WKEEPAVA-STARTING ADDR OF THE WINNER'S BIN IN RSA                   20200013
*   WHOLD-WORK AREA                                                     20400013
*   WLASTRCD-LAST RECORD SWITCH                                         20600013
         SPACE 2                                                        20800013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   21000013
         SPACE 2                                                        21200013
*NOTES: THIS MODULE IS USED FOR ANY VARIABLE LENGTH SORT(TAPE,DISK,ETC) 21400013
         EJECT                                                          21600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            21800013
         SPACE 1                                                        22000013
RA       EQU   0                   CONTENTS IN - N/A                    22200013
*                                  USED - NOT USED                      22400013
*                                  CONTENTS OUT - N/A                   22600013
RB       EQU   1                   CONTENTS IN - N/A                    22800013
*                                  USED - PARAM TO WRITE MOD. NO. OF    23000013
*                                         BYTES IN OUTPUT BUFFER.       23200013
*                                       - PARAM SWITCH TO MOVE MOD      23400013
*                                       - PARAM REG FROM MOVE MOD. NO.  23600013
*                                         OF BINS VACATED               23800013
RC       EQU   2                   CONTENTS IN - N/A                    24000013
*                                  USED - PARAM TO WRITE MOD. ADDR OF   24200013
*                                         OUTPUT BFR                    24400013
*                                  CONTENTS OUT - N/A                   24600013
RD       EQU   3                   CONTENTS IN - PARAM FROM NTWK. ADDR  24800013
*                                                OF WINNER RCD IN RSA   25000013
*                                  USED - NOT USED                      25200013
*                                  CONTENTS OUT - PARAM TO DEBLOCK.ADDR 25400013
*                                                 OF AVIL. BIN IN RSA   25600013
RE       EQU   4                   CONTENTS IN - N/A                    25800013
*                                  USED - PARAM TO MOVE MOD.ADDR OF     26000013
*                                         FREE AREA IN OUTPUT BUFFER    26200013
*                                       - PARAM TO WRITE. SEQUENCE SW.  26400013
*                                  CONTENTS OUT - N/A                   26600013
RF       EQU   5                   CONTENTS IN - N/A                    26800013
*                                  USED - PARAM TO MOVE MOD. ADDR OF    27000013
*                                         WINNER IN RSA                 27200013
*                                       - GENERAL WORK REGISTER         27400013
RG       EQU   6                   CONTENTS IN - N/A                    27600013
*                                  USED - OUTPUT BUFFER CHARACTER CTR   27800013
*                                  CONTENTS OUT - N/A                   28000013
RH       EQU   7                   CONTENTS IN - N/A                    28200013
*                                  USED - GENERAL WORK REGISTER         28400013
*                                  CONTENTS OUT - N/A                   28600013
RI       EQU   8                   CONTENTS IN - N/A                    28800013
*                                  USED - GENERAL WORK REGISTER         29000013
*                                  CONTENTS OUT - N/A                   29200013
RJ       EQU   9                   CONTENTS IN - N/A                    29400013
*                                  USED - NOT USED                      29600013
*                                  CONTENTS OUT - N/A                   29800013
RK       EQU   10                  CONTENTS IN - N/A                    30000013
*                                  USED - NOT USED                      30200013
*                                  CONTENTS OUT - N/A                   30400013
RL       EQU   11                  CONTENTS IN - THIS MODULE ENTRY PT   30600013
*                                  USED - MODULE BASE REGISTER          30800013
*                                  CONTENTS OUT - DEBLOCK ENTRY PT      31000013
RM       EQU   12                  CONTENTS IN - EQUALS OR EXTRACT RTN  31200013
*                                  USED - NOT USED                      31400013
*                                  CONTENTS OUT - EQUALS OR EXTRACT RTN 31600013
RN       EQU   13                  CONTENTS IN - ADDR OF PPI            31800013
*                                  USED - PPI REFERENCES                32000013
*                                  CONTENTS OUT - ADDR OF PPI           32200013
RO       EQU   14                  CONTENTS IN - N/A                    32400013
*                                  USED - RETURN REG FROM MOVE RTN      32600013
*                                  CONTENTS OUT - N/A                   32800013
RP       EQU   15                  CONTENTS IN - N/A                    33000013
*                                  USED - BRANCH REG TO MOVE RTN        33200013
*                                  CONTENTS OUT - N/A                   33400013
         SPACE 2                                                        33600013
*START OF MODULE CODE PROPER:                                           33800013
         SPACE 2                                                        34000013
         SPACE 1                                                        34200013
IERRBE   CSECT                                                          34400013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    34600013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      34800013
         SPACE 1                                                        35000013
*   ENTRY TABLE                                                         35200013
         SPACE 1                                                        35400013
IERDB1   B     RBLSTRCD            LAST RCD ENTRY FROM REPLACEMENT      35600013
         B     RBEOS               EOS ENTRY FROM REPLACEMENT           35800013
         B     RBWRT               WRITE ENTRY.                         36000013
         B     RBLDCCNT            NORMAL ENTRY FROM REPLACEMENT        36200013
         B     *                   DUMMY ENTRY-NOT USED                 36400013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   36600013
*                                    BLOCK ENDING ADDR+1 FOR TAPE, OR   36800013
*                                    OUTPUT BLOCK STARTG ADDR+8 FOR A   37000013
*                                    DISK SORT                          37200013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 37400013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     37600013
*                                  BOTH POINTERS ARE RESET BY WRITE     37800013
*                                    RTN ON EOS                         38000013
         SPACE 2                                                        38200013
*   NORMAL REPLACEMENT ENTRY-INCR BLOCK CHAR CTR,CHECK IF RCD WILL FIT  38400013
*     IN OUTPUT BLOCK. IF NOT, WRITE THE BUFFER BEFORE MOVING THE RCD.  38600013
         SPACE 1                                                        38800013
RBLDCCNT L     RG,WBLKCCNT         OUTPUT BLOCK CHARACTER CTR INITIALLY 39000013
*                                    PRESET TO 8 BY A.P.                39200013
         AH    RG,0(0,RD)          ADD LENGTH OF RCD TO BE MOVED        39400013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 39600013
         BC    2,RBWRTBLK          YES,BR TO WRITE THE BLOCK FIRST      39800013
RBSAVERD ST    RD,WINNER           SAVE ADDR OF RCD IN RSA TO BE BLOCKD 40000013
         L     RE,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD-    40200013
RBTAPE   SH    RE,0(0,RD)          DECR ADDR BY RCD LNGTH-FOR TAPE SORT 40400013
*                                    RCDS FILL OUTPUT BLOCK STARTING    40600013
*                                    FROM HIGH CORE TO LOW CORE. THIS   40800013
*                                    INSTR WILL BE NOP BY A.P. IF DISK  41000013
         SPACE 1                                                        41200013
*   CALCULATE BEGINNING ADDR OF THIS BIN + STORE AS NEW AVAILABLE BIN   41400013
         SPACE 1                                                        41600013
         S     RD,KFOUR            SUBTR 4 BYTES FOR TREE ADDR IN RSA   41800013
         SH    RD,PPILEXFF         SUBTR LENGTH OF CONTROL FIELD        42000013
         ST    RD,WKEEPAVA         SAVE STRTG ADDR OF BIN IN WORK AREA  42200013
         SPACE 1                                                        42400013
*   LOAD PARAMETERS AND BRANCH TO MOVE MODULE TO MOVE RCD FROM RSA TO   42600013
*     THE OUTPUT BLOCK. TEST IF LAST RCD SWITCH SET.                    42800013
         SPACE 1                                                        43000013
         L     RF,WINNER           LOAD ADDR OF RCD IN RSA              43200013
         L     RB,KFOUR            A 4 DENOTES A BLOCK RTN TO MOVE MOD  43400013
         L     RP,PPIBDSVA+12      LOAD ADDR OF MOVE RTN                43600013
*                                                                       43800013
         LR    RI,RE               ELLIOTT I PUT THIS IN.  DLB          44000013
*                                                                       44200013
         BALR  RO,RP               BR TO MOVE RTN(WILL SAVE ALL REGS +  44400013
*                                    PASS = BINS VACATED IN RB,AND LINK 44600013
*                                    ADDR OF LAST BIN OF RCD IN RF)     44800013
*                                                                       45000013
         LR    RE,RI               ELLIOTT I PUT THIS IN.  DLB          45200013
*                                                                       45400013
         CLI   WLASTRCD,X'00'      LAST RCD SWITCH ON                   45600013
         BC    7,RBSEQSW           YES,BR TO SET FINAL EOS SW FOR WRITE 45800013
         L     RI,WINNER           LOAD ADDR OF RCD IN RSA              46000013
RBDISK   AH    RE,0(0,RI)          DISK SORT ONLY-INCR ADDR IN OUTPUT   46200013
*                                    BLOCK BY RCD LENGTH. THIS INSTR    46400013
*                                    WILL BE A NOP IF TAPE SORT.        46600013
         ST    RE,WLSTPTR          SAVE UPDATED OUTPUT BLK ADDR PTR     46800013
         SPACE 1                                                        47000013
*   UPDATE BIN COUNT AND PTR TO NEXT AVAILABLE AREA IN RSA.UPDATE CHAIN 47200013
*     ADDRESS OF LAST BIN VACATED IN RSA IF BIN COUNT IS NOT ZERO       47400013
         SPACE 1                                                        47600013
         L     RI,PPIBDSVA+8       LOAD BIN COUNT                       47800013
         AR    RI,RB               INCR BY = OF BINS JUST VACATED       48000013
         ST    RI,PPIBDSVA+8       STORE UPDATED BIN COUNT FOR DEBLOCK  48200013
         CR    RI,RB               WAS BIN COUNT ZERO BEFORE INCR(IF SO 48400013
*                                    RI WILL NOW EQUAL RB)              48600013
         BC    8,RBSTOKEP          YES,BR TO UPDATE NEXT AVAILABLE BIN  48800013
*                                    PTR ONLY,BECAUSE ALL BINS ARE      49000013
*                                    LINKED TOGETHER ALREADY            49200013
         MVC   0(4,RF),PPIBDSVA+4  STORE ADDR OF NEXT AVAIL BIN IN LINK 49400013
*                                    ADDR OF LAST BIN VACATED           49600013
RBSTOKEP MVC   PPIBDSVA+4(4),WKEEPAVA  ADDR OF AVAIL BIN                49800013
         ST    RG,WBLKCCNT         SAVE CHARACTER COUNTER               50000013
         SPACE 1                                                        50200013
*   INTERFACE TO DEBLOCK MODULE                                         50400013
         SPACE 1                                                        50600013
RBOVLAY1 L     RL,PPIDEB+4         ADDR OF DEBLOCK MOD. THIS INSTR WILL 50800013
*                                    BE OVLAYED BY B RBLDLPTR ON NORMAL 51000013
*                                    EOS, THEN RESTORED FOR NEXT SEQ.   51200013
         B     8(RL)               BR TO DEBLOCK MOD                    51400013
         SPACE 2                                                        51600013
*   FINAL SEQUENCE ROUTINE FOR LAST RECORD                              51800013
         SPACE 1                                                        52000013
RBSEQSW  ST    RE,WLSTPTR          SAVE STRTG ADDR OF LAST RCD IN OUT-  52200013
*                                    PUT BLK FOR TAPE. IGNORE FOR DISK. 52400013
         SR    RE,RE               SET LAST SEQ SWITCH FOR WRITE MODULE 52600013
RBTAPE1  L     RH,WLSTPTRD         FOR DISK,LOAD OUTPUT BLK PTR. FOR    52800013
*                                    TAPE,A.P. WILL SET TO L RH,WLSTPTR 53000013
         B     RBDCRLST            BR TO DECR OUTPUT BLOCK PTR          53200013
         SPACE 2                                                        53400013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK.                  53600013
         SPACE 1                                                        53800013
RBWRTBLK SH    RG,0(0,RD)          SUBTRACT LENGTH OF RCD THAT CANT FIT 54000013
*                                    FROM OUTPUT BLOCK COUNT            54200013
RBOVLAY2 L     RC,WLSTPTR          LOAD OUTPUT BLK PTR.FOR DISK,WLSTPTR 54400013
*                                    WILL BE OVLAYED BY WLSTPTRD BY A.P 54600013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   54800013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            55000013
         MVC   0(2,RC),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     55200013
         LR    RB,RG                 ALSO,IN RB FOR WRITE PARAM         55400013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 55600013
         B     8(RL)               BR TO WRITE MODULE                   55800013
         SPACE 2                                                        56000013
*   WRITE MODULE REENTER VIA BRANCH TABLE. RC,FOR TAPE,HAS ADDR OF AN   56200013
*     OUTPUT BLK ENDING ADDR+1.RC,FOR DISK,HAS OUTPUT BLK STRTG ADDR+8  56400013
         SPACE 1                                                        56600013
RBWRT    ST    RC,WLSTPTRD         SAVE AS INITIAL OUTPUT BLK POINTER   56800013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLOCK WORK PTR       57000013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     57200013
         AH    RG,0(0,RD)          ADD RCD LENGTH OF RCD TO BE MOVED    57400013
*                                    TO OUTPUT BLOCK                    57600013
         B     RBSAVERD                                                 57800013
         SPACE 2                                                        58000013
*   FROM REPLACEMENT. LAST RECORD                                       58200013
         SPACE 1                                                        58400013
RBLSTRCD OI    WLASTRCD,X'01'      TURN ON LAST RCD SWITCH              58600013
         B     RBLDCCNT                                                 58800013
         SPACE 2                                                        59000013
*   FROM REPLACEMENT. NORMAL EOS                                        59200013
         SPACE 1                                                        59400013
RBEOS    MVC   RBOVLAY1,KLDLPTR    OVLAY EXIT TO DEBLOCK FOR NORMAL EOS 59600013
         B     RBLDCCNT            BR TO MOVE LAST RCD OF THIS SEQUENCE 59800013
         SPACE 2                                                        60000013
*   RETURN FROM RBOVLAY1 WHICH WAS OVERLAYED ON THIS NORMAL EOS.        60200013
         SPACE 1                                                        60400013
RBLDLPTR L     RH,WLSTPTRD         LOAD OUTPUT BLOCK PTR(DISK SORT).A.P 60600013
*                                    WILL MAKE L RH,WLSTPTR (TAPE SORT) 60800013
         LA    RE,4                SET SWITCH TO NORMAL EOS FOR WRITE   61000013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           61200013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     61400013
         MVC   RBOVLAY1,KIERDD1    RESET RBOVLAY1 TO ORIGINAL INSTR     61600013
         SPACE 1                                                        61800013
*   CONTINUATION POINT FOR LAST RCD. RH POINTS TO BYTE AFTER EOS ENTRY  62000013
         SPACE 1                                                        62200013
RBDCRLST S     RH,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   62400013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      62600013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            62800013
         MVC   0(2,RH),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     63000013
         LR    RB,RG               LOAD BLOCK CHAR CNT FOR WRITE        63200013
         LR    RC,RH               LOAD OUTPUT BLOCK PTR FOR WRITE MOD  63400013
         SPACE 1                                                        63600013
*   INTERFACE TO WRITE MODULE FOR EOS                                   63800013
         SPACE 1                                                        64000013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 64200013
         B     4(RL)               BR TO WRITE MODULE                   64400013
         SPACE 2                                                        64600013
*   LIST OF CONSTANTS USED BY THE MODULE                                64800013
         SPACE 1                                                        65000013
KFOUR    DC    F'4'                                                     65200013
KEIGHT   DC    F'8'                                                     65400013
KIERDD1  L     RL,PPIDEB+4         RESTORE RBOVLAY1 AFTER NORMAL EOS.   65600013
KLDLPTR  B     RBLDLPTR            OVLAY RBOVLAY1 EVERY NORMAL EOS      65800013
         SPACE 1                                                        66000013
*   LIST OF WORK AREAS USED BY THE MODULE                               66200013
         SPACE 1                                                        66400013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHARACTER CTR INITIALLY 66600013
*                                    PRESET TO 8 BY A.P.(2-BCC,2-SYSTEM 66800013
*                                      CHECK,4-EOS)                     67000013
WINNER   DC    F'0'                ADDR OF RCD IN RSA TO BE BLOCKED     67200013
*                                    POINTS TO 2 BYTE LENGTH FIELD      67400013
WKEEPAVA DC    F'0'                STARTG ADDR OF BIN                   67600013
WHOLD    DC    H'0'               HALF-WORD BOUNDARY WORK AREA          67800013
WLASTRCD DC    X'00'               LAST RCD SWITCH                      68000013
         EJECT                                                          68200013
         SMPPI                                                          68400013
         END                                                            68600013
