         TITLE 'IERRDS -OS/360 SORT/MERGE - 360-SM-023    05/20/65'     00100013
         SPACE                                                          00200013
*MODULE NAME *** IERRDS ***                                             00300013
         SPACE 2                                                        00400013
*STATUS: CHANGE LEVEL 0                                                 00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION:                                                       00700013
*   IERRDS IS AN OSCL/2314 SORT PHASE DEBLOCK MODULE WHICH HANDLES      00800013
*   VARIABLE LENGTH RECORDS BY WAY OF THE QSAM GET MACRO AND CONTAINS   00900013
*   LINKAGE TO THE USER MODIFICATION PROGRAMS VIA THE CALL MACRO EXPAN- 01000013
*   SION INSTRUCTIONS. THE INPUT RECORDS ARE LOCATED IN AN INPUT        01100013
*   BUFFER. BEFORE MOVING THE RECORD TO THE WORK AREA, RSA, THE MODULE  01200013
*   BRANCHES TO THE USER ROUTINE WHICH MAY: 1.DELETE, 2.INSERT OR 3.    01300013
*   ALTER(LENGTHEN, SHORTEN OR DO NOTHING TO THE RECORD). THE ADDRESS   01400013
*   OF THE RECORD IN THE INPUT AREA IS PASSED TO THE USER. THE USER     01500013
*   RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS. THIS MODULE   01600013
*   KEEPS TRACK OF THE MAXIMUM AMOUNT OF RECORDS THAT THE SORT CAN      01700013
*   HANDLE AT ANY ONE TIME(NMAX). IT CHECKS TO SEE IF NMAX IS REACHED   01800013
*   AND IF IT IS REACHED, IT BRANCHES TO THE USER ROUTINE WHICH MAY     01900013
*   DIRECT US TO: 1.SORT CURRENT NUMBER, 2.IGNORE NMAX OR 3.ABORT JOB.  02000013
*   THE USER RETURNS VIA BRANCH REGISTER AND PROPER DISPLACEMENTS. THE  02100013
*   MODULE BRANCHES TO THE MOVE MODULE (IERRBF) WHICH MOVES THE RECORD  02200013
*   INTO RSA. IERRDS THEN PASSES THE RECORD'S LOCATION IN RSA TO THE    02300013
*   REPLACEMENT SORT. USER EXITS E15 AND E16 ARE AVAILABLE IN THIS      02400013
*   MODULE. IT ALSO CHECKS TO DETERMINE WHEN RMAX HAS BEEN REACHED,     02500013
*   THE MAXIMUM NUMBER OF BYTES WHICH CAN FIT ONTO ONE REEL OF TAPE,    02600013
*   AND CAUSES RSA TO BE FLUSHED, FOLLOWED BY A MERGE ONTO ONE REEL,    02700013
*   WHICH IS THEN SET ASIDE. IT CAN REINITIALIZE ITSELF TO BEGIN        02800013
*   REFILLING RSA AFTER IT HAS BEEN FLUSHED AND A MERGE TAKEN PLACE.    02900013
         SPACE 1                                                        03000013
*   IF THE 2314 TECH. IS USED, THE RMAX CHECK AT RDSRMAX IS BYPASSED.   03100013
*   THIS BECOMES AN UNCONDITIONAL BRANCH TO RDSPTB.                     03200013
         SPACE 2                                                        03300013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               03400013
*   IERADS                                                              03500013
         SPACE 2                                                        03600013
*LIST OF MACROS USED BY MODULE:                                         03700013
*   SMPPI                                                               03800013
*   GET                                                                 03900013
         SPACE 2                                                        04000013
*ENTRY POINTS:                                                          04100013
         SPACE 1                                                        04200013
*        ENTRY                     ENTRY FROM NETWORK.                  04300013
*                                    CALLING SEQUENCE-                  04400013
*                                      L     RL,PPIDEB+4                04500013
*                                      B     8(RL)     DURING TREE FILL 04600013
         SPACE 1                                                        04700013
*                                      L     RL,PPIDEB+4                04800013
*                                      BR    RL     ONCE-WHEN TREE FULL 04900013
         SPACE 1                                                        05000013
*        ENTRY                     ENTRY FROM BLOCK.                    05100013
*                                    CALLING SEQUENCE-                  05200013
*                                     L     RL,PPIDEB+4                 05300013
*                                      B     8(RL)                      05400013
         SPACE 1                                                        05500013
*        ENTRY                     ENTRY FROM EOF ROUTINE.              05600013
*                                    CALLING SEQUENCE-                  05700013
*                                      L     RL,PPIDEB+4                05800013
*                                      B     4(RL)                      05900013
         SPACE 1                                                        06000013
