         TITLE 'IERRDE -OS/360 SORT/MERGE - 360-SM-023    05/20/65'     00200013
         SPACE                                                          00400013
*MODULE NAME *** IERRDE ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 0                                                 01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: IERRDE IS A DEBLOCK MODULE WHICH HANDLES    01400013
*   VARIABLE LENGTH RECORDS BY WAY OF THE QSAM GET MACRO AND CONTAINS   01600013
*   LINKAGE TO THE USER MODIFICATION PROGRAMS VIA THE CALL MACRO EXPAN- 01800013
*   SION INSTRUCTIONS. THE INPUT RECORDS ARE LOCATED IN AN INPUT        02000013
*   BUFFER. BEFORE MOVING THE RECORD TO THE WORK AREA, RSA, THE MODULE  02200013
*   BRANCHES TO THE USER ROUTINE WHICH MAY: 1.DELETE, 2.INSERT OR 3.    02400013
*   ALTER(LENGTHEN, SHORTEN OR DO NOTHING TO THE RECORD). THE ADDRESS   02600013
*   OF THE RECORD IN THE INPUT AREA IS PASSED TO THE USER. THE USER     02800013
*   RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS. THIS MODULE   03000013
*   KEEPS TRACK OF THE MAXIMUM AMOUNT OF RECORDS THAT THE SORT CAN      03200013
*   HANDLE AT ANY ONE TIME(NMAX). IT CHECKS TO SEE IF NMAX IS REACHED   03400013
*   AND IF IT IS REACHED, IT BRANCHES TO THE USER ROUTINE WHICH MAY     03600013
*   DIRECT US TO: 1.SORT CURRENT NUMBER, 2.IGNORE NMAX OR 3.ABORT JOB.  03800013
*   THE USER RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS. THE  04000013
*   MODULE BRANCHES TO THE MOVE MODULE (IERRBF) WHICH MOVES THE RECORD  04200013
*   INTO RSA. IERRDE THEN PASSES THE RECORD'S LOCATION IN RSA TO THE    04400013
*   REPLACEMENT SORT. USER EXITS E15 AND E16 ARE AVAILABLE IN THIS      04600013
*   MODULE.                                                             04800013
         SPACE 2                                                        05000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05200013
*   IERADE                                                              05400013
         SPACE 2                                                        05600013
*LIST OF MACROS USED BY MODULE:                                         05800013
*   SMPPI                                                               06000013
*   GET                                                                 06200013
         SPACE 2                                                        06400013
*ENTRY POINTS:                                                          06600013
         SPACE 1                                                        06800013
*        ENTRY                     ENTRY FROM NETWORK.                  07000013
*                                    CALLING SEQUENCE-                  07200013
*                                      L     RL,PPIDEB+4                07400013
*                                      B     8(RL)     DURING TREE FILL 07600013
         SPACE 1                                                        07800013
*                                      L     RL,PPIDEB+4                08000013
*                                      BR    RL     ONCE-WHEN TREE FULL 08200013
         SPACE 1                                                        08400013
*        ENTRY                     ENTRY FROM BLOCK.                    08600013
*                                    CALLING SEQUENCE-                  08800013
*                                     L     RL,PPIDEB+4                 09000013
*                                      B     8(RL)                      09200013
         SPACE 1                                                        09400013
*        ENTRY                     ENTRY FROM EOF ROUTINE.              09600013
*                                    CALLING SEQUENCE-                  09800013
*                                      L     RL,PPIDEB+4                10000013
*                                      B     4(RL)                      10200013
         SPACE 1                                                        10400013
*        ENTRY                     ENTRY FROM E15.                      10600013
*                                    CALLING SEQUENCE-                  10800013
*                                      BR    RO                         11000013
         SPACE 1                                                        11200013
*        ENTRY                     ENTRY FROM E16.                      11400013
*                                    CALLING SEQUENCE-                  11600013
*                                      BR    RO                         11800013
         SPACE 2                                                        12000013
*INPUT: PPI FIELDS REFERENCED -                                         12200013
         SPACE 1                                                        12400013
