         TITLE ' IERROJ - OS/360 SORT/MERGE - 360S-SM-023 04/01/65 '    00200013
*MODULE NAME:*** IERROJ ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION: SORT PHASE POLYPHASE ALGORITHM FOR TAPE.    01200013
*   THIS MODULE CONTROLS  THE DISTRIBUTION OF SEQUENCES ON THE WORK     01400013
*   TAPES AS REQUIRED TO ACHIEVE AN EFFICIENT POLYPHASE SORT.           01600013
         SPACE 2                                                        01800013
*MACRO'S USED:                                                          02000013
         SPACE 1                                                        02200013
*   SMPPI                                                               02400013
         SPACE 2                                                        02600013
*ENTRY POINTS:                                                          02800013
         SPACE 1                                                        03000013
*        ENTRY                     ENTRY FROM: IERRPA                   03200013
*                                    CALLING SEQUENCE-                  03400013
*                                      L    RL,PPIALG+4                 03600013
*                                      B    DISP(0,RL)                  03800013
*                                      DISP = 0 FOR END OF FILE         04000013
*                                           = 4 FOR EOV & NOT EOS       04200013
*                                           = 8 FOR END OF VOL& NOT EOS 04400013
*                                           =16 FOR END OF SEQUENCE     04600013
         SPACE 2                                                        04800013
*INPUT: PPI FIELDS REFERENCED-                                          05000013
         SPACE 1                                                        05200013
*   PPIADSSC   PPINET  PPIRMA                                           05400013
*   PPIWKARE   PPIDEB                                                   05600013
         SPACE 2                                                        05800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             06000013
         SPACE 1                                                        06200013
*   PPIDEPHO  PPISW1                                                    06400013
*   PPITPTBL                                                            06600013
         SPACE 2                                                        06800013
*EXTERNAL ROUTINES:                                                     07000013
         SPACE 1                                                        07200013
*        EXTRN IERRCV              SORT SYSTEM CONTROL                  07400013
         SPACE 2                                                        07600013
*EXTERNAL PARAMETERS:                                                   07800013
         SPACE 1                                                        08000013
*        EXTRN IERRMA              MESSAGE MODULE                       08200013
*EXITS: NORMAL                                                          08400013
         SPACE 1                                                        08600013
*        IERRCV                    SORT SYSTEM CONTROL                  08800013
         SPACE 2                                                        09000013
*EXITS: ERROR                                                           09200013
         SPACE 1                                                        09400013
*        IERRCV                    SORT SYSTEM CONTROL                  09600013
         SPACE 2                                                        09800013
*TABLES/WORK AREAS: NONE                                                10000013
         SPACE 2                                                        10200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  10400013
         SPACE 2                                                        10600013
*NOTES: NONE                                                            10800013
         SPACE 2                                                        11000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            11200013
         SPACE 1                                                        11400013
