         TITLE '      IERRDD - OS/360 SORT/MERGE - 360S-SM023 05/08/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRDD ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 1 RUNNING MOD. F.L. W/E15 AND/OR E16  01400013
*   THE FUNCTION OF THIS MODULE IS TO DEBLOCK FIXED LGTH RCDS USING THE 01600013
*   GET MACRO AND CONTAINS LINKAGE TO THE USER MODIFICATION PROGRAMS    01800013
*   VIA THE CALL MACRO EXPANSION INSTRUCTIONS.                          02000013
*   THE INPUT RECORDS ARE LOCATED IN AN INPUT BUFFER. BEFORE MOVING THE 02200013
*   RECORD TO THE WORK AREA CALLED RSA, RECORD STORAGE AREA, THE MODULE 02400013
*   BRANCHES TO THE USER RTN WHO MAY 1.DELETE, 2.INSERT, OR 3.ALTER,    02600013
*   LENGTHEN, SHORTEN, OR DO NOTHING TO THE RECORD. THE ADDRESS OF      02800013
*   THE RECORD IN THE INPUT AREA IS PASSED TO THE USER.  THE USER       03000013
*   RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS.               03200013
         SPACE 1                                                        03400013
*   THIS MODULE KEEPS TRACK OF THE MAXIMUM AMOUNT OF RECORDS THAT THE   03600013
*   SORT CAN HANDLE AT ANY ONE TIME,NMAX. IT CHECKS TO SEE IF NMAX IS   03800013
*   REACHED, AND WHEN IT IS REACHED IT BRANCHES TO THE USER WHO MAY     04000013
*   1. SORT CURRENT NO, 2.IGNORE NMAX, 3.ABORT THE JOB.  THE USER       04200013
*   RETURNS VIA BRANCHREG AND PROPER DISPLACEMENTS.                     04400013
         SPACE 1                                                        04600013
*   THE MODULE MOVES THE RECORD TO RSA AND PASSES THE RECORD'S LOCATION 04800013
*   IN RSA TO THE REPLACEMENT SORT. THIS MODULE HANDLES UP TO 5 NON-    05000013
*   CONTIGUOUS RSA AREAS.                                               05200013
         SPACE 1                                                        05400013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      05600013
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET.                       05800013
         SPACE 2                                                        06000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               06200013
         SPACE 1                                                        06400013
*   IERADD                                                              06600013
         SPACE 2                                                        06800013
*LIST OF MACROS USED BY MODULE:                                         07000013
         SPACE 1                                                        07200013
*   SMPPI                                                               07400013
*   GET                                                                 07600013
         SPACE 2                                                        07800013
*ENTRY POINTS:                                                          08000013
         SPACE 1                                                        08200013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   08400013
*                                    CALLING SEQUENCE-                  08600013
*                                      L    RL,PPIDEB+4                 08800013
*                                      B    0(RL)      AFTER G RCDS     09000013
*                                      B    8(RL)      FILL TREE        09200013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       09400013
*                                    CALLING SEQUENCE-                  09600013
*                                      L    RL,PPIDEB+4                 09800013
*                                      B    4(RL)      EOF              10000013
*   FROM BLOCK,ALGORITHM           ENTRY FROM:BLOCK OR ALGORITHM        10200013
*                                    CALLING SEQUENCE-                  10400013
*                                      L    RL,PPIDEB+4                 10600013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 10800013
*   FROM GET,MOVE RTN,EXITS,SSC    ENTRY FROM:GET,MOVE RTN,E15,E16,SSC  11000013
*                                    CALLING SEQUENCE-                  11200013
*                                      BR   14         RETURN REG       11400013
         SPACE 2                                                        11600013
*INPUT: - PPI FIELDS REFERENCED                                         11800013
         SPACE 1                                                        12000013
*   PPINET     PPIADSSC   PPIX16                                        12200013
*   PPIBDSVA   PPISW1     PPIRMA                                        12400013
*   PPIBINSZ   PPIX15                                                   12600013
         SPACE 1                                                        12800013
*   ADDR OF NETWORK,MOVE RTN,EXITS,SORT SYSTEM CONTROL,MESSAGE MODULE,  13000013
*   AND BINSIZE TO UPDATE RSA POINTER.                                  13200013
         SPACE 2                                                        13400013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            13600013
         SPACE 1                                                        13800013