*   FROM INITIALIZATION ROUTINE    ENTRY FROM: INITILIZATION ROUTINE    06100013
*                                    CALLING SEQUENCE-                  06200013
*                                      L     RL,PPIDEB+4                06300013
*                                      B     12(RL)                     06400013
         SPACE 1                                                        06500013
*        ENTRY                     ENTRY FROM E15.                      06600013
*                                    CALLING SEQUENCE-                  06700013
*                                      BR    RO                         06800013
         SPACE 1                                                        06900013
*        ENTRY                     ENTRY FROM E16.                      07000013
*                                    CALLING SEQUENCE-                  07100013
*                                      BR    RO                         07200013
         SPACE 2                                                        07300013
*INPUT: PPI FIELDS REFERENCED -                                         07400013
         SPACE 1                                                        07500013
*   PPIBDSVA    PPINET      PPIX15                                      07600013
*   PPIX16      PPISTDCB    PPICOUNT                                    07700013
*   PPINSCT     PPIDELCT    PPIRMA                                      07800013
*   PPIADSSC    PPIRMAX                                                 07900013
         SPACE 2                                                        08000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED -                            08100013
         SPACE 1                                                        08200013
*   PPIBDSVA    PPICOUNT    PPIINSCT                                    08300013
*   PPIDELCT    PPISW1                                                  08400013
         SPACE 2                                                        08500013
*EXTERNAL ROUTINES:                                                     08600013
         SPACE 1                                                        08700013
*        EXTRN IERRMA              ERROR MESSAGE PRINT ROUTINE.         08800013
         SPACE 2                                                        08900013
*EXTERNAL PARAMETERS - N/A                                              09000013
*                                                                       09100013
*                                                                       09200013
*EXITS-NORMAL:                                                          09300013
         SPACE 1                                                        09400013
*   E15      - PHASE 1 RECORD MODIFICATION EXIT.                        09500013
*   E16      - PHASE 1 NMAX EXIT.                                       09600013
*   NETWORK  - PASS ADDRESS OF EACH INCOMING RECORD.                    09700013
         SPACE 2                                                        09800013
*EXITS-ERROR;                                                           09900013
         SPACE 1                                                        10000013
*   PPIADSSC - PRINT NMAX REACHED MESSAGE.                              10100013
         SPACE 2                                                        10200013
*TABLES/WORK AREAS:                                                     10300013
         SPACE 1                                                        10400013
*   WORK AREA AT WSAVE IS A 3 WORD AREA TO SAVE REGISTER INFORMATION    10500013
*   FOR MOVE ROUTINE WHEN ONLY A PORTION OF A RECORD FITS IN RSA.       10600013
*   WORK AREA AT WNMAX IS WHERE A RUNNING COUNT OF RECORDS IS KEPT SO   10700013
*   IT CAN BE DETERMINED WHEN NMAX HAS BEEN REACHED.                    10800013
*   WINSALT - INSERT-ALTER RECORD SWITCH                                10900013
*   WORK AREA WSAVAIL IS A SAVE AREA FOR THE RSA ADDRESS OF THE RECORD  11000013
*   CURRENTLY BEING MOVED.                                              11100013
*   WRMAX - BYTE COUNT TO COMPARE AGAINST PPIRMAX                       11200013
*   WADDRESS - ADDRESS OF NEXT RECORD TO BE MOVED INTO RSA WHEN         11300013
*   THE TREE IS REFILLED                                                11400013
         SPACE 2                                                        11500013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  11600013
         SPACE 2                                                        11700013
*NOTES: THIS MODULE IS USED FOR VARIABLE LENGTH RECORD SORTS WHICH HAVE 11800013
*   EXITS 15 OR 16 ACTIVATED.                                           11900013
         EJECT                                                          12000013
*LIST OF GENERAGENERAL REGISTER EQUATE STATEMENTS:                      12100013
         SPACE 1                                                        12200013
