         TITLE '      IERRBK - OS/360 SORT/MERGE - 360S-SM023 04/22/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME:*** IERRBK ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 2 RUNNING MODULE. V.L. WITH EXIT E25. 01400013
*     THE FUNCTION OF THIS MODULE IS TO HANDLE THE DEBLOCKING AND       01600013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       01800013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     02000013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     02200013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         02400013
         SPACE 1                                                        02600013
*     THE USER EXIT,E25,IS ON THE BLOCK SIDE AND IS EXECUTED ONCE FOR   02800013
*     EVERY RECORD,EXCEPT THE FIRST RECORD OF EACH OUTPUT SEQUENCE.     03000013
*     THE EXIT OCCURS AFTER THE RECORD LEAVES THE MERGE AND WHILE THE   03200013
*     PREVIOUS RECORD IS AVAILABLE IN THE OUTPUT AREA. THE EXIT IS FOR  03400013
*     SUMMARIZATION AND DELETION OF RECORDS(EXCEPT ON THE FIRST RECORD  03600013
*     OF EACH OUTPUT SEQUENCE)                                          03800013
         SPACE 1                                                        04000013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  04200013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  04400013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         04600013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     04800013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     05000013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     05200013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    05400013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   05600013
*     IS REPEATED.                                                      05800013
         SPACE 1                                                        06000013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    06200013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            06400013
         SPACE 2                                                        06600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               06800013
         SPACE 1                                                        07000013
*   IERABK                                                              07200013
         SPACE 2                                                        07400013
*LIST OF MACROS USED BY THE MODULE:                                     07600013
         SPACE 1                                                        07800013
*   SMPPI                                                               08000013
         SPACE 2                                                        08200013
*ENTRY POINTS:                                                          08400013
         SPACE 1                                                        08600013
*   FROM MERGE                     ENTRY FROM: MERGE NETWORK            08800013
*                                    CALLING SEQUENCE-                  09000013
*                                      L    RL,PPIBLK2+4                09200013
*                                      B    0(RL)      NORMAL EOD       09400013
*                                      B    12(RL)     PRIMING ENTRY    09600013
*                                      B    16(RL)     NORMAL           09800013
*   FROM READ                      ENTRY FROM: READ                     10000013
*                                    CALLING SEQUENCE-                  10200013
*                                      L    RL,PPIBLK2+4                10400013
*                                      B    4(RL)                       10600013
*   FROM WRITE                     ENTRY FROM: WRITE                    10800013
*                                    CALLING SEQUENCE-                  11000013
*                                      L    RL,PPIBLK2+4                11200013
*                                      B    8(RL)                       11400013
*   FROM E25                       ENTRY FROM:USER EXIT E25             11600013
*                                    CALLING SEQUENCE-                  11800013
*                                      RETURN  RC=(15) RETRUN ON RO     12000013
         SPACE 2                                                        12200013
*INPUT: PPI FIELDS REFERENCED                                           12400013
         SPACE 1                                                        12600013
*   PPIBDSVA                                                            12800013
*   PPILAB07                                                            13000013
*   PPISBLCT                                                            13200013
         SPACE 1                                                        13400013
*   VARIOUS ADDRESSES                                                   13600013
         SPACE 2                                                        13800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED                              14000013
         SPACE 1                                                        14200013
*   PPICOUNT                                                            14400013
*   PPIDELCT                                                            14600013
         SPACE 1                                                        14800013
*   UPDATE COUNTERS                                                     15000013
         SPACE 2                                                        15200013
*EXTERNAL ROUTINES:                                                     15400013
         SPACE 1                                                        15600013
*   NONE                                                                15800013
         SPACE 2                                                        16000013
*EXTERNAL PARAMETERS:                                                   16200013
         SPACE 1                                                        16400013
*   SEE REGISTERS                                                       16600013
         SPACE 2                                                        16800013
*EXITS: NORMAL                                                          17000013
         SPACE 1                                                        17200013
*   TO READ                        EXIT TO: READ                        17400013
*                                    CALLING SEQUENCE-                  17600013
*                                      L    RL,PPIRD+4                  17800013
*                                      B    8(RL)                       18000013
*   TO NETWORK                     EXIT TO: MERGE NETWORK               18200013
*                                    CALLING SEQUENCE-                  18400013
*                                      L    RL,PPINETM+4                18600013
*                                      B    8(RL)                       18800013
*   TO WRITE                       EXIT TO: WRITE                       19000013
*                                    CALLING SEQUENCE-                  19200013
*                                      L    RL,PPIWRT+4                 19400013
*                                      B    4(RL)      EOD              19600013
*                                      B    8(RL)      NORMAL           19800013
*   TO USER                        EXIT TO: USER EXIT E25               20000013
*                                    CALLING SEQUENCE                   20200013
*                                      L    RP,PPIX25+4                 20400013
*                                      BALR RO,RP                       20600013
         SPACE 2                                                        20800013
