         TITLE '      IERRGM - OS/360 SORT/MERGE - 360S-SM023 05/24/66' 00100013
         SPACE 2                                                        00200013
*MODULE NAME *** IERRGM ***                                             00300013
         SPACE 2                                                        00400013
*STATUS:CHANGE LEVEL 000                                                00500013
         SPACE 2                                                        00600013
*MODULE FUNCTION/OPERATION: PHASE 3 RUNNING MODULE. READ FORWARD        00700013
*   THE FUNCTION OF THIS READ FORWARD MODULE IS TO FILL INPUT BUFFERS   00800013
*   AS NEEDED BY DEBLOCK VIA THE EXCP MACRO. IF THERE IS PARTIAL        00900013
*   OVERLAP IT WILL ASSIGN AN AVAILABLE BUFFER FROM THE AVAILABLE       01000013
*   BUFFER TABLE TO A UNIT HAVING ONLY 1 BUFFER(THE UNIT WHOSE BUFFER   01100013
*   HAS THE LEAST AMOUNT OF RECORDS IN IT).AS EACH INPUT UNIT GOES TO   01200013
*   EOF ITS BUFFER ADDRESS(ES) ARE PUT IN THE AVAILABLE BUFFER TABLE.   01300013
         SPACE 1                                                        01400013
*   THIS MODULE CHECKS FOR READ ERRORS AND IF USER EXIT E38 SYNAD IS    01500013
*   NOT ACTIVATED IT WILL GO TO SSC TO ABORT THE JOB. IF E38 SYNAD IS   01600013
*   ACTIVATED, THE USER MAY TRY TO FIX THE ERROR HIMSELF AFTER IOS HAS  01700013
*   TRIED TO DO SO.                                                     01800013
         SPACE 2                                                        01900013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               02000013
         SPACE 1                                                        02100013
*   IERAGM                                                              02200013
         SPACE 2                                                        02300013
*LIST OF MACROS USED BY MODULE:                                         02400013
         SPACE 1                                                        02500013
*   DCBD                                                                02600013
*   SMPPI                                                               02700013
*   EXCP                                                                02800013
*   CLOSE                                                               02900013
*   WAIT                                                                03000013
         SPACE 2                                                        03100013
*ENTRY POINTS:                                                          03200013
         SPACE 1                                                        03300013
*   FROM DEBLOCK                   ENTRY FROM:DEBLOCK                   03400013
*                                    CALLING SEQUENCE-                  03500013
*                                      L    RL,PPIRD+4                  03600013
*                                      B    4(0,RL)                     03700013
*   FROM E38 SYNAD                 ENTRY FROM:USER EXIT E38 SYNAD       03800013
*                                    CALLING SEQUENCE-                  03900013
*                                      BR   RO         RETURN           04000013
         SPACE 2                                                        04100013
*INPUT: - PPI FIELDS REFERENCED                                         04200013
         SPACE 1                                                        04300013
*   PPIADSSC   PPISRTBL                                                 04400013
*   PPILAB03   PPISTDCB                                                 04500013
*   PPISBLCT   PPIDEB                                                   04600013
         SPACE 2                                                        04700013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            04800013
         SPACE 1                                                        04900013
*   PPILAB02   PPIWKARE                                                 05000013
*   PPIPSVA                                                             05100013
*   PPISW1                                                              05200013
         SPACE 2                                                        05300013
*EXTERNAL ROUTINES:                                                     05400013
         SPACE 1                                                        05500013
*   NONE                                                                05600013
         SPACE 2                                                        05700013
*EXTERNAL PARAMETERS:                                                   05800013
         SPACE 1                                                        05900013
*   SEE REGISTERS                                                       06000013
         SPACE 2                                                        06100013
*EXITS-NORMAL:                                                          06200013
         SPACE 1                                                        06300013
*   TO DEBLOCK                     EXIT TO:DEBLOCK                      06400013
*                                    CALLING SEQUENCE-                  06500013
*                                      L    RL,PPIBLK2+4                06600013
*                                      B    4(0,RL)                     06700013
         SPACE 2                                                        06800013
*EXITS-ERROR:                                                           06900013
         SPACE 1                                                        07000013