*   PPIBDSVA    PPINET      PPIX15                                      12600013
*   PPIX16      PPISTDCB    PPICOUNT                                    12800013
*   PPINSCT     PPIDELCT    PPIRMA                                      13000013
*   PPIADSSC                                                            13200013
         SPACE 2                                                        13400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED -                            13600013
         SPACE 1                                                        13800013
*   PPIBDSVA    PPICOUNT    PPIINSCT                                    14000013
*   PPIDELCT    PPISW1                                                  14200013
         SPACE 2                                                        14400013
*EXTERNAL ROUTINES:                                                     14600013
         SPACE 1                                                        14800013
*        EXTRN IERRMA              ERROR MESSAGE PRINT ROUTINE.         15000013
         SPACE 2                                                        15200013
*EXTERNAL PARAMETERS - N/A                                              15400013
*                                                                       15600013
*                                                                       15800013
*EXITS-NORMAL:                                                          16000013
         SPACE 1                                                        16200013
*   E15      - PHASE 1 RECORD MODIFICATION EXIT.                        16400013
*   E16      - PHASE 1 NMAX EXIT.                                       16600013
*   NETWORK  - PASS ADDRESS OF EACH INCOMING RECORD.                    16800013
         SPACE 2                                                        17000013
*EXITS-ERROR;                                                           17200013
         SPACE 1                                                        17400013
*   PPIADSSC - PRINT NMAX REACHED MESSAGE.                              17600013
         SPACE 2                                                        17800013
*TABLES/WORK AREAS:                                                     18000013
         SPACE 1                                                        18200013
*   WORK AREA AT WSAVE IS A 3 WORD AREA TO SAVE REGISTER INFORMATION    18400013
*   FOR MOVE ROUTINE WHEN ONLY A PORTION OF A RECORD FITS IN RSA.       18600013
*   WORK AREA AT WNMAX IS WHERE A RUNNING COUNT OF RECORDS IS KEPT SO   18800013
*   IT CAN BE DETERMINED WHEN NMAX HAS BEEN REACHED.                    19000013
*   WORK AREAS WUSREOF, WINPEOF AND WINSALT ARE SWITCHES FOR USER END   19200013
*   OF FILE, INPUT END OF FILE AND INSERT-ALTER RECORD RESPECTIVELY.    19400013
*   WORK AREA WSAVAIL IS A SAVE AREA FOR THE RSA ADDRESS OF THE RECORD  19600013
*   CURRENTLY BEING MOVED.                                              19800013
         SPACE 2                                                        20000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  20200013
         SPACE 2                                                        20400013
*NOTES: THIS MODULE IS USED FOR VARIABLE LENGTH RECORD SORTS WHICH HAVE 20600013
*   EXITS 15 OR 16 ACTIVATED.                                           20800013
         EJECT                                                          21000013
*LIST OF GENERAGENERAL REGISTER EQUATE STATEMENTS:                      21200013
         SPACE 1                                                        21400013
