         TITLE 'IERRDT - OS/360 SORT/MERGE - 360-SM-023   05/11/65'     00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERRDT ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 0                                                 01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION:                                                       01400013
*   OSCL/2314 SORT PHASE. IERRDT IS A DEBLOCK MODULE WHICH HANDLES      01600013
*   VARIABLE LENGTH RECORDS BY WAY OF THE QSAM GET MACTO. THERE ARE NO  01800013
*   USER MODIFICATIONS. THE MODULE LINKS TO THE VARIABLE MOVE ROUTINE   02000013
*   (IERRBF), WHICH MOVES THE VARIABLE LENGTH RECORD FROM THE INPUT     02200013
*   BUFFER INTO RSA BIN(S). UPON RETURN FROM THE MOVE ROUTINE, THE      02400013
*   MODULE PASSES ON TO THE REPLACEMENT SORT THE RECORDS LOCATION IN    02600013
*   RSA. IT ALSO CHECKS TO DETERMINE WHEN RMAX HAS BEEN REACHED,        02800013
*   THE MAXIMUM NUMBER OF BYTES WHICH CAN FIT ONTO ONE REEL OF TAPE,    03000013
*   AND CAUSES RSA TO BE FLUSHED, FOLLOWED BY A MERGE ONTO ONE REEL,    03200013
*   WHICH IS THEN SET ASIDE. IT CAN REINITIALIZE ITSELF TO BEGIN        03400013
*   REFILLING RSA AFTER IT HAS BEEN FLUSHED AND A MERGE TAKEN PLACE.    03600013
         SPACE 1                                                        03800013
*   IF THE 2314 TECH. IS USED, THE RMAX CHECK AT RDTRMAX IS BYPASSED.   04000013
*   THIS BECOMES AN UNCONDITIONAL BRANCH TO RDTMOVE.                    04200013
         SPACE 2                                                        04400013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04600013
*   IERADT                                                              04800013
         SPACE 2                                                        05000013
*LIST OF MACROS USED BY MODULE:                                         05200013
*   SMPPI                                                               05400013
*   GET                                                                 05600013
         SPACE 2                                                        05800013
*ENTRY POINTS:                                                          06000013
         SPACE 1                                                        06200013
*        ENTRY                     ENTRY FROM NETWORK                   06400013
*                                    CALLING SEQUENCE-                  06600013
*                                      L     RL,PPIDEB+4                06800013
*                                      B     8(RL)     DURING TREE FILL 07000013
         SPACE 1                                                        07200013
*                                      L     RL,PPIDEB+4                07400013
*                                      BR     RL    ONCE-WHEN TREE FULL 07600013
         SPACE 1                                                        07800013
*        ENTRY                     ENTRY FROM BLOCK                     08000013
*                                    CALLING SEQUENCE-                  08200013
*                                      L     RL,PPIDEB+4                08400013
*                                      B     8(RL)                      08600013
         SPACE 1                                                        08800013
*        ENTRY                     ENTRY FROM EOF ROUTINE               09000013
*                                    CALLING SEQUENCE-                  09200013
*                                      L     RL,PPIDEB+4                09400013
*                                      B     4(RL)                      09600013
*   FROM INITIALIZATION ROUTINE    ENTRY FROM: INITILIZATION ROUTINE    09800013
*                                    CALLING SEQUENCE-                  10000013
*                                      L     RL,PPIDEB+4                10200013
*                                      B     12(RL)                     10400013
         SPACE 2                                                        10600013
*INPUT: PPI FIELDS REFERENCED -                                         10800013
         SPACE 1                                                        11000013
*   PPIBDSVA    PPINET      PPISTDCB                                    11200013
*   PPICOUNT    PPIRMAX                                                 11400013
         SPACE 2                                                        11600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED -                            11800013
         SPACE 1                                                        12000013
*   PPIBDSVA    PPICOUNT    PPISW1                                      12200013
         SPACE 2                                                        12400013
*EXTERNAL ROUTINES:                                                     12600013
         SPACE 1                                                        12800013
*        IERRBF                    USED TO MOVE RECORDS FROM INPUT      13000013
*                                    BUFFER TO RSA.                     13200013
         SPACE 2                                                        13400013
*EXTERNAL PARAMETERS - N/A                                              13600013
*EXTERNAL PARAMETERS - N/A                                              13800013
*                                                                       14000013
*                                                                       14200013
*EXITS-NORMAL:                                                          14400013
         SPACE 1                                                        14600013