RA       EQU   0                   CONTENTS IN - WHEN ENTERED FROM THE  12300013
*                                    MOVE ROUTINE ON A CONDITION WHERE  12400013
*                                    THE RECORD DID NOT FIT IT CONTAINS 12500013
*                                    THE NUMBER OF BYTES YET TO MOVE.   12600013
*                                  USED - NOT USED.                     12700013
*                                  CONTENTS OUT - RESTORED TO VALUE OF  12800013
*                                    CONTENTS IN ONLY WHEN RETURNING TO 12900013
*                                    MOVE ROUTINE TO COMPLETE MOVE.     13000013
*                                               - ADDRESS OF NMAC       13100013
*                                    MESSAGE UPON BRANCH TO PPIADSSC    13200013
RB       EQU   1                   CONTENTS IN - NUMBER OF BINS USED    13300013
*                                    WHEN ENTERED FROM MOVE ROUTINE.    13400013
*                                              - ADDRESS OF RECORD TO   13500013
*                                    BE MOVED INTO RSA UPON RETURN FROM 13600013
*                                    E15. MEANINGLESS IF RECORD IS TO   13700013
*                                    BE DELETED.                        13800013
*                                              - ADDRESS OF RECORD WHEN 13900013
*                                    ENTERED FROM QSAM GET ROUTINE.     14000013
*                                  USED - GENERAL WORK REGISTER.        14100013
*                                  CONTENTS OUT - 0 OR 8 WHEN BRANCHING 14200013
*                                    TO MOVE ROUTINE. 0=NORMAL-8=LAST   14300013
*                                    RECORD DIDN'T FIT IN RSA.          14400013
*                                               - ADDRESS OF PARAMETER  14500013
*                                    LIST WHEN BRANCHING TO E15.        14600013
*                                               - BUFFER ADDRESS OF     14700013
*                                    CURRENT RECORD WHEN BRANCHING TO   14800013
*                                    E16.                               14900013
*                                               - NUMBER OF CHARACTERS  15000013
*                                    IN NMAX MESSAGE WHEN BRANCHING TO  15100013
*                                    ERROR PRINT ROUTINE.               15200013
RC       EQU   2                   CONTENTS IN - N/A                    15300013
*                                  USED - GENERAL WORK REGISTER.        15400013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  15500013
*                                    INPUT BUFFER WHEN BRANCHING TO     15600013
*                                    NETWORK.                           15700013
RD       EQU   3                   CONTENTS IN - N/A                    15800013
*                                  USED - GENERAL WORK REGISTER.        15900013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  16000013
*                                    RSA WHEN BRANCHING TO NETWORK.     16100013
RE       EQU   4                   CONTENTS IN - POINTER TO PORTION OF  16200013
*                                    RECORD IN INPUT BUFFER WHEN MOVE   16300013
*                                    ROUTINE RETURNS BECAUSE RECORD     16400013
*                                    DIDN'T FIT IN RSA.                 16500013
*                                  USED - GENERAL WORK REGISTER.        16600013
*                                  CONTENTS OUT - ADDRESS OF DCB WHEN   16700013
*                                    BRANCHING TO QSAM GET ROUTINE.     16800013
*                                               - ADDRESS OF RECORD IN  16900013
*                                    INPUT BUFFER WHEN BRANCHING TO THE 17000013
*                                    MOVE ROUTINE.                      17100013
RF       EQU   5                   CONTENTS IN - POINTER TO CHAIN       17200013
*                                    ADDRESS OF LAST BIN USED UPON      17300013
*                                    RETURN FROM MOVE ROUTINE.          17400013
*                                  USED - GENERAL WORK REGISTER.        17500013
*                                  CONTENTS OUT - POINTER TO NEXT       17600013
*                                    AVAILABLE BIN IN RSA WHEN BRANCH-  17700013
*                                    ING TO MOVE ROUTINE.               17800013
RG       EQU   6                   CONTENTS IN - N/A                    17900013
*                                  USED - WORK REGISTER                 18000013
*                                  CONTENTS OUT - N/A                   18100013
RH       EQU   7                   CONTENTS IN - N/A                    18200013
*                                  USED - WORK REGISTER                 18300013
*                                  CONTENTS OUT - N/A                   18400013
RI       EQU   8                   CONTENTS IN - N/A                    18500013
*                                  USED - WORK REGISTER                 18600013
*                                  CONTENTS OUT - N/A                   18700013
RJ       EQU   9                   CONTENTS IN - N/A                    18800013
*                                  USED - RECORD COUNT FOR NMAX         18900013
*                                       - GENERAL WORK REGISTER         19000013
*                                  CONTENTS OUT - N/A                   19100013
RK       EQU   10                  NOT USED.                            19200013
RL       EQU   11                  CONTENTS IN - ADDRESS OF IERRDS.     19300013
*                                  USED - MODULE BASE REGISTER.         19400013
*                                  CONTENTS OUT - ADDRESS OF NETWORK.   19500013
RM       EQU   12                  NOT USED.                            19600013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI.        19700013
*                                  CONTENTS OUT - ADDRESS OF PPI.       19800013
RO       EQU   14                  CONTENTS IN - N/A                    19900013
*                                  USED - BASE REGISTER FOR MESSAGE     20000013
*                                    MODULE.                            20100013
*                                       - RETURN REGISTER ON BRANCH TO  20200013
*                                    E15, E16, PRINT ROUTINE AND MOVE   20300013
*                                    ROUTINE.                           20400013
*                                  CONTENTS OUT - N/A                   20500013
RP       EQU   15                  CONTENTS IN - CODE TO DELETE,ALTER   20600013
*                                    OR INSERT RECORD UPON RETURN FROM  20700013
*                                    E15.                               20800013
*                                              - CODE TO CONTINUE SORT- 20900013
*                                    ING, SORT CURRENT RECORDS OR ABORT 21000013
*                                    THE SORT UPON ENTRY FROM E16.      21100013
*                                  USED - GENERAL WORK REGISTER.        21200013
*                                  CONTENTS OUT - ADDRESS OF E15, E16   21300013
*                                    PRINT ROUTINE AND MOVE ROUTINE     21400013
*                                    WHEN THEY ARE BRANCHED TO.         21500013
         SPACE 2                                                        21600013
