         TITLE 'IERROI - OS/360 SORT/MERGE - 360S-SM-023  03/23/65'     00200013
*MODULE NAME:*** IERROI ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: SORT PHASE BALANCED TAPE ALGORITM.          01200013
*   THE FUNCTION OF THIS MODULES IS TO                                  01400013
*     (A) DETERMINE OUTPUT UNIT FOR SORT.                               01600013
*     (B) CHECK FOR SORT CAPACITY BEING EXCEEDED.                       01800013
*     (C) SET APPROPRIATE INDICATORS IN THE TAPE TABLE FOR OPEN RTN.    02000013
*     (D) DETERMINES IF PHASE 2 OR PHASE 3 WILL FOLLOW SORT PHASE       02200013
*         TERMINATION.                                                  02400013
*       1 IF WRONG ORDER FOR PHASE 3 AND ONE OR TWO PASSES OF PHASE TWO 02600013
*         IERROI TURNS ON BLOCK FORWARD AND READ FORWARD LATER AND      02800013
*         HAS SSC CALL PHASE 2.                                         03000013
*       2 IF WRONG ORDER AND NUMBER OF SEQUENCES .LE. FINAL MERGE ORDER 03200013
*         AND RECORDS ARE FIXED LENGTH IT SETS DEBLOCK BACKWARD,READ    03400013
*         FORWARD AND REWIND SWITCHES AND HAS SSC CALL PHASE 3.         03600013
*       3 IF ORDER IS CORRECT AND NUMBER OF SEQUENCES .LS.FINAL MERGE   03800013
*         ORDER IT HAS SSC CALL PHASE 3.                                04000013
*       4 OTHERWISE,IT DOES NOT SET SWITCHES AND HAS SSC CALL PHASE 2.  04200013
         SPACE 2                                                        04400013
*MACROS USED -                                                          04600013
         SPACE 1                                                        04800013
*   SMPPI                                                               05000013
         SPACE 2                                                        05200013
*ENTRY POINTS:                                                          05400013
         SPACE 1                                                        05600013
*        ENTRY                     ENTRY FROM: IERRPA                   05800013
*                                    CALLING SEQUENCE-                  06000013
*                                      L    RL,PPIALG+4                 06200013
*                                      B    DISP(0,RL)                  06400013
*                                        DISP = 0 FOR END OF FILE       06600013
*                                             = 4 FOR EOV & NOT EOS     06800013
*                                             = 8 FOR EOV & END OF SEQ  07000013
*                                             =12 FOR END OF VOLUME     07200013
         SPACE 2                                                        07400013
*INPUT: PPI FIELDS REFERENCED-                                          07600013
         SPACE 1                                                        07800013
*    PPIDEB    PPIWRT     PPIMRGAL   PPISEQCT                           08000013
*    PPIRMA    PPIADSSC   PPIMRGMX   PPISW1                             08200013
         SPACE 2                                                        08400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             08600013
         SPACE 1                                                        08800013
*   PPISW1     PPIMRGMX  PPITPPT                                        09000013
*   PPIDEPHO   PPISEQCT  PPITPTBL                                       09200013
         SPACE 2                                                        09400013
*EXTERNAL ROUTINES:                                                     09600013
         SPACE 1                                                        09800013
*        EXTRN IERDD1              DEBLOCK ROUTINE                      10000013
*        EXTRN IERDPW1             WRITE ROUTINE                        10200013
         SPACE 2                                                        10400013
*EXTERNAL PARAMETERS:                                                   10600013
         SPACE 1                                                        10800013
*        EXTRN IERRMA              MESSAGE MODULE                       11000013
*EXITS: NORMAL                                                          11200013
         SPACE 1                                                        11400013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  11600013
         SPACE 2                                                        11800013
*EXITS: ERROR                                                           12000013
         SPACE 1                                                        12200013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  12400013
         SPACE 2                                                        12600013
*TABLES/WORK AREAS: NONE                                                12800013
         SPACE 2                                                        13000013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  13200013
         SPACE 2                                                        13400013
*NOTES: NONE                                                            13600013
         SPACE 1                                                        13800013
         SPACE 2                                                        14000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14200013
         SPACE 1                                                        14400013
