         TITLE '      IERRDB - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRDB ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 1 RUNNING MODULE. F.L. SORT W/O E15   02100013
*   THE FUNCTION OF THIS MODULE IS TO HANDLE FIXED LENGTH RECORDS USING 02400013
*   THE GET LOCATE MACRO. THERE IS NO DATA CHAINING. SORT RECORD LENGTH 02700013
*   IS LESS THAN OR EQUAL TO 256 BYTES, SO THIS MODULE CONTAINS ONE     03000013
*   IN-LINE MOVE INSTRUCTION TO MOVE THE RECORD INTO RSA. THIS MODULE   03300013
*   HANDLES UP TO 5 NON-CONTIGUOUS RSA'S. THE MODULE THEN PASSES TO     03600013
*   THE REPLACEMENT NETWORK THE RECORD,S LOCATION IN RSA.               03900013
         SPACE 1                                                        04200013
*   INITIALLY FLOW IS BETWEEN DEBLOCK AND THE REPLACEMENT NTWK. AFTER   04500013
*   G RECORDS ARE IN RSA THE NTWK RETURNS TO DEBLOCK FOR THE G+1 RCD TO 04800013
*   FORCE A WINNER AND ALLOW DEBLOCK TO MODIFY ITSELF FOR NORMAL FLOW.  05100013
*   WHEN DEBLOCK RETURNS TO THE NTWK WITH THE G+1 RECORD A WINNER IS    05400013
*   GIVEN TO BLOCK. THE NORMAL FLOW THEN IS  DEBLOCK-NTWK-BLOCK. AT EOF 05700013
*   DEBLOCK IS MODIFIED TO BRANCH DIRECTLY TO THE NETWORK AS SOON AS    06000013
*   IT IS ENTERED BY BLOCK SO THAT THE TREE MAY BE FLUSHED.             06300013
         SPACE 2                                                        06600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               06900013
         SPACE 1                                                        07200013
*   IERADB                                                              07500013
         SPACE 2                                                        07800013
*LIST OF MACROS USED BY MODULE:                                         08100013
         SPACE 1                                                        08400013
*   SMPPI                                                               08700013
*   GET                                                                 09000013
         SPACE 2                                                        09300013
*ENTRY POINTS:                                                          09600013
         SPACE 1                                                        09900013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   10200013
*                                    CALLING SEQUENCE-                  10500013
*                                      L    RL,PPIDEB+4                 10800013
*                                      B    0(RL)      AFTER G RCDS     11100013
*                                      B    8(RL)      FILL TREE        11400013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       11700013
*                                    CALLING SEQUENCE-                  12000013
*                                      L    RL,PPIDEB+4                 12300013
*                                      B    4(RL)      EOF              12600013
*   FROM  BLOCK,ALGORITHM          ENTRY FROM:BLOCK OR ALGORITHM        12900013
*                                    CALLING SEQUENCE-                  13200013
*                                      L    RL,PPIDEB+4                 13500013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 13800013
*   FROM GET                       ENTRY FROM:GET                       14100013
*                                    CALLING SEQUENCE-                  14400013
*                                      BR   14         RETURN REG       14700013
         SPACE 2                                                        15000013
*INPUT: - PPI FIELDS REFERENCED                                         15300013
         SPACE 1                                                        15600013
*   PPINET                                                              15900013
*   PPIBINSZ                                                            16200013
         SPACE 1                                                        16500013
*   ADDRESS OF NTWK, SIZE OF A BIN IN RSA.                              16800013
         SPACE 2                                                        17100013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            17400013
         SPACE 1                                                        17700013
*   PPICOUNT                                                            18000013
         SPACE 1                                                        18300013
*   UPDATE RECORD COUNTER                                               18600013
         SPACE 2                                                        18900013
*EXTERNAL ROUTINES:                                                     19200013
         SPACE 1                                                        19500013
*   NONE                                                                19800013
         SPACE 2                                                        20100013
*EXTERNAL PARAMETERS                                                    20400013
         SPACE 1                                                        20700013
*   SEE REGISTERS                                                       21000013
         SPACE 2                                                        21300013