*START OF MODULE CODE PROPER:                                           21700013
         SPACE 2                                                        21800013
IERRDS   CSECT                                                          21900013
*2930385500                                                        1297 21950018
         USING *,RL                                                     22000013
         USING IERRCA,RN                                                22100013
         USING IERRMA,RO           MESSAGE MODULE ADR                   22200013
IERDD1   B     RDSOLAY             GO TO OVERLAY EXITS                  22300013
         B     RDSEOF              GO TO EOF ROUTINE                    22400013
         B     RDSNTER             NORMAL ENTRY TO DEBLOCK ANOTHER RCD  22500013
         SPACE 2                                                        22600013
*        ENTRY TO REINITIALIZE TO BEGIN REFILLING THE TREE              22700013
         SPACE 1                                                        22800013
         LA    RE,4                CHANGE ENTRIES TO NETWORK            22900013
         STC   RE,RDSFIT+3                                              23000013
         LA    RE,24                                                    23100013
         STC   RE,RDSSPEC-1                                             23200013
         MVC   RDSNTER(4),K6                                            23300013
         SPACE 2                                                        23400013
*        CHAIN BINS TOGETHER BY PUTTING IN EACH BIN THE ADDRESS OF THE  23500013
*        NEXT AVAILABLE BIN. SAVE THE ADDRESS OF THE FIRST AVAILABLE    23600013
*        BIN IN PPIBDSVA+4 AND THE TOTAL NUMBER OF AVAILABLE BINS IN    23700013
*        PPIBDSVA+8.                                                    23800013
         SPACE 1                                                        23900013
         SR    RD,RD                                                    24000013
         ST    RD,PPIBDSVA+8      ZERO OUT AVAILABLE BINS COUNT         24100013
         IC    RD,PPILAB08         NUMBER OF RSA AREAS                  24200013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              24300013
         L     RG,0(RH)            ADDRESS OF THIS RSA AREA BIN         24400013
         ST    RG,PPIBDSVA+4       SAVE ADDRESS OF FIRST RSA BIN        24500013
         SPACE 1                                                        24600013
RDAAAA   L     RF,4(RH)            NO. BYTES IN THIS RSA AREA           24700013
         LA    RI,RDBBBB           LOAD RETURN REG FOR THIS LOOP CALC   24800013
         SR    RE,RE                                                    24900013
         D     RE,PPIBINSZ         RF = NO. BINS IN THIS RSA AREA       25000013
         L     RE,PPIBDSVA+8       TOTAL NO. BINS IN RSA SO FAR         25100013
         AR    RE,RF               UPDATE BIN COUNT                     25200013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               25300013
         SPACE 1                                                        25400013
RDBBBB   BCT   RF,RDDDDD           DECR NO. BINS CTR FOR THIS RSA       25500013
*                                    BR IF MORE BINS IN THIS RSA        25600013
         BCT   RD,RDCCCC           DECR NO. OF RSA'S CTR. BR IF MORE    25700013
*                                    RSA'S. THE LAST BIN IN THE LAST    25800013
*                                    RSA HAS NO CHAIN ADDRESS.          25900013
         B     RDFFFF              BR TO LOAD MOVE PARAMETERS           26000013
         SPACE 1                                                        26100013
RDCCCC   LA    RI,RDSEEE           RESET RETURN REG FOR THIS LOOP       26200013
RDDDDD   A     RG,PPIBINSZ         ADDRESS OF THIS BIN + BIN SIZE       26300013
         LR    RE,RG               SAVE ADDRESS OF NEXT BIN             26400013
         S     RE,KFOUR            PTS TO AREA IN PREVIOS BIN TO PUT    26500013