RA       EQU   0                   CONTENTS IN - WHEN ENTERED FROM THE  21600013
*                                    MOVE ROUTINE ON A CONDITION WHERE  21800013
*                                    THE RECORD DID NOT FIT IT CONTAINS 22000013
*                                    THE NUMBER OF BYTES YET TO MOVE.   22200013
*                                  USED - NOT USED.                     22400013
*                                  CONTENTS OUT - RESTORED TO VALUE OF  22600013
*                                    CONTENTS IN ONLY WHEN RETURNING TO 22800013
*                                    MOVE ROUTINE TO COMPLETE MOVE.     23000013
*                                               - ADDRESS OF NMAC       23200013
*                                    MESSAGE UPON BRANCH TO PPIADSSC    23400013
RB       EQU   1                   CONTENTS IN - NUMBER OF BINS USED    23600013
*                                    WHEN ENTERED FROM MOVE ROUTINE.    23800013
*                                              - ADDRESS OF RECORD TO   24000013
*                                    BE MOVED INTO RSA UPON RETURN FROM 24200013
*                                    E15. MEANINGLESS IF RECORD IS TO   24400013
*                                    BE DELETED.                        24600013
*                                              - ADDRESS OF RECORD WHEN 24800013
*                                    ENTERED FROM QSAM GET ROUTINE.     25000013
*                                  USED - GENERAL WORK REGISTER.        25200013
*                                  CONTENTS OUT - 0 OR 8 WHEN BRANCHING 25400013
*                                    TO MOVE ROUTINE. 0=NORMAL-8=LAST   25600013
*                                    RECORD DIDN'T FIT IN RSA.          25800013
*                                               - ADDRESS OF PARAMETER  26000013
*                                    LIST WHEN BRANCHING TO E15.        26200013
*                                               - BUFFER ADDRESS OF     26400013
*                                    CURRENT RECORD WHEN BRANCHING TO   26600013
*                                    E16.                               26800013
*                                               - NUMBER OF CHARACTERS  27000013
*                                    IN NMAX MESSAGE WHEN BRANCHING TO  27200013
*                                    ERROR PRINT ROUTINE.               27400013
RC       EQU   2                   CONTENTS IN - N/A                    27600013
*                                  USED - GENERAL WORK REGISTER.        27800013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  28000013
*                                    INPUT BUFFER WHEN BRANCHING TO     28200013
*                                    NETWORK.                           28400013
RD       EQU   3                   CONTENTS IN - N/A                    28600013
*                                  USED - GENERAL WORK REGISTER.        28800013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  29000013
*                                    RSA WHEN BRANCHING TO NETWORK.     29200013
RE       EQU   4                   CONTENTS IN - POINTER TO PORTION OF  29400013
*                                    RECORD IN INPUT BUFFER WHEN MOVE   29600013
*                                    ROUTINE RETURNS BECAUSE RECORD     29800013
*                                    DIDN'T FIT IN RSA.                 30000013
*                                  USED - GENERAL WORK REGISTER.        30200013
*                                  CONTENTS OUT - ADDRESS OF DCB WHEN   30400013
*                                    BRANCHING TO QSAM GET ROUTINE.     30600013
*                                               - ADDRESS OF RECORD IN  30800013
*                                    INPUT BUFFER WHEN BRANCHING TO THE 31000013
*                                    MOVE ROUTINE.                      31200013
RF       EQU   5                   CONTENTS IN - POINTER TO CHAIN       31400013
*                                    ADDRESS OF LAST BIN USED UPON      31600013
*                                    RETURN FROM MOVE ROUTINE.          31800013
*                                  USED - GENERAL WORK REGISTER.        32000013
*                                  CONTENTS OUT - POINTER TO NEXT       32200013
*                                    AVAILABLE BIN IN RSA WHEN BRANCH-  32400013
*                                    ING TO MOVE ROUTINE.               32600013
RG       EQU   6                   NOT USED.                            32800013
RH       EQU   7                   NOT USED.                            33000013
RI       EQU   8                   NOT USED.                            33200013
RJ       EQU   9                   CONTENTS IN - N/A                    33400013
*                                  USED - RECORD COUNT FOR NMAX         33600013
*                                       - GENERAL WORK REGISTER         33800013
*                                  CONTENTS OUT - N/A                   34000013
RK       EQU   10                  NOT USED.                            34200013
RL       EQU   11                  CONTENTS IN - ADDRESS OF IERRDE.     34400013
*                                  USED - MODULE BASE REGISTER.         34600013
*                                  CONTENTS OUT - ADDRESS OF NETWORK.   34800013
RM       EQU   12                  NOT USED.                            35000013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI.        35200013
*                                  CONTENTS OUT - ADDRESS OF PPI.       35400013
RO       EQU   14                  CONTENTS IN - N/A                    35600013
*                                  USED - BASE REGISTER FOR MESSAGE     35800013
*                                    MODULE.                            36000013
*                                       - RETURN REGISTER ON BRANCH TO  36200013
*                                    E15, E16, PRINT ROUTINE AND MOVE   36400013
*                                    ROUTINE.                           36600013
*                                  CONTENTS OUT - N/A                   36800013
RP       EQU   15                  CONTENTS IN - CODE TO DELETE,ALTER   37000013
*                                    OR INSERT RECORD UPON RETURN FROM  37200013
*                                    E15.                               37400013
*                                              - CODE TO CONTINUE SORT- 37600013
*                                    ING, SORT CURRENT RECORDS OR ABORT 37800013
*                                    THE SORT UPON ENTRY FROM E16.      38000013
*                                  USED - GENERAL WORK REGISTER.        38200013
*                                  CONTENTS OUT - ADDRESS OF E15, E16   38400013
*                                    PRINT ROUTINE AND MOVE ROUTINE     38600013
*                                    WHEN THEY ARE BRANCHED TO.         38800013
         SPACE 2                                                        39000013
