         TITLE '  IERRCC - OS/360 SORT/MERGE - 360S-SM-023  03/11/65'   00100013
*MODULE NAME:*** IERRCC ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION: READ SORT CONTROL CARDS-GENERAL ASSIGNMENT. 00600013
*  THE FUNCTION OF THIS MODULE IS TO OBTAIN SORT CONTROL CARD INFORM-   00700013
*  ATION, CHECK FOR CERTAIN ERROR CONDITIONS, AND IF NONE, PASS THE     00800013
*  INFORMATION TO FOLLOWING ROUTINES VIA A CONTROL DICTIONARY CALLED    00900013
*   IERRCQ.                                                             01000013
         SPACE 2                                                        01100013
*FLOWCHART CROSS REFERENCES - CH,CI,CJ                                  01200013
         SPACE 2                                                        01300013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT -              01400013
*                                                                       01500013
*   N/A                                                                 01600013
*                                                                       01700013
*                                                                       01800013
*MACROS USED                                                            01900013
         SPACE 1                                                        02000013
*   SMCPI                                                               02100013
*   BUILD                                                               02200013
*   OPEN                                                                02300013
*   GET                                                                 02400013
*   CLOSE                                                               02500013
*   DCB                                                                 02600013
         SPACE 2                                                        02700013
*ENTRY POINTS:                                                          02800013
         SPACE 1                                                        02900013
*        ENTRY IERRCC              ENTRY FROM: IERRCM                   03000013
*                                    CALLING SEQUENCE-                  03100013
*                                      L    RP,=V(IERRCC)               03200013
*                                      BALR RO,RP                       03300013
         SPACE 2                                                        03400013
*INPUT: CPI FIELDS REFERENCED-                                          03500013
         SPACE 1                                                        03600013
*  CPISW1                                                               03700013
         SPACE 2                                                        03800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             03900013
         SPACE 1                                                        04000013
*  CPISW1                                                               04100013
*                                                                       04200013
*  SETS BITS IN CPISW1 INDICATING SORT OR MERGE ONLY AND WHICH CARDS    04300013
*  ARE PRESENT.                                                         04400013
         SPACE 2                                                        04500013
*EXTERNAL ROUTINES:                                                     04600013
         SPACE 1                                                        04700013
*                                                                       04800013
*        V(IERGAPRT)               ERROR MESSAGE PRINT ROUTINE.         04900013
         SPACE 2                                                        05000013
*EXTERNAL PARAMETERS:                                                   05100013
         SPACE 1                                                        05200013
         EXTRN IERRCQ              CONTROL CARD DICTIONARY.             05300013
         EXTRN IERRCY              ERROR MESSAGE MODULE FOR IERRCC.     05400013
*EXITS: NORMAL                                                          05500013
         SPACE 1                                                        05600013
*  IERRCM-WITH ZERO IN RETURN REGISTER (RP) TO INDICATE NO ERROR.       05700013
         SPACE 2                                                        05800013
*EXITS: ERROR                                                           05900013
         SPACE 1                                                        06000013
*  IERGAPRT-WITH ADDRESS AND LENGTH OF ERROR MESSAGE IN RA AND RB.      06100013
*           BEFORE RETURNING TO IERRCM, MUST PLACE 4 IN RP INDICATING   06200013
*           ERROR FOUND BY MODULE.                                      06300013
*                                                                       06400013
         SPACE 2                                                        06500013
*TABLES/WORK AREAS:                                                     06600013
         SPACE 1                                                        06700013
*  WWORK IS 80 CHARACTER AREA INTO WHICH EACH CARD IS READ.             06800013
         SPACE 2                                                        06900013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07000013
         SPACE 2                                                        07100013
*NOTES:ERROR CONDITIONS FOUND BY THIS MODULE REFER TO VIOLATIONS OF     07200013
*  EXTERNAL LANGUAGE CONVENTIONS, AS STATED IN THE DESIGN SUMMARY BOOK- 07300013
*  PAGE 3.12.3-1 AS OF 10-20-64, AND CONVENTIONS AS SPECIFIED IN THE    07400013
*  OS/360 SORT/MERGE SRL.                                               07500013
         EJECT                                                          07600013
         SMCPI                                                          07700013
         SPACE 2                                                        07800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            07900013
         SPACE 1                                                        08000013
