         TITLE '      IERRDC - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRDC ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 1 RUNNING MODULE. F.L. SORT W/O E15   02100013
*   THE FUNCTION OF THIS MODULE IS TO HANDLE FIXED LENGTH RECORDS USING 02400013
*   THE GET LOCATE MACRO. THERE IS NO DATA CHAINING. SORT RECORD LENGTH 02700013
*   IS GREATER THAN 256 BYTES SO THIS MODULE BRANCHES TO A MOVE ROUTINE 03000013
*   IN GENERATED CORE TO MOVE THE RECORD INTO RSA. THIS MODULE HANDLES  03300013
*   UP TO 5 NON-CONTIGUOUS RSA'S. THE MODULE PASSES TO THE REPLACEMENT  03600013
*   NETWORK THE RECORD'S LOCATION IN RSA.                               03900013
         SPACE 1                                                        04200013
*   INITIALLY FLOW IS BETWEEN DEBLOCK AND THE REPLACEMENT NETWORK.AFTER 04500013
*   G RECORDS ARE IN RSA THE NTWK RETURNS TO DEBLOCK FOR THE G+1 RCD TO 04800013
*   FORCE THE WINNER OUT OF THE TREE AND ALSO ALLOWING DEBLOCK TO       05100013
*   MODIFY ITSELF FOR NORMAL FLOW. WHEN DEBLOCK RETURNS TO THE NETWORK  05400013
*   WITH THE G+1 RECORD THE WINNER IS GIVEN TO BLOCK BY THE NTWK. THE   05700013
*   NORMAL FLOW THEN IS DEBLOCK-NTWK-BLOCK-DEBLOCK ETC. AT EOF DEBLOCK  06000013
*   IS MODIFIED TO BRANCH DIRECTLY TO THE NETWORK AS SOON AS IT IS      06300013
*   ENTERED BY BLOCK SO THAT THE TREE MAY BE FLUSHED.                   06600013
         SPACE 2                                                        06900013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               07200013
         SPACE 1                                                        07500013
*   IERADC                                                              07800013
         SPACE 2                                                        08100013
*LIST OF MACROS USED BY MODULE:                                         08400013
         SPACE 1                                                        08700013
*   SMPPI                                                               09000013
*   GET                                                                 09300013
         SPACE 2                                                        09600013
*ENTRY POINTS:                                                          09900013
         SPACE 1                                                        10200013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   10500013
*                                    CALLING SEQUENCE-                  10800013
*                                      L    RL,PPIDEB+4                 11100013
*                                      B    0(RL)      AFTER G RCDS     11400013
*                                      B    8(RL)      FILL TREE        11700013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       12000013
*                                    CALLING SEQUENCE-                  12300013
*                                      L    RL,PPIDEB+4                 12600013
*                                      B    4(RL)      EOF              12900013
*   FROM BLOCK,ALGORITHM           ENTRY FROM:BLOCK OR ALGORITHM        13200013
*                                    CALLING SEQUENCE-                  13500013
*                                      L    RL,PPIDEB+4                 13800013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 14100013
*   FROM GET,MOVE RTN              ENTRY FROM:GET OR MOVE RTN           14400013
*                                    CALLING SEQUENCE-                  14700013
*                                      BR   14         RETURN REG       15000013
         SPACE 2                                                        15300013
*INPUT: - PPI FIELDS REFERENCED                                         15600013
         SPACE 1                                                        15900013
*   PPINET                                                              16200013
*   PPIBDSVA                                                            16500013
*   PPIBINSZ                                                            16800013
         SPACE 1                                                        17100013
*   ADDRESS OF NETWORK,MOVE ROUTINE. SIZE OF A BIN USED TO UPDATE RSA   17400013
*   POINTER.                                                            17700013
         SPACE 2                                                        18000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            18300013
         SPACE 1                                                        18600013
*   PPICOUNT                                                            18900013
         SPACE 1                                                        19200013
*   UPDATE RECORD COUNTER                                               19500013
         SPACE 2                                                        19800013
*EXTERNAL ROUTINES:                                                     20100013
         SPACE 1                                                        20400013
*   MOVE ROUTINE IN GENERATED CORE TO MOVE RCD FROM INPUT BUFFER TO RSA 20700013
         SPACE 2                                                        21000013
*EXTERNAL PARAMETERS                                                    21300013
         SPACE 1                                                        21600013
