         TITLE 'IERRBX  -  OS/360 SORT/MERGE - 360S-SM023 - 5/9/66'     00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRBX ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION:                                                       01400013
*   OSCL/2314 SORT-MERGE PHASE BLOCK/DEBLOCK -VARIABLE WITH EXIT E25.   01600013
*     THE FUNCTION OF THIS MODULE IS TO HANDLE THE DEBLOCKING AND       01800013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       02000013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     02200013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     02400013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         02600013
         SPACE 1                                                        02800013
*     THE USER EXIT,E25,IS ON THE BLOCK SIDE AND IS EXECUTED ONCE FOR   03000013
*     EVERY RECORD,EXCEPT THE FIRST RECORD OF EACH OUTPUT SEQUENCE.     03200013
*     THE EXIT OCCURS AFTER THE RECORD LEAVES THE MERGE AND WHILE THE   03400013
*     PREVIOUS RECORD IS AVAILABLE IN THE OUTPUT AREA. THE EXIT IS FOR  03600013
*     SUMMARIZATION AND DELETION OF RECORDS(EXCEPT ON THE FIRST RECORD  03800013
*     OF EACH OUTPUT SEQUENCE)                                          04000013
         SPACE 1                                                        04200013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  04400013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  04600013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         04800013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     05000013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     05200013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     05400013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    05600013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   05800013
*     IS REPEATED.                                                      06000013
         SPACE 1                                                        06200013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    06400013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            06600013
         SPACE 2                                                        06800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               07000013
         SPACE 1                                                        07200013
*   IERABX                                                              07400013
         SPACE 2                                                        07600013
*LIST OF MACROS USED BY THE MODULE:                                     07800013
         SPACE 1                                                        08000013
*   SMPPI                                                               08200013
         SPACE 2                                                        08400013
*ENTRY POINTS:                                                          08600013
         SPACE 1                                                        08800013
*   FROM MERGE                     ENTRY FROM: MERGE NETWORK            09000013
*                                    CALLING SEQUENCE-                  09200013
*                                      L    RL,PPIBLK2+4                09400013
*                                      B    0(RL)      NORMAL EOD       09600013
*                                      B    12(RL)     PRIMING ENTRY    09800013
*                                      B    16(RL)     NORMAL           10000013
*   FROM READ                      ENTRY FROM: READ                     10200013
*                                    CALLING SEQUENCE-                  10400013
*                                      L    RL,PPIBLK2+4                10600013
*                                      B    4(RL)                       10800013
*   FROM WRITE                     ENTRY FROM: WRITE                    11000013
*                                    CALLING SEQUENCE-                  11200013
*                                      L    RL,PPIBLK2+4                11400013
*                                      B    8(RL)                       11600013
*   FROM E25                       ENTRY FROM:USER EXIT E25             11800013
*                                    CALLING SEQUENCE-                  12000013
*                                      RETURN  RC=(15) RETRUN ON RO     12200013
         SPACE 2                                                        12400013
*INPUT: PPI FIELDS REFERENCED                                           12600013
         SPACE 1                                                        12800013
*   PPIBDSVA                                                            13000013
*   PPILAB07                                                            13200013
*   PPISBLCT                                                            13400013
*   PPIDEPHO                                                            13600013
*   PPIUNTCT                                                            13800013
         SPACE 1                                                        14000013
*   VARIOUS ADDRESSES                                                   14200013
         SPACE 2                                                        14400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED                              14600013
         SPACE 1                                                        14800013
*   PPIDELCT                                                            15000013
*   APPROPRIATE TAPE UNIT COUNTERS IN GENERATED CORE ARE UPDATED        15200013
*   UPDATE COUNTERS                                                     15400013
         SPACE 2                                                        15600013
*EXTERNAL ROUTINES:                                                     15800013
         SPACE 1                                                        16000013
*   NONE                                                                16200013
         SPACE 2                                                        16400013
