         TITLE 'IERRCB - OS/360 SORT/MERGE - 360-SM-023   05/09/66'     00200013
*MODULE NAME *** IERRCB ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 0                                                 00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: THE PURPOSE OF THIS MODULE IS TO CONTROL    01200013
*   THE EXECUTION OF SORT DURING THE OPTIMIZATION PHASE. IT THEN LOADS  01400013
*   IERRCV AND BRANCHES TO IT BEFORE THE START OF PHASE 1 OR MERGE ONLY 01600013
*   PHASE. IT MAINTAINS THE LINKAGE WITH THE SYSTEM AND RETURNS TO IT   01800013
*   WITH THE PROPER CODE UPON NORMAL END OF JOB OR UPON AN ERROR        02000013
*   CONDITION.                                                          02200013
         SPACE 2                                                        02400013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT- N/A           02600013
         SPACE 2                                                        02800013
*LIST OF MACROS USED BY THIS MODULE                                     03000013
*   LINK                                                                03200013
*   LOAD                                                                03400013
*   OPEN                                                                03600013
*   CLOSE                                                               03800013
*   DCB                                                                 04000013
*   DELETE                                                              04200013
*   SMCPI                                                               04400013
         SPACE 2                                                        04600013
*ENTRY POINT:                                                           04800013
         SPACE 1                                                        05000013
*        ENTRY                     ENTRY FROM IERRCO.                   05200013
*                                    CALLING SEQUENCE-                  05400013
*                                    XCTL EP=IERRCB                     05600013
         SPACE 1                                                        05800013
*        ENTRY                     ENTRY FROM IERRCZ.                   06000013
*                                    CALLING SEQUENCE-                  06200013
*                                    BR    RO                           06400013
         SPACE 1                                                        06600013
*        ENTRY                     ENTRY FROM IERRCV.                   06800013
*                                    CALLING SEQUENCE-                  07000013
*                                    BR    RO                           07200013
         SPACE 2                                                        07400013
*INPUT: PPI-CPI FIELDS REFERENCED -                                     07600013
         SPACE 1                                                        07800013
*   CPIP3ASZ   PPISORCE    PPILINK                                      08000013
         SPACE 2                                                        08200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED -                            08400013
         SPACE 1                                                        08600013
*   PPISORCE    PPISLIB                                                 08800013
         SPACE 2                                                        09000013
*EXTERNAL ROUTINES: N/A                                                 09200013
         SPACE 2                                                        09400013
*EXTERNAL PARAMETERS  -  N/A                                            09600013
*                                                                       09800013
*EXITS-NORMAL:                                                          10000013
         SPACE 1                                                        10200013
*   IERRCZ  - LOAD AND BRANCH TO IT FOR OPTIMIZATION-PHASE       A35522 10400021
*   IERRCV   - LOAD AND BRANCH TO IT AFTER OPTIMIZATION PHASE.          10600013
*   SYSTEM   - RETURN CONTROL AT END OF SORT/MERGE.                     10800013
         SPACE 2                                                        11000013
*EXITS-ERROR:                                                           11200013
         SPACE 1                                                        11400013
*   SYSTEM   - RETURN CONTROL WITH ERROR CODE WHENEVER AN ERROR EXISTS. 11600013
         SPACE 2                                                        11800013
*TABLES/WORK AREAS: N/A                                                 12000013
         SPACE 2                                                        12200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12400013
         SPACE 2                                                        12600013
*NOTES: THIS MODULE IS USED IN ALL SORT/MERGE EXECUTIONS.               12800013
         EJECT                                                          13000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13200013
         SPACE 1                                                        13400013
