         TITLE '      IERRBI - OS/360 SORT/MERGE - 360S-SM023 04/22/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME:*** IERRBI ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 2 RUNNING MODULE. V.L. WITHOUT EXITS  01400013
*     THE FUNCTION OF THE MODULE IS TO HANDLE THE DEBLOCKING AND        01600013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       01800013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     02000013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     02200013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         02400013
         SPACE 1                                                        02600013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  02800013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  03000013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         03200013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     03400013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     03600013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     03800013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    04000013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   04200013
*     IS REPEATED.                                                      04400013
         SPACE 1                                                        04600013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    04800013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            05000013
         SPACE 2                                                        05200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05400013
         SPACE 1                                                        05600013
*   IERABI                                                              05800013
         SPACE 2                                                        06000013
*LIST OF MACROS USED BY THE MODULE:                                     06200013
         SPACE 1                                                        06400013
*   SMPPI                                                               06600013
         SPACE 2                                                        06800013
*ENTRY POINTS:                                                          07000013
         SPACE 1                                                        07200013
*   FROM MERGE                     ENTRY FROM: MERGE NETWORK            07400013
*                                    CALLING SEQUENCE-                  07600013
*                                      L    RL,PPIBLK2+4                07800013
*                                      B    0(RL)      NORMAL EDS       08000013
*                                      B    16(RL)     NORMAL           08200013
*   FROM READ                      ENTRY FROM: READ                     08400013
*                                    CALLING SEQUENCE-                  08600013
*                                      L    RL,PPIBLK2+4                08800013
*                                      B    4(RL)                       09000013
*   FROM WRITE                     ENTRY FROM: WRITE                    09200013
*                                    CALLING SEQUENCE-                  09400013
*                                      L    RL,PPIBLK2+4                09600013
*                                      B    8(RL)                       09800013
         SPACE 2                                                        10000013
*INPUT: PPI FIELDS REFERENCED                                           10200013
         SPACE 1                                                        10400013
*   PPIBDSVA                                                            10600013
*   PPILAB07                                                            10800013
*   PPISBLCT                                                            11000013
         SPACE 1                                                        11200013
*   VARIOUS ADDRESSES                                                   11400013
         SPACE 2                                                        11600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             11800013
         SPACE 1                                                        12000013
*   PPICOUNT                                                            12200013
         SPACE 1                                                        12400013
*   UPDATE COUNTERS                                                     12600013
         SPACE 2                                                        12800013
*EXTERNAL ROUTINES:                                                     13000013
         SPACE 1                                                        13200013
*   NONE                                                                13400013
         SPACE 2                                                        13600013
*EXTERNAL PARAMETERS:                                                   13800013
         SPACE 1                                                        14000013
*   SEE REGISTERS                                                       14200013
         SPACE 2                                                        14400013
*EXITS: NORMAL                                                          14600013
         SPACE 1                                                        14800013
*   TO READ                        EXIT TO: READ                        15000013
*                                    CALLING SEQUENCE-                  15200013
*                                      L    RL,PPIRD+4                  15400013
*                                      B    8(RL)                       15600013
*   TO NETWORK                     EXIT TO:NETWORK                      15800013
*                                    CALLING SEQUENCE                   16000013
*                                      L    RL,PPINETM+4                16200013
*                                      B    8(RL)                       16400013
*   TO WRITE                       EXIT TO: WRITE                       16600013
*                                    CALLING SEQUENCE-                  16800013
*                                      L    RL,PPIWRT+4                 17000013
*                                      B    4(RL)      EOS              17200013
*                                      B    8(RL)      NORMAL           17400013
         SPACE 2                                                        17600013
*EXITS: ERROR                                                           17800013
         SPACE 1                                                        18000013
*   NONE                                                                18200013
         SPACE 2                                                        18400013
*TABLES/WORK AREAS:                                                     18600013
         SPACE 1                                                        18800013
*   WBLKCCNT- OUTPUT BUFFER CHARACTER COUNTER                           19000013
*   WRCDLGTH- LENGTH OF WINNER RECORD                                   19200013
*   WINNER- ADDRESS OF THE WINNER RECORD IN THE INPUT BLOCK             19400013
*   WLSTPTR- ADDR OF A FREE AREA IN OUTPUT BUFFER TO MOVE THE WINNER    19600013
*   WLSTPTRD- PTR TO STARTG+8(DISK)OR ENDING+1(TAPE) ADDR OF OUTPUT BFR 19800013
         SPACE 2                                                        20000013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   20200013
         SPACE 2                                                        20400013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY VARIABLE LENGTH SORT WITHOUT   20600013
*       USER EXITS                                                      20800013
         SPACE 2                                                        21000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            21200013
         SPACE 1                                                        21400013