RA       EQU   0                   CONTENTS IN- N/A                     14600013
*                                  USE- MESSAGE ADDRESS                 14800013
*                                  CONTENTS OUT- N/A                    15000013
RB       EQU   1                   CONTENTS IN- N/A                     15200013
*                                  USE- MESSAGE LENGTH & CONDITION CODE 15400013
*                                  CONTENTS OUT- CONDITION CODE         15600013
RC       EQU   2                   CONTENTS IN- N/A                     15800013
*                                  USE- NOT USED                        16000013
*                                  CONTENTS OUT- N/A                    16200013
RD       EQU   3                   CONTENTS IN- N/A                     16400013
*                                  USE- GENERAL WORK REGISTER           16600013
*                                  CONTENTS OUT- N/A                    16800013
RE       EQU   4                   CONTENTS IN- N/A                     17000013
*                                  USE- GENERAL WORK REGISTER           17200013
*                                  CONTENTS OUT- N/A                    17400013
RF       EQU   5                   CONTENTS IN- N/A                     17600013
*                                  USE- GENERAL WORK REGISTER           17800013
*                                  CONTENTS OUT- N/A                    18000013
RG       EQU   6                   CONTENTS IN- N/A                     18200013
*                                  USE- GENERAL WORK REGISTER           18400013
*                                  CONTENTS OUT- N/A                    18600013
RH       EQU   7                   CONTENTS IN- N/A                     18800013
*                                  USE- GENERAL WORK REGISTER           19000013
*                                  CONTENTS OUT- N/A                    19200013
RI       EQU   8                   CONTENTS IN-  N/A                    19400013
*                                  USE- GENERAL WORK REGISTER           19600013
*                                  CONTENTS OUT- N/A                    19800013
RJ       EQU   9                   CONTENTS IN-  N/A                    20000013
*                                  USE- NOT USED                        20200013
*                                  CONTENTS OUT- N/A                    20400013
RK       EQU   10                  CONTENTS IN- N/A                     20600013
*                                  USE- NOT USED                        20800013
*                                  CONTENTS OUT- N/A                    21000013
RL       EQU   11                  CONTENTS IN- N/A                     21200013
*                                  USE- MODULE BASE ADDRESS REGISTER    21400013
*                                  CONTENTS OUT- ADDRESS OF THIS MOD    21600013
RM       EQU   12                  CONTENTS IN- N/A                     21800013
*                                  USE- NOT USED                        22000013
*                                  CONTENTS OUT- NA                     22200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          22400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     22600013
*                                    AREA                               22800013
*                                  CONTENTS OUT- ADDRESS OF PPI         23000013
RO       EQU   14                  CONTENTS IN  N/A                     23200013
*                                  USE- MESSAGE MODULE BASE REG         23400013
*                                  CONTENTS OUT- N/A                    23600013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  23800013
*                                  USE- SORT SYSTEM CONTROL INTERFACE   24000013
*                                  CONTENTS OUT- ADDRESS OF SSC         24200013
         SPACE 2                                                        24400013
*START OF MODULE CODE PROPER:                                           24600013
         SPACE 2                                                        24800013
IERROI   CSECT                                                          25000013
*                                                                A27992 25100000
         USING *,RL                                                     25200013
         USING IERRCA,RN                                                25400013
         USING DIERRMA,RO                                               25600013
*    INTERFACE ENTRIES BRANCH TABLE                                     25800013
IERDOK   B     ROIEOF              AFTER WRITE OF LAST BLK OF FILE      26000013
         B     ROIEOTW             REACH END OF TAPE NOT END OF SEQ BLK 26200013
         B     ROIEOTD             REACH END OF TAPE END OF SEQ BLK     26400013
         B     ROI020                                                   26600013
         SPACE 2                                                        26800013
