         TITLE '      IERRDQ - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERRDQ ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION:                                                       02100013
*   OSCL/2314 SORT DEBLOCK FOR FIXED LENGTH RECORDS W/O USER EXIT E15.  02400013
*   THE FUNCTION OF THIS MODULE IS TO HANDLE FIXED LENGTH RECORDS USING 02700013
*   THE GET LOCATE MACRO. THERE IS NO DATA CHAINING. SORT RECORD LENGTH 03000013
*   IS GREATER THAN 256 BYTES SO THIS MODULE BRANCHES TO A MOVE ROUTINE 03300013
*   IN GENERATED CORE TO MOVE THE RECORD INTO RSA. THIS MODULE HANDLES  03600013
*   UP TO 5 NON-CONTIGUOUS RSA'S. THE MODULE PASSES TO THE REPLACEMENT  03900013
*   NETWORK THE RECORD'S LOCATION IN RSA.                               04200013
         SPACE 1                                                        04500013
*   INITIALLY FLOW IS BETWEEN DEBLOCK AND THE REPLACEMENT NETWORK.AFTER 04800013
*   G RECORDS ARE IN RSA THE NTWK RETURNS TO DEBLOCK FOR THE G+1 RCD TO 05100013
*   FORCE THE WINNER OUT OF THE TREE AND ALSO ALLOWING DEBLOCK TO       05400013
*   MODIFY ITSELF FOR NORMAL FLOW. WHEN DEBLOCK RETURNS TO THE NETWORK  05700013
*   WITH THE G+1 RECORD THE WINNER IS GIVEN TO BLOCK BY THE NTWK. THE   06000013
*   NORMAL FLOW THEN IS DEBLOCK-NTWK-BLOCK-DEBLOCK ETC. AT EOF OR ON    06300013
*   THE (M-1)TH SEQUENCE OR WHEN RMAX (= THE MAXIMUM RECORDS B&G HAS    06600013
*   DECIDED CAN BE CONTAINED ON ONE REEL OF TAPE) HAS BEEN REACHED,     06900013
*   DEBLOCK IS MODIFIED TO BRANCH DIRECTLY TO THE NETWORK AS SOON AS    07200013
*   IT IS ENTERED BY BLOCK SO THAT THE TREE MAY BE FLUSHED.             07500013
         SPACE 1                                                        07800013
*   SINCE RSA MUST BE REFILLED, THE ROUTINE ALSO HAS A REINITIALIZATION 08100013
*   ENTRY WITH WHICH IT REINITIALIZES ITSELF TO BEGIN FILLING THE TREE  08400013
*   AGAIN.                                                              08700013
         SPACE 1                                                        09000013
*   IF THE 2314 TECH. IS USED, THE RMAX CHECK AT RDQ1035 IS BYPASSED.   09300013
         SPACE 2                                                        09600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               09900013
         SPACE 1                                                        10200013
*   IERADQ                                                              10500013
         SPACE 2                                                        10800013
*LIST OF MACROS USED BY MODULE:                                         11100013
         SPACE 1                                                        11400013
*   SMPPI                                                               11700013
*   GET                                                                 12000013
         SPACE 2                                                        12300013
*ENTRY POINTS:                                                          12600013
         SPACE 1                                                        12900013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   13200013
*                                    CALLING SEQUENCE-                  13500013
*                                      L    RL,PPIDEB+4                 13800013
*                                      B    0(RL)      AFTER G RCDS     14100013
*                                      B    8(RL)      FILL TREE        14400013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       14700013
*                                    CALLING SEQUENCE-                  15000013
*                                      L    RL,PPIDEB+4                 15300013
*                                      B    4(RL)      EOF              15600013
*   FROM BLOCK,ALGORITHM           ENTRY FROM:BLOCK OR ALGORITHM        15900013
*                                    CALLING SEQUENCE-                  16200013
*                                      L    RL,PPIDEB+4                 16500013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 16800013
*   FROM INITIALIZATION ROUTINE    ENTRY FROM: INITILIZATION ROUTINE    17100013
*                                    CALLING SEQUENCE-                  17400013
*                                      L     RL,PPIDEB+4                17700013
*                                      B     12(RL)                     18000013
*   FROM GET,MOVE RTN              ENTRY FROM:GET OR MOVE RTN           18300013
*                                    CALLING SEQUENCE-                  18600013
*                                      BR   14         RETURN REG       18900013
         SPACE 2                                                        19200013