*   SEE REGISTERS                                                       21900013
         SPACE 2                                                        22200013
*EXITS-NORMAL                                                           22500013
         SPACE 1                                                        22800013
*   TO NETWORK                     EXIT TO:NETWORK                      23100013
*                                    CALLING SEQUENCE-                  23400013
*                                      L    RL,PPINET+4                 23700013
*                                      B    4(RL)      FILL TREE        24000013
*                                      B    8(RL)      ON INPUT EOF     24300013
*                                      B    12(RL)     NORMAL RUNNING   24600013
*                                      B    16(RL)     FLUSH TREE       24900013
*   TO GET                         EXIT TO:GET                          25200013
*                                    CALLING SEQUENCE-                  25500013
*                                      GET(RG)                          25800013
*   TO MOVE RTN                    EXIT TO:MOVE RTN                     26100013
*                                    CALLING SEQUENCE-                  26400013
*                                      L    RP,PPIBDSVA+4 MOVE RTN ADDR 26700013
*                                      BALR RO,RP                       27000013
         SPACE 2                                                        27300013
*EXITS-ERROR:                                                           27600013
         SPACE 1                                                        27900013
*   NONE                                                                28200013
         SPACE 2                                                        28500013
*TABLES/WORK AREAS:                                                     28800013
         SPACE 1                                                        29100013
*   TABLRSA-TABLE CONSISTING OF UP TO 5 ENTRIES . AN 8 BYTE ENTRY FOR   29400013
*     EACH NON-CONTIGUOUS RSA.                                          29700013
         SPACE 2                                                        30000013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   30300013
         SPACE 2                                                        30600013
*NOTES: THIS MODULE WILL EXECUTE FOR FIXED LENGTH SORTS HAVING RECORD   30900013
*   LENGTHS GREATER THAN 256 BYTES AND W/O EXITS E15 OR E16             31200013
         EJECT                                                          31500013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            31800013
         SPACE 1                                                        32100013
RA       EQU   0                   CONTENTS IN- N/A                     32400013
*                                  USE- NOT USED                        32700013
*                                  CONTENTS OUT- N/A                    33000013
RB       EQU   1                   CONTENTS IN- N/A                     33300013
*                                  USE- GET TO DEBLK(ADDR OF RCD IN     33600013
*                                    INPUT BUFFER)                      33900013
*                                  CONTENTS OUT- N/A                    34200013
RC       EQU   2                   CONTENTS IN- N/A                     34500013
*                                  USE- ADDR OF RCD IN INPUT BUFFER     34800013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  35100013
*                                    RCD IN INPUT BFR)                  35400013
RD       EQU   3                   CONTENTS IN- BLOCK TO DEBLK(ADDR OF  35700013
*                                    A FREE AREA IN RSA)                36000013
*                                  USE- ADDR OF WHERE TO PUT RCD IN RSA 36300013
*                                    BIN                                36600013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  36900013
*                                    THE RCD IN RSA)                    37200013
RE       EQU   4                   CONTENTS IN- N/A                     37500013
*                                  USE- ADDR OF RCD IN INPUT BFR FOR    37800013
*                                    MOVE RTN                           38100013
*                                  CONTENTS OUT- N/A                    38400013
RF       EQU   5                   CONTENTS IN- N/A                     38700013
*                                  USE- ADDR OF AREA IN RSA TO MOVE THE 39000013
*                                    RCD FOR MOVE RTN                   39300013
*                                  CONTENTS OUT- N/A                    39600013
RG       EQU   6                   CONTENTS IN- N/A                     39900013
*                                  USE- ADDR OF INPUT DCB FOR GET       40200013
*                                     - WORK REGISTER                   40500013
*                                  CONTENTS OUT- N/A                    40800013
RH       EQU   7                   CONTENTS IN- N/A                     41100013
*                                  USE- ADDR OF THE RSA TABLE ENTRY WE  41400013
*                                    ARE WORKING WITH                   41700013
*                                  CONTENTS OUT- N/A                    42000013
RI       EQU   8                   CONTENTS IN- N/A                     42300013
*                                  USE- REMAING BYTE CNT OF RSA WE      42600013
*                                    ARE WORKING WITH                   42900013
*                                  CONTENTS OUT- N/A                    43200013
RJ       EQU   9                   CONTENTS IN- N/A                     43500013
*                                  USE- NOT USED                        43800013
*                                  CONTENTS OUT- N/A                    44100013
RK       EQU   10                  CONTENTS IN- N/A                     44400013
*                                  USE- NOT USED                        44700013
*                                  CONTENTS OUT- N/A                    45000013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    45300013
*                                  USE-MODULE BASE REGISTER             45600013
*                                  CONTENTS OUT- ENTRY PT OF NTWK       45900013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   46200013
*                                  USE- NOT USED                        46500013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   46800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              47100013
*                                  USE-PPI REFERENCES,REG SAVE AREA     47400013
*                                  CONTENTS OUT-ADDR OF PPI             47700013
RO       EQU   14                  CONTENTS IN- N/A                     48000013
*                                  USE- RETURN REG FROM GET             48300013
*                                     - RETURN REG FROM MOVE RTN        48600013
*                                  CONTENTS OUT- N/A                    48900013
RP       EQU   15                  CONTENTS IN- N/A                     49200013
*                                  USE- BRANCH REG TO GET               49500013
*                                     - BRANCH REG TO MOVE RTN          49800013
*                                  CONTENTS OUT- N/A                    50100013
         SPACE 2                                                        50400013