*   PPICOUNT                                                            14000013
*   PPIDELCT                                                            14200013
*   PPIINSCT                                                            14400013
         SPACE 1                                                        14600013
*   UPDATE RECORD,DELETE,AND INSERT COUNTERS.                           14800013
         SPACE 2                                                        15000013
*EXTERNAL ROUTINES:                                                     15200013
         SPACE 1                                                        15400013
*   MOVE ROUTINE TO MOVE RECORD FROM THE BUFFER TO RSA                  15600013
         SPACE 2                                                        15800013
*EXTERNAL PARAMETERS:                                                   16000013
         SPACE 1                                                        16200013
*   SEE REGISTERS                                                       16400013
         SPACE 2                                                        16600013
*EXITS-NORMAL:                                                          16800013
         SPACE 1                                                        17000013
*   TO NETWORK                     EXIT TO:NETWORK                      17200013
*                                    CALLING SEQUENCE-                  17400013
*                                      L    RL,PPINET+4                 17600013
*                                      B    4(RL)      FILL TREE        17800013
*                                      B    8(RL)      ON INPUT EOF     18000013
*                                      B    12(RL)     NORMAL RUNNING   18200013
*                                      B    16(RL)     FLUSH TREE       18400013
*   TO GET                         EXIT TO:GET                          18600013
*                                    CALLING SEQUENCE-                  18800013
*                                      GET(RG)         RG=ADDR OF DCB   19000013
*   TO MOVE RTN                    EXIT TO:MOVE RTN                     19200013
*                                    CALLING SEQUENCE-                  19400013
*                                      L    RP,PPIBDSVA+4 MOVE RTN ADDR 19600013
*                                      BALR RO,RP                       19800013
*   TO EXIT E15(OR ATTACHED)       EXIT TO:E15(OR ATTACHED EXIT)        20000013
*                                    CALLING SEQUENCE-                  20200013
*                                      L    RP,PPIX15+4                 20400013
*                                      BALR RO,RP                       20600013
*   TO SORT SYSTEM CONTROL         EXIT TO:SSC                          20800013
*                                    CALLING SEQUENCE-                  21000013
*                                      L    RP,PPIADSSC                 21200013
*                                      BALR RO,RP                       21400013
         SPACE 2                                                        21600013
*EXITS-ERROR:                                                           21800013
         SPACE 1                                                        22000013
*   TO NMAX EXIT                   EXIT TO:E16                          22200013
*                                    CALLING SEQUENCE-                  22400013
*                                      L    RP,PPIX16+4                 22600013
*                                      BALR RO,RP                       22800013
         SPACE 2                                                        23000013
*TABLES/WORK AREAS:                                                     23200013
         SPACE 1                                                        23400013
*   WSW1-A SWITCH IN THE INSERT RTN                                     23600013
*   WINSRTSW-INSERT SWITCH                                              23800013
*   WUSREOF-USER END OF FILE SWITCH(DO NOT RETURN TO E15)               24000013
*   WSYSEOF-SYTEM END OF FILE SWITCH-(INPUT END OF FILE)                24200013
*   WINNER-SAVE AREA FOR ADDR IN RSA THAT THE WINNER JUST VACATED       24400013
*   WNMAX-NMAX COUNTER                                                  24600013
*   WDCB-ADDRESS OF INPUT FILE'S DCB.                                   24800013
*   WRJ-2 FULL WORDS-REGISTER SAVE AREA.                                25000013
*   WINPTRCD-ADDR OF RCD IN INPUT AREA                                  25200013
*   TABLRSA-UP-TO 5 ENTRIES(8 BYTES/ENTRY)FOR 5 NON-CONTIGUOUS RSA'S.   25400013
         SPACE 2                                                        25600013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   25800013
         SPACE 2                                                        26000013
*NOTES:THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT HAVING        26200013
*   USER EXITS E15 AND/OR E16,OR ATTACHED.                              26400013
         EJECT                                                          26600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            26800013
         SPACE 1                                                        27000013