*   NETWORK - PASS ADDRESS OF EACH INCOMING RECORD.                     14800013
         SPACE 2                                                        15000013
*EXITS-ERROR: N/A                                                       15200013
         SPACE 2                                                        15400013
*TABLES/WORK AREAS:                                                     15600013
         SPACE 1                                                        15800013
*   WORK AREA AT WSAVE IS FOR SAVING 3 REGISTERS OF INFORMATION GIVEN   16000013
*   BY THE MOVE MODULE (IERRBF).                                        16200013
*   WORK AREA AT WSAVAIL IS TO HOLD THE ADDRESS OF THE RECORD CURRENTLY 16400013
*   BEING MOVED INTO RSA.                                               16600013
*   WRMAX - COUNT OF RECORDS USED TO COMPARE WITH PPIRMAX               16800013
         SPACE 2                                                        17000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  17200013
         SPACE 2                                                        17400013
*NOTES:                                                                 17600013
*   THIS MODULE IS USED IN THE OSCL/2314 SORT PHASE FOR VARIABLE        17800013
*   LENGTH RECORDS WITHOUT USER EXITS.                                  18000013
         EJECT                                                          18200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            18400013
         SPACE 1                                                        18600013
RA       EQU   0                   CONTENTS IN - WHEN ENTERED FROM THE  18800013
*                                    MOVE ROUTINE ON A CONDITION WHERE  19000013
*                                    THE RECORD DID NOT FIT IT CONTAINS 19200013
*                                    THE NUMBER OF BYTES YET TO MOVE.   19400013
*                                  USED - NOT USED.                     19600013
*                                  CONTENTS OUT - RESTORED TO VALUE OF  19800013
*                                    CONTENTS IN ONLY WHEN RETURNING TO 20000013
*                                    MOVE ROUTINE TO COMPLETE MOVE.     20200013
RB       EQU   1                   CONTENTS IN - NUMBER OF BINS USED    20400013
*                                    WHEN ENTERED FROM MOVE ROUTINE.    20600013
*                                              - ADDRESS OF RECORD WHEN 20800013
*                                    ENTERED FROM QSAM GET ROUTINE.     21000013
*                                  USED - GENERAL WORK REGISTER.        21200013
*                                  CONTENTS OUT - 0 OR 8 WHEN BRANCHING 21400013
*                                    TO MOVE ROUTINE. 0=NORMAL-8-LAST   21600013
*                                    RECORD DIDN'T FIT IN RSA.          21800013
RC       EQU   2                   CONTENTS IN - N/A                    22000013
*                                  USED - GENERAL WORK REGISTER.        22200013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  22400013
*                                    INPUT BUFFER WHEN BRANCHING TO     22600013
*                                    NETWORK.                           22800013
RD       EQU   3                   CONTENTS IN - N/A                    23000013
*                                  USED - GENREAL WORK REGISTER.        23200013
*                                  CONTENTS OUT - ADDRESS OF RECORD IN  23400013
*                                    RSA WHEN BRANCHING TO NETWORK.     23600013
RE       EQU   4                   CONTENTS IN - POINTER TO PORTION OF  23800013
*                                    RECORD IN INPUT BUFFER WHEN MOVE   24000013
*                                    ROUTINE RETURNS BECAUSE RECORD     24200013
*                                    DIDN'T FIT IN RSA.                 24400013
*                                  USED - GENREAL WORK REGISTER.        24600013
*                                  CONTENTS OUT - ADDRESS OF DCB WHEN   24800013
*                                    BRANCHING TO QSAM GET ROUTINE.     25000013
*                                               - ADDRESS OF RECORD IN  25200013
*                                    INPUT BUFFER WHEN BRANCHING TO THE 25400013
*                                    MOVE ROUTINE.                      25600013
RF       EQU   5                   CONTENTS IN - POINTER TO CHAIN       25800013
*                                    ADDRESS OF LAST BIN USED UPON      26000013
*                                    RETURN FROM MOVE ROUTINE.          26200013
*                                  USED - GENERAL WORK REGISTER.        26400013
*                                  CONTENTS OUT - POINTER TO NEXT       26600013
*                                    AVAILABLE BIN IN RSA WHEN BRANCH-  26800013
*                                    ING TO MOVE ROUTINE.               27000013
RG       EQU   6                   CONTENTS IN - N/A                    27200013
*                                  USED - WORK REGISTER                 27400013
*                                  CONTENTS OUT - N/A                   27600013
RH       EQU   7                   CONTENTS IN - N/A                    27800013
*                                  USED - WORK REGISTER                 28000013
*                                  CONTENTS OUT - N/A                   28200013
RI       EQU   8                   CONTENTS IN - N/A                    28400013
*                                  USED - WORK REGISTER                 28600013
*                                  CONTENTS OUT - N/A                   28800013
RJ       EQU   9                   NOT USED.                            29000013
RK       EQU   10                  NOT USED.                            29200013
RL       EQU   11                  CONTENTS IN - ADDRESS OF IERRDT.     29400013
*                                  USED - MODULE BASE REGISTER.         29600013
*                                  CONTENTS OUT - ADDRESS OF NETWORK.   29800013
RM       EQU   12                  NOT USED.                            30000013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI.        30200013
*                                  USED - BASE REGISTER FOR PPI.        30400013
*                                  CONTENTS OUT - ADDRESS OF PPI.       30600013
RO       EQU   14                  CONTENTS IN - N/A                    30800013
*                                  USED - RETURN REGISTER ON BRANCH TO  31000013
*                                    MOVE ROUTINE.                      31200013
*                                  CONTENTS OUT - N/A                   31400013
RP       EQU   15                  CONTENTS IN - N/A                    31600013
*                                  USED - BRANCH REGISTER TO MOVE RTN.  31800013
*                                  CONTENTS OUT - ADDRESS OF MOVE RTN.  32000013
         SPACE 2                                                        32200013
