         TITLE 'IERRDG - OS/360 SORT/MERGE - 360-SM-023   05/11/65'     00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRDG ***                                             00900013
         SPACE 2                                                        01200013
*STATUS: CHANGE LEVEL 0                                                 01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: IERRDG IS A DEBLOCK MODULE WHICH HANDLES    02100013
*   VARIABLE LENGTH RECORDS BY WAY OF THE QSAM GET MACTO. THERE ARE NO  02400013
*   USER MODIFICATIONS. THE MODULE LINKS TO THE VARIABLE MOVE ROUTINE   02700013
*   (IERRBF), WHICH MOVES THE VARIABLE LENGTH RECORD FROM THE INPUT     03000013
*   BUFFER INTO RSA BIN(S). UPON RETURN FROM THE MOVE ROUTINE, THE      03300013
*   MODULE PASSES ON TO THE REPLACEMENT SORT THE RECORDS LOCATION IN    03600013
*   RSA.                                                                03900013
         SPACE 2                                                        04200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04500013
*   IERADG                                                              04800013
         SPACE 2                                                        05100013
*LIST OF MACROS USED BY MODULE:                                         05400013
*   SMPPI                                                               05700013
*   GET                                                                 06000013
         SPACE 2                                                        06300013
*ENTRY POINTS:                                                          06600013
         SPACE 1                                                        06900013
*        ENTRY                     ENTRY FROM NETWORK                   07200013
*                                    CALLING SEQUENCE-                  07500013
*                                      L     RL,PPIDEB+4                07800013
*                                      B     8(RL)     DURING TREE FILL 08100013
         SPACE 1                                                        08400013
*                                      L     RL,PPIDEB+4                08700013
*                                      BR     RL    ONCE-WHEN TREE FULL 09000013
         SPACE 1                                                        09300013
*        ENTRY                     ENTRY FROM BLOCK                     09600013
*                                    CALLING SEQUENCE-                  09900013
*                                      L     RL,PPIDEB+4                10200013
*                                      B     8(RL)                      10500013
         SPACE 1                                                        10800013
*        ENTRY                     ENTRY FROM EOF ROUTINE               11100013
*                                    CALLING SEQUENCE-                  11400013
*                                      L     RL,PPIDEB+4                11700013
*                                      B     4(RL)                      12000013
         SPACE 2                                                        12300013
*INPUT: PPI FIELDS REFERENCED -                                         12600013
         SPACE 1                                                        12900013
*   PPIBDSVA    PPINET      PPISTDCB                                    13200013
*   PPICOUNT                                                            13500013
         SPACE 2                                                        13800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED -                            14100013
         SPACE 1                                                        14400013
*   PPIBDSVA    PPICOUNT                                                14700013
         SPACE 2                                                        15000013
*EXTERNAL ROUTINES:                                                     15300013
         SPACE 1                                                        15600013
*        IERRBF                    USED TO MOVE RECORDS FROM INPUT      15900013
*                                    BUFFER TO RSA.                     16200013
         SPACE 2                                                        16500013
*EXTERNAL PARAMETERS - N/A                                              16800013
*                                                                       17100013
*                                                                       17400013
*                                                                       17700013
*EXITS-NORMAL:                                                          18000013
         SPACE 1                                                        18300013
*   NETWORK - PASS ADDRESS OF EACH INCOMING RECORD.                     18600013
         SPACE 2                                                        18900013
*EXITS-ERROR: N/A                                                       19200013
         SPACE 2                                                        19500013
*TABLES/WORK AREAS:                                                     19800013
         SPACE 1                                                        20100013
*   WORK AREA AT WSAVE IS FOR SAVING 3 REGISTERS OF INFORMATION GIVEN   20400013
*   BY THE MOVE MODULE (IERRBF).                                        20700013
*   WORK AREA AT WSAVAIL IS TO HOLD THE ADDRESS OF THE RECORD CURRENTLY 21000013
*   BEING MOVED INTO RSA.                                               21300013
         SPACE 2                                                        21600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  21900013
         SPACE 2                                                        22200013
*NOTES: THIS MODULE IS USED FOR ALL VARIABLE LENGTH RECORD SORTS EXCEPT 22500013
*   THOSE WHICH HAVE EXITS 15 OR 16 ACTIVATED.                          22800013
         EJECT                                                          23100013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            23400013
         SPACE 1                                                        23700013