*EXTERNAL PARAMETERS:                                                   16600013
         SPACE 1                                                        16800013
*   SEE REGISTERS                                                       17000013
         SPACE 2                                                        17200013
*EXITS: NORMAL                                                          17400013
         SPACE 1                                                        17600013
*   TO READ                        EXIT TO: READ                        17800013
*                                    CALLING SEQUENCE-                  18000013
*                                      L    RL,PPIRD+4                  18200013
*                                      B    8(RL)                       18400013
*   TO NETWORK                     EXIT TO: MERGE NETWORK               18600013
*                                    CALLING SEQUENCE-                  18800013
*                                      L    RL,PPINETM+4                19000013
*                                      B    8(RL)                       19200013
*   TO WRITE                       EXIT TO: WRITE                       19400013
*                                    CALLING SEQUENCE-                  19600013
*                                      L    RL,PPIWRT+4                 19800013
*                                      B    4(RL)      EOD              20000013
*                                      B    8(RL)      NORMAL           20200013
*   TO USER                        EXIT TO: USER EXIT E25               20400013
*                                    CALLING SEQUENCE                   20600013
*                                      L    RP,PPIX25+4                 20800013
*                                      BALR RO,RP                       21000013
         SPACE 2                                                        21200013
*EXITS: ERROR                                                           21400013
         SPACE 1                                                        21600013
*   NONE                                                                21800013
         SPACE 2                                                        22000013
*TABLES/WORK AREAS:                                                     22200013
         SPACE 1                                                        22400013
*   WMRGRCD-ADDR OF WINNER IN INPUT BUFFER          PARAM 1 TO USER     22600013
*   WOUTRCD-ADDR OF LAST RCD PUT IN OUTPUT BUFFER   PARAM 2 TO USER     22800013
*   WBLKCCNT-OUTPUT BUFFER CHARACTER COUNTER                            23000013
*   WRCDLGTH-LENGTH OF WINNER RECORD                                    23200013
*   WINNER-ADDRESS OF WINNER RECORD IN INPUT BUFFER                     23400013
*   WLSTPTR-ADDR OF A FREE AREA IN OUTPUT BUFFER TO MOVE THE WINNER     23600013
*   WLSTPTRD-PTR TO STRTG+8(DISK) OR ENDING+1(TAPE) ADDR OF OUTPUT BFR. 23800013
         SPACE 2                                                        24000013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   24200013
         SPACE 2                                                        24400013
*NOTES:                                                                 24600013
*   THIS MODULE IS USED TO MERGE VARIABLE LENGTH                        24800013
*   RECORDS WHEN USER MODIFICATION EXIT E25 IS ACTIVE.                  25000013
         SPACE 2                                                        25200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            25400013
         SPACE 1                                                        25600013
