         TITLE '      IERRGL - OS/360 SORT/MERGE - 360S-SM023 05/14/66' 00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERRGL ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 2 RUNNING MOD. READ FORWARD           00700013
*   THE FUNCTION OF THIS MODULE IS TO READ FORWARD ON THE INTERMEDIATE  00800013
*   DATA SETS USING THE EXCP MACRO. IF USER EXIT E28 SYNAD IS ACTIVATED 00900013
*   THIS MODULE WILL BRANCH TO IT ON ANY READ ERROR. THE PREVIOUSLY     01000013
*   DEFINED ERROR OPTION CODES TO HANDLE THE READ ERROR ARE 20-TERMI-   01100013
*   NATE THE JOB, 40-SKIP THE PHYSICAL RECORD, 80-ACCEPT THE PHYSICAL   01200013
*   RECORD. IF THE EXIT WAS NOT ACTIVATED THE SORT WILL TERMINATE ON    01300013
*   A READ ERROR.                                                       01400013
*        SPACE 1                                                        01500013
*   INITIALLY THIS MODULE PRIMES THE PRIMARY INPUT BUFFERS AND STARTS   01600013
*   THE READS ON ANY ALTERNATE BUFFERS. WHEN DEBLOCK COMES TO IERRGL    01700013
*   FOR A FULL BUFFER, IERRGL DETERMINES WHETHER THERE IS FULL OR       01800013
*   PARTIAL OR NO OVERLAP AND ISSUES THE NECESSARY READS & WAITS BEFORE 01900013
*   RETURNING TO DEBLOCK WITH A FULL BUFFER.                            02000013
*        SPACE 1                                                        02100013
*   THERE ARE BASICALLY 5 ROUTINES WITHIN THIS MODULE. 1-RUNNING,       02200013
*   2-PRIMING, 3-OVERLAP, 4-ERROR CHECK, 5-END OF FILE. ON END OF FILE  02300013
*   THIS MODULE BRANCHES TO THE MERGE ALGORITHM TO DECREMENT THE MERGE  02400013
*   ORDER BEFORE RETURNING TO DEBLOCK.                                  02500013
         SPACE 2                                                        02600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               02700013
         SPACE 1                                                        02800013
*   IERAGL                                                              02900013
         SPACE 2                                                        03000013
*LIST OF MACROS USED BY MODULE:                                         03100013
         SPACE 1                                                        03200013
*   SMPPI                                                               03300013
*   EXCP                                                                03400013
*   WAIT                                                                03500013
*   CLOSE                                                               03600013
         SPACE 2                                                        03700013
*ENTRY POINTS:                                                          03800013
         SPACE 1                                                        03900013
*   FROM AGORITHM                  ENTRY FROM:ALGORITHM                 04000013
*                                    CALLING SEQUENCE-                  04100013
*                                      L    RL,PPIRD+4                  04200013
*                                      B    4(0,RL)    PRIME TIME       04300013
*                                      BR   RO         EOF-PRIME TIME   04400013
*   FROM DEBLOCK                   ENTRY FROM:DEBLOCK                   04500013
*                                    CALLING SEQUENCE-                  04600013
*                                      L    RL,PPIRD+4                  04700013
*                                      B    8(0,RL)    RUN TIME         04800013
*   FROM USER READ ERROR SYNAD     ENTRY FROM:EXIT E28 SYNAD            04900013
*                                    CALLING SEQUENCE-                  05000013
*                                      BR   RO         ERROR CK TIME    05100013
         SPACE 2                                                        05200013
*INPUT: - PPI FIELDS REFERENCED                                         05300013
         SPACE 1                                                        05400013
*   PPIALG     PPIDEB2    PPILAB03   PPISRTBL                           05500013
*   PPIADSSC   PPIBLK2    PPIRCDL2   PPIMRGMX                           05600013
*   PPINETM    PPISTDCB   PPIBDSVA   PPISBLCT                           05700013
         SPACE 1                                                        05800013
*   VARIOUS LINKAGE ADDRS,AND INFO FOR CALCULATIONS                     05900013
         SPACE 2                                                        06000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            06100013
         SPACE 1                                                        06200013
*   PPIWKARE                                                            06300013
*   PPIPSVA                                                             06400013
*   PPISW1                                                              06500013
         SPACE 1                                                        06600013
*   WORK AREAS AND TABLES,SET READ ERROR BIT IN PPISW1                  06700013
         SPACE 2                                                        06800013
*EXTERNAL ROUTINES:                                                     06900013
         SPACE 1                                                        07000013
*   NONE                                                                07100013
         SPACE 2                                                        07200013
*EXTERNAL PARAMETERS:                                                   07300013
         SPACE 1                                                        07400013
*   SEE REGISTERS                                                       07500013
         SPACE 2                                                        07600013
*EXITS-NORMAL:                                                          07700013
         SPACE 1                                                        07800013
*   TO ALGORITHM                   EXIT TO:ALGORITHM                    07900013
*                                    CALLING SEQUENCE-                  08000013
*                                      L    RL,PPIALG+4                 08100013
*                                      BAL  RO,12(0,RL) EOF-PRIME TIME  08200013
*   TO SORT SYSTEM CONTROL         EXIT TO:SSC                          08300013
*                                    CALLING SEQUENCE-                  08400013
*                                      L    RP,PPIADSSC                 08500013
*                                      B    16(0,RP)                    08600013
*   TO MERGE NETWORK               EXIT TO:NETWORK                      08700013
*                                    CALLING SEQUENCE-                  08800013
*                                      L    RL,PPINETM+4                08900013
*                                      B    4(0,RL)    END INPUT SEQU.  09000013
*   TO BFR TABLE ROUTINE           EXIT TO:BFR TABLE RTN                09100013
*                                    CALLING SEQUENCE-                  09200013
*                                      L    RL,PPIDEB2+4                09300013
*                                      BR   RL         PRIME TIME       09400013
*   TO DEBLOCK                     EXIT TO:DEBLOCK                      09500013
*                                    CALLING SEQUENCE-                  09600013
*                                      L    RL,PPIBLK2+4                09700013
*                                      B    4(0,RL)    RUN TIME         09800013
         SPACE 2                                                        09900013