RA       EQU   0                   CONTENTS IN-  N/A                    11600013
*                                  USE- MESSAGE ADDRESS                 11800013
*                                  CONTENTS OUT- N/A                    12000013
RB       EQU   1                   CONTENTS IN-  N/A                    12200013
*                                  USE- MESSAGE LENGTH & CONDITION CODE 12400013
*                                  CONTENTS OUT- CODE TO CALL PHASE 2.  12600013
RC       EQU   2                   CONTENTS IN-  N/A                    12800013
*                                  USE- UNUSED                          13000013
*                                  CONTENTS OUT- N/A                    13200013
RD       EQU   3                   CONTENTS IN-  N/A                    13400013
*                                  USE- UNUSED                          13600013
*                                  CONTENTS OUT- N/A                    13800013
RE       EQU   4                   CONTENTS IN-  N/A                    14000013
*                                  USE- GENERAL WORK REGISTER           14200013
*                                  CONTENTS OUT- N/A                    14400013
RF       EQU   5                   CONTENTS IN-  N/A                    14600013
*                                  USE- GENERAL WORK REGISTER           14800013
*                                  CONTENTS OUT- N/A                    15000013
RG       EQU   6                   CONTENTS IN-  N/A                    15200013
*                                  USE- GENERAL WORK REGISTER           15400013
*                                  CONTENTS OUT- N/A                    15600013
RH       EQU   7                   CONTENTS IN-  N/A                    15800013
*                                  USE- GENERAL WORK REGISTER           16000013
*                                  CONTENTS OUT- N/A                    16200013
RI       EQU   8                   CONTENTS IN-  N/A                    16400013
*                                  USE- GENERAL WORK REGISTER           16600013
*                                  CONTENTS OUT- N/A                    16800013
RJ       EQU   9                   CONTENTS IN-  N/A                    17000013
*                                  USE- GENERAL WORK REGISTER           17200013
*                                  CONTENTS OUT- N/A                    17400013
RK       EQU   10                  CONTENTS IN-  N/A                    17600013
*                                  USE- BASE REGISTER OF IERRMA'S DSECT 17800013
*                                  CONTENTS OUT- N/A                    18000013
RL       EQU   11                  CONTENTS IN-  N/A                    18200013
*                                  USE- PROGRAM BASE ADDRESS REGISTER   18400013
*                                  CONTENTS OUT- N/A                    18600013
RM       EQU   12                  CONTENTS IN-  N/A                    18800013
*                                  USE- UNUSED                          19000013
*                                  CONTENTS OUT- N/A                    19200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          19400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     19600013
*                                    AREA                               19800013
*                                  CONTENTS OUT- ADDRESS OF PPI         20000013
RO       EQU   14                  CONTENTS IN  N/A                     20200013
*                                  USE- RETURN REGISTER                 20400013
*                                  CONTENTS OUT- N/A                    20600013
RP       EQU   15                  CONTENTS IN- ADDRESS OF THIS MODULE  20800013
*                                  USE- REFERENCING SORT SYSTEM CONTROL 21000013
*                                  CONTENTS OUT- SSC ADDRESS            21200013
         SPACE 2                                                        21400013
*START OF MODULE CODE PROPER:                                           21600013
         SPACE 2                                                        21800013
         SPACE 1                                                        22000013
IERROJ   CSECT                                                          22200013
*                                                                A27992 22300000
         USING *,RL                                                     22400013
         USING IERRCA,RN                                                22600013
         USING DIERRMA,RK                                               22800013
         SPACE 1                                                        23000013
*** ENTRY TABLE                                                         23200013
         SPACE 1                                                        23400013
IERDOK   B     OJEOF               ENTRY FROM WRITE ROUTINE AT EOF      23600013
         B     OJEOV               ENTRY FROM WRITE ROUTINE AT EOV      23800013
*                                  **EOS HAS NOT BEEN REACHED AND       24000013
*                                  **MORE WRITES ARE PENDING.           24200013
         B     OJEOV               ENTRY FROM WRITE ROUTINE AT EOV.     24400013
*                                  **EOS HAS BEEN REACHED BUT ALL       24600013
*                                  ** THE INPUT HAS NOT BEEN PROCESSED. 24800013
         SPACE 2                                                        25000013
*  ENTRY FROM WRITE ROUTINE AT END OF SEQUENCE                          25200013
         SPACE 1                                                        25400013
* INCREMENT COUNT OF SEQUENCES ON THIS UNIT                             25600013
         SPACE 1                                                        25800013
         LH    RE,WOJPOINT         TAPE TABLE POINTER(INC WITHIN TABLE) 26000013
         LH    RF,PPITPTBL+34(RE)  SEQUENCE COUNTER FOR THIS UNIT       26200013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY ONE             26400013
         STH   RF,PPITPTBL+34(RE)  RESTORE SEQUENCE COUNTER             26600013
         SPACE 1                                                        26800013
* DETERMINE IF ENOUGH SEQUENCES HAVE BEEN DISTRIBUTED TO SATISFY        27000013
* THE PRESENT SET OF FIBONACCI NUMBERS.                                 27200013
         SPACE 1                                                        27400013
         L     RF,WOJTOTAL         COUNT SEQUENCES TO DISTRIBUTE        27600013
         BCT   RF,OJNOUPDT         BRANCH IF FIBS DO NOT NEED UPDATING  27800013
         SPACE 1                                                        28000013