RA       EQU   0                   CONTENTS IN - N/A                    21600013
*                                  USE- NOT USED                        21800013
*                                  CONTENTS OUT- N/A                    22000013
RB       EQU   1                   CONTENTS IN - N/A                    22200013
*                                  USE- BLK TO WRITE(BLOCK CHAR COUNT)  22400013
*                                  CONTENTS OUT- N/A                    22600013
RC       EQU   2                   CONTENTS IN - N/A                    22800013
*                                  USE- BLK TO WRITE(STRTG ADDR OF      23000013
*                                    OUTPUT BUFFER)                     23200013
*                                     - DEBLK TO READ(ADDR OF AN EMPTY  23400013
*                                    INPUT BUFFER)                      23600013
*                                  CONTENTS OUT- N/A                    23800013
RD       EQU   3                   CONTENTS IN - N/A                    24000013
*                                  USE- NTWK TO BLOCK(ADDR OF WINNER IN 24200013
*                                    INPUT BFR W/INCR IN 1ST BYTE)      24400013
*                                     - DEBLOCK TO READ(INCR IN LOW     24600013
*                                    ORDER BYTE-EMPTY BFR INCR)         24800013
*                                  CONTENTS OUT- N/A                    25000013
RE       EQU   4                   CONTENTS IN- N/A                     25200013
*                                  USE- GENERAL WORK REGISTER           25400013
*                                  CONTENTS OUT- N/A                    25600013
RF       EQU   5                   CONTENTS IN- N/A                     25800013
*                                  USE- GENERAL WORK REGISTER           26000013
*                                  CONTENTS OUT- N/A                    26200013
RG       EQU   6                   CONTENTS IN- N/A                     26400013
*                                  USE- GENERAL WORK REGISTER           26600013
*                                  CONTENTS OUT- N/A                    26800013
RH       EQU   7                   CONTENTS IN- N/A                     27000013
*                                  USE- GENERAL WORK REGISTER           27200013
*                                  CONTENTS OUT- N/A                    27400013
RI       EQU   8                   CONTENTS IN- N/A                     27600013
*                                  USE- GENERAL WORK REGISTER           27800013
*                                  CONTENTS OUT- N/A                    28000013
RJ       EQU   9                   CONTENTS IN- N/A                     28200013
*                                  USE- NOT USED                        28400013
*                                  CONTENTS OUT- N/A                    28600013
RK       EQU   10                  CONTENTS IN- N/A                     28800013
*                                  USE- NOT USED                        29000013
*                                  CONTENTS OUT- N/A                    29200013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    29400013
*                                  USE- MODULE BASE REGISTER            29600013
*                                  CONTENTS OUT- NTWK ENTRY PT          29800013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   30000013
*                                  USE- NOT USED                        30200013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  30400013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          30600013
*                                  USE- PPI REFERENCE,REGISTER SAVE     30800013
*                                    AREA                               31000013
*                                  CONTENTS OUT- ADDRESS OF PPI         31200013
RO       EQU   14                  CONTENTS IN- N/A                     31400013
*                                  USE- NOT USED                        31600013
*                                  CONTENTS OUT- N/A                    31800013
RP       EQU   15                  CONTENTS IN- N/A                     32000013
*                                  USE- NOT USED                        32200013
*                                  CONTENTS OUT- N/A                    32400013
         SPACE 2                                                        32600013
*START OF MODULE CODE PROPER:                                           32800013
         SPACE 2                                                        33000013
IERRBI   CSECT                                                          33200013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    33400013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        33600013
         SPACE 1                                                        33800013
*   ENTRY TABLE                                                         34000013
         SPACE 1                                                        34200013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             34400013
         B     RBRDRTRN            FROM READ MODULE                     34600013
         B     RBWRT               FROM WRITE MODULE                    34800013
         BC    0,RBSAVE            PRIMING ENTRY-ONLY FOR USER MODS MOD 35000013
         SPACE 1                                                        35200013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   35400013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      35600013
         SPACE 1                                                        35800013
         L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      36000013
*                                    PRESET TO 8 BY A.P.                36200013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  36400013
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  36600013
*                                    CTR                                36800013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 37000013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     37200013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          37400013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      37600013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     37800013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 38000013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 38200013
*                                    HI CORE TO LOW. A.P. WILL NOP THIS 38400013
*                                    INSTR IF DISK                      38600013
         L     RG,PPICOUNT         RECORD COUNTER                       38800013
         LA    RG,1(0,RG)          INCR BY 1 FOR THIS RCD               39000013
         ST    RG,PPICOUNT         STORE UPDATED RECORD COUNTER         39200013
         LR    RE,RD               ADDR OF RCD IN INPUT AREA FOR MOVE   39400013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           39600013
         SPACE 1                                                        39800013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   40000013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   40200013
         SPACE 1                                                        40400013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  40600013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    40800013
*        RI    DATA RCD LENGTH                                          41000013
         SPACE 1                                                        41200013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   41400013
         SPACE 1                                                        41600013
         CL    RI,KON256           RCD LENGTH TO 256                    41800013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   42000013
         SPACE 1                                                        42200013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    42400013
         LNR   RG,RH                 256 BYTES EACH                     42600013