*                                    THE CHAIN AD OF NEXT BIN (IN RG)   26600013
         ST    RG,0(RE)            PREVIOUS BIN NOW CHAINED TO NEXT BIN 26700013
         BR    RI                  BR TO RDBBBB ON ALL BINS EXCEPT THE  26800013
*                                    LAST BIN IN EACH RSA. OTHERWISE    26900013
*                                    BR TO RDSEEE                       27000013
         SPACE 1                                                        27100013
RDSEEE   LA    RH,8(RH)            UPDATE PPI RSA TABLE PTR TO NEXT     27200013
*                                    RSA ENTRY                          27300013
         L     RG,0(RH)            ADDRESS OF FIRST BIN IN NEXT RSA     27400013
         ST    RG,0(RE)            STORE AS CHAIN ADDRESS IN LAST BIN   27500013
*                                    OF PREVIOUS RSA.                   27600013
         B     RDAAAA                                                   27700013
         SPACE 2                                                        27800013
*        LOAD PARAMS TO MOVE SAVED RECORD INTO RSA                      27900013
         SPACE 1                                                        28000013
RDFFFF   L     RE,WADDRESS         GE3 ADDRES2 OF SAVED RECORD          28100013
         B     RDSRMAX             B TO RESTART RMAX COUNT              28200013
         SPACE 2                                                        28300013
*        NORMAL ENTRY TO DEBLOCK ANOTHER RECORD                         28400013
         SPACE 1                                                        28500013
RDSNTER  CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  28600013
         BL    RDSNORM             NO FIT SWITCH OFF                    28700013
         BH    RDSSPEC             NO. OF BINS WAS=0                    28800013
         SR    RE,RE                                                    28900013
         A     RE,PPIBDSVA+8                                            29000013
         BZ    RDSBINZ             BIN COUNT STILL=0                    29100013
         L     RA,WSAVE                                                 29200013
         L     RE,WSAVE+4          RELOAD REGS TO CONTINUE MOVE         29300013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 29400013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                29500013
         ST    RD,0(0,RC)          INSERT CHAIN ADDRESS                 29600013
         LA    RB,8(0)             INDICATE DEBLOCK WITH NOFIT PREVIOUS 29700013
         L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          29800013
RDSMOVE  L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             29900013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               30000013
         SPACE 2                                                        30100013
         B     RDSNOTF             RECORD DIDN'T FIT                    30200013
         SPACE                                                          30300013
*  RECORD FIT ROUTINE                                                   30400013
         SPACE                                                          30500013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  30600013
         BC    7,RDSUSUAL          LAST MOVE WAS NOT A NO FIT           30700013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       30800013
         SR    RC,RC                                                    30900013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     31000013
         B     RDSUSUAL+4          RD ALREADY LOADED                    31100013
RDSUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RCD JUST MOVED          31200013
         AH    RD,EXPLFOUR         ADD EXT SIZE & 4                     31300013
         L     RC,ADRHOLDB         LOAD BUFFER ADDRESS                  31400013
         L     RE,PPIBDSVA+8                                            31500013
         SR    RE,RB                                                    31600013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     31700013
         L     RE,0(0,RF)                                               31800013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         31900013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               32000013
         L     RL,PPINET+4                                              32100013
RDSFIT   B     4(0,RL)             EXIT TO SORT ON RECORD FIT CONDITION 32200013
         SPACE 2                                                        32300013
*  RECORD NO FIT ROUTINE                                                32400013
         SPACE                                                          32500013
RDSNOTF  ST    RA,WSAVE                                                 32600013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              32700013
         SR    RD,RD                                                    32800013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         32900013
         OI    NOFITSW,X'01'       SET NOFITSW=01                       33000013
         A     RD,WSAVAIL                                               33100013
         BC    7,RDSBINZ           MORE THAN ONE NO FIT ON SAME RECORD  33200013
         L     RD,PPIBDSVA+4                                            33300013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      33400013
RDSBINZ  L     RL,PPINET+4                                              33500013
         B     24(0,RL)            EXIT TO SORT ON RECORD NO FIT        33600013
         SPACE 2                                                        33700013
RDSSPEC  SR    RE,RE                                                    33800013
         A     RE,PPIBDSVA+8       CHECK BIN COUNT                      33900013
         BZ    RDSBINZ             BIN COUNT STILL ZERO                 34000013
         NI    NOFITSW,X'00'       ZERO NOFITSW-BIN COUNT NO LONGER 0   34100013
         L     RE,ADRHOLDA         RELOAD BUFFER ADDRESS                34200013
