         TITLE 'IERRDR - OS/360 SORT/MERGE - 360-2M 23  5111166'        00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERRDR ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION:                                                       00700013
*   THIS IS AN OSCL/2314 SORT PH RTN FOR F.L. RCDS W/ E15 AND/OR E16.   00800013
*   THE FUNCTION OF THIS MODULE IS TO DEBLOCK FIXED LGTH RCDS USING THE 00900013
*   GET MACRO AND CONTAINS LINKAGE TO THE USER MODIFICATION PROGRAMS    01000013
*   VIA THE CALL MACRO EXPANSION INSTRUCTIONS.                          01100013
*   THE INPUT RECORDS ARE LOCATED IN AN INPUT BUFFER. BEFORE MOVING THE 01200013
*   RECORD TO THE WORK AREA CALLED RSA, RECORD STORAGE AREA, THE MODULE 01300013
*   BRANCHES TO THE USER RTN WHO MAY 1.DELETE, 2.INSERT, OR 3.ALTER,    01400013
*   LENGTHEN, SHORTEN, OR DO NOTHING TO THE RECORD. THE ADDRESS OF      01500013
*   THE RECORD IN THE INPUT AREA IS PASSED TO THE USER.  THE USER       01600013
*   RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS.               01700013
         SPACE 1                                                        01800013
*   THIS MODULE KEEPS TRACK OF THE MAXIMUM AMOUNT OF RECORDS THAT THE   01900013
*   SORT CAN HANDLE AT ANY ONE TIME,NMAX. IT CHECKS TO SEE IF NMAX IS   02000013
*   REACHED, AND WHEN IT IS REACHED IT BRANCHES TO THE USER WHO MAY     02100013
*   1. SORT CURRENT NO, 2.IGNORE NMAX, 3.ABORT THE JOB.  THE USER       02200013
*   RETURNS VIA BRANCHREG AND PROPER DISPLACEMENTS.                     02300013
         SPACE 1                                                        02400013
*   THE MODULE ALSO KEEPS TRACK OF RMAX (= THE MAXIMUM NUMBER OF        02500013
*   RECORDS WHICH B&G HAS DECIDED WILL FIT ON ONE REEL OF TAPE) AND     02600013
*   CAUSES THE FLUSHING OF RSA AND A MERGE TO FILL ONE REEL, WHICH IS   02700013
*   THEN SET ASIDE.                                                     02800013
         SPACE 1                                                        02900013
*   THE MODULE MOVES THE RECORD TO RSA AND PASSES THE RECORD'S LOCATION 03000013
*   IN RSA TO THE REPLACEMENT SORT. THIS MODULE HANDLES UP TO 5 NON-    03100013
*   CONTIGUOUS RSA AREAS.                                               03200013
         SPACE 1                                                        03300013
*   THIS ROUTINE HAS A REINITIALIZATION ENTRY THRU WHICH IT CAN         03400013
*   REINITIALIZE ITSELF TO BEGIN REFILLING RSA AFTER A MERGE HAS TAKEN  03500013
*   PLACE.                                                              03600013
         SPACE 1                                                        03700013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      03800013
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET.                       03900013
         SPACE 1                                                        04000013
*   IF THE 2314 TECH. IS USED, THE RMAX CHECK AT RDRMXCNT IS BYPASSED.  04100013
*   THIS BECOMES AN UNCONDITIONAL BRANCH TO RDOVLAY5.                   04200013
         SPACE 2                                                        04300013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04400013
         SPACE 1                                                        04500013
*   IERADR                                                              04600013
         SPACE 2                                                        04700013
*LIST OF MACROS USED BY MODULE:                                         04800013
         SPACE 1                                                        04900013
*   SMPPI                                                               05000013
*   GET                                                                 05100013
         SPACE 2                                                        05200013
*ENTRY POINTS:                                                          05300013
         SPACE 1                                                        05400013