*INPUT: - PPI FIELDS REFERENCED                                         19500013
         SPACE 1                                                        19800013
*   PPINET                                                              20100013
*   PPIBDSVA                                                            20400013
*   PPIBINSZ                                                            20700013
*   PPIRMAX                                                             21000013
         SPACE 1                                                        21300013
*   ADDRESS OF NETWORK,MOVE ROUTINE. SIZE OF A BIN USED TO UPDATE RSA   21600013
*   POINTER.                                                            21900013
         SPACE 2                                                        22200013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            22500013
         SPACE 1                                                        22800013
*   PPICOUNT                                                            23100013
*   PPISW1                                                              23400013
         SPACE 1                                                        23700013
*   UPDATE RECORD COUNTER                                               24000013
         SPACE 2                                                        24300013
*EXTERNAL ROUTINES:                                                     24600013
         SPACE 1                                                        24900013
*   MOVE ROUTINE IN GENERATED CORE TO MOVE RCD FROM INPUT BUFFER TO RSA 25200013
         SPACE 2                                                        25500013
*EXTERNAL PARAMETERS                                                    25800013
         SPACE 1                                                        26100013
*   SEE REGISTERS                                                       26400013
         SPACE 2                                                        26700013
*EXITS-NORMAL                                                           27000013
         SPACE 1                                                        27300013
*   TO NETWORK                     EXIT TO:NETWORK                      27600013
*                                    CALLING SEQUENCE-                  27900013
*                                      L    RL,PPINET+4                 28200013
*                                      B    4(RL)      FILL TREE        28500013
*                                      B    8(RL)      ON INPUT EOF     28800013
*                                      B    12(RL)     NORMAL RUNNING   29100013
*                                      B    16(RL)     FLUSH TREE       29400013
*   TO GET                         EXIT TO:GET                          29700013
*                                    CALLING SEQUENCE-                  30000013
*                                      GET(RG)                          30300013
*   TO MOVE RTN                    EXIT TO:MOVE RTN                     30600013
*                                    CALLING SEQUENCE-                  30900013
*                                      L    RP,PPIBDSVA+4 MOVE RTN ADDR 31200013
*                                      BALR RO,RP                       31500013
         SPACE 2                                                        31800013
*EXITS-ERROR:                                                           32100013
         SPACE 1                                                        32400013
*   NONE                                                                32700013
         SPACE 2                                                        33000013
*TABLES/WORK AREAS:                                                     33300013
         SPACE 1                                                        33600013
*   TABLRSA-TABLE CONSISTING OF UP TO 5 ENTRIES . AN 8 BYTE ENTRY FOR   33900013
*     EACH NON-CONTIGUOUS RSA.                                          34200013
*   WADDRESS - ADDRESS OF RECORD WHICH LAST 'GET' RETURNED IN RB        34500013
*   WRMAX - COUNT OF RECORDS USED TO COMPARE WITH PPIRMAX               34800013
*   WADDRSA - UPDATED ADDRESS OF NEXT FREE AREA IN RSA                  35100013
*   WBYTECNT - COUNT OF REMAINING BYTES IN THIS RSA CHUNK               35400013
         SPACE 2                                                        35700013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   36000013
         SPACE 2                                                        36300013
*NOTES: THIS MODULE WILL EXECUTE FOR FIXED LENGTH SORTS HAVING RECORD   36600013
*   LENGTHS GREATER THAN 256 BYTES AND W/O EXITS E15 OR E16             36900013
         EJECT                                                          37200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            37500013
         SPACE 1                                                        37800013
