         TITLE 'IERRBM - OS/360 SORT/MERGE - 360S-SM-023 - 4/22/66'     00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRBM ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 3 RUNNING MODULE. F.L. WITH E35.      02100013
*   THE FUNCTION OF THIS MODULE IS TO BLOCK FIXED LENGTH RECORDS. TO    02400013
*   ACCOMPLISH THIS, IT USES A MOVE ROUTINE WITH THE PUT LOCATE MACRO.  02700013
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      03000013
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 03300013
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  03600013
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   03900013
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 04200013
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   04500013
         SPACE 1                                                        04800013
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   05100013
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      05400013
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      05700013
         SPACE 1                                                        06000013
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       06300013
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      06600013
*   OUTPUT BUFFER INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.       06900013
         SPACE 1                                                        07200013
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  07500013
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    07800013
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 08100013
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    08400013
*   THIRD PARAMETER OF THE PARAMETER LIST                               08700013
         SPACE 1                                                        09000013
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        09300013
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     09600013
         SPACE 1                                                        09900013
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           10200013
         SPACE 1                                                        10500013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      10800013
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET                        11100013
         SPACE 2                                                        11400013
*THIS MODULE APPEARS AS A DSECT IN-   IERABM.                           11700013
*                                                                       12000013
*LIST OF MACROS USED BY THE MODULE                                      12300013
         SPACE 1                                                        12600013
*   SMPPI                                                               12900013
*   PUT                                                                 13200013
         SPACE 2                                                        13500013
*ENTRY POINTS:                                                          13800013
         SPACE 1                                                        14100013
*   FROM MERGE NTWK                ENTRY FROM MERGE NETWORK             14400013
*                                    CALLING SEQUENCE-                  14700013
*                                      L    RL,PPIBLK+4                 15000013
*                                      B    0(RL)      LAST RCD         15300013
*                                      B    4(RL)      NORMAL           15600013
*   FROM SYSTEM PUT                ENTRY FROM PUT                       15900013
*                                    CALLING SEQUENCE-                  16200013
*                                      BR   RO                          16500013
*   FROM OPEN OUTPUT/EOJ           ENTRY FROM IERRPG                    16800013
*                                    CALLING SEQUENCE-                  17100013
*                                      L    RL,PPIBLK+4                 17400013
*                                      B    0(RL)      ZERO INPUT FILE  17700013
*   FROM  USER                     ENTRY FROM EXIT E35                  18000013
*                                    CALLING SEQUENCE                   18300013
*                                      RETURN   RC=(15)                 18600013
         SPACE 2                                                        18900013
*INPUT: - PPI FIELDS REFERENCED                                         19200013
         SPACE 1                                                        19500013
*   PPIBDSVA    PPIX35                                                  19800013
*   PPICOUNT                                                            20100013
*   PPIDEB                                                              20400013
         SPACE 1                                                        20700013
*   VARIOUS ADDRESSES, COUNTERS                                         21000013
         SPACE 2                                                        21300013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            21600013
         SPACE 1                                                        21900013
*   PPICOUNT                                                            22200013
*   PPIDOOBA                                                            22500013
*   PPIDOUO                                                             22800013
         SPACE 1                                                        23100013
*   UPDATE COUNTERS AND OUTPUT BUFFER ADDRESSES                         23400013
         SPACE 1                                                        23700013
*EXTERNAL ROUTINES                                                      24000013
         SPACE 1                                                        24300013
*   MOVE ROUTINE IN GENERATED CORE                                      24600013
         SPACE 2                                                        24900013
*EXTERNAL PARAMETERS:                                                   25200013
         SPACE 1                                                        25500013
*   SEE REGISTERS                                                       25800013
         SPACE 2                                                        26100013
*EXITS-NORMAL:                                                          26400013
         SPACE 1                                                        26700013
*   DEBLOCK                        EXIT TO DEBLOCK                      27000013
*                                    CALLING SEQUENCE-                  27300013
*                                      L    RL,PPIDEB+4                 27600013
*                                      B    4(RL)                       27900013
*   PUT LOCATE                     EXIT TO OS PUT LOCATE RTN            28200013
*                                    CALLING SEQUENCE                   28500013
*                                      L    RF,WDCB    DCB ADDR         28800013
*                                      PUT  (RF)                        29100013
*   END OF JOB                     EXIT TO IERRPG                       29400013
*                                    CALLING SEQUENCE-                  29700013
*                                      L    RL,PPIWRT+4                 30000013
*                                      BR   RL                          30300013
*   USER                           EXIT TO EXIT E35                     30600013
*                                    CALLING SEQUENCE-                  30900013
*                                      L    RP,PPIX35+4                 31200013
*                                      BALR RO,RP                       31500013
         SPACE 2                                                        31800013
*EXITS-ERROR:                                                           32100013
         SPACE 1                                                        32400013
*   NONE                                                                32700013
         SPACE 2                                                        33000013
*TABLES/WORK AREAS:                                                     33300013
         SPACE 1                                                        33600013