* CALCULATE NUMBER OF SEQUENCES TO BE DISTRIBUTED AFTER THIS UPDATE     28200013
* OF THE FIBONACCI NUMBERS.                                             28400013
         SPACE 1                                                        28600013
         LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     28800013
         LH    RH,PPITPTBL+102(RH) LAST OF ORIGINAL OLD FIBONACCI NOS.  29000013
         LH    RI,WOJCTN2          COUNT OF (N-2)                       29200013
         MR    RG,RI               MULTIPLY TO DETERMINE NEW SEQ. COUNT 29400013
         ST    RH,WOJTOTAL         RESET NEW COUNT OF SEQ TO DISTRIBUTE 29600013
         SPACE 1                                                        29800013
* UPDATE TO NEXT HIGHER SET OF FIBONACCI NUMBERS                        30000013
         SPACE 1                                                        30200013
OJUPDFIB LH    RF,WOJCTN2          COUNT OF (N-2)                       30400013
         LH    RE,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     30600013
         LA    RE,PPITPTBL+102(RE) ADDR OF LAST OF OLD FIB. NUMBERS     30800013
         LR    RG,RE               ADDR OF LAST OF OLD FIB. NUMBERS     31000013
         LH    RH,0(0,RE)          LAST OF OLD FIBONACCI NUMBERS        31200013
         LR    RJ,RH               LAST OF OLD FIBONACCI NUMBERS        31400013
         LA    RI,2                CONSTANT OF 2                        31600013
OJNEXFIB SR    RE,RI               DECREMENT ADDR TO PRECEEDING FIB.NO. 31800013
         AH    RH,0(0,RE)          LAST OLD FIB.PLUS NEXT TO LAST, ETC. 32000013
         STH   RH,0(0,RG)          TOATAL INTO LAST FIBS POSITION ETC.  32200013
         LR    RH,RJ               LAST OF OLD FIBONACCI NUMBERS        32400013
         SR    RG,RI               DECREMENT ADDR TO PRECEEDING FIB.NO. 32600013
         BCT   RF,OJNEXFIB         BRANCH IF ALL FIBS NOT UPDATED       32800013
         STH   RH,0(0,RE)          ORIGINAL OLD LAST FIB AS NEW 1ST FIB 33000013
         SPACE 1                                                        33200013
* DETERMINE IF THE UPDATED FIBONACCI NUMBERS ARE ALL ODD. IF THEY ARE   33400013
* ALL ODD, ANOTHER UPDATE MUST BE PERFORMED NOW.                        33600013
         SPACE 1                                                        33800013
         LH    RE,WOJALODD         ALL ODD COUNTER (EVERY N UPDATES THE 34000013
*                                  **FIBONACCI NUMBERS ARE ALL ODD)     34200013
         BCT   RE,OJNOTODD         BRANCH IF NOT ALL ODD                34400013
         MVC   WOJALODD(2),WOJCTN  RESET ALL ODD COUNTER TO N           34600013
         SPACE 1                                                        34800013
* CALCULATE NUMBER OF ADDITIONAL SEQUENCES TO BE DISTRIBUTED AFTER      35000013
* THIS UPDATE AND ADD THEM TO PREVIOUS COUNT.                           35200013
         SPACE 1                                                        35400013
         LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     35600013
         LH    RH,PPITPTBL+102(RH) LAST OF ORIGINAL OLD FIBONACCI NOS.  35800013
         LH    RI,WOJCTN2          COUNT OF (N-2)                       36000013
         MR    RG,RI               MULTIPLY TO DETERMINE NEW SEQ. COUNT 36200013
         A     RH,WOJTOTAL         OLD COUNT OF SEQUENCES TO DISTRIBUTE 36400013
         ST    RH,WOJTOTAL         RESET NEW COUNT OF SEQ.TO DISTRIBUTE 36600013
         B     OJUPDFIB            BRANCH TO UPDATE FIBONACCI NUMBERS   36800013
         SPACE 2                                                        37000013
OJNOTODD STH   RE,WOJALODD         SAVE ALL ODD COUNTER                 37200013
         SPACE 1                                                        37400013