RA       EQU   0                   CONTENTS IN - WHEN ENTERED FROM THE  24000013
*                                    MOVE ROUTINE ON A CONDITION WHERE  24300013
*                                    THE RECORD DID NOT FIT IT CONTAINS 24600013
*                                    THE NUMBER OF BYTES YET TO MOVE.   24900013
*                                  USED - NOT USED.                     25200013
*                                  CONTENTS OUT - RESTORED TO VALUE OF  25500013
*                                    CONTENTS IN ONLY WHEN RETURNING TO 25800013
*                                    MOVE ROUTINE TO COMPLETE MOVE.     26100013
RB       EQU   1                   CONTENTS IN - NUMBER OF BINS USED    26400013
*                                    WHEN ENTERED FROM MOVE ROUTINE.    26700013
*                                              - ADDRESS OF RECORD WHEN 27000013
*                                    ENTERED FROM QSAM GET ROUTINE.     27300013
*                                  USED - GENERAL WORK REGISTER.        27600013
*                                  CONTENTS OUT - 0 OR 8 WHEN BRANCHING 27900013
*                                    TO MOVE ROUTINE. 0=NORMAL-8-LAST   28200013
*                                    RECORD DIDN'T FIT IN RSA.          28500013
RC       EQU   2                   CONTENTS IN - N/A                    28800013
*                                  USED - GENERAL WORK REGISTER.        29100013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  29400013
*                                    INPUT BUFFER WHEN BRANCHING TO     29700013
*                                    NETWORK.                           30000013
RD       EQU   3                   CONTENTS IN - N/A                    30300013
*                                  USED - GENREAL WORK REGISTER.        30600013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  30900013
*                                    RSA WHEN BRANCHING TO NETWORK.     31200013
RE       EQU   4                   CONTENTS IN - POINTER TO PORTION OF  31500013
*                                    RECORD IN INPUT BUFFER WHEN MOVE   31800013
*                                    ROUTINE RETURNS BECAUSE RECORD     32100013
*                                    DIDN'T FIT IN RSA.                 32400013
*                                  USED - GENREAL WORK REGISTER.        32700013
*                                  CONTENTS OUT - ADDRESS OF DCB WHEN   33000013
*                                    BRANCHING TO QSAM GET ROUTINE.     33300013
*                                               - ADDRESS OF RECORD IN  33600013
*                                    INPUT BUFFER WHEN BRANCHING TO THE 33900013
*                                    MOVE ROUTINE.                      34200013
RF       EQU   5                   CONTENTS IN - POINTER TO CHAIN       34500013
*                                    ADDRESS OF LAST BIN USED UPON      34800013
*                                    RETURN FROM MOVE ROUTINE.          35100013
*                                  USED - GENERAL WORK REGISTER.        35400013
*                                  CONTENTS OUT - POINTER TO NEXT       35700013
*                                    AVAILABLE BIN IN RSA WHEN BRANCH-  36000013
*                                    ING TO MOVE ROUTINE.               36300013
RG       EQU   6                   NOT USED.                            36600013
RH       EQU   7                   NOT USED.                            36900013
RI       EQU   8                   NOT USED.                            37200013
RJ       EQU   9                   NOT USED.                            37500013
RK       EQU   10                  NOT USED.                            37800013
RL       EQU   11                  CONTENTS IN - ADDRESS OF IERRDG.     38100013
*                                  USED - MODULE BASE REGISTER.         38400013
*                                  CONTENTS OUT - ADDRESS OF NETWORK.   38700013
RM       EQU   12                  NOT USED.                            39000013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI.        39300013
*                                  USED - BASE REGISTER FOR PPI.        39600013
*                                  CONTENTS OUT - ADDRESS OF PPI.       39900013
RO       EQU   14                  CONTENTS IN - N/A                    40200013
*                                  USED - RETURN REGISTER ON BRANCH TO  40500013
*                                    MOVE ROUTINE.                      40800013
*                                  CONTENTS OUT - N/A                   41100013
RP       EQU   15                  CONTENTS IN - N/A                    41400013
*                                  USED - BRANCH REGISTER TO MOVE RTN.  41700013
*                                  CONTENTS OUT - ADDRESS OF MOVE RTN.  42000013
         SPACE 2                                                        42300013
*START OF MODULE CODE PROPER:                                           42600013
         SPACE 2                                                        42900013
IERRDG   CSECT                                                          43200013
         USING *,RL                                                     43500013
         USING IERRCA,RN                                                43800013
IERDD1   B     RDGOLAY             GO TO OVERLAY EXITS                  44100013
         B     RDGEOF              GO TO EOF ROUTINE                    44400013
RDGBEGIN CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  44700013
         BL    RDGNORM             NO FIT SWITCH OFF                    45000013
         BH    RDGSPEC             NO. OF BINS=0 DURING FILL            45300013
         SR    RE,RE                                                    45600013
         A     RE,PPIBDSVA+8                                            45900013
         BZ    RDGNOFIT                                                 46200013
         L     RA,WSAVE                                                 46500013
         L     RE,WSAVE+4                                               46800013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 47100013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                47400013
         ST    RD,0(RC)            INSERT CHAIN ADDRESS                 47700013
         L     RB,KEIGHT           INDICATE DEBLOCK WITH NOFIT PREV     48000013
RDGBINS  L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          48300013
         L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             48600013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               48900013
         SPACE 2                                                        49200013
         B     RDGNOTF             RECORD DIDN'T FIT                    49500013
         SPACE                                                          49800013