RA       EQU   0                   CONTENTS IN-N/A                      27200013
*                                  USE-DEBLK TO SSC(NAME OF MESSAGE)    27400013
*                                  CONTENTS OUT-N/A                     27600013
RB       EQU   1                   CONTENTS IN-N/A                      27800013
*                                  USE-DEBLK TO E15(ADDR OF PARAM LIST) 28000013
*                                     -E15 TO DEBLK(ADDR OF INPUT RCD)  28200013
*                                     -GET TO DEBLK(ADDR OF INPUT RCD)  28400013
*                                     -DEBLK TO SSC(BYTE LENGTH OF MSG) 28600013
*                                  CONTENTS OUT-N/A                     28800013
RC       EQU   2                   CONTENTS IN-N/A                      29000013
*                                  USE-DEBLK TO NTWK(ADDR OF INPUT RCD  29200013
*                                    IN INPUT BFR FOR EXTRACT RTN)      29400013
*                                  CONTENTS OUT-ADDR OF RCD IN INPT BFR 29600013
RD       EQU   3                   CONTENTS IN-BLK TO DEBLK/ADDR IN RSA 29800013
*                                    TO MOVE NEXT INPUT RCD-RUN TIME)   30000013
*                                  USE-ADDR IN RSA TO MOVE NEXT RCD     30200013
*                                    (FILL TIME)                        30400013
*                                  CONTENTS OUT-DEBLK TO NTWK(ADDR OF   30600013
*                                    RCD IN RSA)                        30800013
RE       EQU   4                   CONTENTS IN-N/A                      31000013
*                                  USE-DEBLK TO MOVE RTN(ADDR OF RCD IN 31200013
*                                    INPUT BFR)                         31400013
*                                     -WORK REGISTER                    31600013
*                                  CONTENTS OUT-N/A                     31800013
RF       EQU   5                   CONTENTS IN-N/A                      32000013
*                                  USE-DEBLK TO MOVE RTN(ADDR IN RSA TO 32200013
*                                    MOVE INPUT RCD)                    32400013
*                                  CONTENTS OUT-N/A                     32600013
RG       EQU   6                   CONTENTS IN-N/A                      32800013
*                                  USE-INPUT FILE RECORD COUNTER        33000013
*                                  CONTENTS OUT-N/A                     33200013
RH       EQU   7                   CONTENTS IN-N/A                      33400013
*                                  USE-DELETE COUNTER                   33600013
*                                  CONTENTS OUT- N/A                    33800013
RI       EQU   8                   CONTENTS IN- N/A                     34000013
*                                  USE-INSERT COUNTER                   34200013
*                                  CONTENTS OUT- N/A                    34400013
RJ       EQU   9                   CONTENTS IN- N/A                     34600013
*                                  USE-NMAX COUNTER                     34800013
*                                  CONTENTS OUT- N/A                    35000013
RK       EQU   10                  CONTENTS IN- N/A                     35200013
*                                  USE-ADDR OF INPUT DCB                35400013
*                                     -RSA TABLE POINTER                35600013
*                                  CONTENTS OUT-N/A                     35800013
RL       EQU   11                  CONTENTS IN-THIS MODULE ENTRY PT     36000013
*                                  USE-MODULE BASE REGISTER             36200013
*                                  CONTENTS OUT-NETWORK ENTRY PT        36400013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   36600013
*                                  USE-NOT USED                         36800013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   37000013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              37200013
*                                  USE-PPI REFERENCES,REG SAVE AREA     37400013
*                                  CONTENTS OUT-ADDR OF PPI             37600013
RO       EQU   14                  CONTENTS IN-N/A                      37800013
*                                  USE-RETURN REG FROM GET,USER EXITS,  38000013
*                                    SSC,MOVE RTN                       38200013
*                                  CONTENTS OUT-N/A                     38400013
RP       EQU   15                  CONTENTS IN-N/A                      38600013
*                                  USE-USER EXITS TO DEBLK(RETURN CODE) 38800013
*                                     -BRANCH REG TO GET,USER EXITS,    39000013
*                                    SSC,MOVE RTN                       39200013
*                                  CONTENTS OUT-N/A                     39400013
         SPACE 2                                                        39600013
*START OF MODULE CODE PROPER:                                           39800013
         SPACE 2                                                        40000013
IERRDD   CSECT                                                          40200013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    40400013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  40600013
         USING IERRMA,RO           MESSAGE MODULE ADDR                  40800013
         SPACE 1                                                        41000013
* ENTER BRANCH TABLE FROM REPLACEMENT SORT,0(RL).FROM READ MOD, 4(RL).  41200013
*   OR FROM REPLACEMENT SORT(INITIALLY TO FILL TREE), ALGORITHM(AT THE  41400013
*   END OF A SEQUENCE), BLOCK MODULE(AFTER FILLING TREE), 8(RL).        41600013
IERDD1   B     RDOVLAYF            FROM REPL SORT,FINISHD FILLING TREE  41800013
         B     RDSETSW             FROM READ MOD(GET,ON EOF)            42000013