RA       EQU   0                   CONTENTS IN - ADDRESS OF IERRCV UPON 13600013
*                                    RETURN FROM LOAD MACRO ROUTINE.    13800013
*                                  USED - ADDRESS OF IERRCV MOVED TO RP 14000013
*                                  CONTENTS OUT - N/A                   14200013
RB       EQU   1                   CONTENTS IN - ADDRESS OF CPI UPON    14400013
*                                    ENTRY FROM IERRCB.                 14600013
*                                  USED - GENERAL WORK REGISTER.        14800013
*                                  CONTENTS OUT - N/A                   15000013
RC       EQU   2                   CONTENTS IN - N/A                    15200013
*                                  USED - CPI BASE REGISTER.            15400013
*                                  CONTENTS OUT - ADDRESS OF CPI UPON   15600013
*                                    LINK TO IERRCZ.                    15800013
RD       EQU   3                   CONTENTS IN - N/A                    16000013
*                                  USED - GENERAL WORK REGISTER.        16200013
*                                  CONTENTS OUT - ADDRESS OF SYSOUT DCB 16400013
*                                    UPON EXIT TO IERRCZ AND IERRCV.    16600013
RE       EQU   4                   NOT USED.                            16800013
RF       EQU   5                   NOT USED.                            17000013
RG       EQU   6                   NOT USED.                            17200013
RH       EQU   7                   NOT USED.                            17400013
RI       EQU   8                   CONTENTS IN - N/A                    17600013
*                                  USED - MODULE BASE REGISTER.         17800013
*                                  CONTENTS OUT - N/A                   18000013
RJ       EQU   9                   NOT USED.                            18200013
RK       EQU   10                  NOT USED.                            18400013
RL       EQU   11                  NOT USED.                            18600013
RM       EQU   12                  NOT USED.                            18800013
RN       EQU   13                  CONTENTS IN - N/A                    19000013
*                                  USED - BASE REGISTER FOR PPI.        19200013
*                                  CONTENTS OUT - ADDRESS OF PPI UPON   19400013
*                                    EXIT TO IERRCZ AND IERRCV.         19600013
RO       EQU   14                  CONTENTS IN - N/A                    19800013
*                                  USED - NOT USED.                     20000013
*                                  CONTENTS OUT - ADDRESS OF POINT IN   20200013
*                                    SYSTEM WHERE CONTROL IS PASSED     20400013
*                                    WHEN RETURNING TO THE SYSTEM.      20600013
RP       EQU   15                  CONTENTS IN - ADDRESS OF IERRCB UPON 20800013
*                                    ENTRY FROM IERRCO.                 21000013
*                                              - POSSIBLE ERROR CODE    21200013
*                                    UPON RETURN FROM IERRCZ OR IERRCV. 21400013
*                                              - ADDRESS OF IERRCB UPON 21600013
*                                     ENTRY FROM SYNAD ERROR IN SYSOUT. 21800013
*                                  USED - GENERAL WORK REGISTER.        22000013
*                                  CONTENTS OUT - ADDRESS OF IERRCV     22200013
*                                    UPON BRANCHING TO IT.              22400013
         SPACE 2                                                        22600013
*START OF MODULE CODE PROPER:                                           22800013
         SPACE 2                                                        23000013
IERRCB   CSECT                                                          23200013
*A362100                                                         A31880 23210020
*D270000                                                         A35522 23210121
*D366000                                                         A31880 23220020
*A270000-271999                                                  A35522 23220121
*A278500,318500                                                  A35522 23230021
*C362900                                                         A35522 23240021
*                                                                A27971 23250019
*1586370000                                                        3771 23300015
         USING *,RI                MODULE BASE REGISTER                 23400013
         USING IERRC5,RC           CPI BASE REGISTER                    23600013
         USING IERRCA,RN           PPI BASE REGISTER                    23800013
         STM   RO,RM,12(RN)        SAVE REGISTER 14 THROUGH 12          24000013
         LR    RI,RP               SET MODULE BASE REGISTER             24200013
         LR    RC,RB               LOAD CPI BASE REGISTER               24400013
         L     RB,RCBRCAX          GET ADDRESS OF PPI                   24600013
         ST    RB,8(0,RN)          SAVE MY SAVE AREA ADDRESS            24800013
         ST    RN,4(0,RB)          SAVE OUR SAVE AREA ADDRESS           25000013
         LR    RN,RB               LOAD PPI BASE REGISTER               25200013
         MVC   RCBEXTFR+2(2),CPIEXTSZ  INSERT EXTRACT ROUTINE SIZE      25400013
         CLI   CPIP3ASZ+1,16       COMPARE MESSAGE INDEX TO 16          25600013
         BE    RCB001              IF EQUAL TAKE BRANCH                 25800013
         CLI   CPIP3ASZ+1,8        COMPARE MESSAGE INDEX TO 8           26000013
         BNE   RCB002              IF NOT EQUAL TAKE BRANCH             26200013
         SPACE 1                                                        26400013