RDSPTB   L     RF,PPIBDSVA+4                                            34300013
         AH    RF,EXPLFOUR         ADD EXT SIZE & 4 TO AVAIL ADR        34400013
         ST    RE,ADRHOLDB         SAVE BUFFER ADDRESS                  34500013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     34600013
         B     RDSMOVE             CONTINUE PREP FOR MOVE               34700013
         SPACE 2                                                        34800013
RDSNORM  TM    PPISW1+7,X'20'                                           34900013
         BO    RDSISWON                                                 35000013
RDSGET   LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 35100019
         GET   (1),(0)                                           A26453 35200019
         SPACE 2                                                        35400013
         L     RJ,PPICOUNT                                              35500013
         LA    RJ,1(0,RJ)                                               35600013
         ST    RJ,PPICOUNT         ADD 1 TO RECORD COUNT                35700013
         ST    RB,WADDRESS         SET FOR RE-INIT. ENTRY               35800013
         ST    RB,ADRHOLD                                               35900013
RDSISWON LA    RB,ADRHOLD          SET UP PARAMETER FOR USER MOD        36000013
*                                    WILL BE L RB,ADRHOLD ON USER EOF   36100013
         L     RJ,WNMAX                                                 36200013
         SPACE                                                          36300013
*  USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.           36400013
*    ADDRESS OF INPUT RECORD PASSED IN RB                               36500013
         SPACE                                                          36600013
RDSUEXIT L     RP,PPIX15+4         OVERLAYED IF THIS EXIT NOT ACTIVATED 36700013
*                                  OR IF USER EOF REACHED.              36800013
         BALR  RO,RP               BRANCH TO USER                       36900013
         SPACE 2                                                        37000013
*  USER RETURNS VIA RO WITH PROPER DISPLACEMENT IN RP. HE ALSO PASSES,  37100013
*    IN REG RB, THE ADR OF THE RECORD TO BE INSERTED OR THE ADR OF THE  37200013
*    WORK AREA IF THE USER HAS ALTERED THE RECORD.                      37300013
         SPACE                                                          37400013
         B     *+4(15)                                                  37500013
         B     RDSDONO             ALTER OR DO NOTHING                  37600013
         B     RDSLETE             DELETE A RECORD                      37700013
         B     RDSUEOF             USER END OF FILE                     37800013
         SPACE                                                          37900013
*  INSERT A RECORD                                                      38000013
         SPACE                                                          38100013
RDSMAXCK BCT   RJ,RDSINSRT         CHECK FOR NMAX AND DECREMENT         38200013
         B     RDSMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  38300013
         SPACE 2                                                        38400013
RDSINSRT OI    PPISW1+7,X'20'      SET INSERT SWITCH                    38500013
         L     RF,PPIINSCT                                              38600013
         LA    RF,1(0,RF)                                               38700013
         ST    RF,PPIINSCT         ADD 1 TO INSERT COUNT                38800013
RDSTSTBC LR    RE,RB               SET UP BUFF ADR FOR MOVE             38900013
         ST    RJ,WNMAX            SAVE NMAX REG                        39000013
         ST    RB,WADDRESS         SET FOR REINITIALIZATION ENTRY  1297 39100018
         SR    RF,RF                                                    39200013
         A     RF,PPIBDSVA+8       TEST BIN COUNT                       39300013
         BC    7,RDSRMAX           BRANCH UNLESS BIN COUNT EQUALS ZERO  39400013
         ST    RE,ADRHOLDA         SAVE RCD ADR UNTIL BIN IS AVAILABLE  39500013
         OI    NOFITSW,X'03'       SET NO FIT SWITCH = 11               39600013
         B     RDSBINZ             GO TO NO FIT EXIT                    39700013
         SPACE 2                                                        39800013
RDSDONO  BCT   RJ,RDSNOTM          CHECK FOR NMAX AND DECREMENT         39900013
         B     RDSMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  40000013
         SPACE 2                                                        40100013
RDSNOTM  NI    PPISW1+7,X'DF'     ZERO OUT INSERT SWITCH                40200013
         B     RDSTSTBC            GO CHECK BIN COUNT                   40300013
         SPACE 2                                                        40400013
RDSLETE  NI    PPISW1+7,X'DF'     ZERO OUT INSERT SWITCH                40500013
         L     RF,PPIDELCT                                              40600013
         LA    RF,1(0,RF)                                               40700013
         ST    RF,PPIDELCT         ADD 1 TO DELETE COUNT                40800013
         B     RDSGET              GO GET ANOTHER RECORD                40900013
         SPACE 2                                                        41000013