*START OF MODULE CODE PROPER:                                           50700013
         SPACE 2                                                        51000013
IERRDC   CSECT                                                          51300013
* 558000                                                         A24562 51400019
         USING *,RL                THIS MODULE BASE REGISTER            51600013
         USING IERRCA,RN                                                51900013
IERDD1   B     RDC1050             ENTRY FROM SORT NETWORK. G RECORDS   52200013
*                                    ARE IN THE TREE(ONCE ONLY)         52500013
         B     RDC1060             ENTRY FROM EOF ROUTINE               52800013
         SPACE 2                                                        53100013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  53400013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING.                  53700013
         SPACE 1                                                        54000013
RDC1010  L     RH,ADCONPTR         LOAD RSA TABLE POINTER. THIS INSTR   54300013
*                                    WILL BE OVLAYED BY B RDB1020 AFTER 54600013
*                                    RSA IS FILLED WITH G+1 RCDS AND    54900013
*                                    BY A BR TO THE NTWK AFTER EOF.     55200013
         L     RD,0(RH)            ADDR OF AREA IN RSA FOR INPUT RCD    55500013
         L     RI,4(RH)            REMAINING BYTE COUNT OF RSA   A24562 55800019
RDC1020  L     RG,KADCB            ADDR OF THE INPUT DCB                56100013
         GET   (RG)                                                     56400013
         SPACE 1                                                        56700013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         57000013
         SPACE 1                                                        57300013
RDCRTRN  S     RI,PPIBINSZ         SUBTRACT BINSIZE FROM RSA BYTE COUNT 57600013
*                                    THIS WILL BE OVLAYED BY B RDLOADRC 57900013
*                                    AFTER G+1 RCDS                     58200013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS RSA 58500013
RDCOVLAY BC    0,RDCLAST           WILL BE A BR AFTER TREE HAS G RCDS.  58800013
         SPACE 2                                                        59100013
*LINK TO MOVE LIST WHICH MOVES THE RECORD FROM THE INPUT BUFFER TO RSA. 59400013
*INPUT BUFFER RCD ADDR IN RE. RSA RCD ADDR IN RF                        59700013
         SPACE 1                                                        60000013
RDLOADRF LR    RF,RD               ADDR IN RSA TO MOVE INPUT RCD        60300013
         LR    RE,RB               INPUT RCD ADDR                       60600013
         L     RP,PPIBDSVA+4       ADDR OF MOVE LIST                    60900013
         BALR  RO,RP                                                    61200013
         SPACE 2                                                        61500013
*UPDATE RECORD COUNTER. LOAD RC IN CASE WE HAVE EXTRACT ROUTINE         61800013
         SPACE 1                                                        62100013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          62400013
         L     RG,PPICOUNT                                              62700013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  63000013
         ST    RG,PPICOUNT                                              63300013
         SPACE 2                                                        63600013
*UPDATE RSA TABLE PARAMETERS                                            63900013
         SPACE 1                                                        64200013