RCB001   OPEN  (SYSOUT,(OUTPUT))   OPEN OUTPUT DCB                      26600013
         SPACE 1                                                        26800013
RCB002   LOAD  EP=IERRCZ                                         A35522 27000021
         LR    RP,RA                                             A35522 27050021
         CNOP  0,4                 ALLIGN LIST ON W-BOUNDARY     A35522 27100021
         BAL   RB,RCB003           LOAD LISTADDRESS INTO REG1    A35522 27150021
         DC    A(SYSOUT)                                         A35522 27160021
         DC    A(SORTLIB)                                        A35522 27170021
         DC    A(USERLIB)                                        A35522 27180021
         DC    B'00000000'                                       A35522 27190021
         DC    AL3(SYSLMOD)                                      A35522 27192021
RCB003   BALR  RO,RP               BRANCH AND LINK TO IERRCZ     A35522 27194021
         SPACE                                                          27200013
         SPACE 1                                                        27400013
         LR    RH,RP               SAVE RC FOR LATER TESTING            27600021
         DELETE EP=IERRCZ          DELETE MODULE IERRCZ          A35522 27850021
         DELETE EP=IEWSZOVR        DELETE OVERLAY SUPERVISOR            27880021
         LTR   RH,RH               TEST RC FROM IERRCZ                  27910021
         BH    RCBERROR            BRANCH IF ERROR RETURN               27940021
         SPACE 1                                                        28000013
         SPACE 1                                                        28200013
RCBLDRCV LOAD  EP=IERRCV,DCB=SORTLIB                                    28400013
         SPACE 1                                                        28600013
         LR    RP,RA               MOVE ADDRESS OF IERRCV INTO RP       28800013
         LA    RD,SYSOUT           PASS SYSOUT DCB ADDRESS              29000013
         BALR  RO,RP               BRANCH AND LINK TO IERRCV            29200013
         SPACE 2                                                        29400013
         LR    RH,RP               SAVE RC FOR LATER TESTING            29600021
         DELETE EP=IERRCV          DELETE MODULE IERRCV                 29660021
         LTR   RH,RH               ERROR RETURN FROM IERRCV?            29720021
         BZ    RCBCLOSE            NO - GO CLOSE DCB'S                  29800013
RCBERROR MVI   RCBEXIT+3,16        YES - SET ERROR CODE                 30000013
         SPACE 1                                                        30200013
RCBCLOSE CLOSE (SYSOUT,,SORTLIB,,SYSLMOD,,USERLIB)                      30400013
         SPACE 1                                                        30600013
         TM    PPISW1+6,X'01'      IS DIAGNOSTIC BIT ON                 30800013
         BZ    RCBNODG             BRANCH IF NO                         31000013
         SPACE 1                                                        31200013
         DELETE EP=IERDM4          DELETE CONVERT MODULE                31400013
         SPACE 1                                                        31600013
RCBNODG  TM    PPISW1+3,X'40'      WAS THERE AN EXTRACT ROUTINE         31800021
         BO    RCBEXTFR            YES - FREE CORE                      32400013
         TM    PPISW1+3,X'80'      WAS THERE AN EQUALS ROUTINE          32600013
         BNO   RCBEXIT             BRANCH IF NEITHER EQUALS NOR EXTRACT 32800013
         LA    RA,96               EQUALS ROUTINE SIZE IS 96 BYTES      33000013
         B     RCBGETAD            GO GET ADDRESS OF ROUTINE TO FREE    33200013
         SPACE 2                                                        33400013