*   EXIT TO USER EXIT E38 SYNAD    EXIT TO:USER SYNAD EXIT E38          07100013
*                                    CALLING SEQUENCE-                  07200013
*                                      L    RP,ADCONE38                 07300013
*                                      BALR RO,RP                       07400013
*                                  EXIT TO:SSC VIA                      07500013
*   TO SSC ON READ ERROR               L    RP,PPIADSSC                 07600013
*                                      B    16(0,RP)                    07700013
         SPACE 2                                                        07800013
*TABLES/WORK AREAS:                                                     07900013
         SPACE 1                                                        08000013
*   TFCNT-FILE COUNT TABLE.4 BYTES PER ENTRY.M ENTRIES.TELLS STATUS OF  08100013
*     EACH ORIGINAL INPUT FILE IN REGARD TO THE NUMBER OF BUFFERS       08200013
*     ATTACHED TO EACH FILE(I.E EITHER 2,1,OR THE FILE WENT TO EOF)     08300013
*   WSENSE0-HOLDS SENSE BYTE ON UNIT CHECK                              08400013
         SPACE 2                                                        08500013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   08600013
         SPACE 2                                                        08700013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY TAPE SORT REQUIRING A READ     08800013
*   FORWARD PASS IN PHASE 3.                                            08900013
         EJECT                                                          09000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            09100013
         SPACE 1                                                        09200013
RA       EQU   0                   CONTENTS IN-N/A                      09300013
*                                  USE-READ TO E28(INCR TO CCW IN IOB   09400013
*                                    AND IOB ADDR)                      09500013
*                                     -WORK REGISTER                    09600013
*                                  CONTENTS OUT-N/A                     09700013
RB       EQU   1                   CONTENTS IN-N/A                      09800013
*                                  USE-WORK REGISTER                    09900013
*                                     -RD TO E38(DCB ADDR OF ERR FILE)  10000013
*                                  CONTENTS OUT-RD TO DBLK(BLOCK CNT OF 10100013
*                                    FULL BFR-F.L,OR CHAR CNT-V.L RCDS) 10200013
RC       EQU   2                   CONTENTS IN-DBLK TO RD(EMPTY BFR     10300013
*                                     STRTG ADDR)                       10400013
*                                  USE-WORK REGISTER                    10500013
*                                  CONTENTS OUT-RD TO DBLK(PTR TO 1ST   10600013
*                                    RCD IN FULL BFR)                   10700013
RD       EQU   3                   CONTENTS IN-DBLK TO RD(INCR OF FILE) 10800013
*                                  USE-WORK REGISTER                    10900013
*                                  CONTENTS OUT-RD TO DBLK(FILE INCR)   11000013
RE       EQU   4                   CONTENTS IN-N/A                      11100013
*                                  USE-WORK REGISTER                    11200013
*                                  CONTENTS OUT-RD TO DBLK(STARTG ADDR  11300013
*                                    OF THE FULL BUFFER)                11400013
RF       EQU   5                   CONTENTS IN-N/A                      11500013
*                                  USE-N/A                              11600013
*                                     -WORK REGISTER                    11700013
*                                     -IOB DSECT BASE REGISTER          11800013
*                                  CONTENTS OUT-N/A                     11900013
RG       EQU   6                   CONTENTS IN-N/A                      12000013
*                                  USE-WORK REGISTER                    12100013
*                                     -DCB DSECT BASE REGISTER          12200013
*                                  CONTENTS OUT-N/A                     12300013
RH       EQU   7                   CONTENTS IN-N/A                      12400013
*                                  USE-WORK REGISTER                    12500013
*                                  CONTENTS OUT-N/A                     12600013
RI       EQU   8                   CONTENTS IN-N/A                      12700013
*                                  USE-NOT USED                         12800013
*                                  CONTENTS OUT-N/A                     12900013
RJ       EQU   9                   CONTENTS IN-N/A                      13000013
*                                  USE-NOT USED                         13100013
*                                  CONTENTS OUT-N/A                     13200013
RK       EQU   10                  CONTENTS IN-N/A                      13300013
*                                  USE-NOT USED                         13400013
*                                  CONTENTS OUT-N/A                     13500013
RL       EQU   11                  CONTENTS IN-THIS MODULE ENTRY PT     13600013
*                                  USE-MODULE BASE REGISTER,NETWK ENTRY 13700013
*                                    PT ON EOF                          13800013
*                                  CONTENTS OUT-DEBLOCK ENTRY PT        13900013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   14000013
*                                  USE-NOT USED                         14100013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   14200013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              14300013
*                                  USE-PPI REFERENCES,REG SAVE AREA     14400013
*                                  CONTENTS OUT-ADDR OF PPI             14500013
RO       EQU   14                  CONTENTS IN-N/A                      14600013
*                                  USE-E38 TO RD(RD RETURN ADDR)        14700013
*                                     -CTR FOR FIXED LENGTH BFR RCDS    14800013
*                                  CONTENTS OUT-N/A                     14900013
RP       EQU   15                  CONTENTS IN-N/A                      15000013
*                                  USE-BR REG TO USER E38 SYNAD         15100013
*                                     -WORK REGISTER                    15200013
*                                  CONTENTS OUT-N/A                     15300013
         SPACE 2                                                        15400013