*START OF MODULE CODE PROPER:                                           39200013
         SPACE 2                                                        39400013
IERRDE   CSECT                                                          39600013
         USING *,RL                                                     39800013
         USING IERRCA,RN                                                40000013
         USING IERRMA,RO           MESSAGE MODULE ADR                   40200013
IERDD1   B     RDEOLAY             GO TO OVERLAY EXITS                  40400013
         B     RDEEOF              GO TO EOF ROUTINE                    40600013
RDENTER  CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  40800013
         BL    RDENORM             NO FIT SWITCH OFF                    41000013
         BH    RDESPEC             NO. OF BINS WAS=0                    41200013
         SR    RE,RE                                                    41400013
         A     RE,PPIBDSVA+8                                            41600013
         BZ    RDEBINZ             BIN COUNT STILL=0                    41800013
         L     RA,WSAVE                                                 42000013
         L     RE,WSAVE+4          RELOAD REGS TO CONTINUE MOVE         42200013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 42400013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                42600013
         ST    RD,0(0,RC)          INSERT CHAIN ADDRESS                 42800013
         LA    RB,8(0)             INDICATE DEBLOCK WITH NOFIT PREVIOUS 43000013
         L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          43200013
RDEMOVE  L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             43400013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               43600013
         SPACE 2                                                        43800013
         B     RDENOTF             RECORD DIDN'T FIT                    44000013
         SPACE                                                          44200013
*  RECORD FIT ROUTINE                                                   44400013
         SPACE                                                          44600013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  44800013
         BC    7,RDEUSUAL          LAST MOVE WAS NOT A NO FIT           45000013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       45200013
         SR    RC,RC                                                    45400013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     45600013
         B     RDEUSUAL+4          RD ALREADY LOADED                    45800013
RDEUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RCD JUST MOVED          46000013
         AH    RD,EXPLFOUR         ADD EXT SIZE & 4                     46200013
         L     RC,ADRHOLDB         LOAD BUFFER ADDRESS                  46400013
         L     RE,PPIBDSVA+8                                            46600013
         SR    RE,RB                                                    46800013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     47000013
         L     RE,0(0,RF)                                               47200013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         47400013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               47600013
         L     RL,PPINET+4                                              47800013
RDEFIT   B     4(0,RL)             EXIT TO SORT ON RECORD FIT CONDITION 48000013
         SPACE 2                                                        48200013
*  RECORD NO FIT ROUTINE                                                48400013
         SPACE                                                          48600013
RDENOTF  ST    RA,WSAVE                                                 48800013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              49000013
         SR    RD,RD                                                    49200013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         49400013
         OI    NOFITSW,X'01'       SET NOFITSW=01                       49600013
         A     RD,WSAVAIL                                               49800013
         BC    7,RDEBINZ           MORE THAN ONE NO FIT ON SAME RECORD  50000013
         L     RD,PPIBDSVA+4                                            50200013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      50400013
RDEBINZ  L     RL,PPINET+4                                              50600013
         B     24(0,RL)            EXIT TO SORT ON RECORD NO FIT        50800013
         SPACE 2                                                        51000013