RCBEXTFR LA    RA,0                LAST 2 BYTES WILL BE OVERLAID WITH   33600013
*                                    THE SIZE OF THE EXTRACT ROUTINE    33800013
RCBGETAD L     RB,PPIAXERT         GET ADDRESS OF EQUALS OR EXTRACT RTN 34000013
         LTR   RB,RB               GETMAIN DONE FOR EXTRACT RTN  A27971 34060019
         BZ    RCBEXIT             NO, BR OVER FREEMAIN INSTR    A27971 34120019
         FREEMAIN R,LV=(0),A=(1)   FREE EQUALS OR EXTRACT ROUTINE       34200013
         SPACE 2                                                        34400013
RCBEXIT  LA    RP,0                SET RETURN CODE                      34600013
         L     RN,4(0,RN)          GET ADDRESS OF CALLERS SAVE AREA     34800013
         LM    RC,RM,28(RN)        RESTORE REGISTERS 2 THROUGH 12       35000013
         L     RO,12(0,RN)         RESTORE REGISTER 14                  35200013
         MVI   12(RN),X'FF'        SET FLAG IN CALLERS AREA             35400013
         BR    RO                  RETURN TO CALLER                     35600013
         SPACE 2                                                        35800013
         USING *,RP                                                     36000013
RCBSYNAD L     RI,RCBRCBX          RESTORE MODULE BASE REGISTER         36200013
         DROP RP                                                 A35522 36210121
         SYNADAF  ACSMETH=BSAM                                     I302 36230019
         MVC   RMBIOS+8(120),8(RB) PREPARE MESSAGE TO PROGRAMMER   I302 36260019
         LA    RB,RMBIOS+4         ADDRESS OF MESSAGE            A35522 36290021
         WTO   MF=(E,(1))                                          I302 36320019
         SYNADRLS                                                  I302 36350019
         B     RCBERROR            BRANCH TO ERROR EXIT LINKAGE         36400013
         SPACE 2                                                        36800013
SYSOUT   DCB   DSORG=PS,MACRF=(W),DDNAME=SYSOUT,                   3771X37000015
               RECFM=U,BLKSIZE=120,SYNAD=RCBSYNAD                       37200013
         SPACE 2                                                        37400013
SYSLMOD  DCB   DSORG=PO,MACRF=(E),DDNAME=SYSLMOD                        37600013
         SPACE 2                                                        37800013
USERLIB  DCB   DSORG=PO,MACRF=(E)                                       38000013
         SPACE 2                                                        38200013
SORTLIB  DCB   DSORG=PO,MACRF=(E),DDNAME=SORTLIB                        38400013
         SPACE 2                                                        38600013
RCBRCAX  DC    A(IERRCA)           ADDRESS OF PPI                       38800013
RCBRCBX  DC    A(IERRCB)           ADDRESS OF THIS MODULE               39000013
RMBIOS   DC    A(MSGIOS)                                           I302 39040019
MSGIOS   WTO   '                                                       X39080019
                                                                       X39120019
                         ',ROUTCDE=11,DESC=4,MF=L                  I302 39160019
         EJECT                                                          39200013
IERRCA   CSECT                     PHASE-TO-PHASE INFORMATION AREA      39400013
PPISVARE DC    XL32'0'             SYSTEM REGISTER SAVE AREA            39600013
         DC    XL32'0'             SAVE AREA                            39800018
         DC    XL8'0'              SAVE AREA                            40000018
PPIWKARE DS    0CL256              STARTING ADDRESS OF SORT WORK AREA   40200013
PPIPDWA  DS    0CL64               MERGE NETWORK PRIME AREA             40400013
PPIP1GC  DC    XL4'0'              SIZE OF SORT PHASE GEN. CORE         40600013
PPIP1ASZ DC    XL4'0'              PHASE 1 ASSIGNMENT SIZE              40800013
PPISKPRD DC    XL4'0'              SKIP RECORD COUNT                    41000013
PPIATP1E DC    XL4'0'              ADDRESS OF ATTACH'ORS PHASE 1 EXIT   41200013
PPIIPBLK DC    XL4'0'              INPUT BLOCKING                       41400013
PPIBUF1  DC    XL4'0'              NUMBER OF BUFFERS - PHASE 1          41600013
PPIEXTSZ DC    XL4'0'              SIZE OF EXTRACT ROUTINE              41800013
PPIFFF   DC    XL4'0'              DISPLACEMENT OF F FIELD              42000013
PPIPBUFF DC    XL4'0'              DISPLACEMENT OF PACKING BUFFER       42200013
         DC    XL4'0'              ALIGNMENT BYTES                      42400018