*START OF MODULE CODE PROPER:                                           15500013
         SPACE 2                                                        15600013
IERRGM   CSECT                                                          15700013
*                                                                A31855 15750021
         USING *,RL                                                     15800013
         USING IERRCA,RN                                                15900013
         USING IERIOB,RF                                                16000013
         USING IHADCB,RG                                                16100013
IERDGB3  BC    0,IERDGB3           DUMMY ENTRY                          16200013
         SPACE 2                                                        16300013
         STM   RC,RH,KSAVE                                              16400013
         ST    RC,IERDGB3                                               16500013
         L     RG,PPISTDCB                                              16600013
         L     RG,0(RD,RG)         APPROPRIATE DCB VIA INCR IN RD       16700013
         L     RF,DCBIOBAD         IOB ADDR.                            16800013
         TM    DCBBUFNO,X'02'      BUFNO- CK FOR ALTERNATE BUFFER       16900013
         BC    1,RGDAL020            FOR FILE.                          17000013
*FILE ONLY HAS ONE BUFFER ATTACHED TO THE IOB                           17100013
         EXCP  (RF)                READ FORWARD                         17200013
         L     RB,ECBPTR                                                17300013
         WAIT  1,ECB=(1)           WAIT ON FILE                         17400013
RGDLINK  BAL   RH,RGDEE100         EOF-ERROR CK.SUBRTN.                 17500013
         SPACE 2                                                        17600013
*RETURN FROM EOF-ERROR CK RTN. RB-ACTUAL COUNT OF RCOS IN THE BUFFER    17700013
*   FOR F.L.,OR ACTUAL NO.OF BYTES IN BUFFER -4(FOR BCC)FOR V.L. RCDS.  17800013
*   RC AND RE CONTAIN STARTING ADDR OF THE BUFFER.                      17900013
         SPACE 1                                                        18000013
         LH    RC,KCOUNT           AVAILABLE BUFFER                     18100013
         BCT   RC,RGDBF010           ON LIST TO ATTACH TO FILE          18200013
RGDRTRN  LM    RC,RH,KSAVE                                              18300013
         L     RL,PPIDEB+4                                              18400013
RGDRTRNV LA    RC,4(0,RC)          FIXED-BYPASS EOS INDICATOR           18500013
*                                  VAR.- BYPASS EOS INDICATOR AND BCC   18600013
         BCR   15,RL                                                    18700013
*                                                                       18800013
*                                                                       18900013
*ATTACH AVAILABLE BUFFER TO FILE WHICH PREVIOUSLY HAD NO ALTERNATE      19000013
*   BUFFER                                                              19100013
RGDBF010 STH   RC,KCOUNT                                                19200013
         L     RC,PPILAB02                                              19300013
         BAL   RH,RGDIOBUP         UPDATE IOB- ATTACH BUFFER FROM       19400013
         LA    RC,4(0,RC)            AVAILABLE LIST                     19500013
         ST    RC,PPILAB02         UPDATE LIST                          19600013
         STC   RD,RGDINST+1        FILE INCR(FR DEBLOCK)                19700013
         LH    RA,PPISRTBL                                              19800013
         LA    RH,RGDRTRN                                               19900013
RGDFLUP  LA    RC,TFCNT            FIND FILE COUNT IN ORDER             20000013
RGDINST  CLI   0(RC),X'00'                                              20100013
         BC    8,RGDBF015            TO UPDATE COUNT                    20200013
         LA    RC,4(0,RC)                                               20300013
         BC    15,RGDINST                                               20400013
*                                                                       20500013
*                                                                       20600013
RGDBF015 L     RE,0(0,RC)          ADD SORT BLOCKING                    20700013
         AR    RE,RA                                                    20800013
         ST    RE,0(0,RC)            TO FILE COUNT                      20900013
         BCR   15,RH                                                    21000013
