         TITLE 'IERRCT - OS/360 SORT/MERGE - 360S-SM023 05/10/66'       00300013
*MODULE NAME:*** IERRCT ***                                             00600013
         SPACE 2                                                        00900013
*STATUS: CHANGE LEVEL 000                                               01200013
         SPACE 2                                                        01500013
*MODULE FUNCTION/OPERATION: INTER-PHASE CORE DELETION MODULE.           01800013
*   THE FUCTION OF THIS MODULE IS TO FREE CORE OBTAINED BY THE GETMAIN  02100013
*   MACRO , DELETES SORT RUNNING PROGRAMS AND USER PROGRAMS, AND CLOSES 02400013
*   I/O DEVICES IF THE JOB IS TO BE ABNORMALLY TERMINATED. THIS MODULE  02700013
*   IS IN CORE ONLY WHEN NECESSARY.GENERATED CORE WILL NOT BE FREED BY  03000013
*   THIS MODULE EXCEPT AT END OF TASK.                                  03300013
         SPACE 2                                                        03600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT -              03900013
*                                                                       04200013
*   N/A                                                                 04500013
*                                                                       04800013
*                                                                       05100013
*MACROS USED -                                                          05400013
         SPACE 1                                                        05700013
*   SMPPI   CLOSE  FREEMAIN                                             06000013
*   DELETE  DCBD                                                        06300013
         SPACE 2                                                        06600013
*ENTRY POINTS:                                                          06900013
         SPACE 1                                                        07200013
*        ENTRY                     ENTRY FROM: IERRCV                   07500013
*                                   CALLING SEQUENCE-                   07800013
*                                      LOAD    EP=IERRCT,DCB=SORTLIB    08100013
*                                      LR      RL,RA                    08400013
*                                      BALR    RO,RL                    08700013
         SPACE 2                                                        09000013
*INPUT: PPI FIELDS REFERENCED-                                          09300013
         SPACE 1                                                        09600013
*   PPISW1     PPIBDSVA  PPIMODEX  PPIALG                               09900013
*   PPISTDCB   PPIWKARE  PPIX16    PPINDSKA                             10200013
         SPACE 2                                                        10500013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED- NONE                        10800013
         SPACE 2                                                        11100013
*EXTERNAL ROUTINES:                                                     11400013
         SPACE 1                                                        11700013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  12000013
         SPACE 2                                                        12300013
*EXTERNAL PARAMETERS: NONE                                              12600013
         SPACE 1                                                        12900013
*EXITS: NORMAL                                                          13200013
         SPACE 1                                                        13500013
*        IERRCV                    SORT SYSTEM CONTROL                  13800013
         SPACE 2                                                        14100013
*EXITS: ERROR - NONE                                                    14400013
         SPACE 2                                                        14700013
*TABLES/WORK AREA:                                                      15000013
         SPACE 1                                                        15300013
*   GETMAIN TABLE POINTED TO BY PPIWKARE,(USED TO FREE CORE).           15600013
*   GETMAIN SIZES TABLE POINTED TO BY PPIWKARE+4,(USED TO FREE CORE).   15900013
*   DCB ENTRY TABLE POINTED TO BY PPISTDCB,(USED IN CLOSING UNITS).     16200013
*   MODULE TABLE BEGINING AT PPIALG AND ENDING AT PPIX16,               16500013
*      (USED AS A LIST OF MODULES TO BE DELETED).                       16800013
         SPACE 2                                                        17100013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  17400013
         SPACE 2                                                        17700013
*NOTES:                                                                 18000013
         SPACE 1                                                        18300013
*  CONDITION CODE IS PASSED IN RP.  ZERO INDICATES DELETION ONLY; 12    18600013
*  MEANS DELETION AND CLOSING OF OPEN DCB@S.   LABLES ARE KEYED TO      18900013
*  THE BOXES IN AUTOCHART KZ.                                           19200013
         SPACE 2                                                        19500013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            19800013
         SPACE 1                                                        20100013
