         TITLE '      IERRBO - OS/360 SORT/MERGE - 360S-SM023 04/22/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME:*** IERRBO ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 3 RUNNING MODULE. V.L. WITH E35       01400013
*   THE FUNCTION OF THIS MODULE IS TO BLOCK VARIABLE LENGTH RECORDS. TO 01600013
*   ACCOMPLISH THIS IT USES A MOVE ROUTINE WITH THE PUT LOCATE MACRO.   01800013
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      02000013
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 02200013
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  02400013
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   02600013
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 02800013
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   03000013
         SPACE 1                                                        03200013
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   03400013
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      03600013
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      03800013
         SPACE 1                                                        04000013
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       04200013
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      04400013
*   OUTPUT BUFFER INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.       04600013
         SPACE 1                                                        04800013
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  05000013
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    05200013
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 05400013
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    05600013
*   THIRD PARAMETER OF THE PARAMETER LIST                               05800013
         SPACE 1                                                        06000013
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        06200013
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     06400013
         SPACE 1                                                        06600013
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           06800013
         SPACE 1                                                        07000013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      07200013
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET                        07400013
         SPACE 2                                                        07600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               07800013
         SPACE 1                                                        08000013
*   IERABO                                                              08200013
         SPACE 2                                                        08400013
*LIST OF MACROS USED BY THE MODULE:                                     08600013
         SPACE 1                                                        08800013
*   SMPPI                                                               09000013
*   PUT                                                                 09200013
         SPACE 2                                                        09400013
*ENTRY POINTS:                                                          09600013
         SPACE 1                                                        09800013
*   FROM MERGE NETWORK             ENTRY FROM MERGE NETWORK:            10000013
*                                    CALLING SEQUENCE-                  10200013
*                                      L    RL,PPIBLK+4                 10400013
*                                      B    0(RL)      LAST RECORD      10600013
*                                      B    4(RL)      NORMAL           10800013
*   FROM  SYSTEM PUT               ENTRY FROM PUT :                     11000013
*                                    CALLING SEQUENCE-                  11200013
*                                      BR   RO                          11400013
*   FROM OPEN OUTPUT/EOJ           ENTRY FROM IERRPG:                   11600013
*                                    CALLING SEQUENCE-                  11800013
*                                      L    RL,PPIBLK+4                 12000013
*                                      B    0(RL)      ZERO INPUT FILE  12200013
*   FROM USER EXIT                 ENTRY FROM EXIT E35                  12400013
*                                    CALLING SEQUENCE-                  12600013
*                                      RETURN  RC=(15) RO = RETURN REG  12800013
         SPACE 2                                                        13000013
*INPUT: PPI FIELDS REFERENCED                                           13200013
         SPACE 1                                                        13400013
*   PPICOUNT    PPIX35                                                  13600013
*   PPIDOOBA                                                            13800013
*   PPIDEB                                                              14000013
         SPACE 1                                                        14200013
*   VARIOUS ADDRESSES AND COUNTERS                                      14400013
         SPACE 2                                                        14600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             14800013
         SPACE 1                                                        15000013
*   PPICOUNT                                                            15200013
*   PPIDOOBA                                                            15400013
*   PPIDOUO                                                             15600013
         SPACE 1                                                        15800013
*   UPDATE COUNTERS AND OUTPUT BUFFER ADDRESSES                         16000013
         SPACE 2                                                        16200013
*EXTERNAL ROUTINES:                                                     16400013
         SPACE 1                                                        16600013
*   NONE                                                                16800013
         SPACE 2                                                        17000013
*EXTERNAL PARAMETERS:                                                   17200013
         SPACE 1                                                        17400013
*   SEE REGISTERS                                                       17600013
         SPACE 2                                                        17800013
*EXITS: NORMAL                                                          18000013
         SPACE 1                                                        18200013
*   DEBLOCK                        EXIT TO DEBLOCK                      18400013
*                                    CALLING SEQUENCE-                  18600013
*                                      L    RL,PPIDEB+4                 18800013
*                                      B    4(RL)                       19000013
*   PUT LOCATE                     EXIT TO OS PUT LOCATE RTN            19200013
*                                    CALLING SEQUENCE                   19400013
*                                      L    RF,WDCB    DCB ADDR         19600013
*                                      PUT  (RF)                        19800013
*   END OF JOB                     EXIT TO IERRPG                       20000013
*                                    CALLING SEQUENCE-                  20200013
*                                      L    RL,PPIWRT+4                 20400013
*                                      BR   RL                          20600013
*   USER                           EXIT TO EXIT E35                     20800013
*                                    CALLING SEQUENCE                   21000013
*                                      L    RP,PPIX35+4                 21200013
*                                      BALR RO,RP                       21400013
         SPACE 2                                                        21600013