* FROM REPLACEMT SORT BLOCK MOD,OR ALGORITHM                            42200013
         SPACE 1                                                        42400013
RDNORMAL ST    RD,WINNER           ADDR OF A FREE AREA IN RSA-LAST WNR  42600013
RDLDCTRS STM   RJ,RK,WRJ           SAVE TRANSPARENT REGS                42800013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     43000013
         L     RK,WDCB             RESTORE DCB ADDRESS                  43200013
         L     RJ,PPINMAX          RESTORE NMAX                         43400013
         LTR   RJ,RJ               CHECK FOR 0 OR NMAX                  43600013
         BC    2,RDTSTISW          IF NMAX PLUS CONTINUE                43800013
         LA    RJ,1                NMAX MUST BE 1                       44000013
RDTSTISW TM    WINSRTSW,X'01'      TST INSERT SW. WILL BE OVLAYED BY    44200013
*                                    A.P. IF ATTACHED,OR BY R.P. ON     44400013
*                                    SYSTEM EOF,WITH B RDUSREXT         44600013
         BC    1,RDUSREXT          ON, BR TO USER EXIT                  44800013
RDGET    GET   (RK)                UPDATE ADDR IN INPUT AREA(REG RB)    45000013
*                                    REG RK HAS DCB ADDR                45200013
         LA    RG,1(0,RG)          INCR RCD CTR BY ONE                  45400013
         ST    RB,WINPTRCD         SAVE ADDR OF RCD THATS IN INPUT BLK  45600013
         SPACE 1                                                        45800013
* USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.            46000013
*   PASS ADDR OF PARAMETER LIST(ADDR OF INPUT RCD) IN REGISTER RB       46200013
         SPACE 1                                                        46400013
RDUSREXT LA    RB,WINPTRCD         ADDR OF PARAMETER LIST. IF E15 NOT   46600013
*                                    ACTIVATED, OR IF ACTIVATED AND HIT 46800013
*                                    USER EOF,THIS INSTR WILL BE OVLAYD 47000013
*                                    BY B RDALSHNO                      47200013
         L     RP,PPIX15+4         ADDR OF USER EXIT E15. IF ATTACHED   47400013
*                                    A.P. WILL LOAD PPIX15 WITH ADDR IN 47600013
*                                    PPIATP1E                           47800013
         BALR  RO,RP               BR TO USER                           48000013
         SPACE 1                                                        48200013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS. USER   48400013
*   PASSES ADDR OF RECORD TO BE INSERTED OR ADDR OF WORK AREA IF HE     48600013
*   ALTERS,LENGTHENS,OR SHORTENS A RCD IN REG RB.                       48800013
         SPACE 1                                                        49000013
         B     *+4(15)                                                  49200013
RDOVLAY4 B     RDALSHNO            ALTER,LENGTHN,SHORTN,DO NOTHING      49400013
*                                    WILL BE OVERLAYED BY K4 IF,WHEN    49600013
*                                    REACH NMAX IT IS IGNORED, OR BY    49800013
*                                    A.P. WITH K4 IF EXIT NOT ACTIVE    50000013
         B     RDDELETE            DELETE A RCD                         50200013
         B     RDUSREOF            USER END OF FILE                     50400013
         SPACE 1                                                        50600013
* INSERT A RECORD                                                       50800013
         SPACE 1                                                        51000013
RDTSTNMX BCT   RJ,RDISWON          DECR NMAX CTR BY ONE AND TEST TO     51200013
*                                    SEE IF REACHED NMAX                51400013
*                                    WILL BE OVERLAYED BY K3 IF, WHEN   51600013
*                                    REACH NMAX IT IS IGNORED, OR BY    51800013
*                                    A.P. WITH K3 IF EXIT NOT ACTIVE    52000013
         B     RDWSW1ON            YES,BR TO NMAX USER EXIT E16,SW ON   52200013
         SPACE 2                                                        52400013
* SYSTEM END OF FILE ROUTINE                                            52600013
         SPACE 1                                                        52800013