RA       EQU   0                   CONTENTS IN  - N/A                   20400013
*                                  USE- PARAMETER REGISTER              20700013
*                                  CONTENTS OUT- N/A                    21000013
RB       EQU   1                   CONTENTS IN  - N/A                   21300013
*                                  USE- PARAMETER REGISTER              21600013
*                                  CONTENTS OUT- N/A                    21900013
RC       EQU   2                   CONTENTS IN  - N/A                   22200013
*                                  USE- BASE ADDRESS REGISTER FOR DCB'S 22500013
*                                  CONTENTS OUT- N/A                    22800013
RD       EQU   3                   CONTENTS IN  - N/A                   23100013
*                                  USE- GENERAL WORK REGISTER           23400013
*                                  CONTENTS OUT- N/A                    23700013
RE       EQU   4                   CONTENTS IN  - N/A                   24000013
*                                  USE- GENERAL WORK REGISTER           24300013
*                                  CONTENTS OUT- N/A                    24600013
RF       EQU   5                   CONTENTS IN  - N/A                   24900013
*                                  USE- COUNT OF WORK UNITS             25200013
*                                  CONTENTS OUT- N/A                    25500013
RG       EQU   6                   CONTENTS IN  - N/A                   25800013
*                                  USE- NOT USED                        26100013
*                                  CONTENTS OUT- N/A                    26400013
RH       EQU   7                   CONTENTS IN  - N/A                   26700013
*                                  USE- NOT USED                        27000013
*                                  CONTENTS OUT- N/A                    27300013
RI       EQU   8                   CONTENTS IN  - N/A                   27600013
*                                  USE- NOT USED                        27900013
*                                  CONTENTS OUT- N/A                    28200013
RJ       EQU   9                   CONTENTS IN  - N/A                   28500013
*                                  USE- NOT USED                        28800013
*                                  CONTENTS OUT- N/A                    29100013
RK       EQU   10                  CONTENTS IN  - N/A                   29400013
*                                  USE- NOT USED                        29700013
*                                  CONTENTS OUT- N/A                    30000013
RL       EQU   11                  CONTENTS IN  - THIS MODULE'S ADDRESS 30300013
*                                  USE- BASE REGISTER FOR THIS MODULE.  30600013
*                                  CONTENTS OUT- N/A                    30900013
RM       EQU   12                  CONTENTS IN  - N/A                   31200013
*                                  USE- NOT USED                        31500013
*                                  CONTENTS OUT- N/A                    31800013
RN       EQU   13                  CONTENTS IN  - ADDRESS OF PPI        32100013
*                                  USE- PPI REFERENCE,REGISTER SAVE     32400013
*                                    AREA                               32700013
*                                  CONTENTS OUT- ADDRESS OF PPI         33000013
*                                  USE- RETURN REGISTER                 33300013
RO       EQU   14                  CONTENTS IN  - RETURN ADDRESS IN RCV 33600013
*                                  CONTENTS OUT- RETURN ADDRESS         33900013
RP       EQU   15                  CONTENTS IN  - CONDITION CODE        34200013
*                                  USE- CONDITION CODE                  34500013
*                                  CONTENTS OUT- CONDITION CODE         34800013
         SPACE 2                                                        35100013
*START OF MODULE CODE PROPER:                                           35400013
         SPACE 2                                                        35700013
IERRCT   CSECT                                                          36000013
*0722789000                                                        4546 36100018
         USING *,RL                RL MAKES THIS MODULE ADDRESSABLE     36300013
         USING IHADCB,RC           RC WILL MAKE DCB ADDRESSABLE         36600013
         USING IERRCA,RN           RN MAKES PPI ADDRESSABLE             36900013
         SPACE 2                                                        37200013
         STM   RA,RP,RCTHOLD       SAVE GERNERAL REGISTERS              37500013
         SPACE 2                                                        37800013
         LA    RC,12               IF CONDITION CODE IN RP IS 12,       38100013
         CLR   RC,RP                 PERFORM ABNORMAL ENDING PROCEDURE. 38400013
         BE    RCTC2               GO TO TEST FOR MERGE RUN             38700018
         SPACE 2                                                        39000013
         TM    PPISW1+2,X'06'      IF PHASE THREE OR MERGE ONLY         39300013
         BNZ   RCTCHK              TEST FOR CHECKPOINT OPTION           39600017
         SPACE 1                                                        39900013
         TM    RCTB4SW+1,X'20'     IF BEFORE SWITCH IS ON CONTINUE      40200013
         BO    RCTA1                 WHERE WE LEFT OFF                  40500013
         SPACE 1                                                        40800013
         MVI   RCTB4SW+1,X'20'       ELSE TURN BEFORE SWITCH ON         41100013
         SPACE 1                                                        41400013
