         TITLE '      IERRDP - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRDP ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION:                                                       02100013
*   OSCL/2314 SORT DEBLOCK FOR FIXED LENGTH RECORDS W/O USER EXIT E15.  02400013
*   THE FUNCTION OF THIS MODULE IS TO HANDLE FIXED LENGTH RECORDS USING 02700013
*   THE GET LOCATE MACRO. THERE IS NO DATA CHAINING. SORT RECORD LENGTH 03000013
*   IS LESS THAN OR EQUAL TO 256 BYTES, SO THIS MODULE CONTAINS ONE     03300013
*   IN-LINE MOVE INSTRUCTION TO MOVE THE RECORD INTO RSA. THIS MODULE   03600013
*   HANDLES UP TO 5 NON-CONTIGUOUS RSA'S. THE MODULE THEN PASSES TO     03900013
*   THE REPLACEMENT NETWORK THE RECORD,S LOCATION IN RSA.               04200013
         SPACE 1                                                        04500013
*   INITIALLY FLOW IS BETWEEN DEBLOCK AND THE REPLACEMENT NTWK. AFTER   04800013
*   G RECORDS ARE IN RSA THE NTWK RETURNS TO DEBLOCK FOR THE G+1 RCD TO 05100013
*   FORCE A WINNER AND ALLOW DEBLOCK TO MODIFY ITSELF FOR NORMAL FLOW.  05400013
*   WHEN DEBLOCK RETURNS TO THE NTWK WITH THE G+1 RECORD A WINNER IS    05700013
*   GIVEN TO BLOCK. THE NORMAL FLOW THEN IS  DEBLOCK-NTWK-BLOCK. AT EOF 06000013
*   OR ON THE (M-1)TH SEQUENCE OR WHEN RMAX (= THE MAXIMUM RECORDS B&G  06300013
*   HAS DECIDED CAN BE CONTAINED ON ONE REEL OF TAPE) HAS BEEN REACHED, 06600013
*   DEBLOCK IS MODIFIED TO BRANCH DIRECTLY TO THE NETWORK AS SOON AS    06900013
*   IT IS ENTERED BY BLOCK SO THAT THE TREE MAY BE FLUSHED.             07200013
         SPACE 1                                                        07500013
*   SINCE RSA MUST BE REFILLED, THE ROUTINE ALSO HAS A REINITIALIZATION 07800013
*   ENTRY WITH WHICH IT REINITIALIZES ITSELF TO BEGIN FILLING THE TREE  08100013
*   AGAIN.                                                              08400013
         SPACE 1                                                        08700013
*   IF THE 2314 TECH. IS USED, THE RMAX CHECK AT RDP1035 IS BYPASSED.   09000013
*   THIS BECOMES AN UNCONDITIONAL BRANCH TO RDP1030 -2                  09300013
         SPACE 2                                                        09600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               09900013
         SPACE 1                                                        10200013
*   IERADP                                                              10500013
         SPACE 2                                                        10800013
*LIST OF MACROS USED BY MODULE:                                         11100013
         SPACE 1                                                        11400013
*   SMPPI                                                               11700013
*   GET                                                                 12000013
         SPACE 2                                                        12300013
*ENTRY POINTS:                                                          12600013
*                                    CALLING SEQUENCE-                  12900013
         SPACE 1                                                        13200013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   13500013
*                                      L    RL,PPIDEB+4                 13800013
*                                      B    0(RL)      AFTER G RCDS     14100013
*                                      B    8(RL)      FILL TREE        14400013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       14700013
*                                    CALLING SEQUENCE-                  15000013
*                                    CALLING SEQUENCE-                  15300013
*   FROM  BLOCK,ALGORITHM          ENTRY FROM:BLOCK OR ALGORITHM        15600013
*                                      L    RL,PPIDEB+4                 15900013
*                                    CALLING SEQUENCE-                  16200013
*                                      L    RL,PPIDEB+4                 16500013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 16800013
*   FROM INITIALIZATION ROUTINE    ENTRY FROM: INITILIZATION ROUTINE    17100013
*                                    CALLING SEQUENCE-                  17400013
*                                      L     RL,PPIDEB+4                17700013
*                                      B     12(RL)                     18000013
*   FROM GET                       ENTRY FROM:GET                       18300013
*                                    CALLING SEQUENCE-                  18600013
*                                      BR   14         RETURN REG       18900013
         SPACE 2                                                        19200013
*INPUT: - PPI FIELDS REFERENCED                                         19500013
         SPACE 1                                                        19800013
*   PPINET                                                              20100013
*   PPIBINSZ                                                            20400013
*   PPIRMAX                                                             20700013
         SPACE 1                                                        21000013
*   ADDRESS OF NTWK, SIZE OF A BIN IN RSA.                              21300013
         SPACE 2                                                        21600013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            21900013
         SPACE 1                                                        22200013