* MOVE THE UPDATED FIBONACCI NUMBERS TO THE FUTURE NUMBERS POSITION     37600013
* OF TABLE AND PERMUTE THEM AS NECESSARY FOR THIS UPDATE.               37800013
         SPACE 1                                                        38000013
         MVC   PPITPTBL+68(32),PPITPTBL+102 UPDATED FIBS TO FUTURE FIBS 38200013
         LH    RE,WOJPERM          COUNT OF TIMES TO PERMUTE THIS SET   38400013
         BCT   RE,OJPERMUT         BRANCH IF FUTURE FIBS NEED PERMUTING 38600013
         MVC   WOJPERM(2),WOJCTN1  RESET PERMUTING COUNTER TO (N-1)     38800013
         B     OJRESET             BRANCH TO RESET TAPE TABLE POINTER   39000013
         SPACE 2                                                        39200013
OJPERMUT STH   RE,WOJPERM          SAVE PERMUTING COUNTER               39400013
         MVC   OJMOVER+1(1),WOJINCPT+1 SET LENGTH FIELD IN MOVE INST.   39600013
*                                     *TO MOVE (N-1) FIB.NUMBERS.       39800013
OJPERONE LH    RH,WOJINCPT         INCREMENT TO LAST ITEMS IN TABLE     40000013
         LH    RF,PPITPTBL+68(RH)  LAST OF FUTURE FIBONACCI NUMBERS     40200013
         MVC   PPIWKARE+1(32),PPITPTBL+68 SAVE THE UNPERMUTED FUTURE    40400013
*                                        *FIBS.THIS IS DONE TO AVOID    40600013
*                                        *MOVING OVERLAPPING FIELDS.    40800013
OJMOVER  MVC   PPITPTBL+69(1),PPIWKARE MOVE 1ST (N-1) FUTURE FIBS BACK  41000013
*                                     *TO TABLE,SHIFTED BY 1 POSITION   41200013
         STH   RF,PPITPTBL+68      LAST OF FUTURE FIB AS 1ST FUTURE FIB 41400013
         BCT   RE,OJPERONE         BRANCH TO PERMUTE ONE MORE POSITION  41600013
         B     OJRESET                                                  41800013
         SPACE 2                                                        42000013
* SAVE COUNT OF SEQUENCES TO DISTRIBUTE.                                42200013
         SPACE 1                                                        42400013
OJNOUPDT ST    RF,WOJTOTAL         SAVE COUNT OF SEQS. TO DISTRIBUTE    42600013
         SPACE 1                                                        42800013
* DETERMINE NEXT UNIT TO GET A SEQUENCE                                 43000013
         SPACE 1                                                        43200013
OJBACK1  LTR   RE,RE               TEST TAPE TABLE POINTER FOR ZERO     43400013
         BZ    OJRESET             BRANCH IF ZERO                       43600013
         LA    RF,2                CONSTANT OF 2                        43800013
         SR    RE,RF               DEC TAPE TABLE POINTER 1 POSITION    44000013
         B     OJSTPT                                                   44200013
         SPACE 2                                                        44400013
OJRESET  LH    RE,WOJINCPT         RESET TAPE TABLE POINTER TO LAST POS 44600013
OJSTPT   STH   RE,WOJPOINT         SAVE TAPE TABLE POINTER              44800013
         LH    RF,PPITPTBL+34(RE)  COUNT OF SEQUENCES ON THIS TAPE      45000013
         LH    RG,PPITPTBL+68(RE)  FUTURE COUNT OF SEQUENCES FOR TAPE   45200013
         CLR   RF,RG               COMPARE THE COUNTS                   45400013
         BE    OJBACK1             DEC POSITION IN TAPE TABLE IF EQUAL  45600013
         SPACE 1                                                        45800013
* DETERMINE THE MUNBER OF UNITS THAT STILL REQUIRE SEQUENCES            46000013
* THIS PASS OF THE TAPE TABLE.                                          46200013
         SPACE 1                                                        46400013
         SR    RF,RF               ZERO A REGISTER                      46600013
         LA    RG,2(0,RE)          SAVE TP TBL POINTER+2 AS INC         46800013