*EXITS: ERROR                                                           21800013
         SPACE 1                                                        22000013
*   NONE                                                                22200013
         SPACE 2                                                        22400013
*TABLES/WORK AREAS:                                                     22600013
         SPACE 1                                                        22800013
*   WRCDLGTH-LENGTH OF RECORD TO MOVE TO OUTPUT BUFFER                  23000013
*   WMRGRCD-ADDR OF WINNER RECORD IN INPUT BUFFER                       23200013
*   WOPBUFAD-ADDR OF WINNER RECORD IN OUTPUT BUFFER                     23400013
*   WINTEGSW-SEQUENCE CHECK SWITCH SET BY USER                          23600013
*   WDCB-OUTPUT DCB ADDRESS                                             23800013
*   WINSRTSW-INSERT SWITCH IS TURNED ON FOR INSERTING RECORDS           24000013
*   WSYSEOF-SYSTEM END OF FILE SW TURNED ON WHEN INPUT EOF IS REACHED   24200013
*   WUSREOF-USER END OF FILE SWITCH IS TURNED ON AFTER USER REACHES EOF 24400013
         SPACE 2                                                        24600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  24800013
         SPACE 2                                                        25000013
*NOTES:                                                                 25200013
         SPACE 1                                                        25400013
*   THIS MODULE WILL EXECUTE FOR ANY VARIABLE LENGTH SORT WITH USER     25600013
*   EXIT E35.                                                           25800013
         SPACE 2                                                        26000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            26200013
         SPACE 1                                                        26400013