*   FROM NETWORK                   ENTRY FROM:NETWORK                   05500013
*                                    CALLING SEQUENCE-                  05600013
*                                      L    RL,PPIDEB+4                 05700013
*                                      B    0(RL)      AFTER G RCDS     05800013
*                                      B    8(RL)      FILL TREE        05900013
*   FROM END OF FILE RTN           ENTRY FROM:EOF                       06000013
*                                    CALLING SEQUENCE-                  06100013
*                                      L    RL,PPIDEB+4                 06200013
*                                      B    4(RL)      EOF              06300013
*   FROM BLOCK,ALGORITHM           ENTRY FROM:BLOCK OR ALGORITHM        06400013
*                                    CALLING SEQUENCE-                  06500013
*                                      L    RL,PPIDEB+4                 06600013
*                                      B    8(RL)      BLK=NRML,ALG=EOS 06700013
*   FROM INITIALIZATION ROUTINE    ENTRY FROM: INITILIZATION ROUTINE    06800013
*                                    CALLING SEQUENCE-                  06900013
*                                      L     RL,PPIDEB+4                07000013
*                                      B     12(RL)                     07100013
*   FROM GET,MOVE RTN,EXITS,SSC    ENTRY FROM:GET,MOVE RTN,E15,E16,SSC  07200013
*                                    CALLING SEQUENCE-                  07300013
*                                      BR   14         RETURN REG       07400013
         SPACE 2                                                        07500013
*INPUT: - PPI FIELDS REFERENCED                                         07600013
         SPACE 1                                                        07700013
*   PPINET     PPIADSSC   PPIX16                                        07800013
*   PPIBDSVA   PPISW1     PPIRMA                                        07900013
*   PPIBINSZ   PPIX15     PPIRMAX                                       08000013
         SPACE 1                                                        08100013
*   ADDR OF NETWORK,MOVE RTN,EXITS,SORT SYSTEM CONTROL,MESSAGE MODULE,  08200013
*   AND BINSIZE TO UPDATE RSA POINTER.                                  08300013
         SPACE 2                                                        08400013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            08500013
         SPACE 1                                                        08600013
*   PPICOUNT                                                            08700013
*   PPIDELCT                                                            08800013
*   PPIINSCT                                                            08900013
*   PPISW1                                                              09000013
         SPACE 1                                                        09100013
*   UPDATE RECORD,DELETE,AND INSERT COUNTERS.                           09200013
         SPACE 2                                                        09300013
*EXTERNAL ROUTINES:                                                     09400013
         SPACE 1                                                        09500013
*   MOVE ROUTINE TO MOVE RECORD FROM THE BUFFER TO RSA                  09600013
         SPACE 2                                                        09700013
*EXTERNAL PARAMETERS:                                                   09800013
         SPACE 1                                                        09900013
*   SEE REGISTERS                                                       10000013
         SPACE 2                                                        10100013
*EXITS-NORMAL:                                                          10200013
         SPACE 1                                                        10300013
*   TO NETWORK                     EXIT TO:NETWORK                      10400013
*                                    CALLING SEQUENCE-                  10500013
*                                      L    RL,PPINET+4                 10600013
*                                      B    4(RL)      FILL TREE        10700013
*                                      B    8(RL)      ON INPUT EOF     10800013
*                                      B    12(RL)     NORMAL RUNNING   10900013
*                                      B    16(RL)     FLUSH TREE       11000013
*   TO GET                         EXIT TO:GET                          11100013
*                                    CALLING SEQUENCE-                  11200013
*                                      GET(RG)         RG=ADDR OF DCB   11300013
*   TO MOVE RTN                    EXIT TO:MOVE RTN                     11400013
*                                    CALLING SEQUENCE-                  11500013
*                                      L    RP,PPIBDSVA+4 MOVE RTN ADDR 11600013
*                                      BALR RO,RP                       11700013
*   TO EXIT E15(OR ATTACHED)       EXIT TO:E15(OR ATTACHED EXIT)        11800013
*                                    CALLING SEQUENCE-                  11900013
*                                      L    RP,PPIX15+4                 12000013
*                                      BALR RO,RP                       12100013
*   TO SORT SYSTEM CONTROL         EXIT TO:SSC                          12200013
*                                    CALLING SEQUENCE-                  12300013
*                                      L    RP,PPIADSSC                 12400013
*                                      BALR RO,RP                       12500013
         SPACE 2                                                        12600013
*EXITS-ERROR:                                                           12700013
         SPACE 1                                                        12800013
*   TO NMAX EXIT                   EXIT TO:E16                          12900013
*                                    CALLING SEQUENCE-                  13000013
*                                      L    RP,PPIX16+4                 13100013
*                                      BALR RO,RP                       13200013
         SPACE 2                                                        13300013
*TABLES/WORK AREAS:                                                     13400013
         SPACE 1                                                        13500013