*EXITS-ERROR:                                                           10000013
         SPACE 1                                                        10100013
*   TO USER SYNAD EXIT             EXIT TO:E28 SYNAD                    10200013
*                                    CALLING SEQUENCE-                  10300013
*                                      L    RP,ADCONE28                 10400013
*                                      BALR RO,RP      ERROR CHECK TIME 10500013
         SPACE 2                                                        10600013
*TABLES/WORK AREAS:                                                     10700013
         SPACE 1                                                        10800013
*   WSAVE-REGISTER SAVE AREA ON EVERY INPUT EOF                         10900013
*   WSAVEB-BLOCK COUNT OF BUFFER JUST FILLED                            11000013
*   TINCR-TABLE OF INPUT EOF INCREMENTS AT PRIME TIME                   11100013
*   TFCNT-TABLE OF INPUT FILE COUNTERS                                  11200013
*   WSENSE0-WILL CONTAIN SENSE BYTE 0 ON UNIT CHECK                     11300013
*   PPIWKARE-TABLE OF INPUT RCD ADDRS AT PRIME TIME                     11400013
         SPACE 2                                                        11500013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   11600013
         SPACE 2                                                        11700013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY BALANCED TAPE SORT INVOLVING   11800013
*   A READ FORWARD EXECUTION TO SAVE A COPY PASS.                       11900013
         EJECT                                                          12000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            12100013
         SPACE 1                                                        12200013
RA       EQU   0                   CONTENTS IN-N/A                      12300013
*                                  USE-READ TO E28(INCR TO CCW IN IOB   12400013
*                                    AND IOB ADDR)                      12500013
*                                     -WORK REGISTER                    12600013
*                                  CONTENTS OUT-N/A                     12700013
RB       EQU   1                   CONTENTS IN-N/A                      12800013
*                                  USE-READ TO E28(DCB ADDR OF UNIT     12900013
*                                    WITH ERROR)                        13000013
*                                     -WORK REGISTER                    13100013
*                                  CONTENTS OUT-READ TO DBLK(BLOCK CNT) 13200013
RC       EQU   2                   CONTENTS IN-DBLK TO READ(ADDR OF     13300013
*                                    EMPTY BUFFER)                      13400013
*                                  USE-WORK REGISTER                    13500013
*                                  CONTENTS OUT-READ TO DBLK(PTR TO 1ST 13600013
*                                    RCD IN THE BUFFER)                 13700013
RD       EQU   3                   CONTENTS IN-DBLK TO READ(INCR OF THE 13800013
*                                    UNIT W/THE EMPTY BUFFER)           13900013
*                                  USE-READ TO ALG(INCR OF EOF UNIT-AT  14000013
*                                    PRIME TIME)                        14100013
*                                     -WORK REGISTER                    14200013
*                                  CONTENTS OUT-READ TO DBLK(INCR OF    14300013
*                                    FILE W/THE FULL BUFFER)            14400013
RE       EQU   4                   CONTENTS IN-N/A                      14500013
*                                  USE-WORK REGISTER                    14600013
*                                  CONTENTS OUT-READ TO DBLK(STARTG     14700013
*                                    ADDR OF THE FULL BUFFER)           14800013
RF       EQU   5                   CONTENTS IN-N/A                      14900013
*                                  USE-IOB DSECT BASE REGISTER          15000013
*                                     -WORK REGISTER                    15100013
*                                  CONTENTS OUT-N/A                     15200013
RG       EQU   6                   CONTENTS IN-N/A                      15300013
*                                  USE-DCB DSECT BASE REGISTER          15400013
*                                     -WORK REGISTER                    15500013
*                                  CONTENTS OUT-N/A                     15600013
RH       EQU   7                   CONTENTS IN-N/A                      15700013
*                                  USE-WORK REGISTER                    15800013
*                                  CONTENTS OUT-N/A                     15900013
RI       EQU   8                   CONTENTS IN-N/A                      16000013
*                                  USE-WORK REGISTER                    16100013
*                                  CONTENTS OUT-N/A                     16200013
RJ       EQU   9                   CONTENTS IN-N/A                      16300013
*                                  USE-WORK REGISTER                    16400013
*                                  CONTENTS OUT-N/A                     16500013
RK       EQU   10                  CONTENTS IN-N/A                      16600013
*                                  USE-NOT USED                         16700013
*                                  CONTENTS OUT-N/A                     16800013
RL       EQU   11                  CONTENTS IN-THIS MODULE ENTRY PT     16900013
*                                  USE-MODULE BASE REGISTER,BFR TABLE   17000013
*                                    RTN AND ALG ENTRY PTS              17100013
*                                  CONTENTS OUT-DEBLOCK ENTRY PT        17200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   17300013
*                                  USE-NOT USED                         17400013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   17500013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              17600013
*                                  USE-PPI REFERENCES,REG SAVE AREA     17700013
*                                  CONTENTS OUT-ADDR OF PPI             17800013
RO       EQU   14                  CONTENTS IN-N/A                      17900013
*                                  USE-RETURN REG FROM ALGORITHM AND    18000013
*                                    E28 SYNAD                          18100013
*                                  CONTENTS OUT-N/A                     18200013
RP       EQU   15                  CONTENTS IN-N/A                      18300013
*                                  USE-BRANCH REGISTER TO E28 SYNAD AND 18400013
*                                    SORT SYSTEM CONTROL                18500013
*                                  CONTENTS OUT-N/A                     18600013
         SPACE 2                                                        18700013
*START OF MODULE CODE PROPER:                                           18800013
         SPACE 2                                                        18900013
IERRGL   CSECT                                                          19000013
*C326000,D327000                                                 A31855 19010021
*C369000                                                         A31871 19020020
*                                                                A26439 19050019
         USING *,RL                THIS MODULE BASE REGISTER            19100013
         USING IERRCA,RN           PPI BASE REG(DSECT)                  19200013
         USING IERIOB,RF           IOB BASE REG(DSECT)                  19300013
         USING IHADCB,RG           DCB BASE REG(DSECT)                  19400013
         SPACE 2                                                        19500013