RDSETSW  OI    WSYSEOF,X'01'       SET SYSTEM EOF SWITCH                53000013
         SR    RB,RB               CLEAR INPUT RCD PARAM REG            53200013
         MVC   RDTSTISW,K5         TO BYPASS GOING TO GET AFTER SYS EOF 53400013
         TM    WUSREOF,X'01'       TEST IF USER EOF SWITCH ON           53600013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              53800013
         B     RDUSREXT-4          NO, BR TO USER                       54000013
         SPACE 2                                                        54200013
* USER END OF FILE ROUTINE                                              54400013
         SPACE 1                                                        54600013
RDUSREOF OI    WUSREOF,X'01'       SET USER EOF SWITCH                  54800013
         MVC   RDUSREXT,RDOVLAY4   OVLAY USER EXIT-BYPASS EXIT E15      55000013
         TM    WSYSEOF,X'01'       TEST IF SYSTEM EOF SWITCH ON         55200013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              55400013
         L     RB,WINPTRCD         RESTORE ADDR OF RCD IN INPUT BLK     55600013
         B     RDALSHNO            BR TO SORT THIS RCD                  55800013
         SPACE 2                                                        56000013
RDISWON  OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                56200013
         LA    RI,1(0,RI)          INCR INSERT CTR BY ONE               56400013
RDSTM    STM   RG,RI,PPICOUNT      SAVE COUNTERS                        56600013
         ST    RJ,PPINMAX          SAVE NMAX CTR                        56800013
         SPACE 1                                                        57000013
* INITALIZE AND BR TO MOVE RTN TO MOVE NEXT INPUT RCD TO RSA            57200013
         SPACE 1                                                        57400013
RDOVLAY5 B     RDDLDRSA            BR TO GET ADDR IN RSA TO MOVE RCD    57600013
*                                    WILL BE OVLAYED BY L RF,WINNER     57800013
*                                    AFTER G+1 RCDS                     58000013
RDDLDRE  LR    RE,RB               ADDR OF RCD IN INPUT BUFFER OR FROM  58200013
*                                    USER'S WORK AREA                   58400013
         L     RP,PPIBDSVA+4       ADDR OF MOVE RTN IN GENERATED CORE   58600013
         BALR  RO,RP               BR TO MOVE RTN.MOVE RCD TO RSA       58800013
RDOVLAY6 B     RDFILLTR            BR TO SORT NETWORK FILLING TREE RTN  59000013
*                                    WILL BE OVLAYED BY NOP AFTER       59200013
*                                    TREE IS INITIALLY FILLED           59400013
         SPACE 2                                                        59600013
* NORMAL EXIT TO SORT NETWORK AFTER PREVIOUS INSTR IS OVERLAYED BY NOP  59800013
         SPACE 1                                                        60000013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          60200013
         L     RD,WINNER                                                60400013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 60600013
         B     12(RL)              BR TO SORT NETWORK NORMAL RTN        60800013
         SPACE 2                                                        61000013
* EXIT TO SORT NETWORK WHILE FILLING TREE                               61200013
         SPACE 1                                                        61400013
RDFILLTR LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          61600013
         A     RD,PPIBINSZ         UPDATE TO NEXT BIN IN THIS RSA       61800013
         ST    RD,0(0,RK)          SAVE IN RSA TABLE                    62000013
         S     RD,PPIBINSZ         RESTORE FOR NETWORK. ADDR OF THIS    62200013
*                                    RCD IN RSA                         62400013
         L     RL,PPINET+4         ADDR OF NETWORK                      62600013
         B     4(RL)               BR TO SORT NETWORK FILL TREE RTN     62800013
         SPACE 2                                                        63000013
         SPACE 2                                                        63200013
* FINISHED FILLING TREE RTN -ONE TIME RTN                               63400013
         SPACE 1                                                        63600013
RDOVLAYF NI    RDOVLAY6+1,X'00'    NOP THE BR INSTR TO THE FILLING EXIT 63800013
         MVI   RDDOVLAY+1,X'F0'    OVLAY INSTR IN RSA TABLE ROUTINE     64000013
         B     RDLDCTRS            BR TO GET G+1 RECORD.                64200013
         SPACE 2                                                        64400013
*RSA TABLE ROUTINE USED DURING FILLING OF TREE. ENTER HERE ONLY THROUGH 64600013
*   G+1 RECORDS.                                                        64800013
         SPACE 1                                                        65000013