*EXITS: ERROR                                                           21000013
         SPACE 1                                                        21200013
*   NONE                                                                21400013
         SPACE 2                                                        21600013
*TABLES/WORK AREAS:                                                     21800013
         SPACE 1                                                        22000013
*   WMRGRCD-ADDR OF WINNER IN INPUT BUFFER          PARAM 1 TO USER     22200013
*   WOUTRCD-ADDR OF LAST RCD PUT IN OUTPUT BUFFER   PARAM 2 TO USER     22400013
*   WBLKCCNT-OUTPUT BUFFER CHARACTER COUNTER                            22600013
*   WRCDLGTH-LENGTH OF WINNER RECORD                                    22800013
*   WINNER-ADDRESS OF WINNER RECORD IN INPUT BUFFER                     23000013
*   WLSTPTR-ADDR OF A FREE AREA IN OUTPUT BUFFER TO MOVE THE WINNER     23200013
*   WLSTPTRD-PTR TO STRTG+8(DISK) OR ENDING+1(TAPE) ADDR OF OUTPUT BFR. 23400013
         SPACE 2                                                        23600013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   23800013
         SPACE 2                                                        24000013
*NOTES - THIS MODULE EXECUTES FOR ANY VARIABLE LENGTH SORT WITH USER    24200013
*        EXIT E25 ACTIVE.                                               24400013
         SPACE 2                                                        24600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            24800013
         SPACE 1                                                        25000013
RA       EQU   0                   CONTENTS IN- N/A                     25200013
*                                  USE- NOT USED                        25400013
*                                  CONTENTS OUT- N/A                    25600013
RB       EQU   1                   CONTENTS IN- N/A                     25800013
*                                  USE- BLK TO WRITE(BLOCK CHAR COUNT)  26000013
*                                     - BLK TO E25(ADDR OF PARAM LIST)  26200013
*                                     - E25 TO BLK(ADDR OF NEXT OUTPUT  26400013
*                                    RECORD)                            26600013
*                                  CONTENTS OUT- N/A                    26800013
RC       EQU   2                   CONTENTS IN- N/A                     27000013
*                                  USE- BLK TO WRITE(STARTG ADDR OF     27200013
*                                    OUTPUT BUFFER)                     27400013
*                                     - DEBLK TO READ(ADDR OF AN EMPTY  27600013
*                                    INPUT BUFFER)                      27800013
*                                  CONTENTS OUT- N/A                    28000013
RD       EQU   3                   CONTENTS IN- N/A                     28200013
*                                  USE- NTWK TO BLOCK(ADDR OF WINNER IN 28400013
*                                    INPUT BFR W/INCR IN 1ST BYTE)      28600013
*                                     - DEBLOCK TO READ(INCR IN LOW     28800013
*                                    ORDER BYTE-EMPTY BFR INCR)         29000013
*                                  CONTENTS OUT- N/A                    29200013
RE       EQU   4                   CONTENTS IN- N/A                     29400013
*                                  USE- GENERAL WORK REGISTER           29600013
*                                  CONTENTS OUT- N/A                    29800013
RF       EQU   5                   CONTENTS IN- N/A                     30000013
*                                  USE- GENERAL WORK REGISTER           30200013
*                                  CONTENTS OUT- N/A                    30400013
RG       EQU   6                   CONTENTS IN- N/A                     30600013
*                                  USE- GENERAL WORK REGISTER           30800013
*                                  CONTENTS OUT- N/A                    31000013
RH       EQU   7                   CONTENTS IN- N/A                     31200013
*                                  USE- GENERAL WORK REGISTER           31400013
*                                  CONTENTS OUT- N/A                    31600013
RI       EQU   8                   CONTENTS IN- N/A                     31800013
*                                  USE- GENERAL WORK REGISTER           32000013
*                                  CONTENTS OUT- N/A                    32200013
RJ       EQU   9                   CONTENTS IN- N/A                     32400013
*                                  USE- NOT USED                        32600013
*                                  CONTENTS OUT- N/A                    32800013
RK       EQU   10                  CONTENTS IN- N/A                     33000013
*                                  USE- NOT USED                        33200013
*                                  CONTENTS OUT- N/A                    33400013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    33600013
*                                  USE- MODULE BASE REG                 33800013
*                                  CONTENTS OUT- NTWK ENTRY PT          34000013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   34200013
*                                  USE- NOT USED                        34400013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  34600013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          34800013
*                                  USE- PPI REFERENCE,REGISTER SAVE     35000013
*                                    AREA                               35200013
*                                  CONTENTS OUT- ADDRESS OF PPI         35400013
RO       EQU   14                  CONTENTS IN- N/A                     35600013
*                                  USE- RETURN REG FROM EXIT E25        35800013
*                                  CONTENTS OUT- N/A                    36000013
RP       EQU   15                  CONTENTS IN- N/A                     36200013
*                                  USE- BRANCH REG TO EXIT E25          36400013
*                                     - RETURN CODE FROM EXIT E25       36600013
*                                  CONTENTS OUT- N/A                    36800013
         SPACE 2                                                        37000013