*START OF ACTUAL CODE                                                   19600013
         SPACE 1                                                        19700013
IERDGB2D BC    0,IERDGB2D          DUMMY ENTRY                          19800013
         B     RGBPR200            ENTRY FROM ALG-PRIME TIME            19900013
         SPACE 2                                                        20000013
*ENTRY FROM DEBLOCK DURING RUN TIME. RC-ADDR OF EMPTY INPUT BLOCK. RD-  20100013
*   INCREMENT OF THE INPUT UNIT.                                        20200013
         SPACE 1                                                        20300013
         STM   RC,RH,KSAVE         SAVE REGS                            20400013
         ST    RC,IERDGB2D         ALSO SAVE RC SEPARATELY              20500013
RGBCKEOS TM    2(RC),X'07'         IS THIS AN EOS BFR. A.P. WILL OVLAY  20600013
*                                    THE 2 W/6 FOR V.L. BUFFER          20700013
         BZ    RGBST010            BR IF NOT EQUAL TO EOS BFR           20800013
         SPACE 2                                                        20900013
*INTERFACE TO MERGE NETWORK ON END OF SEQUENCE FOR THIS UNIT            21000013
         SPACE 1                                                        21100013
RGBRTEOS L     RL,PPINETM+4                                             21200013
         B     4(0,RL)             BR TO MERGE ON AN INPUT EOS          21300013
         SPACE 2                                                        21400013
*THERE IS NO EOS ON THIS FILE. IF THERE IS NO ALTERNATE BUFFER ISSUE A  21500013
*   READ ON THIS FILE(TO FILL THE EMPTY BFR) AND A WAIT, OTHERWISE      21600013
*   ISSUE A WAIT ON THE ALTERNATE BUFFER.                               21700013
         SPACE 1                                                        21800013
RGBST010 L     RG,PPISTDCB         PTR TO INPUT DCB ADDR TABLE          21900013
         L     RG,0(RD,RG)         THIS FILE'S DCB ADDR                 22000013
         L     RF,DCBIOBAD         THIS DCB'S IOB ADDR                  22100013
         TM    DCBBUFNO,X'02'      TEST IF 2 BUFFERS FOR THIS FILE      22200013
         BO    RGBAL020            BR IF 2,TO WAIT ON THE ACT BFR       22300013
         EXCP  (RF)                READ FWD                             22400013
         BAL   RE,RGBEOSCK         BR TO WAIT & CK IF EOS BFR.          22500013
         SPACE 2                                                        22600013
*AT THIS POINT RB-NO OF RCDS IN THE BFR(F.L) OR RB-BCC MINUS 4 EOS      22700013
*   BYTES(V.L.).IT INCLUDES THE 4 BCC BYTES FOR V.L. WHICH BLOCK WILL   22800013
*   SUBTRACT.                                                           22900013
         SPACE 1                                                        23000013
RGBRTRN  LM    RC,RH,KSAVE         RC NOW CONTAINS STRTG ADDR OF THE    23100013
*                                    FILLED BUFFER.                     23200013
         SPACE 2                                                        23300013
*INTERFACE TO DEBLOCK. THE REGISTERS WILL CONTAIN: RB-BLOCK COUNT,      23400013
*   RC-PTR TO 1ST RCD(LO CORE) IN THE BLOCK, RD-FILE INCR, RE-STRTG     23500013
*   ADDRESS OF THE BLOCK                                                23600013
         SPACE 1                                                        23700013
RGBRTRNV LA    RC,4(0,RC)          RC NOW PTS TO 1ST RCD IN BFR. A.P.   23800013
*                                    WILL OVLAY 4 W/8 TO BYPASS THE 4   23900013
*                                    BYTES FOR THE BCC IN ADDTN TO EOS  24000013
         L     RL,PPIBLK2+4        ADDR OF BLOCK/DEBLOCK                24100013
         B     4(0,RL)             GO TO BLOCK/DEBLOCK RTN.             24200018
         SPACE 2                                                        24300013
*ISSUE A WAIT ON THE BUFFER                                             24400013
         SPACE 1                                                        24500013
RGBEOSCK L     RB,ECBPTR           ADDR OF IOB'S ECB                    24600013
         WAIT  1,ECB=(1)                                                24700013
         BAL   RH,RGBEE100         BR TO EOF/ERROR CHECK RTN            24800013
RGBEOSV  TM    2(RC),X'07'         IS BUFFER EOS.                       24900013
         BCR   12,RE               BR IF NO TO DEBLOCK(NO ALT BFRS) OR  25000013
*                                    TO ALT BFR RTN                     25100013
RGBEOS   MVI   KSAVE+8,C'$'        SET EOS BYTE ON IN HI ORDER BYTE OF  25200013
*                                    BFR ADDR FOR NXT RD ON THIS FILE   25300013
         B     RGBRTRN             RESTORE REGS. THEN GO TO DEBLOCK     25400018
         SPACE 2                                                        25500013
RGBAL020 BAL   RE,RGBEOSCK         WAIT ON FILE-CHECK FOR EOS           25600013
RGBRFBF  BC    0,RGBFL040          A.P. WILL SET THIS NOP TO A BR IF    25700013
*                                    HAVE PARTIAL OVLAP(FLOATING BFRS)  25800013
         SPACE 2                                                        25900013
*ATTACH EMPTY BFR FROM DEBLOCK TO THE FILE VIA THE IOB START PTR AND    26000013
*   DATA ADDR. IN THE CCW                                               26100013
         SPACE 1                                                        26200013
RGBAL030 LA    RC,IERDGB2D         ADDR OF THE BFR                      26300013
         LA    RH,RGBRTRN          RETURN ADDR                          26400013
         B     RGBIOBUP            BR TO ISSUE READ ON BUFFER           26500013
         SPACE 2                                                        26600013
*ERROR CHECKING ROUTINE                                                 26700013
         SPACE 1                                                        26800013