*START OF MODULE CODE PROPER:                                           32400013
         SPACE 2                                                        32600013
IERRDT   CSECT                                                          32800013
         USING *,RL                                                     33000013
         USING IERRCA,RN                                                33200013
IERDD1   B     RDTOLAY             GO TO OVERLAY EXITS                  33400013
         B     RDTEOF              GO TO EOF ROUTINE                    33600013
         B     RDTBEGIN            NORMAL ENTRY TO DEBLOCK ANOTHER RCD  33800013
         SPACE 2                                                        34000013
*        ENTRY TO REINITIALIZE TO BEGIN REFILLING THE TREE              34200013
         SPACE 1                                                        34400013
         LA    RE,4                CHANGE ENTRIES TO NETWORK            34600013
         STC   RE,RDTFIT+3                                              34800013
         LA    RE,24                                                    35000013
         STC   RE,RDTNORM-1                                             35200013
         MVC   RDTBEGIN(8),KREINITI                                     35400013
         SPACE 2                                                        35600013
*        CHAIN BINS TOGETHER BY PUTTING IN EACH BIN THE ADDRESS OF THE  35800013
*        NEXT AVAILABLE BIN. SAVE THE ADDRESS OF THE FIRST AVAILABLE    36000013
*        BIN IN PPIBDSVA+4 AND THE TOTAL NUMBER OF AVAILABLE BINS IN    36200013
*        PPIBDSVA+8.                                                    36400013
         SPACE 1                                                        36600013
         SR    RD,RD                                                    36800013
         ST    RD,PPIBDSVA+8      REINITIALIZE TOTAL OF AVAILABE BINE   37000013
         IC    RD,PPILAB08         NUMBER OF RSA AREAS                  37200013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              37400013
         L     RG,0(RH)            ADDRESS OF THIS RSA AREA BIN         37600013
         ST    RG,PPIBDSVA+4       SAVE ADDRESS OF FIRST RSA BIN        37800013
         SPACE 1                                                        38000013
RDAAAA   L     RF,4(RH)            NO. BYTES IN THIS RSA AREA           38200013
         LA    RI,RDBBBB           LOAD RETURN REG FOR THIS LOOP CALC   38400013
         SR    RE,RE                                                    38600013
         D     RE,PPIBINSZ         RF = NO. BINS IN THIS RSA AREA       38800013
         L     RE,PPIBDSVA+8       TOTAL NO. BINS IN RSA SO FAR         39000013
         AR    RE,RF               UPDATE BIN COUNT                     39200013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               39400013
         SPACE 1                                                        39600013
RDBBBB   BCT   RF,RDDDDD           DECR NO. BINS CTR FOR THIS RSA       39800013
*                                    BR IF MORE BINS IN THIS RSA        40000013
         BCT   RD,RDCCCC           DECR NO. OF RSA'S CTR. BR IF MORE    40200013
*                                    RSA'S. THE LAST BIN IN THE LAST    40400013
*                                    RSA HAS NO CHAIN ADDRESS.          40600013
         B     RDFFFF              BR TO LOAD MOVE PARAMETERS           40800013
         SPACE 1                                                        41000013