*EXITS-NORMAL                                                           21600013
         SPACE 1                                                        21900013
*   TO NETWORK                     EXIT TO:NETWORK                      22200013
*                                    CALLING SEQUENCE-                  22500013
*                                      L    RL,PPINET+4                 22800013
*                                      B    4(RL)      FILL TREE        23100013
*                                      B    8(RL)      ON EOF           23400013
*                                      B    12(RL)     NORMAL           23700013
*                                      B    16(RL)     FLUSH TREE       24000013
*   TO GET                         EXIT TO:GET                          24300013
*                                    CALLING SEQUENCE-                  24600013
*                                      GET(RG)                          24900013
         SPACE 2                                                        25200013
*EXITS-ERROR:                                                           25500013
         SPACE 1                                                        25800013
*   NONE                                                                26100013
         SPACE 2                                                        26400013
*TABLES/WORK AREAS:                                                     26700013
         SPACE 1                                                        27000013
*   TABLRSA-TABLE CONSISTING OF UP TO 5 NON-CONTIGUOUS RSA AREA ENTRIES 27300013
*   WITH  8 BYTE ENTRIES FOR EACH RSA AREA.                             27600013
         SPACE 2                                                        27900013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   28200013
         SPACE 2                                                        28500013
*NOTES: THIS MODULE WILL EXECUTE FOR FIXED LENGTH SORTS HAVING RECORD   28800013
*   LENGTHS LESS OR EQUL 256 BYTES AND W/O EXITS E15 OR E16.            29100013
         EJECT                                                          29400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            29700013
         SPACE 1                                                        30000013
RA       EQU   0                   CONTENTS IN- N/A                     30300013
*                                  USE- NOT USED                        30600013
*                                  CONTENTS OUT- N/A                    30900013
RB       EQU   1                   CONTENTS IN- N/A                     31200013
*                                  USE- GET TO DEBLK(ADDR OF RCD IN     31500013
*                                    INPUT BUFFER)                      31800013
*                                  CONTENTS OUT- N/A                    32100013
RC       EQU   2                   CONTENTS IN- N/A                     32400013
*                                  USE- LOAD ADDR OF RCD IN INPUT BFR   32700013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  33000013
*                                    RCD IN INPUT BFR)                  33300013
RD       EQU   3                   CONTENTS IN- BLOCK TO DEBLK(ADDR OF  33600013
*                                    A FREE AREA IN RSA)                33900013
*                                  USE- LOAD ADDR OF AREA IN THE RSA    34200013
*                                    BIN TO MOVE THE NEXT INPUT RCD     34500013
*                                  CONTENTS OUT- DEBLOCK TO NTWK(ADDR   34800013
*                                    OF THE RCD IN RSA)                 35100013
RE       EQU   4                   CONTENTS IN- N/A                     35400013
*                                  USE- REMAINING BYTE COUNT OF THE RSA 35700013
*                                    WE ARE WORKING WITH                36000013
*                                  CONTENTS OUT- N/A                    36300013
RF       EQU   5                   CONTENTS IN- N/A                     36600013
*                                  USE- WORK REGISTER                   36900013
*                                  CONTENTS OUT- N/A                    37200013
RG       EQU   6                   CONTENTS IN- N/A                     37500013
*                                  USE- WORK REGISTER                   37800013
*                                     - ADDR OF INPUT DCB FOR GET       38100013
*                                  CONTENTS OUT- N/A                    38400013
RH       EQU   7                   CONTENTS IN- N/A                     38700013
*                                  USE- ADDR OF THE RSA TABLE ENTRY     39000013
*                                    WE ARE WORKING WITH                39300013
*                                  CONTENTS OUT- N/A                    39600013
RI       EQU   8                   CONTENTS IN- N/A                     39900013
*                                  USE- NOT USED                        40200013
*                                  CONTENTS OUT- N/A                    40500013
RJ       EQU   9                   CONTENTS IN- N/A                     40800013
*                                  USE- NOT USED                        41100013
*                                  CONTENTS OUT- N/A                    41400013
RK       EQU   10                  CONTENTS IN- N/A                     41700013
*                                  USE- NOT USED                        42000013
*                                  CONTENTS OUT- N/A                    42300013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    42600013
*                                  USE-MODULE BASE REGISTER             42900013
*                                  CONTENTS OUT- ENTRY PT OF NTWK       43200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   43500013
*                                  USE- NOT USED                        43800013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   44100013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              44400013
*                                  USE-PPI REFERENCES,REG SAVE AREA     44700013
*                                  CONTENTS OUT-ADDR OF PPI             45000013
RO       EQU   14                  CONTENTS IN- N/A                     45300013
*                                  USE- RETURN REG FROM GET             45600013
*                                  CONTENTS OUT- N/A                    45900013
RP       EQU   15                  CONTENTS IN- N/A                     46200013
*                                  USE- BRANCH REG TO GET               46500013
*                                  CONTENTS OUT- N/A                    46800013
         SPACE 2                                                        47100013