RGBEE100 TM    CSW+4,X'01'         UNIT EXCEPTION IN CSW ON FOR EOF TM  26900013
         BO    RGBEOF              BR IF ON TO EOF ROUTINE              27000013
         TM    CSW+4,X'02'         UNIT CHECK ON IN CSW FOR DEVICE ERR  27100013
         BZ    RGBPRMSK            BR IF NOT ON.CHECK CHANNEL ERROR     27200013
         MVC   WSENSE0,SENSE       SAVE SENSE BYTE.WE HAVE DEVICE ERR   27300013
         B     RGBERROR            ERROR RTN.                           27400018
RGBPRMSK TM    CSW+5,X'08'         CHECK IF CHANNEL ERROR               27500013
         BC    1,RGSTORRF          BR IF ON TO SAVE IOB ADDR BEFORD     27600013
*                                    GOING TO ERROR RTN                 27700013
         SPACE 1                                                        27800013
         L     RC,START            SET RC TO STARTING                   27900013
         L     RC,0(0,RC)            LOCATION IN THE BUFFER             28000013
         TM    CSW+5,X'40'         CHECK IF INCORRECT LENGTH BIT ON     28100013
         BC    8,RGBEE105          NO - BR                              28200013
         SPACE 1                                                        28300013
RGBLSTBK TM    2(RC),X'07'         IS IT LAST BLOCK OF SEQUENCE.        28400013
         BZ    RGSTORRF            NO-BLOCK IS IN ERROR                 28500013
         SPACE 2                                                        28600013
*NO ERRORS ON THIS BUFFER                                               28700013
         SPACE 1                                                        28800013
         NI    DCBIFLGS,X'3F'                                           28900013
RGBEE105 LH    RB,PPILAB03+2       SIZE OF AN INPUT BUFFER              29000013
         SH    RB,CSW+6            SUBTR RESIDUAL COUNT(NO. OF BYTES    29100013
*                                    DIDNT READ IN)                     29200013
         LA    RC,0(0,RC)          CLEAR COMMAND CODE IN RC             29300013
         ST    RC,KSAVE+8          SET RE(IN THE SAVE AREA) FOR DEBLOCK 29400013
         SH    RB,KFOUR            SUBTR EOS BYTES FROM RESIDUAL CNT    29500013
RGBBRVR  BC    0,RGBEE110          A.P. WILL OVLAY TO A BR IF V.L. RCDS 29600013
         SPACE 2                                                        29700013
*COUNT THE NUMBER OF RECORDS IN THE FIXED LENGTH BLOCK                  29800013
         SPACE 1                                                        29900013
         SR    RO,RO               RECORD CTR                           30000013
RGBFIX   SH    RB,PPIRCDL2         SORT RECORD LENGTH                   30100013
         LA    RO,1(0,RO)          ADD 1 TO RECORD CTR                  30200013
         CH    RB,PPIRCDL2         CHECK TO SEE IF MORE RCDS IN BUFFER  30300013
         BC    10,RGBFIX           BR ON RB =OR GTR.THUS MORE RCDS      30400013
*                                    REMAIN IN BUFFER                   30500013
         LR    RB,RO               RB HAS NO OF RCDS IN BUFFER          30600013
RGBEE110 ST    RC,KSAVE            SET RC(IN THE SAVE AREA) FOR DEBLOCK 30700013
         BR    RH                  BR TO RGBEREOS IF E28 ACTIVE & USER  30800013
*                                    WANTS TO SKIP OR RGBBCCV AT        30900013
*                                    PRIME TIME OR RGBEOSV AT RUN TIME  31000013
         SPACE 2                                                        31100013
*END OF FILE ROUTINE. ONLY COME HERE AT PRIME TIME BECAUSE THE RUNNING  31200013
*   PORTION OF RGL ONLY CHECKS FOR EOS. THUS CAN ONLY GET EOF AT PRIME. 31300013
         SPACE 1                                                        31400013
RGBEOF   STM   RD,RJ,KSAVE         SAVE REGISTERS                       31500013
         SR    RA,RA                                                    31600013
         IC    RA,0(0,RD)          OBTAIN FILE INCREMENT                31700013
         LR    RD,RA                                                    31800013
         L     RG,PPISTDCB         DCB ADDR TABLE POINTER               31900013
         L     RG,0(RD,RG)         DCB ADDR                             32000013
         NI    DCBIFLGS,X'3F'      RESET 1ST 2 BITS OF IFLGS FIELD      32100013
         LH    RA,KNNINE           UPDATE FILE CNT TO EOF               32200013
         STC   RD,RGBINST+1        SET I FIELD TO UNIT'S INCR           32300013
         BAL   RH,RGBFLUP          BR TO UPDATE UNIT'S FILE CTR TO EOF  32400013
         SPACE 2                                                        32500013
         OI    DCBOFLGS,X'04'      TURN OFF FLAG BITS IN DCB     A31855 32600021
         CLOSE ((RG))              CLOSE AND REWIND THIS FILE           32800013
         L     RG,PPISTDCB                                              32900013
         AR    RG,RD               ADD INCR TO GET TO THIS INPUT DCB    33000013
*                                    ADDR                               33100013
         MVI   0(RG),X'80'         TURN ON CLOSE BIT IN DCB ADDR TABLE  33200013
         SPACE 2                                                        33300013
*INTERFACE TO ALGORITHM. EOF AT PRIME TIME                              33400013
         SPACE 1                                                        33500013
         L     RL,PPIALG+4                                              33600013
         BAL   RO,12(0,RL)         GO TO ALGORITHM                      33700018
         SPACE 2                                                        33800013
         LM    RD,RJ,KSAVE         RESTORE REGS FOR PRIMING             33900013
         LR    RO,RE               RE HAS M MINUS NO.OF ACTUAL FILLED   34000013
*                                    BFRS                               34100013
         SLL   RO,2                X4                                   34200013
         BCTR  RO,0                -1                                   34300018
         EX    RO,KMOVE            BYPASS FILE ENTRY W/EOF IN PPIA      34400013
         B     RGBPRLP             BR TO DECR RE & WAIT ON REMAING BFRS 34500013
         SPACE 2                                                        34600013