*   WSW1-A SWITCH IN THE INSERT RTN                                     13600013
*   WINNER-SAVE AREA FOR ADDR IN RSA THAT THE WINNER JUST VACATED       13700013
*   WNMAX-NMAX COUNTER                                                  13800013
*   WDCB-ADDRESS OF INPUT FILE'S DCB.                                   13900013
*   WRJ-2 FULL WORDS-REGISTER SAVE AREA.                                14000013
*   WINPTRCD-ADDR OF RCD IN INPUT AREA                                  14100013
*   WADDRESS - ADDRESS OF NEXT RECORD TO BE MOVED INTO RSA WHEN         14200013
*   THE TREE IS REFILLED                                                14300013
*   WRMAX - COUNT OF RECORDS USED TO COMPARE WITH PPIRMAX               14400013
*   WADDRSA - UPDATED ADDRESS OF NEXT FREE AREA IN RSA                  14500013
*   WBYTECNT - COUNT OF REMAINING BYTES IN THIS RSA CHUNK               14600013
         SPACE 2                                                        14700013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   14800013
         SPACE 2                                                        14900013
*NOTES:THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT HAVING        15000013
*   USER EXITS E15 AND/OR E16 OR WHICH IS ATTACHED, WHICH USES THE      15100013
*   OSCILLATING OR 2314 METHOD.                                         15200013
         EJECT                                                          15300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            15400013
         SPACE 1                                                        15500013
RA       EQU   0                   CONTENTS IN-N/A                      15600013
*                                  USE-DEBLK TO SSC(NAME OF MESSAGE)    15700013
*                                  CONTENTS OUT-N/A                     15800013
RB       EQU   1                   CONTENTS IN-N/A                      15900013
*                                  USE-DEBLK TO E15(ADDR OF PARAM LIST) 16000013
*                                     -E15 TO DEBLK(ADDR OF INPUT RCD)  16100013
*                                     -GET TO DEBLK(ADDR OF INPUT RCD)  16200013
*                                     -DEBLK TO SSC(BYTE LENGTH OF MSG) 16300013
*                                  CONTENTS OUT-N/A                     16400013
RC       EQU   2                   CONTENTS IN-N/A                      16500013
*                                  USE-DEBLK TO NTWK(ADDR OF INPUT RCD  16600013
*                                    IN INPUT BFR FOR EXTRACT RTN)      16700013
*                                  CONTENTS OUT-ADDR OF RCD IN INPT BFR 16800013
RD       EQU   3                   CONTENTS IN-BLK TO DEBLK/ADDR IN RSA 16900013
*                                    TO MOVE NEXT INPUT RCD-RUN TIME)   17000013
*                                  USE-ADDR IN RSA TO MOVE NEXT RCD     17100013
*                                    (FILL TIME)                        17200013
*                                  CONTENTS OUT-DEBLK TO NTWK(ADDR OF   17300013
*                                    RCD IN RSA)                        17400013
RE       EQU   4                   CONTENTS IN-N/A                      17500013
*                                  USE-DEBLK TO MOVE RTN(ADDR OF RCD IN 17600013
*                                    INPUT BFR)                         17700013
*                                     -WORK REGISTER                    17800013
*                                  CONTENTS OUT-N/A                     17900013
RF       EQU   5                   CONTENTS IN-N/A                      18000013
*                                  USE-DEBLK TO MOVE RTN(ADDR IN RSA TO 18100013
*                                    MOVE INPUT RCD)                    18200013
*                                  CONTENTS OUT-N/A                     18300013
RG       EQU   6                   CONTENTS IN-N/A                      18400013
*                                  USE-INPUT FILE RECORD COUNTER        18500013
*                                  CONTENTS OUT-N/A                     18600013
RH       EQU   7                   CONTENTS IN-N/A                      18700013
*                                  USE-DELETE COUNTER                   18800013
*                                  CONTENTS OUT- N/A                    18900013
RI       EQU   8                   CONTENTS IN- N/A                     19000013
*                                  USE-INSERT COUNTER                   19100013
*                                  CONTENTS OUT- N/A                    19200013
RJ       EQU   9                   CONTENTS IN- N/A                     19300013
*                                  USE-NMAX COUNTER                     19400013
*                                  CONTENTS OUT- N/A                    19500013
RK       EQU   10                  CONTENTS IN- N/A                     19600013
*                                  USE-ADDR OF INPUT DCB                19700013
*                                     -RSA TABLE POINTER                19800013
*                                  CONTENTS OUT-N/A                     19900013
RL       EQU   11                  CONTENTS IN-THIS MODULE ENTRY PT     20000013
*                                  USE-MODULE BASE REGISTER             20100013
*                                  CONTENTS OUT-NETWORK ENTRY PT        20200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   20300013
*                                  USE-NOT USED                         20400013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   20500013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              20600013
*                                  USE-PPI REFERENCES,REG SAVE AREA     20700013
*                                  CONTENTS OUT-ADDR OF PPI             20800013
RO       EQU   14                  CONTENTS IN-N/A                      20900013
*                                  USE-RETURN REG FROM GET,USER EXITS,  21000013
*                                    SSC,MOVE RTN                       21100013
*                                  CONTENTS OUT-N/A                     21200013
RP       EQU   15                  CONTENTS IN-N/A                      21300013
*                                  USE-USER EXITS TO DEBLK(RETURN CODE) 21400013
*                                     -BRANCH REG TO GET,USER EXITS,    21500013
*                                    SSC,MOVE RTN                       21600013
*                                  CONTENTS OUT-N/A                     21700013
         SPACE 2                                                        21800013