*SPECIAL EOV ENTRY FROM WRITE ROUTINE -                                 27000013
*   WHEN TWO OUTPUT BUFFERS ARE PRESENT AND EOS-EOV OCCURS ON THE SAME  27200013
*   BLOCK, THE EOV IS NOT DETECTED UNTIL AFTER EOS HAS BEEN PROCESSED   27400013
*   BY THE ALGORITHM.  THIS ENTRY THEN PROCESSES EOV BY RESETTING       27600013
*   POINTERS AS THEY WERE PRIOR TO THE LAST EOS AND THEN EXECUTING AS   27800013
*   FOR AN EOV.  THIS ENTRY EXISTS ONLY IN THE BALANCED ALGORITHM.      28000013
         SPACE 1                                                        28200013
         MVC   ROIRSW(2),KROIRSC2  SET RSWITCH TO GO TO WRITE RTN       28400013
         LH    RE,IERROITL                                              28600013
         CH    RE,IERROILT         IS COUNT AT UPPER LIMIT              28800013
         BC    10,ROI010           YES - RESET                          29000013
         SPACE 1                                                        29200013
         LA    RE,1(RE)            NO-INCREMENT                         29400013
         STH   RE,IERROITL                                              29600013
         L     RE,IERROITP                                              29800013
         S     RE,KROITWO                                               30000013
         ST    RE,IERROITP                                              30200013
         B     ROI030                                                   30400013
         SPACE 2                                                        30600013
ROI010   LA    RE,1                                                     30800013
         STH   RE,IERROITL                                              31000013
         L     RE,IERROILA                                              31200013
         ST    RE,IERROITP                                              31400013
         B     ROI030                                                   31600013
         SPACE 2                                                        31800013
*    INTERFACE ENTRY AFTER WRITE OF LAST BLK OF A SEQUENCE CHART ABC4   32000013
         SPACE 1                                                        32200013
ROI020   L     RE,PPISEQCT+4       NUMBER OF GENERATED SEQUENCES        32400013
         LA    RE,1(0,RE)          INCR NUMBER OF GENERATED SEQUENCES   32600013
         ST    RE,PPISEQCT+4                                            32800013
         LH    RE,IERROITL         TAPE TABLE POINTER LIMIT             33000013
         BCT   RE,ROIITTP          GO TO INCR TAPE POINTER              33200013
         MVC   IERROITL(2),IERROILT  RESET POINTER LIMIT                33400013
         LA    RE,PPITPTBL+1                                            33600013
         ST    RE,IERROITP         RESET TABLE POINTER TO FIRST UNIT    33800013
         B     ROISOU              GO TO SET DCB INCR FOR WRITE RTN     34000013
         SPACE 2                                                        34200013
ROIITTP  STH   RE,IERROITL                                              34400013
         L     RE,IERROITP                                              34600013
         LA    RE,2(0,RE)          INCR TAPE TABLE POINTER              34800013
         ST    RE,IERROITP                                              35000013
ROISOU   MVC   PPIDEPHO+3(1),0(RE) SET DCB INCR FOR WRITE RTN           35200013
         L     RL,PPIDEB+4                                              35400013
         B     8(0,RL)             EXIT TO THE DEBLOCK RTN              35600013
         SPACE 2                                                        35800013
*    INTERFACE ENTRIES WHEN END OF TAPE REACHED CHRT ADC1 + ADC2        36000013
         SPACE 1                                                        36200013
ROIEOTD  MVC   ROIRSW(2),KROIRSC1  SET RSWITCH TO GO TO DEBLOCK RTN     36400013
ROIINGS  L     RE,PPISEQCT+4                                            36600013
         LA    RE,1(0,RE)          INCR NUMBER OF GENERATED SEQUENCES   36800013
         ST    RE,PPISEQCT+4                                            37000013
         SPACE 1                                                        37200013
*    THE UPDATING OF THE CURRENT NUMBER OF WORKING TAPES CONSTANT       37400013
*       AND EXCEED SORT CAPACITY CHECK SECTION                          37600013
         SPACE 1                                                        37800013
ROI030   LH    RE,IERROLMT                                              38000013
         BCT   RE,ROICONT                                               38200013