*RD PTS TO THE CORRECT ENTRY IN THE PPIWKARE TABLE                      34700013
         SPACE 1                                                        34800013
KMOVE    MVC   0(1,RD),4(RD)       SHIFT THE REMAINDER OF THE TABLE UP  34900013
*                                    TO OVLAY THIS EOF ENTRY. THERE     35000013
*                                    MUST BE NO HOLES IN THE TABLE      35100013
         SPACE 2                                                        35200013
*A REAL ERROR HAS OCCURED. EITHER UNIT OR CHANNEL DATA CHECK            35300013
         SPACE 1                                                        35400013
RGBERROR OI    PPISW1+5,X'80'      TURN ON READ ERROR BIT               35500013
RGLTERM  NOP   RGPRTABT            SKIP DIRECTLY TO END IF NO E28       35600013
         L     RB,DCBPTR           DCB ADDR. A.P. WILL OVLAY TO BR TO   35700013
*                                    SSC IF E28 SYNAD NOT ACTIVATED.    35800013
         ST    RF,PPIWKARE         IOB ADDR                             35900013
         MVI   PPIWKARE,X'10'      INCR TO CCW ADDR                     36000013
         L     RA,PPIWKARE         INCR TO CCW IN THE IOB & IOB ADDR    36100013
         SPACE 2                                                        36200013
*INTERFACE TO E28 SYNAD                                                 36300013
         SPACE 1                                                        36400013
         BALR  RO,RP               USER MOD.                            36500018
         SPACE 2                                                        36600013
*PRINT IOS READ ERROR MSG BEFORE ABORTING                               36700013
         SPACE 1                                                        36800013
RGPRTABT LR    RE,RF               ADDRESS OF CURRENT IOB        A31871 36900020
         L     RE,20(0,RE)         ADDR OF IOB'S DCB                    37000013
         L     RE,44(0,RE)         ADDR OF DCB'S DEB                    37100013
         L     RE,32(0,RE)         ADDR OF DEB'S UCB                    37200013
         MVC   PPIRCV(3),13(RE)                                         37300013
         L     RP,PPIADSSC                                              37400013
         BAL   RO,16(0,RP)         SORT SYSTEM CONTROL                  37500018
         SPACE 2                                                        37600013
*RESET ALL ERROR BITS SET BY IOS IN THE DCB & IOB OTHERWISE THE FILE    37700013
*   WILL REMAIN PURGED.                                                 37800013
         SPACE 1                                                        37900013
RGBSKIP  OI    FLG1,X'40'                                               38000013
         NI    CSW+5,X'B7'                                              38100013
         NI    DCBIFLGS,X'3F'                                           38200013
RGBACCPT BAL   RH,RGBEE105         A.P. WILL OVLAY WITH B RGBEE105 ON   38300013
*                                    E28 ACCEPT OPTION=80.              38400013
RGBEREOS TM    2(RC),X'07'         CHECK IF ERROR WAS ON EOS BLOCK.     38500013
         BO    RGBRTEOS            BR IF EOS BFR                        38600013
         EXCP  (RF)                ISSUE NEW READ INTO BUFFER AREA      38700013
         B     RGBEOSCK            GO TO WAIT                           38800018
RGSTORRF ST    RF,PPIWKARE                                              38900013
         B     RGBERROR            ERROR RTN.                           39000018
         SPACE 2                                                        39100013
*ISSUE READ ON THE EMPTY BUFFER                                         39200013
         SPACE 1                                                        39300013
RGBIOBUP L     RE,START            ATTACH THE ALTERNATE CCW TO          39400013
         L     RP,ECBPTR                                                39500013
         MVC   START+1(3),5(RP)    FILE TO HANDLE READS ON              39600013
         ST    RE,4(0,RP)            THE ALTERNATE BUFFER               39700013
         L     RE,START                                                 39800013
         MVC   1(3,RE),1(RC)       STORE BUFFER ADDR. IN CCW            39900013
         MVI   DCBBUFNO,X'02'      UPDATE BUFNO                         40000013
         LR    RE,RB               SAVE BLOCK COUNT                     40100013
         EXCP  (RF)                READ BACKWARDS                       40200013
         LR    RB,RE               RESTORE BLOCK COUNT FOR DEBLOCK      40300013
         BCR   15,RH               RETURN TO EOF RTN.                   40400018
         SPACE 2                                                        40500013
*SEARCH FILE COUNTER TABLE. SET FILE COUNT ON EOF UNIT TO FFFF. RGBINST 40600013
*  'I' FIELD WILL CONTAIN INCR OF EOF UNIT(SET BY EOF RTN)              40700013
         SPACE 1                                                        40800013
RGBFLUP  LA    RC,TFCNT            ADDR OF TABLE OF FILE COUNTERS       40900013
RGBINST  CLI   0(RC),X'00'         COMPARE FOR EOF UNIT                 41000013
         BE    RGBFL120            BR WHEN FOUND                        41100013
         LA    RC,4(0,RC)          UPDATE POINTER                       41200013
         B     RGBINST             CHECK FOR EOF                        41300018
         SPACE 2                                                        41400013
RGBFL120 L     RE,0(0,RC)          OBTAIN THE COUNT OF THE UNIT(COULD   41500013
*                                    BE B, OR 2B)                       41600013
         AR    RE,RA               ADD FFFF(EOF) TO FILE COUNT          41700013
         ST    RE,0(0,RC)          RESTORE COUNT                        41800013
         BCR   15,RH               RETURN TO EOF ROUTINE                41900013
         SPACE 2                                                        42000013
*PARTIAL OVERLAP,FLOATING BUFFER RTN.EXECUTED DURING RUN TIME. AT THIS  42100013
*   POINT WE HAVE AN EMPTY BFR AND A FULL BUFFER ON THE FILE FOR DEBLK. 42200013
*   FIND A FILE W/1 BFR HAVING THE LEAST AMOUNT OF RCDS IN IT. THIS IS  42300013
*   THE FILE TO ATTACH THE ALTERNATE BUFFER(MOST LIKELY TO EMPTY 1ST)   42400013
         SPACE 1                                                        42500013