*                                                                       21100013
*                                                                       21200013
RGDIOBUP L     RE,START            ATTACH NEW(OR ALTERNATE) CCW         21300013
         L     RP,ECBPTR                                                21400013
         MVC   START+1(3),5(RP)      TO FILE TO HANDLE READS ON         21500013
         ST    RE,4(0,RP)            ALTERNATE BUFFER                   21600013
         L     RE,START                                                 21700013
         MVC   1(3,RE),1(RC)       STORE BUFFER ADDR. IN CCW            21800013
         MVI   DCBBUFNO,X'02'      UPDATE BUFNO                         21900013
         LR    RE,RB               SAVE BLOCK COUNT                     22000013
         EXCP  (RF)                READ FWD                             22100013
         LR    RB,RE               RESTORE BLOCK COUNT FOR DEBLOCK      22200013
         BCR   15,RH                                                    22300013
         SPACE 2                                                        22400013
RGDAL020 L     RB,ECBPTR                                                22500013
         WAIT  1,ECB=(1)           WAIT ON ALTERNATE                    22600013
         BAL   RH,RGDEE100         EOF-ERROR CK.                        22700013
         SPACE 1                                                        22800013
         SPACE 2                                                        22900013
*RETURN FROM EOF-ERROR CK RTN. RB-ACTUAL COUNT OF RCDS IN THE BUFFER    23000013
*   FOR F.L.,OR ACTUAL NO.OF BYTES IN BUFFER -4(FOR BCC) FOR V.L. RCDS. 23100013
*   RC AND RE CONTAIN STARTING ADDR OF THE BUFFER.                      23200013
         SPACE 1                                                        23300013
RGDK2M   CLI   KTOTAL,X'00'        FULL OVLAP TEST.'I' FIELD SET TO 2M  23400013
*                                    BY A.P. AND RECALC ON EA INPT      23500013
*                                    EOF BY R.P.                        23600013
         BL    RGDFL030            BR ON KTOTAL LESS THAN 2M            23700013
         SPACE 2                                                        23800013
*FULL OVERLAP IN PHASE 3                                                23900013
         SPACE 1                                                        24000013
RGDAL025 LA    RC,IERDGB3          ATTACH EMPTY BUFFER                  24100013
         LA    RH,RGDRTRN            TO SAME FILE AGAIN                 24200013
         B     RGDIOBUP            BR TO UPDATE IOB                     24300013
         SPACE 2                                                        24400013
*PARTIAL OVERLAP ROUTINE. ASSIGN AN AVAILABLE BUFFER TO A UNIT HAVING   24500013
*   ONLY 1 BUFFER. SINCE THERE MAY BE MORE THAN 1 UNIT HAVING 1 BUFFER  24600013
*   TAKE THE BUFFER WITH THE LEAST AMOUNT OF RECORDS IN IT.             24700013
         SPACE 1                                                        24800013
RGDFL030 LA    RC,TFCNT            ADDR OF TABLE OF FILE COUNTERS       24900013
         ST    RB,KSAVEB           SAVE BLOCK CNT FOR DEBLOCK           25000013
         L     RB,PPISBLCT                                              25100013
         LH    RH,KMRGMX              -ADDING OF  DEBLOCK               25200013
         LA    RE,PPIPSVA                                               25300013
         SR    RO,RO                    COUNTS TO THE                   25400013
         ST    RO,0(RD,RB)         SET RELEASED FILE'S BLCNT=0          25500013
         SPACE 2                                                        25600013
*THE TABLE OF FILE COUNTERS CONTAIN ENTRIES OF ALL THE INPUT UNITS INTO 25700013
*   PHASE 3. EACH ENTRY IS 4 BYTES. 1ST BYTE IS THE FILE INCR. THE NEXT 25800013
*   3 BYTES IS EITHER 2B OR B DEPENDING WHETHER 2 OR 1 BUFFER IS        25900013
*   ATTACHED TO THE FILE. TAKE THESE ENTRIES AND ADD THE BLOCK COUNT    26000013
*   OF EACH FILE'S BLOCK COUNTERS AND ESTABLISH A PPIPSVA TABLE WHICH   26100013
*   WILL HAVE A 4 BYTE ENTRY FOR EACH FILE. 1ST BYTE IS FILE INCR. NEXT 26200013
*   3 BYTES IS(2B OR B) + REMAINING BLOCK COUNT FROM THE TABLE OF       26300013
*   BLOCK COUNTERS. THE RELEASED FILE'S BLOCK COUNT WAS SET TO 0 SO ITS 26400013
*   ENTRY IN PPIPSVA TABLE CANNOT EXCEED 2B.                            26500013
         SPACE 1                                                        26600013