OJDEC1   LA    RH,2                CONSTANT OF 2                        47000013
         SR    RG,RH               DECREMENT TAPE TABLE POINTER ONE POS 47200013
         LH    RI,PPITPTBL+34(RG)  COUNT OF SEQUENCES ON THIS TAPE      47400013
         LH    RJ,PPITPTBL+68(RG)  FUTURE COUNT OF SEQS FOR THIS TAPE   47600013
         CLR   RI,RJ               COMPARE THE COUNTS                   47800013
         BE    OJCKLAST            IF EQUAL DO NOT INC COUNTER          48000013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY 1               48200013
OJCKLAST LTR   RG,RG               TEST TAPE TABLE POINTER FOR ZERO     48400013
         BNE   OJDEC1              IF NOT ZERO CONTINUE  CHECKING       48600013
         SPACE 1                                                        48800013
* SET OUTPUT UNIT INDICATOR IN PPIA                                     49000013
         SPACE 1                                                        49200013
         IC    RG,PPITPTBL+1(RE)   OUTPUT UNIT DESIGNATOR               49400013
         STC   RG,PPIDEPHO+3       SET OUTPUT UNIT DESIGNATOR FOR WRITE 49600013
         SPACE 1                                                        49800013
* CHECK COUNT OF TAPES THAT STILL REQUIRE SEQUENCES THIS PASS           50000013
* OF TAPE TABLE AND PROCEED ACCORDINGLY.                                50200013
         SPACE 1                                                        50400013
         BCT   RF,OJDEBLCK         CHECK COUNTER                        50600013
         L     RL,PPINET+4                                              50800013
         SPACE 1                                                        51000013
* EXIT TO REPLACEMENT NETWORK TO REVERSE THE SEQUENCE AFTER THIS        51200013
         SPACE 1                                                        51400013
         B     20(0,RL)            REVERSE THE NEXT SEQUENCE            51600013
         SPACE 2                                                        51800013
OJDEBLCK L     RL,PPIDEB+4                                              52000013
         SPACE 1                                                        52200013
* EXIT TO DEBLOCK ROUTINE (NO REVERSAL OF SEQUENCES NECESSARY)          52400013
         SPACE 1                                                        52600013
         B     8(0,RL)             DEBLOCK A RECORD                     52800013
         SPACE 2                                                        53000013
* ENTRY FROM WRITE ROUTINE AT EOV                                       53200013
         SPACE 1                                                        53400013
OJEOV    L     RK,PPIRMA+4                                              53600013
         LM    RA,RB,MSGP1A02      ADDRESS AND LENGTH OF MESSAGE        53800013
*                                  ' SORT CAPACITY EXCEEDED '           54000013
         SPACE 1                                                        54200013
* EXIT TO SSC TO PRINT ERROR MESSAGE.                                   54400013
         SPACE 1                                                        54600013
         L     RP,PPIADSSC         SSC BASE REGISTER                    54800013
         BAL   RO,12(0,RP)         EXIT TO SSC TO PRINT ERROR MESSAGE   55000013
         SPACE 2                                                        55200013
         SPACE 1                                                        55400013
*APROX RCD CNT IS PPICOUNT -G - B, WHERE G AND B ARE MAX. VALUES.  SO   55600013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO PPICOUNT-G+B OR JUST B.        55800013
*   THIS NEGATIVE CONDITION IS MOST LIKELY IF THE BLOCK BEING WRITTEN   56000013
*   OUT IS SHORT AND/OR RECORD FORMAT IS VARIABLE.                      56200013
         SPACE 1                                                        56400013
         L     RB,PPICOUNT         NO. RCD. READ IN MINUS G             56600013
         A     RB,PPIINSCT         ADD NO. OF INSERTED RECORDS   A27992 56660000
         S     RB,PPIDELCT         SUBTRACT NO. DELETED RECORDS  A27992 56720000
         S     RB,PPISRTG            G - MAX. NO. OF RCDS. IN TREE      56800013
         LH    RP,PPISRTBL           B - F = NO. RCDS/BLOCK             57000013
         TM    PPISW1,X'80'              V = BYTES/BLOCK                57200013
         BO    ROI031                                                   57400013
         SPACE 1                                                        57600013
         LH    RA,PPIRCDL4         B / MIN. RCD. LENGTH = MAX. NO.      57800013
         SR    RO,RO                                                    58000013
         DR    RO,RA                 RCDS. IN BLOCK                     58200013