RGBFL040 LA    RC,TFCNT            ATTACH FLOATING BUFFER TO NEXT       42600013
         ST    RB,KSAVEB           SAVE BLOCK CNT FOR DEBLOCK           42700013
         L     RB,PPISBLCT           FILE TO BE READ                    42800013
         LH    RH,KMRGMX                                                42900013
         LA    RE,PPIPSVA                                               43000013
         SR    RO,RO                                                    43100013
         ST    RO,0(RD,RB)         SET RELEASED FILE'S BLCNT=0          43200013
RGBFL050 IC    RO,0(0,RC)          OBTAIN DEBLOCK'S BLOCK COUNTERS      43300013
         L     RP,0(RO,RB)                                              43400013
         A     RP,0(0,RC)            AND ADD THEM TO READ'S APPROPRIATE 43500013
         ST    RP,0(0,RE)                                               43600013
         LA    RC,4(0,RC)            FILE COUNTERS.                     43700013
         LA    RE,4(0,RE)                                               43800013
         BCT   RH,RGBFL050         GET NEXT COUNTER                     43900018
*                                                                       44000013
         LA    RC,PPIPSVA                                               44100013
         LH    RB,KMRGMX                                                44200013
         STC   RD,RGBINST1+1                                            44300013
         LR    RE,RC                                                    44400013
         BC    15,RGBINST1         CHECK FILE COUNT                     44500018
*                                                                       44600013
*                                                                       44700013
RGBFL060 LA    RE,4(0,RE)          SCAN FOR LOWEST FILE COUNT           44800013
         CLC   1(3,RC),1(RE)                                            44900013
         BC    2,RGBEX070            AND FOR THE RELEASED               45000013
RGBINST1 CLI   0(RE),X'00'                                              45100013
         BC    8,RGBRL080            FILE COUNT                         45200013
RGBLPEND BCT   RB,RGBFL060         CONTINUE SCAN                        45300018
*                                                                       45400013
         LA    RA,PPIPSVA          OBTAIN FILE COUNT ADDRS. VIA         45500013
         SR    RC,RA                 DISPLACEMENTS OF LOWEST AND        45600013
         SR    RP,RA                 RELEASED FROM PPIPSVA              45700013
         LA    RA,TFCNT                                                 45800013
         AR    RP,RA                                                    45900013
         AR    RC,RA                                                    46000013
         MVI   DCBBUFNO,X'01'        RELEASED FILE'S BUFNO(IN DCB)      46100013
         LR    RO,RG                                                    46200013
         LR    RA,RF                                                    46300013
         IC    RB,0(0,RC)          INCR IN NEW FILE COUNT'S FIRST BYTE  46400013
         L     RG,PPISTDCB                                              46500013
         L     RG,0(RB,RG)         DCB  AND IOB ADDRS.                  46600013
         L     RF,DCBIOBAD           OF NEW FILE                        46700013
         L     RE,PPIBDSVA         BUFFER TABLE ADDR.                   46800013
         AR    RE,RB                                                    46900013
         L     RB,KSAVEB           RESTORE BLOCK CNT                    47000013
RGBFBV   CLI   0(RE),C'$'          CK FOR EOS                           47100013
         BC    7,RGBCONT           YES- BRANCH                          47200018
         LR    RG,RO               REATTACH BUFFER TO PREVIOUS          47300013
         LR    RF,RA                                                    47400013
         BC    15,RGBAL030           (IE RELEASED FILE)                 47500013
         SPACE 2                                                        47600013
*CHECK FOR EOS AT PRIMING ON THE FILE W/LEAST RCDS IN ITS BUFFER        47700013
         SPACE 1                                                        47800013
RGBCONT  CLI   WEOSCNT,X'00'       EOS ON THIS LOWEST FILE              47900013
         BC    7,RGBFBV+8          BR IF YES.FALL THRU IF NO            48000013
         L     RE,0(0,RC)          FILE COUNT FOR LOWEST FILE=B.        48100013
         AH    RE,PPISRTBL         ADD B. NOW=2B                        48200013
         ST    RE,0(0,RC)          STORE AS NEW FILE COUNT              48300013
         L     RE,0(0,RP)          FILE COUNT FOR RELEASED FILE=2B      48400013
         SH    RE,PPISRTBL         SUBTRACT B, NOW=B.                   48500013
         ST    RE,0(0,RP)          STORE AS NEW FILE COUNT              48600013
         B     RGBAL030            BR TO ACTUALLY ATTACH EMPTY BFR      48700013
         SPACE 2                                                        48800013
*FOUND A NEW LOWER FILE COUNT                                           48900013
         SPACE 1                                                        49000013
RGBEX070 LR    RC,RE               ADDR OF LOWEST FILE COUNT            49100013
         B     RGBINST1            CHECK FILE COUNT                     49200018
         SPACE 2                                                        49300013
*ADDR IN PPISVA OF UNIT WITH EMPTY BFR                                  49400013
         SPACE 1                                                        49500013
RGBRL080 LR    RP,RE               ADDR OF RELEASED FILE COUNT          49600013
         B     RGBLPEND            CONTINUE SCAN FOR LOWEST FILE        49700018
         SPACE 2                                                        49800013
*PRIMING SUBROUTINE                                                     49900013
         SPACE 1                                                        50000013
RGBPR200 MVI   WEOSCNT,X'00'       RESET EOS CTR FROM PREVIOUS PRIME    50100013
*                                    PASS                               50200013
         LA    RB,TINCR            ADDR OF TABLE OF INCREMENTS          50300013
         ST    RB,AEOSPR                                                50400013
RGBPR220 LA    RE,PPITPTBL         ADDR OF TAPE TABLE                   50500013
         LH    RH,PPIMRGMX         M                                    50600013
         L     RJ,PPISTDCB         DCB TABLE OF ADDRS PTR               50700013
         LA    RD,PPIWKARE                                              50800013
         SPACE 2                                                        50900013
*SEARCH TAPE TABLE FOR INPUT FILES. AS A UNIT IS FOUND ISSUE A READ ON  51000013
*   IT AND RETURN.                                                      51100013
         SPACE 1                                                        51200013
