         TITLE '      IERRDX - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00400013
         SPACE 2                                                        00800013
*MODULE NAME *** IERRDX ***                                             01200013
         SPACE 2                                                        01600013
*STATUS:CHANGE LEVEL 000                                                02000013
         SPACE 2                                                        02400013
*MODULE FUNCTION/OPERATION: PHASE 3 RUNNING MODULE- F.L. TAPE SORT      02800013
*   THE FUNCTION OF THIS MODULE IS TO DEBLOCK FIXED LENGTH RECORDS      03200013
*   STARTING FROM THE HI CORE END OF THE BUFFER TO THE LOW CORE START   03600013
*   OF THE BUFFER. THIS MODULE IS ONLY EXECUTED WHEN A COPY PASS IN     04000013
*   PHASE 2 IS TO BE ELIMINATED. THE RECORDS IN PHASE 1 HAVE BEEN       04400013
*   BLOCKED FROM HI TO LOW CORE AS IF FOR A NORMAL PHASE 2 READ BACK    04800013
*   OPERATION, HOWEVER THE PHASE 1 ALGORITHM HAS DETERMINED THAT PHASE  05200013
*   2 NEED NOT BE EXECUTED AND PHASE 3 IS BROUGHT IN INSTEAD. WHEN      05600013
*   IERRDX HAS DETERMINED THAT A BUFFER IS EMPTY IT BRANCHES TO THE     06000013
*   READ FORWD MODULE WHICH FILLS THE EMPTY BUFFER AND PASSES BACK THE  06400013
*   INFORMATION TO DEBLOCK TO START DEBLOCKING THIS OR THE ALTERNATE    06800013
*   BUFFER IF DOUBLE BUFFERED. THIS MODULE THEN BRANCHES TO THE MERGE   07200013
*   NETWORK WITH THE ADDRESS OF THE 1ST RECORD IN THIS BUFFER.          07600013
         SPACE 1                                                        08000013
*   NORMAL FLOW IS FROM DEBLOCK TO MERGE NTWK TO BLOCK TO DEBLOCK,ETC.  08400013
         SPACE 2                                                        08800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               09200013
         SPACE 1                                                        09600013
*   IERADX                                                              10000013
         SPACE 2                                                        10400013
*LIST OF MACROS USED BY MODULE:                                         10800013
         SPACE 1                                                        11200013
*   SMPPI                                                               11600013
         SPACE 2                                                        12000013
*ENTRY POINTS:                                                          12400013
         SPACE 1                                                        12800013
*   FROM BLOCK                     ENTRY FROM: BLOCK                    13200013
*                                    CALLING SEQUENCE-                  13600013
*                                      L    RL,PPIDEB+4                 14000013
*                                      B    4(0,RL)                     14400013
*   FROM READ                      ENTRY FROM: IERRGM                   14800013
*                                    CALLING SEQUENCE                   15200013
*                                      L    RL,PPIDEB+4                 15600013
*                                      B    0(0,RL)                     16000013
         SPACE 2                                                        16400013
*INPUT: - PPI FIELDS REFERENCED                                         16800013
         SPACE 1                                                        17200013
*   PPINET     PPIRCDL2                                                 17600013
*   PPIRD                                                               18000013
*   PPISBLCT                                                            18400013
         SPACE 1                                                        18800013
*   ADDRESSES OF MODULES AND TABLES. RECORD LENGTH IS USED IN A BUFFER  19200013
*   ADDRESS CALCULATION                                                 19600013
         SPACE 2                                                        20000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            20400013
         SPACE 1                                                        20800013
*   NONE                                                                21200013
         SPACE 2                                                        21600013
*EXTERNAL ROUTINES:                                                     22000013
         SPACE 1                                                        22400013
*   NONE                                                                22800013
         SPACE 2                                                        23200013
*EXTERNAL PARAMETERS:                                                   23600013
         SPACE 1                                                        24000013
*   SEE REGISTERS                                                       24400013
         SPACE 2                                                        24800013
*EXITS-NORMAL:                                                          25200013
         SPACE 1                                                        25600013
*   TO MERGE NETWORK               EXIT TO: MERGE NETWORK               26000013
*                                    CALLING SEQUENCE-                  26400013
*                                      L    RL,PPINET+4                 26800013
*                                      B    8(0,RL)                     27200013
*   TO READ MODULE                 EXIT TO: IERRGM                      27600013
*                                    CALLING SEQUENCE-                  28000013
*                                      L    RL,PPIRD+4                  28400013
*                                      B    4(0,RL)                     28800013
         SPACE 2                                                        29200013