* THIS ROUTINE FRESS CORE OBTAINED VIA A GETMAIN. THE ADDRESS OF EACH   41700013
* PORTION OF CORE CAN BE FOUND IN A TABLE POINTED TO BY PPIWKARE, AND   42000013
* THE SIZE OF EACH PORTION CAN BE FOUND IN A TABLE POINTED TO BY PPI-   42300013
* WKARE+4 . THE LAST SIZE ENTRY MUST HAVE BIT 0 = 1 TO END FREEMAIN.    42600013
         SPACE 1                                                        42900013
         L     RJ,PPISTDCB         SET DCB TABLE ADDRESS                42930013
         SPACE 1                                                        42933013
         TM    PPISW1,X'02'        IS THIS AN OSCILLATING SORT          42936013
         BO    RCTPH               BRANCH IF YES                        42939013
         TM    PPISW1+6,X'02'      IS THIS A 2314 SORT                  42942013
         BO    RCTPH               BRANCH IF NO                         42945013
         TM    PPISW1+2,X'0E'      TEST FOR END OF PHASE 1              42948013
         BNZ   RCTD1              IF NO, BYPASS TEST FOR SORTIN CLOSED  42951013
         SPACE 1                                                        42954013
RCTPH    CLI   0(RJ),X'80'         IS SORTIN CLOSED                     42964013
         BE    RCTD1               YES, BRANCH AROUND SORTIN CLOSE      42990013
         L     RC,0(0,RJ)          GET DCB ADDRESS                      43020013
         CLOSE ((RC))              CLOSE SORTIN                         43050013
         MVI   0(RJ),X'80'         INDICATE SORTIN CLOSED               43080013
         SPACE 1                                                        43110013
RCTD1    L     RD,PPIWKARE         SET POINTER TO A(ADDRESSES)          43200013
         L     RC,PPIWKARE+4       SET POINTER TO A(SIZES)              43500013
RCTD1A   MVC   RCTPOSTV+1(3),1(RC) INSURE SIGN BIT IS DROPPED           43800013
         L     RA,RCTPOSTV         SET RA TO LENGTH OF CORE FREED       44100013
         L     RB,0(0,RD)          SET RB TO ADDRESS OF CORE FREED      44400013
         SPACE                                                          44700013
         FREEMAIN R,LV=(0),A=(1)   FREE PIECE OF CORE                   45000013
         SPACE                                                          45300013
         TM    0(RC),X'80'         WAS BIT ZERO = 1% I.E. LIST ENDED ?  45600013
         BO    RCTF1                 IF SO, CONTINUE                    45900013
         LA    RC,4(0,RC)          SET RC TO NEXT ENTRY LENGTH          46200013
         LA    RD,4(0,RD)          SET RD TO NEXT ENTRY ADDRESS         46500013
         B     RCTD1A              FREE NEXT PIECE OF CORE              46800013
         SPACE 2                                                        47100013
RCTF1    LA    RC,PPIALG           START OF MODULES                     47400013
         LA    RD,PPIOPEN          END OF MODULES STARTED BY IER        47700013
         LA    RE,PPIEOF                                                48000013
         SPACE 2                                                        48300013
RCTF2    L     RA,0(0,RC)          SET PARAMETER REGISTER TO AN ENTRY.  48600013
         LTR   RA,RA               IF THIS IS A NULL ENTRY              48900013
         BZ    RCTF3                 SKIP TO  NEXT ENTRY UPDATE         49200013
RCTST    MVC   WORK+3(3),0(RC)       ELSE PLACE NAME IN WORK AND        49500013
         LA    RA,WORK               ADDRESS OF WORK IN RA              49800013
         SPACE 2                                                        50100013
         DELETE   EPLOC=(0)        DELETE CORE INDICATED BY ENTRY.      50400013
         SPACE 2                                                        50700013
         LTR   RP,RP               IF AN ERROR CODE IS GENERATED BY     51000013
         BC    7,RCTJ1               THE DELETE MACRO,MODULE WAS LOST.  51300013
         SPACE 2                                                        51600013
RCTF3    LA    RC,8(0,RC)          UPDATE TO NEXT MODULE LIST ENTRY.    51900013
         CLR   RC,RE               TEST TO SEE IF BEFORE SWITCH SHOULD  52200013
RCTB4SW  NOP   RCTA2                 CAUSE A PAUSE OVER TO RCV          52500013
RCTG3    CLR   RC,RD               IF POINTER IS POINTING TO AN ENTRY   52800013
         BNH   RCTF2                 IN THE TABLE,GO BACK TO DELETE     53100013
         MVI   WORK,C' '           CLEAR WORK AREA TO BLANKS            53400013
         MVC   WORK+1(7),WORK                                           53700013
         MVC   RCTST(6),RCTSTOV    OVERLAY FOR USER EXITS               54000013
         LA    RD,PPIX16           SET RD TO END OF MODULES             54300013
         CLR   RC,RD               ARE WE ALREADY FINISHED              54600013
         BNH   RCTF2                 IF NOT FINISH USER EXITS           54900013
         SPACE 2                                                        55200013