*START OF MODULE CODE PROPER:                                           21900013
         SPACE 2                                                        22000013
IERRDR   CSECT                                                          22100013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    22200013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  22300013
         USING IERRMA,RO           MESSAGE MODULE ADDR                  22400013
         SPACE 1                                                        22500013
* ENTER BRANCH TABLE FROM REPLACEMENT SORT,0(RL).FROM READ MOD, 4(RL).  22600013
*   OR FROM REPLACEMENT SORT(INITIALLY TO FILL TREE), ALGORITHM(AT THE  22700013
*   END OF A SEQUENCE), BLOCK MODULE(AFTER FILLING TREE), 8(RL).        22800013
IERDD1   B     RDOVLAYF            FROM REPL SORT,FINISHD FILLING TREE  22900013
         B     RDSETSW             FROM READ MOD(GET,ON EOF)            23000013
         B     RDNORMAL            NORMAL ENTRY FROM REPLACEMENT SORT   23100013
*                                    BLOCK MODULE OR ALGORITHM          23200013
         SPACE 2                                                        23300013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN REFILLING TREE         23400013
         SPACE 1                                                        23500013
         OI    RDOVLAY6+1,X'F0'    REACTIVATE BR INSTR TO FILLING EXIT  23600013
         NI    RDDOVLAY+1,X'00'    NOP BRANCH ON (G+1)TH RECORD         23700013
         MVC   RDNORMAL,K6         REINITIALIZE ENTRY BRANCH INSTR      23800013
         MVC   RDOVLAY5,K7         REOVERLAY BRANCH ON (G+1)TH RECORD   23900013
         L     RK,PPILAB08        LOAD ADDRESS OF RSA PARAM TABLE       24000013
         ST    RK,ADCONPTR         STORE                                24100013
         MVC   WADDRSA(8),0(RK)    MOVE NEW RSA PARAMS INTO WORK AREA   24200013
*                                    FIRST WORD = ADDRESS NEXT RSA BIN  24300013
*                                    SECOND = BIN BYTE COUNT            24400013
         L     RB,WADDRESS         LOAD AD OF LAST RECORD FOR MOVE RTN  24500013
         L     RD,WADDRSA           TO MOVE SAVED RCD INTO RSA          24600013
         B     RDRMXCNT                                                 24700013
         SPACE 2                                                        24800013
* FROM REPLACEMT SORT BLOCK MOD,OR ALGORITHM                            24900013
         SPACE 1                                                        25000013
RDNORMAL ST    RD,WINNER           ADDR OF A FREE AREA IN RSA-LAST WNR  25100013
RDLDCTRS STM   RJ,RK,WRJ           SAVE TRANSPARENT REGS                25200013
         LM    RJ,RK,WNMAX         RESTORE NMAX AND DCB ADDR            25400013
RDTSTISW TM    PPISW1+7,X'20'     TST INSERT SW. WILL BE OVERLAID BY    25500013
*                                    A.P. IF ATTACHED,OR BY R.P. ON     25600013
*                                    SYSTEM EOF,WITH B RDUSREXT         25700013
         BC    1,RDUSREXT          ON, BR TO USER EXIT                  25800013
RDGET    GET   (RK)                UPDATE ADDR IN INPUT AREA(REG RB)    25900013
*                                    REG RK HAS DCB ADDR                26000013
         L     RG,PPICOUNT         RECORD COUNTER                       26050013
         LA    RG,1(0,RG)          INCR RCD CTR BY ONE                  26100013
         ST    RG,PPICOUNT         STORE RECORD COUNT                   26150013
         ST    RB,WADDRESS         SET FOR RE-INIT. ENTRY               26200013
         ST    RB,WINPTRCD         SAVE ADDR OF RCD THATS IN INPUT BLK  26300013
         SPACE 1                                                        26400013
* USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.            26500013
*   PASS ADDR OF PARAMETER LIST(ADDR OF INPUT RCD) IN REGISTER RB       26600013
         SPACE 1                                                        26700013
RDUSREXT LA    RB,WINPTRCD         ADDR OF PARAMETER LIST. IF E15 NOT   26800013
*                                    ACTIVATED, OR IF ACTIVATED AND HIT 26900013
*                                    USER EOF,THIS INSTR WILL BE OVLAYD 27000013
*                                    BY B RDALSHNO                      27100013
         L     RP,PPIX15+4         ADDR OF USER EXIT E15. IF ATTACHED   27200013
*                                    A.P. WILL LOAD PPIX15 WITH ADDR IN 27300013
*                                    PPIATP1E                           27400013
         BALR  RO,RP               BR TO USER                           27500013
         SPACE 1                                                        27600013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS. USER   27700013
*   PASSES ADDR OF RECORD TO BE INSERTED OR ADDR OF WORK AREA IF HE     27800013
*   ALTERS,LENGTHENS,OR SHORTENS A RCD IN REG RB.                       27900013
         SPACE 1                                                        28000013
         B     *+4(15)                                                  28100013
RDOVLAY4 B     RDALSHNO            ALTER,LENGTHN,SHORTN,DO NOTHING      28200013
*                                    WILL BE OVERLAYED BY K4 IF,WHEN    28300013
*                                    REACH NMAX IT IS IGNORED, OR BY    28400013
*                                    A.P. WITH K4 IF EXIT NOT ACTIVE    28500013
         B     RDDELETE            DELETE A RCD                         28600013
         B     RDUSREOF            USER END OF FILE                     28700013
         SPACE 1                                                        28800013
* INSERT A RECORD                                                       28900013
         SPACE 1                                                        29000013
RDTSTNMX BCT   RJ,RDISWON          DECR NMAX CTR BY ONE AND TEST TO     29100013
*                                    SEE IF REACHED NMAX                29200013
*                                    WILL BE OVERLAYED BY K3 IF, WHEN   29300013
*                                    REACH NMAX IT IS IGNORED, OR BY    29400013
*                                    A.P. WITH K3 IF EXIT NOT ACTIVE    29500013
         B     RDWSW1ON            YES,BR TO NMAX USER EXIT E16,SW ON   29600013
         SPACE 2                                                        29700013
* SYSTEM END OF FILE ROUTINE                                            29800013
         SPACE 1                                                        29900013
RDSETSW  TM    PPISW1+7,X'80'      TEST IF USER EOF SWITCH ON           30000013
         BO    RDCNTSRT              YES, BRANCH TO FLUSH TREE          30100013
         SPACE 1                                                        30200013
         TM    PPISW1+3,X'01'      TEST IF SIMULATED EOF                30300013
         BNO   RDCNTSRT              YES, BRANCH TO FLUSH TREE          30400013
           SPACE 1                                                      30500013
         CLI   REALEOF,X'01'       IS THIS SIM. EOF AFTER               30600013
         BE    RDCNTSRT              REAL EOF                           30700013
         SPACE 1                                                        30800013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       30900013
*                                    EOF'S ARE SIMULATED                31000013
         SPACE 1                                                        31100013
         SR    RB,RB               CLEAR INPUT RCD PARAM REG            31200013
         MVC   RDTSTISW,K5         TO BYPASS GOING TO GET AFTER SYS EOF 31300013
         B     RDUSREXT-4          NO, BR TO USER                       31400013
         SPACE 2                                                        31500013
* USER END OF FILE ROUTINE                                              31600013
         SPACE 1                                                        31700013
RDUSREOF OI    PPISW1+7,X'80'     SET USER EOF SWITCH                   31800013
         MVC   RDUSREXT,RDOVLAY4   OVLAY USER EXIT-BYPASS EXIT E15      31900013
         TM    PPISW1+3,X'01'     TEST IF SYSTEM EOF SWITCH ON          32000013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              32100013
         L     RB,WINPTRCD         RESTORE ADDR OF RCD IN INPUT BLK     32200013
         B     RDALSHNO            BR TO SORT THIS RCD                  32300013
         SPACE 2                                                        32400013
RDISWON  OI    PPISW1+7,X'20'     TURN INSET SWITCH ON                  32500013
         L     RI,PPIINSCT         INSERT COUNT                         32550013
         LA    RI,1(0,RI)          INCR INSERT CTR BY ONE               32600013
         ST    RI,PPIINSCT         STORE INSERT COUNT                   32700013