*START OF MODULE CODE PROPER:                                           37200013
         SPACE 2                                                        37400013
IERRBK   CSECT                                                          37600013
*1581394000,448000,482000                                          4553 37700018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    37800013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        38000013
         SPACE 1                                                        38200013
*   ENTRY TABLE                                                         38400013
         SPACE 1                                                        38600013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             38800013
         B     RBRDRTRN            FROM READ MODULE                     39000013
         B     RBWRT               FROM WRITE MODULE                    39200013
         B     RBBPSUS1            PRIME ENTRY,BYPASS EXIT RTN     4553 39400018
         SPACE 1                                                        39600013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   39800013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      40000013
         SPACE 1                                                        40200013
         ST    RD,WMRGRCD          PARAM 1 TO USER.ADDR OF RCD IN INPUT 40400013
*                                    BLOCK                              40600013
         SPACE 1                                                        40800013
*   CALL MACRO EXPANSION INSTRUCTIONS TO USER EXIT E25                  41000013
         SPACE 1                                                        41200013
         L     RP,PPIX25+4         ADDR OF USER EXIT E25                41400013
         LA    RB,WMRGRCD                                               41600013
         BALR  RO,RP                                                    41800013
         SPACE 1                                                        42000013
*   RETURN FROM USER                                                    42200013
         SPACE 1                                                        42400013
         B     *+4(RP)                                                  42600013
         B     RBBPSUSR            DO NOTHING                           42800013
         L     RG,PPIDELCT         DELETE COUNTER                       43000013
         LA    RG,1(0,RG)          INCR DELETE CTR BY 1                 43200013
         ST    RG,PPIDELCT         SAVE UPDATED DELETE CTR              43400013
         ST    RD,WINNER           SAVE WINNER ADDR (DEBLK WILL DELETE) 43600013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  43800013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            44000013
RBBPSUS1 LR    RB,RD                                               4553 44100018
         SPACE 1                                                        44200013
RBBPSUSR L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      44400013
*                                    PRESET TO 8 BY A.P.                44600013
         MVC   WRCDLGTH+2(2),0(RB) MOVE RCD LENGTH TO PROPER BNDRY 4553 44800018
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  45000013
*                                    CTR                                45200013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 45400013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     45600013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          45800013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      46000013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     46200013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 46400013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 46600013
*                                    HI CORE TO LOW. A.P. WILL NOP THIS 46800013
*                                    INSTR IF DISK                      47000013
         ST    RF,WOUTRCD          PARAM 2 TO USER.ADDR OF RCD IN       47200013
*                                    OUTPUT BLOCK                       47400013
         L     RG,PPICOUNT         RECORD COUNTER                       47600013
         LA    RG,1(0,RG)          INCR BY 1 FOR THIS RCD               47800013
         ST    RG,PPICOUNT         STORE UPDATED RECORD COUNTER         48000013
         LR    RE,RB               ADDR OF RCD IN INPUT AREA       4553 48200018
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           48400013
         SPACE 1                                                        48600013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   48800013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   49000013
         SPACE 1                                                        49200013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  49400013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    49600013
*        RI    DATA RCD LENGTH                                          49800013
         SPACE 1                                                        50000013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   50200013
         SPACE 1                                                        50400013
         CL    RI,KON256           RCD LENGTH TO 256                    50600013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   50800013
         SPACE 1                                                        51000013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    51200013
         LNR   RG,RH                 256 BYTES EACH                     51400013
RBKMOVE  MVC   0(256,RF),0(RE)                                          51600013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     51800013
         AR    RF,RH                 BYTES                              52000013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    52200013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 52400013
         SPACE 2                                                        52600013
KON256   DC    F'256'                                                   52800013
KMOVE1   MVC   0(1,RF),0(RE)                                            53000013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             53200013
         BCTR  RG,0                DECR RG BY ONE                       53400013
         EX    RG,KMOVE1                                                53600013
         SPACE 1                                                        53800013
*   END OF GENERALIZED MOVE ROUTINE.                                    54000013
         SPACE 1                                                        54200013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       54400013
*                                    REMAINING RCD LENGTH               54600013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR DISK SORT 54800013
*                                    A.P. WILL NOP THIS INSTR.          55000013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    55200013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            55400013
         SPACE 2                                                        55600013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   55800013
         SPACE 1                                                        56000013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   56200013