*   PPICOUNT                                                            22500013
*   PPISW1                                                              22800013
         SPACE 1                                                        23100013
*   UPDATE RECORD COUNTER                                               23400013
         SPACE 2                                                        23700013
*EXTERNAL ROUTINES:                                                     24000013
         SPACE 1                                                        24300013
*   NONE                                                                24600013
         SPACE 2                                                        24900013
*EXTERNAL PARAMETERS                                                    25200013
         SPACE 1                                                        25500013
*   SEE REGISTERS                                                       25800013
         SPACE 2                                                        26100013
*EXITS-NORMAL                                                           26400013
         SPACE 1                                                        26700013
*   TO NETWORK                     EXIT TO:NETWORK                      27000013
*                                    CALLING SEQUENCE-                  27300013
*                                      L    RL,PPINET+4                 27600013
*                                      B    4(RL)      FILL TREE        27900013
*                                      B    8(RL)      ON EOF           28200013
*                                      B    12(RL)     NORMAL           28500013
*                                      B    16(RL)     FLUSH TREE       28800013
*   TO GET                         EXIT TO:GET                          29100013
*                                    CALLING SEQUENCE-                  29400013
*                                      GET(RG)                          29700013
         SPACE 2                                                        30000013
*EXITS-ERROR:                                                           30300013
         SPACE 1                                                        30600013
*   NONE                                                                30900013
         SPACE 2                                                        31200013
*TABLES/WORK AREAS:                                                     31500013
         SPACE 1                                                        31800013
*   TABLRSA-TABLE CONSISTING OF UP TO 5 NON-CONTIGUOUS RSA AREA ENTRIES 32100013
*   WITH  8 BYTE ENTRIES FOR EACH RSA AREA.                             32400013
*   WADDRESS - ADDRESS OF RECORD WHICH LAST 'GET' RETURNED IN RB        32700013
*   WRMAX - COUNT OF RECORDS USED TO COMPARE WITH PPIRMAX               33000013
*   WADDRSA - UPDATED ADDRESS OF NEXT FREE AREA IN RSA                  33300013
*   WBYTECNT - COUNT OF REMAINING BYTES IN THIS RSA CHUNK               33600013
         SPACE 2                                                        33900013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   34200013
         SPACE 2                                                        34500013
*NOTES: THIS MODULE WILL EXECUTE FOR FIXED LENGTH SORTS HAVING RECORD   34800013
*   LENGTHS LESS THAN OR EQUAL TO 256 BYTES AND W/O EXITS E15 OR E16    35100013
         EJECT                                                          35400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            35700013
         SPACE 1                                                        36000013
RA       EQU   0                   CONTENTS IN- N/A                     36300013
*                                  USE- NOT USED                        36600013
*                                  CONTENTS OUT- N/A                    36900013
RB       EQU   1                   CONTENTS IN- N/A                     37200013
*                                  USE- GET TO DEBLK(ADDR OF RCD IN     37500013
*                                    INPUT BUFFER)                      37800013
*                                  CONTENTS OUT- N/A                    38100013
RC       EQU   2                   CONTENTS IN- N/A                     38400013
*                                  USE- LOAD ADDR OF RCD IN INPUT BFR   38700013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  39000013
*                                    RCD IN INPUT BFR)                  39300013
RD       EQU   3                   CONTENTS IN- BLOCK TO DEBLK(ADDR OF  39600013
*                                    A FREE AREA IN RSA)                39900013
*                                  USE- LOAD ADDR OF AREA IN THE RSA    40200013
*                                    BIN TO MOVE THE NEXT INPUT RCD     40500013
*                                  CONTENTS OUT- DEBLOCK TO NTWK(ADDR   40800013
*                                    OF THE RCD IN RSA)                 41100013
RE       EQU   4                   CONTENTS IN- N/A                     41400013
*                                  USE- REMAINING BYTE COUNT OF THE RSA 41700013
*                                    WE ARE WORKING WITH                42000013
*                                  CONTENTS OUT- N/A                    42300013
RF       EQU   5                   CONTENTS IN- N/A                     42600013
*                                  USE- WORK REGISTER                   42900013
*                                  CONTENTS OUT- N/A                    43200013
RG       EQU   6                   CONTENTS IN- N/A                     43500013
*                                  USE- WORK REGISTER                   43800013
*                                     - ADDR OF INPUT DCB FOR GET       44100013
*                                  CONTENTS OUT- N/A                    44400013
RH       EQU   7                   CONTENTS IN- N/A                     44700013
*                                  USE- ADDR OF THE RSA TABLE ENTRY     45000013
*                                    WE ARE WORKING WITH                45300013
*                                  CONTENTS OUT- N/A                    45600013
RI       EQU   8                   CONTENTS IN- N/A                     45900013
*                                  USE- NOT USED                        46200013
*                                  CONTENTS OUT- N/A                    46500013
RJ       EQU   9                   CONTENTS IN- N/A                     46800013
*                                  USE- NOT USED                        47100013
*                                  CONTENTS OUT- N/A                    47400013
RK       EQU   10                  CONTENTS IN- N/A                     47700013
*                                  USE- NOT USED                        48000013
*                                  CONTENTS OUT- N/A                    48300013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    48600013
*                                  USE-MODULE BASE REGISTER             48900013
*                                  CONTENTS OUT- ENTRY PT OF NTWK       49200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   49500013
*                                  USE- NOT USED                        49800013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   50100013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              50400013
*                                  USE-PPI REFERENCES,REG SAVE AREA     50700013
*                                  CONTENTS OUT-ADDR OF PPI             51000013
RO       EQU   14                  CONTENTS IN- N/A                     51300013
*                                  USE- RETURN REG FROM GET             51600013
*                                  CONTENTS OUT- N/A                    51900013
RP       EQU   15                  CONTENTS IN- N/A                     52200013
*                                  USE- BRANCH REG TO GET               52500013
*                                  CONTENTS OUT- N/A                    52800013
         SPACE 2                                                        53100013