RDSTM    ST    RB,WADDRESS         SAVE FOR RE-INIT                     32800013
         ST    RJ,WNMAX            SAVE NMAX CTR                        32900013
RDRMXCNT L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   33000013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   33100013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     33200013
         BH    RDRMAX              BRANCH ON YES                        33300013
         ST    RG,WRMAX            SAVE                                 33400013
         SPACE 1                                                        33500013
* INITALIZE AND BR TO MOVE RTN TO MOVE NEXT INPUT RCD TO RSA            33600013
         SPACE 1                                                        33700013
RDOVLAY5 B     RDDLDRSA            BR TO GET ADDR IN RSA TO MOVE RCD    33800013
*                                    WILL BE OVLAYED BY L RF,WINNER     33900013
*                                    AFTER G+1 RCDS                     34000013
RDDLDRE  LR    RE,RB               ADDR OF RCD IN INPUT BUFFER OR FROM  34100013
*                                    USER'S WORK AREA                   34200013
         L     RP,PPIBDSVA+4       ADDR OF MOVE RTN IN GENERATED CORE   34300013
         BALR  RO,RP               BR TO MOVE RTN.MOVE RCD TO RSA       34400013
RDOVLAY6 B     RDFILLTR            BR TO SORT NETWORK FILLING TREE RTN  34500013
*                                    WILL BE OVLAYED BY NOP AFTER       34600013
*                                    TREE IS INITIALLY FILLED           34700013
         SPACE 2                                                        34800013
* NORMAL EXIT TO SORT NETWORK AFTER PREVIOUS INSTR IS OVERLAYED BY NOP  34900013
         SPACE 1                                                        35000013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          35100013
         L     RD,WINNER                                                35200013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 35300013
         B     12(RL)              BR TO SORT NETWORK NORMAL RTN        35400013
         SPACE 2                                                        35500013
* EXIT TO SORT NETWORK WHILE FILLING TREE                               35600013
         SPACE 1                                                        35700013
RDFILLTR LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          35800013
         A     RD,PPIBINSZ         UPDATE TO NEXT BIN IN THIS RSA       35900013
         ST    RD,WADDRSA          SAVE UPDATED RSA ADDRESS             36000013
         S     RD,PPIBINSZ         RESTORE FOR NETWORK. ADDR OF THIS    36100013
*                                    RCD IN RSA                         36200013
         L     RL,PPINET+4         ADDR OF NETWORK                      36300013
         B     4(RL)               BR TO SORT NETWORK FILL TREE RTN     36400013
         SPACE 2                                                        36500013
         SPACE 2                                                        36600013
* FINISHED FILLING TREE RTN -ONE TIME RTN                               36700013
         SPACE 1                                                        36800013
RDOVLAYF NI    RDOVLAY6+1,X'00'    NOP THE BR INSTR TO THE FILLING EXIT 36900013
         MVI   RDDOVLAY+1,X'F0'    OVLAY INSTR IN RSA TABLE ROUTINE     37000013
         B     RDLDCTRS            BR TO GET G+1 RECORD.                37100013
         SPACE 2                                                        37200013
*RSA TABLE ROUTINE USED DURING FILLING OF TREE. ENTER HERE ONLY THROUGH 37300013
*   G+1 RECORDS.                                                        37400013
         SPACE 1                                                        37500013
RDDLDRSA L     RK,ADCONPTR         RSA TABLE PTR                        37600013
RDDRTRN  LM    RD,RE,WADDRSA       RD=ADDR IN THIS RSA, RE = REMAINING  37700013
*                                    BYTE COUNT OF THIS RSA.            37800013
         S     RE,PPIBINSZ         SUBTR SIZE OF THIS RCD               37900013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS RSA 38000013
RDDOVLAY BC    0,RDDLAST           WILL BE A BR AFTER RSA HAS G RCDS    38100013
         SPACE 2                                                        38200013
         ST    RE,WBYTECNT         SAVE REMAINING BYTE COUNT THIS RSA   38300013
         LR    RF,RD               ADDR IN RSA TO MOVE THE RCD          38400013
         B     RDDLDRE             BR TO MOVE RCD TO RSA                38500013
         SPACE 2                                                        38600013
RDNEWRSA LA    RK,8(0,RK)          UPDATE RSA TABLE PTR TO NEXT RSA     38700013
*                                    ENTRY(NEXT NON-CONTIGUOUS RSA)     38800013
         ST    RK,ADCONPTR         SAVE UPDATED PTR                     38900013
         MVC   WADDRSA(8),0(RK)   MOVE NEW PARAMS INTO WORK AREA        39000013