RDCCCC   LA    RI,RDEEEE           RESET RETURN REG FOR THIS LOOP       41200013
RDDDDD   A     RG,PPIBINSZ         ADDRESS OF THIS BIN + BIN SIZE       41400013
         LR    RE,RG               SAVE ADDRESS OF NEXT BIN             41600013
         S     RE,KFOUR            PTS TO AREA IN PREVIOS BIN TO PUT    41800013
*                                    THE CHAIN AD OF NEXT BIN (IN RG)   42000013
         ST    RG,0(RE)            PREVIOUS BIN NOW CHAINED TO NEXT BIN 42200013
         BR    RI                  BR TO RDBBBB ON ALL BINS EXCEPT THE  42400013
*                                    LAST BIN IN EACH RSA. OTHERWISE    42600013
*                                    BR TO RDEEEE                       42800013
         SPACE 1                                                        43000013
RDEEEE   LA    RH,8(RH)            UPDATE PPI RSA TABLE PTR TO NEXT     43200013
*                                    RSA ENTRY                          43400013
         L     RG,0(RH)            ADDRESS OF FIRST BIN IN NEXT RSA     43600013
         ST    RG,0(RE)            STORE AS CHAIN ADDRESS IN LAST BIN   43800013
*                                    OF PREVIOUS RSA.                   44000013
         B     RDAAAA                                                   44200013
         SPACE 2                                                        44400013
*        LOAD PARAMS TO MOVE SAVED RECORD INTO RSA                      44600013
         SPACE 1                                                        44800013
RDFFFF   L     RE,ADRHOLD          GET ADDRESS OF SAVED RECORD          45000013
         B     RDTRMAX             B TO RESTART RMAX COUNT              45200013
         SPACE 2                                                        45400013
*        NORMAL ENTRY TO DEBLOCK ANOTHER RECORD                         45600013
         SPACE 1                                                        45800013
RDTBEGIN CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  46000013
         BL    RDTNORM             NO FIT SWITCH OFF                    46200013
         BH    RDTSPEC             NO. OF BINS=0 DURING FILL            46400013
         SR    RE,RE                                                    46600013
         A     RE,PPIBDSVA+8                                            46800013
         BZ    RDTNOFIT                                                 47000013
         L     RA,WSAVE                                                 47200013
         L     RE,WSAVE+4                                               47400013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 47600013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                47800013
         ST    RD,0(RC)            INSERT CHAIN ADDRESS                 48000013
         L     RB,KEIGHT           INDICATE DEBLOCK WITH NOFIT PREV     48200013
RDTBINS  L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          48400013
         L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             48600013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               48800013
         SPACE 2                                                        49000013
         B     RDTNOTF             RECORD DIDN'T FIT                    49200013
         SPACE                                                          49400013
*  RECORD FIT ROUTINE                                                   49600013
         SPACE                                                          49800013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  50000013
         BC    7,RDTUSUAL          LAST MOVE WAS NOT A NO FIT           50200013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       50400013
         SR    RC,RC                                                    50600013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     50800013
         B     RDTUSUAL+4          RD ALREADY LOADED                    51000013
RDTUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RECORD JUST MOVED       51200013
         AH    RD,EXPLFOUR         ADD EXT SIZE + 4                     51400013
         L     RC,ADRHOLD          LOAD BUFFER ADDRESS                  51600013
         L     RE,PPIBDSVA+8                                            51800013
         SR    RE,RB                                                    52000013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     52200013
         L     RE,0(RF)                                                 52400013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         52600013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               52800013
         L     RL,PPINET+4                                              53000013
RDTFIT   B     4(RL)               EXIT TO SORT ON RECORD FIT CONDITION 53200013
         SPACE 2                                                        53400013
*  RECORD NOFIT ROUTINE                                                 53600013
         SPACE                                                          53800013
RDTNOTF  ST    RA,WSAVE                                                 54000013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              54200013
         SR    RD,RD                                                    54400013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         54600013
         OI    NOFITSW,X'01'                                            54800013
         A     RD,WSAVAIL                                               55000013
         BC    7,RDTNOFIT         SECOND NOFIT ON SAME RECORD           55200013
         L     RD,PPIBDSVA+4                                            55400013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      55600013
RDTNOFIT L     RL,PPINET+4                                              55800013
         B     24(RL)              EXIT TO SORT ON RECORD NO FIT        56000013
         SPACE 2                                                        56200013
RDTNORM  LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 56400019
         GET   (1),(0)                                           A26453 56600019
         SPACE 2                                                        57000013