*START OF MODULE CODE PROPER:                                           53400013
         SPACE 2                                                        53700013
IERRDP   CSECT                                                          54000013
         USING *,RL                THIS MODULE BASE REG                 54300013
         USING IERRCA,RN           PPI ADDR                             54600013
IERDD1   B     RDP1050             ENTRY FROM SORT NETWORK. G RECORDS   54900013
*                                    ARE IN THE TREE(ONCE ONLY)         55200013
         B     RDP1060             ENTRY FROM EOF ROUTINE               55500013
         B     RDP1010             NORMAL ENTRY WHILE FILLING TREE      55800013
*                                   WILL BE OVERLAID BY:                56100013
*                                   B  RDP1020 WHEN RSA HAS BEEN FILLD  56400013
*                                   B  RDP1065 AFTER INPUT EOF          56700013
         SPACE 2                                                        57000013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN FILLING TREE           57300013
         SPACE 1                                                        57600013
         MVC   RDP1040(8),KMOD5    REOVERLAY OVERLAID INSTRUCTIONS      57900013
         MVC   IERDD1+8(4),KMOD2                                        58200013
         L     RH,PPILAB08         LOAD ADDRESS OF RSA PARAM TABLE      58500013
         ST    RH,ADCONPTR         STORE                                58800013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       59100013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   59400013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  59700013
*                                   ONE RECORD LENGTH                   60000013
         L     RB,WADDRESS         LOAD REGISTER FOR MOVE INSTRUCTION   60300013
         L     RD,WADDRSA            TO MOVE SAVED RECORD INTO RSA      60600013
         B     RDP1035             BRANCH TO MOVE RECORD                60900013
         SPACE 2                                                        61200013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  61500013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING                   61800013
         SPACE 1                                                        62100013
RDP1010  L     RD,WADDRSA          LOAD UPDATED ADDRESS OF RSA          62400013
RDP1020  L     RG,KADCB            ADDR OF THE INPUT DCB                62700013
         GET   (RG)                                                     63000013
         SPACE 1                                                        63300013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         63600013
         SPACE 1                                                        63900013
         ST    RB,WADDRESS         SAVE ADDRESS OF RECORD IN BUFFER     64200013
         SPACE 1                                                        64500013
*UPDATE RECORD  COUNTER                                                 64800013
         SPACE 1                                                        65100013
         L     RG,PPICOUNT                                              65400013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  65700013
         ST    RG,PPICOUNT                                              66000013
RDP1035  L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   66300013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   66600013
         ST    RG,WRMAX           SAVE                                  66900013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     67200013
         BH    RDP1055             BRANCH ON YES                        67500013
         SPACE 2                                                        67800013
*        MOVE RECORD FROM INPUT BUFFER TO RSA                           68100013
         SPACE 1                                                        68400013
         LR    RC,RB               LOAD PARAM REG FOR SORT NETWORK      68700013
RDP1030  MVC   0(1,RD),0(RC)       MOVE RCD FROM INPUT BUFFER TO RSA    69000013
*                                    LENGTH SET BY ASSIGNMENT ROUTINE   69300013
         SPACE 2                                                        69600013
*UPDATE RSA TABLE PARAMETERS                                            69900013
         SPACE 1                                                        70200013