*START OF MODULE CODE PROPER:                                           47400013
         SPACE 2                                                        47700013
IERRDB   CSECT                                                          48000013
         USING *,RL                THIS MODULE BASE REG                 48300013
         USING IERRCA,RN           PPI ADDR                             48600013
IERDD1   B     RDB1050             ENTRY FROM SORT NETWORK. G RECORDS   48900013
*                                    ARE IN THE TREE(ONCE ONLY)         49200013
         B     RDB1060             ENTRY FROM EOF ROUTINE               49500013
         SPACE 2                                                        49800013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  50100013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING                   50400013
         SPACE 1                                                        50700013
RDB1010  L     RH,ADCONPTR         LOAD RSA TABLE POINTER. THIS INSTR   51000013
*                                    WILL BE OVLAYED BY B RDB1020 AFTER 51300013
*                                    RSA IS FILLED WITH G+1 RCDS AND    51600013
*                                    BY A BR TO THE NTWK AFTER EOF.     51900013
         LM    RD,RE,0(RH)         RD-START OF RSA RCD. RE- THIS RSA    52200013
*                                    REMAINING BYTE COUNT.              52500013
RDB1020  L     RG,KADCB            ADDR OF THE INPUT DCB                52800013
         GET   (RG)                                                     53100013
         SPACE 1                                                        53400013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         53700013
         SPACE 1                                                        54000013
RDBRTRN  S     RE,PPIBINSZ         SUBTRACT BINSIZE FROM RSA BYTE COUNT 54300013
*                                    WILL BE B RDLOADRC AFTER G+1 RCDS. 54600013
         BM    RDNEWRSA            BR IF MINUS(RCD CAN'T FIT IN THIS    54900013
*                                    RSA)                               55200013
RDBOVLAY BC    0,RDBLAST           WILL BE A BR AFTER TREE HAS G RCDS.  55500013
         SPACE 2                                                        55800013
*MOVE RECORD FROM INPUT BUFFER TO RSA.                                  56100013
         SPACE 1                                                        56400013
RDLOADRC LR    RC,RB               INPUT RCD ADDR FOR EXTRACT RTN       56700013
RDB1030  MVC   0(1,RD),0(RC)       MOVE RCD FROM INPUT BFR TO RSA.      57000013
*                                    LENGTH SET BY A.P.                 57300013
         SPACE 1                                                        57600013
*UPDATE RECORD  COUNTER                                                 57900013
         SPACE 1                                                        58200013
         L     RG,PPICOUNT                                              58500013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  58800013
         ST    RG,PPICOUNT                                              59100013
         SPACE 2                                                        59400013
*UPDATE RSA TABLE PARAMETERS                                            59700013
         SPACE 1                                                        60000013
RDB1040  LR    RF,RD               WILL BE OVLAYED BY BR TO NETWORK     60300013
*                                    AFTER G+1 RCDS                     60600013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          60900013
         ST    RF,0(0,RH)          STORE IN RSA TABLE                   61200013
         ST    RE,4(0,RH)          STORE THIS RSA REMAINING BYTE COUNT  61500013
         SPACE 1                                                        61800013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       62100013
         SPACE 1                                                        62400013
         L     RL,PPINET+4         ADDR OF NETWORK                      62700013
         B     4(RL)                 BR TO FILL TREE.                   63000013
         SPACE 2                                                        63300013