RA       EQU   0                   CONTENTS IN-N/A                      08100013
*                                  USE-ADDRESS OF ERROR MESSAGE         08200013
*                                  CONTENTS OUT-N/A                     08300013
RB       EQU   1                   CONTENTS IN-N/A                      08400013
*                                  USE-LENGTH OF ERROR MESSAGE.         08500013
*                                  CONTENTS OUT-N/A                     08600013
RC       EQU   2                   CONTENTS IN-N/A                      08700013
*                                  USE-COUNT OF CONTINUATION CARDS.     08800013
*                                  CONTENTS OUT-N/A                     08900013
RD       EQU   3                   CONTENTS IN-N/A                      09000013
*                                  USE-TOTAL CARD COUNT.                09100013
*                                  CONTENTS OUT-N/A                     09200013
RE       EQU   4                   CONTENTS IN-N/A                      09300013
*                                  USE-INCREMENT FOR ERROR MESSAGE.     09400013
*                                  CONTENTS OUT-N/A                     09500013
RF       EQU   5                   CONTENTS IN-N/A                      09600013
*                                  USE-ADDRESS OF INPUT WORK AREA.      09700013
*                                  CONTENTS OUT-N/A                     09800013
RG       EQU   6                   CONTENTS IN-N/A                      09900013
*                                  USE-ADDRESS OF INPUT WORK AREA.      10000013
*                                  CONTENTS OUT-N/A                     10100013
RH       EQU   7                   CONTENTS IN-N/A                      10200013
*                                  USE-COLUMN COUNTER.                  10300013
*                                  CONTENTS OUT-N/A                     10400013
RI       EQU   8                   CONTENTS IN-N/A                      10500013
*                                  USE-POINTER TO DICTIONARY ENTRY      10600013
*                                  CONTENTS OUT-N/A                     10700013
RJ       EQU   9                   CONTENTS IN-N/A                      10800013
*                                  USE-POINTER TO WORK AREA.            10900013
*                                  CONTENTS OUT-N/A                     11000013
RK       EQU   10                  CONTENTS IN-N/A                      11100013
*                                  USE-N/A                              11200013
*                                  CONTENTS OUT-N/A                     11300013
RL       EQU   11                  CONTENTS IN-N/A                      11400013
*                                  USE-MODULE BASE REGISTER.            11500013
*                                  CONTENTS OUT-N/A                     11600013
RM       EQU   12                  CONTENTS IN-N/A                      11700013
*                                  USE-IERRCQ BASE (CONTROL DICTIONARY) 11800013
*                                  CONTENTS OUT-N/A                     11900013
RN       EQU   13                  CONTENTS IN- ADDRESS OF CPI          12000013
*                                  USE- CPI REFERENCE,REGISTER SAVE     12100013
*                                    AREA                               12200013
*                                  CONTENTS OUT- ADDRESS OF CPI         12300013
RO       EQU   14                  CONTENTS IN-RETURN REGISTER.         12400013
*                                  USE-RETURN REGISTER.                 12500013
*                                  CONTENTS OUT-RETURN REGISTER.        12600013
RP       EQU   15                  CONTENTS IN-ADDRESS OF MODULE.       12700013
*                                  USE-RETURN CODE REGISTER.            12800013
*                                  CONTENTS OUT-RETURN CODE.            12900013
PPISW1   EQU   CPISW1                                                   13000013
         SPACE 2                                                        13100013
*START OF MODULE CODE PROPER:                                           13200013
         SPACE 2                                                        13300013
IERRCC   CSECT                                                          13400013
         USING *,RL                PROGRAM BASE                         13500013
         USING IERRC5,RN           CPI BASE                             13600013
         USING IERRCQ,RM           CONTROL DICTIONARY BASE              13700013
         SPACE 3                                                        13800013
         STM   RC,RL,0(RM)         SAVE REGISTERS.                      13900013
         LR    RL,RP               SET PROGRAM BASE.                    14000013
         ST    RM,RSAVE12          STORE REGS 12 AND 14.                14100013
         ST    RO,RSAVE14                                               14200013
         L     RM,IERRCQX          LOAD IERRCQ BASE.                    14300013
*                                                                       14400013
*                                                                       14500013
* THIS SECTION CHECKS IF SORT HAS BEEN ATTACHED OR NOT. IF IT HAS, USER 14600013
* SUPPLIED POINTER ARE MOVED TO THE CONTROL DICTIONARY. THESE POINTERS  14700013
* ARE CHECKED THAT ENTRY LENGTHS DO NOT EXCEED PPOPER LIMITS. IF THEY   14800013
* DO, ERROR MESSAGE 8 IS PRINTED. IF NOT, CONTROL IS RETURN TO SORT     14900013
* SYSTEM CONTROL. IF SORT IS NOT ATTACHED, THIS ROUTINE CONTINUES BY    15000013
* READING A CARD.                                                       15100013
*                                                                       15200013
         TM    PPISW1+3,X'04'      HAS SORT BEEN ATTACHED.              15300013
         BZ    RRINIT              IF NOT, CONTINUE INTO ROUTINE.       15400013
         NI    PPISW1+4,X'87'      TURN ON SW1 TO INDICATE SORT AND     15500013
         OI    PPISW1+4,X'50'        RECORD CARDS PRESENT.              15600013
         MVC   IERRCQ(16),0(RC)    IF SO,MOVE POINTERS INTO DICTIONARY. 15700013
         L     RB,4(0,RM)          DOES EITHER ENTRY EXCEED THE MAXIMUM 15800013
         S     RB,IERRCQ             ALLOWABLE NO. OF CHARACTERS.       15900013
         L     RC,K1100              IF SO, GO TO PRINTERR              16000013
         CR    RB,RC                                                    16100013
         BH    PRINTERR            BRANCH IF ERROR                      16200018
         L     RB,12(0,RM)                                              16300013
         S     RB,8(0,RM)                                               16400013
         CR    RB,RC                                                    16500013
         BH    PRINTERR            BRANCH IF ERROR                      16600018
         B     RZERO               IF ENTRIES OK, GO TO RZERO.          16700013
*                                                                       16800013
PRINTERR LA    RE,8                                                     16900013
         A     RE,IERRCYX          SET UP PRINT ERROR MESSAGE.          17000013
         LM    0,1,0(RE)                                                17100013
         L     RP,IERGAPRX                                              17200013
         BALR  RO,RP               GO TO PRINT ROUTINE.                 17300013
         B     RFOUR               GO TO RFOUR TO RETURN.               17400013
*                                                                       17500013
* THIS SECTION INITIALIZES POINTERS AND SWITCHES FOR USE WITHIN THE     17600013
* READ MODULE (IEREAD).                                                 17700013
*                                                                       17800013
RRINIT   MVI   RERRORSW,X'00'      SET ERROR SWITCH OFF.                17900013
         NI    PPISW1+4,X'87'      INITIALIZE PPISW1.                   18000013
         MVI   WWORKSW1,X'00'                                           18100013
         MVI   WWORKSW2,X'00'      TURN OFF 'WORKING ON' SWITCHES.      18200013
         MVI   WWORKSW3,X'00'                                           18300013
         MVI   WCOMSW,X'00'        SET COMMENT SWITCH OFF.              18400013
         MVI   WDONE,X'00'         SET 'WORKING ON' SWITCH OFF.         18500013
         MVI   WCOL16,X'00'        SET COLUMN 16 SWITCH OFF.            18600013
         LA    RD,34               INITIALIZE TOTAL CARD COUNT          18700013
         L     RI,WPOINT           RI CONTAINS POINTER TO DICT. ENTRY.  18800013
         LA    RG,WWORK            ADDRESS OF WORK AREA FOR MOVE.       18900013
         OPEN  (CONCARD)           OPEN SYSIN (CONCARD)                 19100013
