         TITLE 'IERRBV - OS/360 SORT/MERGE - 360S-SM023 05/09/66'       00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRBV ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION:  OSCL/2314 SORT/MERGE BLOCK/DEBLOCK W/O EXITS.        01400013
*     THE FUNCTION OF THE MODULE IS TO HANDLE THE DEBLOCKING AND        01600013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       01800013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     02000013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     02200013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         02400013
         SPACE 1                                                        02600013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  02800013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  03000013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         03200013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     03400013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     03600013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     03800013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    04000013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   04200013
*     IS REPEATED.                                                      04400013
         SPACE 1                                                        04600013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    04800013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            05000013
         SPACE 2                                                        05200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05400013
         SPACE 1                                                        05600013
*   IERABV                                                              05800013
         SPACE 2                                                        06000013
*LIST OF MACROS USED BY THE MODULE:                                     06200013
         SPACE 1                                                        06400013
*   SMPPI                                                               06600013
         SPACE 2                                                        06800013
*ENTRY POINTS:                                                          07000013
         SPACE 1                                                        07200013
*   FROM MERGE                     ENTRY FROM: MERGE NETWORK            07400013
*                                    CALLING SEQUENCE-                  07600013
*                                      L    RL,PPIBLK2+4                07800013
*                                      B    0(RL)      NORMAL EDS       08000013
*                                      B    16(RL)     NORMAL           08200013
*   FROM READ                      ENTRY FROM: READ                     08400013
*                                    CALLING SEQUENCE-                  08600013
*                                      L    RL,PPIBLK2+4                08800013
*                                      B    4(RL)                       09000013
*   FROM WRITE                     ENTRY FROM: WRITE                    09200013
*                                    CALLING SEQUENCE-                  09400013
*                                      L    RL,PPIBLK2+4                09600013
*                                      B    8(RL)                       09800013
         SPACE 2                                                        10000013
*INPUT: PPI FIELDS REFERENCED                                           10200013
         SPACE 1                                                        10400013
*   PPIBDSVA                                                            10600013
*   PPILAB07                                                            10800013
*   PPISBLCT                                                            11000013
*   PPIDEPHO                                                            11200013
*   PPIUNTCT                                                            11400013
         SPACE 1                                                        11600013
*   VARIOUS ADDRESSES                                                   11800013
         SPACE 2                                                        12000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             12200013
         SPACE 1                                                        12400013
*   APPROPRIATE TAPE UNIT COUNTERS IN GENERATED CORE ARE UPDATED        12600013
         SPACE 1                                                        12800013
*   UPDATE COUNTERS                                                     13000013
         SPACE 2                                                        13200013
*EXTERNAL ROUTINES:                                                     13400013
         SPACE 1                                                        13600013
*   NONE                                                                13800013
         SPACE 2                                                        14000013
*EXTERNAL PARAMETERS:                                                   14200013
         SPACE 1                                                        14400013
*   SEE REGISTERS                                                       14600013
         SPACE 2                                                        14800013
*EXITS: NORMAL                                                          15000013
         SPACE 1                                                        15200013
*   TO READ                        EXIT TO: READ                        15400013
*                                    CALLING SEQUENCE-                  15600013
*                                      L    RL,PPIRD+4                  15800013
*                                      B    8(RL)                       16000013
*   TO NETWORK                     EXIT TO:NETWORK                      16200013
*                                    CALLING SEQUENCE                   16400013
*                                      L    RL,PPINETM+4                16600013
*                                      B    8(RL)                       16800013
*   TO WRITE                       EXIT TO: WRITE                       17000013
*                                    CALLING SEQUENCE-                  17200013
*                                      L    RL,PPIWRT+4                 17400013
*                                      B    4(RL)      EOS              17600013
*                                      B    8(RL)      NORMAL           17800013
         SPACE 2                                                        18000013
*EXITS: ERROR                                                           18200013
         SPACE 1                                                        18400013
*   NONE                                                                18600013
         SPACE 2                                                        18800013
*TABLES/WORK AREAS:                                                     19000013
         SPACE 1                                                        19200013
*   WBLKCCNT- OUTPUT BUFFER CHARACTER COUNTER                           19400013
*   WRCDLGTH- LENGTH OF WINNER RECORD                                   19600013
*   WINNER- ADDRESS OF THE WINNER RECORD IN THE INPUT BLOCK             19800013
*   WLSTPTR- ADDR OF A FREE AREA IN OUTPUT BUFFER TO MOVE THE WINNER    20000013
*   WLSTPTRD- PTR TO STARTG+8(DISK)OR ENDING+1(TAPE) ADDR OF OUTPUT BFR 20200013
         SPACE 2                                                        20400013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   20600013
         SPACE 2                                                        20800013
*NOTES                                                                  21000013
*   THIS MODULE IS USED TO MERGE                                        21200013
*   VARIABLE LENGTH RECORDS WITHOUT USER EXITS.                         21400013
         SPACE 2                                                        21600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            21800013
         SPACE 1                                                        22000013