ROI031   CR    RB,RP               CHECK TO MAKE SURE CNT ISN'T         58400013
         BH    ROI032                NEGATIVE                           58600013
         SPACE 1                                                        58800013
         AR    RB,RP               ADD B TO CNT                         59000013
         CR    RB,RP               IS CNT STILL NEG. -IF YES,           59200013
         BNL   ROI033                                                   59400013
         SPACE 1                                                        59600013
         LR    RB,RP               SET CNT TO B                         59800013
         B     ROI033                                                   60000013
         SPACE 2                                                        60200013
ROI032   SR    RB,RP               APROX. RCD CNT = PPICOUNT -G -B      60400013
ROI033   CVD   RB,PPIWKARE           USUALLY - SET UP CNT FOR           60600013
         UNPK  PPIWKARE+8(8),PPIWKARE(8) PRINTING                       60800013
         OI    PPIWKARE+15,X'F0'                                        61000013
         SPACE 2                                                        61200013
         L     RO,PPIRMA+4                                              61400013
         LM    RA,RB,MSGP1A06                                           61600013
         MVC   MSGP1R06+24(7),PPIWKARE+9                                61800013
         L     RP,PPIRCV+4         PRINT MESSAGE - APROX RCD CNT        62000013
         BAL   RO,12(0,RP)                                              62200013
         SPACE 1                                                        62400013
* EXIT TO SSC  TO ABORT JOB, PHYSICAL N(MAX) EXCEEDED                   62600013
         SPACE 1                                                        62800013
         L     RP,PPIADSSC         SSC BASE REGISTER                    63000013
         B     16(0,RP)            EXIT TO SSC TO ABORT THE SORT        63200013
         SPACE 2                                                        63400013
* ENTRY FROM WRITE ROUTINE AT EOF                                       63600013
         SPACE 1                                                        63800013
* INCREMENT COUNT OF SEQUENCES ON THIS UNIT                             64000013
         SPACE 1                                                        64200013
OJEOF    LH    RE,WOJPOINT         TAPE TABLE POINTER(INC WITHIN TABLE) 64400013
         LH    RF,PPITPTBL+34(RE)  SEQUENCE COUNTER FOR THIS UNIT       64600013
         LA    RF,1(0,RF)          INCREMENT COUNTER BY ONE             64800013
         STH   RF,PPITPTBL+34(RE)  RESTORE SEQUENCE COUNTER             65000013
         SPACE 1                                                        65200013
* SET OPEN BIT ON IN LAST UNIT IN TAPE TABLE.                           65400013
         SPACE 1                                                        65600013
         LH    RE,WOJINCPT         INCREMENT TO LAST POSITIONS IN TABLE 65800013
         LA    RF,PPITPTBL+2(RE)   ADDR OF BYTE IN TAPE TABLE FOR BIT   66000013
         OI    0(RF),X'40'         SET OPEN BIT ON                      66200013
         SPACE 1                                                        66400013
* TURN OFF OPEN BITS IN FIRST (N-1) UNITS IN TAPE TABLE                 66600013
* THAT DID NOT RECEIVE SEQUENCES.                                       66800013
         SPACE 1                                                        67000013
         LH    RF,WOJCTN1          COUNT OF (N-1)                       67200013
         LA    RG,PPITPTBL         ADDRESS OF TAPE TABLE     2          67400013
OJMOROFF SR    RH,RH               ZERO THE REGISTER                    67600013
         SH    RH,34(0,RG)         FIRST SEQUENCE COUNTER               67800013
         BNE   OJLEAVON            IF NOT ZERO LEAVE OPEN BIT ON        68000013
         NI    0(RG),X'BF'         TURN OPEN BIT OFF                    68200013