PPINUMCF DC    XL2'0'              NUMBER OF CONTROL FIELDS             42600013
PPIPCF01 DC    XL3'0'              CONTROL FIELD 01 - POSITION          42800013
PPIMCF01 DC    XL2'0'                               - MEASUREMENT       43000013
PPIFCF01 DC    XL1'0'                               - FORMAT + SEQUENCE 43200013
PPIPCF02 DC    XL3'0'              CONTROL FIELD 02 - POSITION          43400013
PPIMCF02 DC    XL2'0'                               - MEASUREMENT       43600013
PPIFCF02 DC    XL1'0'                               - FORMAT + SEQUENCE 43800013
PPIPCF03 DC    XL3'0'              CONTROL FIELD 03 - POSITION          44000013
PPIMCF03 DC    XL2'0'                               - MEASUREMENT       44200013
PPIFCF03 DC    XL1'0'                               - FORMAT + SEQUENCE 44400013
PPIPCF04 DC    XL3'0'              CONTROL FIELD 04 - POSITION          44600013
PPIMCF04 DS    0CL2                                 - MEASUREMENT       44800013
         DC    XL1'0'                               - MEASUREMENT       45000018
PPIPSVA  DS    0CL64               MERGE NETWORK PRIME SAVE AREA        45200013
         DC    XL1'0'                               - MEASUREMENT       45400018
PPIFCF04 DC    XL1'0'                               - FORMAT + SEQUENCE 45600013
PPIPCF05 DC    XL3'0'              CONTROL FIELD 05 - POSITION          45800013
PPIMCF05 DC    XL2'0'                               - MEASUREMENT       46000013
PPIFCF05 DC    XL1'0'                               - FORMAT + SEQUENCE 46200013
PPIPCF06 DC    XL3'0'              CONTROL FIELD 06 - POSITION          46400013
PPIMCF06 DC    XL2'0'                               - MEASUREMENT       46600013
PPIFCF06 DC    XL1'0'                               - FORMAT + SEQUENCE 46800013
PPIPCF07 DS    0CL3                CONTROL FIELD 07 - POSITION          47000013
         DC    XL2'0'                               - POSITION          47200018
PPIDSKED DS    0CL48              THIS AREA IS USED FOR UP TO 6 DISK    47400013
         DC    XL1'0'                               - POSITION          47600018
PPIMCF07 DC    XL2'0'                               - MEASUREMENT       47800013
PPIFCF07 DC    XL1'0'                               - FORMAT + SEQUENCE 48000013
PPIPCF08 DC    XL3'0'              CONTROL FIELD 08 - POSITION          48200013
PPIMCF08 DC    XL2'0'                               - MEASUREMENT       48400013
PPIFCF08 DC    XL1'0'                               - FORMAT + SEQUENCE 48600013
PPIPCF09 DC    XL3'0'              CONTROL FIELD 09 - POSITION          48800013
PPIMCF09 DC    XL2'0'                               - MEASUREMENT       49000013
PPIFCF09 DC    XL1'0'                               - FORMAT + SEQUENCE 49200013
PPIPCF10 DC    XL3'0'              CONTROL FIELD 10 - POSITION          49400013
PPIMCF10 DC    XL2'0'                               - MEASUREMENT       49600013
PPIFCF10 DC    XL1'0'                               - FORMAT + SEQUENCE 49800013
PPIPCF11 DC    XL3'0'              CONTROL FIELD 11 - POSITION          50000013
PPIMCF11 DC    XL2'0'                               - MEASUREMENT       50200013
PPIFCF11 DC    XL1'0'                               - FORMAT + SEQUENCE 50400013
PPIPCF12 DC    XL3'0'              CONTROL FIELD 12 - POSITION          50600013
PPIMCF12 DC    XL2'0'                               - MEASUREMENT       50800013
PPIFCF12 DC    XL1'0'                               - FORMAT + SEQUENCE 51000013
         DC    XL14'0'             ALIGNMENT BYTES                      51200018