RDDLDRSA L     RK,ADCONPTR         RSA TABLE PTR                        65200013
RDDRTRN  LM    RD,RE,0(RK)         RD=ADDR IN THIS RSA,RE=REMAINING     65400013
*                                    BYTE COUNT OF THIS RSA.            65600013
         S     RE,PPIBINSZ         SUBTR SIZE OF THIS RCD               65800013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS RSA 66000013
RDDOVLAY BC    0,RDDLAST           WILL BE A BR AFTER RSA HAS G RCDS    66200013
         SPACE 2                                                        66400013
         ST    RE,4(0,RK)          SAVE REMAING BYTE COUNT OF THIS RSA  66600013
         LR    RF,RD               ADDR IN RSA TO MOVE THE RCD          66800013
         B     RDDLDRE             BR TO MOVE RCD TO RSA                67000013
         SPACE 2                                                        67200013
RDNEWRSA LA    RK,8(0,RK)          UPDATE RSA TABLE PTR TO NEXT RSA     67400013
*                                    ENTRY(NEXT NON-CONTIGUOUS RSA)     67600013
         ST    RK,ADCONPTR         SAVE UPDATED PTR                     67800013
         B     RDDRTRN             BR TO USE THIS RSA                   68000013
         SPACE 2                                                        68200013
*WE ARE GOING TO PROCESS THE G+1 RECORD.                                68400013
         SPACE 1                                                        68600013
RDDLAST  ST    RD,WINNER           ADDR IN RSA TO MOVE RCD              68800013
         MVC   RDOVLAY5(4),K1      OVLAY BRANCH INSTR TO RSA TABLE RTN  69000013
         B     RDOVLAY5            BR TO MOVE G+1 RCD TO RSA.           69200013
         SPACE 2                                                        69400013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              69600013
         SPACE 1                                                        69800013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 70000013
         TM    WSYSEOF,X'01'       WAS SYSTEM EOF REACHED               70200013
         BC    1,RDCNTSRT          YES,BR AROUND NEXT INSTRS-FLUSH TREE 70400013
         BCTR  RG,0                DECR PPICOUNT BY ONE                 70600013
         SPACE 1                                                        70800013
* FROM GET ON END OF FILE                                               71000013
RDCNTSRT MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               71200013
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        71400013
         L     RL,PPINET+4         ADDR OF NTWK                         71600013
         B     8(RL)               BR TO NTWK TO EMPTY TREE             71800013
         SPACE 2                                                        72000013
RDEMPTYT L     RL,PPINET+4         ADDR OF NTWK                         72200013
         B     16(RL)              BR TO SORT TO CONTINUE EMPTYING TREE 72400013
         SPACE 2                                                        72600013
* WRITE MESSAGE NMAX EXCEEDED                                           72800013
         SPACE 1                                                        73000013
RDWSW1ON OI    WSW1,X'01'          TURN SWITCH 1 ON                     73200013
RDMSGS   L     RO,PPIRMA+4         ADDR OF MESSAGE MODULE               73400013
         LR    RE,RB               SAVE ADDR OF NMAX+1 RCD              73600013
         LM    RA,RB,MSGP1A04      NAME AND LENGTH OF MESSAGE           73800013
         L     RP,PPIADSSC         LOAD PRINT RTN ADDR                  74000013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      74200013
         SPACE 1                                                        74400013
* USER EXIT E16 -SORT CAPACITY, NMAX, HAS BEEN REACHED                  74600013
*   CALL MACRO INSTRUCTION EXPANSION                                    74800013
         SPACE 1                                                        75000013
         LR    RB,RE               RESTORE ADDR OF NMAX+1 RCD           75200013
         L     RP,PPIX16+4         ADDR OF NMAX EXIT                    75400013
         BALR  RO,RP               BR TO USER                           75600013
         SPACE 2                                                        75800013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS.        76000013
         SPACE 1                                                        76200013
         B     *+4(15)                                                  76400013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         76600013
         B     RDIGNORE            IGNORE NMAX AND CONTINUE TO SORT     76800013
         SPACE 1                                                        77000013
* ABORT THE JOB. SET UP ABNORMAL END INDICATION FOR SORT SYSTEM CONTROL 77200013
         SPACE 1                                                        77400013
         L     RP,PPIADSSC                                              77600013
         BAL   RO,16(0,RP)         BR TO SORT SYSTEM CONTROL            77800013
         SPACE 1                                                        78000013
* IGNORE NMAX. OVERLAY NMAX TEST WITH A BYPASS BRANCH INSTR.            78200013
         SPACE 1                                                        78400013