OJLEAVON LA    RG,2(0,RG)          INCREMENT TO NEXT TABLE POSITION     68400013
         BCT   RF,OJMOROFF         BRANCH IF MORE COUNTERS TO CHECK     68600013
         SPACE 1                                                        68800013
* SET UP COUNTERS FOR DUMMY SEQUENCES AS NECESSARY FOR PHASE 2          69000013
* IF FIBONACCI LEVEL IS ALL ONES GO TO NEXT LEVEL BEFORE SETTING DUMMYS 69200013
         SPACE 1                                                        69400013
         LA    RF,2                CONSTANT OF 2                        69600013
         LA    RG,1                CONSTANT OF 1                        69800013
         SH    RG,PPITPTBL+68      FIRST OF FUTURE FIBS                 70000013
         BNE   OJNOTONE            BRANCH IF COUNT WAS NOT ONE          70200013
         LH    RH,WOJCTN2          COUNT OF (N-2)                       70400013
         LA    RG,PPITPTBL+68      ADDRESS OF FIRST FUTURE FIB          70600013
OJSETTWO STH   RF,0(0,RG)          SET FUTURE FIB TO TWO                70800013
         LA    RG,2(0,RG)          INCREMENT TO NEXT FUTURE FIB         71000013
         BCT   RH,OJSETTWO         BRANCH IF MORE FIBS TO BE UPDATED    71200013
OJNOTONE LH    RG,WOJCTN1          COUNT OF (N-1)                       71400013
OJMORDUM LH    RH,PPITPTBL+68(RE)  LAST OF FUTURE FIBONACCI NUMBERS,ETC 71600013
         SH    RH,PPITPTBL+34(RE)  COUNT OF SEQUENCES ALREADY ON UNIT   71800013
         STH   RH,PPITPTBL+68(RE)  COUNT OF DUMMYS FOR THIS UNIT        72000013
         SR    RE,RF               DECREMENT INCREMENT POINTER BY 1 POS 72200013
         BCT   RG,OJMORDUM         BRANCH IF MORE DUMMYS TO CALCULATE   72400013
         SPACE 1                                                        72600013
* REVERSE SEQUENCE INDICATOR BIT AND EXIT TO CLOSE ROUTINE              72800013
* WHICH WILL PRINT A MESSAGE AND EXIT TO SSC TO CALL PHASE 2.           73000013
         SPACE 1                                                        73200013
         XI    PPISW1+3,X'10'      REVERSE SEQUENCE INDICATOR BIT       73400013
         L     RP,PPIADSSC                                              73600013
         LA    RB,0                RETURN TO SSC REQUESTING PHASE 2     73800013
         BAL   RO,20(0,RP)                                              74000013
         EJECT                                                          74200013
         SPACE 1                                                        74400013
*** WORK AREAS                                                          74600013
         SPACE 1                                                        74800013
WOJCTN   DS    1H                  COUNT OF N                           75000013
WOJCTN1  DS    1H                  COUNT OF (N-1)                       75200013
WOJCTN2  DS    1H                  COUNT OF (N-2)                       75400013
WOJALODD DS    1H                  ALL ODD COUNTER (INITIALLY N)        75600013
WOJPERM  DS    1H                  PERMUTE COUNTER (INITIALLY N-1)      75800013
WOJPOINT DS    1H                  TAPE TABLE POINTER (INCREMENT)       76000013
WOJINCPT DS    1H                  INCREMENT TO LAST ITEMS IN TABLE     76200013
WOJTOTAL DS    1F                  COUNT OF SEQUENCES TO DISTRIBUTE     76400013
         EJECT                                                          76600013
*** IERRMA *** MESSAGE MODULE                                           76800013
         SPACE 1                                                        77000013
*********************************************************************   77200013
* THIS MODULE IS A DSECT OF RUNNING MODULE IERRMA.                      77400013
*********************************************************************   77600013
         SPACE 1                                                        77800013
DIERRMA  DSECT                                                          78000013
         SPACE 1                                                        78200013
         COPY  RMAMAIN                                                  78400013
         SPACE 1                                                        78600013
         EJECT                                                          78800013
         SMPPI                                                          79000013
         END                                                            79200013