*                                                                       19200013
* THE FOLLOWING CHECKS FOR SUCCESSFUL OPEN OF SYSIN. IF NOT SUCCESSFUL, 19300013
*  IT PRINTS 'OPEN ERR'.                                                19400013
*                                                                       19500013
         TM    RERRSW2,X'FF'       IS BLKSIZE VALID                     19520017
         BO    RCCBLKBD            BRANCH IF NO                         19540017
         SPACE 1                                                        19560017
         TM    CONCARD+48,X'10'    WAS OPEN SUCCESSFUL....              19600013
         BO    RREAD                 YES-BRANCH AND CONTINUE.           19700013
*                                                                       19800013
         LA    RE,56                 NO-SET UP ADDRESS AND LENGTH OF    19900013
         A     RE,IERRCYX            'OPEN ERR' MESSAGE.                20000013
         LM    0,1,0(RE)                                                20100013
         L     RP,IERGAPRX                                              20200013
         BALR  RO,RP                 GO TO PRINT ERROR MESSAGE.         20300013
         LA    RP,4                  SET ERROR CODE IN REG 15.          20400013
         B     RLEAVE                BRANCH TO EXIT TO IERRCM.          20500013
         SPACE 2                                                        20510017
RCCBLKBD LA    RE,56               SET UP ADDRESS                       20520017
         A     RE,IERRCYX          AND LENGTH OF                        20530017
         LM    0,1,0(RE)           'OPEN ERR'                           20540017
         L     RP,IERGAPRX         MESSAGE                              20550017
         BALR  RO,RP               GO TO PRINT ERROR MESSAGE.           20560017
         B     RFOUR               GO CLOSE SYSIN AND ABORT             20570017
*                                                                       20600013
*                                                                       20700013
* THIS SECTION READS A CARD INTO WWORK. IF END OF CARDS, IT GOES TO     20800013
* LAST CARD ROUTINE. IT CHECKS FOR BLANK FIRST COLUMN FOLLOWED BY       20900013
* STMT DEFINER.                                                         21000013
*                                                                       21100013
RREAD    LA    RH,70               INITIALIZE COLUMN COUNT.             21200013
         LA    RJ,WWORK+1          INITIALIZE POINTER TO WWORK.         21300013
         LA    10,CONCARD                                               21400013
         GET   (10)                GET NEXT CARD.                       21500013
         MVC   WWORK(80),0(1)      MOVE IMAGE FROM BUFFER TO WWORK.     21600013
         TM    CPISW1+6,X'01'      IS DIAGNOSTIC SWITCH ON....          21700013
         BZ    *+8                   NO-BRANCH AROUND NEXT INSTRUCTION. 21800013
         BAL   RK,RCCONPRT           YES-BRANCH TO PRINT CARD.          21900013
*                                                                       22000013
         BCT   RD,RNEXT            HAVE 33 CARDS BEEN READ              22100013
         B     RERROR18            IF SO, ERROR EXIT 18.                22200013
RNEXT    CLI   WWORK,C' '          TEST COLUMN ONE FOR BLANK.           22300013
         BNE   RERROR1             IF NOT BLANK, ERROR EXIT1.           22400013
RCOMPARE CLI   0(RJ),C' '          SEARCH FOR NON-BLANKS.               22500013
         BNE   RTEST               BLANKS FOUND, SO TEST FOR STMT DEF.  22600013
         LA    RJ,1(0,RJ)          INCREMENT COLUMN COUNTER.            22700013
         BCT   RH,RCOMPARE         DECREMENT COLUMN COUNT.              22800013
         B     RERROR11            WHOLE CARD BLANK, ERROR EXIT 11.     22900013