RA       EQU   0                   CONTENTS IN- N/A                     38100013
*                                  USE- NOT USED                        38400013
*                                  CONTENTS OUT- N/A                    38700013
RB       EQU   1                   CONTENTS IN- N/A                     39000013
*                                  USE- GET TO DEBLK(ADDR OF RCD IN     39300013
*                                    INPUT BUFFER)                      39600013
*                                  CONTENTS OUT- N/A                    39900013
RC       EQU   2                   CONTENTS IN- N/A                     40200013
*                                  USE- ADDR OF RCD IN INPUT BUFFER     40500013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  40800013
*                                    RCD IN INPUT BFR)                  41100013
RD       EQU   3                   CONTENTS IN- BLOCK TO DEBLK(ADDR OF  41400013
*                                    A FREE AREA IN RSA)                41700013
*                                  USE- ADDR OF WHERE TO PUT RCD IN RSA 42000013
*                                    BIN                                42300013
*                                  CONTENTS OUT- DEBLK TO NTWK(ADDR OF  42600013
*                                    THE RCD IN RSA)                    42900013
RE       EQU   4                   CONTENTS IN- N/A                     43200013
*                                  USE- ADDR OF RCD IN INPUT BFR FOR    43500013
*                                    MOVE RTN                           43800013
*                                  CONTENTS OUT- N/A                    44100013
RF       EQU   5                   CONTENTS IN- N/A                     44400013
*                                  USE- ADDR OF AREA IN RSA TO MOVE THE 44700013
*                                    RCD FOR MOVE RTN                   45000013
*                                  CONTENTS OUT- N/A                    45300013
RG       EQU   6                   CONTENTS IN- N/A                     45600013
*                                  USE- ADDR OF INPUT DCB FOR GET       45900013
*                                     - WORK REGISTER                   46200013
*                                  CONTENTS OUT- N/A                    46500013
RH       EQU   7                   CONTENTS IN- N/A                     46800013
*                                  USE- ADDR OF THE RSA TABLE ENTRY WE  47100013
*                                    ARE WORKING WITH                   47400013
*                                  CONTENTS OUT- N/A                    47700013
RI       EQU   8                   CONTENTS IN- N/A                     48000013
*                                  USE- REMAING BYTE CNT OF RSA WE      48300013
*                                    ARE WORKING WITH                   48600013
*                                  CONTENTS OUT- N/A                    48900013
RJ       EQU   9                   CONTENTS IN- N/A                     49200013
*                                  USE- NOT USED                        49500013
*                                  CONTENTS OUT- N/A                    49800013
RK       EQU   10                  CONTENTS IN- N/A                     50100013
*                                  USE- NOT USED                        50400013
*                                  CONTENTS OUT- N/A                    50700013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    51000013
*                                  USE-MODULE BASE REGISTER             51300013
*                                  CONTENTS OUT- ENTRY PT OF NTWK       51600013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   51900013
*                                  USE- NOT USED                        52200013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   52500013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              52800013
*                                  USE-PPI REFERENCES,REG SAVE AREA     53100013
*                                  CONTENTS OUT-ADDR OF PPI             53400013
RO       EQU   14                  CONTENTS IN- N/A                     53700013
*                                  USE- RETURN REG FROM GET             54000013
*                                     - RETURN REG FROM MOVE RTN        54300013
*                                  CONTENTS OUT- N/A                    54600013
RP       EQU   15                  CONTENTS IN- N/A                     54900013
*                                  USE- BRANCH REG TO GET               55200013
*                                     - BRANCH REG TO MOVE RTN          55500013
*                                  CONTENTS OUT- N/A                    55800013
         SPACE 2                                                        56100013
*START OF MODULE CODE PROPER:                                           56400013
         SPACE 2                                                        56700013
IERRDQ   CSECT                                                          57000013
         USING *,RL                THIS MODULE BASE REGISTER            57300013
         USING IERRCA,RN                                                57600013
IERDD1   B     RDQ1050             ENTRY FROM SORT NETWORK. G RECORDS   57900013
*                                    ARE IN THE TREE(ONCE ONLY)         58200013
         B     RDQ1060             ENTRY FROM EOF ROUTINE               58500013
         B     RDQ1010             NORMAL ENTRY WHILE FILLING TREE      58800013