RGBPR230 TM    0(RE),X'80'         TEST FOR INPUT BIT                   51300013
         BO    RGBPR240            BR ON INPUT UNIT                     51400013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE POINTER            51500013
         B     RGBPR230            CHECK NEXT ENTRY IN TABLE            51600018
         SPACE 2                                                        51700013
*PRIME M BUFFERS                                                        51800013
         SPACE 1                                                        51900013
RGBPR240 SR    RG,RG                                                    52000013
         IC    RG,1(0,RE)          INPUT UNIT INCREMENT FROM TAPE TABLE 52100013
         STC   RG,0(0,RD)          STORE IN PPIWKARE 1ST BYTE           52200013
         L     RG,0(RG,RJ)         INPUT UNIT'S DCB ADDR                52300013
         MVC   1(3,RD),DCBIOBAD+1  STORE IT'S IOB ADDR IN NEXT 3 BYTES  52400013
*                                    IN PPIWKARE TABLE                  52500013
         L     RF,DCBIOBAD         IOB ADDR                             52600013
         EXCP  (RF)                READ FORWARD. PRIME 1 INPUT BLOCK    52700013
         LA    RD,4(0,RD)          UPDATE PPIWKARE PTR                  52800013
         LA    RE,2(0,RE)          UPDATE TAPE TABLE PTR                52900013
         BCT   RH,RGBPR230         DECR MERGE ORDER BY 1. GO BACK TO    53000013
*                                    PRIME ANOTHER INPUT BUFFER         53100013
         SPACE 2                                                        53200013
*AT THIS POINT M INPUT BUFFERS HAVE BEEN PRIMED. ISSUE WAITS ON EACH    53300013
*   BUFFER                                                              53400013
         SPACE 1                                                        53500013
         LH    RE,PPIMRGMX         M                                    53600013
         L     RI,PPISBLCT         TABLE OF BLOCK CTRS PTR              53700013
         LA    RJ,TFCNT            PTR  TO TABLE OF FILE CTRS           53800013
         LA    RD,PPIWKARE         PTR TO PPIWKARE TABLE                53900013
RGBPR245 L     RF,0(0,RD)          ADDR OF IOB WE ARE WORKING WITH      54000013
         L     RG,DCBPTR           LOAD DCB ADDR                 A26439 54050019
         L     RB,ECBPTR           ADDR OF THAT IOB'S ECB               54100013
         WAIT  1,ECB=(1)           ISSUE A WAIT ON THE BUFFER(IN ORDER  54200013
*                                    OF PRIMING)                        54300013
         BAL   RH,RGBEE100         BR TO ERROR CHECK RTN                54400013
RGBBCCV  BC    0,RGBPR280          A.P. WILL CHANGE TO A BR FOR V.L RCD 54500013
         L     RP,START                                                 54600013
         MVI   4(RP),X'00'         TURN OFF SILI BIT FOR F.L. RCDS      54700013
RGBPR280 SR    RO,RO                                                    54800013
         IC    RO,0(RD)            INCR OF UNIT WE ARE WORKG WITH(FROM  54900013
*                                    PPIWKARE TABLE)                    55000013
RGBPREOS TM    2(RC),X'07'         IS IT EOS ON COMPLETED READ          55100013
         BO    RGBPR260            BR ON EOS BUFFER                     55200013
         SPACE 2                                                        55300013
*CHECK UNIT FOR AN ALTERNATE BUFFER                                     55400013
         SPACE 1                                                        55500013
         L     RG,DCBPTR           ADDR OF THE IOB'S DCB                55600013
         CLI   DCBBUFNO,X'02'      CHECK DCB FOR 2 BUFFERS(1 IS AN ALT) 55700013
         BE    RGBPR270            BR IF IT HAS AN ALT BFR              55800013
RGBPR250 MVC   2(2,RJ),PPISRTBL    SET UNIT'S TABLE OF FILE COUNTERS TO 55900013
*                                    SORT BLKG=B                        56000013
RGBBRVAR LA    RC,4(0,RC)          F.L- BYPASS EOS INDICATOR            56100013
*                                    V.L- BYPASS EOS & BCC. A.P. WILL   56200013
*                                    OVLAY THE 4 TO AN 8 DISPLACEMENT.  56300013
         STC   RO,0(0,RJ)          STORE INCR IN HI BYTE OF FILE CTR    56400013
         LA    RJ,4(0,RJ)          UPDATE FILE PTR                      56500013
         ST    RB,0(RO,RI)         STORE BLOCK COUNT IN TABLE OF BLOCK  56600013
*                                    CTR FOR THE DEBLOCK RTN.           56700013
         ST    RC,IERDGB2D         SAVE STRTG ADDR OF INPUT BUFFER JUST 56800013
*                                    READ IN.                           56900013
         MVC   1(3,RD),IERDGB2D+1  STORE IN PPIWKARE TABLE NEXT TO INCR 57000013
*                                    FOR MERGE NETWORK                  57100013
         LA    RD,4(0,RD)          UPDATE PPIWKARE PTR                  57200013
RGBPRLP  BCT   RE,RGBPR245         DECR MERGE ORDER,LOOP TO PROCESS     57300013
*                                    NEXT UNIT'S PRIMARY BUFFER.        57400013
         SPACE 2                                                        57500013
*AT THIS POINT M INPUT BUFFERS ARE PRIMED. THEY HAVE BEEN CHECKED FOR   57600013
*   ERRORS. READS ON ALL THE ALTERNATE BUFFERS HAVE BEEN STARTED & THE  57700013
*   IOBS HAVE BEEN UPDATED TO POINT TO THE ALT CCW. THE WAITS WILL BE   57800013
*   ISSUED AT RUN TIME.                                                 57900013
         SPACE 1                                                        58000013
         MVC   KMRGMX(2),PPIMRGMX                                       58100013
         SPACE 2                                                        58200013