*UPDATE POINTER TO NEXT RSA TABLE ENTRY(NEXT RSA AREA)                  63600013
         SPACE 1                                                        63900013
RDNEWRSA LA    RH,8(0,RH)          UPDATE PTR                           64200013
         ST    RH,ADCONPTR         SAVE UPDATED PTR TO THE TABLE        64500013
         LM    RD,RE,0(RH)         NEW RSA PARAMETERS                   64800013
         B     RDBRTRN             BR TO PROCESS THIS INPUT RCD         65100013
         SPACE 2                                                        65400013
         SPACE 2                                                        65700013
*SORT TREE HAS BEEN FILLED.  THE NEXT DEBLOCKED RECORD IS MOVED TO THE  66000013
*NEXT SPACE IN RSA.  IN ALL SUBSEQUENT ENTRIES TO THIS MODULE, RD WILL  66300013
*POINT TO THE WINNER RECORD IN RSA.  THE DEBLOCKED RECORD MUST BE MOVED 66600013
*TO THE LOCATION INDICATED BY RD. ALSO, THIS MODULE MUST NOW ENTER THE  66900013
*SORT NETWORK AT ITS NORMAL ENTRY POINT.  THE FOLLOWING CODE MODIFIES   67200013
*THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.                          67500013
         SPACE 1                                                        67800013
RDB1050  MVI   RDBOVLAY+1,X'F0'    MAKE THE INSTR A DIRECT BRANCH       68100013
         B     RDB1010             BR TO PROCESS THE G+1 RCD            68400013
         SPACE 2                                                        68700013
RDBLAST  MVC   RDB1010(4),KMOD1                                         69000013
         MVC   RDBRTRN(4),KMOD2                                         69300013
         MVC   RDB1040(8),KMOD3                                         69600013
         B     RDLOADRC            MOVE THIS INPUT RCD TO RSA(G+1 RCD)  69900013
         SPACE 2                                                        70200013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   70500013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      70800013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT ITS    71100013
*EMPTYING ENTRY.  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT 71400013
*TO EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT ITS EOF    71700013
*ENTRY.                                                                 72000013
         SPACE 1                                                        72300013
RDB1060  MVC   RDB1010(8),KMOD4    BR DIRECTLY TO SORT NETWORK          72600013
         SPACE 2                                                        72900013
*INTERFACE TO SORT NETWORK ON EOF.                                      73200013
         SPACE 1                                                        73500013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 73800013
         B     8(RL)                                                    74100013
         SPACE 2                                                        74400013
*ADCONS USED BY THE MODULE:                                             74700013
         SPACE 1                                                        75000013
ADCONPTR DC    A(TABLRSA)                                               75300013
         SPACE 2                                                        75600013
*CONSTANTS USED BY THE MODULE:                                          75900013
         SPACE 1                                                        76200013
KMOD1    B     RDB1020             OVERLAY RDB1010 AFTER G+1 RCDS       76500013
KMOD2    B     RDLOADRC            OVERLAY RDBRTRN AFTER G+1 RCDS       76800013
KMOD3    L     RL,PPINET+4         OVERLAY RDB1040 AFTER G+1 RCDS       77100013
         B     12(RL)                NORMAL BRANCH TO NETWORK           77400013
KMOD4    L     RL,PPINET+4         OVERLAY RDB1010 AFTER EOF            77700013
         B     16(RL)                FLUSH BRANCH TO NTWK               78000013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        78300013
         SPACE 2                                                        78600013
*LIST OF WORK AREAS/TABLES:                                             78900013
         SPACE 1                                                        79200013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 79500013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    79800013
*                                    4 BYTES-ADDR IN BIN TO MOVE RCD    80100013
*                                    4 BYTES-REMAINING BYTE COUNT OF    80400013
*                                      THIS RSA.                        80700013
*                                    INITIALIZED BY A.P.                81000013
         EJECT                                                          81300013
         SMPPI                                                          81600013
         END                                                            81900013