*                                   WILL BE OVERLAID BY:                59100013
*                                   B  RDQ1020 WHEN RSA HAS BEEN FILLD  59400013
*                                   B  RDQ1065 AFTER INPUT EOF          59700013
         SPACE 2                                                        60000013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN FILLING TREE           60300013
         SPACE 1                                                        60600013
         MVC   RDQ1040(8),KMOD5    REOVERLAY OVERLAID INSTRUCTIONS      60900013
         MVC   IERDD1+8(4),KMOD2                                        61200013
         L     RH,PPILAB08         LOAD ADDRESS OF RSA PARAM TABLE      61500013
         ST    RH,ADCONPTR         STORE                                61800013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       62100013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   62400013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  62700013
*                                   ONE RECORD LENGTH                   63000013
         L     RB,WADDRESS         LOAD REGISTER FOR MOVE INSTRUCTION   63300013
         LR    RC,RB               INITIALIZE RC IN CASE OF EXTRACT     63600013
         L     RD,WADDRSA            TO MOVE SAVED RECORD INTO RSA      63900013
         B     RDQ1035             BRANCH TO MOVE RECORD                64200013
         SPACE 2                                                        64500013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  64800013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING.                  65100013
         SPACE 1                                                        65400013
RDQ1010  L     RD,WADDRSA          LOAD UPDATED ADDRESS OF RSA          65700013
RDQ1020  L     RG,KADCB            ADDR OF THE INPUT DCB                66000013
         GET   (RG)                                                     66300013
         SPACE 1                                                        66600013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         66900013
         SPACE 1                                                        67200013
         ST    RB,WADDRESS         SAVE ADDRESS OF RECORD IN BUFFER     67500013
         LR    RC,RB              INITIALIZE RC IN CASE OF EXTRACT      67800013
         SPACE 2                                                        68100013
*        UPDATE RECORD COUNTER                                          68400013
         SPACE 1                                                        68700013
         L     RG,PPICOUNT                                              69000013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  69300013
         ST    RG,PPICOUNT                                              69600013
RDQ1035  L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   69900013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   70200013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     70500013
         BH    RDQ1055             BRANCH ON YES                        70800013
         ST    RG,WRMAX            SAVE                                 71100013
         SPACE 2                                                        71400013
*LINK TO MOVE LIST WHICH MOVES THE RECORD FROM THE INPUT BUFFER TO RSA. 71700013
*INPUT BUFFER RCD ADDRESS IN RE. RSA RCD ADDRESS IN RF.                 72000013
         SPACE 1                                                        72300013
         LR    RF,RD               ADDRESS IN RSA TO MOVE INPUT RCD     72600013
         LR    RE,RB               INPUT RECORD ADDRESS                 72900013
         L     RP,PPIBDSVA+4       ADDRESS OF MOVE LIST                 73200013
         BALR  RO,RP                                                    73500013
         SPACE 2                                                        73800013
*UPDATE RSA TABLE PARAMETERS                                            74100013
         SPACE 1                                                        74400013
RDQ1040  LR    RF,RD               ADDR OF RCD IN RSA. WILL BE OVLAYED  74700013
*                                    BY BR TO NETWORK AFTER G+1 RCDS.   75000013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          75300013
         ST    RF,WADDRSA          STORE                                75600013
         L     RE,WBYTECNT         LOAD REMAINING BYTES IN RSA CHUNK    75900013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF NEXT RECORD       76200013
         BM    RDQ1045             BRANCH ON MINUS RESULT TO UPDATE PTR 76500013
         ST    RE,WBYTECNT         OTHERWISE STORE                      76800013
         SPACE 1                                                        77100013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       77400013
         SPACE 1                                                        77700013
         L     RL,PPINET+4         ADDR OF NETWORK                      78000013
         B     4(RL)               BR TO FILL TREE                      78300013
         SPACE 2                                                        78600013