RGDFL035 IC    RO,0(0,RC)                                               26700013
         L     RP,0(RO,RB)              FILE COUNTS                     26800013
         A     RP,0(0,RC)                                               26900013
         ST    RP,0(0,RE)                                               27000013
         LA    RC,4(0,RC)                                               27100013
         LA    RE,4(0,RE)                                               27200013
         BCT   RH,RGDFL035                                              27300013
*                                                                       27400013
         LA    RC,PPIPSVA          OBTAIN FILE COUNT ADDRS. VIA         27500013
         LH    RB,KMRGMX             FILE TO BE READ                    27600013
         STC   RD,RGDINST1+1                                            27700013
         LR    RE,RC                                                    27800013
         B     RGDINST1            BR TO SCAN PPISVA TABLE              27900013
         SPACE 2                                                        28000013
*FIND THE FILE ENTRY IN PPIPSVA OF THE FILE RELEASING THE BUFFER AND    28100013
*   THE FILE TO WHICH THE BUFFER WILL BE GIVEN. THE DISPLACEMENTS WILL  28200013
*   CORRESPOND TO THE DISPLACEMENTS OF THESE FILES IN THE TABLE OF      28300013
*   FILE CTRS. THE RELEASED FILES BUFFER WILL BE UPDATED TO B AND THE   28400013
*   NEW 2 BUFFER FILE WILL BE UPDATED TO 2B IN THE TABLE OF FILE CTRS.  28500013
         SPACE 1                                                        28600013
RGDLP040 LA    RE,4(0,RE)            SCAN FOR LOWEST FILE COUNT         28700013
         CLC   1(3,RC),1(RE)                                            28800013
         BC    2,RGDEX050              AND FOR THE RELEASED             28900013
RGDINST1 CLI   0(RE),X'00'                                              29000013
         BC    8,RGDRL060            FILE COUNT                         29100013
RGDLPEND BCT   RB,RGDLP040                                              29200013
*                                                                       29300013
         LR    RB,RA                                                    29400013
         LA    RA,PPIPSVA            DISPLACEMENTS OF LOWEST AND        29500013
         SR    RC,RA                 RELEASED FROM PPIPSVA              29600013
         SR    RB,RA                                                    29700013
         LA    RA,TFCNT                                                 29800013
         AR    RB,RA                                                    29900013
         AR    RC,RA                                                    30000013
         L     RE,0(0,RC)          UPDATE-                              30100013
         AH    RE,PPISRTBL                                              30200013
         ST    RE,0(0,RC)            NEW FILE COUNT                     30300013
         MVI   DCBBUFNO,X'01'        RELEASED FILE'S BUFNO(IN DCB)      30400013
         L     RE,0(0,RB)                                               30500013
         SH    RE,PPISRTBL                                              30600013
         ST    RE,0(0,RB)            RELEASED FILE COUNT                30700013
         SR    RB,RB                                                    30800013
         IC    RB,0(0,RC)          INCR IN NEW FILE COUNT'S FIRST BYTE  30900013
         L     RG,PPISTDCB                                              31000013
         L     RG,0(RB,RG)         IOB ADDR.                            31100013
         L     RF,DCBIOBAD           OF NEW FILE                        31200013
         L     RB,KSAVEB           RESTORE BLOCK CNT                    31300013
         BC    15,RGDAL025                                              31400013
*                                                                       31500013
*                                                                       31600013
RGDEX050 LR    RC,RE               ADDR. OF LOWEST FILE COUNT           31700013
         BC    15,RGDINST1                                              31800013
*                                                                       31900013
*                                                                       32000013
RGDRL060 LR    RA,RE                                                    32100013
         BC    15,RGDLPEND         ADDR. OF RELEASED FILE COUNT         32200013
         SPACE 2                                                        32300013
*END OF FILE/ERROR CHECK ROUTINE                                        32400013
         SPACE 1                                                        32500013