*                                    FIRST WORD = ADDRESS NEXT RSA BIN  39100013
*                                    SECOND = BIN BYTE COUNT            39200013
         B     RDDRTRN             BR TO USE THIS RSA                   39300013
         SPACE 2                                                        39400013
*WE ARE GOING TO PROCESS THE G+1 RECORD.                                39500013
         SPACE 1                                                        39600013
RDDLAST  ST    RD,WINNER           ADDR IN RSA TO MOVE RCD              39700013
         MVC   RDOVLAY5(4),K1      OVLAY BRANCH INSTR TO RSA TABLE RTN  39800013
         B     RDOVLAY5            BR TO MOVE G+1 RCD TO RSA.           39900013
         SPACE 2                                                        40000013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              40100013
         SPACE 1                                                        40200013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 40300013
         OI    PPISW1+7,X'80'      SET USER EOF FOR ALG.                40400013
         TM    PPISW1+3,X'01'    WAS SYS EOF REACHED                    40500013
         BC    1,RDCNTSRT          YES,BR AROUND NEXT INSTRS-FLUSH TREE 40600013
         L     RG,PPICOUNT         RECORD COUNT                         40650013
         BCTR  RG,0                DECR PPICOUNT BY ONE                 40700013
         ST    RG,PPICOUNT         STORE RECORD COUNT                   40750013
         OI    PPISW1+3,X'01'      SET EOF SW, SO ALG. WON'T RETURN     40800013
         SPACE 1                                                        40900013
* FROM GET ON END OF FILE                                               41000013
RDCNTSRT MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               41100013
         L     RL,PPINET+4         ADDR OF NTWK                         41300013
         B     8(RL)               BR TO NTWK TO EMPTY TREE             41400013
         SPACE 2                                                        41500013
RDEMPTYT L     RL,PPINET+4         ADDR OF NTWK                         41600013
         B     16(RL)              BR TO SORT TO CONTINUE EMPTYING TREE 41700013
         SPACE 2                                                        41800013
* WRITE MESSAGE NMAX EXCEEDED                                           41900013
         SPACE 1                                                        42000013
RDWSW1ON OI    WSW1,X'01'          TURN SWITCH 1 ON                     42100013
RDMSGS   L     RO,PPIRMA+4        ADDRESS OF MESSAGE MODULE             42200013
         LR    RE,RB               SAVE ADDR OF NMAX+1 RCD              42300013
         LM    RA,RB,MSGP1A04      NAME AND LENGTH OF MESSAGE           42400013
         L     RP,PPIADSSC         LOAD PRINT RTN ADDR                  42500013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      42600013
         SPACE 1                                                        42700013
* USER EXIT E16 -SORT CAPACITY, NMAX, HAS BEEN REACHED                  42800013
*   CALL MACRO INSTRUCTION EXPANSION                                    42900013
         SPACE 1                                                        43000013
         LR    RB,RE               RESTORE ADDR OF NMAX+1 RCD           43100013
         L     RP,PPIX16+4         ADDR OF NMAX EXIT                    43200013
         BALR  RO,RP               BR TO USER                           43300013
         SPACE 2                                                        43400013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS.        43500013
         SPACE 1                                                        43600013
         B     *+4(15)                                                  43700013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         43800013
         B     RDIGNORE            IGNORE NMAX AND CONTINUE TO SORT     43900013
         SPACE 1                                                        44000013
* ABORT THE JOB. SET UP ABNORMAL END INDICATION FOR SORT SYSTEM CONTROL 44100013
         SPACE 1                                                        44200013
         L     RP,PPIADSSC                                              44300013
         BAL   RO,16(0,RP)         BR TO SORT SYSTEM CONTROL            44400013
         SPACE 1                                                        44500013
* IGNORE NMAX. OVERLAY NMAX TEST WITH A BYPASS BRANCH INSTR.            44600013
         SPACE 1                                                        44700013
RDIGNORE MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN         44800013
         CLC   RDUSREXT,RDOVLAY4   HAS USER EXIT CODE BEEN OVERLAID?    44900013
         BNE   *+10                IF NOT, BRANCH AROUND NEXT INSTRUC   45000013
         MVC   RDUSREXT,K4         CHANGE OVERLAID INSTRUCTION          45100013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ALTER RTN 45200013
         TM    WSW1,X'01'          TEST SWITCH 1                        45300013
         BC    1,RDISWON           ON,BR TO TURN INSERT SWITCH ON       45400013
         B     RDISWOFF            BR TO TURN INSERT SWITCH OFF         45500013
         SPACE 2                                                        45600013