RDSMSG   STH   RP,WINSALT          SAVE INSERT-ALTER CONDITION          41100013
         L     RO,PPIRMA+4         MESSAGE MODULE ADR                   41200013
         LR    RE,RB               SAVE BUFF ADR                        41300013
         LM    RA,RB,MSGP1A04                                           41400013
         L     RP,PPIADSSC         LOAD PRINT RTN ADR                   41500013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      41600013
         SPACE 2                                                        41700013
*  USER EXIT E16-SORT CAPACITY, NMAX, HAS BEEN REACHED                  41800013
*    CALL MACRO INSTRUCTION EXPANSION                                   41900013
         SPACE                                                          42000013
         LR    RB,RE               RESTORE BUFF ADR                     42100013
         L     RP,PPIX16+4         NMAX EXIT ADR                        42200013
         BALR  RO,RP               BRANCH TO USER                       42300013
         SPACE 2                                                        42400013
*  USER RETURNS TO MODULE VIA RO WITH PROPER DISPLACEMENT IN RP         42500013
         SPACE                                                          42600013
         B     *+4(15)                                                  42700013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         42800013
         B     RDSIGNOR            IGNORE NMAX-CONTINUE SORT            42900013
         SPACE                                                          43000013
*  ABORT THE JOB                                                        43100013
         SPACE                                                          43200013
         L     RP,PPIADSSC                                              43300013
         BAL   RO,16(0,RP)         EXIT TO SORT SYSTEM CONTROL          43400013
         SPACE 2                                                        43500013
RDSSRTCR MVC   RDSNTER(4),K1       OVERLAY ENTRANCE                     43600013
         L     RL,PPINET+4                                              43700013
         B     8(0,RL)             BRANCH TO SORT TO EMPTY TREE         43800013
         SPACE 2                                                        43900013
RDSMPTYT L     RL,PPINET+4                                              44000013
         B     16(0,RL)            BRANCH TO SORT TO CONT. EMPTY TREE   44100013
         SPACE 2                                                        44200013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              44300013
         SPACE 1                                                        44400013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 44500013
         OI    PPISW1+7,X'80'      SET USER EOF FOR ALG.                44600013
         TM    PPISW1+3,X'01'     WAS SYSTEM INPUT EOF REACHED          44700013
         BO    RDSSRTCR           YES, DO NOT DECR PPICOUNT-FLUCH TREE  44800013
         L     RE,PPICOUNT         RCD IN INPUT BFR WILL NOT BE SORTED  44900013
         BCTR  RE,0                DECR PPICOUNT BY ONE                 45000013
         ST    RE,PPICOUNT         RESTORE PPICOUNT                     45100013
         OI    PPISW1+3,X'01'      SET EOF SW, SO ALG. WON'T RETURN     45200013
         B     RDSSRTCR            BR TO FLUSH TREE                     45300013
         SPACE 1                                                        45400013
*  IGNORE NMAX-OVERLAY NMAX TEST WITH A BRANCH                          45500013
         SPACE                                                          45600013
RDSIGNOR MVC   RDSMAXCK(4),K2      OVERLAY NMAX CK IN INSERT LEG        45700013
         MVC   RDSDONO(4),K3       OVERLAY NMAX CK IN ALTER LEG         45800013
         SR    RF,RF                                                    45900013
         AH    RF,WINSALT                                               46000013
         BZ    RDSNOTM             RESUME WITH INPUT RECORD             46100013
         B     RDSINSRT            RESUME WITH INSERT RECORD            46200013
         SPACE 2                                                        46300013
RDSOLAY  LA    RE,12(0)                                                 46400013
         STC   RE,RDSFIT+3         OVERLAY FILLING-FIT EXIT             46500013
         LA    RE,28(0)                                                 46600013
         STC   RE,RDSSPEC-1        OVERLAY FILLING-NO FIT EXIT          46700013
         B     RDSNTER             BRANCH TO NORMAL ENTRANCE            46800013
         SPACE 2                                                        46900013
RDSUEOF  OI    PPISW1+7,X'80'      INDICATE USER EOF                    47000013
         TM    PPISW1+3,X'01'      HAVE WE REACHED INPUT EOF            47100013
         BO    RDSSRTCR            YES - GO EMPTY TREE                  47200013
         MVC   RDSUEXIT(4),K4      OVERLAY AFTER USER EOF               47300013
         MVC   RDSMSG,K7                                                47400013
         L     RB,ADRHOLD          RESTORE ADDR OF RCD IN INPUT BLK     47500013
         MVI   RDSISWON,X'58'      CHANGE LA INSTRUCTION TO L           47600013
         B     RDSNOTM             BRANCH TO MOVE INPUT RECORD          47700013
         SPACE 2                                                        47800013