RGDEE100 TM    CSW+4,X'01'         UNIT EXCEPTION. HIT TAPE MARK        32600013
         BO    RGDEOFR             BR IF YES TO EOF ROUTINE             32700013
         TM    CSW+4,X'02'         UNIT CHECK FOR DEVICE ERROR          32800013
         BC    8,RGDPRMSK          BR IF NOT ON TO CHECK CHANNEL ERROR  32900013
         MVC   WSENSE0,SENSE       SENSE BYTE IN IOB TO SAVE AREA       33000013
RGSTORRF ST    RF,PPIWKARE         SAVE IOB ADDR IN CASE NO SYNAD RTN   33100013
RGDERROR OI    PPISW1+5,X'80'      TURN ON ERROR BIT IN PPI             33200013
RGMTERM  NOP   RGPRTABT                                                 33300013
         L     RB,DCBPTR           DCB ADDR IN IOB FOR E38 SYNAD        33400013
         ST    RF,PPIWKARE         IOB ADDR                             33500013
         MVI   PPIWKARE,X'10'      INCR TO CCW ADDR IN IOB FOR E38      33600013
         L     RA,PPIWKARE                                              33700013
         SPACE 2                                                        33800013
* INTERFACE WITH USER EXIT E38 SYNAD                                    33900013
         SPACE 1                                                        34000013
         L     RP,ADCONE38                                              34100013
         BALR  RO,RP                                                    34200013
         SPACE 2                                                        34300013
*PRINT IOS READ ERROR MSG BEFORE ABORTING                               34400013
         SPACE 1                                                        34500013
RGPRTABT L     RE,PPIWKARE         ADDR OF IOB WITH ERROR ON IT         34600013
         L     RE,20(0,RE)         ADDR OF IOB'S DCB                    34700013
         L     RE,44(0,RE)         ADDR OF DCB'S DEB                    34800013
         L     RE,32(0,RE)         ADDR OF DEB'S UCB                    34900013
         MVC   PPIRCV(3),13(RE)                                         35000013
         L     RP,PPIADSSC                                              35100013
         BAL   RO,16(0,RP)                                              35200013
         SPACE 2                                                        35300013
         SPACE 1                                                        35400013
RGDSKIP  OI    FLG1,X'40'          IF ERROR ACCEPTED, RESET ERROR BITS  35500013
         NI    CSW+5,X'B7'           IN THE IOB AND DCB                 35600013
         NI    DCBIFLGS,X'3F'      DCB EXCEPTION BITS FOR PERM. ERROR   35700013
RGDACCPT EXCP  (RF)                READ FORWARD INTO SAME BUFFER        35800013
         L     RB,ECBPTR                                                35900013
         WAIT  1,ECB=(1)                                                36000013
RGDACCBR B     RGDEE110                                                 36100013
         SPACE 2                                                        36200013
*NO UNIT EXCEPTION OR UNIT CHECK BITS ON. CHECK IF OTHER ERRORS.        36300013
         SPACE 1                                                        36400013
RGDPRMSK TM    CSW+5,X'08'         CHECK IF CHANNEL ERROR               36500013
         BO    RGSTORRF            BR IF YES TO SAVE IOB ADDR           36600013
         TM    CSW+5,X'40'         CHECK IF INCORRECT LENGTH BIT ON     36700013
         BO    RGDEOSBF            BR IF YES TO CHECK IF EOS BFR        36800013
RGDEE110 L     RE,START            ADDR OF CCW FROM IOB                 36900013
         L     RE,0(RE)            STARTING BFR ADDR FROM CCW FOR DEBLK 37000013
         SPACE 2                                                        37100013
*TEST IF VARIABLE LENGTH RECORDS.                                       37200013
         SPACE 1                                                        37300013
RGDBRVR  BC    0,RGDVAR            A.P. WILL MAKE A BR IF V.L. RCDS.    37400013
         SPACE 1                                                        37500013
         TM    2(RE),X'07'         IS BUFFER EOS.                       37600013
         BO    RGDFIX              BR IF YES TO COUNT RCDS IN SHORT BLK 37700013
         LH    RB,PPISRTBL         NO,LOAD SORT BLOCKING INTO RB        37800013
RGDEE120 LR    RC,RE                                                    37900013
         ST    RC,KSAVE            STORE IN RC POS'N IN SAVE AREA       38000013
         MVI   KSAVE,X'00'         ZERO OUT CC                          38100013
         ST    RE,KSAVE+8          STORE IN RE POS'N IN SAVE AREA       38200013
         BCR   15,RH               RETURN TO MAIN LINE TO EITHER THE    38300013