RBKMOVE  MVC   0(256,RF),0(RE)                                          42800013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     43000013
         AR    RF,RH                 BYTES                              43200013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    43400013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 43600013
         SPACE 2                                                        43800013
KON256   DC    F'256'                                                   44000013
KMOVE1   MVC   0(1,RF),0(RE)                                            44200013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             44400013
         BCTR  RG,0                DECR RG BY ONE                       44600013
         EX    RG,KMOVE1                                                44800013
         SPACE 1                                                        45000013
*   END OF GENERALIZED MOVE ROUTINE.                                    45200013
         SPACE 1                                                        45400013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       45600013
*                                    REMAINING RCD LENGTH               45800013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR DISK SORT 46000013
*                                    A.P. WILL NOP THIS INSTR.          46200013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    46400013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            46600013
         SPACE 2                                                        46800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   47000013
         SPACE 1                                                        47200013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   47400013
*                                    FROM OUTPUT BLOCK CHAR COUNT       47600013
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RCD PTR. FOR DISK, 47800013
*                                    A.P.WILL OVERLAY WLSTPTR WITH      48000013
*                                    WLSTPTRD                           48200013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   48400013
         ST    RG,WBLKCCNT         STORE BLK CHAR CTR IN 1ST 2 BYTES    48600013
         MVC   0(2,RC),WBLKCCNT+2                                       48800013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 49000013
         SPACE 1                                                        49200013
*   INTERFACE TO WRITE MODULE                                           49400013
         SPACE 1                                                        49600013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 49800013
         B     8(RL)               BR TO WRITE MODULE                   50000013
         SPACE 1                                                        50200013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   50400013
*     BLOCK ENDING ADDR+1. FOR DISK, RC HAS OUTPUT BLK STARTING ADDR+8  50600013
         SPACE 1                                                        50800013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   51000013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     51200013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     51400013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     51600013
*                                    OUTPUT BLOCK                       51800013
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       52000013
         SPACE 2                                                        52200013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 52400013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  52600013
         SPACE 1                                                        52800013
RBEOS    L     RE,WLSTPTR          FOR TAPE USE WLSTPTR.FOR DISK,A.P.   53000013
*                                    WILL OVLAY WLSTPTR WITH WLSTPTRD   53200013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           53400013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   53600013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      53800013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     54000013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    54200013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     54400013
         LA    RD,4                SET SWITCH TO NORMAL EOS FOR WRITE   54600013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      54800013
         SPACE 1                                                        55000013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            55200013
         SPACE 1                                                        55400013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 55600013
         B     4(RL)               BR TO WRITE MODULE                   55800013
         SPACE 2                                                        56000013
*   DEBLOCK SIDE OF PROGRAM                                             56200013
         SPACE 1                                                        56400013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   56600013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 56800013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  57000013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        57200013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       57400013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      57600013
*                                    INPUT BLK JUST VACATED             57800013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      58000013
         L     RD,WINNER           RESTORE WINNER                       58200013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    58400013
         SPACE 1                                                        58600013
*   INTERFACE TO MERGE NETWORK                                          58800013
         SPACE 1                                                        59000013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 59200013
         B     8(RL)               BR TO MERGE MODULE                   59400013
         SPACE 2                                                        59600013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     59800013
         SPACE 1                                                        60000013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         60200013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     60400013
         SPACE 1                                                        60600013
*   INTERFACE TO READ MODULE                                            60800013
         SPACE 1                                                        61000013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  61200013
         B     8(RL)               BR TO READ MODULE                    61400013
         SPACE 2                                                        61600013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  61800013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 62000013
*     RD - INCR,RE - ENDING ADDR OF BLOCK FOR TAPE OR STARTING ADDR     62200013
*     OF BLOCK FOR DISK.                                                62400013
         SPACE 1                                                        62600013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         62800013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLOCK  63000013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    63200013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     63400013
*                                    ADDRESSES                          63600013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   63800013
         SLL   RD,24               POSITION INCR IN HI BYTE             64000013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  64200013
         B     RBMERGE             BR TO MERGE                          64400013
         SPACE 2                                                        64600013
*   LIST OF CONSTANTS USED BY THE MODULE                                64800013
         SPACE 1                                                        65000013
KZERO    DC    F'0'                ZERO                                 65200013
KFOUR    DC    F'4'                FOUR                                 65400013
KEIGHT   DC    F'8'                EIGHT                                65600013
         SPACE 2                                                        65800013
*   LIST OF WORK AREAS                                                  66000013
         SPACE 1                                                        66200013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      66400013
*                                    PRESET TO 8 BY A.P.                66600013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 66800013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    67000013
WLSTPTR  DC    F'0'                ADDR IN OUTPUT BLOCK TO MOVE WINNER  67200013
*                                    A.P. INITIALLY SETS TO OUTPUT ENDG 67400013
*                                    ADDR+1 FOR TAPE,OR OUTPUT BLK      67600013
*                                    STARTG ADDR+8 FOR DISK SORT        67800013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 68000013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     68200013
         EJECT                                                          68400013
         SMPPI                                                          68600013
         END                                                            68800013