RDTGOT   ST    RB,ADRHOLD          SAVE ADDRESS OF RECORD               57200013
         L     RE,PPICOUNT                                              57400013
         LA    RE,1(RE)                                                 57600013
         ST    RE,PPICOUNT         ADD ONE TO RECORD COUNT              57800013
         LR    RE,RB               SET UP BUFFER ADDRESS FOR MOVE RTN   58000013
         SR    RD,RD                                                    58200013
         A     RD,PPIBDSVA+8                                            58400013
         BC    7,RDTRMAX           BRANCH UNLESS BIN COUNT EQUALS ZERO  58600013
         OI    NOFITSW,X'03'                                            58800013
         B     RDTNOFIT            SPECIAL NO FIT CONDITION             59000013
         SPACE 2                                                        59200013
*  OVERLAY EXITS TO REPLACEMENT - CHANGE FROM FILLING TO NORMAL         59400013
         SPACE                                                          59600013
RDTOLAY  LA    RE,12(0)                                                 59800013
         STC   RE,RDTFIT+3         OVERLAY EXIT TO SORT-RECORD FIT      60000013
         LA    RE,28(0)                                                 60200013
         STC   RE,RDTNORM-1        OVERLAY EXIT TO SORT-RECORD NO FIT   60400013
         B     RDTBEGIN            BRANCH TO NORMAL ENTRY               60600013
         SPACE 2                                                        60800013
*  EOF - SET UP UNCONDITIONAL RETURN TO REPLACEMENT FOR FUTURE USE      61000013
         SPACE                                                          61200013
RDTEOF   MVC   RDTBEGIN(4),RDTFIT-4                                     61400013
         MVC   RDTBEGIN+4(4),KBRANCH    OVERLAY ENTRY WITH UNCOND EXIT  61600013
         L     RL,PPINET+4                                              61800013
         B     8(RL)               ONE TIME EXIT AT EOF                 62000013
         SPACE 2                                                        62200013
RDTSPEC  SR    RE,RE                                                    62400013
         A     RE,PPIBDSVA+8                                            62600013
         BZ    RDTNOFIT                                                 62800013
         NI    NOFITSW,X'00'       ZERO NOFITSW - SPEC CONDITION        63000013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE             63200013
         L     RE,ADRHOLD          LOAD BUFFER ADR                      63400013
RDTMOVE  L     RF,PPIBDSVA+4                                            63600013
         AH    RF,EXPLFOUR         ADD EXT SIZE + 4 TO AVAIL ADR        63800013
         SR    RB,RB               INICATE DEBLOCK TO MOVE ROUTINE      64000013
         B     RDTBINS+4           CONTINUE PREP FOR MOVE               64200013
         SPACE 2                                                        64400013
*        TEST TO SEE WHETHER TO FLUSH TREE AND MERGE RECORDS ONTO       64600013
*        ONE REEL OF TAPE                                               64800013
         SPACE 1                                                        65000013
RDTRMAX  L     RC,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   65200013
         MVC   WRCDLEN(2),0(RE)    MAX NO OF BYTES ON ONE REEL TAPE     65400013
         AH    RC,WRCDLEN                                               65600013
         ST    RC,WRMAX            SAVE                                 65800013
         C     RC,PPIRMAX          HAVE RMAX BYTES BEEN EXCEEDED?       66000013
         BH    RDTRMXCT            BRANCH ON YES                        66200013
         B     RDTMOVE                                                  66400013
         SPACE 2                                                        66600013
*        ENOUGH BYTES HAVE BEEN READ IN TO FILL ONE REEL OF TAPE        66800013
         SPACE 1                                                        67000013
RDTRMXCT SR    RE,RE                                                    67200013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   67400013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  67600013
         B     RDTEOF              BRANCH TO OVERLAY DEBLOCK            67800013
         SPACE 2                                                        68000013
         SPACE 2                                                        68200013
KBRANCH  B     16(RL)                                                   68400013
KREINITI CLI   NOFITSW,X'01'                                            68600013
         BL    RDTNORM                                                  68800013
NOFITSW  DC    X'00'                                                    69000013
ADRHOLD  DC    F'0'                                                     69200013
KEIGHT   DC    F'8'                                                     69400013
KFOUR    DC    F'4'                                                     69600013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     69800013
WSAVE    DC    3F'0'                                                    70000013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADR         70200013
EXPLFOUR DC    H'0'                EXTRACT SIZE + 4                     70400013
WRCDLEN  DS    H                  HALF-WORD BOUNDARY FOR RECORD LENGTH  70600013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 70700019
         SMPPI                                                          70800013
         END                                                            71000013