*                                    OVERLAP OR NO OVERLAP RTN          38400013
         SPACE 2                                                        38500013
*CHECK IF BUFFER IS AN EOS BUFFER(INCORRECT LENGTH BIT IS ON IN CSW)    38600013
         SPACE 1                                                        38700013
RGDEOSBF L     RE,START                                                 38800013
         L     RE,0(RE)                                                 38900013
RGDEOSB1 TM    2(RE),X'07'         IS IT EOS.                           39000013
         BZ    RGSTORRF            BR IF NO TO PRINT MSG BEFORE ABORTG  39100013
         NI    DCBIFLGS,X'3F'      RESET IFLGS                          39200013
         B     RGDBRVR             BR IF YES TO CHK IF V.L. RCDS        39300013
         SPACE 2                                                        39400013
*DETERMINE ACTUAL NO OF BYTES IN THE V.L. BFR MINUS 4 FOR THE BCC       39500013
         SPACE 1                                                        39600013
RGDVAR   LH    RB,PPILAB03+2       SIZE OF ROUNDED INPUT BUFFER         39700013
         SH    RB,CSW+6            MINUS NO. OF BYTES DIDN'T READ IN    39800013
*                                    FROM COUNT FIELD OF CSW            39900013
         LR    RA,RB                                                    40000013
         SH    RB,KFOUR            MINUS 4 BYTES FOR BCC                40100013
         B     RGDEE120            BR TO LOAD RC & RE W/STRTG BFR ADDR  40200013
         SPACE 2                                                        40300013
*COUNT THE NUMBER OF RECORDS IN THE FIXED LENGTH EOS BUFFER             40400013
         SPACE 1                                                        40500013
RGDFIX   L     RB,KBLKCHR          COUNT OF A FULL BUFFER FROM PPILAB03 40600013
         SH    RB,CSW+6            MINUS NO. OF BYTES NOT READ IN       40700013
*                                    EQUALS NO. OF BYTES READ IN        40800013
         SH    RB,KFOUR            MINUS 4 FOR EOS BYTES                40900013
         SR    RO,RO                                                    41000013
RGDLOOP  SH    RB,PPIRCDL2         SUBTR LGTH OF 1 F.L. RCD FROM COUNT  41100013
         LA    RO,1(0,RO)          INCR RECORD COUNTER BY 1             41200013
         CH    RB,PPIRCDL2         COMPARE REMAINING COUNT              41300013
         BC    10,RGDLOOP          BR ON EQ OR GTR(MORE RCDS IN BFR)    41400013
         LR    RB,RO               LOAD NO. OF RCDS IN BUFFER IN RB     41500013
         B     RGDEE120            BR TO LOAD RC AND RE FOR DEBLOCK.    41600013
         SPACE 2                                                        41700013
*END OF FILE ROUTINE. PUT THIS FILE'S BUFFER(S) ON THE AVAILABLE BUFFER 41800013
*   LIST.                                                               41900013
         SPACE 1                                                        42000013
RGDEOFR  L     RE,START            ADDR OF PRIMARY CCW FROM THE IOB     42100013
RGDTWO   L     RC,PPILAB02         AVAIL BUFFER TABLE PTR               42200013
         SH    RC,KFOUR            DECR PTR                             42300013
         MVC   1(3,RC),1(RE)       BUFFER ADDR IN CCW TO TABLE          42400013
         ST    RC,PPILAB02         UPDATED BUFFER TABLE PTR             42500013
         LH    RC,KCOUNT                                                42600013
         LA    RC,1(0,RC)          ADD 1 TO AVAILABLE BUFFER CTR        42700013
         STH   RC,KCOUNT           STORE UPDATED CTR                    42800013
         CLI   DCBBUFNO,X'02'      DOES THIS FILE HAVE 2 BUFFERS        42900013
         BNE   RGDONE              BR IF NO                             43000013
         MVI   DCBBUFNO,X'01'      YES,CHANGE THE 2 TO A 1              43100013
         L     RE,ECBPTR           ADDR OF THE ECB                      43200013
         L     RE,4(0,RE)          ADDR OF THE ALTERNATE CCW            43300013
         B     RGDTWO                                                   43400013
         SPACE 2                                                        43500013