*  RECORD FIT ROUTINE                                                   50100013
         SPACE                                                          50400013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  50700013
         BC    7,RDGUSUAL          LAST MOVE WAS NOT A NO FIT           51000013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       51300013
         SR    RC,RC                                                    51600013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     51900013
         B     RDGUSUAL+4          RD ALREADY LOADED                    52200013
RDGUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RECORD JUST MOVED       52500013
         AH    RD,EXPLFOUR         ADD EXT SIZE + 4                     52800013
         L     RC,ADRHOLD          LOAD BUFFER ADDRESS                  53100013
         L     RE,PPIBDSVA+8                                            53400013
         SR    RE,RB                                                    53700013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     54000013
         L     RE,0(RF)                                                 54300013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         54600013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               54900013
         L     RL,PPINET+4                                              55200013
RDGFIT   B     4(RL)               EXIT TO SORT ON RECORD FIT CONDITION 55500013
         SPACE 2                                                        55800013
*  RECORD NOFIT ROUTINE                                                 56100013
         SPACE                                                          56400013
RDGNOTF  ST    RA,WSAVE                                                 56700013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              57000013
         SR    RD,RD                                                    57300013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         57600013
         OI    NOFITSW,X'01'                                            57900013
         A     RD,WSAVAIL                                               58200013
         BC    7,RDGNOFIT         SECOND NOFIT ON SAME RECORD           58500013
         L     RD,PPIBDSVA+4                                            58800013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      59100013
RDGNOFIT L     RL,PPINET+4                                              59400013
         B     24(RL)              EXIT TO SORT ON RECORD NO FIT        59700013
         SPACE 2                                                        60000013
RDGNORM  LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 60400019
         GET   (1),(0)                                           A26453 60800019
         SPACE 2                                                        61200013
RDGGOT   ST    RB,ADRHOLD          SAVE ADDRESS OF RECORD               61500013
         L     RE,PPICOUNT                                              61800013
         LA    RE,1(RE)                                                 62100013
         ST    RE,PPICOUNT         ADD ONE TO RECORD COUNT              62400013
         LR    RE,RB               SET UP BUFFER ADDRESS FOR MOVE RTN   62700013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     63000013
         SR    RD,RD                                                    63300013
         A     RD,PPIBDSVA+8                                            63600013
         BC    7,RDGMOVE           BRANCH UNLESS BIN COUNT=0            63900013
         OI    NOFITSW,X'03'                                            64200013
         B     RDGNOFIT            SPECIAL NO FIT CONDITION             64500013
         SPACE 2                                                        64800013
*  OVERLAY EXITS TO REPLACEMENT - CHANGE FROM FILLING TO NORMAL         65100013
         SPACE                                                          65400013
RDGOLAY  LA    RE,12(0)                                                 65700013
         STC   RE,RDGFIT+3         OVERLAY EXIT TO SORT-RECORD FIT      66000013
         LA    RE,28(0)                                                 66300013
         STC   RE,RDGNORM-1        OVERLAY EXIT TO SORT-RECORD NO FIT   66600013
         B     RDGBEGIN            BRANCH TO NORMAL ENTRY               66900013
         SPACE 2                                                        67200013
*  EOF - SET UP UNCONDITIONAL RETURN TO REPLACEMENT FOR FUTURE USE      67500013
         SPACE                                                          67800013
RDGEOF   MVC   RDGBEGIN(4),RDGFIT-4                                     68100013
         MVC   RDGBEGIN+4(4),KBRANCH    OVERLAY ENTRY WITH UNCOND EXIT  68400013
         L     RL,PPINET+4                                              68700013
         B     8(RL)               ONE TIME EXIT AT EOF                 69000013
         SPACE 2                                                        69300013
RDGSPEC  SR    RE,RE                                                    69600013
         A     RE,PPIBDSVA+8                                            69900013
         BZ    RDGNOFIT                                                 70200013
         NI    NOFITSW,X'00'       ZERO NOFITSW - SPEC CONDITION        70500013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE             70800013
         L     RE,ADRHOLD          LOAD BUFFER ADR                      71100013
RDGMOVE  L     RF,PPIBDSVA+4                                            71400013
         AH    RF,EXPLFOUR         ADD EXT SIZE + 4 TO AVAIL ADR        71700013
         B     RDGBINS+4           CONTINUE PREP FOR MOVE               72000013
         SPACE 2                                                        72300013
         SPACE 2                                                        72600013
KBRANCH  B     16(RL)                                                   72900013
NOFITSW  DC    X'00'                                                    73200013
ADRHOLD  DC    F'0'                                                     73500013
KEIGHT   DC    F'8'                                                     73800013
WSAVE    DC    3F'0'                                                    74100013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADR         74400013
EXPLFOUR DC    H'0'                EXTRACT SIZE + 4                     74700013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 74800019
         SMPPI                                                          75000013
         END                                                            75300013