*    EXCEED SORT CAPACITY M FULL TAPES  ABORT THE SORT                  38400013
         SPACE 1                                                        38600013
         L     RO,PPIRMA+4                                              38800013
         LM    RA,RB,MSGP1A02      SORT CAPACITY EXCEEDED               39000013
         L     RP,PPIADSSC                                              39200013
         BAL   RO,12(0,RP)                                              39400013
         SPACE 1                                                        39600013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   39800013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        40000013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   40200013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      40400013
         SPACE 1                                                        40600013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             40800013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 40860000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 40920000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      41000013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             41200013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                41400013
         BO    ROI031                                                   41600013
         SPACE 1                                                        41800013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      42000013
         SR    RO,RO                                                    42200013
         DR    RO,RA                 RCDS. IN BLOCK                     42400013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         42600013
         BH    ROI032                NEGATIVE                           42800013
         SPACE 1                                                        43000013
         AR    RB,RP               ADD B TO CNT                         43200013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           43400013
         BNL   ROI033                                                   43600013
         SPACE 1                                                        43800013
         LR    RB,RP               SET CNT TO B                         44000013
         B     ROI033                                                   44200013
         SPACE 2                                                        44400013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      44600013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           44800013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       45000013
         OI    PPIWKARE+15,X'F0'                                        45200013
         SPACE 2                                                        45400013
         L     RO,PPIRMA+4                                              45600013
         LM    RA,RB,MSGP1A06                                           45800013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                46000013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        46200013
         BAL   RO,12(0,RP)                                              46400013
         SPACE 1                                                        46600013
         L     RP,PPIADSSC                                              46800013
         BAL   RO,16(0,RP)         ABORT THE SORT CODE                  47000013
         SPACE 2                                                        47200013
ROICONT  STH   RE,IERROLMT                                              47400013
         LH    RE,IERROILT                                              47600013
         BCTR  RE,0                                                     47800013
         STH   RE,IERROILT                                              48000013
         SPACE 1                                                        48200013
*    THE UPDATING OF THE TAPE TABLE SECTION                             48400013
         SPACE 1                                                        48600013
         LH    RE,IERROITL         CURRENT VALUE OF TAPE TBL PT LIMIT   48800013
         BCTR  RE,0                                                     49000013
         SLA   RE,1(0)                                                  49200013
         BC    8,ROISTC                                                 49400013
         BCTR  RE,0                                                     49600013
ROISTC   STC   RE,ROIMOV+1                                              49800013
         L     RF,IERROITP         ADDR IN TAPE TBL PT CONSTANT         50000013
         LR    RG,RF                                                    50200013
         LA    RG,1(0,RG)                                               50400013
         BCTR  RF,0                                                     50600013
         L     RH,IERROILA         ADDRESS OF TAPE TBL POINTER LMT      50800013
         MVC   ROISVTTE(2),0(RF)   SAVE ENTRY OF TAPE TBL               51000013
ROIMOV   MVC   0(1,RF),0(RG)       UPDATE TAPE TABLE                    51200013
         MVC   0(2,RH),ROISVTTE                                         51400013
         SPACE 1                                                        51600013
*    UPDATE ADDRESS OF TAPE TABLE POINTER LIMIT                         51800013
         S     RH,KROITWO                                               52000013
         ST    RH,IERROILA                                              52200013
         LH    RE,IERROITL         DECREMENT TAPE TABLE POINTER LIMIT   52400013
         BCT   RE,ROISDCBI         GO TO SET DCB INCR                   52600013
         MVC   IERROITL(2),IERROILT  RESET POINTER LMT                  52800013
         LA    RE,PPITPTBL+1                                            53000013
         ST    RE,IERROITP         RESET TABLE POINTER TO FIRST UNIT    53200013
ROIMDCB  MVC   PPIDEPHO+3(1),0(RE) SET DCB INCR FOR WRITE RTN           53400013
         SPACE 1                                                        53600013
*    CHECK RSWITCH FOR EXIT                                             53800013
         SPACE 1                                                        54000013
         TM    ROIRSW+1,X'01'                                           54200013
         BC    1,ROIEWR                                                 54400013
         L     RL,PPIDEB+4                                              54600013
         B     8(0,RL)             EXIT TO DEBLOCK RTN                  54800013
         SPACE 2                                                        55000013
ROIEWR   L     RL,PPIWRT+4                                              55200013
         BR    RL                  EXIT TO THE WRITE RTN                55400013
         SPACE 2                                                        55600013
ROISDCBI STH   RE,IERROITL         SAVE TAPE TBL POINTER LMT            55800013
         L     RE,IERROITP         TAPE TABLE POINTER                   56000013
         B     ROIMDCB             GO TO SET DCB INCR FOR WRITE RTN     56200013
         SPACE 2                                                        56400013
ROIEOTW  MVC   ROIRSW(2),KROIRSC2  SET RSWITCH TO GO TO WRITE RTN       56600013
         B     ROIINGS             GO TO INCR NUMBER OF SEQUENCES       56800013
         SPACE 2                                                        57000013