*                                                                       23000013
* THIS SECTION TESTS FOR STMT DEFINER,  IF NONE OF THE ALLOWABLE ONES,  23100013
* ERROR EXIT 12 IS TAKEN.                                               23200013
*                                                                       23300013
RTEST    CLC   KSORT,0(RJ)         IS IT A SORT.                        23400013
         BE    RSORT               IF SO( GO TO RSORT.                  23500013
         CLC   KMERGE,0(RJ)        IS IT A MERGE.                       23600013
         BE    RMERGE              IF SO( GO TO RMERGE.                 23700013
         CLC   KRECORD,0(RJ)        IS IT A RECORD.                     23800013
         BE    RRECORD             IF SO, GO TO RRECORD.                23900013
         CLC   KMOD,0(RJ)          IS IT A MOD.                         24000013
         BE    RMOD                IF SO, GO TO RMOD.                   24100013
         CLC   KEND,0(RJ)          IS IT END.                           24200013
         BE    RCCEND              IF SO, TAKE BRANCH.                  24300013
         CLC   KINPFIL,0(RJ)       IS IT INPFIL.                        24400013
         BE    RCHECK              IF SO, TAKE BRANCH                   24500013
         CLC   KOUTFIL,0(RJ)       IS IT OUTFIL.                        24600013
         BE    RCHECK              IF SO, TAKE BRANCH.                  24700013
         CLC   KOPTION,0(RJ)       IS IT OPTION.                        24800013
         BE    RCHECK              IF SO, TAKE BRANCH.                  24900013
         B     RERROR7             IF NONE OF ABOVE, GO TO ERROR EXIT7. 25000013
*                                                                       25100013
* THIS SECTION HANDLES SETTING THE SORT BIT IN PPISW1 AND UP'DATING THE 25200013
* COLLUMN POINTER TO THE WORK AREA.                                     25300013
*                                                                       25400013
RSORT    CLI   0(RJ),C' '          SEARCH FOR BLENK FOLLOWING SORT.     25500013
         BE    RSET1               GO AND SET BIT IN PPISW1             25600018
         LA    RJ,1(0,RJ)          UP'DATE POINTER.                     25700013
         BCT   RH,RSORT            DECREMENT COLUMN COUNT.              25800013
         B     RERROR14            NO BLANK, GO TO ERROR EXIT 14.       25900013
*                                                                       26000013
RSET1    OI    PPISW1+4,X'40'      SET SORT BIT IN PPISW1.              26100013
*                                                                       26200013
* THIS SECTION IS USED BY BOTH SORT AND MERGE. IT TESTS FOR ALREADY     26300013
* PROCESSED SORT/MERGE CARDS, PLACES ADDRESS OF STARTING POINT INTO THE 26400013
* DICTIONARY AND INITIALIZES THE CONTINUATION COUNT (RE).               26500013
*                                                                       26600013
RCOMMON  TM    WDONE,X'01'         HAVE SORT/MERGE CARDS BEEN PROCESSED 26700013
         BO    RERROR8             IF SO, ERROR EXIT 8.                 26800013
         MVI   WWORKSW1,X'01'      INDICATE WORKING ON SORT/MERGE CARD. 26900013
         OI    WDONE,X'01'         INDICATE S/M CARD PROCESSED.         27000013
         ST    RI,IERRCQ           PLACE STARTING ADDRESS IN DICT.      27100013
         LA    RC,20               INITIALIZE CONTINUATION COUNTER      27200013
         B     RCONT               BRANCH TO FURTHER CHECKS.            27300013
*                                                                       27400013
* THIS SECTION UP-DATES POINTER TO COLUMN AND SETS BIT IN PPISW1 FOR    27500013
* MERGE.                                                                27600013
*                                                                       27700013
RMERGE   CLI   0(RJ),C' '          UP-DATE POINTER TO COLUMN.           27800013
         BE    RSET2               GO AND SET MERGEBIT IN PPISW1        27900018
         LA    RJ,1(0,RJ)                                               28000013
         BCT   RH,RMERGE           IF COLUMN 71 EXCEEDED, GO TO ERROR   28100013
         B     RERROR14              EXIT 14.                           28200013
*                                                                       28300013
RSET2    OI    PPISW1+4,X'20'      SET MERGE BIT IN PPI.                28400013
         B     RCOMMON             GO TO COMMON ROUTINE.                28500013
*                                                                       28600013
* THIS SECTION UP-DATES POINTER, TURNS ON MOD BIT IN PPI, AND INITIAL-  28700013
* IZES CONTINUATION COUNT.                                              28800013
*                                                                       28900013
RMOD     CLI   0(RJ),C' '         UP-DATE POINTER.                      29000013
         BE    RSET3               BRANCH IF NO MOD                     29100018
         LA    RJ,1(0,RJ)                                               29200013
         BCT   RH,RMOD             UPDATE COUNTER                       29300018
         B     RERROR14            GO TO PRINT DEFINER ERROR            29400018
*                                                                       29500013
RSET3    TM    WDONE,X'04'         HAVE MOD CARDS BEEN PROCESSED.       29600013
         BO    RERROR8                                                  29700013
         MVI   WWORKSW3,X'01'      INDICATE WORKING ON MOCS CARD.       29800013
         OI    PPISW1+4,X'08'      SET MOD BIT IN PPI.                  29900013
         ST    RI,16(0,RM)         STORE STARTING ADDRESS IN DICT.      30000013
         LA    RC,20               INITIALIZE CONTNUATION COUNTER.      30100013
         B     RCONT               CONTINUE AT RCONT.                   30200013
*                                                                       30300013
* THIS SECTION UP-DATES POINTER, TURNS ON RECORD BIT IN PPISW1, AND     30400013
* INITIALIZES CONTINUATION COUNT.                                       30500013
*                                                                       30600013
RRECORD CLI    0(RJ),C' '          UP-DATE POINTER.                     30700013
         BE    RSET4                                                    30800013
         LA    RJ,1(0,RJ)                                               30900013
         BCT   RH,RRECORD                                               31000013
         B     RERROR14                                                 31100013
*                                                                       31200013
RSET4    TM    WDONE,X'02'         HAS RECORD CARD BEEN PROCESSED.      31300013
         BO    RERROR8             IF SO, ERROR EXIT8.                  31400013
         MVI   WWORKSW2,X'01'      INDICATE WORKING ON RECORD CARDS.    31500013
         OI    PPISW1+4,X'10'      SET RECORD BIT IN PPI.               31600013
         ST    RI,8(0,RM)          STORE STARTING ADDRESS IN DICT.      31700013
         LA    RC,6                INITIALIZE CONTINUATION COUNTER.     31800013
         B     RCONT               CONTINUE.                            31900013
*                                                                       32000013
* THIS SECTION HANDLES CHECKING REMAINDER OF THE CARD FOR CONTINUATION, 32100013
* COMMENTS. IT MOVES CARD IMAGES FROM INPUT WORK AREA TO DICTIONARY,    32200013
* PROVIDES ENDING ADDRESSES TO DICTIONARY, COUNTS CONTINUATION CARDS.   32300013
*                                                                       32400013
RCONT    CLI   0(RJ),C' '          SERACH FOR MORE NON-BLANKS.          32500013
         BNE   RMOREBL             FOUND, SO GO TO RMOREBL              32600013
         LA    RJ,1(0,RJ)          IF NOT, INCREMENT POINTER AND KEEP   32700013
         BCT   RH,RCONT              SEARCHING.                         32800013
         B     RERROR14            IF EXCEED COL 71,ERROR EXIT 14.      32900013
*                                                                       33000013
RMOREBL  CLI   0(RJ),C' '          OPERAND FOUND, SO SEARCH FOR BLANKS. 33100013
         BE    RCOMMA              IF FOUND, GO TO RCOMMA.              33200013
         LA    RJ,1(0,RJ)          UP-DATE POINTER.                     33300013
         BCT   RH,RMOREBL          KEEP SEARCHING FOR BLANKS.           33400013
         CLI   0(RJ),C' '          IS COLUMN 72 BLANK                   33500013
         BNE   RMOVE2              IF NOT, GO TO REMOV2.                33600013
RMOVE1   CLI   WCOL16,X'00'                                             33700013
         BNE   RMOVE3              IS COL 16 SWITCH ON.                 33800013
         MVC   0(71,RI),WWORK      MOVE CHARS TO DICTIONARY.            33900013
         LA    RI,70(0,RI)         UP-DATE POINTER TO END OF ENTRY.     34000013
RWHICH   CLI   WWORKSW1,X'01'      IS IT A SORT/MERGE CARD.             34100013
         BE    RSTORE1             IF SO, GO TO RSTORE1.                34200013
         CLI   WWORKSW2,X'01'      IS IT A RECORD CARD.                 34300013
         BE    RSTORE2             IF SO, GO TO RSTORE2.                34400013
         B     RSTORE3             IF NEITHER 1 NOR 2, BRANCH TO 3.     34500013
*                                                                       34600013
RMOVE3   MVC   0(56,RI),15(RG)     VOVE CHARS. FROM COL 16-71 TO DICT.  34700013
         LA    RI,55(0,RI)         UP-DATE POINTER TO END OF ENTRYZ.    34800013
         B     RWHICH              BRANCH TO TEST TYPE OF CARD          34900018
*                                                                       35000013
RSTORE3  ST    RI,20(0,RM)         STORE ENDING ADDRESS IN DICT.        35100013
         OI    WDONE,X'04'         INDICATE MODS PROCESSED.             35200013
RRETURN  LA    RI,1(0,RI)          UP-DATE POINTER TO NEXT START.       35300013
         MVI   WWORKSW1,X'00'                                           35400013
         MVI   WWORKSW2,X'00'      TURN OFF WORKING ON SWITCHES.        35500013
         MVI   WWORKSW3,X'00'                                           35600013
         MVI   WCOL16,X'00'        TURN OFF COLUMN 16 SWITCH.           35700013
         B     RREAD               READ ANOTHER CARD.                   35800013
*                                                                       35900013
RSTORE1  ST    RI,4(0,RM)          STORE ENDING ADDRESS FOR SORT/MERGE. 36000013
         OI    WDONE,X'01'         INDICATE SORT/MERGE PROCESSED.       36100013
         B     RRETURN             READ ANOTHER CARD.                   36200013
RSTORE2  ST    RI,12(0,RM)         STORE ENDING ADDRESS FOR RECORD CD.  36300013
         OI    WDONE,X'02'         INDICATE RECORD PROCESSED.           36400013
         B     RRETURN             READ ANOTHER CARD.                   36500013
*                                                                       36600013
RCOMMA   BCTR  RJ,0                IS THE PREVIOUS CHARACTER A COMMA{   36700013
         CLI   0(RJ),C','                                               36800013
         BE    RCHECK72            IF SO, CHECK COL.72 FOR BLANKS.      36900013
         CLI   WWORK+71,C' '       CHECK COL.72 FOR BLANKS.             37000013
         BE    RMOVE1              IF SO, MOVE TO DICTIONARY.           37100013
         MVI   WCOMSW,X'01'        IF NOT, TURN ON COMMENT SWITCH.      37200013
RMOVE2   CLI   WCOL16,X'00'        IS COL.16 SWITCH ON{                 37300013
         BNE   RMOVE               IF SO, GO TO RMOVE.                  37400013
         MVC   0(71,RI),WWORK      MOVE CHARACTERS TO DICTIONARY.       37500013
         LA    RI,71(0,RI)         INCREMENT DICT POINTER BY 71.        37600013
         B     RENTRY              GO TO RENTRY.                        37700013
*                                                                       37800013
* THIS SECTION HANDLES MOVEING CHARACTER STARTING IN COLUMN 16 FROM THE 37900013
* WORK AREA TO THE DICTIONARY.                                          38000013
*                                                                       38100013
RMOVE    MVC   0(56,RI),15(RG)     MOVE CHARS FROM COLS 16-71 TO DICT.  38200013
         LA    RI,56(0,RI)         UP-DATE DICT POINTER.                38300013
RENTRY   BCT   RC,RREAD2           IF TOO MANY CARDS, ERROR EXIT 8.     38400013
         B     RERROR8             GO TO PRINT EXCESS CARDS             38500018
RREAD2   LA    10,CONCARD                                               38600013
         MVC   CONCARD+33(3),ERROR16X   SET UP END OF CARDS ROUTINE     38700013
*                                         (RERROR16) INTO DCB FOR GET.  38800013
         GET   (10)                 GET NEXT CARD.                      38900013
         MVC   CONCARD+33(3),LASTCDX    RESET END OF CARDS ADDRESS.     39000013
         MVC   WWORK(80),0(1)      MOVE IMAGE FROM BUFFER TO WWORK.     39100013
         TM    CPISW1+6,X'01'      IS DIAGNOSTIC SWITCH ON....          39200013
         BZ    *+8                   NO-BRANCH AROUND NEXT INSTRUCTION. 39300013
         BAL   RK,RCCONPRT           YES-BRANCH TO PRINT CARD.          39400013
*                                                                       39500013
         BCT   RD,RNEXT1           HAVE CARDS EXCEEDED 33               39600013
         B     RERROR18            IF SO, ERROR EXIT 18.                39700013
RNEXT1   LA    RH,15               REINITIALIZE COLUMN COUNT.           39800013
         LA    RJ,WWORK            REINITIALIZE COLUMN POINTER.         39900013
RBLANKS  CLI   0(RJ),C' '          ARE COLS. 1-15 BLANK{                40000013
         BNE   RERROR3             IF NOT, ERROR EXIT 3.                40100013
         LA    RJ,1(0,RJ)          INCREMENT POINTER.                   40200013
         BCT   RH,RBLANKS          DECREMENT COLUMN COUNT.              40300013
         MVI   WCOL16,X'01'        COLS 1-15 BLANK, TURN ON COL 16 SW.  40400013
         CLI   WCOMSW,X'00'        IS COMMENT SWITCH ON{                40500013
         BE    REINIT              IF NOT,RESET COL COUNT,GO TO RMOREBL 40600013
RCOL72   CLI   WWORK+71,C' '       IS COLUMN 72 BLANK.                  40700013
         BNE   RENTRY              IF NOT, READ UNTIL ALL COMMENTS DONE 40800013
         MVI   WCOMSW,X'00'        IF SO. TURN OFF COMMENT SWITCH.      40900013
         B     RWHICH              GO TO RWHICH.                        41000013
*                                                                       41100013
REINIT   CLI   WWORK+15,C' '       IS COLUMN 16 BLANK.                  41200013
         BE    RTURNON             IF SO, GO TO RTURNON.                41300013
         LA    RH,56               RESET COLUMN COUNT.                  41400013
         B     RMOREBL             BO TO RMOREBL.                       41500013
*                                                                       41600013
RTURNON  MVI   WCOMSW,X'01'        TURN ON COMMENT SWITCH.              41700013
         B     RCOL72              BRANCH TO CHECK COL 72.              41800013
*                                                                       41900013
RCHECK72 CLI   WWORK+71,C' '       IS COLUMN 72 BLANK{                  42000013
         BE    RERROR15            IF SO, ERROR EXIT 15.                42100013
         LA    RJ,1(0,RJ)          RESET POINTER IN WWORK.              42200013
         S     RJ,WADDR            IF NOT,FIND NUMBER OF CHARS TO MOVE. 42300013
         CLI   WCOL16,X'00'        IS COL 16 SWITCH ON{                 42400013
         BNE   RFIND               IF SO, GO TO RFIND.                  42500013
         MVC   0(71,RI),WWORK      IF NOT, MOVE TO DICT.                42600013
         AR    RI,RJ               UP-DATE DICT POINTER BY NO. MOVED.   42700013
         B     RENTRY              CHECK CARD COUNT.                    42800013
*                                                                       42900013
RFIND    S     RJ,KFIFTEEN         IF COL.16 SWITCH ON, SUB 15 FROM     43000013
*                                    NUMBER TO MOVE                     43100013
         MVC   0(56,RI),15(RG)     MOVE COLS 16-71 TO DICT.             43200013
         AR    RI,RJ               UP-DATE DICT POINTER BY NO. MOVED.   43300013
         B     RENTRY              BRANCH TO CHECK CARD COUNT.          43400013
RERROR1  LA    RE,0                MESSAGE....                          43500013
         B     RPRINT                COL 1 OR 1-15 NOT BLANK            43600013
*                                                                       43700013
RERROR3  LA    RE,0                MESSAGE....                          43800013
         B     RPRINT                COL 1 OR 1-15 NOT BLANK            43900013
*                                                                       44000013
RERROR7  LA    RE,32               MESSAGE....                          44100013
         B     RPRINT                STMT DEFINER ERR                   44200013
*                                                                       44300013
RERROR8  LA    RE,8                MESSAGE....                          44400013
         B     RPRINT                EXCESS CARDS                       44500013
*                                                                       44600013
RERROR11 LA    RE,32               MESSAGE....                          44700013
         B     RPRINT                STMT DEFINER ERR                   44800013
*                                                                       44900013
RERROR14 LA    RE,40               MESSAGE....                          45000013
         B     RPRINT                OP DEFINER ERR                     45100013
*                                                                       45200013
RERROR15 LA    RE,24               MESSAGE....                          45300013
         B     RPRINT                ILLEGAL OP DELIMITER               45400013
*                                                                       45500013
RERROR16 LA    RE,16               MESSAGE....                          45600013
         B     RPRINT2               NO CONTIN CARD                     45700013
*                                                                       45800013
RERROR17 LA    RE,48               MESSAGE....NO S/M CARD.              45900013
RPRINT1  A     RE,IERRCYX                                               46000013
         LM    0,1,0(RE)           SET UP ERROR MESSAGE.                46100013
         L     RP,IERGAPRX                                              46200013
         BALR  RO,RP               GO TO PRINT ROUTINE.                 46300013
         MVI   RERRORSW,X'01'      SET ERROR SWITCH ON.                 46400013
         B     RRETURN1            RETURN.                              46500013
*                                                                       46600013
*                                                                       46700013
RPRINT2  A     RE,IERRCYX                                               46800013
         LM    0,1,0(RE)           SET UP ERROR MESSAGE.                46900013
         L     RP,IERGAPRX                                              47000013
         BALR  RO,RP               GO TO PRINT ROUTINE.                 47100013
         MVI   RERRORSW,X'01'      TURN ON ERROR SWITCH.                47200013
         B     LASTCARD            GO TO LASTCARD.                      47300013
*                                                                       47400013
*                                                                       47500013
RPRINT   A     RE,IERRCYX                                               47600013
         LM    0,1,0(RE)           SET UP ERROR MESSAGE.                47700013
         L     RP,IERGAPRX                                              47800013
         BALR  RO,RP               GO TO PRINT ROUTINE.                 47900013
         MVI   RERRORSW,X'01'      TURN ON ERROR SWITCH.                48000013
RCHECK   CLI   WWORK+71,C' '       IS COLUMN 72 BLANK.                  48100013
         BE    RRETURN+4           IF BLANK, READ ANOTHER CARD.         48200013
         LA    10,CONCARD                                               48300013
         GET   (10)                 GET NEXT CARD.                      48400013
         MVC   WWORK(80),0(1)      MOVE IMAGE FROM BUFFER TO WWORK.     48500013
         TM    CPISW1+6,X'01'      IS DIAGNOSTIC SWITCH ON....          48600013
         BZ    *+8                   NO-BRANCH AROUND NEXT INSTRUCTION. 48700013
         BAL   RK,RCCONPRT           YES-BRANCH TO PRINT CARD.          48800013
*                                                                       48900013
*                                                                       49000013
         BCT   RD,RCHECK           HAVE 33 CARDS BEEN RXCEEDED          49100013
RERROR18 LA    RE,8                                                     49200013
         A     RE,IERRCYX          SET UP ERROR MESSAGE.                49300013
         LM    0,1,0(RE)                                                49400013
         L     RP,IERGAPRX                                              49500013
         BALR  RO,RP               GO TO PRINT ROUTINE.                 49600013
         MVI   RERRORSW,X'01'      TURN ON ERROR SWITCH.                49700013
RREAD3   LA    10,CONCARD                                               49800013
         GET   (10)                GET NEXT CARD.                       49900013
         MVC   WWORK(80),0(1)      MOVE IMAGE FROM BUFFER TO WWORK.     50000013
         TM    CPISW1+6,X'01'      IS DIAGNOSTIC SWITCH ON....          50100013
         BZ    *+8                   NO-BRANCH AROUND NEXT INSTRUCTION. 50200013
         BAL   RK,RCCONPRT           YES-BRANCH TO PRINT CARD.          50300013
*                                                                       50400013
         CLI   WWORK,C' '          IS COLUMN ONE BLANK.                 50500013
         BNE   RREAD3              IF NOT, READ ANOTHER CARD.           50600013
         LA    RH,70               INITIALIZE COLUMN  COUNT.            50700013
         LA    RJ,WWORK+1          INITIALIZE COLUMN POINTER.           50800013
RCOMPAR1 CLI   0(RJ),C' '          SEARCH FOR NON-BLANK.                50900013
         BNE   RTEST1              IF NOT BALNK, BRANCH TO RTEST1.      51000013
         LA    RJ,1(0,RJ)          UP-DATE POINTER.                     51100013
         BCT   RH,RCOMPAR1         DECREMENT COLUMN COUNT.              51200013
         B     RREAD3              IF CRD BLANK, READ NEXT CARD.        51300013
RTEST1   CLC   KEND,0(RJ)          IS IT AN END CARD.                   51400013
         BNE   RREAD3              IF NOT, READ NEXT CARD.              51500013
*                                                                       51600013
*                                                                       51700013
*  THIS SECTION TAKES CARE OF RETURN TO ROUTINE FROM WHICH THE READ     51800013
* ROUTINE WAS CALLED. IT CHECKS THE ERROR SWITHC OT DETERMINE IF ANY    51900013
* ERRORS HAD BEEN ENCOUNTERED.  IF SO, IT PLACES A 4 IN REG 15.  IF     52000013
* NOT, IT PLACES A ZERO IN REG 15.                                      52100013
*                                                                       52200013
RRETURN1 CLI   RERRORSW,X'01'      IS ERROR SWITCH ON.                  52300013
         BE    RFOUR               IF SO, BRANCH TO RFOUR.              52400013
RZERO    CLOSE (CONCARD)           CLOSE SYSIN (CONCARD).               52500013
         TM    CPISW1+3,X'04'      WERE WE LINKED,ATTACHED OR XCTL'D    52520017
         BO    RNOSYSIN            BRANCH IF YES                        52540017
         FREEPOOL CONCARD          FREE SYSIN BUFFER                    52560017
RNOSYSIN EQU   *                                                        52580017
         SR    RP,RP               PLACE ZERO INTO REG 15.              52600013
RLEAVE   L     RM,RSAVE12                                               52700013
         L     RO,RSAVE14          RESTORE REGISTERS.                   52800013
         LM    RC,RL,0(RM)                                              52900013
         BR    RO                  RETURN.                              53000013
*                                                                       53100013
RFOUR    CLOSE (CONCARD)           CLOSE SYSIN (CONCARD).               53200013
         TM    CPISW1+3,X'04'      WERE WE LINKED,ATTACHED OR XCTL'D    53220017
         BO    RNOSYSN             BRANCH IF YES                        53240017
         FREEPOOL CONCARD          FREE SYSIN BUFFER                    53260017
RNOSYSN  EQU   *                                                        53280017
         LA    RP,4                PLACE ERROR CODE INTO REG 15.        53300013
         B     RLEAVE              RETURN.                              53400013
*                                                                       53500013
*                                                                       53600013
LASTCARD TM    WDONE,X'01'         HAS SORT/MERGE BEEN HANDLED.         53700013
         BZ    RERROR17            IF NOT, ERROR EXIT 17.               53800013
         B     RRETURN1            IF SO, RETURN.                       53900013
*                                                                       54000013
*                                                                       54100013
*  THIS SECTION CHECKS FOR CONTINUATION OR NO CONTINUATION ON END       54200013
*    CARD AND LEGALITY OF CONTINUATION IF PRESENT.                      54300013
*                                                                       54400013
RCCEND   CLI   WWORK+71,C' '       IS COLUMN 72 BLANK....               54500013
         BE    LASTCARD              YES-GO TO LASTCARD.                54600013
RCCGET   LA    10,CONCARD                                               54700013
         MVC   CONCARD+33(3),ERROR16X  SET UP END OF CARDS ROUTINE      54800013
*                                    (RERROR16) IN DCB.                 54900013
         GET   (10)                GET NEXT CARD.                       55000013
         MVC   WWORK(80),0(1)      MOVE CARD IMAGE TO WORK AREA.        55100013
         TM    CPISW1+6,X'01'      IS DIAGNOSTIC SWITCH ON....          55200013
         BZ    *+8                   NO-BRANCH AROUND NEXT INSTRUCTION. 55300013
         BAL   RK,RCCONPRT           YES-BRANCH TO PRINT CARD.          55400013
*                                                                       55500013
         BCT   RD,RCC1TO15         HAVE 33 CARDS BEEN READ              55600013
         B     RERROR18              YES-TAKE BRANCH.                   55700013
RCC1TO15 CLC   WWORK(15),KCCBLANK  COLUMNS 1 TO 15 BLANK....            55800013
         BNE   RERROR3               NO-TAKE BRANCH.                    55900013
         CLI   WWORK+71,C' '       IS COLUMN 72 BLANK....               56000013
         BE    LASTCARD              YES-GO TO LASTCARD.                56100013
         B     RCCGET                NO-GO TO GET ANOTHER CARD.         56200013
*                                                                       56300013
*                                                                       56400013
* THIS SECTION PRINTS OUT THE SORT CONTROL CARDS IF THE DIAGNOSTIC      56500013
*  SWITCH IS ON.                                                        56600013
*                                                                       56700013
RCCONPRT LA    RA,WWORK            LOAD PRINT-OUT AREA ADDRESS.         56800013
         LA    RB,80                 SET UP MESSAGE LENGTH.             56900013
         L     RP,IERGAPRX           SET UP PRINT ROUTINE ADDRESS.      57000013
         BALR  RO,RP               GO TO PRINT CONTROL CARD.            57100013
         BR    RK                  RETURN TO CALLER.                    57200013
*                                                                       57300013
*                                                                       57400013
*THE FOLLOWING IS THE CONSTANT AND WORK AREA                            57500013
*                                                                       57600013
KCCBLANK DC    CL15' '             15 BLANKS                            57700013
         DS    0D                                                       58000013
WWORK    DS    CL80                80-BYTE INPUT WORK AREA              58100013
         DS    0D                  FORCE DOUBLE WORD BOUNDARY           58200013
WADDR    DC    A(WWORK)            ADDRESS OF WORK AREA.                58300013
KFIFTEEN DC    F'15'               FIFTEEN                              58400018
IERRCQX  DC    A(IERRCQ)           STARTING ADRESS OF DICTIONARY.       58500013
IERRCYX  DC    A(IERRCY)           ADDRESS OF MESSAGE MODULE            58600013
IERGAPRX DC    V(IERGAPRT)         ADDRESS OF PRINT ROUTINE             58700013
LASTCDX  DC    AL3(LASTCARD)       ADDRESS OF TWO LASTCARD              58800013
ERROR16X DC    AL3(RERROR16)          ROUTINES.                         58900013
         DS    0F                  FORCE FULL WORD BOUNDARY.            59000013
RSAVE12  DC    F'0'                SAVEAREA FOR REG 12                  59100018
RSAVE14  DC    F'0'                                                     59200018
K1100    DC    A(1100)             MAX ALLOWABLE CHARACTERS IN ENTRY    59300018
WCOMSW   DC    X'00'               COMMENT SWITCH                       59400013
WWORKSW1 DC    X'00'               SORT/MERGE WORKING SWITCH            59500013
WWORKSW2 DC    X'00'               RECORD WORKING SWITCH                59600013
WWORKSW3 DC    X'00'               MODS WORKING SWITCH.                 59700013
WDONE    DC    X'00'               DONE WITH SWITCH.                    59800013
RERRORSW DC    X'00'               ERROR SWITCH                         59900013
RERRSW2  DC    X'00'               ERROR SW. FOR INVALID SYSIN BLKSIZE  59950017
WPOINT   DC    A(IERRCQ+24)        CONTAINS ADDRESS OF ENTRY IN DECT.   60000013
KSORT    DC    CL5'SORT '          SORT IMAGE                           60100018
KMERGE   DC    CL6'MERGE '         MERGE IMAGE                          60200018
KRECORD  DC    CL7'RECORD '                                             60300018
KMOD     DC    CL5'MODS '          MODS IMAGE                           60400018
KEND     DC    CL4'END '           END  IMAGE                           60500018
KINPFIL  DC    CL7'INPFIL '        INPFILE IMAGE                        60600018
KOUTFIL  DC    CL7'OUTFIL '        OUTFILE IMAGE                        60700018
KOPTION  DC    CL7'OPTION '        OPTION IMAGE                         60800018
WCOL16   DC    X'00'               COLUMN 16 SWITCH.                    60900013
         DS    0F                                                       61000013
         EJECT                                                          61100013
CONCARD  DCB   DSORG=PS,MACRF=(GL),RECFM=FB,LRECL=80,EXLST=RCCDCBEX,   X61110017
               BUFNO=1,DDNAME=SYSIN,EODAD=LASTCARD                      61120017
RCCDCBEX DS    0F                                                       61130017
         DC    X'85'               EXITLIST                             61140018
         DC    AL3(RCCEXIT)        ADDRESS TO RCCEXIT                   61150018
RCCEXIT  OC    62(2,RB),62(RB)     HAS BLKSIZE BEEN PROVIDED            61160017
         BNZ   RCCBLKSI            BRANCH IF YES                        61170017
         MVC   62(2,RB),82(RB)     NO - SET = LRECL                     61180017
         BR    RO                  RETURN                               61190017
         SPACE 2                                                        61200017
RCCBLKSI SR    RC,RC                                                    61210017
         LH    RP,82(RB)           PICK UP LRECL                        61220017
         LH    RD,62(RB)           PICK UP BLKSIZE                      61230017
         DR    RC,RP                                                    61240017
         LTR   RC,RC               ANY REMAINDER                        61250017
         BCR   8,RO                IF NOT - RETURN                      61260017
         SPACE 2                                                        61270017
         MVI   RERRSW2,X'FF'       SET ERROR INDICATION                 61280017
         BR    RO                  RETURN                               61290017
         SPACE 2                                                        61300017
         END                                                            61400013