RDESPEC  SR    RE,RE                                                    51200013
         A     RE,PPIBDSVA+8       CHECK BIN COUNT                      51400013
         BZ    RDEBINZ             BIN COUNT STILL ZERO                 51600013
         NI    NOFITSW,X'00'       ZERO NOFITSW-BIN COUNT NO LONGER 0   51800013
         L     RE,ADRHOLDA         RELOAD BUFFER ADDRESS                52000013
RDEPTB   L     RF,PPIBDSVA+4                                            52200013
         AH    RF,EXPLFOUR         ADD EXT SIZE & 4 TO AVAIL ADR        52400013
         ST    RE,ADRHOLDB         SAVE BUFFER ADDRESS                  52600013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     52800013
         B     RDEMOVE             CONTINUE PREP FOR MOVE               53000013
         SPACE 2                                                        53200013
RDENORM  CLI   INSERTSW,X'00'                                           53400013
         BH    RDEISWON                                                 53600013
RDEGET   LM    RA,RB,KAWORK        DCB ADDR AND/OR VRE WORK ADDR A26453 53800019
         GET   (1),(0)             GET RECORD GL OR GM           A26453 54100019
         SPACE 2                                                        54400013
         L     RJ,PPICOUNT                                              54600013
         LA    RJ,1(0,RJ)                                               54800013
         ST    RJ,PPICOUNT         ADD 1 TO RECORD COUNT                55000013
         ST    RB,ADRHOLD                                               55200013
RDEISWON LA    RB,ADRHOLD          SET UP PARAMETER FOR USER MOD        55400013
*                                    WILL BE L RB,ADRHOLD ON USER EOF   55600013
         L     RJ,PPINMAX          RESTORE NMAX REG                     55800013
         LTR   RJ,RJ               TEST FOR 0 OR NMAX                   56000013
         BC    2,RDEUEXIT          IF NMAX PLUS EXIT                    56200013
         LA    RJ,1                NMAX MUST BE AT LEAST 1              56400013
         SPACE                                                          56600013
*  USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.           56800013
*    ADDRESS OF INPUT RECORD PASSED IN RB                               57000013
         SPACE                                                          57200013
RDEUEXIT L     RP,PPIX15+4         OVERLAYED IF THIS EXIT NOT ACTIVATED 57400013
*                                  OR IF USER EOF REACHED.              57600013
         BALR  RO,RP               BRANCH TO USER                       57800013
         SPACE 2                                                        58000013
*  USER RETURNS VIA RO WITH PROPER DISPLACEMENT IN RP. HE ALSO PASSES,  58200013
*    IN REG RB, THE ADR OF THE RECORD TO BE INSERTED OR THE ADR OF THE  58400013
*    WORK AREA IF THE USER HAS ALTERED THE RECORD.                      58600013
         SPACE                                                          58800013
         B     *+4(15)                                                  59000013
         B     RDEDONO             ALTER OR DO NOTHING                  59200013
         B     RDELETE             DELETE A RECORD                      59400013
         B     RDEUEOF             USER END OF FILE                     59600013
         SPACE                                                          59800013
*  INSERT A RECORD                                                      60000013
         SPACE                                                          60200013
RDEMAXCK BCT   RJ,RDEINSRT         CHECK FOR NMAX AND DECREMENT         60400013
         B     RDEMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  60600013
         SPACE 2                                                        60800013
RDEINSRT OI    INSERTSW,X'01'      SET INSERT SWITCH                    61000013
         L     RF,PPIINSCT                                              61200013
         LA    RF,1(0,RF)                                               61400013
         ST    RF,PPIINSCT         ADD 1 TO INSERT COUNT                61600013
RDETSTBC LR    RE,RB               SET UP BUFF ADR FOR MOVE             61800013
         ST    RJ,PPINMAX          SAVE NMAX REG                        62000013
         SR    RF,RF                                                    62200013
         A     RF,PPIBDSVA+8       TEST BIN COUNT                       62400013
         BC    7,RDEPTB            BRANCH ON BIN COUNT NOT EQUAL 0      62600013
         ST    RE,ADRHOLDA         SAVE RCD ADR UNTIL BIN IS AVAILABLE  62800013
         OI    NOFITSW,X'03'       SET NO FIT SWITCH = 11               63000013
         B     RDEBINZ             GO TO NO FIT EXIT                    63200013
         SPACE 2                                                        63400013