RDIGNORE MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN         78600013
         CLC   RDUSREXT,RDOVLAY4   HAS USER EXIT CODE BEEN OVERLAID?    78800013
         BNE   *+10                IF NOT, BRANCH AROUND NEXT INSTRUC   79000013
         MVC   RDUSREXT,K4         CHANGE OVERLAID INSTRUCTION          79200013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ALTER RTN 79400013
         TM    WSW1,X'01'          TEST SWITCH 1                        79600013
         BC    1,RDISWON           ON,BR TO TURN INSERT SWITCH ON       79800013
         B     RDISWOFF            BR TO TURN INSERT SWITCH OFF         80000013
         SPACE 2                                                        80200013
* DO NOTHING, ALTER, LENGTHEN, SHORTEN A RCD. ADDR OF INPUT RCD IN RB.  80400013
         SPACE 1                                                        80600013
RDALSHNO BCT   RJ,RDISWOFF         DECR NMAX CTR BY ONE AND TST TO SEE  80800013
*                                    IF REACHED NMAX                    81000013
         B     RDMSGS              YES, BR TO NMAX USER EXIT E16        81200013
         SPACE 2                                                        81400013
RDISWOFF NI    WINSRTSW,X'00'      TURN OFF INSERT SWITCH               81600013
         B     RDSTM               BR TO LOAD ADDR OF FREE AREA IN RSA  81800013
         SPACE 2                                                        82000013
* DELETE A RECORD                                                       82200013
         SPACE 1                                                        82400013
RDDELETE NI    WINSRTSW,X'00'      TURN OFF INSERT SWITCH               82600013
         LA    RH,1(0,RH)          INCR DELETE CTR BY ONE               82800013
         B     RDGET               BR TO GET ANOTHER RECORD             83000013
         SPACE 1                                                        83200013
* END OF CODING --- ADCONS NEXT PAGE                                    83400013
         EJECT                                                          83600013
* LIST OF ADCONS USED BY THE MODULE                                     83800013
         SPACE 1                                                        84000013
ADCONPTR DC    A(TABLRSA)          ADDR OF RSA TABLE                    84200013
* LIST OF CONSTANTS USED BY THE MODULE                                  84400013
         SPACE 1                                                        84600013
K1       L     RF,WINNER           OVERLAY WHEN FINISHED FILLING TREE   84800013
K2       B     RDEMPTYT            OVERLAY TO EMPTYTREE ON GET EOF      85000013
K3       B     RDISWON             BYPASS NMAX TEST IN INSERT RTN       85200013
K4       B     RDISWOFF            BYPASS NMAX TEST IN DO NOTHG,ETC RTN 85400013
K5       B     RDUSREXT            OVERLAY INSERT SW TEST BY A.P. IF    85600013
*                                    ATTACHED                           85800013
         SPACE 2                                                        86000013
* LIST OF WORK AREAS                                                    86200013
         SPACE 1                                                        86400013
WSW1     DC    X'00'               SWITCH 1 IN INSERT RTN               86600013
WINSRTSW DC    X'00'               INSERT SWITCH                        86800013
WUSREOF  DC    X'00'               USER END OF FILE SW. SET BY A.P. IF  87000013
*                                    EXIT E15 IS INACTIVE.              87200013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            87400013
WINNER   DC    F'0'                SORT WINNER RCD ADDR                 87600013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR INPUT FILE  87800013
*                                    LOADED BY ASSIGNMENT ROUTINE       88000013
WRJ      DC    2F'0'               SAVE TRANPARENT REGS                 88200013
WINPTRCD DC    F'0'                ADDR OF RCD IN INPUT AREA            88400013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 88600013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    88800013
*                                    4 BYTES- ADDR IN BIN TO MOVE RCD   89000013
*                                    4 BYTES- REMAINING BYTE COUNT OF   89200013
*                                      THIS RSA.                        89400013
*                                    THIS TABLE INITIALIZED BY IERADD   89600013
         EJECT                                                          89800013
* MODULE NAME ***IERRMA***                                              90000013
*                                                                       90200013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        90400013
* PHASE 1 RUNNING PROGRAM.                                              90600013
         SPACE 1                                                        90800013
IERRMA   DSECT                                                          91000013
*                                                                       91200013
       COPY  RMAMAIN                                                    91400013
         EJECT                                                          91600013
         SMPPI                                                          91800013
         END                                                            92000013