RA       EQU   0                   CONTENTS IN- N/A                     22200013
*                                  USE- NOT USED                        22400013
*                                  CONTENTS OUT- N/A                    22600013
RB       EQU   1                   CONTENTS IN- N/A                     22800013
*                                  USE- BLK TO WRITE(BLOCK CHAR COUNT)  23000013
*                                  CONTENTS OUT- N/A                    23200013
RC       EQU   2                   CONTENTS IN- N/A                     23400013
*                                  USE- BLK TO WRITE(STRTG ADDR OF      23600013
*                                    OUTPUT BUFFER)                     23800013
*                                     - DEBLK TO READ(ADDR OF AN EMPTY  24000013
*                                    INPUT BUFFER)                      24200013
*                                  CONTENTS OUT- N/A                    24400013
RD       EQU   3                   CONTENTS IN- N/A                     24600013
*                                  USE- NTWK TO BLOCK(ADDR OF WINNER IN 24800013
*                                    INPUT BFR W/INCR IN 1ST BYTE)      25000013
*                                     - DEBLOCK TO READ(INCR IN LOW     25200013
*                                    ORDER BYTE-EMPTY BFR INCR)         25400013
*                                  CONTENTS OUT- N/A                    25600013
RE       EQU   4                   CONTENTS IN- N/A                     25800013
*                                  USE- GENERAL WORK REGISTER           26000013
*                                       CONTENTS OUT - A '4' TO INDI-   26200013
*                                         CATE NON-FINAL EOS TO WRITE   26400013
RF       EQU   5                   CONTENTS IN- N/A                     26600013
*                                  USE- GENERAL WORK REGISTER           26800013
*                                  CONTENTS OUT- N/A                    27000013
RG       EQU   6                   CONTENTS IN- N/A                     27200013
*                                  USE- GENERAL WORK REGISTER           27400013
*                                  CONTENTS OUT- N/A                    27600013
RH       EQU   7                   CONTENTS IN- N/A                     27800013
*                                  USE- GENERAL WORK REGISTER           28000013
*                                  CONTENTS OUT- N/A                    28200013
RI       EQU   8                   CONTENTS IN- N/A                     28400013
*                                  USE- GENERAL WORK REGISTER           28600013
*                                  CONTENTS OUT- N/A                    28800013
RJ       EQU   9                   CONTENTS IN- N/A                     29000013
*                                  USE- NOT USED                        29200013
*                                  CONTENTS OUT- N/A                    29400013
RK       EQU   10                  CONTENTS IN- N/A                     29600013
*                                  USE- NOT USED                        29800013
*                                  CONTENTS OUT- N/A                    30000013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    30200013
*                                  USE- MODULE BASE REGISTER            30400013
*                                  CONTENTS OUT- NTWK ENTRY PT          30600013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   30800013
*                                  USE- NOT USED                        31000013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  31200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          31400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     31600013
*                                    AREA                               31800013
*                                  CONTENTS OUT- ADDRESS OF PPI         32000013
RO       EQU   14                  CONTENTS IN- N/A                     32200013
*                                  USE- NOT USED                        32400013
*                                  CONTENTS OUT- N/A                    32600013
RP       EQU   15                  CONTENTS IN- N/A                     32800013
*                                  USE- NOT USED                        33000013
*                                  CONTENTS OUT- N/A                    33200013
         SPACE 2                                                        33400013
*START OF MODULE CODE PROPER:                                           33600013
         SPACE 2                                                        33800013
IERRBV   CSECT                                                          34000013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    34200013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        34400013
         SPACE 1                                                        34600013
*   ENTRY TABLE                                                         34800013
         SPACE 1                                                        35000013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             35200013
         B     RBRDRTRN            FROM READ MODULE                     35400013
         B     RBWRT               FROM WRITE MODULE                    35600013
         BC    0,RBSAVE            PRIMING ENTRY-ONLY FOR USER MODS MOD 35800013
         B     RBBRANCH                                                 36000013
         SPACE 1                                                        36200013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   36400013
*                                    BLOCK ENDING ADDRESS + 1.          36600013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     36800013
         SPACE 1                                                        37000013
         SPACE 1                                                        37200013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   37400013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      37600013
         SPACE 1                                                        37800013
RBBRANCH L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      38000013
*                                    PRESET TO 8 BY A.P.                38200013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  38400013
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  38600013
*                                    CTR                                38800013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 39000013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     39200013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          39400013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      39600013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     39800013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 40000013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 40200013
*                                    HI CORE TO LOW.                    40400013
         SR    RG,RG                                                    40600013
         IC    RG,PPIDEPHO+3        INCREMENT FOR OUTPUT UNIT COUNT     40800013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       41000013
         L     RI,0(RG,RH)          LOAD COUNT FOR THIS UNIT            41200013
         LA    RI,1(RI)           INCREMENT BY ONE                      41400013
         ST    RI,0(RG,RH)          RESTORE                             41600013
         LR    RE,RD               ADDR OF RCD IN INPUT AREA FOR MOVE   41800013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           42000013
         SPACE 1                                                        42200013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   42400013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   42600013
         SPACE 1                                                        42800013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  43000013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    43200013