*EXITS-ERROR:                                                           29600013
         SPACE 1                                                        30000013
*   NONE                                                                30400013
         SPACE 2                                                        30800013
*TABLES/WORK AREAS:                                                     31200013
         SPACE 1                                                        31600013
*   WDBLSV-ADDRESS OF TABLE OF INPUT BUFFER ADDRESSES                   32000013
         SPACE 2                                                        32400013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   32800013
         SPACE 2                                                        33200013
*NOTES: THIS MODULE WILL BE EXECUTED ONLY FOR FIXED LENGTH RECORDS WHEN 33600013
*   A PHASE 2 COPY PASS IS ELIMINATED FOR A TAPE SORT.                  34000013
         EJECT                                                          34400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            34800013
         SPACE 1                                                        35200013
RA       EQU   0                   CONTENTS IN- N/A                     35600013
*                                  USE-NOT USED                         36000013
*                                  CONTENTS OUT- N/A                    36400013
RB       EQU   1                   CONTENTS IN- N/A                     36800013
*                                  USE- READ TO DEBLK(BLOCK COUNT OF    37200013
*                                    NEW BUFFER                         37600013
*                                     - WORK REGISTER                   38000013
*                                  CONTENTS OUT- N/A                    38400013
RC       EQU   2                   CONTENTS IN- N/A                     38800013
*                                  USE- READ TO DEBLK(STRTG ADDR+4 OF   39200013
*                                    A FREE BUFFER)                     39600013
*                                     - DEBLK TO READ(STRTG ADDR OF     40000013
*                                    EMPTY BFR)                         40400013
*                                  CONTENTS OUT- N/A                    40800013
RD       EQU   3                   CONTENTS IN- BLK TO DEBLK(INCR AND   41200013
*                                    ADDR OF WNR RCD IN INPUT BFR)      41600013
*                                  USE- DEBLK TO READ(INCR OF FILE'S    42000013
*                                    EMPTY BFR)                         42400013
*                                     - READ TO DEBLK(INCR OF FILE'S    42800013
*                                    FULL BFR)                          43200013
*                                  CONTENTS OUT- DEBLK TO MERGE(INCR    43600013
*                                    AND ADDR OF NEXT INPUT RCD)        44000013
RE       EQU   4                   CONTENTS IN- N/A                     44400013
*                                  USE- READ TO DEBLOCK(STARTG ADDR OF  44800013
*                                    FILE'S FULL BUFFER)                45200013
*                                     - WORK REGISTER                   45600013
*                                  CONTENTS OUT- N/A                    46000013
RF       EQU   5                   CONTENTS IN- N/A                     46400013
*                                  USE- WORK REGISTER                   46800013
*                                  CONTENTS OUT- N/A                    47200013
RG       EQU   6                   CONTENTS IN- N/A                     47600013
*                                  USE- WORK REGISTER                   48000013
*                                  CONTENTS OUT- N/A                    48400013
RH       EQU   7                   CONTENTS IN- N/A                     48800013
*                                  USE- NOT USED                        49200013
*                                  CONTENTS OUT- N/A                    49600013
RI       EQU   8                   CONTENTS IN- N/A                     50000013
*                                  USE- NOT USED                        50400013
*                                  CONTENTS OUT- N/A                    50800013
RJ       EQU   9                   CONTENTS IN- N/A                     51200013
*                                  USE- NOT USED                        51600013
*                                  CONTENTS OUT- N/A                    52000013
RK       EQU   10                  CONTENTS IN- N/A                     52400013
*                                  USE- NOT USED                        52800013
*                                  CONTENTS OUT- N/A                    53200013
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    53600013
*                                  USE-MODULE BASE REGISTER,READ MODULE 54000013
*                                    ENTRY PT.                          54400013
*                                  CONTENTS OUT- MERGE NTWK ENTRY PT.   54800013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   55200013
*                                  USE- NOT USED                        55600013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   56000013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              56400013
*                                  USE-PPI REFERENCES,REG SAVE AREA     56800013
*                                  CONTENTS OUT-ADDR OF PPI             57200013
RO       EQU   14                  CONTENTS IN- N/A                     57600013
*                                  USE- NOT USED                        58000013
*                                  CONTENTS OUT- N/A                    58400013
RP       EQU   15                  CONTENTS IN- N/A                     58800013
*                                  USE- NOT USED                        59200013
*                                  CONTENTS OUT- N/A                    59600013
         SPACE 2                                                        60000013
*START OF MODULE CODE PROPER:                                           60400013
         SPACE 2                                                        60800013
IERRDX   CSECT                                                          61200013
         USING *,RL                THIS MODULE BASE REGISTER            61600013
         USING IERRCA,RN           ADDR OF PPI                          62000013
         BC    15,RDHDB020         FROM READ                            62400013
         LR    RG,RD               FROM BLOCK-RD HAS INCR & ADDR OF WNR 62800013
         SRL   RD,24               OBTAIN INCR                          63200013
         SPACE 1                                                        63600013
*LOAD BLOCK COUNT OF WNR'S BUFFER. IF EMPTY BRANCH TO READ RTN          64000013
         SPACE 1                                                        64400013
         L     RE,PPISBLCT         ADDR OF INPUT BFRS BLOCK CNT TABLE   64800013
         L     RF,0(RE,RD)         LOAD WINNER'S REMAINING BLOCK COUNT  65200013
         S     RF,KONE             DECR BY 1                            65600013
         BC    12,RDHDB010         BR TO READ IF BUFFER IS EMPTY        66000013
         ST    RF,0(RE,RD)         SAVE ADJUSTED BLOCK COUNT            66400013
         LR    RD,RG               RESTORE RD                           66800013
         SH    RD,PPIRCDL2         OBTAIN NEW INPUT RECORD ADDR         67200013
         SPACE 1                                                        67600013
*INTERFACE WITH NETWORK. RD HAS INCR AND NEW INPUT RCD ADDR             68000013
         SPACE 1                                                        68400013
         L     RL,PPINET+4         ADDR OF MERGE NETWORK                68800013
         B     8(0,RL)             BR TO NETWORK                        69200013
         SPACE 2                                                        69600013
*INTERFACE WITH READ ROUTINE                                            70000013
         SPACE 1                                                        70400013
RDHDB010 L     RG,WDBLSV           ADDR OF BUFFER ADDR TABLE            70800013
         L     RC,0(RG,RD)         THIS FILE'S EMPTY STRTG BFR ADDR     71200013
         L     RL,PPIRD+4          ADDR OF READ RTN                     71600013
         B     4(0,RL)             BR TO READ RTN                       72000013
         SPACE 2                                                        72400013
*RETURN POINT FROM READ RTN. DISPLACE ADDR IN RC BY BLOCK CNT IN RB-1 * 72800013
*   RCD LENGTH TO FIND 1ST RCD TO DEBLOCK IN THE BFR FOR MERGE.         73200013
         SPACE 1                                                        73600013
RDHDB020 L     RF,PPISBLCT         ADDR OF TABLE OF INPUT BFRS BLK CNT  74000013
         ST    RB,0(RF,RD)         STORE NEW BUFFER'S BLOCK COUNT IN    74400013
*                                    ITS APPROPRIATE PLACE.             74800013
         BCTR  RB,0                BLOCK CNT -1                         75200013
         MH    RB,PPIRCDL2         EQUALS CHAR CNT OF RCDS IN THIS BFR  75600013
*                                    MINUS ONE RCD                      76000013
         AR    RB,RC               ADD STRTG ADDR+4 OF THE BUFFER       76400013
         ST    RE,0(RG,RD)         STORE STRTG ADDR OF BUFFER IN TABLE  76800013
*                                    OF INPUT BUFFER ADDRS.             77200013
         SLL   RD,24               REPOSITION INCR                      77600013
         AR    RD,RB               INSERT STRTG ADDR OF 1ST RCD TO DBLK 78000013
         SPACE 2                                                        78400013
*INTERFACE TO MERGE NETWORK                                             78800013
         SPACE 1                                                        79200013
         L     RL,PPINET+4         ADDR OF MERGE NETWORK                79600013
         B     8(0,RL)             BRANCH TO MERGE NTWK                 80000013
         SPACE 2                                                        80400013
*LIST OF WORK AREAS:                                                    80800013
         SPACE 1                                                        81200013
WDBLSV   DC    F'0'                A.P. WILL LOAD TO ADDR OF TABLE OF   81600013
*                                    INPUT BUFFER ADDRS                 82000013
         SPACE 2                                                        82400013
*LIST OF CONSTANTS:                                                     82800013
         SPACE 1                                                        83200013
KONE     DC    F'1'                CONSTANT OF 1                        83600013
         EJECT                                                          84000013
         SMPPI                                                          84400013
         END                                                            84800013