RA       EQU   0                   CONTENTS IN- N/A                     26600013
*                                  USE- NOT USED                        26800013
*                                  CONTENTS OUT- N/A                    27000013
RB       EQU   1                   CONTENTS IN- N/A                     27200013
*                                  USE- E35 TO BLK(ADDR OF NEXT RECORD  27400013
*                                    TO BE PUT)                         27600013
*                                     - PUT TO BLK(ADDR OF A FREE AREA  27800013
*                                    IN THE OUTPUT BUFFER)              28000013
*                                     - BLK TO E35(ADDR OF A PARAMETER  28200013
*                                    LIST)                              28400013
*                                  CONTENTS OUT- N/A                    28600013
RC       EQU   2                   CONTENTS IN- N/A                     28800013
*                                  USE- NOT USED                        29000013
*                                  CONTENTS OUT- N/A                    29200013
RD       EQU   3                   CONTENTS IN- NTWK TO BLK(ADDR OF A   29400013
*                                    WINNER IN INPUT BFR W/FILE INCR IN 29600013
*                                    1ST BYTE)                          29800013
*                                  USE- NOT USED                        30000013
*                                  CONTENTS OUT- BLK TO DEBLK(INCR OF   30200013
*                                    WINNER'S FILE)                     30400013
RE       EQU   4                   CONTENTS IN- N/A                     30600013
*                                  USE- WORK REGISTER HAVING ADDR OF    30800013
*                                    WINNER IN INPUT BUFFER             31000013
*                                  CONTENTS OUT- N/A                    31200013
RF       EQU   5                   CONTENTS IN- N/A                     31400013
*                                  USE- WORK REGISTER HAVING ADDR OF    31600013
*                                    AREA IN OUTPUT BUFFER TO MOVE RCD  31800013
*                                     - BLK TO PUT(ADDR OF OUTPUT DCB)  32000013
*                                  CONTENTS OUT- N/A                    32200013
RG       EQU   6                   CONTENTS IN- N/A                     32400013
*                                  USE- GENERAL WORK REGISTER           32600013
*                                     - RECORD COUNTER                  32800013
*                                  CONTENTS OUT- N/A                    33000013
RH       EQU   7                   CONTENTS IN- N/A                     33200013
*                                  USE- DELETE SUMMARIZE COUNTER        33400013
*                                     - GENERAL WORK REGISTER           33600013
RI       EQU   8                   CONTENTS IN- N/A                     33800013
*                                  USE- LENGTH OF WINNER RECORD         34000013
*                                     - INSERT COUNTER                  34200013
*                                  CONTENTS OUT - N/A                   34400013
RJ       EQU   9                   CONTENTS IN- N/A                     34600013
*                                  USE- NOT USED                        34800013
*                                  CONTENTS OUT- N/A                    35000013
RK       EQU   10                  CONTENTS IN- N/A                     35200013
*                                  USE- NOT USED                        35400013
*                                  CONTENTS OUT- N/A                    35600013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    35800013
*                                  USE- MODULE BASE REGISTER            36000013
*                                  CONTENTS OUT- DEBLOCK ENTRY PT       36200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   36400013
*                                  USE- NOT USED                        36600013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  36800013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          37000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     37200013
*                                    AREA                               37400013
*                                  CONTENTS OUT- ADDRESS OF PPI         37600013
RO       EQU   14                  CONTENTS IN- N/A                     37800013
*                                  USE- RETURN REG FROM PUT AND USER    38000013
*                                    EXIT E35.                          38200013
*                                  CONTENTS OUT- N/A                    38400013
RP       EQU   15                  CONTENTS IN- N/A                     38600013
*                                  USE- BRANCH REG TO PUT AND EXIT E35  38800013
*                                     - RETURN CODE FROM EXIT E35.      39000013
*                                  CONTENTS OUT- N/A                    39200013
         SPACE 2                                                        39400013
*START OF MODULE CODE PROPER:                                           39600013
         SPACE 2                                                        39800013
IERRBO   CSECT                                                          40000013
*1582                                                              4549 40100018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    40200013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  40400013
         USING IHADCB,RF                                                40600013
         SPACE 1                                                        40800013
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       41000013
         SPACE 1                                                        41200013
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           41400013
*                                  FROM READ PRIME ZERO INPUT FILE      41600013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     41800013
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  42000013
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   42200013
         SPACE 1                                                        42400013
* CALL MACRO EXPANSION TO USER EXIT E35                                 42600013
         SPACE 1                                                        42800013
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  43000013
*                                    B RBLOADRE ON USER EOF             43200013
         L     RP,PPIX35+4         IF ATTACHED, PPIX35 WILL HAVE ADDR   43400013
*                                    OF ATTACHED EXIT FROM PPI          43600013
         BALR  RO,RP               BR TO USER                           43800013
         SPACE 1                                                        44000013
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        44200013
         SPACE 1                                                        44400013
         B     *+4(15)                                                  44600013
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  44800013
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          45000013
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       45200013
         SPACE 1                                                        45400013
* INSERT A RECORD                                                       45600013
         SPACE 1                                                        45800013
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                46000013
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             46200013
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        46400013
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  46600013
         SPACE 2                                                        46800013
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 47000013
         SPACE 1                                                        47200013
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  47400013
*                                    FOR MERGE NETWORK SEQU CHECK       47600013
RBLOADRE MVC   WRCDLGTH+2(2),0(RB)  MOVE RCD LENGTH TO A BOUNDARY. RB   47800013
*                                     WILL BE OVLAYD BY RD ON USER EOF. 48000013
RBOVLAY1 LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  48200013
*                                    MOVE RTN REG. THIS INSTR WILL BE   48400013
*                                    OVLAYD BY LR RE,RD ON USER EOF     48600013
         L     RF,WDCB             DCB ADDRESS                          48800013
         MVC   DCBLRECL(2),WRCDLGTH+2  RCD LENGTH                       49000013
         PUT   (RF)                UPDATE ADDR IN OUTPUT AREA(REG RB)   49200013
         SPACE 1                                                        49400013
         ST    RB,WOPBUFAD         SAVE ADDR OF RCD IN OUTPUT BFR TO    49600013
*                                    MOVE RCD(2 OF 2 PARAM TO USER)     49800013
         LR    RF,RB               LOAD ADDR OF OUT AREA FOR MOVE RTN   50000013
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        50200013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           50400013
         SPACE 1                                                        50600013
* GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA     50800013
*   AREA TO ANOTHER, REGISTERS ARE USED AS FOLLOWS-                     51000013
         SPACE 1                                                        51200013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  51400013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    51600013
*        RI    DATA RCD LENGTH                                          51800013
         SPACE 1                                                        52000013
* IN ADDITION THE ROUTINE USES REGISTERS RG AND RH                      52200013
         SPACE 1                                                        52400013
         CL    RI,KON256           RCD LENGTH TO 256                    52600013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   52800013
         SPACE 1                                                        53000013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    53200013
         LNR   RG,RH                 256 BYTES EACH                     53400013
RBKMOVE  MVC   0(256,RF),0(RE)                                          53600013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     53800013
         AR    RF,RH                 BYTES                              54000013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    54200013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 54400013
         SPACE 1                                                        54600013
KON256   DC    F'256'                                                   54800013
KMOVE1   MVC   0(1,RF),0(RE)                                            55000013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             55200013
         BCTR  RG,0                DECR RG BY ONE                       55400013
         EX    RG,KMOVE1                                                55600013
         SPACE 1                                                        55800013
* END OF GENERALIZED MOVE ROUTINE.                                      56000013
         SPACE 1                                                        56200013
         LM    RG,RI,PPICOUNT      RESTORE REGISTERS                    56400013
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   56600013
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   56800013
*                                    IN PPI                             57000013
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               57200013
         B     RBUSREXT            BR TO USER EXIT                      57400013
         SPACE 2                                                        57600013
RBDOOBA  ST    RB,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         57800013
         LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          58000013
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        58200013
         SPACE 1                                                        58400013
* INTERFACE TO DEBLOCK MODULE. RD HAS FILE NO OF WINNER IN 1ST BYTE     58600013
         SPACE 1                                                        58800013
         L     RL,PPIDEB+4         DEBLOCK ADDR                         59000013
         B     4(0,RL)             BR TO DEBLOCK MODULE                 59200013
         SPACE 2                                                        59400013
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               59600013
         SPACE 1                                                        59800013
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     60000013
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     60200013
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        60400013
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   60600013
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           60800013
         B     RBSETPAR            OFF,BR TO USER ROUTINE               61000013
         SPACE 2                                                        61200013
* USER END OF FILE ROUTINE                                              61400013
         SPACE 1                                                        61600013
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          61800013
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   62000013
         MVI   RBLOADRE+4,X'30'    OVERLAY INSTR(CHANGES RB TO RD)      62200013
         MVI   RBOVLAY1+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      62400013
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   62600013
*                                    CHECK THE REST OF THE RCDS         62800013
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 63000013
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          63200013
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 63260018
         BO    RBEOJ               IF YES BR TO EOJ                4549 63320018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         63400013
         SPACE 2                                                        63600013
* LINKAGE TO END OF JOB MODULE                                          63800013
RBEOJ    L     RL,PPIWRT+4         END OF JOB ADDRESS                   64000013
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      64200013
         SPACE 2                                                        64400013
* DELETE OR SUMMARIZE A RECORD                                          64600013
         SPACE 1                                                        64800013
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 65000013
         MVC   PPIDOOBA(4),WOPBUFAD  ADDR OF RCD IN OUTPUT BFR(THE RCD  65200013
*                                      BEFORE THE DELETD OR SUMRZD RCD) 65400013
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       65600013
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        65800013
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  66000013
*                                    FOR MERGE NETWORK SEQU CHECK       66200013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66400013
         SPACE 2                                                        66600013
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    66800013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         67000013
         SPACE 1                                                        67200013
         SPACE 2                                                        67400013
* LIST OF CONSTANTS USED BY THE MODULE                                  67600013
KZERO    DC    F'0'                ZERO                                 67800013
KFOUR    DC    F'4'                FOUR                                 68000013
         SPACE 2                                                        68200013
* LIST OF WORK AREAS                                                    68400013
         SPACE 1                                                        68600013
WRCDLGTH DC    F'0'                RECORD LENGTH                        68800013
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   69000013
WOPBUFAD DC    F'0'                PARAM 2,ADDR OF LAST RCD PUT(OUTBUF) 69200013
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     69400013
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  69600013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 69800013
*                                    LOADED BY ASSGN RTN                70000013
WINSRTSW DC    X'00'               INSERT SWITCH                        70200013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            70400013
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              70600013
RINSERT  EQU   RI                                                       70800013
RDELSUMM EQU   RH                                                       71000013
RCDCTR   EQU   RG                                                       71200013
         SPACE 2                                                        71400013
         EJECT                                                          71600013
         SMPPI                                                          71800013
         EJECT                                                          72000013
         DCBD  DSORG=PS                                                 72200013
         END                                                            72400013