RDEDONO  BCT   RJ,RDENOTM          CHECK FOR NMAX AND DECREMENT         63600013
         B     RDEMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  63800013
         SPACE 2                                                        64000013
RDENOTM  NI    INSERTSW,X'00'      ZERO INSERT SWITCH                   64200013
         B     RDETSTBC            GO CHECK BIN COUNT                   64400013
         SPACE 2                                                        64600013
RDELETE  NI    INSERTSW,X'00'      ZERO INSERT SWITCH                   64800013
         L     RF,PPIDELCT                                              65000013
         LA    RF,1(0,RF)                                               65200013
         ST    RF,PPIDELCT         ADD 1 TO DELETE COUNT                65400013
         B     RDEGET              GO GET ANOTHER RECORD                65600013
         SPACE 2                                                        65800013
RDEMSG   STH   RP,WINSALT          SAVE INSERT-ALTER CONDITION          66000013
         L     RO,PPIRMA+4         MESSAGE MODULE ADR                   66200013
         LR    RE,RB               SAVE BUFF ADR                        66400013
         LM    RA,RB,MSGP1A04                                           66600013
         L     RP,PPIADSSC         LOAD PRINT RTN ADR                   66800013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      67000013
         SPACE 2                                                        67200013
*  USER EXIT E16-SORT CAPACITY, NMAX, HAS BEEN REACHED                  67400013
*    CALL MACRO INSTRUCTION EXPANSION                                   67600013
         SPACE                                                          67800013
         LR    RB,RE               RESTORE BUFF ADR                     68000013
         L     RP,PPIX16+4         NMAX EXIT ADR                        68200013
         BALR  RO,RP               BRANCH TO USER                       68400013
         SPACE 2                                                        68600013
*  USER RETURNS TO MODULE VIA RO WITH PROPER DISPLACEMENT IN RP         68800013
         SPACE                                                          69000013
         B     *+4(15)                                                  69200013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         69400013
         B     RDEIGNOR            IGNORE NMAX-CONTINUE SORT            69600013
         SPACE                                                          69800013
*  ABORT THE JOB                                                        70000013
         SPACE                                                          70200013
         L     RP,PPIADSSC                                              70400013
         BAL   RO,16(0,RP)         EXIT TO SORT SYSTEM CONTROL          70600013
         SPACE 2                                                        70800013
RDESRTCR MVC   RDENTER(4),K1       OVERLAY ENTRANCE                     71000013
         L     RL,PPINET+4                                              71200013
         B     8(0,RL)             BRANCH TO SORT TO EMPTY TREE         71400013
         SPACE 2                                                        71600013
RDEMPTYT L     RL,PPINET+4                                              71800013
         B     16(0,RL)            BRANCH TO SORT TO CONT. EMPTY TREE   72000013
         SPACE 2                                                        72200013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              72400013
         SPACE 1                                                        72600013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 72800013
         CLI   WINPEOF,X'00'       WAS SYSTEM INPUT EOF REACHED         73000013
         BC    8,RDESRTCR          YES,DO NOT DECR PPICOUNT-FLUSH TREE  73200013
         L     RE,PPICOUNT         RCD IN INPUT BFR WILL NOT BE SORTED  73400013
         BCTR  RE,0                DECR PPICOUNT BY ONE                 73600013
         ST    RE,PPICOUNT         RESTORE PPICOUNT                     73800013
         B     RDESRTCR            BR TO FLUSH TREE                     74000013
         SPACE 1                                                        74200013
*  IGNORE NMAX-OVERLAY NMAX TEST WITH A BRANCH                          74400013
         SPACE                                                          74600013