*UPDATE POINTER TO NEXT ENTRY IN RSA TABLE(EQUALS NEXT RSA AREA)        78900013
         SPACE 1                                                        79200013
RDQ1045  L     RH,ADCONPTR         LOAD ADDRESS IN RSA PARAM TABLE      79500013
         LA    RH,8(RH)                UPDATE TO NEXT TABLE ENTRY       79800013
         ST    RH,ADCONPTR             SAVE UPDATED POINTER TO TABLE    80100013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       80400013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   80700013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  81000013
*                                   ONE RECORD LENGTH                   81300013
         L     RL,PPINET+4         ADDRESS OF SORT NETWORK              81600013
         B     4(RL)               BRANCH TO FILL TREE                  81900013
         SPACE 2                                                        82200013
*SORT TREE HAS BEEN FILLED.  IN FUTURE ENTRIES TO THIS MODULE, RD WILL  82500013
*POINT TO THE WINNER RECORD IN RSA.  THE NEW RECORD WHICH HAS BEEN      82800013
*DEBLOCKED MUST BE MOVED TO THE LOCATION IN RSA INDICATED BY RD.  ALSO, 83100013
*THIS MODULE MUST NOW ENTER THE SORT NETWORK AT 12(RL).       THE       83400013
*FOLLOWING CODE MODIFIES THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.  83700013
         SPACE 1                                                        84000013
RDQ1050  MVC   IERDD1+8(4),KMOD1   MOCIFY ENTRY BRANCH ADDRESS          84300013
         MVC   RDQ1040(8),KMOD3    MODIFY EXIT ADDRESS                  84600013
         B     RDQ1010             RETURN TO GET NEXT RECORD            84900013
         SPACE 1                                                        85200013
RDQ1055  SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         85500013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   85800013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  86100013
         SPACE 2                                                        86400013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   86700013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      87000013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT        87300013
*16(RL).  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT TO      87600013
*EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT 8(RL), THE    87900013
*EOF ENTRY.                                                             88200013
         SPACE 1                                                        88500013
RDQ1060  MVC   IERDD1+8(4),KMOD4   BR DIRECTLY TO SORT NETWORK          88800013
         SPACE 2                                                        89100013
*INTERFACE TO SORT NETWORK ON EOF.                                      89400013
         SPACE 1                                                        89700013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 90000013
         B     8(RL)                                                    90300013
         SPACE 2                                                        90600013
*        INTERFACE TO SORT NETWORK TO FLUSH TREE                        90900013
         SPACE 1                                                        91200013
RDQ1065  L     RL,PPINET+4         BRANCH IMMEDIATELY BACK TO NETWORK   91500013
         B     16(RL)                AFTER INPUT EOF                    91800013
         SPACE 2                                                        92100013
*CONSTANTS USED BY THE MODULE:                                          92400013
         SPACE 1                                                        92700013
KMOD1    B     RDQ1020             OVERLAY RDQ1010 AFTER G+1 RCDS       93000013
KMOD2    B     RDQ1010             TO RESTORE NETWORK ENTRY FOR FILLING 93300013
KMOD3    L     RL,PPINET+4         OVERLAY RDQ1040 AFTER G+1 RCDS       93600013
         B     12(RL)                NORMAL BR TO THE NETWORK           93900013
KMOD4    B     RDQ1065                                                  94200013
KMOD5    LR    RF,RD               TO RESTORE INSTRUCTIONS OVERLAID     94500013
         A     RF,PPIBINSZ           BY BRANCH TO NETWORK AFTER TREE    94800013
         ST    RF,WADDRSA            IS FILLED                          95100013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        95400013
         SPACE 2                                                        95700013
*LIST OF WORK AREAS/TABLES:                                             96000013
         SPACE 1                                                        96300013
WADDRESS DS    F                   ADDRESS OF RECORD FROM LAST 'GET'    96600013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     96900013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               97200013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    97500013
ADCONPTR  DS   F                                                        97800013
         EJECT                                                          98100013
         SMPPI                                                          98400013
         END                                                            98700013