RA       EQU   0                   CONTENTS IN- N/A                     25800013
*                                  USE- NOT USED                        26000013
*                                  CONTENTS OUT- N/A                    26200013
RB       EQU   1                   CONTENTS IN- N/A                     26400013
*                                  USE- BLK TO WRITE(BLOCK CHAR COUNT)  26600013
*                                     - BLK TO E25(ADDR OF PARAM LIST)  26800013
*                                     - E25 TO BLK(ADDR OF NEXT OUTPUT  27000013
*                                    RECORD)                            27200013
*                                  CONTENTS OUT- N/A                    27400013
RC       EQU   2                   CONTENTS IN- N/A                     27600013
*                                  USE- BLK TO WRITE(STARTG ADDR OF     27800013
*                                    OUTPUT BUFFER)                     28000013
*                                     - DEBLK TO READ(ADDR OF AN EMPTY  28200013
*                                    INPUT BUFFER)                      28400013
*                                  CONTENTS OUT- N/A                    28600013
RD       EQU   3                   CONTENTS IN- N/A                     28800013
*                                  USE- NTWK TO BLOCK(ADDR OF WINNER IN 29000013
*                                    INPUT BFR W/INCR IN 1ST BYTE)      29200013
*                                     - DEBLOCK TO READ(INCR IN LOW     29400013
*                                    ORDER BYTE-EMPTY BFR INCR)         29600013
*                                  CONTENTS OUT- N/A                    29800013
RE       EQU   4                   CONTENTS IN- N/A                     30000013
*                                  USE- GENERAL WORK REGISTER           30200013
*                                       CONTENTS OUT - A '4' TO INDI-   30400013
*                                         CATE NON-FINAL EOS TO WRITE   30600013
RF       EQU   5                   CONTENTS IN- N/A                     30800013
*                                  USE- GENERAL WORK REGISTER           31000013
*                                  CONTENTS OUT- N/A                    31200013
RG       EQU   6                   CONTENTS IN- N/A                     31400013
*                                  USE- GENERAL WORK REGISTER           31600013
*                                  CONTENTS OUT- N/A                    31800013
RH       EQU   7                   CONTENTS IN- N/A                     32000013
*                                  USE- GENERAL WORK REGISTER           32200013
*                                  CONTENTS OUT- N/A                    32400013
RI       EQU   8                   CONTENTS IN- N/A                     32600013
*                                  USE- GENERAL WORK REGISTER           32800013
*                                  CONTENTS OUT- N/A                    33000013
RJ       EQU   9                   CONTENTS IN- N/A                     33200013
*                                  USE- NOT USED                        33400013
*                                  CONTENTS OUT- N/A                    33600013
RK       EQU   10                  CONTENTS IN- N/A                     33800013
*                                  USE- NOT USED                        34000013
*                                  CONTENTS OUT- N/A                    34200013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    34400013
*                                  USE- MODULE BASE REG                 34600013
*                                  CONTENTS OUT- NTWK ENTRY PT          34800013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   35000013
*                                  USE- NOT USED                        35200013
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  35400013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          35600013
*                                  USE- PPI REFERENCE,REGISTER SAVE     35800013
*                                    AREA                               36000013
*                                  CONTENTS OUT- ADDRESS OF PPI         36200013
RO       EQU   14                  CONTENTS IN- N/A                     36400013
*                                  USE- RETURN REG FROM EXIT E25        36600013
*                                  CONTENTS OUT- N/A                    36800013
RP       EQU   15                  CONTENTS IN- N/A                     37000013
*                                  USE- BRANCH REG TO EXIT E25          37200013
*                                     - RETURN CODE FROM EXIT E25       37400013
*                                  CONTENTS OUT- N/A                    37600013
         SPACE 2                                                        37800013
*START OF MODULE CODE PROPER:                                           38000013
         SPACE 2                                                        38200013
IERRBX   CSECT                                                          38400013
*1580402000,468000,506000                                          4553 38500018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    38600013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        38800013
         SPACE 1                                                        39000013
*   ENTRY TABLE                                                         39200013
         SPACE 1                                                        39400013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             39600013
         B     RBRDRTRN            FROM READ MODULE                     39800013
         B     RBWRT               FROM WRITE MODULE                    40000013
         B     RBBPSUS1            PRIME ENTRY,BYPASS EXIT RTN     4553 40200018
         B     RBBRANCH                                                 40400013
         SPACE 1                                                        40600013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   40800013
*                                    BLOCK ENDING ADDRESS + 1.          41000013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     41200013
         SPACE 1                                                        41400013
         SPACE 1                                                        41600013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   41800013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      42000013
         SPACE 1                                                        42200013
RBBRANCH ST    RD,WMRGRCD          PARAM 1 TO USER. AD OF RCD IN INPUT  42400013
*                                    BLOCK                              42600013
         SPACE 1                                                        42800013