*    ENTRY AFTER WRITE OF LAST BLK OF FILE                              57200013
*    CHART AC                                                           57400013
         SPACE 1                                                        57600013
ROIEOF   L     RE,PPISEQCT+4       NUMBER OF GENERATED SEQUENCES        57800013
         LA    RE,1(0,RE)          INCR NUMBER OF SEQUENCES             58000013
         ST    RE,PPISEQCT+4                                            58200013
         MVC   PPITPPT(2),PPIMRGMX  NO UNITS IN 1 HALF OF TAPE TBL      58400013
         MVC   PPITPPT+2(2),PPIMRGAL  NO OF UNITS IN 2 HALF OF TP TBL   58600013
         CH    RE,PPIMRGMX         COMPARE NUMBER OF GENERATED SEQUENCE 58800013
*                                  TO THE MERGE ORDER                   59000013
*                                  IF GREATER CALL FOR PHASE 2          59200013
*                                  IF NOT GREATER  CALL FOR PHASE 3     59400013
         BE    ROICASE             BYPASS SETTING OFF OPEN BITS         59600013
         BL    ROICALL3            JUMP TO SEE IF PHASE 3 CAN BE CALLED 59800013
         LH    RD,PPIMRGMX         DETERMINE IF WE MIGHT ENTER PHASE 2  60000013
         MH    RD,PPIMRGAL           WITH ONLY ENOUGH SEQUENCES FOR ONE 60200013
         CLR   RE,RD                 PASS.                              60400013
         BNH   ROIX1PH2            ONE PHASE 2 PASS                     60600013
         MH    RD,PPIMRGMX                                              60800013
         CLR   RE,RD               CHECK FOR 2 PASS CASE OF PHASE 2     61000013
         BNH   ROIX2PH2            TWO PHASE 2 PASSES                   61200013
*    THIS SECTION OF CODE SETS THE OPEN BITS OF THE ENTRIES IN THE      61400013
*       SECOND HALF OF THE TAPE TBL ON                                  61600013
         SPACE 1                                                        61800013
ROILDP2  LA    RE,PPITPTBL                                              62000013
         LH    RD,PPIMRGMX                                              62200013
         SLA   RD,1                                                     62400013
         AR    RE,RD               STARTING PT OF 2 HALF OF TP TBL      62600013
         LH    RD,PPIMRGAL         ALT MRG ORD FOR TRAVERSE TP TBL      62800013
ROISTPTB OI    0(RE),X'40'         STORE A 1 IN OPEN BIT                63000013
         LA    RE,2(0,RE)          GO TO DO NEXT ITEM                   63200013
         BCT   RD,ROISTPTB         IS TABLE TRAVERSED                   63400013
ROIEXCL  L     RP,PPIADSSC                                              63600013
         XI    PPISW1+3,X'10'                                           63800013
         LA    RB,0                EXIT TO SSC CALLING FOR PHASE 2      64000013
         BAL   RO,20(0,RP)                                              64200013
         SPACE 2                                                        64400013
* THE FOLLOWING ROUTINE DECIDES IF A REWIND IS POSSIBLE IF DESIRABLE.   64600013
         SPACE 1                                                        64800013
ROIX2PH2 TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      65000013
         BC    14,ROICHK2            ASCENDING SEQUENCE.GO TO CHK2      65200013
ROICHK1  TM    PPISW1+3,X'30'      IF USER SEQ IS OPPOSITE TO PRES SEQ  65400013
         BC    11,ROILDP2          DO NOT PERFORM SPECIAL ROUTINES      65600013
ROISET   OI    PPISW1+6,X'18'     TURN ON BLOCK FORWARD AND READ        65800013
         B     ROILDP2               FORWARD LATER SWITCHES             66000013
ROICHK2  TM    PPISW1+3,X'30'      IF USER SEQ AGREES WITH PRES SEQ     66200013
         BM    ROILDP2             DO NOT PERFORM SPECIAL ROUTINES      66400013
         B     ROISET                                                   66600013
         SPACE 2                                                        66800013
ROIX1PH2 TM    PPISW1+3,X'60'      IF NOT EXTRACTING OR USER WANTS      67000013
         BC    14,ROICHK1            ASCENDING SEQUENCE GO TO CHK1      67200013
         B     ROICHK2               ELSE CHK2                          67400013
         SPACE 2                                                        67600013
         SPACE 2                                                        67800013