*        RI    DATA RCD LENGTH                                          43400013
         SPACE 1                                                        43600013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   43800013
         SPACE 1                                                        44000013
         CL    RI,KON256           RCD LENGTH TO 256                    44200013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   44400013
         SPACE 1                                                        44600013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    44800013
         LNR   RG,RH                 256 BYTES EACH                     45000013
RBKMOVE  MVC   0(256,RF),0(RE)                                          45200013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     45400013
         AR    RF,RH                 BYTES                              45600013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    45800013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 46000013
         SPACE 2                                                        46200013
KON256   DC    F'256'                                                   46400013
KMOVE1   MVC   0(1,RF),0(RE)                                            46600013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             46800013
         BCTR  RG,0                DECR RG BY ONE                       47000013
         EX    RG,KMOVE1                                                47200013
         SPACE 1                                                        47400013
*   END OF GENERALIZED MOVE ROUTINE.                                    47600013
         SPACE 1                                                        47800013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       48000013
*                                    REMAINING RCD LENGTH               48200013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDRESS BY RECORD LENGTH        48400013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    48600013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            48800013
         SPACE 2                                                        49000013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   49200013
         SPACE 1                                                        49400013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   49600013
*                                    FROM OUTPUT BLOCK CHAR COUNT       49800013
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RECORD POINTER     50000013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   50200013
         ST    RG,WBLKCCNT         STORE BLK CHAR CTR IN 1ST 2 BYTES    50400013
         MVC   0(2,RC),WBLKCCNT+2                                       50600013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 50800013
         SPACE 1                                                        51000013
*   INTERFACE TO WRITE MODULE                                           51200013
         SPACE 1                                                        51400013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 51600013
         B     8(RL)               BR TO WRITE MODULE                   51800013
         SPACE 1                                                        52000013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   52200013
*   BLOCK ENDING ADDRESS+1.                                             52400013
         SPACE 1                                                        52600013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   52800013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     53000013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          53200013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     53400013
*                                    OUTPUT BLOCK                       53600013
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       53800013
         SPACE 2                                                        54000013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 54200013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  54400013
         SPACE 1                                                        54600013
RBEOS    L     RE,WLSTPTR                                               54800013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           55000013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   55200013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      55400013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     55600013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    55800013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     56000013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      56200013
         LA    RE,4                 SET INDICATION FOR NON-FINAL EOS    56400013
         SPACE 1                                                        56600013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            56800013
         SPACE 1                                                        57000013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 57200013
         B     4(RL)               BR TO WRITE MODULE                   57400013
         SPACE 2                                                        57600013
*   DEBLOCK SIDE OF PROGRAM                                             57800013
         SPACE 1                                                        58000013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   58200013
         L     RH,PPIUNTCT        LOAD ADDRESS OF UNIT COUNTERS         58400013
         L     RF,0(RD,RH)        LOAD COUNT FOR THIS UNIT              58600013
         BCTR  RF,0               DECREMENT BY ONE                      58800013
         ST    RF,0(RD,RH)        STORE                                 59000013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 59200013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  59400013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        59600013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       59800013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      60000013
*                                    INPUT BLK JUST VACATED             60200013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      60400013
         L     RD,WINNER           RESTORE WINNER                       60600013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    60800013
         SPACE 1                                                        61000013
*   INTERFACE TO MERGE NETWORK                                          61200013
         SPACE 1                                                        61400013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 61600013
         B     8(RL)               BR TO MERGE MODULE                   61800013
         SPACE 2                                                        62000013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     62200013
         SPACE 1                                                        62400013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         62600013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     62800013
         SPACE 1                                                        63000013
*   INTERFACE TO READ MODULE                                            63200013
         SPACE 1                                                        63400013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  63600013
         B     8(RL)               BR TO READ MODULE                    63800013
         SPACE 2                                                        64000013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  64200013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 64400013
*      RD - INCREMENT, RE - ENDING ADDRESS OF BLOCK                     64600013
         SPACE 1                                                        64800013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         65000013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLOCK  65200013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    65400013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     65600013
*                                    ADDRESSES                          65800013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   66000013
         SLL   RD,24               POSITION INCR IN HI BYTE             66200013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  66400013
         B     RBMERGE             BR TO MERGE                          66600013
         SPACE 2                                                        66800013
*   LIST OF CONSTANTS USED BY THE MODULE                                67000013
         SPACE 1                                                        67200013
KZERO    DC    F'0'                ZERO                                 67400013
KFOUR    DC    F'4'                FOUR                                 67600013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  67800013
         SPACE 2                                                        68000013
*   LIST OF WORK AREAS                                                  68200013
         SPACE 1                                                        68400013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      68600013
*                                    PRESET TO 8 BY A.P.                68800013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 69000013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    69200013
         EJECT                                                          69400013
         SMPPI                                                          69600013
         END                                                            69800013