PPILAB01 DS    0CL64               UTILITY STORAGE POSITION 1           51400013
         DC    XL32'0'             SEQUENCE ADDRESSES                   51600018
         DC    XL12'0'             ALIGNMENT BYTES                      51800018
PPITPPT  DC    XL4'0'              TAPE TABLE POINTER                   52000013
PPITPTBL DS    0CL136              TAPE TABLE                           52200013
         DC    XL32'0'             TAPE TABLE                           52400018
PPIDIRAD DC    XL8'0'              DISK DIRECTORY ADDRESS               52600013
PPIODOM  DS    0CL64               ODOMETER TABLE FOR OSCILLATING       52800013
PPISTAR  DC    XL32'0'             DIRECT ACCESS STARTING ADDRESSES     53000013
         DC    XL32'0'             MBBCCHHR                             53200018
         DC    XL32'0'               ONE ENTRY FOR EACH OF 3 TO 17      53400013
         DC    XL32'0'             DISK                                 53600018
         DC    XL8'0'                EXTENTS                            53800013
PPIENDAR DC    XL32'0'             DIRECT ACCESS ENDING ADDRESSES       54000013
         DC    XL32'0'             MBBCCHHR                             54200018
         DC    XL32'0'               RESET FROM PPIDSKED FOR 2301/2311  54400013
         DC    XL32'0'             ONE FOR EACH EXTENT                  54600018
         DC    XL8'0'                NEVER ALTERED FOR 2314             54800013
PPISW1   DC    XL8'0'              SW1                                  55000013
PPIMODEX DC    XL4'0'              MODIFICATION EXITS ACTIVATED         55200013
PPILINK  DC    XL4'0'              MOD EXIT LINK EDIT INFO SET BY RCH   55400013
PPICOUNT DC    XL4'0'              RECORD COUNTER                       55600013
PPIDELCT DC    XL4'0'              DELETE COUNTER                       55800013
PPIINSCT DC    XL4'0'              INSERT COUNTER                       56000013
PPIRCDCT DC    XL4'0'              RECORD COUNTER                       56200013
PPISEQCT DC    XL12'0'             SEQUENCE COUNTERS                    56400013
PPIFILSZ DC    XL4'0'              FILE SIZE                            56600013
PPIBINSZ DC    XL4'0'              BIN SIZE                             56800013
PPINMAX  DC    XL4'0'              N(MAX)                               57000013
PPIRMAX  DC    XL4'0'              CALCULATED BY ALG                    57200013
PPISRTG  DC    XL4'0'              G-NO. RECORDS IN RSA; SET BY B/G     57400013
PPISRTBL DC    XL2'0'              B-SORT BLOCKING; SET BY B/G          57600013
PPIOPBLK DC    XL2'0'              OUTPUT BLOCKING                      57800013
PPIBUF23 DC    XL2'0'              NUMBER OF BUFFERS - PHASE 2 AND 3    58000013
         DS    0F                                                       58200013