RCTJ3    LM    RA,RP,RCTHOLD       RESTORE REGISTERS                    55500013
         BR    RO                  RETURN TO SORT SYSTEM CONTROL (RCV)  55800013
         SPACE 1                                                        56100013
RCTA1    LM    RC,RE,REGREST                                            56400013
         MVI   RCTB4SW+1,X'00'     TURN OFF BEFORE SWITCH               56700013
         B     RCTF2               GO TO TEST FOR NULL ENTRY            57000018
         SPACE 1                                                        57300013
RCTA2    STM   RC,RE,REGREST       SAVE REGS C,D & E FOR NEXT PASS      57600013
         B     RCTJ3               RETURN TO RCV FOR CLOSE              57900013
         SPACE 2                                                        58200013
RCTJ1    L     RP,PPIADSSC                                              58500013
         BAL   RO,28(0,RP)         WRITE DELETE ERROR MESSAGE           58800013
         MVI   RCTG4+1,X'00'       SET BRANCH TO RCTD1 AT RCTG4 TO NOP  59100013
         LM    RA,RO,RCTHOLD       RESTORE REGISTERS EXCEPT CC(RP).     59400013
         LA    RP,12               SET CC (RP) TO ERROR = 12.           59700013
         ST    RP,RCTHOLD+60       RESET RP TO INDICATE ERROR CODE      60000013
         SPACE 2                                                        60300013
RCTC2    L     RD,PPISTDCB         RD WILL BE A POINTER TO DCB ENTRIES, 60600013
         L     RC,0(0,RD)            EACH CLOSED ENTRY BYTE 1 = X'80'.  60900013
         TM    PPISW1+2,X'02'      IS THIS A MERGE ONLY RUN             61200013
         BZ    RCTXX1              IF NOT, SKIP MERGE SET UP            61500013
         LH    RF,PPIMRGMX                                              61800013
         B     RCTE3A              GO TO INCREMENT DCB PTR              62100018
RCTXX1   TM    PPISW1+1,X'40'      IF TAPE IS INDICATED, SET UP COUNTER 62400013
         BO    RCTC2A              FROM NUMBER OF TAPE UNITS            62700013
         LH    RF,PPINDSKA         RF WILL BECOME DISK AREA COUNTER     63000013
         B     RCTD3                 SET FROM NUMBER OF DISK AREAS.     63300013
         SPACE 2                                                        63600013
RCTC2A   SR    RF,RF               RF WILL BECOME A WORK UNIT COUNTER   63900013
         IC    RF,PPIBDSVA           SET FROM TOTAL WORK UNITS FIELD.   64200013
         SPACE 2                                                        64500013
* IF PHASE 1 CLOSE FIRST UNIT AS INPUT(REWIND TO LOAD POINT) , SET DCB- 64800013
* OFLAGS AND CLOSE REST AS OUTPUT. IF PHASE 2,SET DCBOFLAGS CLOSE ALL   65100013
* AS OUTPUT (AT LOAD POINT). IF PHASE 3,CLOSE FIRST AS OUTPUT,SET DCB-  65400013
* OFLAGS AND CLOSE REST AS OUTPUT.IF MERGE ONLY,CLOSE FIRST AS OUTPUT,  65700013
* REST AS INPUT. IN ALL CASE EXIT THROUGH RCTG4 (FOR POSSIBLE OVERLAY). 66000013
         SPACE 1                                                        66300013
RCTD3    TM    PPISW1+2,X'0C'      TEST FOR PHASE 2 OR 3                66600013
         BC    8,RCTD2             NO PHASE 1                           66900013
         TM    PPISW1+2,X'04'      TEST FOR PHASE 3                     67200013
         BNO   RCTD4X                NO,  PHASE 2                       67500013
*                                  ASSUME PHASE 3 OR MERGE ONLY         67800013
RCTE3A   LA    RD,4(0,RD)          INCREMENT TO NEST DCB POINTER        68100013
         LTR   RC,RC               IS ENTRY ALREADY CLOSED,IF SO DO NOT 68400013
         BM    RCTE4                 CLOSE IT AND BRANCH TO REMAINDER.  68700013
         SPACE 2                                                        69000013
         CLOSE ((RC),LEAVE)        LEAVE UNIT DOSITIONED AT LOAD POINT  69300013
         SPACE 2                                                        69600013
RCTE4    TM    PPISW1+2,X'02'       MERGE ONLY                          69900013
         BZ    RCTD4                IF NOT ,MUST BE PHASE 3             70200013