*   CALL MACRO EXPANSION INSTRUCTIONS TO USER EXIT E25                  43000013
         SPACE 1                                                        43200013
         L     RP,PPIX25+4         ADDR OF USER EXIT E25                43400013
         LA    RB,WMRGRCD                                               43600013
         BALR  RO,RP                                                    43800013
         SPACE 1                                                        44000013
*   RETURN FROM USER                                                    44200013
         SPACE 1                                                        44400013
         B     *+4(RP)                                                  44600013
         B     RBBPSUSR            DO NOTHING                           44800013
         L     RG,PPIDELCT         DELETE COUNTER                       45000013
         LA    RG,1(0,RG)          INCR DELETE CTR BY 1                 45200013
         ST    RG,PPIDELCT         SAVE UPDATED DELETE CTR              45400013
         ST    RD,WINNER           SAVE WINNER ADDR (DEBLK WILL DELETE) 45600013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  45800013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            46000013
RBBPSUS1 LR    RB,RD                                               4553 46100018
         SPACE 1                                                        46200013
RBBPSUSR L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      46400013
*                                    PRESET TO 8 BY A.P.                46600013
         MVC   WRCDLGTH+2(2),0(RB) MOVE RCD LENGTH TO PROPER BNDRY 4553 46800018
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  47000013
*                                    CTR                                47200013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 47400013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     47600013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          47800013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      48000013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     48200013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 48400013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 48600013
*                                    HI CORE TO LOW.                    48800013
         ST    RF,WOUTRCD          PARAM 2 TO USER.ADDR OF RCD IN       49000013
*                                    OUTPUT BLOCK                       49200013
         SR    RG,RG                                                    49400013
         IC    RG,PPIDEPHO+3        INCREMENT FOR OUTPUT UNIT COUNT     49600013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       49800013
         L     RI,0(RG,RH)          LOAD COUNT FOR THIS UNIT            50000013
         LA    RI,1(RI)           INCREMENT BY ONE                      50200013
         ST    RI,0(RG,RH)          RESTORE                             50400013
         LR    RE,RB               ADDR OF RCD IN INPUT AREA       4553 50600018
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           50800013
         SPACE 1                                                        51000013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   51200013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   51400013
         SPACE 1                                                        51600013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  51800013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    52000013
*        RI    DATA RCD LENGTH                                          52200013
         SPACE 1                                                        52400013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   52600013
         SPACE 1                                                        52800013
         CL    RI,KON256           RCD LENGTH TO 256                    53000013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   53200013
         SPACE 1                                                        53400013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    53600013
         LNR   RG,RH                 256 BYTES EACH                     53800013
RBKMOVE  MVC   0(256,RF),0(RE)                                          54000013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     54200013
         AR    RF,RH                 BYTES                              54400013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    54600013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 54800013
         SPACE 2                                                        55000013
KON256   DC    F'256'                                                   55200013
KMOVE1   MVC   0(1,RF),0(RE)                                            55400013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             55600013
         BCTR  RG,0                DECR RG BY ONE                       55800013
         EX    RG,KMOVE1                                                56000013
         SPACE 1                                                        56200013
*   END OF GENERALIZED MOVE ROUTINE.                                    56400013
         SPACE 1                                                        56600013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       56800013
*                                    REMAINING RCD LENGTH               57000013
RBSUBRLD S     RF,WRCDLGTH          DECREMENT ADDRESS BY RECORD LENGTH  57200013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    57400013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            57600013
         SPACE 2                                                        57800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   58000013
         SPACE 1                                                        58200013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   58400013
*                                    FROM OUTPUT BLOCK CHAR COUNT       58600013
         ST    RB,WRBSAVE          STORE MOD RCD ADDR              4553 58700018
RBLSTPTR L     RC,WLSTPTR           LOAD OUTPUT BLOCK RECORD POINTER    58800013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   59000013
         ST    RG,WBLKCCNT         ALIGN TO WD BOUNDARY                 59200013
         MVC   0(2,RC),WBLKCCNT+2  STORE BLOK CHAR CTR IN 1ST 2 BYTES   59400013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 59600013
         SPACE 1                                                        59800013