RDSEOF   TM    PPISW1+7,X'80'     HAS USER REACHED EOF                  47900013
         BO    RDSSRTCR                                                 48000013
         SPACE 1                                                        48100013
         TM    PPISW1+3,X'01'      TEST IF SIMULATED EOF                48200013
         BNO   RDSSRTCR              YES, BRANCH TO FLUSH TREE          48300013
           SPACE 1                                                      48400013
         CLI   REALEOF,X'01'       IS THIS SIM. EOF AFTER               48500013
         BE    RDSSRTCR              REAL EOF                           48600013
         SPACE 1                                                        48700013
         MVI   REALEOF,X'01'       SET SWITCH TO INDICATE REST OF       48800013
*                                    EOF'S ARE SIMULATED                48900013
         SPACE 1                                                        49000013
         MVC   RDSGET(4),K5        OVERLAY AFTER INPUT EOF              49100013
         SR    RB,RB                                                    49200013
         ST    RB,ADRHOLD          INPUT EOF INDICATION TO USER         49300013
         B     RDSISWON            GO TO SET UP FOR BRANCH TO USER      49400013
         SPACE 2                                                        49500013
*        TEST TO SEE WHETHER TO FLUSH TREE AND MERGE RECORDS ONTO       49600013
*        ONE REEL OF TAPE                                               49700013
         SPACE 1                                                        49800013
RDSRMAX  L     RC,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   49900013
         MVC   WRCDLEN(2),0(RE)    MAX NO OF BYTES ON ONE REEL TAPE     50000013
         AH    RC,WRCDLEN                                               50100013
         ST    RC,WRMAX            SAVE                                 50200013
         C     RC,PPIRMAX          HAVE RMAX BYTES BEEN EXCEEDED?       50300013
         BH    RDSRMXCT            BRANCH ON YES                        50400013
         B     RDSPTB                                                   50500013
         SPACE 2                                                        50600013
*        ENOUGH BYTES HAVE BEEN READ IN TO FILL ONE REEL OF TAPE        50700013
         SPACE 1                                                        50800013
RDSRMXCT SR    RE,RE                                                    50900013
         ST    RB,WADDRESS         SAVE ADDRESS OF THIS RECORD          51000013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   51100013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  51200013
         B     RDSSRTCR            BRANCH TO OVERLAY DEBLOCK            51300013
         SPACE 2                                                        51400013
         SPACE 2                                                        51500013
NOFITSW  DC    X'00'                                                    51600013
REALEOF  DC    X'00'                                                    51700013
EXPLFOUR DC    H'0'                                                     51800013
WSAVE    DC    3F'0'               FOR MOVE RTN                         51900013
ADRHOLD  DC    F'0'                FOR BUFFER ADR                       52000013
ADRHOLDA DC    F'0'                RECORD ADR WHEN BIN COUNT=0          52100013
ADRHOLDB DC    F'0'                RECORD ADR FOR MOVE RTN AND SORT RTN 52200013
WADDRESS DS    F                   ADDRESS OF NEXT RECORD TO BE MOVED   52300013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     52400013
WNMAX    DC    F'0'                NUMBER OF RCDS TO GO & 1             52500013
WINSALT  DC    H'0'                INSERT-ALTER SWITCH                  52600013
WRCDLEN  DS    H                  HALF-WORD BOUNDARY FOR RECORD LENGTH  52700013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADDRESS     52800013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 52850019
         SPACE 2                                                        52900013
K1       B     RDSMPTYT            OVERLAY TO EMPTY TREE                53000013
K2       B     RDSINSRT            OVERLAY IN INSERT LEG                53100013
K3       B     RDSNOTM             OVERLAY IN ALTER LEG                 53200013
K4       B     RDSDONO             OVERLAY AFTER USER EOF               53300013
K5       B     RDSISWON           OVLY AFTER INPUT E O F                53400013
K6       CLI   NOFITSW,X'01'                                            53500013
K7       NOP   0                                                        53600013
KFOUR    DC    F'4'                                                     53700013
         SMPPI                                                          53800013
* MODULE NAME ***IERRMA***                                              53900013
*                                                                       54000013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        54100013
* PHASE 1 RUNNING PROGRAM.                                              54200013
         SPACE 1                                                        54300013
IERRMA   DSECT                                                          54400013
*                                                                       54500013
       COPY  RMAMAIN                                                    54600013
*                                                                       54700013
         END                                                            54800013