*   WMRGRCD-ADDR OF NEXT RCD OT BE PUT(IN OUTPUT BUFFER)                33900013
*   WOPBUFAD-ADDR OF LAST RCD PUT(IN OUTPUT BUFFER)                     34200013
*   WINTEGSW-USER SEQUENCE SWITCH                                       34500013
*   WDCB-ADDRESS OF OUTPUT DCB                                          34800013
*   WINSRTSW-USER INSERT SWITCH                                         35100013
*   WSYSEOF-SYSTEM END OF FILE SWITCH                                   35400013
*   WUSREOF-USER E35 END OF FILE SWITCH                                 35700013
         SPACE 2                                                        36000013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   36300013
         SPACE 2                                                        36600013
*NOTES: THIS MODULE IS USED WITH ANY FIXED LENGTH SORT WITH E35 ACTIVE  36900013
         EJECT                                                          37200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            37500013
         SPACE 1                                                        37800013
RA       EQU   0                   CONTENTS IN- N/A                     38100013
*                                  USED- NOT USED                       38400013
*                                  CONTENTS OUT- N/A                    38700013
RB       EQU   1                   CONTENTS IN- N/A                     39000013
*                                  USED- E35 TO BLK(ADDR OF NXT RCD TO  39300013
*                                        BE PUT                         39600013
*                                       -PUT TO BLK(ADDR OF A FREE AREA 39900013
*                                        IN THE OUTPUT BFR)             40200013
*                                       -BLK TO E35(ADDR OF PARAM LIST) 40500013
*                                  CONTENTS OUT- N/A                    40800013
RC       EQU   2                   CONTENTS IN- N/A                     41100013
*                                  USED- NOT USED                       41400013
*                                  CONTENTS OUT- N/A                    41700013
RD       EQU   3                   CONTENTS IN- NTWK TO BLK(ADDR OF A   42000013
*                                               WINNER IN INPUT BFR W/  42300013
*                                               FILE INCR IN 1ST BYTE)  42600013
*                                  USED- NOT USED                       42900013
*                                  CONTENTS OUT- BLK TO DEBLK(INCR OF   43200013
*                                                WINNER'S FILE)         43500013
RE       EQU   4                   CONTENTS IN- N/A                     43800013
*                                  USED- BLK TO MOVE RTN(ADDR OF RCD IN 44100013
*                                        INPUT BUFFER)                  44400013
*                                  CONTENTS OUT- N/A                    44700013
RF       EQU   5                   CONTENTS IN- N/A                     45000013
*                                  USED- BLK TO MOVE RTN(ADDR OF FREE   45300013
*                                        AREA IN OUTPUT BFR)            45600013
*                                      - BLK TO PUT(ADDR OF OUTPUT DCB) 45900013
*                                  CONTENTS OUT- N/A                    46200013
RG       EQU   6                   CONTENTS IN- N/A                     46500013
*                                  USED- RECORD COUNTER                 46800013
*                                  CONTENTS OUT- N/A                    47100013
RH       EQU   7                   CONTENTS IN- N/A                     47400013
*                                  USED- DELETE/SUMMARIZE COUNTER       47700013
*                                  CONTENTS OUT- N/A                    48000013
RI       EQU   8                   CONTENTS IN- N/A                     48300013
*                                  USED- INSERT COUNTER                 48600013
*                                  CONTENTS OUT- N/A                    48900013
RJ       EQU   9                   CONTENTS IN- N/A                     49200013
*                                  USED- NOT USED                       49500013
*                                  CONTENTS OUT- N/A                    49800013
RK       EQU   10                  CONTENTS IN- N/A                     50100013
*                                  USE- NOT USED                        50400013
*                                  CONTENTS OUT- N/A                    50700013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    51000013
*                                  USED- MODULE BASE REG                51300013
*                                  CONTENTS OUT- DEBLOCK ENTRY PT       51600013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   51900013
*                                  USED- NOT USED                       52200013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  52500013
RN       EQU   13                  CONTENTS IN- ADDR OF PPI             52800013
*                                  USED- PPI REFERENCES                 53100013
*                                  CONTENTS OUT- ADDR OF PPI            53400013
RO       EQU   14                  CONTENTS IN- N/A                     53700013
*                                  USED- RETURN REG FROM MOVE,PUT,E35   54000013
*                                  CONTENTS OUT- N/A                    54300013
RP       EQU   15                  CONTENTS IN- N/A                     54600013
*                                  USED- BRANCH REG TO PUT & MOVE RTN   54900013
*                                      - RETURN CODE FROM EXIT E35      55200013
*                                  CONTENTS OUT- N/A                    55500013
         SPACE 2                                                        55800013
*START OF MODULE CODE PROPER:                                           56100013
         SPACE 2                                                        56400013
IERRBM   CSECT                                                          56700013
*1582                                                              4549 56800018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    57000013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  57300013
         SPACE 1                                                        57600013
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       57900013
         SPACE 1                                                        58200013
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           58500013
*                                  FROM READ PRIME ZERO INPUT FILE      58800013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     59100013
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  59400013
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   59700013
         SPACE 1                                                        60000013
* CALL MACRO EXPANSION TO USER EXIT E35                                 60300013
         SPACE 1                                                        60600013
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  60900013
*                                    B RBLOADRE ON USER EOF             61200013
         L     RP,PPIX35+4         IF ATTACHED,PPIX35 WILL HAVE ADDR    61500013
*                                    OF ATTACHED EXIT FROM PPI          61800013
         BALR  RO,RP               BR TO USER                           62100013
         SPACE 1                                                        62400013
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        62700013
         SPACE 1                                                        63000013
         B     *+4(15)                                                  63300013
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  63600013
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          63900013
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       64200013
         SPACE 1                                                        64500013
* INSERT A RECORD                                                       64800013
         SPACE 1                                                        65100013
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                65400013
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             65700013
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        66000013
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  66300013
         SPACE 2                                                        66600013
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 66900013
         SPACE 1                                                        67200013
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  67500013
*                                    FOR MERGE NETWORK SEQU CHECK       67800013
RBLOADRE LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  68100013
*                                    MOVE RTN REG. THIS INSTR WILL BE   68400013
*                                    OVLAYD BY LR RE,RD ON USER EOF     68700013
         L     RF,WDCB             DCB ADDRESS                          69000013
         PUT   (RF)                UPDATE ADDR IN OUTPUT AREA(REG RB)   69300013
         SPACE 1                                                        69600013
         ST    RB,WOPBUFAD         SAVE ADDR OF RCD IN OUTPUT BFR TO    69900013
*                                    MOVE RCD(2 OF 2 PARAM TO USER)     70200013
         LR    RF,RB               LOAD ADDR OF OUT AREA FOR MOVE RTN   70500013
         L     RP,PPIBDSVA+8       LOAD MOVE RTN BASE REG W/ADDR OF     70800013
*                                    MOVE RCD RTN                       71100013
         BALR  RO,RP               BR TO MOVE RTN-MOVE RCD TO OUT AREA  71400013
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   71700013
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   72000013
*                                    IN PPI                             72300013
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               72600013
         B     RBUSREXT            BR TO USER EXIT                      72900013
         SPACE 2                                                        73200013
RBDOOBA  ST    RB,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         73500013
         LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          73800013
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        74100013
         SPACE 1                                                        74400013
* INTERFACE TO DEBLOCK MODULE. RD HAS FILE NO OF WINNER IN 1ST BYTE     74700013
         SPACE 1                                                        75000013
         L     RL,PPIDEB+4         LOAD DEBLOCK ADDR                    75300013
         B     4(0,RL)             BR TO DEBLOCK MODULE                 75600013
         SPACE 2                                                        75900013
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               76200013
         SPACE 1                                                        76500013
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     76800013
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     77100013
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        77400013
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   77700013
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           78000013
         B     RBSETPAR            OFF,BR TO USER ROUTINE               78300013
         SPACE 2                                                        78600013
* USER END OF FILE ROUTINE                                              78900013
         SPACE 1                                                        79200013
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          79500013
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   79800013
         MVI   RBLOADRE+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      80100013
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   80400013
*                                    CHECK THE REST OF THE RCDS         80700013
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 81000013
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          81300013
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 81400018
         BO    RBEOJ               IF YES BR TO EOJ                4549 81500018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         81600013
         SPACE 2                                                        81900013
* LINKAGE TO END OF JOB MODULE                                          82200013
RBEOJ    STM   RG,RI,PPICOUNT      SAVE COUNTERS                        82500013
         L     RL,PPIWRT+4         EOJ MODULE ADDR                      82800013
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      83100013
         SPACE 2                                                        83400013
* DELETE OR SUMMARIZE A RECORD                                          83700013
         SPACE 1                                                        84000013
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 84300013
         MVC   PPIDOOBA(4),WOPBUFAD  ADDR OF RCD IN OUTPUT BFR(THE RCD  84600013
*                                      BEFORE THE DELETD OR SUMRZD RCD) 84900013
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       85200013
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        85500013
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  85800013
*                                    FOR MERGE NETWORK SEQU CHECK       86100013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         86400013
         SPACE 2                                                        86700013
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    87000013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         87300013
         EJECT                                                          87600013
* LIST OF CONSTANTS USED BY THE MODULE                                  87900013
KZERO    DC    F'0'                ZERO                                 88200013
KFOUR    DC    F'4'                FOUR                                 88500013
         SPACE 2                                                        88800013
* LIST OF WORK AREAS                                                    89100013
         SPACE 1                                                        89400013
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   89700013
WOPBUFAD DC    F'0'                PARAM 2,ADDR OF LAST RCD PUT(OUTBUF) 90000013
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     90300013
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  90600013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 90900013
*                                    LOADED BY ASSGN RTN                91200013
WINSRTSW DC    X'00'               INSERT SWITCH                        91500013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            91800013
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              92100013
RINSERT  EQU   RI                                                       92400013
RDELSUMM EQU   RH                                                       92700013
RCDCTR   EQU   RG                                                       93000013
         SMPPI                                                          93300013
         END                                                            93600013