RCTF4    L     RC,0(0,RD)          SET RC TO ADDRESS OF NEXT DCB        70500013
         LTR   RC,RC               IS THIS DCB ALREADY CLOSED,IF SO     70800013
         BM    RCTF4A                CHECK NEXT ENTRY.                  71100013
         SPACE 2                                                        71400013
         CLOSE ((RC),REREAD)         IF NOT CLOSE WITH REWIND.          71700013
         SPACE 2                                                        72000013
RCTF4A   LA    RD,4(0,RD)          INCREMENT TO NEST DCB POINTER        72300013
         BCT   RF,RCTF4            DECREMENT RF,IF NONE LEFT EXIT RCTG4 72600013
         SPACE 2                                                        72900013
RCTG4    B     RCTD1               THIS BRANCH MAY BECOME NOP AT RCTK1  73200013
         B     RCTJ3               ALTERNATE BRANCH POINT IF RCTG4=NOP. 73500013
         SPACE 2                                                        73800013
RCTD2    LA    RD,4(0,RD)          INCREMENT TO FIRST WORK UNIT         74100013
         LTR   RC,RC               IS THIS UNIT ALREADY CLOSED          74400013
         BM    RCTD4                 IF SO BRANCH TO REMAINDER OF UNITS 74700013
         SPACE 2                                                        75000013
         CLOSE ((RC),REREAD)         IF NOT CLOSE WITH REWIND.          75300013
         SPACE 2                                                        75600013
RCTD4    L     RC,0(0,RD)          SET RC TO NEXT DCB ADDRESS ENTRY     75900013
         LTR   RC,RC              IS THIS UNIT ALREADY CLOSED           76200013
         BM    RCTD5A             BRANCH TO SET UP FOR NEXT             76500013
         NI    DCBOFLGS,X'BF'      TURN OFF READ BACKWARDS BIT IF ON    76800013
         SPACE 2                                                        77100013
         TM    PPISW1+1,X'40'      IS IT A TAPE SORT.                   77400013
         BC    1,RCTCLOSE          BRANCH ON YES.                       77700013
         SPACE 2                                                        78000013
         LA    RK,0                                                     78300013
         STH   RK,26(RC)           CLEAR DSORG FOR DIRECT ACCESS.       78600013
RCTCLOSE CLOSE ((RC),REREAD)       CLOSE A UNIT                    4546 78900018
         SPACE 2                                                        79200013
RCTD5A   LA    RD,4(0,RD)          INCREMENT TO NEST DCB POINTER        79500013
         BCT   RF,RCTD4            IF UNITS REMAIN,GO BACK TO CLOSE     79800013
         B     RCTG4                 ELSE GO TO SWITCH RCTG4            80100013
RCTSTOV  MVC   WORK(3),0(RC)       USED TO OVERLAY USER EXITS           80400013
         SPACE 2                                                        80700013
RCTD4X   TM    PPISW1,X'02'        IF OSC, USE PHASE 1 LOGIC            81000013
         BO    RCTD2               GO TO INCREMENT TO FIRST WORK UNIT   81300018
         SPACE 1                                                        81600013
         LA    RD,4(0,RD)          SKIP OVER UNUSED SORTIN/OUT SLOT     81900013
         B     RCTD4               OTHERWISE - PH 2                     82200013
RCTCHK   TM    PPISW1+2,X'01'      IS CHECKPOINT ACTIVATED....          82220017
         BZ    RCTD1               NO,  NO CHECKPOINT TO DELETE         82240017
         SPACE                                                          82260017
         LA    RA,RCTCHKAD         LOAD ADDR OF MODULE NAME             82280017
         DELETE  EPLOC=(0)         DELETE CHECKPOINT MODULE             82300017
         SPACE                                                          82320017
         LTR   RP,RP               IF AN ERROR CODE IS GENERATED BY     82340017
         BC    7,RCTJ1               THE DELETE MACRO, MODULE WAS LOST  82360017
         B     RCTD1               NO ERROR RETURN TO MAIN LINE         82380017
         SPACE 2                                                        82400017
         SPACE 5                                                        82500013
         DS    0D                                                       82800013
WORK     DC    CL8'IER'            C O N S                              83000018
RCTCHKAD DC    CL8'IERCHK'          T A N T S                           83200018
RCTHOLD  DS    16F                 SIXTEEN WORD SAVE AREA               83400013
RCTPOSTV DC    F'0'                C O N S                              83700018
REGREST  DC    3F'0'                T A N T S                           84000018
         EJECT                                                          84300013
         DCBD  DSORG=PS                                                 84600013
         EJECT                                                          84900013
         SMPPI                                                          85200013
         END                                                            85500013