RDEIGNOR MVC   RDEMAXCK(4),K2      OVERLAY NMAX CK IN INSERT LEG        74800013
         MVC   RDEDONO(4),K3       OVERLAY NMAX CK IN ALTER LEG         75000013
         SR    RF,RF                                                    75200013
         AH    RF,WINSALT                                               75400013
         BZ    RDENOTM             RESUME WITH INPUT RECORD             75600013
         B     RDEINSRT            RESUME WITH INSERT RECORD            75800013
         SPACE 2                                                        76000013
RDEOLAY  LA    RE,12(0)                                                 76200013
         STC   RE,RDEFIT+3         OVERLAY FILLING-FIT EXIT             76400013
         LA    RE,28(0)                                                 76600013
         STC   RE,RDESPEC-1        OVERLAY FILLING-NO FIT EXIT          76800013
         B     RDENTER             BRANCH TO NORMAL ENTRANCE            77000013
         SPACE 2                                                        77200013
RDEUEOF  CLI   WINPEOF,X'00'       HAVE WE REACHED INPUT EOF            77400013
         BE    RDESRTCR            YES-GO EMPTY TREE                    77600013
         SR    RF,RF                                                    77800013
         STC   RF,WUSREOF          INDICATE USER EOF                    78000013
         MVC   RDEUEXIT(4),K4      OVERLAY AFTER USER EOF               78200013
         MVC   RDEMSG,K6                                                78400013
         L     RB,ADRHOLD          RESTORE ADDR OF RCD IN INPUT BLK     78600013
         MVI   RDEISWON,X'58'      CHANGE LA INSTRUCTION TO L           78800013
         B     RDENOTM             BRANCH TO MOVE INPUT RECORD          79000013
         SPACE 2                                                        79200013
RDEEOF   CLI   WUSREOF,X'00'       HAS USER REACHED EOF                 79400013
         BE    RDESRTCR            GO OVERLAY ENTRANCE                  79600013
         SR    RF,RF                                                    79800013
         STC   RF,WINPEOF          INDICATE INPUT EOF                   80000013
         MVC   RDEGET(4),K5        OVERLAY AFTER INPUT EOF              80200013
         SR    RB,RB                                                    80400013
         ST    RB,ADRHOLD          INPUT EOF INDICATION TO USER         80600013
         B     RDEISWON            GO TO SET UP FOR BRANCH TO USER      80800013
         SPACE 2                                                        81000013
         SPACE 2                                                        81200013
NOFITSW  DC    X'00'                                                    81400013
INSERTSW DC    X'00'                                                    81600013
EXPLFOUR DC    H'0'                                                     81800013
WSAVE    DC    3F'0'               FOR MOVE RTN                         82000013
ADRHOLD  DC    F'0'                FOR BUFFER ADR                       82200013
ADRHOLDA DC    F'0'                RECORD ADR WHEN BIN COUNT=0          82400013
ADRHOLDB DC    F'0'                RECORD ADR FOR MOVE RTN AND SORT RTN 82600013
WUSREOF  DC    X'01'               USER EOF SWITCH                      82800013
WINPEOF  DC    X'01'               INPUT EOF SWITCH                     83000013
WINSALT  DC    H'0'                INSERT-ALTER SWITCH                  83200013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADDRESS     83400013
         SPACE 2                                                        83600013
K1       B     RDEMPTYT            OVERLAY TO EMPTY TREE                83800013
K2       B     RDEINSRT            OVERLAY IN INSERT LEG                84000013
K3       B     RDENOTM             OVERLAY IN ALTER LEG                 84200013
K4       B     RDEDONO             OVERLAY AFTER USER EOF               84400013
K5       B     RDEISWON           OVLY AFTER INPUT E O F                84600013
K6       BC    0,0                                                      84800013
KAWORK   DC    2F'0'               FOR DCB AND VRE WORK ADDRS    A26453 84900019
         SMPPI                                                          85000013
* MODULE NAME ***IERRMA***                                              85200013
*                                                                       85400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        85600013
* PHASE 1 RUNNING PROGRAM.                                              85800013
         SPACE 1                                                        86000013
IERRMA   DSECT                                                          86200013
*                                                                       86400013
       COPY  RMAMAIN                                                    86600013
*                                                                       86800013
         END                                                            87000013