*   INTERFACE TO WRITE MODULE                                           60000013
         SPACE 1                                                        60200013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 60400013
         B     8(RL)               BR TO WRITE MODULE                   60600013
         SPACE 1                                                        60800013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   61000013
*   BLOCK ENDING ADDRESS+1.                                             61200013
         SPACE 1                                                        61400013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   61600013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     61800013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          62000013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     62200013
*                                    OUTPUT BLOCK                       62400013
         L     RB,WRBSAVE          RELOAD MOD RCD ADDR             4553 62500018
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       62600013
         SPACE 2                                                        62800013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 63000013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  63200013
         SPACE 1                                                        63400013
RBEOS    L     RE,WLSTPTR                                               63600013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           63800013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   64000013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      64200013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     64400013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    64600013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     64800013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      65000013
         LA    RE,4                 SET INDICATION FOR NON-FINAL EOS    65200013
         SPACE 1                                                        65400013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            65600013
         SPACE 1                                                        65800013
         L     RL,PPIWRT+4                                              66000013
         B     4(RL)               BR TO WRITE MODULE                   66200013
         EJECT                                                          66400013
*   DEBLOCK SIDE OF PROGRAM                                             66600013
         SPACE 1                                                        66800013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   67000013
         L     RH,PPIUNTCT        LOAD ADDRESS OF UNIT COUNTERS         67200013
         L     RF,0(RD,RH)        LOAD COUNT FOR THIS UNIT              67400013
         BCTR  RF,0               DECREMENT BY ONE                      67600013
         ST    RF,0(RD,RH)        STORE                                 67800013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 68000013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  68200013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        68400013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       68600013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      68800013
*                                    INPUT BLK JUST VACATED             69000013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      69200013
         L     RD,WINNER           RESTORE WINNER                       69400013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    69600013
         SPACE 1                                                        69800013
*   INTERFACE TO MERGE NETWORK                                          70000013
         SPACE 1                                                        70200013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 70400013
         B     8(RL)               BR TO MERGE MODULE                   70600013
         SPACE 2                                                        70800013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     71000013
         SPACE 1                                                        71200013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         71400013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     71600013
         SPACE 1                                                        71800013
*   INTERFACE TO READ MODULE                                            72000013
         SPACE 1                                                        72200013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  72400013
         B     8(RL)               BR TO READ MODULE                    72600013
         SPACE 2                                                        72800013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  73000013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 73200013
*     RD - INCREMENT, RE - ENDING ADDRESS OF BLOCK.                     73400013
         SPACE 1                                                        73600013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         73800013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLK    74000013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    74200013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     74400013
*                                    ADDRESSES                          74600013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   74800013
         SLL   RD,24               POSITION INCR IN HI BYTE             75000013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  75200013
         B     RBMERGE             BR TO MERGE NETWORK                  75400013
         SPACE 2                                                        75600013
*   LIST OF CONSTANTS USED BY THE MODULE                                75800013
         SPACE 1                                                        76000013
KZERO    DC    F'0'                ZERO                                 76200013
KFOUR    DC    F'4'                FOUR                                 76400013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  76600013
         SPACE 2                                                        76800013
*   LIST OF WORK AREAS                                                  77000013
         SPACE 1                                                        77200013
WMRGRCD  DC    F'0'                ADDR OF RCD IN INPUT BLK-USER PARAM1 77400013
WOUTRCD  DC    F'0'                ADDR OF RCD IN OUTPUT BLK-USR PARAM2 77600013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      77800013
*                                    PRESET TO 8 BY A.P.                78000013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 78200013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    78400013
WRBSAVE  DC    F'0'                CURRENT MODIFIED RCD ADDR       4553 78500018
         EJECT                                                          78600013
         SMPPI                                                          78800013
         END                                                            79000013