* DO NOTHING, ALTER, LENGTHEN, SHORTEN A RCD. ADDR OF INPUT RCD IN RB.  45700013
         SPACE 1                                                        45800013
RDALSHNO BCT   RJ,RDISWOFF         DECR NMAX CTR BY ONE AND TST TO SEE  45900013
*                                    IF REACHED NMAX                    46000013
         B     RDMSGS              YES, BR TO NMAX USER EXIT E16        46100013
         SPACE 2                                                        46200013
RDISWOFF NI    PPISW1+7,X'DF'     TURN OFF INSERT SWITCH                46300013
         B     RDSTM               BR TO LOAD ADDR OF FREE AREA IN RSA  46400013
         SPACE 2                                                        46500013
* DELETE A RECORD                                                       46600013
         SPACE 1                                                        46700013
RDDELETE NI    PPISW1+7,X'DF'     TURN OFF INSERT SWITCH                46800013
         L     RH,PPIDELCT         DELETE COUNT                         46850013
         LA    RH,1(0,RH)          INCR DELETE CTR BY ONE               46900013
         ST    RH,PPIDELCT         STORE DELETE COUNT                   46950013
         B     RDGET               BR TO GET ANOTHER RECORD             47000013
         SPACE 2                                                        47100013
*        ENOUGH RECORDS HAVE BEEN READ IN TO FILL ONE REEL OF TAPE      47200013
         SPACE 1                                                        47300013
RDRMAX   SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         47400013
         ST    RB,WADDRESS         SAVE ADDRESS OF THIS RECORD          47500013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   47600013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  47700013
         MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               47800013
         L     RL,PPINET+4         ADDRESS OF NETWORK                   47900013
         B     8(RL)               BR TO NETWORK TO EMPTY TREE          48000013
         SPACE 1                                                        48100013
* END OF CODING --- ADCONS NEXT PAGE                                    48200013
         EJECT                                                          48300013
* LIST OF CONSTANTS USED BY THE MODULE                                  48400013
         SPACE 1                                                        48500013
K1       L     RF,WINNER           OVERLAY WHEN FINISHED FILLING TREE   48600013
K2       B     RDEMPTYT            OVERLAY TO EMPTYTREE ON GET EOF      48700013
K3       B     RDISWON             BYPASS NMAX TEST IN INSERT RTN       48800013
K4       B     RDISWOFF            BYPASS NMAX TEST IN DO NOTHG,ETC RTN 48900013
K5       B     RDUSREXT            OVERLAY INSERT SW TEST BY A.P. IF    49000013
*                                    ATTACHED                           49100013
K6       ST    RD,WINNER           AD OF FREE AREA IN RSA - LAST WINNER 49200013
K7       B     RDDLDRSA            BR TO GET AD IN RSA TO MOVE RECORD   49300013
         SPACE 2                                                        49400013
* LIST OF WORK AREAS                                                    49500013
         SPACE 1                                                        49600013
WSW1     DC    X'00'               SWITCH 1 IN INSERT RTN               49700013
REALEOF  DC    X'00'                                                    49800013
WINNER   DC    F'0'                SORT WINNER RCD ADDR                 49900013
WNMAX    DC    F'0'                MAX NO OF RCDS TO SORT PLUS ONE(FOR  50000013
*                                    SPEED, CAN NOW USE BCT TO DECR     50100013
*                                    NMAX CTR TO ZERO)                  50200013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR INPUT FILE  50300013
*                                    LOADED BY ASSIGNMENT ROUTINE       50400013
WRJ      DC    2F'0'               SAVE TRANPARENT REGS                 50500013
WINPTRCD DC    F'0'                ADDR OF RCD IN INPUT AREA            50600013
WADDRESS DS    F                   ADDRESS OF NEXT RECORD TO BE MOVED   50700013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     50800013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               50900013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    51000013
ADCONPTR DS    F                  UPDATED ADDRESS OF RSA PARAM TABLE    51100013
         EJECT                                                          51200013
* MODULE NAME ***IERRMA***                                              51300013
*                                                                       51400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        51500013
* PHASE 1 RUNNING PROGRAM.                                              51600013
         SPACE 1                                                        51700013
IERRMA   DSECT                                                          51800013
*                                                                       51900013
       COPY  RMAMAIN                                                    52000013
         EJECT                                                          52100013
         SMPPI                                                          52200013
         END                                                            52300013