RDC1040  LR    RF,RD               ADDR OF RCD IN RSA. WILL BE OVLAYED  64500013
*                                    BY BR TO NETWORK AFTER G+1 RCDS.   64800013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          65100013
         ST    RF,0(0,RH)          STORE IN RSA TABLE                   65400013
         ST    RI,4(0,RH)          STORE THIS RSA REMAINING BYTE COUNT  65700013
         SPACE 1                                                        66000013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       66300013
         SPACE 1                                                        66600013
         L     RL,PPINET+4         ADDR OF NETWORK                      66900013
         B     4(RL)               BR TO FILL TREE                      67200013
         SPACE 2                                                        67500013
*UPDATE POINTER TO NEXT ENTRY IN RSA TABLE(EQUALS NEXT RSA AREA)        67800013
         SPACE 1                                                        68100013
RDNEWRSA LA    RH,8(0,RH)          UPDATE PTR                           68400013
         ST    RH,ADCONPTR         SAVE UPDATED PTR                     68700013
         L     RD,0(RH)            NEW RSA RCD ADDR                     69000013
         L     RI,4(RH)            COUNT OF THIS NEW RSA                69300013
         B     RDCRTRN             BR TO PROCESS THE INPUT RCD          69600013
         SPACE 2                                                        69900013
*SORT TREE HAS BEEN FILLED.  IN FUTURE ENTRIES TO THIS MODULE, RD WILL  70200013
*POINT TO THE WINNER RECORD IN RSA.  THE NEW RECORD WHICH HAS BEEN      70500013
*DEBLOCKED MUST BE MOVED TO THE LOCATION IN RSA INDICATED BY RD.  ALSO, 70800013
*THIS MODULE MUST NOW ENTER THE SORT NETWORK AT 12(RL).       THE       71100013
*FOLLOWING CODE MODIFIES THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.  71400013
         SPACE 1                                                        71700013
RDC1050  MVI   RDCOVLAY+1,X'F0'    MAKE THE INSTR A DIRECT BRANCH       72000013
         B     RDC1010             BR TO PROCESS THE G+1 RCD            72300013
         SPACE 2                                                        72600013
RDCLAST  MVC   RDC1010(4),KMOD1                                         72900013
         MVC   RDCRTRN(4),KMOD2                                         73200013
         MVC   RDC1040(8),KMOD3                                         73500013
         B     RDLOADRF            BR TO MOVE G+1 RCD TO RSA            73800013
         SPACE 2                                                        74100013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   74400013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      74700013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT        75000013
*16(RL).  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT TO      75300013
*EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT 8(RL), THE    75600013
*EOF ENTRY.                                                             75900013
         SPACE 1                                                        76200013
RDC1060  MVC   RDC1010(8),KMOD4    BR DIRECTLY TO SORT NETWORK          76500013
         SPACE 2                                                        76800013
*INTERFACE TO SORT NETWORK ON EOF.                                      77100013
         SPACE 1                                                        77400013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 77700013
         B     8(RL)                                                    78000013
         SPACE 2                                                        78300013
*ADCONS USED BY THE MODULE:                                             78600013
         SPACE 1                                                        78900013
ADCONPTR DC    A(TABLRSA)                                               79200013
         SPACE 2                                                        79500013
*CONSTANTS USED BY THE MODULE:                                          79800013
         SPACE 1                                                        80100013
KMOD1    B     RDC1020             OVERLAY RDC1010 AFTER G+1 RCDS       80400013
KMOD2    B     RDLOADRF            OVERLAY RDCRTRN AFTER G+1 RCDS       80700013
KMOD3    L     RL,PPINET+4         OVERLAY RDC1040 AFTER G+1 RCDS       81000013
         B     12(RL)                NORMAL BR TO THE NETWORK           81300013
KMOD4    L     RL,PPINET+4         OVERLAY RDC1010 AFTER INPUT EOF.     81600013
         B     16(RL)                FLUSH BRANCH TO NETWORK            81900013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        82200013
         SPACE 2                                                        82500013
*LIST OF WORK AREAS/TABLES:                                             82800013
         SPACE 1                                                        83100013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 83400013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    83700013
*                                    4 BYTES-ADDR IN BIN TO MOVE RCD    84000013
*                                    4 BYTES-REMAINING BYTE COUNT OF    84300013
*                                      THIS RSA.                        84600013
*                                    THIS TABLE INITIALIZED BY A.P.     84900013
         EJECT                                                          85200013
         SMPPI                                                          85500013
         END                                                            85800013