RGDONE   LH    RA,KNNINE           EOF INDICATION TO UPDATE TABLE OF    43600013
*                                    FILE COUNTERS.                     43700013
         STC   RD,RGDINST+1        INCR OF EOF FILE                     43800013
         BAL   RH,RGDFLUP          UPDATE TABLE OF FILE CTR ENTRY(EOF)  43900013
         LH    RH,KMRGMX1          ACTUAL INPUT MERGE ORDER UPDATED     44000013
         BCTR  RH,0                DECR BY 1 FOR THE INPUT EOF          44100013
         STH   RH,KMRGMX1          RESTORE NEW MERGE ORDER              44200013
         AR    RH,RH               2M                                   44300013
         STC   RH,RGDK2M+1         SET THE 'I' FIELD OF THE CLI INSTR   44400013
         OI    DCBOFLGS,X'04'      TURN OFF FLAG BITS IN DCB     A31855 44500021
         CLOSE ((RG))              CLOSE THE INPUT FILE                 44600013
         SPACE 2                                                        44700013
*INTERFACE TO MERGE NETWORK TO CUTBACK MERGE ORDER THEN MERGE GOES      44800013
*   TO BLOCK WITH ANOTHER WINNER.                                       44900013
         SPACE 1                                                        45000013
         L     RL,PPINET+4                                              45100013
         B     4(0,RL)                                                  45200013
         SPACE 2                                                        45300013
*LIST OF WORK AREAS/TABLES:                                             45400013
         SPACE 1                                                        45500013
TFCNT    DS    16F                 FILE COUNT TABLE, 4 BYTE ENTRIES     45600013
*                                    1ST BYTE-FILE INCR                 45700013
*                                    NEXT 3 BYTES- 2B=2 BFRS OR B=1 BFR 45800013
*                                      OR FFFF FOR EOF ON THE FILE      45900013
WSENSE0  DC    X'00'               SENSE BYTE SAVED ON UNIT CHECK       46000013
         SPACE 2                                                        46100013
*LIST OF CONSTANTS:                                                     46200013
         SPACE 1                                                        46300013
KTOTAL   DC    X'0000'             NO. OF INPUT BUFFERS PRESENTLY       46400013
*                                    ATTACHED                           46500013
KMRGMX   DC    H'0'                A.P. INSERTS INPUT MERGE ORDER INTO  46600013
*                                    PHASE 3                            46700013
KMRGMX1  DC    H'0'                A.P INSERTS INPUT MERGE ORDER INTO   46800013
*                                    PH 3.  R.P. DECR BY 1 EA INPT EOF  46900013
KCOUNT   DC    AL2(1)              AVAILABLE BUFFER COUNTER             47000013
KNNINE   DC    X'7FFF'             EOF CONSTANT FOR TFCNT ENTRY ON EOF  47100013
KFOUR    DC    AL2(4)              CONSTANT OF 4                        47200013
KBLKCHR  DC    F'0'                SORT BLOCK CHAR CNT(F AND V RCDS)    47300013
KSAVE    DC    6F'0'               REGISTER SAVE AREA                   47400013
KSAVEB   DC    F'0'                                                     47500013
         SPACE 2                                                        47600013
*LIST OF ADCONS:                                                        47700013
         SPACE 1                                                        47800013
ADCONE38 DC    F'0'                ADDR OF USER EXIT E38 SYNAD.LOADED   47900013
*                                    BY A.P.                            48000013
         EJECT                                                          48100013
         DS    0F                                                       48200013
IERIOB   DSECT                     DUMMY IOB-(SEE 14.90.1.4)            48300013
FLG1     DC    X'00'                                                    48400013
FLG2     DC    X'00'                                                    48500013
SENSE    DC    AL2(0)                                                   48600013
ECBPTR   DC    AL4(0)                                                   48700013
CSW      DC    AL4(0)                                                   48800013
         DC    AL4(0)                                                   48900013
START    DC    AL4(0)              HIGH ORDER BYTE IS CC.               49000013
DCBPTR   DC    AL4(0)              HIGH ORDER BYTE IS WGHT.             49100013
RESTART  DC    AL4(0)                                                   49200013
INCAMT   DC    AL2(0)                                                   49300013
ERRCNTS  DC    AL2(0)                                                   49400013
*                                                                       49500013
         EJECT                                                          49600013
         SMPPI                                                          49700013
         DCBD  DSORG=PS                                                 49800013
         END                                                            49900013