*INTERFACE WITH BUFFER TABLE ROUTINE TO BUILD TABLE OF INPUT BUFFER     58300013
*   ADDRESSES(1ST RCD ADDR IN EACH BUFFER FOR NETWORK)                  58400013
         SPACE 1                                                        58500013
         L     RL,PPIDEB2+4                                             58600013
         BR    RL                  BUILD INPUT BUFFER ADDR. TABLE       58700018
         SPACE 2                                                        58800013
*END OF SEQUENCE ROUTINE AT PRIMING TIME. MOVE INCR OF EOS UNIT INTO    58900013
*   INCREMENT TABLE AND UPDATE EOS COUNTER.                             59000013
         SPACE 1                                                        59100013
RGBPR260 L     RP,AEOSPR           PTR TO TABLE OF INCREMENTS           59200013
         MVC   0(1,RP),0(RD)       MOVE INCR OF EOS UNIT INTO TABLE     59300013
*                                    THIS TABLE IS FOR RUN TIME TO TELL 59400013
*                                    WHICH UNITS HIT EOS AT PRIME TIME. 59500013
         LA    RP,1(0,RP)          UPDATE TABLE PTR                     59600013
         ST    RP,AEOSPR           STORE UPDATED PTR                    59700013
         SR    RP,RP                                                    59800013
         IC    RP,WEOSCNT                                               59900013
         LA    RP,1(0,RP)          UPDATE COUNT OF NO. OF EOS UNITS     60000013
         STC   RP,WEOSCNT          RESTORE UPDATED COUNTER              60100013
         B     RGBPR250            CHECK SORT BLOCKING                  60200018
         SPACE 2                                                        60300013
*PRIME ALTERNATE BUFFER ROUTINE. SWITCH THE ALTERNATE CCW WITH THE      60400013
*   PRIME CCW AND ISSUE A READ ON THE IOB(ALT CCW ADDR NOW IN IOB)      60500013
         SPACE 1                                                        60600013
RGBPR270 LR    RA,RO               INCR OF UNIT WE ARE WORKING WITH     60700013
         STM   RA,RC,KSAVE                                              60800013
         L     RB,ECBPTR                                                60900013
         L     RP,4(0,RB)          ALT CCW ADDR                         61000013
         MVC   5(3,RB),START+1     MOVE PRIMARY CCW ADDR INTO ALT CCW   61100013
*                                    LOCATION(4 BYTES AFTER ECB)        61200013
         ST    RP,START            STORE ALT CCW ADDR AS NEW PRIMARY    61300013
*                                    CCW ADDR IN THE IOB.               61400013
         EXCP  (RF)                START A READ ON THE ALT. BFR         61500013
         LM    RA,RC,KSAVE         RA=INCR,RB=BLOCK CNT FOR F.L RCDS OR 61600013
*                                    BCC-4 EOS BYTES FOR V.L. RCDS,RC=  61700013
*                                    STRTG ADDR OF PREVIOUS PRMRY BFR.  61800013
         LR    RO,RA               INCR OF THIS INPUT UNIT              61900013
         LH    RP,PPISRTBL         B                                    62000013
         SLL   RP,1                2XB                                  62100013
         STH   RP,2(0,RJ)          STORE IN TABLE OF FILE CTRS FOR      62200013
         B     RGBBRVAR              THIS UNIT                          62300013
         SPACE 2                                                        62400013
*LIST OF ADCONS:                                                        62500013
         SPACE 1                                                        62600013
AEOSPR   DC    A(TINCR)            TABLE OF INCREMENTS PTR              62700013
ADCONE28 DC    F'0'                SYNAD E28 ADDR. LOADED BY A.P.       62800013
         SPACE 2                                                        62900013
*LIST OF WORK AREAS/TABLES:                                             63000013
         SPACE 1                                                        63100013
TINCR    DC    4F'0'               TABLE OF INCREMENTS(EOS UNITS AT     63200013
*                                    PRIME TIME                         63300013
TFCNT    DC    16F'0'              TABLE OF FILE CTRS                   63400013
WSENSE0  DC    X'00'               CONTAINS SENSE BYTE 0 ON UNIT CHECK  63500013
WEOSCNT  DC    X'00'               CTR FOR NO. OF UNITS HITTING EOS     63600013
         SPACE 2                                                        63700013
*LIST OF CONSTANTS:                                                     63800013
         SPACE 1                                                        63900013
KSAVE    DC    7F'0'               WILL HAVE RD-RJ ON EVERY INPUT EOF   64000013
*                                    AND RC-RH DURING RUN TIME          64100013
KSAVEB   DC    1F'0'               BLOCK CNT OF BFR JUST READ IN-FILLED 64200013
*                                    DURING FLOATG BFR RTN              64300013
KNNINE   DC    X'FFFF'             FFFF                                 64400013
KMRGMX   DC    X'0000'             NO. OF INPUT UNITS ENTERING 1ST PASS 64500013
KFOUR    DC    X'0004'             CONSTANT OF FOUR                     64600018
KOUTINCR DC    X'00'               TEMP. STORAGE                        64700018
         EJECT                                                          64800013
         DS    0F                                                       64900013
IERIOB   DSECT ,                   DUMMY IOB- SEE 14.90.1.4             65000013
FLG1     DC    X'00'               IOB EXPANSION                        65100018
FLG2     DC    X'00'               IOB EXPANSION                        65200018
SENSE    DC    AL2(0)              IOB EXPANSION                        65300018
ECBPTR   DC    AL4(0)              IOB EXPANSION                        65400018
CSW      DC    AL4(0)              IOB EXPANSION                        65500018
         DC    AL4(0)              IOB EXPANSION                        65600018
START    DC    AL4(0)              IOB EXPANSION                        65700018
DCBPTR   DC    AL4(0)              IOB EXPANSION                        65800018
RESTART  DC    AL4(0)              IOB EXPANSION                        65900018
INCAMT   DC    AL2(0)              IOB EXPANSION                        66000018
ERRCNTS  DC    AL2(0)              IOB EXPANSION                        66100018
*                                                                       66200013
         EJECT                                                          66300013
         SMPPI                                                          66400013
         EJECT                                                          66500013
         DCBD  DSORG=PS                                                 66600013
         END                                                            66700013