*                                    FROM OUTPUT BLOCK CHAR COUNT       56400013
         ST    RB,WRBSAVE          STORE MOD RCD ADDR              4553 56500018
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RCD PTR. FOR DISK, 56600013
*                                    A.P.WILL OVERLAY WLSTPTR WITH      56800013
*                                    WLSTPTRD                           57000013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   57200013
         ST    RG,WBLKCCNT         ALIGN TO WD BOUNDARY                 57400013
         MVC   0(2,RC),WBLKCCNT+2  STORE BLOK CHAR CTR IN 1ST 2 BYTES   57600013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 57800013
         SPACE 1                                                        58000013
*   INTERFACE TO WRITE MODULE                                           58200013
         SPACE 1                                                        58400013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 58600013
         B     8(RL)               BR TO WRITE MODULE                   58800013
         SPACE 1                                                        59000013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   59200013
*     BLOCK ENDING ADDR+1. FOR DISK, RC HAS OUTPUT BLK STARTING ADDR+8  59400013
         SPACE 1                                                        59600013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   59800013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     60000013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     60200013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     60400013
*                                    OUTPUT BLOCK                       60600013
         L     RB,WRBSAVE          RELOAD MOD RCD ADDR             4553 60700018
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       60800013
         SPACE 2                                                        61000013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 61200013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  61400013
         SPACE 1                                                        61600013
RBEOS    L     RE,WLSTPTR          FOR TAPE USE WLSTPTR.FOR DISK,A.P.   61800013
*                                    WILL OVLAY WLSTPTR WITH WLSTPTRD   62000013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           62200013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   62400013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      62600013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     62800013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    63000013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     63200013
         LA    RD,4                SET SWITCH TO NORMAL EOS FOR WRITE   63400013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      63600013
         SPACE 1                                                        63800013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            64000013
         SPACE 1                                                        64200013
         L     RL,PPIWRT+4                                              64400013
         B     4(RL)               BR TO WRITE MODULE                   64600013
         EJECT                                                          64800013
*   DEBLOCK SIDE OF PROGRAM                                             65000013
         SPACE 1                                                        65200013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   65400013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 65600013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  65800013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        66000013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       66200013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      66400013
*                                    INPUT BLK JUST VACATED             66600013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      66800013
         L     RD,WINNER           RESTORE WINNER                       67000013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    67200013
         SPACE 1                                                        67400013
*   INTERFACE TO MERGE NETWORK                                          67600013
         SPACE 1                                                        67800013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 68000013
         B     8(RL)               BR TO MERGE MODULE                   68200013
         SPACE 2                                                        68400013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     68600013
         SPACE 1                                                        68800013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         69000013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     69200013
         SPACE 1                                                        69400013
*   INTERFACE TO READ MODULE                                            69600013
         SPACE 1                                                        69800013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  70000013
         B     8(RL)               BR TO READ MODULE                    70200013
         SPACE 2                                                        70400013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  70600013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 70800013
*     RD - INCR,RE - ENDING ADDR OF BLOCK FOR TAPE OR STARTING ADDR     71000013
*     OF BLOCK FOR DISK.                                                71200013
         SPACE 1                                                        71400013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         71600013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLK    71800013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    72000013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     72200013
*                                    ADDRESSES                          72400013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   72600013
         SLL   RD,24               POSITION INCR IN HI BYTE             72800013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  73000013
         B     RBMERGE             BR TO MERGE NETWORK                  73200013
         SPACE 2                                                        73400013
*   LIST OF CONSTANTS USED BY THE MODULE                                73600013
         SPACE 1                                                        73800013
KZERO    DC    F'0'                ZERO                                 74000013
KFOUR    DC    F'4'                FOUR                                 74200013
KEIGHT   DC    F'8'                EIGHT                                74400013
         SPACE 2                                                        74600013
*   LIST OF WORK AREAS                                                  74800013
         SPACE 1                                                        75000013
WMRGRCD  DC    F'0'                ADDR OF RCD IN INPUT BLK-USER PARAM1 75200013
WOUTRCD  DC    F'0'                ADDR OF RCD IN OUTPUT BLK-USR PARAM2 75400013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      75600013
*                                    PRESET TO 8 BY A.P.                75800013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 76000013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    76200013
WLSTPTR  DC    F'0'                ADDR IN OUTPUT BLOCK TO MOVE WINNER  76400013
*                                    A.P. INITIALLY SETS TO OUTPUT ENDG 76600013
*                                    ADDR+1 FOR TAPE,OR OUTPUT BLK      76800013
*                                    STARTG ADDR+8 FOR DISK SORT        77000013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 77200013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     77400013
WRBSAVE  DC    F'0'                CURRENT MODIFIED RCD ADDR       4553 77500018
         EJECT                                                          77600013
         SMPPI                                                          77800013
         END                                                            78000013