ROICALL3 LH    RI,PPIMRGMX         GET MERGE ORDER                      68000013
         STH   RE,PPIMRGMX         STORE NEW MERGE ORDER (SEQUENCES)    68200013
         SR    RE,RI               STRINGS-MERGE ORDER (OLD)            68400013
         LCR   RE,RE               OLD MERGE ORDER - NUMBER OF STRINGS  68600013
         BCTR  RI,0                                                     68800013
         MH    RI,KROITWO+2        DOUBLE RI TO CONVERT IT TO AN INDEX  69000013
         LA    RI,PPITPTBL(RI)     POINT AT LAST ENTRY AFFECTED         69200013
ROIRON01 NI    0(RI),X'3F'         TURN OFF OPEN + INPUT BITS           69400013
         S     RI,KROITWO          SUBTRACT 2 TO INDEX BACK IN TABLE    69600013
         BCT   RE,ROIRON01         IF NEXT ENTRY IS AFFECTED, BRANCH    69800013
ROICASE  TM    PPISW1+3,X'60'      IF EXTRACTING AND USER WANTS         70000013
         BO    ROINOEXT              DESCENDING SEQUENCE GO TO NOEXT    70200013
         TM    PPISW1+3,X'30'      INPUT LOOK GOOD FOR PHASE 3          70400013
         BM    ROILDP3               IF SO GO TO LOAD PHASE 3           70600013
         B     ROITEST               IF NOT CHECK FOR REWIND POSSIBLE   70800013
ROINOEXT TM    PPISW1+3,X'30'      INPUT LOOK GOOD FOR PHASE 3          71000013
         BNM   ROILDP3               IF SO GO TO LOAD PHASE 3           71200013
ROITEST  TM    PPISW1,X'80'        ARE THESE FIXED LENGTH RECORDS       71400013
         BZ    ROILDP2               IF NOT A PHASE TWO NORMAL PASS     71600013
         OI    PPISW1+6,X'E0'        MUST BE CALLED,ELSE SET SWITCHES   71800013
         XI    PPISW1+3,X'10'                                           72000013
ROILDP3  L     RP,PPIADSSC           AND CALL PHASE 3.                  72200013
         XI    PPISW1+3,X'10'      SET INPUT SEQ. BIT FOR MERGING       72400013
         LA    RB,4                                                     72600013
         BAL   RO,20(0,RP)                                              72800013
         EJECT                                                          73000013
         DS    0F                                                       73200013
IERROITL DS    1H                  TAPE TABLE POINTER LIMIT  THE ASSGN  73400013
*                                  RTN SETS THIS EQUAL TO MAX MRG ORD   73600013
IERROILT DS    1H                  TAPE TABLE POINTER LIMIT EQUAL TO    73800013
*                                  THE CURRENT NUMBER OF WORK UNITS     74000013
IERROLMT DS    1F                  SORT CAPACITY LIMIT                  74200013
IERROITP DS    1F                  TAPE TBL POINTER  AN ADDRESS         74400013
IERROILA DC    X'00000000'         ADDRESS OF TAPE TABLE POINTER LIMIT  74600013
ROISVTTE DS    1F                  SAVE TAPE TABLE ENTRY                74800013
ROIRSW   DC    X'0000'             RSWITCH                              75000013
ROICODE  DC    X'0010'             ABORT CODE FOR SORT SYS CONTROL      75200013
         SPACE 1                                                        75400013
KROIRSC1 DC    X'0000'             RSWITCH CONSTANT  GO TO DEBLOCK      75600013
KROIRSC2 DC    X'0001'             RSWITCH CONSTANT  GO TO WRITE        75800013
KROITHRE DC    XL4'3'                                                   76000013
KROIFOUR DC    XL4'4'                                                   76200013
KROIEIGH DC    XL4'8'                                                   76400013
KROITWO  DC    XL4'2'                                                   76600013
         EJECT                                                          76800013
DIERRMA  DSECT                                                          77000013
* MODULE NAME ***IERRMA***                                              77200013
*                                                                       77400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        77600013
* PHASE 1 RUNNING PROGRAM.                                              77800013
         SPACE 1                                                        78000013
         COPY  RMAMAIN                                                  78200013
         SMPPI                                                          78400013
         END                                                            78600013