RDP1040  LR    RF,RD               WILL BE OVLAYED BY BR TO NETWORK     70500013
*                                    AFTER G+1 RCDS                     70800013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          71100013
         ST    RF,WADDRSA          STORE                                71400013
         L     RE,WBYTECNT         LOAD REMAINING BYTES IN RSA CHUNK    71700013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF NEXT RECORD       72000013
         BM    RDP1045             BRANCH ON MINUS RESULT TO UPDATE PTR 72300013
         ST    RE,WBYTECNT         OTHERWISE STORE                      72600013
         SPACE 1                                                        72900013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       73200013
         SPACE 1                                                        73500013
         L     RL,PPINET+4         ADDR OF NETWORK                      73800013
         B     4(RL)                 BR TO FILL TREE.                   74100013
         SPACE 2                                                        74400013
*UPDATE POINTER TO NEXT RSA TABLE ENTRY(NEXT RSA AREA)                  74700013
         SPACE 1                                                        75000013
RDP1045  L     RH,ADCONPTR         LOAD ADDRESS IN RSA PARAM TABLE      75300013
         LA    RH,8(RH)                UPDATE TO NEXT TABLE ENTRY       75600013
         ST    RH,ADCONPTR             SAVE UPDATED POINTER TO TABLE    75900013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       76200013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   76500013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  76800013
*                                   ONE RECORD LENGTH                   77100013
         L     RL,PPINET+4         ADDRESS OF SORT NETWORK              77400013
         B     4(RL)               BRANCH TO FILL TREE                  77700013
         SPACE 2                                                        78000013
         SPACE 2                                                        78300013
*SORT TREE HAS BEEN FILLED.  THE NEXT DEBLOCKED RECORD IS MOVED TO THE  78600013
*NEXT SPACE IN RSA.  IN ALL SUBSEQUENT ENTRIES TO THIS MODULE, RD WILL  78900013
*POINT TO THE WINNER RECORD IN RSA.  THE DEBLOCKED RECORD MUST BE MOVED 79200013
*TO THE LOCATION INDICATED BY RD. ALSO, THIS MODULE MUST NOW ENTER THE  79500013
*SORT NETWORK AT ITS NORMAL ENTRY POINT.  THE FOLLOWING CODE MODIFIES   79800013
*THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.                          80100013
         SPACE 1                                                        80400013
RDP1050  MVC   IERDD1+8(4),KMOD1   MOCIFY ENTRY BRANCH ADDRESS          80700013
         MVC   RDP1040(8),KMOD3    MODIFY EXIT ADDRESS                  81000013
         B     RDP1010             RETURN TO GET NEXT RECORD            81300013
         SPACE 1                                                        81600013
RDP1055  SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         81900013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   82200013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  82500013
         SPACE 2                                                        82800013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   83100013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      83400013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT ITS    83700013
*EMPTYING ENTRY.  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT 84000013
*TO EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT ITS EOF    84300013
*ENTRY.                                                                 84600013
         SPACE 1                                                        84900013
RDP1060  MVC   IERDD1+8(4),KMOD4   BR DIRECTLY TO SORT NETWORK          85200013
         SPACE 2                                                        85500013
*INTERFACE TO SORT NETWORK ON EOF.                                      85800013
         SPACE 1                                                        86100013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 86400013
         B     8(RL)                                                    86700013
         SPACE 2                                                        87000013
*        INTERFACE TO SORT NETWORK TO FLUSH TREE                        87300013
         SPACE 1                                                        87600013
RDP1065  L     RL,PPINET+4         BRANCH IMMEDIATELY BACK TO NETWORK   87900013
         B     16(RL)                AFTER INPUT EOF                    88200013
         SPACE 2                                                        88500013
*CONSTANTS USED BY THE MODULE:                                          88800013
         SPACE 1                                                        89100013
KMOD1    B     RDP1020             OVERLAY RDP1010 AFTER G+1 RCDS       89400013
KMOD2    B     RDP1010             TO RESTORE NETWORK ENTRY FOR FILLING 89700013
KMOD3    L     RL,PPINET+4         OVERLAY RDP1040 AFTER G+1 RCDS       90000013
         B     12(RL)                NORMAL BRANCH TO NETWORK           90300013
KMOD4    B     RDP1065             RETURN TO NETWORK AFTER INPUT EOF    90600013
KMOD5    LR    RF,RD               TO RESTORE INSTRUCTIONS OVERLAID     90900013
         A     RF,PPIBINSZ           BY BRANCH TO NETWORK AFTER TREE    91200013
         ST    RF,WADDRSA            IS FILLED                          91500013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        91800013
         SPACE 2                                                        92100013
*LIST OF WORK AREAS/TABLES:                                             92400013
         SPACE 1                                                        92700013
WADDRESS DS    F                   ADDRESS OF RECORD FROM LAST 'GET'    93000013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     93300013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               93600013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    93900013
ADCONPTR  DS   F                                                        94200013
         EJECT                                                          94500013
         SMPPI                                                          94800013
         END                                                            95100013
I95400013         LR    RC,RB               LOAD PARAM REG FOR SORT NETWORK