PPIOPFMP DC    XL8'0'              OUTPUT UNIT FOR PHASE 3              58400013
PPIDEPHO DC    XL8'0'              OUTPUT UNIT ADDRESS                  58600013
PPIRCDL1 DC    XL2'0'              F - INPUT RECORD LENGTH              58800013
PPIRCDL2 DC    XL2'0'              F - SORT RECORD LENGTH               59000013
PPIRCDL3 DC    XL2'0'              F - OUTPUT RECORD LENGTH             59200013
PPIRCDL4 DC    XL2'0'              F - NOT USED                         59400013
PPIRCDL5 DC    XL2'0'              F - NOT USED                         59600013
PPIMRGMX DC    XL2'0'              MAXIMUM MERGE ORDER                  59800013
PPIMRGAL DC    XL2'0'              ALTERNATE MERGE ORDER                60000013
PPIMRGOP DC    XL2'0'              OPTIMUM MERGE ORDER                  60200013
PPIDD0L1 DC    XL4'0'              MERGE NETWORK'S MAJOR CONTROL FIELD  60400013
PPIAXERT DC    XL4'0'              ADDRESS OF EQUALS OR EXTRACT ROUTINE 60600013
PPIUSER  DC    XL4'0'              USER COMMUNICATION AREA              60800013
PPILEXFD DC    XL2'0'              LENGTH OF EXTRACTED FIELDS FOR COMPA 61000013
PPILEXFF DC    XL2'0'              LENGTH OF EXTRACTED FIELDS FULL      61200013
PPINDSKA DC    XL2'0'              NUMBER OF DISK AREAS                 61400013
PPIBPTRK DC    XL2'0'              BLOCKS PER TRACK FOR DIRECT ACCESS   61600013
PPILAB03 DC    XL4'0'              SET BY B/G TO INPUT BUFF SIZE        61800013
PPILAB07 DC    XL4'0'              SET BY B/G TO OUTPUT BUFFER SIZE     62000013
PPIDOUO  DS    0CL4                USER OPTION FOR SEQUENCE CKECK       62200013
PPILAB09 DC    XL4'0'              SET BY B/G                           62400013
PPIP2GC  DC    XL4'0'              SIZE OF MERGE PHASE GENERATED CORE,  62600013
PPIP3GC  DC    XL4'0'              SIZE OF FINAL MERGE PHASE GENERATED  62800013
PPIP3ASZ DC    XL4'0'              USED FOR MESSAGE INDEX -SET BY RCV   63000013
PPIATP3E DC    XL4'0'              ADDRESS OF ATTACH'ORS PHASE 3 EXIT   63200013
PPITAVLC DC    XL4'0'             SORT PHASE AVAILABLE CORE             63400013
PPITREND DC    XL4'0'              ENDING ADDRESS OF TREE               63600013
PPISPGN1 DC    XL4'0'              ADDRS OF NEXT AVAILABLE BYTE IN      63800013
PPILAB02 DC    XL4'0'              ADDRESS OF INPUT BUFFER TABLE        64000013
PPILAB04 DC    XL4'0'              ADDRESS OF OUTPUT BUFFER 1           64200013
PPILAB05 DC    XL4'0'              ADDRESS OF OUTPUT BUFFER 2           64400013
PPILAB06 DC    XL4'0'              ADDRESS OF CONTROL BUFFER            64600013
PPIDOOBA DS    0CL4                ADDRESS OF RECORD FOR SEQUENCE CHECK 64800013
PPILAB08 DC    XL4'0'              BYTE 1 - NO. ENTRIES IN RSA TABLE    65000013
PPIBDSVA DC    XL16'0'             BLOCK/DEBLOCK SAVE AREA              65200013
PPISTDCB DC    XL4'0'              STARTING ADDRESS OF DCB TABLE        65400013
PPISBLCT DC    XL4'0'              ADDRESS OF BLOCK COUNT TABLE         65600013
PPISTIOB DC    XL4'0'              STARTING ADDRESS OF IOB TABLE        65800013
PPIUNTCT DC    XL4'0'              OSC ONLY-ADDRS OF UNIT COUNT TABLE   66000013
PPILAB10 DC    XL4'0'              OSC ONLY-ADDRS OF INPUT BUFFER TABLE 66200013
PPIGETMN DC    XL4'0'              ADDRESS OF GETMAIN TABLE OF ADDRESS. 66400013
PPIGETSZ DC    XL4'0'              ADDRESS OF GETMAIN TABLE OF SIZES    66600013
PPISORCE DC    XL8'0'              DDNAME OF USER MOD LIBRARY           66800013
*                                    DCB ADDRESSES OF SYSLMOD-USER LIB  67000013
PPISLIB  DC    XL4'0'              DCB ADDRESS OF SORT LIBRARY          67200013
PPIRCV   DC    XL4'0'              SORT SYSTEM CONTROL FOR RUNNING PGM. 67400013
PPIADSSC DC    XL4'0'              ADDRESS OF RC9                       67600018
PPIALG   DC    XL8'0'              ALGORITHM  -PH 1 AND PH 2            67800013
PPIDEB   DC    XL8'0'              DEBLOCK  -PH 1 AND PH 3              68000013
PPINET   DC    XL8'0'              NETWORK  -PH 1 AND PH 3              68200013
PPIBLK   DC    XL8'0'              BLOCK  -PH 1 AND PH3                 68400013
PPIWRT   DC    XL8'0'              WRITE  -PH 1 AND PH2                 68600013
PPIVMV   DC    XL8'0'              VAR MOVE - SORT PHASE                68800013
PPIRD    DC    XL8'0'              READ  -PH 2 AND PH3                  69000013
PPIDEB2  DC    XL8'0'              DEBLOCK PH2 - PRIME RTN.             69200013
PPINETM  DC    XL8'0'              MERGE NETWORK  -PH 2                 69400013
PPIBLK2  DC    XL8'0'              BLOCK/DEBLOCK  PH 2                  69600013
PPIINT   DC    XL8'0'              INITIALIZE SORT AND TREE - OSC.      69800013
PPICONV  DC    XL8'0'              CONVERT HEX. TO CHAR. FOR MESSAGE    70000013
PPIEOF   DC    XL8'0'              EODAD FOR QSAM IN P1 AND MRG ONLY    70200013
PPIRMA   DC    XL8'0'              MESSAGES FOR PH1 RUNNING PGM.        70400013
PPIRMC   DS    0CL8                MESSAGES FOR PH3 RUNNING PGM.        70600013
PPIRMB   DC    XL8'0'              MESSAGES FOR PH2 RUNNING PGM.        70800013
PPIAMA   DC    XL8'0'              MESSAGES FOR PH1 ASSIGNMENT PGM.     71000013
PPIAMC   DS    0CL8                MESSAGES FOR PH3 ASSIGNMENT PGM.     71200013
PPIAMB   DC    XL8'0'              MESSAGES FOR PH2 ASSIGNMENT PGM.     71400013
PPIOPEN  DC    XL8'0'              OPEN LIST -PH1, PH2, AND PH3         71600013
PPIX11   DC    XL8'0'              EXIT FOR                             71800013
PPIX31   DS    0CL8                  USER INITIALIZATION                72000013
PPIX21   DC    XL8'0'                FUNCTIONS                          72200013
PPIX15   DC    XL8'0'              EXIT FOR                             72400013
PPIX35   DS    0CL8                  LOGICAL                            72600013
PPIX25   DC    XL8'0'                RECORD MODIFICATION                72800013
PPIX17   DC    XL8'0'              EXIT FOR                             73000013
PPIX37   DS    0CL8                  CLOSING USER DATA SETS             73200013
PPIX27   DC    XL8'0'                AT END OF PHASE                    73400013
PPIX18   DC    XL8'0'              EXIT FOR                             73600013
PPIX38   DS    0CL8                  READ ERROR                         73800013
PPIX28   DC    XL8'0'              PH2 OR PH3                           74000018
PPIX19   DC    XL8'0'              EXIT FOR                             74200013
PPIX39   DS    0CL8                  WRITE ERROR                        74400013
PPIX29   DC    XL8'0'              PH2 OR PH3                           74600018
PPIX61   DC    XL8'0'              EXIT FOR EXTRACT                     74800013
PPIX16   DC    XL8'0'              EXIT FOR NMAX                        75000013
PPIADDCF DC    XL4'0'              ADDRESS OF C.F. INFO FOR MORE THAN   75200013
*                                    TWELVE CONTROL FIELDS              75400013
PPIDDSRT DC    CL4'SORT'           FOUR LETTER IDENT. FROM PARM. FIELD  75600013
         DC    XL1'2'              PPI VERSION NUMBER 2                 75800013
         DC    XL3'0'              NOT USED                             75860017
PPICHKAD DC    XL4'0'              CHECKPOINT MODULE ADDRESS            75920017
PPIDCBIN DC    XL2'0'              SIZE OF SORTIN DCB            A26453 75940019
PPIDCBOU DC    XL2'0'              SIZE OF SORTOUT DCB           A26453 75960019
         SMCPI                                                          76000013
         END                                                            76200013
